lib/PublicInbox/Msgmap.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # bidirectional Message-ID <-> Article Number mapping
   4 package PublicInbox::Msgmap;
   5 use strict;
   6 use warnings;
   7 use fields qw(dbh mid_insert mid_for num_for num_minmax);
   8 use DBI;
   9 use DBD::SQLite;
  10
  11 sub new {
  12         my ($class, $git_dir, $writable) = @_;
  13         my $d = "$git_dir/public-inbox";
  14         if ($writable && !-d $d && !mkdir $d) {
  15                 my $err = $!;
  16                 -d $d or die "$d not created: $err";
  17         }
  18         my $f = "$d/msgmap.sqlite3";
  19         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  20                 AutoCommit => 1,
  21                 RaiseError => 1,
  22                 PrintError => 0,
  23                 sqlite_use_immediate_transaction => 1,
  24         });
  25         $dbh->do('PRAGMA case_sensitive_like = ON');
  26         my $self = fields::new($class);
  27         $self->{dbh} = $dbh;
  28
  29         if ($writable) {
  30                 create_tables($dbh);
  31                 $self->created_at(time) unless $self->created_at;
  32         }
  33         $self;
  34 }
  35
  36 sub meta_accessor {
  37         my ($self, $key, $value) = @_;
  38         use constant {
  39                 meta_select => 'SELECT val FROM meta WHERE key = ? LIMIT 1',
  40                 meta_update => 'UPDATE meta SET val = ? WHERE key = ? LIMIT 1',
  41                 meta_insert => 'INSERT INTO meta (key,val) VALUES (?,?)',
  42         };
  43
  44         my $dbh = $self->{dbh};
  45         my $prev;
  46         defined $value or
  47                 return $dbh->selectrow_array(meta_select, undef, $key);
  48
  49         $dbh->begin_work;
  50         eval {
  51                 $prev = $dbh->selectrow_array(meta_select, undef, $key);
  52
  53                 if (defined $prev) {
  54                         $dbh->do(meta_update, undef, $value, $key);
  55                 } else {
  56                         $dbh->do(meta_insert, undef, $key, $value);
  57                 }
  58                 $dbh->commit;
  59         };
  60         my $err = $@;
  61         return $prev unless $err;
  62
  63         $dbh->rollback;
  64         die $err;
  65 }
  66
  67 sub last_commit {
  68         my ($self, $commit) = @_;
  69         $self->meta_accessor('last_commit', $commit);
  70 }
  71
  72 sub created_at {
  73         my ($self, $second) = @_;
  74         $self->meta_accessor('created_at', $second);
  75 }
  76
  77 sub mid_insert {
  78         my ($self, $mid) = @_;
  79         my $dbh = $self->{dbh};
  80         use constant MID_INSERT => 'INSERT INTO msgmap (mid) VALUES (?)';
  81         my $sth = $self->{mid_insert} ||= $dbh->prepare(MID_INSERT);
  82         $sth->bind_param(1, $mid);
  83         $sth->execute;
  84         $dbh->last_insert_id(undef, undef, 'msgmap', 'num');
  85 }
  86
  87 use constant MID_FOR => 'SELECT mid FROM msgmap WHERE num = ? LIMIT 1';
  88 sub mid_for {
  89         my ($self, $num) = @_;
  90         my $dbh = $self->{dbh};
  91         my $sth = $self->{mid_for} ||= $dbh->prepare(MID_FOR);
  92         $sth->bind_param(1, $num);
  93         $sth->execute;
  94         $sth->fetchrow_array;
  95 }
  96
  97 sub num_for {
  98         my ($self, $mid) = @_;
  99         my $dbh = $self->{dbh};
 100         use constant NUM_FOR => 'SELECT num FROM msgmap WHERE mid = ? LIMIT 1';
 101         my $sth = $self->{num_for} ||= $dbh->prepare(NUM_FOR);
 102         $sth->bind_param(1, $mid);
 103         $sth->execute;
 104         $sth->fetchrow_array;
 105 }
 106
 107 sub minmax {
 108         my ($self) = @_;
 109         my $dbh = $self->{dbh};
 110         use constant NUM_MINMAX => 'SELECT MIN(num),MAX(num) FROM msgmap';
 111         my $sth = $self->{num_minmax} ||= $dbh->prepare(NUM_MINMAX);
 112         $sth->execute;
 113         $sth->fetchrow_array;
 114 }
 115
 116 sub mid_prefixes {
 117         my ($self, $pfx, $limit) = @_;
 118
 119         die "No prefix given" unless (defined $pfx && $pfx ne '');
 120         $pfx =~ s/([%_])/\\$1/g;
 121         $pfx .= '%';
 122
 123         $limit ||= 100;
 124         $limit += 0; # force to integer
 125         $limit ||= 100;
 126
 127         $self->{dbh}->selectcol_arrayref('SELECT mid FROM msgmap ' .
 128                                          'WHERE mid LIKE ? ESCAPE ? ' .
 129                                          "ORDER BY num DESC LIMIT $limit",
 130                                          undef, $pfx, '\\');
 131 }
 132
 133 sub mid_delete {
 134         my ($self, $mid) = @_;
 135         my $dbh = $self->{dbh};
 136         use constant MID_DELETE => 'DELETE FROM msgmap WHERE mid = ?';
 137         my $sth = $dbh->prepare(MID_DELETE);
 138         $sth->bind_param(1, $mid);
 139         $sth->execute;
 140 }
 141
 142 sub create_tables {
 143         my ($dbh) = @_;
 144         my $e;
 145
 146         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM msgmap;') };
 147         defined $e or $dbh->do('CREATE TABLE msgmap (' .
 148                         'num INTEGER PRIMARY KEY AUTOINCREMENT, '.
 149                         'mid VARCHAR(1000) NOT NULL, ' .
 150                         'UNIQUE (mid) )');
 151
 152         $e = eval { $dbh->selectrow_array('EXPLAIN SELECT * FROM meta') };
 153         defined $e or $dbh->do('CREATE TABLE meta (' .
 154                         'key VARCHAR(32) PRIMARY KEY, '.
 155                         'val VARCHAR(255) NOT NULL)');
 156 }
 157
 158 sub each_id_batch {
 159         my ($self, $cb) = @_;
 160         my $dbh = $self->{dbh};
 161         my $n = 0;
 162         my $total = 0;
 163         my $nr;
 164         my $sth = $dbh->prepare('SELECT num FROM msgmap WHERE num > ? '.
 165                                 'ORDER BY num ASC LIMIT 1000');
 166         while (1) {
 167                 $sth->execute($n);
 168                 my $ary = $sth->fetchall_arrayref;
 169                 @$ary = map { $_->[0] } @$ary;
 170                 $nr = scalar @$ary;
 171                 last if $nr == 0;
 172                 $total += $nr;
 173                 $n = $ary->[-1];
 174                 $cb->($ary);
 175         }
 176         $total;
 177 }
 178
 179 1;