lib/PublicInbox/MultiMidQueue.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # temporary queue for public-inbox-index to support multi-Message-ID
   5 # messages on mirrors of v2 inboxes
   6 package PublicInbox::MultiMidQueue;
   7 use strict;
   8 use SDBM_File; # part of Perl standard library
   9 use Fcntl qw(O_RDWR O_CREAT);
  10 use File::Temp 0.19 (); # 0.19 for ->newdir
  11 my %e = (freebsd => 0x100000, linux => 0x80000, openbsd => 0x10000);
  12 my $O_CLOEXEC = $e{$^O} // 0;
  13
  14 sub new {
  15         my ($class) = @_;
  16         my $tmpdir = File::Temp->newdir('multi-mid-q-XXXXXX', TMPDIR => 1);
  17         my $base = $tmpdir->dirname . '/q';
  18         my %sdbm;
  19         my $flags = O_RDWR|O_CREAT;
  20         if (!tie(%sdbm, 'SDBM_File', $base, $flags|$O_CLOEXEC, 0600)) {
  21                 if (!tie(%sdbm, 'SDBM_File', $base, $flags, 0600)) {
  22                         die "could not tie ($base): $!";
  23                 }
  24                 $O_CLOEXEC = 0;
  25         }
  26
  27         bless {
  28                 cur => 1,
  29                 min => 1,
  30                 max => 0,
  31                 sdbm => \%sdbm,
  32                 tmpdir => $tmpdir,
  33         }, $class;
  34 }
  35
  36 sub set_oid {
  37         my ($self, $i, $oid, $v2w) = @_;
  38         $self->{max} = $i if $i > $self->{max};
  39         $self->{min} = $i if $i < $self->{min};
  40         $self->{sdbm}->{$i} = "$oid\t$v2w->{autime}\t$v2w->{cotime}";
  41 }
  42
  43 sub get_oid {
  44         my ($self, $i, $v2w) = @_;
  45         my $rec = $self->{sdbm}->{$i} or return;
  46         my ($oid, $autime, $cotime) = split(/\t/, $rec);
  47         $v2w->{autime} = $autime;
  48         $v2w->{cotime} = $cotime;
  49         $oid
  50 }
  51
  52 sub push_oid {
  53         my ($self, $oid, $v2w) = @_;
  54         set_oid($self, $self->{cur}++, $oid, $v2w);
  55 }
  56
  57 1;