lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 # LISTGROUP could get pretty bad, too...
  38 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  39
  40 my $EXPMAP; # fd -> [ idle_time, $self ]
  41 my $expt;
  42 our $EXPTIME = 180; # 3 minutes
  43 my $nextt;
  44
  45 my $nextq = [];
  46 sub next_tick () {
  47         $nextt = undef;
  48         my $q = $nextq;
  49         $nextq = [];
  50         foreach my $nntp (@$q) {
  51                 # for request && response protocols, always finish writing
  52                 # before finishing reading:
  53                 if (my $long_cb = $nntp->{long_res}) {
  54                         $nntp->write($long_cb);
  55                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  56                         event_read($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub update_idle_time ($) {
  62         my ($self) = @_;
  63         my $fd = $self->{fd};
  64         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  65 }
  66
  67 sub expire_old () {
  68         my $now = now();
  69         my $exp = $EXPTIME;
  70         my $old = $now - $exp;
  71         my $nr = 0;
  72         my %new;
  73         while (my ($fd, $v) = each %$EXPMAP) {
  74                 my ($idle_time, $nntp) = @$v;
  75                 if ($idle_time < $old) {
  76                         $nntp->close; # idempotent
  77                 } else {
  78                         ++$nr;
  79                         $new{$fd} = $v;
  80                 }
  81         }
  82         $EXPMAP = \%new;
  83         if ($nr) {
  84                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  85         } else {
  86                 $expt = undef;
  87                 # noop to kick outselves out of the loop ASAP so descriptors
  88                 # really get closed
  89                 PublicInbox::EvCleanup::asap(sub {});
  90         }
  91 }
  92
  93 sub new ($$$) {
  94         my ($class, $sock, $nntpd) = @_;
  95         my $self = fields::new($class);
  96         $self->SUPER::new($sock);
  97         $self->{nntpd} = $nntpd;
  98         res($self, '201 server ready - post via email');
  99         $self->{rbuf} = '';
 100         $self->watch_read(1);
 101         update_idle_time($self);
 102         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 103         $self;
 104 }
 105
 106 sub args_ok ($$) {
 107         my ($cb, $argc) = @_;
 108         my $tot = prototype $cb;
 109         my ($nreq, undef) = split(';', $tot);
 110         $nreq = ($nreq =~ tr/$//) - 1;
 111         $tot = ($tot =~ tr/$//) - 1;
 112         ($argc <= $tot && $argc >= $nreq);
 113 }
 114
 115 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 116 sub process_line ($$) {
 117         my ($self, $l) = @_;
 118         my ($req, @args) = split(/\s+/, $l);
 119         $req = lc($req);
 120         $req = eval {
 121                 no strict 'refs';
 122                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 123         };
 124         return res($self, '500 command not recognized') unless $req;
 125         return res($self, r501) unless args_ok($req, scalar @args);
 126
 127         my $res = eval { $req->($self, @args) };
 128         my $err = $@;
 129         if ($err && !$self->{closed}) {
 130                 local $/ = "\n";
 131                 chomp($l);
 132                 err($self, 'error from: %s (%s)', $l, $err);
 133                 $res = '503 program fault - command not performed';
 134         }
 135         return 0 unless defined $res;
 136         res($self, $res);
 137 }
 138
 139 sub cmd_mode ($$) {
 140         my ($self, $arg) = @_;
 141         $arg = uc $arg;
 142         return r501 unless $arg eq 'READER';
 143         '201 Posting prohibited';
 144 }
 145
 146 sub cmd_slave ($) { '202 slave status noted' }
 147
 148 sub cmd_xgtitle ($;$) {
 149         my ($self, $wildmat) = @_;
 150         more($self, '282 list of groups and descriptions follows');
 151         list_newsgroups($self, $wildmat);
 152         '.'
 153 }
 154
 155 sub list_overview_fmt ($) {
 156         my ($self) = @_;
 157         do_more($self, $OVERVIEW_FMT);
 158 }
 159
 160 sub list_headers ($;$) {
 161         my ($self) = @_;
 162         do_more($self, $LIST_HEADERS);
 163 }
 164
 165 sub list_active ($;$) {
 166         my ($self, $wildmat) = @_;
 167         wildmat2re($wildmat);
 168         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 169                 $ng->{newsgroup} =~ $wildmat or next;
 170                 group_line($self, $ng);
 171         }
 172 }
 173
 174 sub list_active_times ($;$) {
 175         my ($self, $wildmat) = @_;
 176         wildmat2re($wildmat);
 177         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 178                 $ng->{newsgroup} =~ $wildmat or next;
 179                 my $c = eval { $ng->mm->created_at } || time;
 180                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 181         }
 182 }
 183
 184 sub list_newsgroups ($;$) {
 185         my ($self, $wildmat) = @_;
 186         wildmat2re($wildmat);
 187         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 188                 $ng->{newsgroup} =~ $wildmat or next;
 189                 my $d = $ng->description;
 190                 more($self, "$ng->{newsgroup} $d");
 191         }
 192 }
 193
 194 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 195 sub cmd_list ($;$$) {
 196         my ($self, @args) = @_;
 197         if (scalar @args) {
 198                 my $arg = shift @args;
 199                 $arg =~ tr/A-Z./a-z_/;
 200                 $arg = "list_$arg";
 201                 return r501 if $DISABLED{$arg};
 202
 203                 $arg = eval {
 204                         no strict 'refs';
 205                         *{$arg}{CODE};
 206                 };
 207                 return r501 unless $arg && args_ok($arg, scalar @args);
 208                 more($self, '215 information follows');
 209                 $arg->($self, @args);
 210         } else {
 211                 more($self, '215 list of newsgroups follows');
 212                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 213                         group_line($self, $ng);
 214                 }
 215         }
 216         '.'
 217 }
 218
 219 sub cmd_listgroup ($;$) {
 220         my ($self, $group) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226
 227         $self->{ng} or return '412 no newsgroup selected';
 228         long_response($self, 0, long_response_limit, sub {
 229                 my ($i) = @_;
 230                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 231                         my ($ary) = @_;
 232                         more($self, join("\r\n", @$ary));
 233                 });
 234
 235                 # -1 to adjust for implicit increment in long_response
 236                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 237         });
 238 }
 239
 240 sub parse_time ($$;$) {
 241         my ($date, $time, $gmt) = @_;
 242         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 243         if (defined $gmt) {
 244                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 245                 $gmt = 1;
 246         }
 247         my @now = $gmt ? gmtime : localtime;
 248         my ($YYYY, $MM, $DD);
 249         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 250                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 251         } else { # legacy clients send YYMMDD
 252                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 253                 my $cur_year = $now[5] + 1900;
 254                 if ($YYYY > $cur_year) {
 255                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 256                 }
 257         }
 258         if ($gmt) {
 259                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 260         } else {
 261                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 262         }
 263 }
 264
 265 sub group_line ($$) {
 266         my ($self, $ng) = @_;
 267         my ($min, $max) = $ng->mm->minmax;
 268         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 269 }
 270
 271 sub cmd_newgroups ($$$;$$) {
 272         my ($self, $date, $time, $gmt, $dists) = @_;
 273         my $ts = eval { parse_time($date, $time, $gmt) };
 274         return r501 if $@;
 275
 276         # TODO dists
 277         more($self, '231 list of new newsgroups follows');
 278         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 279                 my $c = eval { $ng->mm->created_at } || 0;
 280                 next unless $c > $ts;
 281                 group_line($self, $ng);
 282         }
 283         '.'
 284 }
 285
 286 sub wildmat2re (;$) {
 287         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 288         my %keep;
 289         my $salt = rand;
 290         my $tmp = $_[0];
 291
 292         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 293                 my $orig = $1;
 294                 my $key = sha1_hex($orig . $salt);
 295                 $orig =~ s/([^\w\-])+/\Q$1/g;
 296                 $keep{$key} = $orig;
 297                 $key
 298                 #gex;
 299         my %map = ('*' => '.*', '?' => '.' );
 300         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 301         if (scalar %keep) {
 302                 $tmp =~ s#([a-f0-9]{40})#
 303                         my $orig = $keep{$1};
 304                         defined $orig ? $orig : $1;
 305                         #ge;
 306         }
 307         $_[0] = qr/\A$tmp\z/;
 308 }
 309
 310 sub ngpat2re (;$) {
 311         return $_[0] = qr/\A\z/ unless defined $_[0];
 312         my %map = ('*' => '.*', ',' => '|');
 313         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 314         $_[0] = qr/\A(?:$_[0])\z/;
 315 }
 316
 317 sub cmd_newnews ($$$$;$$) {
 318         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 319         my $ts = eval { parse_time($date, $time, $gmt) };
 320         return r501 if $@;
 321         more($self, '230 list of new articles by message-id follows');
 322         my ($keep, $skip) = split('!', $newsgroups, 2);
 323         ngpat2re($keep);
 324         ngpat2re($skip);
 325         my @srch;
 326         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 327                 $ng->{newsgroup} =~ $keep or next;
 328                 $ng->{newsgroup} =~ $skip and next;
 329                 my $srch = $ng->search or next;
 330                 push @srch, $srch;
 331         };
 332         return '.' unless @srch;
 333
 334         $ts .= '..';
 335         my $opts = { asc => 1, limit => 1000, offset => 0 };
 336         long_response($self, 0, long_response_limit, sub {
 337                 my ($i) = @_;
 338                 my $srch = $srch[0];
 339                 my $res = $srch->query($ts, $opts);
 340                 my $msgs = $res->{msgs};
 341                 if (my $nr = scalar @$msgs) {
 342                         more($self, '<' .
 343                                 join(">\r\n<", map { $_->mid } @$msgs ).
 344                                 '>');
 345                         $opts->{offset} += $nr;
 346                 } else {
 347                         shift @srch;
 348                         if (@srch) { # continue onto next newsgroup
 349                                 $opts->{offset} = 0;
 350                         } else { # break out of the long response.
 351                                 $$i = long_response_limit;
 352                         }
 353                 }
 354         });
 355 }
 356
 357 sub cmd_group ($$) {
 358         my ($self, $group) = @_;
 359         my $no_such = '411 no such news group';
 360         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 361
 362         $self->{ng} = $ng;
 363         my ($min, $max) = $ng->mm->minmax;
 364         $min ||= 0;
 365         $max ||= 0;
 366         $self->{article} = $min;
 367         my $est_size = $max - $min;
 368         "211 $est_size $min $max $group";
 369 }
 370
 371 sub article_adj ($$) {
 372         my ($self, $off) = @_;
 373         my $ng = $self->{ng} or return '412 no newsgroup selected';
 374
 375         my $n = $self->{article};
 376         defined $n or return '420 no current article has been selected';
 377
 378         $n += $off;
 379         my $mid = $ng->mm->mid_for($n);
 380         unless ($mid) {
 381                 $n = $off > 0 ? 'next' : 'previous';
 382                 return "421 no $n article in this group";
 383         }
 384         $self->{article} = $n;
 385         "223 $n <$mid> article retrieved - request text separately";
 386 }
 387
 388 sub cmd_next ($) { article_adj($_[0], 1) }
 389 sub cmd_last ($) { article_adj($_[0], -1) }
 390
 391 # We want to encourage using email and CC-ing everybody involved to avoid
 392 # the single-point-of-failure a single server provides.
 393 sub cmd_post ($) {
 394         my ($self) = @_;
 395         my $ng = $self->{ng};
 396         $ng ? "440 mailto:$ng->{-primary_address} to post"
 397                 : '440 posting not allowed'
 398 }
 399
 400 sub cmd_quit ($) {
 401         my ($self) = @_;
 402         res($self, '205 closing connection - goodbye!');
 403         $self->close;
 404         undef;
 405 }
 406
 407 sub header_append ($$$) {
 408         my ($hdr, $k, $v) = @_;
 409         my @v = $hdr->header($k);
 410         foreach (@v) {
 411                 return if $v eq $_;
 412         }
 413         $hdr->header_set($k, @v, $v);
 414 }
 415
 416 sub set_nntp_headers {
 417         my ($hdr, $ng, $n, $mid) = @_;
 418
 419         # clobber some
 420         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 421         $hdr->header_set('Xref', xref($ng, $n));
 422         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 423         if (my $url = $ng->base_url) {
 424                 $mid = mid_escape($mid);
 425                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 426                 header_append($hdr, 'List-Archive', "<$url>");
 427         }
 428 }
 429
 430 sub art_lookup ($$$) {
 431         my ($self, $art, $set_headers) = @_;
 432         my $ng = $self->{ng};
 433         my ($n, $mid);
 434         my $err;
 435         if (defined $art) {
 436                 if ($art =~ /\A\d+\z/o) {
 437                         $err = '423 no such article number in this group';
 438                         $n = int($art);
 439                         goto find_mid;
 440                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 441                         $mid = $1;
 442                         $err = r430;
 443                         $n = $ng->mm->num_for($mid) if $ng;
 444                         goto found if defined $n;
 445                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 446                                 $n = $g->mm->num_for($mid);
 447                                 if (defined $n) {
 448                                         $ng = $g;
 449                                         goto found;
 450                                 }
 451                         }
 452                         return $err;
 453                 } else {
 454                         return r501;
 455                 }
 456         } else {
 457                 $err = '420 no current article has been selected';
 458                 $n = $self->{article};
 459                 defined $n or return $err;
 460 find_mid:
 461                 $ng or return '412 no newsgroup has been selected';
 462                 $mid = $ng->mm->mid_for($n);
 463                 defined $mid or return $err;
 464         }
 465 found:
 466         my $bytes;
 467         my $s = eval { $ng->msg_by_mid($mid, \$bytes) } or return $err;
 468         $s = Email::Simple->new($s);
 469         my $lines;
 470         if ($set_headers) {
 471                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 472                 $lines = $s->body =~ tr!\n!\n!;
 473
 474                 # must be last
 475                 $s->body_set('') if ($set_headers == 2);
 476         }
 477         [ $n, $mid, $s, $bytes, $lines, $ng ];
 478 }
 479
 480 sub simple_body_write ($$) {
 481         my ($self, $s) = @_;
 482         my $body = $s->body;
 483         $s->body_set('');
 484         $body =~ s/^\./../smg;
 485         $body =~ s/(?<!\r)\n/\r\n/sg;
 486         do_more($self, $body);
 487         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 488         '.'
 489 }
 490
 491 sub set_art {
 492         my ($self, $art) = @_;
 493         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 494 }
 495
 496 sub _header ($) {
 497         my $hdr = $_[0]->header_obj->as_string;
 498         utf8::encode($hdr);
 499         $hdr
 500 }
 501
 502 sub cmd_article ($;$) {
 503         my ($self, $art) = @_;
 504         my $r = art_lookup($self, $art, 1);
 505         return $r unless ref $r;
 506         my ($n, $mid, $s) = @$r;
 507         set_art($self, $art);
 508         more($self, "220 $n <$mid> article retrieved - head and body follow");
 509         do_more($self, _header($s));
 510         do_more($self, "\r\n");
 511         simple_body_write($self, $s);
 512 }
 513
 514 sub cmd_head ($;$) {
 515         my ($self, $art) = @_;
 516         my $r = art_lookup($self, $art, 2);
 517         return $r unless ref $r;
 518         my ($n, $mid, $s) = @$r;
 519         set_art($self, $art);
 520         more($self, "221 $n <$mid> article retrieved - head follows");
 521         do_more($self, _header($s));
 522         '.'
 523 }
 524
 525 sub cmd_body ($;$) {
 526         my ($self, $art) = @_;
 527         my $r = art_lookup($self, $art, 0);
 528         return $r unless ref $r;
 529         my ($n, $mid, $s) = @$r;
 530         set_art($self, $art);
 531         more($self, "222 $n <$mid> article retrieved - body follows");
 532         simple_body_write($self, $s);
 533 }
 534
 535 sub cmd_stat ($;$) {
 536         my ($self, $art) = @_;
 537         my $r = art_lookup($self, $art, 0);
 538         return $r unless ref $r;
 539         my ($n, $mid, undef) = @$r;
 540         set_art($self, $art);
 541         "223 $n <$mid> article retrieved - request text separately";
 542 }
 543
 544 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 545
 546 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 547
 548 sub cmd_help ($) {
 549         my ($self) = @_;
 550         more($self, '100 help text follows');
 551         '.'
 552 }
 553
 554 sub get_range ($$) {
 555         my ($self, $range) = @_;
 556         my $ng = $self->{ng} or return '412 no news group has been selected';
 557         defined $range or return '420 No article(s) selected';
 558         my ($beg, $end);
 559         my ($min, $max) = $ng->mm->minmax;
 560         if ($range =~ /\A(\d+)\z/) {
 561                 $beg = $end = $1;
 562         } elsif ($range =~ /\A(\d+)-\z/) {
 563                 ($beg, $end) = ($1, $max);
 564         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 565                 ($beg, $end) = ($1, $2);
 566         } else {
 567                 return r501;
 568         }
 569         $beg = $min if ($beg < $min);
 570         $end = $max if ($end > $max);
 571         return '420 No article(s) selected' if ($beg > $end);
 572         [ $beg, $end ];
 573 }
 574
 575 sub long_response ($$$$) {
 576         my ($self, $beg, $end, $cb) = @_;
 577         die "BUG: nested long response" if $self->{long_res};
 578
 579         my $fd = $self->{fd};
 580         defined $fd or return;
 581         # make sure we disable reading during a long response,
 582         # clients should not be sending us stuff and making us do more
 583         # work while we are stream a response to them
 584         $self->watch_read(0);
 585         my $t0 = now();
 586         $self->{long_res} = sub {
 587                 # limit our own running time for fairness with other
 588                 # clients and to avoid buffering too much:
 589                 my $lim = 100;
 590
 591                 my $err;
 592                 do {
 593                         eval { $cb->(\$beg, \$lim) };
 594                 } until (($err = $@) || $self->{closed} ||
 595                          ++$beg > $end || --$lim < 0 ||
 596                          $self->{write_buf_size});
 597
 598                 if ($err || $self->{closed}) {
 599                         $self->{long_res} = undef;
 600
 601                         if ($err) {
 602                                 err($self,
 603                                     "%s during long response[$fd] - %0.6f",
 604                                     $err, now() - $t0);
 605                         }
 606                         if ($self->{closed}) {
 607                                 out($self, " deferred[$fd] aborted - %0.6f",
 608                                            now() - $t0);
 609                         } else {
 610                                 update_idle_time($self);
 611                                 $self->watch_read(1);
 612                         }
 613                 } elsif ($lim < 0 || $self->{write_buf_size}) {
 614                         # no recursion, schedule another call ASAP
 615                         # but only after all pending writes are done
 616                         update_idle_time($self);
 617
 618                         push @$nextq, $self;
 619                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 620                 } else { # all done!
 621                         $self->{long_res} = undef;
 622                         $self->watch_read(1);
 623                         res($self, '.');
 624                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 625                 }
 626         };
 627         $self->{long_res}->(); # kick off!
 628         undef;
 629 }
 630
 631 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 632         my ($self, $xhdr, $range) = @_;
 633
 634         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 635                 my ($ng, $n) = mid_lookup($self, $1);
 636                 return r430 unless $n;
 637                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 638         } else { # numeric range
 639                 $range = $self->{article} unless defined $range;
 640                 my $r = get_range($self, $range);
 641                 return $r unless ref $r;
 642                 my $mm = $self->{ng}->mm;
 643                 my ($beg, $end) = @$r;
 644                 more($self, $xhdr ? r221 : r225);
 645                 long_response($self, $beg, $end, sub {
 646                         my ($i) = @_;
 647                         my $mid = $mm->mid_for($$i);
 648                         more($self, "$$i <$mid>") if defined $mid;
 649                 });
 650         }
 651 }
 652
 653 sub xref ($$) {
 654         my ($ng, $n) = @_;
 655         "$ng->{domain} $ng->{newsgroup}:$n"
 656 }
 657
 658 sub mid_lookup ($$) {
 659         my ($self, $mid) = @_;
 660         my $self_ng = $self->{ng};
 661         if ($self_ng) {
 662                 my $n = $self_ng->mm->num_for($mid);
 663                 return ($self_ng, $n) if defined $n;
 664         }
 665         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 666                 next if defined $self_ng && $ng eq $self_ng;
 667                 my $n = $ng->mm->num_for($mid);
 668                 return ($ng, $n) if defined $n;
 669         }
 670         (undef, undef);
 671 }
 672
 673 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 674         my ($self, $xhdr, $range) = @_;
 675
 676         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 677                 my ($ng, $n) = mid_lookup($self, $1);
 678                 return r430 unless $n;
 679                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 680         } else { # numeric range
 681                 $range = $self->{article} unless defined $range;
 682                 my $r = get_range($self, $range);
 683                 return $r unless ref $r;
 684                 my $ng = $self->{ng};
 685                 my $mm = $ng->mm;
 686                 my ($beg, $end) = @$r;
 687                 more($self, $xhdr ? r221 : r225);
 688                 long_response($self, $beg, $end, sub {
 689                         my ($i) = @_;
 690                         my $mid = $mm->mid_for($$i);
 691                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 692                 });
 693         }
 694 }
 695
 696 sub search_header_for {
 697         my ($srch, $mid, $field) = @_;
 698         my $smsg = $srch->lookup_mail($mid) or return;
 699         $smsg->$field;
 700 }
 701
 702 sub hdr_searchmsg ($$$$) {
 703         my ($self, $xhdr, $field, $range) = @_;
 704         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 705                 my ($ng, $n) = mid_lookup($self, $1);
 706                 return r430 unless $n;
 707                 my $v = search_header_for($ng->search, $range, $field);
 708                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 709         } else { # numeric range
 710                 $range = $self->{article} unless defined $range;
 711                 my $srch = $self->{ng}->search;
 712                 my $mm = $self->{ng}->mm;
 713                 my $r = get_range($self, $range);
 714                 return $r unless ref $r;
 715                 my ($beg, $end) = @$r;
 716                 more($self, $xhdr ? r221 : r225);
 717                 my $off = 0;
 718                 long_response($self, $beg, $end, sub {
 719                         my ($i, $lim) = @_;
 720                         my $res = $srch->query_xover($beg, $end, $off);
 721                         my $msgs = $res->{msgs};
 722                         my $nr = scalar @$msgs or return;
 723                         $off += $nr;
 724                         $$lim -= $nr;
 725                         my $tmp = '';
 726                         foreach my $s (@$msgs) {
 727                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 728                         }
 729                         utf8::encode($tmp);
 730                         do_more($self, $tmp);
 731                         # -1 to adjust for implicit increment in long_response
 732                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 733                 });
 734         }
 735 }
 736
 737 sub do_hdr ($$$;$) {
 738         my ($self, $xhdr, $header, $range) = @_;
 739         my $sub = lc $header;
 740         if ($sub eq 'message-id') {
 741                 hdr_message_id($self, $xhdr, $range);
 742         } elsif ($sub eq 'xref') {
 743                 hdr_xref($self, $xhdr, $range);
 744         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 745                                 bytes|lines)\z/x) {
 746                 hdr_searchmsg($self, $xhdr, $sub, $range);
 747         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 748                 hdr_searchmsg($self, $xhdr, $1, $range);
 749         } else {
 750                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 751         }
 752 }
 753
 754 # RFC 3977
 755 sub cmd_hdr ($$;$) {
 756         my ($self, $header, $range) = @_;
 757         do_hdr($self, 0, $header, $range);
 758 }
 759
 760 # RFC 2980
 761 sub cmd_xhdr ($$;$) {
 762         my ($self, $header, $range) = @_;
 763         do_hdr($self, 1, $header, $range);
 764 }
 765
 766 sub hdr_mid_prefix ($$$$$) {
 767         my ($self, $xhdr, $ng, $n, $mid) = @_;
 768         return $mid if $xhdr;
 769
 770         # HDR for RFC 3977 users
 771         if (my $self_ng = $self->{ng}) {
 772                 ($self_ng eq $ng) ? $n : '0';
 773         } else {
 774                 '0';
 775         }
 776 }
 777
 778 sub hdr_mid_response ($$$$$$) {
 779         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 780         my $res = '';
 781         if ($xhdr) {
 782                 $res .= r221 . "\r\n";
 783                 $res .= "$mid $v\r\n";
 784         } else {
 785                 $res .= r225 . "\r\n";
 786                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 787                 $res .= "$pfx $v\r\n";
 788         }
 789         res($self, $res .= '.');
 790         undef;
 791 }
 792
 793 sub cmd_xrover ($;$) {
 794         my ($self, $range) = @_;
 795         my $ng = $self->{ng} or return '412 no newsgroup selected';
 796         (defined $range && $range =~ /[<>]/) and
 797                 return '420 No article(s) selected'; # no message IDs
 798
 799         $range = $self->{article} unless defined $range;
 800         my $r = get_range($self, $range);
 801         return $r unless ref $r;
 802         my ($beg, $end) = @$r;
 803         my $mm = $ng->mm;
 804         my $srch = $ng->search;
 805         more($self, '224 Overview information follows');
 806         long_response($self, $beg, $end, sub {
 807                 my ($i) = @_;
 808                 my $mid = $mm->mid_for($$i) or return;
 809                 my $h = search_header_for($srch, $mid, 'references');
 810                 more($self, "$$i $h");
 811         });
 812 }
 813
 814 sub over_line ($$) {
 815         my ($num, $smsg) = @_;
 816         # n.b. field access and procedural calls can be
 817         # 10%-15% faster than OO method calls:
 818         my $s = join("\t", $num,
 819                 $smsg->{subject},
 820                 $smsg->{from},
 821                 PublicInbox::SearchMsg::date($smsg),
 822                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 823                 $smsg->{references},
 824                 PublicInbox::SearchMsg::bytes($smsg),
 825                 PublicInbox::SearchMsg::lines($smsg));
 826         utf8::encode($s);
 827         $s
 828 }
 829
 830 sub cmd_over ($;$) {
 831         my ($self, $range) = @_;
 832         if ($range && $range =~ /\A<(.+)>\z/) {
 833                 my ($ng, $n) = mid_lookup($self, $1);
 834                 my $smsg = $ng->search->lookup_mail($range) or
 835                         return '430 No article with that message-id';
 836                 more($self, '224 Overview information follows (multi-line)');
 837
 838                 # Only set article number column if it's the current group
 839                 my $self_ng = $self->{ng};
 840                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 841                 more($self, over_line($n, $smsg));
 842                 '.';
 843         } else {
 844                 cmd_xover($self, $range);
 845         }
 846 }
 847
 848 sub cmd_xover ($;$) {
 849         my ($self, $range) = @_;
 850         $range = $self->{article} unless defined $range;
 851         my $r = get_range($self, $range);
 852         return $r unless ref $r;
 853         my ($beg, $end) = @$r;
 854         more($self, "224 Overview information follows for $beg to $end");
 855         my $srch = $self->{ng}->search;
 856         my $off = 0;
 857         long_response($self, $beg, $end, sub {
 858                 my ($i, $lim) = @_;
 859                 my $res = $srch->query_xover($beg, $end, $off);
 860                 my $msgs = $res->{msgs};
 861                 my $nr = scalar @$msgs or return;
 862                 $off += $nr;
 863                 $$lim -= $nr;
 864
 865                 # OVERVIEW.FMT
 866                 more($self, join("\r\n", map {
 867                         over_line(PublicInbox::SearchMsg::num($_), $_);
 868                         } @$msgs));
 869
 870                 # -1 to adjust for implicit increment in long_response
 871                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 872         });
 873 }
 874
 875 sub cmd_xpath ($$) {
 876         my ($self, $mid) = @_;
 877         return r501 unless $mid =~ /\A<(.+)>\z/;
 878         $mid = $1;
 879         my @paths;
 880         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 881                 my $n = $ng->mm->num_for($mid);
 882                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 883         }
 884         return '430 no such article on server' unless @paths;
 885         '223 '.join(' ', @paths);
 886 }
 887
 888 sub res ($$) {
 889         my ($self, $line) = @_;
 890         do_write($self, $line . "\r\n");
 891 }
 892
 893 sub more ($$) {
 894         my ($self, $line) = @_;
 895         do_more($self, $line . "\r\n");
 896 }
 897
 898 sub do_write ($$) {
 899         my ($self, $data) = @_;
 900         my $done = $self->write($data);
 901         return if $self->{closed};
 902
 903         # Do not watch for readability if we have data in the queue,
 904         # instead re-enable watching for readability when we can
 905         $self->watch_read(0) if (!$done || $self->{long_res});
 906
 907         $done;
 908 }
 909
 910 sub err ($$;@) {
 911         my ($self, $fmt, @args) = @_;
 912         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 913 }
 914
 915 sub out ($$;@) {
 916         my ($self, $fmt, @args) = @_;
 917         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 918 }
 919
 920 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 921
 922 sub do_more ($$) {
 923         my ($self, $data) = @_;
 924         if (MSG_MORE && !$self->{write_buf_size}) {
 925                 my $n = send($self->{sock}, $data, MSG_MORE);
 926                 if (defined $n) {
 927                         my $dlen = length($data);
 928                         return 1 if $n == $dlen; # all done!
 929                         $data = substr($data, $n, $dlen - $n);
 930                 }
 931         }
 932         do_write($self, $data);
 933 }
 934
 935 # callbacks for Danga::Socket
 936
 937 sub event_hup { $_[0]->close }
 938 sub event_err { $_[0]->close }
 939
 940 sub event_write {
 941         my ($self) = @_;
 942         update_idle_time($self);
 943         # only continue watching for readability when we are done writing:
 944         if ($self->write(undef) == 1 && !$self->{long_res}) {
 945                 $self->watch_read(1);
 946         }
 947 }
 948
 949 sub event_read {
 950         my ($self) = @_;
 951         use constant LINE_MAX => 512; # RFC 977 section 2.3
 952
 953         if (index($self->{rbuf}, "\n") < 0) {
 954                 my $buf = $self->read(LINE_MAX) or return $self->close;
 955                 $self->{rbuf} .= $$buf;
 956         }
 957         my $r = 1;
 958         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 959                 my $line = $1;
 960                 return $self->close if $line =~ /[[:cntrl:]]/s;
 961                 my $t0 = now();
 962                 my $fd = $self->{fd};
 963                 $r = eval { process_line($self, $line) };
 964                 my $d = $self->{long_res} ?
 965                         " deferred[$fd]" : '';
 966                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 967         }
 968
 969         return $self->close if $r < 0;
 970         my $len = length($self->{rbuf});
 971         return $self->close if ($len >= LINE_MAX);
 972         update_idle_time($self);
 973 }
 974
 975 sub watch_read {
 976         my ($self, $bool) = @_;
 977         my $rv = $self->SUPER::watch_read($bool);
 978         if ($bool && $self->{rbuf} ne '') {
 979                 # Force another read if there is a pipelined request.
 980                 # We don't know if the socket has anything for us to read,
 981                 # and we must double-check again by the time the timer fires
 982                 # in case we really did dispatch a read event and started
 983                 # another long response.
 984                 push @$nextq, $self;
 985                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 986         }
 987         $rv;
 988 }
 989
 990 sub not_idle_long ($$) {
 991         my ($self, $now) = @_;
 992         defined(my $fd = $self->{fd}) or return;
 993         my $ary = $EXPMAP->{$fd} or return;
 994         my $exp_at = $ary->[0] + $EXPTIME;
 995         $exp_at > $now;
 996 }
 997
 998 # for graceful shutdown in PublicInbox::Daemon:
 999 sub busy {
1000         my ($self, $now) = @_;
1001         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
1002          not_idle_long($self, $now));
1003 }
1004
1005 1;