lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 require PublicInbox::EvCleanup;
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  17 use URI::Escape qw(uri_escape_utf8);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $WEAKEN = {}; # string(nntpd) -> nntpd
  42 my $weakt;
  43 my $nextt;
  44
  45 my $nextq = [];
  46 sub next_tick () {
  47         $nextt = undef;
  48         my $q = $nextq;
  49         $nextq = [];
  50         foreach my $nntp (@$q) {
  51                 # for request && response protocols, always finish writing
  52                 # before finishing reading:
  53                 if (my $long_cb = $nntp->{long_res}) {
  54                         $nntp->write($long_cb);
  55                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  56                         event_read($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub update_idle_time ($) {
  62         my ($self) = @_;
  63         my $tmp = $self->{sock} or return;
  64         $tmp = fileno($tmp);
  65         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  66 }
  67
  68 # reduce FD pressure by closing some "git cat-file --batch" processes
  69 # and unused FDs for msgmap and Xapian indices
  70 sub weaken_groups () {
  71         $weakt = undef;
  72         foreach my $nntpd (values %$WEAKEN) {
  73                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  74         }
  75         $WEAKEN = {};
  76 }
  77
  78 sub expire_old () {
  79         my $now = now();
  80         my $exp = $EXPTIME;
  81         my $old = $now - $exp;
  82         my $nr = 0;
  83         my %new;
  84         while (my ($fd, $v) = each %$EXPMAP) {
  85                 my ($idle_time, $nntp) = @$v;
  86                 if ($idle_time < $old) {
  87                         $nntp->close; # idempotent
  88                 } else {
  89                         ++$nr;
  90                         $new{$fd} = $v;
  91                 }
  92         }
  93         $EXPMAP = \%new;
  94         if ($nr) {
  95                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  96                 weaken_groups();
  97         } else {
  98                 $expt = undef;
  99                 # noop to kick outselves out of the loop ASAP so descriptors
 100                 # really get closed
 101                 PublicInbox::EvCleanup::asap(sub {});
 102
 103                 # grace period for reaping resources
 104                 $weakt ||= PublicInbox::EvCleanup::later(*weaken_groups);
 105         }
 106 }
 107
 108 sub new ($$$) {
 109         my ($class, $sock, $nntpd) = @_;
 110         my $self = fields::new($class);
 111         $self->SUPER::new($sock);
 112         $self->{nntpd} = $nntpd;
 113         res($self, '201 server ready - post via email');
 114         $self->{rbuf} = '';
 115         $self->watch_read(1);
 116         update_idle_time($self);
 117         $WEAKEN->{"$nntpd"} = $nntpd;
 118         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 119         $self;
 120 }
 121
 122 sub args_ok ($$) {
 123         my ($cb, $argc) = @_;
 124         my $tot = prototype $cb;
 125         my ($nreq, undef) = split(';', $tot);
 126         $nreq = ($nreq =~ tr/$//) - 1;
 127         $tot = ($tot =~ tr/$//) - 1;
 128         ($argc <= $tot && $argc >= $nreq);
 129 }
 130
 131 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 132 sub process_line ($$) {
 133         my ($self, $l) = @_;
 134         my ($req, @args) = split(/\s+/, $l);
 135         $req = lc($req);
 136         $req = eval {
 137                 no strict 'refs';
 138                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 139         };
 140         return res($self, '500 command not recognized') unless $req;
 141         return res($self, r501) unless args_ok($req, scalar @args);
 142
 143         my $res = eval { $req->($self, @args) };
 144         my $err = $@;
 145         if ($err && !$self->{closed}) {
 146                 chomp($l);
 147                 err($self, 'error from: %s (%s)', $l, $err);
 148                 $res = '503 program fault - command not performed';
 149         }
 150         return 0 unless defined $res;
 151         res($self, $res);
 152 }
 153
 154 sub cmd_mode ($$) {
 155         my ($self, $arg) = @_;
 156         $arg = uc $arg;
 157         return r501 unless $arg eq 'READER';
 158         '201 Posting prohibited';
 159 }
 160
 161 sub cmd_slave ($) { '202 slave status noted' }
 162
 163 sub cmd_xgtitle ($;$) {
 164         my ($self, $wildmat) = @_;
 165         more($self, '282 list of groups and descriptions follows');
 166         list_newsgroups($self, $wildmat);
 167         '.'
 168 }
 169
 170 sub list_overview_fmt ($) {
 171         my ($self) = @_;
 172         do_more($self, $OVERVIEW_FMT);
 173 }
 174
 175 sub list_headers ($;$) {
 176         my ($self) = @_;
 177         do_more($self, $LIST_HEADERS);
 178 }
 179
 180 sub list_active ($;$) {
 181         my ($self, $wildmat) = @_;
 182         wildmat2re($wildmat);
 183         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 184                 $ng->{newsgroup} =~ $wildmat or next;
 185                 group_line($self, $ng);
 186         }
 187 }
 188
 189 sub list_active_times ($;$) {
 190         my ($self, $wildmat) = @_;
 191         wildmat2re($wildmat);
 192         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 193                 $ng->{newsgroup} =~ $wildmat or next;
 194                 my $c = eval { $ng->mm->created_at } || time;
 195                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 196         }
 197 }
 198
 199 sub list_newsgroups ($;$) {
 200         my ($self, $wildmat) = @_;
 201         wildmat2re($wildmat);
 202         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 203                 $ng->{newsgroup} =~ $wildmat or next;
 204                 my $d = $ng->description;
 205                 more($self, "$ng->{newsgroup} $d");
 206         }
 207 }
 208
 209 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 210 sub cmd_list ($;$$) {
 211         my ($self, @args) = @_;
 212         if (scalar @args) {
 213                 my $arg = shift @args;
 214                 $arg =~ tr/A-Z./a-z_/;
 215                 $arg = "list_$arg";
 216                 return r501 if $DISABLED{$arg};
 217
 218                 $arg = eval {
 219                         no strict 'refs';
 220                         *{$arg}{CODE};
 221                 };
 222                 return r501 unless $arg && args_ok($arg, scalar @args);
 223                 more($self, '215 information follows');
 224                 $arg->($self, @args);
 225         } else {
 226                 more($self, '215 list of newsgroups follows');
 227                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 228                         group_line($self, $ng);
 229                 }
 230         }
 231         '.'
 232 }
 233
 234 sub cmd_listgroup ($;$) {
 235         my ($self, $group) = @_;
 236         if (defined $group) {
 237                 my $res = cmd_group($self, $group);
 238                 return $res if ($res !~ /\A211 /);
 239                 more($self, $res);
 240         }
 241
 242         $self->{ng} or return '412 no newsgroup selected';
 243         long_response($self, 0, long_response_limit, sub {
 244                 my ($i) = @_;
 245                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 246                         my ($ary) = @_;
 247                         more($self, join("\r\n", @$ary));
 248                 });
 249
 250                 # -1 to adjust for implicit increment in long_response
 251                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 252         });
 253 }
 254
 255 sub parse_time ($$;$) {
 256         my ($date, $time, $gmt) = @_;
 257         use Time::Local qw();
 258         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 259         if (defined $gmt) {
 260                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 261                 $gmt = 1;
 262         }
 263         my @now = $gmt ? gmtime : localtime;
 264         my ($YYYY, $MM, $DD);
 265         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 266                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 267         } else { # legacy clients send YYMMDD
 268                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 269                 if ($YYYY > strftime('%y', @now)) {
 270                         my $cur_year = $now[5] + 1900;
 271                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 272                 }
 273         }
 274         if ($gmt) {
 275                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 276         } else {
 277                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 278         }
 279 }
 280
 281 sub group_line ($$) {
 282         my ($self, $ng) = @_;
 283         my ($min, $max) = $ng->mm->minmax;
 284         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 285 }
 286
 287 sub cmd_newgroups ($$$;$$) {
 288         my ($self, $date, $time, $gmt, $dists) = @_;
 289         my $ts = eval { parse_time($date, $time, $gmt) };
 290         return r501 if $@;
 291
 292         # TODO dists
 293         more($self, '231 list of new newsgroups follows');
 294         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 295                 my $c = eval { $ng->mm->created_at } || 0;
 296                 next unless $c > $ts;
 297                 group_line($self, $ng);
 298         }
 299         '.'
 300 }
 301
 302 sub wildmat2re (;$) {
 303         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 304         my %keep;
 305         my $salt = rand;
 306         use Digest::SHA qw(sha1_hex);
 307         my $tmp = $_[0];
 308
 309         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 310                 my $orig = $1;
 311                 my $key = sha1_hex($orig . $salt);
 312                 $orig =~ s/([^\w\-])+/\Q$1/g;
 313                 $keep{$key} = $orig;
 314                 $key
 315                 #gex;
 316         my %map = ('*' => '.*', '?' => '.' );
 317         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 318         if (scalar %keep) {
 319                 $tmp =~ s#([a-f0-9]{40})#
 320                         my $orig = $keep{$1};
 321                         defined $orig ? $orig : $1;
 322                         #ge;
 323         }
 324         $_[0] = qr/\A$tmp\z/;
 325 }
 326
 327 sub ngpat2re (;$) {
 328         return $_[0] = qr/\A\z/ unless defined $_[0];
 329         my %map = ('*' => '.*', ',' => '|');
 330         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 331         $_[0] = qr/\A(?:$_[0])\z/;
 332 }
 333
 334 sub cmd_newnews ($$$$;$$) {
 335         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 336         my $ts = eval { parse_time($date, $time, $gmt) };
 337         return r501 if $@;
 338         more($self, '230 list of new articles by message-id follows');
 339         my ($keep, $skip) = split('!', $newsgroups, 2);
 340         ngpat2re($keep);
 341         ngpat2re($skip);
 342         my @srch;
 343         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 344                 $ng->{newsgroup} =~ $keep or next;
 345                 $ng->{newsgroup} =~ $skip and next;
 346                 my $srch = $ng->search or next;
 347                 push @srch, $srch;
 348         };
 349         return '.' unless @srch;
 350
 351         $ts .= '..';
 352         my $opts = { asc => 1, limit => 1000, offset => 0 };
 353         long_response($self, 0, long_response_limit, sub {
 354                 my ($i) = @_;
 355                 my $srch = $srch[0];
 356                 my $res = $srch->query($ts, $opts);
 357                 my $msgs = $res->{msgs};
 358                 if (my $nr = scalar @$msgs) {
 359                         more($self, '<' .
 360                                 join(">\r\n<", map { $_->mid } @$msgs ).
 361                                 '>');
 362                         $opts->{offset} += $nr;
 363                 } else {
 364                         shift @srch;
 365                         if (@srch) { # continue onto next newsgroup
 366                                 $opts->{offset} = 0;
 367                         } else { # break out of the long response.
 368                                 $$i = long_response_limit;
 369                         }
 370                 }
 371         });
 372 }
 373
 374 sub cmd_group ($$) {
 375         my ($self, $group) = @_;
 376         my $no_such = '411 no such news group';
 377         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 378
 379         $self->{ng} = $ng;
 380         my ($min, $max) = $ng->mm->minmax;
 381         $min ||= 0;
 382         $max ||= 0;
 383         $self->{article} = $min;
 384         my $est_size = $max - $min;
 385         "211 $est_size $min $max $group";
 386 }
 387
 388 sub article_adj ($$) {
 389         my ($self, $off) = @_;
 390         my $ng = $self->{ng} or return '412 no newsgroup selected';
 391
 392         my $n = $self->{article};
 393         defined $n or return '420 no current article has been selected';
 394
 395         $n += $off;
 396         my $mid = $ng->mm->mid_for($n);
 397         unless ($mid) {
 398                 $n = $off > 0 ? 'next' : 'previous';
 399                 return "421 no $n article in this group";
 400         }
 401         $self->{article} = $n;
 402         "223 $n <$mid> article retrieved - request text separately";
 403 }
 404
 405 sub cmd_next ($) { article_adj($_[0], 1) }
 406 sub cmd_last ($) { article_adj($_[0], -1) }
 407
 408 # We want to encourage using email and CC-ing everybody involved to avoid
 409 # the single-point-of-failure a single server provides.
 410 sub cmd_post ($) {
 411         my ($self) = @_;
 412         my $ng = $self->{ng};
 413         $ng ? "440 mailto:$ng->{-primary_address} to post"
 414                 : '440 posting not allowed'
 415 }
 416
 417 sub cmd_quit ($) {
 418         my ($self) = @_;
 419         res($self, '205 closing connection - goodbye!');
 420         $self->close;
 421         undef;
 422 }
 423
 424 sub header_append ($$$) {
 425         my ($hdr, $k, $v) = @_;
 426         my @v = $hdr->header($k);
 427         foreach (@v) {
 428                 return if $v eq $_;
 429         }
 430         $hdr->header_set($k, @v, $v);
 431 }
 432
 433 sub set_nntp_headers {
 434         my ($hdr, $ng, $n, $mid) = @_;
 435
 436         # clobber some
 437         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 438         $hdr->header_set('Xref', xref($ng, $n));
 439         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 440         if (my $url = $ng->base_url) {
 441                 $mid = uri_escape_utf8($mid);
 442                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 443                 header_append($hdr, 'List-Archive', "<$url>");
 444         }
 445 }
 446
 447 sub art_lookup ($$$) {
 448         my ($self, $art, $set_headers) = @_;
 449         my $ng = $self->{ng};
 450         my ($n, $mid);
 451         my $err;
 452         if (defined $art) {
 453                 if ($art =~ /\A\d+\z/o) {
 454                         $err = '423 no such article number in this group';
 455                         $n = int($art);
 456                         goto find_mid;
 457                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 458                         $mid = $1;
 459                         $err = r430;
 460                         $n = $ng->mm->num_for($mid) if $ng;
 461                         goto found if defined $n;
 462                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 463                                 $n = $g->mm->num_for($mid);
 464                                 if (defined $n) {
 465                                         $ng = $g;
 466                                         goto found;
 467                                 }
 468                         }
 469                         return $err;
 470                 } else {
 471                         return r501;
 472                 }
 473         } else {
 474                 $err = '420 no current article has been selected';
 475                 $n = $self->{article};
 476                 defined $n or return $err;
 477 find_mid:
 478                 $ng or return '412 no newsgroup has been selected';
 479                 $mid = $ng->mm->mid_for($n);
 480                 defined $mid or return $err;
 481         }
 482 found:
 483         my $bytes;
 484         my $s = eval { $ng->msg_by_mid($mid, \$bytes) } or return $err;
 485         $s = Email::Simple->new($s);
 486         my $lines;
 487         if ($set_headers) {
 488                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 489                 $lines = $s->body =~ tr!\n!\n!;
 490
 491                 # must be last
 492                 $s->body_set('') if ($set_headers == 2);
 493         }
 494         [ $n, $mid, $s, $bytes, $lines, $ng ];
 495 }
 496
 497 sub simple_body_write ($$) {
 498         my ($self, $s) = @_;
 499         my $body = $s->body;
 500         $s->body_set('');
 501         $body =~ s/^\./../smg;
 502         $body =~ s/(?<!\r)\n/\r\n/sg;
 503         do_more($self, $body);
 504         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 505         '.'
 506 }
 507
 508 sub set_art {
 509         my ($self, $art) = @_;
 510         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 511 }
 512
 513 sub _header ($) {
 514         my $hdr = $_[0]->header_obj->as_string;
 515         utf8::encode($hdr);
 516         $hdr
 517 }
 518
 519 sub cmd_article ($;$) {
 520         my ($self, $art) = @_;
 521         my $r = art_lookup($self, $art, 1);
 522         return $r unless ref $r;
 523         my ($n, $mid, $s) = @$r;
 524         set_art($self, $art);
 525         more($self, "220 $n <$mid> article retrieved - head and body follow");
 526         do_more($self, _header($s));
 527         do_more($self, "\r\n");
 528         simple_body_write($self, $s);
 529 }
 530
 531 sub cmd_head ($;$) {
 532         my ($self, $art) = @_;
 533         my $r = art_lookup($self, $art, 2);
 534         return $r unless ref $r;
 535         my ($n, $mid, $s) = @$r;
 536         set_art($self, $art);
 537         more($self, "221 $n <$mid> article retrieved - head follows");
 538         do_more($self, _header($s));
 539         '.'
 540 }
 541
 542 sub cmd_body ($;$) {
 543         my ($self, $art) = @_;
 544         my $r = art_lookup($self, $art, 0);
 545         return $r unless ref $r;
 546         my ($n, $mid, $s) = @$r;
 547         set_art($self, $art);
 548         more($self, "222 $n <$mid> article retrieved - body follows");
 549         simple_body_write($self, $s);
 550 }
 551
 552 sub cmd_stat ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 0);
 555         return $r unless ref $r;
 556         my ($n, $mid, undef) = @$r;
 557         set_art($self, $art);
 558         "223 $n <$mid> article retrieved - request text separately";
 559 }
 560
 561 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 562
 563 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 564
 565 sub cmd_help ($) {
 566         my ($self) = @_;
 567         more($self, '100 help text follows');
 568         '.'
 569 }
 570
 571 sub get_range ($$) {
 572         my ($self, $range) = @_;
 573         my $ng = $self->{ng} or return '412 no news group has been selected';
 574         defined $range or return '420 No article(s) selected';
 575         my ($beg, $end);
 576         my ($min, $max) = $ng->mm->minmax;
 577         if ($range =~ /\A(\d+)\z/) {
 578                 $beg = $end = $1;
 579         } elsif ($range =~ /\A(\d+)-\z/) {
 580                 ($beg, $end) = ($1, $max);
 581         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 582                 ($beg, $end) = ($1, $2);
 583         } else {
 584                 return r501;
 585         }
 586         $beg = $min if ($beg < $min);
 587         $end = $max if ($end > $max);
 588         return '420 No article(s) selected' if ($beg > $end);
 589         [ $beg, $end ];
 590 }
 591
 592 sub long_response ($$$$) {
 593         my ($self, $beg, $end, $cb) = @_;
 594         die "BUG: nested long response" if $self->{long_res};
 595
 596         my $fd = $self->{fd};
 597         defined $fd or return;
 598         # make sure we disable reading during a long response,
 599         # clients should not be sending us stuff and making us do more
 600         # work while we are stream a response to them
 601         $self->watch_read(0);
 602         my $t0 = now();
 603         $self->{long_res} = sub {
 604                 # limit our own running time for fairness with other
 605                 # clients and to avoid buffering too much:
 606                 my $lim = 100;
 607
 608                 my $err;
 609                 do {
 610                         eval { $cb->(\$beg) };
 611                 } until (($err = $@) || $self->{closed} ||
 612                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 613
 614                 if ($err || $self->{closed}) {
 615                         $self->{long_res} = undef;
 616
 617                         if ($err) {
 618                                 err($self,
 619                                     "%s during long response[$fd] - %0.6f",
 620                                     $err, now() - $t0);
 621                         }
 622                         if ($self->{closed}) {
 623                                 out($self, " deferred[$fd] aborted - %0.6f",
 624                                            now() - $t0);
 625                         } else {
 626                                 update_idle_time($self);
 627                                 $self->watch_read(1);
 628                         }
 629                 } elsif (!$lim || $self->{write_buf_size}) {
 630                         # no recursion, schedule another call ASAP
 631                         # but only after all pending writes are done
 632                         update_idle_time($self);
 633
 634                         push @$nextq, $self;
 635                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 636                 } else { # all done!
 637                         $self->{long_res} = undef;
 638                         $self->watch_read(1);
 639                         res($self, '.');
 640                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 641                 }
 642         };
 643         $self->{long_res}->(); # kick off!
 644         undef;
 645 }
 646
 647 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 648         my ($self, $xhdr, $range) = @_;
 649
 650         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 651                 my ($ng, $n) = mid_lookup($self, $1);
 652                 return r430 unless $n;
 653                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 654         } else { # numeric range
 655                 $range = $self->{article} unless defined $range;
 656                 my $r = get_range($self, $range);
 657                 return $r unless ref $r;
 658                 my $mm = $self->{ng}->mm;
 659                 my ($beg, $end) = @$r;
 660                 more($self, $xhdr ? r221 : r225);
 661                 long_response($self, $beg, $end, sub {
 662                         my ($i) = @_;
 663                         my $mid = $mm->mid_for($$i);
 664                         more($self, "$$i <$mid>") if defined $mid;
 665                 });
 666         }
 667 }
 668
 669 sub xref ($$) {
 670         my ($ng, $n) = @_;
 671         "$ng->{domain} $ng->{newsgroup}:$n"
 672 }
 673
 674 sub mid_lookup ($$) {
 675         my ($self, $mid) = @_;
 676         my $self_ng = $self->{ng};
 677         if ($self_ng) {
 678                 my $n = $self_ng->mm->num_for($mid);
 679                 return ($self_ng, $n) if defined $n;
 680         }
 681         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 682                 next if defined $self_ng && $ng eq $self_ng;
 683                 my $n = $ng->mm->num_for($mid);
 684                 return ($ng, $n) if defined $n;
 685         }
 686         (undef, undef);
 687 }
 688
 689 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 690         my ($self, $xhdr, $range) = @_;
 691
 692         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 693                 my ($ng, $n) = mid_lookup($self, $1);
 694                 return r430 unless $n;
 695                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 696         } else { # numeric range
 697                 $range = $self->{article} unless defined $range;
 698                 my $r = get_range($self, $range);
 699                 return $r unless ref $r;
 700                 my $ng = $self->{ng};
 701                 my $mm = $ng->mm;
 702                 my ($beg, $end) = @$r;
 703                 more($self, $xhdr ? r221 : r225);
 704                 long_response($self, $beg, $end, sub {
 705                         my ($i) = @_;
 706                         my $mid = $mm->mid_for($$i);
 707                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 708                 });
 709         }
 710 }
 711
 712 sub search_header_for {
 713         my ($srch, $mid, $field) = @_;
 714         my $smsg = $srch->lookup_mail($mid) or return;
 715         $smsg->$field;
 716 }
 717
 718 sub hdr_searchmsg ($$$$) {
 719         my ($self, $xhdr, $field, $range) = @_;
 720         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 721                 my ($ng, $n) = mid_lookup($self, $1);
 722                 return r430 unless $n;
 723                 my $v = search_header_for($ng->search, $range, $field);
 724                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 725         } else { # numeric range
 726                 $range = $self->{article} unless defined $range;
 727                 my $srch = $self->{ng}->search;
 728                 my $mm = $self->{ng}->mm;
 729                 my $r = get_range($self, $range);
 730                 return $r unless ref $r;
 731                 my ($beg, $end) = @$r;
 732                 more($self, $xhdr ? r221 : r225);
 733                 my $off = 0;
 734                 long_response($self, $beg, $end, sub {
 735                         my ($i) = @_;
 736                         my $res = $srch->query_xover($beg, $end, $off);
 737                         my $msgs = $res->{msgs};
 738                         my $nr = scalar @$msgs or return;
 739                         $off += $nr;
 740                         my $tmp = '';
 741                         foreach my $s (@$msgs) {
 742                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 743                         }
 744                         utf8::encode($tmp);
 745                         do_more($self, $tmp);
 746                         # -1 to adjust for implicit increment in long_response
 747                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 748                 });
 749         }
 750 }
 751
 752 sub do_hdr ($$$;$) {
 753         my ($self, $xhdr, $header, $range) = @_;
 754         my $sub = lc $header;
 755         if ($sub eq 'message-id') {
 756                 hdr_message_id($self, $xhdr, $range);
 757         } elsif ($sub eq 'xref') {
 758                 hdr_xref($self, $xhdr, $range);
 759         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 760                                 bytes|lines)\z/x) {
 761                 hdr_searchmsg($self, $xhdr, $sub, $range);
 762         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 763                 hdr_searchmsg($self, $xhdr, $1, $range);
 764         } else {
 765                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 766         }
 767 }
 768
 769 # RFC 3977
 770 sub cmd_hdr ($$;$) {
 771         my ($self, $header, $range) = @_;
 772         do_hdr($self, 0, $header, $range);
 773 }
 774
 775 # RFC 2980
 776 sub cmd_xhdr ($$;$) {
 777         my ($self, $header, $range) = @_;
 778         do_hdr($self, 1, $header, $range);
 779 }
 780
 781 sub hdr_mid_prefix ($$$$$) {
 782         my ($self, $xhdr, $ng, $n, $mid) = @_;
 783         return $mid if $xhdr;
 784
 785         # HDR for RFC 3977 users
 786         if (my $self_ng = $self->{ng}) {
 787                 ($self_ng eq $ng) ? $n : '0';
 788         } else {
 789                 '0';
 790         }
 791 }
 792
 793 sub hdr_mid_response ($$$$$$) {
 794         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 795         my $res = '';
 796         if ($xhdr) {
 797                 $res .= r221 . "\r\n";
 798                 $res .= "$mid $v\r\n";
 799         } else {
 800                 $res .= r225 . "\r\n";
 801                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 802                 $res .= "$pfx $v\r\n";
 803         }
 804         res($self, $res .= '.');
 805         undef;
 806 }
 807
 808 sub cmd_xrover ($;$) {
 809         my ($self, $range) = @_;
 810         my $ng = $self->{ng} or return '412 no newsgroup selected';
 811         (defined $range && $range =~ /[<>]/) and
 812                 return '420 No article(s) selected'; # no message IDs
 813
 814         $range = $self->{article} unless defined $range;
 815         my $r = get_range($self, $range);
 816         return $r unless ref $r;
 817         my ($beg, $end) = @$r;
 818         my $mm = $ng->mm;
 819         my $srch = $ng->search;
 820         more($self, '224 Overview information follows');
 821         long_response($self, $beg, $end, sub {
 822                 my ($i) = @_;
 823                 my $mid = $mm->mid_for($$i) or return;
 824                 my $h = search_header_for($srch, $mid, 'references');
 825                 more($self, "$$i $h");
 826         });
 827 }
 828
 829 sub over_line ($$) {
 830         my ($num, $smsg) = @_;
 831         # n.b. field access and procedural calls can be
 832         # 10%-15% faster than OO method calls:
 833         my $s = join("\t", $num,
 834                 $smsg->{subject},
 835                 $smsg->{from},
 836                 PublicInbox::SearchMsg::date($smsg),
 837                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 838                 $smsg->{references},
 839                 PublicInbox::SearchMsg::bytes($smsg),
 840                 PublicInbox::SearchMsg::lines($smsg));
 841         utf8::encode($s);
 842         $s
 843 }
 844
 845 sub cmd_over ($;$) {
 846         my ($self, $range) = @_;
 847         if ($range && $range =~ /\A<(.+)>\z/) {
 848                 my ($ng, $n) = mid_lookup($self, $1);
 849                 my $smsg = $ng->search->lookup_mail($range) or
 850                         return '430 No article with that message-id';
 851                 more($self, '224 Overview information follows (multi-line)');
 852
 853                 # Only set article number column if it's the current group
 854                 my $self_ng = $self->{ng};
 855                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 856                 more($self, over_line($n, $smsg));
 857                 '.';
 858         } else {
 859                 cmd_xover($self, $range);
 860         }
 861 }
 862
 863 sub cmd_xover ($;$) {
 864         my ($self, $range) = @_;
 865         $range = $self->{article} unless defined $range;
 866         my $r = get_range($self, $range);
 867         return $r unless ref $r;
 868         my ($beg, $end) = @$r;
 869         more($self, "224 Overview information follows for $beg to $end");
 870         my $srch = $self->{ng}->search;
 871         my $off = 0;
 872         long_response($self, $beg, $end, sub {
 873                 my ($i) = @_;
 874                 my $res = $srch->query_xover($beg, $end, $off);
 875                 my $msgs = $res->{msgs};
 876                 my $nr = scalar @$msgs or return;
 877                 $off += $nr;
 878
 879                 # OVERVIEW.FMT
 880                 more($self, join("\r\n", map {
 881                         over_line(PublicInbox::SearchMsg::num($_), $_);
 882                         } @$msgs));
 883
 884                 # -1 to adjust for implicit increment in long_response
 885                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 886         });
 887 }
 888
 889 sub cmd_xpath ($$) {
 890         my ($self, $mid) = @_;
 891         return r501 unless $mid =~ /\A<(.+)>\z/;
 892         $mid = $1;
 893         my @paths;
 894         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 895                 my $n = $ng->mm->num_for($mid);
 896                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 897         }
 898         return '430 no such article on server' unless @paths;
 899         '223 '.join(' ', @paths);
 900 }
 901
 902 sub res ($$) {
 903         my ($self, $line) = @_;
 904         do_write($self, $line . "\r\n");
 905 }
 906
 907 sub more ($$) {
 908         my ($self, $line) = @_;
 909         do_more($self, $line . "\r\n");
 910 }
 911
 912 sub do_write ($$) {
 913         my ($self, $data) = @_;
 914         my $done = $self->write($data);
 915         die if $self->{closed};
 916
 917         # Do not watch for readability if we have data in the queue,
 918         # instead re-enable watching for readability when we can
 919         $self->watch_read(0) if (!$done || $self->{long_res});
 920
 921         $done;
 922 }
 923
 924 sub err ($$;@) {
 925         my ($self, $fmt, @args) = @_;
 926         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 927 }
 928
 929 sub out ($$;@) {
 930         my ($self, $fmt, @args) = @_;
 931         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 932 }
 933
 934 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 935
 936 sub do_more ($$) {
 937         my ($self, $data) = @_;
 938         if (MSG_MORE && !$self->{write_buf_size}) {
 939                 my $n = send($self->{sock}, $data, MSG_MORE);
 940                 if (defined $n) {
 941                         my $dlen = length($data);
 942                         return 1 if $n == $dlen; # all done!
 943                         $data = substr($data, $n, $dlen - $n);
 944                 }
 945         }
 946         do_write($self, $data);
 947 }
 948
 949 # callbacks for Danga::Socket
 950
 951 sub event_hup { $_[0]->close }
 952 sub event_err { $_[0]->close }
 953
 954 sub event_write {
 955         my ($self) = @_;
 956         update_idle_time($self);
 957         # only continue watching for readability when we are done writing:
 958         if ($self->write(undef) == 1 && !$self->{long_res}) {
 959                 $self->watch_read(1);
 960         }
 961 }
 962
 963 sub event_read {
 964         my ($self) = @_;
 965         use constant LINE_MAX => 512; # RFC 977 section 2.3
 966         my $r = 1;
 967
 968         my $buf = $self->read(LINE_MAX) or return $self->close;
 969         $self->{rbuf} .= $$buf;
 970         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 971                 my $line = $1;
 972                 return $self->close if $line =~ /[[:cntrl:]]/s;
 973                 my $t0 = now();
 974                 my $fd = $self->{fd};
 975                 $r = eval { process_line($self, $line) };
 976                 my $d = $self->{long_res} ?
 977                         " deferred[$fd]" : '';
 978                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 979         }
 980
 981         return $self->close if $r < 0;
 982         my $len = length($self->{rbuf});
 983         return $self->close if ($len >= LINE_MAX);
 984         update_idle_time($self);
 985 }
 986
 987 sub watch_read {
 988         my ($self, $bool) = @_;
 989         my $rv = $self->SUPER::watch_read($bool);
 990         if ($bool && $self->{rbuf} ne '') {
 991                 # Force another read if there is a pipelined request.
 992                 # We don't know if the socket has anything for us to read,
 993                 # and we must double-check again by the time the timer fires
 994                 # in case we really did dispatch a read event and started
 995                 # another long response.
 996                 push @$nextq, $self;
 997                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 998         }
 999         $rv;
1000 }
1001
1002 # for graceful shutdown in PublicInbox::Daemon:
1003 sub busy () {
1004         my ($self) = @_;
1005         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1006 }
1007
1008 1;