lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use URI::Escape qw(uri_escape_utf8);
  19 use Encode qw(find_encoding);
  20 my $enc_utf8 = find_encoding('UTF-8');
  21 use constant {
  22         r501 => '501 command syntax error',
  23         r221 => '221 Header follows',
  24         r224 => '224 Overview information follows (multi-line)',
  25         r225 => '225 Headers follow (multi-line)',
  26         r430 => '430 No article with that message-id',
  27         long_response_limit => 0xffffffff,
  28 };
  29
  30 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36
  37 # disable commands with easy DoS potential:
  38 # LISTGROUP could get pretty bad, too...
  39 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  40
  41 my $EXPMAP; # fd -> [ idle_time, $self ]
  42 my $expt;
  43 our $EXPTIME = 180; # 3 minutes
  44 my $WEAKEN = {}; # string(nntpd) -> nntpd
  45 my $weakt;
  46 my $nextt;
  47
  48 my $nextq = [];
  49 sub next_tick () {
  50         $nextt = undef;
  51         my $q = $nextq;
  52         $nextq = [];
  53         foreach my $nntp (@$q) {
  54                 # for request && response protocols, always finish writing
  55                 # before finishing reading:
  56                 if (my $long_cb = $nntp->{long_res}) {
  57                         $nntp->write($long_cb);
  58                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  59                         event_read($nntp);
  60                 }
  61         }
  62 }
  63
  64 sub update_idle_time ($) {
  65         my ($self) = @_;
  66         my $tmp = $self->{sock} or return;
  67         $tmp = fileno($tmp);
  68         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  69 }
  70
  71 # reduce FD pressure by closing some "git cat-file --batch" processes
  72 # and unused FDs for msgmap and Xapian indices
  73 sub weaken_groups () {
  74         $weakt = undef;
  75         foreach my $nntpd (values %$WEAKEN) {
  76                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  77         }
  78         $WEAKEN = {};
  79 }
  80
  81 sub expire_old () {
  82         my $now = now();
  83         my $exp = $EXPTIME;
  84         my $old = $now - $exp;
  85         my $nr = 0;
  86         my %new;
  87         while (my ($fd, $v) = each %$EXPMAP) {
  88                 my ($idle_time, $nntp) = @$v;
  89                 if ($idle_time < $old) {
  90                         $nntp->close; # idempotent
  91                 } else {
  92                         ++$nr;
  93                         $new{$fd} = $v;
  94                 }
  95         }
  96         $EXPMAP = \%new;
  97         if ($nr) {
  98                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  99                 weaken_groups();
 100         } else {
 101                 $expt = undef;
 102                 # noop to kick outselves out of the loop ASAP so descriptors
 103                 # really get closed
 104                 PublicInbox::EvCleanup::asap(sub {});
 105
 106                 # grace period for reaping resources
 107                 $weakt ||= PublicInbox::EvCleanup::later(*weaken_groups);
 108         }
 109 }
 110
 111 sub new ($$$) {
 112         my ($class, $sock, $nntpd) = @_;
 113         my $self = fields::new($class);
 114         $self->SUPER::new($sock);
 115         $self->{nntpd} = $nntpd;
 116         res($self, '201 server ready - post via email');
 117         $self->{rbuf} = '';
 118         $self->watch_read(1);
 119         update_idle_time($self);
 120         $WEAKEN->{"$nntpd"} = $nntpd;
 121         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 122         $self;
 123 }
 124
 125 sub args_ok ($$) {
 126         my ($cb, $argc) = @_;
 127         my $tot = prototype $cb;
 128         my ($nreq, undef) = split(';', $tot);
 129         $nreq = ($nreq =~ tr/$//) - 1;
 130         $tot = ($tot =~ tr/$//) - 1;
 131         ($argc <= $tot && $argc >= $nreq);
 132 }
 133
 134 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 135 sub process_line ($$) {
 136         my ($self, $l) = @_;
 137         my ($req, @args) = split(/\s+/, $l);
 138         $req = lc($req);
 139         $req = eval {
 140                 no strict 'refs';
 141                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 142         };
 143         return res($self, '500 command not recognized') unless $req;
 144         return res($self, r501) unless args_ok($req, scalar @args);
 145
 146         my $res = eval { $req->($self, @args) };
 147         my $err = $@;
 148         if ($err && !$self->{closed}) {
 149                 chomp($l);
 150                 err($self, 'error from: %s (%s)', $l, $err);
 151                 $res = '503 program fault - command not performed';
 152         }
 153         return 0 unless defined $res;
 154         res($self, $res);
 155 }
 156
 157 sub cmd_mode ($$) {
 158         my ($self, $arg) = @_;
 159         $arg = uc $arg;
 160         return r501 unless $arg eq 'READER';
 161         '201 Posting prohibited';
 162 }
 163
 164 sub cmd_slave ($) { '202 slave status noted' }
 165
 166 sub cmd_xgtitle ($;$) {
 167         my ($self, $wildmat) = @_;
 168         more($self, '282 list of groups and descriptions follows');
 169         list_newsgroups($self, $wildmat);
 170         '.'
 171 }
 172
 173 sub list_overview_fmt ($) {
 174         my ($self) = @_;
 175         do_more($self, $OVERVIEW_FMT);
 176 }
 177
 178 sub list_headers ($;$) {
 179         my ($self) = @_;
 180         do_more($self, $LIST_HEADERS);
 181 }
 182
 183 sub list_active ($;$) {
 184         my ($self, $wildmat) = @_;
 185         wildmat2re($wildmat);
 186         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                 $ng->{newsgroup} =~ $wildmat or next;
 188                 group_line($self, $ng);
 189         }
 190 }
 191
 192 sub list_active_times ($;$) {
 193         my ($self, $wildmat) = @_;
 194         wildmat2re($wildmat);
 195         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 196                 $ng->{newsgroup} =~ $wildmat or next;
 197                 my $c = eval { $ng->mm->created_at } || time;
 198                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 199         }
 200 }
 201
 202 sub list_newsgroups ($;$) {
 203         my ($self, $wildmat) = @_;
 204         wildmat2re($wildmat);
 205         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 206                 $ng->{newsgroup} =~ $wildmat or next;
 207                 my $d = $ng->description;
 208                 more($self, "$ng->{newsgroup} $d");
 209         }
 210 }
 211
 212 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 213 sub cmd_list ($;$$) {
 214         my ($self, @args) = @_;
 215         if (scalar @args) {
 216                 my $arg = shift @args;
 217                 $arg =~ tr/A-Z./a-z_/;
 218                 $arg = "list_$arg";
 219                 return r501 if $DISABLED{$arg};
 220
 221                 $arg = eval {
 222                         no strict 'refs';
 223                         *{$arg}{CODE};
 224                 };
 225                 return r501 unless $arg && args_ok($arg, scalar @args);
 226                 more($self, '215 information follows');
 227                 $arg->($self, @args);
 228         } else {
 229                 more($self, '215 list of newsgroups follows');
 230                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 231                         group_line($self, $ng);
 232                 }
 233         }
 234         '.'
 235 }
 236
 237 sub cmd_listgroup ($;$) {
 238         my ($self, $group) = @_;
 239         if (defined $group) {
 240                 my $res = cmd_group($self, $group);
 241                 return $res if ($res !~ /\A211 /);
 242                 more($self, $res);
 243         }
 244
 245         $self->{ng} or return '412 no newsgroup selected';
 246         long_response($self, 0, long_response_limit, sub {
 247                 my ($i) = @_;
 248                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 249                         my ($ary) = @_;
 250                         more($self, join("\r\n", @$ary));
 251                 });
 252
 253                 # -1 to adjust for implicit increment in long_response
 254                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 255         });
 256 }
 257
 258 sub parse_time ($$;$) {
 259         my ($date, $time, $gmt) = @_;
 260         use Time::Local qw();
 261         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 262         if (defined $gmt) {
 263                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 264                 $gmt = 1;
 265         }
 266         my @now = $gmt ? gmtime : localtime;
 267         my ($YYYY, $MM, $DD);
 268         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 269                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 270         } else { # legacy clients send YYMMDD
 271                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 272                 if ($YYYY > strftime('%y', @now)) {
 273                         my $cur_year = $now[5] + 1900;
 274                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 275                 }
 276         }
 277         if ($gmt) {
 278                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 279         } else {
 280                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 281         }
 282 }
 283
 284 sub group_line ($$) {
 285         my ($self, $ng) = @_;
 286         my ($min, $max) = $ng->mm->minmax;
 287         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 288 }
 289
 290 sub cmd_newgroups ($$$;$$) {
 291         my ($self, $date, $time, $gmt, $dists) = @_;
 292         my $ts = eval { parse_time($date, $time, $gmt) };
 293         return r501 if $@;
 294
 295         # TODO dists
 296         more($self, '231 list of new newsgroups follows');
 297         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 298                 my $c = eval { $ng->mm->created_at } || 0;
 299                 next unless $c > $ts;
 300                 group_line($self, $ng);
 301         }
 302         '.'
 303 }
 304
 305 sub wildmat2re (;$) {
 306         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 307         my %keep;
 308         my $salt = rand;
 309         use Digest::SHA qw(sha1_hex);
 310         my $tmp = $_[0];
 311
 312         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 313                 my $orig = $1;
 314                 my $key = sha1_hex($orig . $salt);
 315                 $orig =~ s/([^\w\-])+/\Q$1/g;
 316                 $keep{$key} = $orig;
 317                 $key
 318                 #gex;
 319         my %map = ('*' => '.*', '?' => '.' );
 320         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 321         if (scalar %keep) {
 322                 $tmp =~ s#([a-f0-9]{40})#
 323                         my $orig = $keep{$1};
 324                         defined $orig ? $orig : $1;
 325                         #ge;
 326         }
 327         $_[0] = qr/\A$tmp\z/;
 328 }
 329
 330 sub ngpat2re (;$) {
 331         return $_[0] = qr/\A\z/ unless defined $_[0];
 332         my %map = ('*' => '.*', ',' => '|');
 333         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 334         $_[0] = qr/\A(?:$_[0])\z/;
 335 }
 336
 337 sub cmd_newnews ($$$$;$$) {
 338         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 339         my $ts = eval { parse_time($date, $time, $gmt) };
 340         return r501 if $@;
 341         more($self, '230 list of new articles by message-id follows');
 342         my ($keep, $skip) = split('!', $newsgroups, 2);
 343         ngpat2re($keep);
 344         ngpat2re($skip);
 345         my @srch;
 346         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 347                 $ng->{newsgroup} =~ $keep or next;
 348                 $ng->{newsgroup} =~ $skip and next;
 349                 my $srch = $ng->search or next;
 350                 push @srch, $srch;
 351         };
 352         return '.' unless @srch;
 353
 354         $ts .= '..';
 355         my $opts = { asc => 1, limit => 1000, offset => 0 };
 356         long_response($self, 0, long_response_limit, sub {
 357                 my ($i) = @_;
 358                 my $srch = $srch[0];
 359                 my $res = $srch->query($ts, $opts);
 360                 my $msgs = $res->{msgs};
 361                 if (my $nr = scalar @$msgs) {
 362                         more($self, '<' .
 363                                 join(">\r\n<", map { $_->mid } @$msgs ).
 364                                 '>');
 365                         $opts->{offset} += $nr;
 366                 } else {
 367                         shift @srch;
 368                         if (@srch) { # continue onto next newsgroup
 369                                 $opts->{offset} = 0;
 370                         } else { # break out of the long response.
 371                                 $$i = long_response_limit;
 372                         }
 373                 }
 374         });
 375 }
 376
 377 sub cmd_group ($$) {
 378         my ($self, $group) = @_;
 379         my $no_such = '411 no such news group';
 380         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 381
 382         $self->{ng} = $ng;
 383         my ($min, $max) = $ng->mm->minmax;
 384         $min ||= 0;
 385         $max ||= 0;
 386         $self->{article} = $min;
 387         my $est_size = $max - $min;
 388         "211 $est_size $min $max $group";
 389 }
 390
 391 sub article_adj ($$) {
 392         my ($self, $off) = @_;
 393         my $ng = $self->{ng} or return '412 no newsgroup selected';
 394
 395         my $n = $self->{article};
 396         defined $n or return '420 no current article has been selected';
 397
 398         $n += $off;
 399         my $mid = $ng->mm->mid_for($n);
 400         unless ($mid) {
 401                 $n = $off > 0 ? 'next' : 'previous';
 402                 return "421 no $n article in this group";
 403         }
 404         $self->{article} = $n;
 405         "223 $n <$mid> article retrieved - request text separately";
 406 }
 407
 408 sub cmd_next ($) { article_adj($_[0], 1) }
 409 sub cmd_last ($) { article_adj($_[0], -1) }
 410
 411 # We want to encourage using email and CC-ing everybody involved to avoid
 412 # the single-point-of-failure a single server provides.
 413 sub cmd_post ($) {
 414         my ($self) = @_;
 415         my $ng = $self->{ng};
 416         $ng ? "440 mailto:$ng->{-primary_address} to post"
 417                 : '440 posting not allowed'
 418 }
 419
 420 sub cmd_quit ($) {
 421         my ($self) = @_;
 422         res($self, '205 closing connection - goodbye!');
 423         $self->close;
 424         undef;
 425 }
 426
 427 sub header_append ($$$) {
 428         my ($hdr, $k, $v) = @_;
 429         my @v = $hdr->header($k);
 430         foreach (@v) {
 431                 return if $v eq $_;
 432         }
 433         $hdr->header_set($k, @v, $v);
 434 }
 435
 436 sub set_nntp_headers {
 437         my ($hdr, $ng, $n, $mid) = @_;
 438
 439         # clobber some
 440         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 441         $hdr->header_set('Xref', xref($ng, $n));
 442         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 443         if (my $url = $ng->base_url) {
 444                 $mid = uri_escape_utf8($mid);
 445                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 446                 header_append($hdr, 'List-Archive', "<$url>");
 447         }
 448 }
 449
 450 sub art_lookup ($$$) {
 451         my ($self, $art, $set_headers) = @_;
 452         my $ng = $self->{ng};
 453         my ($n, $mid);
 454         my $err;
 455         if (defined $art) {
 456                 if ($art =~ /\A\d+\z/o) {
 457                         $err = '423 no such article number in this group';
 458                         $n = int($art);
 459                         goto find_mid;
 460                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 461                         $mid = $1;
 462                         $err = r430;
 463                         $n = $ng->mm->num_for($mid) if $ng;
 464                         goto found if defined $n;
 465                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 466                                 $n = $g->mm->num_for($mid);
 467                                 if (defined $n) {
 468                                         $ng = $g;
 469                                         goto found;
 470                                 }
 471                         }
 472                         return $err;
 473                 } else {
 474                         return r501;
 475                 }
 476         } else {
 477                 $err = '420 no current article has been selected';
 478                 $n = $self->{article};
 479                 defined $n or return $err;
 480 find_mid:
 481                 $ng or return '412 no newsgroup has been selected';
 482                 $mid = $ng->mm->mid_for($n);
 483                 defined $mid or return $err;
 484         }
 485 found:
 486         my $o = 'HEAD:' . mid2path($mid);
 487         my $bytes;
 488         my $s = eval { Email::Simple->new($ng->gcf->cat_file($o, \$bytes)) };
 489         return $err unless $s;
 490         my $lines;
 491         if ($set_headers) {
 492                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 493                 $lines = $s->body =~ tr!\n!\n!;
 494
 495                 # must be last
 496                 $s->body_set('') if ($set_headers == 2);
 497         }
 498         [ $n, $mid, $s, $bytes, $lines, $ng ];
 499 }
 500
 501 sub simple_body_write ($$) {
 502         my ($self, $s) = @_;
 503         my $body = $s->body;
 504         $s->body_set('');
 505         $body =~ s/^\./../smg;
 506         $body =~ s/(?<!\r)\n/\r\n/sg;
 507         do_more($self, $body);
 508         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 509         '.'
 510 }
 511
 512 sub set_art {
 513         my ($self, $art) = @_;
 514         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 515 }
 516
 517 sub cmd_article ($;$) {
 518         my ($self, $art) = @_;
 519         my $r = art_lookup($self, $art, 1);
 520         return $r unless ref $r;
 521         my ($n, $mid, $s) = @$r;
 522         set_art($self, $art);
 523         more($self, "220 $n <$mid> article retrieved - head and body follow");
 524         do_more($self, $s->header_obj->as_string);
 525         do_more($self, "\r\n");
 526         simple_body_write($self, $s);
 527 }
 528
 529 sub cmd_head ($;$) {
 530         my ($self, $art) = @_;
 531         my $r = art_lookup($self, $art, 2);
 532         return $r unless ref $r;
 533         my ($n, $mid, $s) = @$r;
 534         set_art($self, $art);
 535         more($self, "221 $n <$mid> article retrieved - head follows");
 536         do_more($self, $s->header_obj->as_string);
 537         '.'
 538 }
 539
 540 sub cmd_body ($;$) {
 541         my ($self, $art) = @_;
 542         my $r = art_lookup($self, $art, 0);
 543         return $r unless ref $r;
 544         my ($n, $mid, $s) = @$r;
 545         set_art($self, $art);
 546         more($self, "222 $n <$mid> article retrieved - body follows");
 547         simple_body_write($self, $s);
 548 }
 549
 550 sub cmd_stat ($;$) {
 551         my ($self, $art) = @_;
 552         my $r = art_lookup($self, $art, 0);
 553         return $r unless ref $r;
 554         my ($n, $mid, undef) = @$r;
 555         set_art($self, $art);
 556         "223 $n <$mid> article retrieved - request text separately";
 557 }
 558
 559 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 560
 561 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 562
 563 sub cmd_help ($) {
 564         my ($self) = @_;
 565         more($self, '100 help text follows');
 566         '.'
 567 }
 568
 569 sub get_range ($$) {
 570         my ($self, $range) = @_;
 571         my $ng = $self->{ng} or return '412 no news group has been selected';
 572         defined $range or return '420 No article(s) selected';
 573         my ($beg, $end);
 574         my ($min, $max) = $ng->mm->minmax;
 575         if ($range =~ /\A(\d+)\z/) {
 576                 $beg = $end = $1;
 577         } elsif ($range =~ /\A(\d+)-\z/) {
 578                 ($beg, $end) = ($1, $max);
 579         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 580                 ($beg, $end) = ($1, $2);
 581         } else {
 582                 return r501;
 583         }
 584         $beg = $min if ($beg < $min);
 585         $end = $max if ($end > $max);
 586         return '420 No article(s) selected' if ($beg > $end);
 587         [ $beg, $end ];
 588 }
 589
 590 sub long_response ($$$$) {
 591         my ($self, $beg, $end, $cb) = @_;
 592         die "BUG: nested long response" if $self->{long_res};
 593
 594         my $fd = $self->{fd};
 595         defined $fd or return;
 596         # make sure we disable reading during a long response,
 597         # clients should not be sending us stuff and making us do more
 598         # work while we are stream a response to them
 599         $self->watch_read(0);
 600         my $t0 = now();
 601         $self->{long_res} = sub {
 602                 # limit our own running time for fairness with other
 603                 # clients and to avoid buffering too much:
 604                 my $lim = 100;
 605
 606                 my $err;
 607                 do {
 608                         eval { $cb->(\$beg) };
 609                 } until (($err = $@) || $self->{closed} ||
 610                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 611
 612                 if ($err || $self->{closed}) {
 613                         $self->{long_res} = undef;
 614
 615                         if ($err) {
 616                                 err($self,
 617                                     "%s during long response[$fd] - %0.6f",
 618                                     $err, now() - $t0);
 619                         }
 620                         if ($self->{closed}) {
 621                                 out($self, " deferred[$fd] aborted - %0.6f",
 622                                            now() - $t0);
 623                         } else {
 624                                 update_idle_time($self);
 625                                 $self->watch_read(1);
 626                         }
 627                 } elsif (!$lim || $self->{write_buf_size}) {
 628                         # no recursion, schedule another call ASAP
 629                         # but only after all pending writes are done
 630                         update_idle_time($self);
 631
 632                         push @$nextq, $self;
 633                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 634                 } else { # all done!
 635                         $self->{long_res} = undef;
 636                         $self->watch_read(1);
 637                         res($self, '.');
 638                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 639                 }
 640         };
 641         $self->{long_res}->(); # kick off!
 642         undef;
 643 }
 644
 645 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 646         my ($self, $xhdr, $range) = @_;
 647
 648         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 649                 my ($ng, $n) = mid_lookup($self, $1);
 650                 return r430 unless $n;
 651                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 652         } else { # numeric range
 653                 $range = $self->{article} unless defined $range;
 654                 my $r = get_range($self, $range);
 655                 return $r unless ref $r;
 656                 my $mm = $self->{ng}->mm;
 657                 my ($beg, $end) = @$r;
 658                 more($self, $xhdr ? r221 : r225);
 659                 long_response($self, $beg, $end, sub {
 660                         my ($i) = @_;
 661                         my $mid = $mm->mid_for($$i);
 662                         more($self, "$$i <$mid>") if defined $mid;
 663                 });
 664         }
 665 }
 666
 667 sub xref ($$) {
 668         my ($ng, $n) = @_;
 669         "$ng->{domain} $ng->{newsgroup}:$n"
 670 }
 671
 672 sub mid_lookup ($$) {
 673         my ($self, $mid) = @_;
 674         my $self_ng = $self->{ng};
 675         if ($self_ng) {
 676                 my $n = $self_ng->mm->num_for($mid);
 677                 return ($self_ng, $n) if defined $n;
 678         }
 679         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 680                 next if defined $self_ng && $ng eq $self_ng;
 681                 my $n = $ng->mm->num_for($mid);
 682                 return ($ng, $n) if defined $n;
 683         }
 684         (undef, undef);
 685 }
 686
 687 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 688         my ($self, $xhdr, $range) = @_;
 689
 690         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 691                 my ($ng, $n) = mid_lookup($self, $1);
 692                 return r430 unless $n;
 693                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 694         } else { # numeric range
 695                 $range = $self->{article} unless defined $range;
 696                 my $r = get_range($self, $range);
 697                 return $r unless ref $r;
 698                 my $ng = $self->{ng};
 699                 my $mm = $ng->mm;
 700                 my ($beg, $end) = @$r;
 701                 more($self, $xhdr ? r221 : r225);
 702                 long_response($self, $beg, $end, sub {
 703                         my ($i) = @_;
 704                         my $mid = $mm->mid_for($$i);
 705                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 706                 });
 707         }
 708 }
 709
 710 sub search_header_for {
 711         my ($srch, $mid, $field) = @_;
 712         my $smsg = $srch->lookup_message($mid) or return;
 713         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 714         $smsg->$field;
 715 }
 716
 717 sub hdr_searchmsg ($$$$) {
 718         my ($self, $xhdr, $field, $range) = @_;
 719         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 720                 my ($ng, $n) = mid_lookup($self, $1);
 721                 return r430 unless $n;
 722                 my $v = search_header_for($ng->search, $range, $field);
 723                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 724         } else { # numeric range
 725                 $range = $self->{article} unless defined $range;
 726                 my $srch = $self->{ng}->search;
 727                 my $mm = $self->{ng}->mm;
 728                 my $r = get_range($self, $range);
 729                 return $r unless ref $r;
 730                 my ($beg, $end) = @$r;
 731                 more($self, $xhdr ? r221 : r225);
 732                 my $off = 0;
 733                 long_response($self, $beg, $end, sub {
 734                         my ($i) = @_;
 735                         my $res = $srch->query_xover($beg, $end, $off);
 736                         my $msgs = $res->{msgs};
 737                         my $nr = scalar @$msgs or return;
 738                         $off += $nr;
 739                         my $tmp = '';
 740                         foreach my $s (@$msgs) {
 741                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 742                         }
 743                         do_more($self, $tmp);
 744                         # -1 to adjust for implicit increment in long_response
 745                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 746                 });
 747         }
 748 }
 749
 750 sub do_hdr ($$$;$) {
 751         my ($self, $xhdr, $header, $range) = @_;
 752         my $sub = lc $header;
 753         if ($sub eq 'message-id') {
 754                 hdr_message_id($self, $xhdr, $range);
 755         } elsif ($sub eq 'xref') {
 756                 hdr_xref($self, $xhdr, $range);
 757         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 758                                 bytes|lines)\z/x) {
 759                 hdr_searchmsg($self, $xhdr, $sub, $range);
 760         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 761                 hdr_searchmsg($self, $xhdr, $1, $range);
 762         } else {
 763                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 764         }
 765 }
 766
 767 # RFC 3977
 768 sub cmd_hdr ($$;$) {
 769         my ($self, $header, $range) = @_;
 770         do_hdr($self, 0, $header, $range);
 771 }
 772
 773 # RFC 2980
 774 sub cmd_xhdr ($$;$) {
 775         my ($self, $header, $range) = @_;
 776         do_hdr($self, 1, $header, $range);
 777 }
 778
 779 sub hdr_mid_prefix ($$$$$) {
 780         my ($self, $xhdr, $ng, $n, $mid) = @_;
 781         return $mid if $xhdr;
 782
 783         # HDR for RFC 3977 users
 784         if (my $self_ng = $self->{ng}) {
 785                 ($self_ng eq $ng) ? $n : '0';
 786         } else {
 787                 '0';
 788         }
 789 }
 790
 791 sub hdr_mid_response ($$$$$$) {
 792         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 793         my $res = '';
 794         if ($xhdr) {
 795                 $res .= r221 . "\r\n";
 796                 $res .= "$mid $v\r\n";
 797         } else {
 798                 $res .= r225 . "\r\n";
 799                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 800                 $res .= "$pfx $v\r\n";
 801         }
 802         res($self, $res .= '.');
 803         undef;
 804 }
 805
 806 sub cmd_xrover ($;$) {
 807         my ($self, $range) = @_;
 808         my $ng = $self->{ng} or return '412 no newsgroup selected';
 809         (defined $range && $range =~ /[<>]/) and
 810                 return '420 No article(s) selected'; # no message IDs
 811
 812         $range = $self->{article} unless defined $range;
 813         my $r = get_range($self, $range);
 814         return $r unless ref $r;
 815         my ($beg, $end) = @$r;
 816         my $mm = $ng->mm;
 817         my $srch = $ng->search;
 818         more($self, '224 Overview information follows');
 819         long_response($self, $beg, $end, sub {
 820                 my ($i) = @_;
 821                 my $mid = $mm->mid_for($$i) or return;
 822                 my $h = search_header_for($srch, $mid, 'references');
 823                 more($self, "$$i $h");
 824         });
 825 }
 826
 827 sub over_line ($$) {
 828         my ($num, $smsg) = @_;
 829         # n.b. field access and procedural calls can be
 830         # 10%-15% faster than OO method calls:
 831         join("\t", $num,
 832                 $smsg->{subject},
 833                 $smsg->{from},
 834                 PublicInbox::SearchMsg::date($smsg),
 835                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 836                 $smsg->{references},
 837                 PublicInbox::SearchMsg::bytes($smsg),
 838                 PublicInbox::SearchMsg::lines($smsg));
 839 }
 840
 841 sub cmd_over ($;$) {
 842         my ($self, $range) = @_;
 843         if ($range && $range =~ /\A<(.+)>\z/) {
 844                 my ($ng, $n) = mid_lookup($self, $1);
 845                 my $smsg = $ng->search->lookup_message($range) or
 846                         return '430 No article with that message-id';
 847                 more($self, '224 Overview information follows (multi-line)');
 848                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 849
 850                 # Only set article number column if it's the current group
 851                 my $self_ng = $self->{ng};
 852                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 853                 more($self, over_line($n, $smsg));
 854                 '.';
 855         } else {
 856                 cmd_xover($self, $range);
 857         }
 858 }
 859
 860 sub cmd_xover ($;$) {
 861         my ($self, $range) = @_;
 862         $range = $self->{article} unless defined $range;
 863         my $r = get_range($self, $range);
 864         return $r unless ref $r;
 865         my ($beg, $end) = @$r;
 866         more($self, "224 Overview information follows for $beg to $end");
 867         my $srch = $self->{ng}->search;
 868         my $off = 0;
 869         long_response($self, $beg, $end, sub {
 870                 my ($i) = @_;
 871                 my $res = $srch->query_xover($beg, $end, $off);
 872                 my $msgs = $res->{msgs};
 873                 my $nr = scalar @$msgs or return;
 874                 $off += $nr;
 875
 876                 # OVERVIEW.FMT
 877                 more($self, join("\r\n", map {
 878                         over_line(PublicInbox::SearchMsg::num($_), $_);
 879                         } @$msgs));
 880
 881                 # -1 to adjust for implicit increment in long_response
 882                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 883         });
 884 }
 885
 886 sub cmd_xpath ($$) {
 887         my ($self, $mid) = @_;
 888         return r501 unless $mid =~ /\A<(.+)>\z/;
 889         $mid = $1;
 890         my @paths;
 891         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 892                 my $n = $ng->mm->num_for($mid);
 893                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 894         }
 895         return '430 no such article on server' unless @paths;
 896         '223 '.join(' ', @paths);
 897 }
 898
 899 sub res ($$) {
 900         my ($self, $line) = @_;
 901         $line = $enc_utf8->encode($line);
 902         do_write($self, $line . "\r\n");
 903 }
 904
 905 sub more ($$) {
 906         my ($self, $line) = @_;
 907         do_more($self, $line . "\r\n");
 908 }
 909
 910 sub do_write ($$) {
 911         my ($self, $data) = @_;
 912         my $done = $self->write($data);
 913         die if $self->{closed};
 914
 915         # Do not watch for readability if we have data in the queue,
 916         # instead re-enable watching for readability when we can
 917         $self->watch_read(0) if (!$done || $self->{long_res});
 918
 919         $done;
 920 }
 921
 922 sub err ($$;@) {
 923         my ($self, $fmt, @args) = @_;
 924         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 925 }
 926
 927 sub out ($$;@) {
 928         my ($self, $fmt, @args) = @_;
 929         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 930 }
 931
 932 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 933
 934 sub do_more ($$) {
 935         my ($self, $data) = @_;
 936         $data = $enc_utf8->encode($data);
 937         if (MSG_MORE && !$self->{write_buf_size}) {
 938                 my $n = send($self->{sock}, $data, MSG_MORE);
 939                 if (defined $n) {
 940                         my $dlen = length($data);
 941                         return 1 if $n == $dlen; # all done!
 942                         $data = substr($data, $n, $dlen - $n);
 943                 }
 944         }
 945         do_write($self, $data);
 946 }
 947
 948 # callbacks for Danga::Socket
 949
 950 sub event_hup { $_[0]->close }
 951 sub event_err { $_[0]->close }
 952
 953 sub event_write {
 954         my ($self) = @_;
 955         update_idle_time($self);
 956         # only continue watching for readability when we are done writing:
 957         if ($self->write(undef) == 1 && !$self->{long_res}) {
 958                 $self->watch_read(1);
 959         }
 960 }
 961
 962 sub event_read {
 963         my ($self) = @_;
 964         use constant LINE_MAX => 512; # RFC 977 section 2.3
 965         my $r = 1;
 966
 967         my $buf = $self->read(LINE_MAX) or return $self->close;
 968         $self->{rbuf} .= $$buf;
 969         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 970                 my $line = $1;
 971                 return $self->close if $line =~ /[[:cntrl:]]/s;
 972                 my $t0 = now();
 973                 my $fd = $self->{fd};
 974                 $r = eval { process_line($self, $line) };
 975                 my $d = $self->{long_res} ?
 976                         " deferred[$fd]" : '';
 977                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 978         }
 979
 980         return $self->close if $r < 0;
 981         my $len = length($self->{rbuf});
 982         return $self->close if ($len >= LINE_MAX);
 983         update_idle_time($self);
 984 }
 985
 986 sub watch_read {
 987         my ($self, $bool) = @_;
 988         my $rv = $self->SUPER::watch_read($bool);
 989         if ($bool && $self->{rbuf} ne '') {
 990                 # Force another read if there is a pipelined request.
 991                 # We don't know if the socket has anything for us to read,
 992                 # and we must double-check again by the time the timer fires
 993                 # in case we really did dispatch a read event and started
 994                 # another long response.
 995                 push @$nextq, $self;
 996                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 997         }
 998         $rv;
 999 }
1000
1001 # for graceful shutdown in PublicInbox::Daemon:
1002 sub busy () {
1003         my ($self) = @_;
1004         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1005 }
1006
1007 1;