lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 require PublicInbox::EvCleanup;
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  17 use URI::Escape qw(uri_escape_utf8);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  54                         event_read($nntp);
  55                 }
  56         }
  57 }
  58
  59 sub update_idle_time ($) {
  60         my ($self) = @_;
  61         my $fd = $self->{fd};
  62         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  63 }
  64
  65 sub expire_old () {
  66         my $now = now();
  67         my $exp = $EXPTIME;
  68         my $old = $now - $exp;
  69         my $nr = 0;
  70         my %new;
  71         while (my ($fd, $v) = each %$EXPMAP) {
  72                 my ($idle_time, $nntp) = @$v;
  73                 if ($idle_time < $old) {
  74                         $nntp->close; # idempotent
  75                 } else {
  76                         ++$nr;
  77                         $new{$fd} = $v;
  78                 }
  79         }
  80         $EXPMAP = \%new;
  81         if ($nr) {
  82                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  83         } else {
  84                 $expt = undef;
  85                 # noop to kick outselves out of the loop ASAP so descriptors
  86                 # really get closed
  87                 PublicInbox::EvCleanup::asap(sub {});
  88         }
  89 }
  90
  91 sub new ($$$) {
  92         my ($class, $sock, $nntpd) = @_;
  93         my $self = fields::new($class);
  94         $self->SUPER::new($sock);
  95         $self->{nntpd} = $nntpd;
  96         res($self, '201 server ready - post via email');
  97         $self->{rbuf} = '';
  98         $self->watch_read(1);
  99         update_idle_time($self);
 100         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 101         $self;
 102 }
 103
 104 sub args_ok ($$) {
 105         my ($cb, $argc) = @_;
 106         my $tot = prototype $cb;
 107         my ($nreq, undef) = split(';', $tot);
 108         $nreq = ($nreq =~ tr/$//) - 1;
 109         $tot = ($tot =~ tr/$//) - 1;
 110         ($argc <= $tot && $argc >= $nreq);
 111 }
 112
 113 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 114 sub process_line ($$) {
 115         my ($self, $l) = @_;
 116         my ($req, @args) = split(/\s+/, $l);
 117         $req = lc($req);
 118         $req = eval {
 119                 no strict 'refs';
 120                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 121         };
 122         return res($self, '500 command not recognized') unless $req;
 123         return res($self, r501) unless args_ok($req, scalar @args);
 124
 125         my $res = eval { $req->($self, @args) };
 126         my $err = $@;
 127         if ($err && !$self->{closed}) {
 128                 chomp($l);
 129                 err($self, 'error from: %s (%s)', $l, $err);
 130                 $res = '503 program fault - command not performed';
 131         }
 132         return 0 unless defined $res;
 133         res($self, $res);
 134 }
 135
 136 sub cmd_mode ($$) {
 137         my ($self, $arg) = @_;
 138         $arg = uc $arg;
 139         return r501 unless $arg eq 'READER';
 140         '201 Posting prohibited';
 141 }
 142
 143 sub cmd_slave ($) { '202 slave status noted' }
 144
 145 sub cmd_xgtitle ($;$) {
 146         my ($self, $wildmat) = @_;
 147         more($self, '282 list of groups and descriptions follows');
 148         list_newsgroups($self, $wildmat);
 149         '.'
 150 }
 151
 152 sub list_overview_fmt ($) {
 153         my ($self) = @_;
 154         do_more($self, $OVERVIEW_FMT);
 155 }
 156
 157 sub list_headers ($;$) {
 158         my ($self) = @_;
 159         do_more($self, $LIST_HEADERS);
 160 }
 161
 162 sub list_active ($;$) {
 163         my ($self, $wildmat) = @_;
 164         wildmat2re($wildmat);
 165         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 166                 $ng->{newsgroup} =~ $wildmat or next;
 167                 group_line($self, $ng);
 168         }
 169 }
 170
 171 sub list_active_times ($;$) {
 172         my ($self, $wildmat) = @_;
 173         wildmat2re($wildmat);
 174         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 175                 $ng->{newsgroup} =~ $wildmat or next;
 176                 my $c = eval { $ng->mm->created_at } || time;
 177                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 178         }
 179 }
 180
 181 sub list_newsgroups ($;$) {
 182         my ($self, $wildmat) = @_;
 183         wildmat2re($wildmat);
 184         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 185                 $ng->{newsgroup} =~ $wildmat or next;
 186                 my $d = $ng->description;
 187                 more($self, "$ng->{newsgroup} $d");
 188         }
 189 }
 190
 191 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 192 sub cmd_list ($;$$) {
 193         my ($self, @args) = @_;
 194         if (scalar @args) {
 195                 my $arg = shift @args;
 196                 $arg =~ tr/A-Z./a-z_/;
 197                 $arg = "list_$arg";
 198                 return r501 if $DISABLED{$arg};
 199
 200                 $arg = eval {
 201                         no strict 'refs';
 202                         *{$arg}{CODE};
 203                 };
 204                 return r501 unless $arg && args_ok($arg, scalar @args);
 205                 more($self, '215 information follows');
 206                 $arg->($self, @args);
 207         } else {
 208                 more($self, '215 list of newsgroups follows');
 209                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 210                         group_line($self, $ng);
 211                 }
 212         }
 213         '.'
 214 }
 215
 216 sub cmd_listgroup ($;$) {
 217         my ($self, $group) = @_;
 218         if (defined $group) {
 219                 my $res = cmd_group($self, $group);
 220                 return $res if ($res !~ /\A211 /);
 221                 more($self, $res);
 222         }
 223
 224         $self->{ng} or return '412 no newsgroup selected';
 225         long_response($self, 0, long_response_limit, sub {
 226                 my ($i) = @_;
 227                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 228                         my ($ary) = @_;
 229                         more($self, join("\r\n", @$ary));
 230                 });
 231
 232                 # -1 to adjust for implicit increment in long_response
 233                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 234         });
 235 }
 236
 237 sub parse_time ($$;$) {
 238         my ($date, $time, $gmt) = @_;
 239         use Time::Local qw();
 240         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 241         if (defined $gmt) {
 242                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 243                 $gmt = 1;
 244         }
 245         my @now = $gmt ? gmtime : localtime;
 246         my ($YYYY, $MM, $DD);
 247         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 248                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 249         } else { # legacy clients send YYMMDD
 250                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 251                 if ($YYYY > strftime('%y', @now)) {
 252                         my $cur_year = $now[5] + 1900;
 253                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 254                 }
 255         }
 256         if ($gmt) {
 257                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 258         } else {
 259                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 260         }
 261 }
 262
 263 sub group_line ($$) {
 264         my ($self, $ng) = @_;
 265         my ($min, $max) = $ng->mm->minmax;
 266         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 267 }
 268
 269 sub cmd_newgroups ($$$;$$) {
 270         my ($self, $date, $time, $gmt, $dists) = @_;
 271         my $ts = eval { parse_time($date, $time, $gmt) };
 272         return r501 if $@;
 273
 274         # TODO dists
 275         more($self, '231 list of new newsgroups follows');
 276         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 277                 my $c = eval { $ng->mm->created_at } || 0;
 278                 next unless $c > $ts;
 279                 group_line($self, $ng);
 280         }
 281         '.'
 282 }
 283
 284 sub wildmat2re (;$) {
 285         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 286         my %keep;
 287         my $salt = rand;
 288         use Digest::SHA qw(sha1_hex);
 289         my $tmp = $_[0];
 290
 291         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 292                 my $orig = $1;
 293                 my $key = sha1_hex($orig . $salt);
 294                 $orig =~ s/([^\w\-])+/\Q$1/g;
 295                 $keep{$key} = $orig;
 296                 $key
 297                 #gex;
 298         my %map = ('*' => '.*', '?' => '.' );
 299         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 300         if (scalar %keep) {
 301                 $tmp =~ s#([a-f0-9]{40})#
 302                         my $orig = $keep{$1};
 303                         defined $orig ? $orig : $1;
 304                         #ge;
 305         }
 306         $_[0] = qr/\A$tmp\z/;
 307 }
 308
 309 sub ngpat2re (;$) {
 310         return $_[0] = qr/\A\z/ unless defined $_[0];
 311         my %map = ('*' => '.*', ',' => '|');
 312         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 313         $_[0] = qr/\A(?:$_[0])\z/;
 314 }
 315
 316 sub cmd_newnews ($$$$;$$) {
 317         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 318         my $ts = eval { parse_time($date, $time, $gmt) };
 319         return r501 if $@;
 320         more($self, '230 list of new articles by message-id follows');
 321         my ($keep, $skip) = split('!', $newsgroups, 2);
 322         ngpat2re($keep);
 323         ngpat2re($skip);
 324         my @srch;
 325         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 326                 $ng->{newsgroup} =~ $keep or next;
 327                 $ng->{newsgroup} =~ $skip and next;
 328                 my $srch = $ng->search or next;
 329                 push @srch, $srch;
 330         };
 331         return '.' unless @srch;
 332
 333         $ts .= '..';
 334         my $opts = { asc => 1, limit => 1000, offset => 0 };
 335         long_response($self, 0, long_response_limit, sub {
 336                 my ($i) = @_;
 337                 my $srch = $srch[0];
 338                 my $res = $srch->query($ts, $opts);
 339                 my $msgs = $res->{msgs};
 340                 if (my $nr = scalar @$msgs) {
 341                         more($self, '<' .
 342                                 join(">\r\n<", map { $_->mid } @$msgs ).
 343                                 '>');
 344                         $opts->{offset} += $nr;
 345                 } else {
 346                         shift @srch;
 347                         if (@srch) { # continue onto next newsgroup
 348                                 $opts->{offset} = 0;
 349                         } else { # break out of the long response.
 350                                 $$i = long_response_limit;
 351                         }
 352                 }
 353         });
 354 }
 355
 356 sub cmd_group ($$) {
 357         my ($self, $group) = @_;
 358         my $no_such = '411 no such news group';
 359         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 360
 361         $self->{ng} = $ng;
 362         my ($min, $max) = $ng->mm->minmax;
 363         $min ||= 0;
 364         $max ||= 0;
 365         $self->{article} = $min;
 366         my $est_size = $max - $min;
 367         "211 $est_size $min $max $group";
 368 }
 369
 370 sub article_adj ($$) {
 371         my ($self, $off) = @_;
 372         my $ng = $self->{ng} or return '412 no newsgroup selected';
 373
 374         my $n = $self->{article};
 375         defined $n or return '420 no current article has been selected';
 376
 377         $n += $off;
 378         my $mid = $ng->mm->mid_for($n);
 379         unless ($mid) {
 380                 $n = $off > 0 ? 'next' : 'previous';
 381                 return "421 no $n article in this group";
 382         }
 383         $self->{article} = $n;
 384         "223 $n <$mid> article retrieved - request text separately";
 385 }
 386
 387 sub cmd_next ($) { article_adj($_[0], 1) }
 388 sub cmd_last ($) { article_adj($_[0], -1) }
 389
 390 # We want to encourage using email and CC-ing everybody involved to avoid
 391 # the single-point-of-failure a single server provides.
 392 sub cmd_post ($) {
 393         my ($self) = @_;
 394         my $ng = $self->{ng};
 395         $ng ? "440 mailto:$ng->{-primary_address} to post"
 396                 : '440 posting not allowed'
 397 }
 398
 399 sub cmd_quit ($) {
 400         my ($self) = @_;
 401         res($self, '205 closing connection - goodbye!');
 402         $self->close;
 403         undef;
 404 }
 405
 406 sub header_append ($$$) {
 407         my ($hdr, $k, $v) = @_;
 408         my @v = $hdr->header($k);
 409         foreach (@v) {
 410                 return if $v eq $_;
 411         }
 412         $hdr->header_set($k, @v, $v);
 413 }
 414
 415 sub set_nntp_headers {
 416         my ($hdr, $ng, $n, $mid) = @_;
 417
 418         # clobber some
 419         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 420         $hdr->header_set('Xref', xref($ng, $n));
 421         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 422         if (my $url = $ng->base_url) {
 423                 $mid = uri_escape_utf8($mid);
 424                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 425                 header_append($hdr, 'List-Archive', "<$url>");
 426         }
 427 }
 428
 429 sub art_lookup ($$$) {
 430         my ($self, $art, $set_headers) = @_;
 431         my $ng = $self->{ng};
 432         my ($n, $mid);
 433         my $err;
 434         if (defined $art) {
 435                 if ($art =~ /\A\d+\z/o) {
 436                         $err = '423 no such article number in this group';
 437                         $n = int($art);
 438                         goto find_mid;
 439                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 440                         $mid = $1;
 441                         $err = r430;
 442                         $n = $ng->mm->num_for($mid) if $ng;
 443                         goto found if defined $n;
 444                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 445                                 $n = $g->mm->num_for($mid);
 446                                 if (defined $n) {
 447                                         $ng = $g;
 448                                         goto found;
 449                                 }
 450                         }
 451                         return $err;
 452                 } else {
 453                         return r501;
 454                 }
 455         } else {
 456                 $err = '420 no current article has been selected';
 457                 $n = $self->{article};
 458                 defined $n or return $err;
 459 find_mid:
 460                 $ng or return '412 no newsgroup has been selected';
 461                 $mid = $ng->mm->mid_for($n);
 462                 defined $mid or return $err;
 463         }
 464 found:
 465         my $bytes;
 466         my $s = eval { $ng->msg_by_mid($mid, \$bytes) } or return $err;
 467         $s = Email::Simple->new($s);
 468         my $lines;
 469         if ($set_headers) {
 470                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 471                 $lines = $s->body =~ tr!\n!\n!;
 472
 473                 # must be last
 474                 $s->body_set('') if ($set_headers == 2);
 475         }
 476         [ $n, $mid, $s, $bytes, $lines, $ng ];
 477 }
 478
 479 sub simple_body_write ($$) {
 480         my ($self, $s) = @_;
 481         my $body = $s->body;
 482         $s->body_set('');
 483         $body =~ s/^\./../smg;
 484         $body =~ s/(?<!\r)\n/\r\n/sg;
 485         do_more($self, $body);
 486         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 487         '.'
 488 }
 489
 490 sub set_art {
 491         my ($self, $art) = @_;
 492         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 493 }
 494
 495 sub _header ($) {
 496         my $hdr = $_[0]->header_obj->as_string;
 497         utf8::encode($hdr);
 498         $hdr
 499 }
 500
 501 sub cmd_article ($;$) {
 502         my ($self, $art) = @_;
 503         my $r = art_lookup($self, $art, 1);
 504         return $r unless ref $r;
 505         my ($n, $mid, $s) = @$r;
 506         set_art($self, $art);
 507         more($self, "220 $n <$mid> article retrieved - head and body follow");
 508         do_more($self, _header($s));
 509         do_more($self, "\r\n");
 510         simple_body_write($self, $s);
 511 }
 512
 513 sub cmd_head ($;$) {
 514         my ($self, $art) = @_;
 515         my $r = art_lookup($self, $art, 2);
 516         return $r unless ref $r;
 517         my ($n, $mid, $s) = @$r;
 518         set_art($self, $art);
 519         more($self, "221 $n <$mid> article retrieved - head follows");
 520         do_more($self, _header($s));
 521         '.'
 522 }
 523
 524 sub cmd_body ($;$) {
 525         my ($self, $art) = @_;
 526         my $r = art_lookup($self, $art, 0);
 527         return $r unless ref $r;
 528         my ($n, $mid, $s) = @$r;
 529         set_art($self, $art);
 530         more($self, "222 $n <$mid> article retrieved - body follows");
 531         simple_body_write($self, $s);
 532 }
 533
 534 sub cmd_stat ($;$) {
 535         my ($self, $art) = @_;
 536         my $r = art_lookup($self, $art, 0);
 537         return $r unless ref $r;
 538         my ($n, $mid, undef) = @$r;
 539         set_art($self, $art);
 540         "223 $n <$mid> article retrieved - request text separately";
 541 }
 542
 543 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 544
 545 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 546
 547 sub cmd_help ($) {
 548         my ($self) = @_;
 549         more($self, '100 help text follows');
 550         '.'
 551 }
 552
 553 sub get_range ($$) {
 554         my ($self, $range) = @_;
 555         my $ng = $self->{ng} or return '412 no news group has been selected';
 556         defined $range or return '420 No article(s) selected';
 557         my ($beg, $end);
 558         my ($min, $max) = $ng->mm->minmax;
 559         if ($range =~ /\A(\d+)\z/) {
 560                 $beg = $end = $1;
 561         } elsif ($range =~ /\A(\d+)-\z/) {
 562                 ($beg, $end) = ($1, $max);
 563         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 564                 ($beg, $end) = ($1, $2);
 565         } else {
 566                 return r501;
 567         }
 568         $beg = $min if ($beg < $min);
 569         $end = $max if ($end > $max);
 570         return '420 No article(s) selected' if ($beg > $end);
 571         [ $beg, $end ];
 572 }
 573
 574 sub long_response ($$$$) {
 575         my ($self, $beg, $end, $cb) = @_;
 576         die "BUG: nested long response" if $self->{long_res};
 577
 578         my $fd = $self->{fd};
 579         defined $fd or return;
 580         # make sure we disable reading during a long response,
 581         # clients should not be sending us stuff and making us do more
 582         # work while we are stream a response to them
 583         $self->watch_read(0);
 584         my $t0 = now();
 585         $self->{long_res} = sub {
 586                 # limit our own running time for fairness with other
 587                 # clients and to avoid buffering too much:
 588                 my $lim = 100;
 589
 590                 my $err;
 591                 do {
 592                         eval { $cb->(\$beg) };
 593                 } until (($err = $@) || $self->{closed} ||
 594                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 595
 596                 if ($err || $self->{closed}) {
 597                         $self->{long_res} = undef;
 598
 599                         if ($err) {
 600                                 err($self,
 601                                     "%s during long response[$fd] - %0.6f",
 602                                     $err, now() - $t0);
 603                         }
 604                         if ($self->{closed}) {
 605                                 out($self, " deferred[$fd] aborted - %0.6f",
 606                                            now() - $t0);
 607                         } else {
 608                                 update_idle_time($self);
 609                                 $self->watch_read(1);
 610                         }
 611                 } elsif (!$lim || $self->{write_buf_size}) {
 612                         # no recursion, schedule another call ASAP
 613                         # but only after all pending writes are done
 614                         update_idle_time($self);
 615
 616                         push @$nextq, $self;
 617                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 618                 } else { # all done!
 619                         $self->{long_res} = undef;
 620                         $self->watch_read(1);
 621                         res($self, '.');
 622                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 623                 }
 624         };
 625         $self->{long_res}->(); # kick off!
 626         undef;
 627 }
 628
 629 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 630         my ($self, $xhdr, $range) = @_;
 631
 632         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 633                 my ($ng, $n) = mid_lookup($self, $1);
 634                 return r430 unless $n;
 635                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 636         } else { # numeric range
 637                 $range = $self->{article} unless defined $range;
 638                 my $r = get_range($self, $range);
 639                 return $r unless ref $r;
 640                 my $mm = $self->{ng}->mm;
 641                 my ($beg, $end) = @$r;
 642                 more($self, $xhdr ? r221 : r225);
 643                 long_response($self, $beg, $end, sub {
 644                         my ($i) = @_;
 645                         my $mid = $mm->mid_for($$i);
 646                         more($self, "$$i <$mid>") if defined $mid;
 647                 });
 648         }
 649 }
 650
 651 sub xref ($$) {
 652         my ($ng, $n) = @_;
 653         "$ng->{domain} $ng->{newsgroup}:$n"
 654 }
 655
 656 sub mid_lookup ($$) {
 657         my ($self, $mid) = @_;
 658         my $self_ng = $self->{ng};
 659         if ($self_ng) {
 660                 my $n = $self_ng->mm->num_for($mid);
 661                 return ($self_ng, $n) if defined $n;
 662         }
 663         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 664                 next if defined $self_ng && $ng eq $self_ng;
 665                 my $n = $ng->mm->num_for($mid);
 666                 return ($ng, $n) if defined $n;
 667         }
 668         (undef, undef);
 669 }
 670
 671 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 672         my ($self, $xhdr, $range) = @_;
 673
 674         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 675                 my ($ng, $n) = mid_lookup($self, $1);
 676                 return r430 unless $n;
 677                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 678         } else { # numeric range
 679                 $range = $self->{article} unless defined $range;
 680                 my $r = get_range($self, $range);
 681                 return $r unless ref $r;
 682                 my $ng = $self->{ng};
 683                 my $mm = $ng->mm;
 684                 my ($beg, $end) = @$r;
 685                 more($self, $xhdr ? r221 : r225);
 686                 long_response($self, $beg, $end, sub {
 687                         my ($i) = @_;
 688                         my $mid = $mm->mid_for($$i);
 689                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 690                 });
 691         }
 692 }
 693
 694 sub search_header_for {
 695         my ($srch, $mid, $field) = @_;
 696         my $smsg = $srch->lookup_mail($mid) or return;
 697         $smsg->$field;
 698 }
 699
 700 sub hdr_searchmsg ($$$$) {
 701         my ($self, $xhdr, $field, $range) = @_;
 702         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 703                 my ($ng, $n) = mid_lookup($self, $1);
 704                 return r430 unless $n;
 705                 my $v = search_header_for($ng->search, $range, $field);
 706                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 707         } else { # numeric range
 708                 $range = $self->{article} unless defined $range;
 709                 my $srch = $self->{ng}->search;
 710                 my $mm = $self->{ng}->mm;
 711                 my $r = get_range($self, $range);
 712                 return $r unless ref $r;
 713                 my ($beg, $end) = @$r;
 714                 more($self, $xhdr ? r221 : r225);
 715                 my $off = 0;
 716                 long_response($self, $beg, $end, sub {
 717                         my ($i) = @_;
 718                         my $res = $srch->query_xover($beg, $end, $off);
 719                         my $msgs = $res->{msgs};
 720                         my $nr = scalar @$msgs or return;
 721                         $off += $nr;
 722                         my $tmp = '';
 723                         foreach my $s (@$msgs) {
 724                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 725                         }
 726                         utf8::encode($tmp);
 727                         do_more($self, $tmp);
 728                         # -1 to adjust for implicit increment in long_response
 729                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 730                 });
 731         }
 732 }
 733
 734 sub do_hdr ($$$;$) {
 735         my ($self, $xhdr, $header, $range) = @_;
 736         my $sub = lc $header;
 737         if ($sub eq 'message-id') {
 738                 hdr_message_id($self, $xhdr, $range);
 739         } elsif ($sub eq 'xref') {
 740                 hdr_xref($self, $xhdr, $range);
 741         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 742                                 bytes|lines)\z/x) {
 743                 hdr_searchmsg($self, $xhdr, $sub, $range);
 744         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 745                 hdr_searchmsg($self, $xhdr, $1, $range);
 746         } else {
 747                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 748         }
 749 }
 750
 751 # RFC 3977
 752 sub cmd_hdr ($$;$) {
 753         my ($self, $header, $range) = @_;
 754         do_hdr($self, 0, $header, $range);
 755 }
 756
 757 # RFC 2980
 758 sub cmd_xhdr ($$;$) {
 759         my ($self, $header, $range) = @_;
 760         do_hdr($self, 1, $header, $range);
 761 }
 762
 763 sub hdr_mid_prefix ($$$$$) {
 764         my ($self, $xhdr, $ng, $n, $mid) = @_;
 765         return $mid if $xhdr;
 766
 767         # HDR for RFC 3977 users
 768         if (my $self_ng = $self->{ng}) {
 769                 ($self_ng eq $ng) ? $n : '0';
 770         } else {
 771                 '0';
 772         }
 773 }
 774
 775 sub hdr_mid_response ($$$$$$) {
 776         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 777         my $res = '';
 778         if ($xhdr) {
 779                 $res .= r221 . "\r\n";
 780                 $res .= "$mid $v\r\n";
 781         } else {
 782                 $res .= r225 . "\r\n";
 783                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 784                 $res .= "$pfx $v\r\n";
 785         }
 786         res($self, $res .= '.');
 787         undef;
 788 }
 789
 790 sub cmd_xrover ($;$) {
 791         my ($self, $range) = @_;
 792         my $ng = $self->{ng} or return '412 no newsgroup selected';
 793         (defined $range && $range =~ /[<>]/) and
 794                 return '420 No article(s) selected'; # no message IDs
 795
 796         $range = $self->{article} unless defined $range;
 797         my $r = get_range($self, $range);
 798         return $r unless ref $r;
 799         my ($beg, $end) = @$r;
 800         my $mm = $ng->mm;
 801         my $srch = $ng->search;
 802         more($self, '224 Overview information follows');
 803         long_response($self, $beg, $end, sub {
 804                 my ($i) = @_;
 805                 my $mid = $mm->mid_for($$i) or return;
 806                 my $h = search_header_for($srch, $mid, 'references');
 807                 more($self, "$$i $h");
 808         });
 809 }
 810
 811 sub over_line ($$) {
 812         my ($num, $smsg) = @_;
 813         # n.b. field access and procedural calls can be
 814         # 10%-15% faster than OO method calls:
 815         my $s = join("\t", $num,
 816                 $smsg->{subject},
 817                 $smsg->{from},
 818                 PublicInbox::SearchMsg::date($smsg),
 819                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 820                 $smsg->{references},
 821                 PublicInbox::SearchMsg::bytes($smsg),
 822                 PublicInbox::SearchMsg::lines($smsg));
 823         utf8::encode($s);
 824         $s
 825 }
 826
 827 sub cmd_over ($;$) {
 828         my ($self, $range) = @_;
 829         if ($range && $range =~ /\A<(.+)>\z/) {
 830                 my ($ng, $n) = mid_lookup($self, $1);
 831                 my $smsg = $ng->search->lookup_mail($range) or
 832                         return '430 No article with that message-id';
 833                 more($self, '224 Overview information follows (multi-line)');
 834
 835                 # Only set article number column if it's the current group
 836                 my $self_ng = $self->{ng};
 837                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 838                 more($self, over_line($n, $smsg));
 839                 '.';
 840         } else {
 841                 cmd_xover($self, $range);
 842         }
 843 }
 844
 845 sub cmd_xover ($;$) {
 846         my ($self, $range) = @_;
 847         $range = $self->{article} unless defined $range;
 848         my $r = get_range($self, $range);
 849         return $r unless ref $r;
 850         my ($beg, $end) = @$r;
 851         more($self, "224 Overview information follows for $beg to $end");
 852         my $srch = $self->{ng}->search;
 853         my $off = 0;
 854         long_response($self, $beg, $end, sub {
 855                 my ($i) = @_;
 856                 my $res = $srch->query_xover($beg, $end, $off);
 857                 my $msgs = $res->{msgs};
 858                 my $nr = scalar @$msgs or return;
 859                 $off += $nr;
 860
 861                 # OVERVIEW.FMT
 862                 more($self, join("\r\n", map {
 863                         over_line(PublicInbox::SearchMsg::num($_), $_);
 864                         } @$msgs));
 865
 866                 # -1 to adjust for implicit increment in long_response
 867                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 868         });
 869 }
 870
 871 sub cmd_xpath ($$) {
 872         my ($self, $mid) = @_;
 873         return r501 unless $mid =~ /\A<(.+)>\z/;
 874         $mid = $1;
 875         my @paths;
 876         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 877                 my $n = $ng->mm->num_for($mid);
 878                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 879         }
 880         return '430 no such article on server' unless @paths;
 881         '223 '.join(' ', @paths);
 882 }
 883
 884 sub res ($$) {
 885         my ($self, $line) = @_;
 886         do_write($self, $line . "\r\n");
 887 }
 888
 889 sub more ($$) {
 890         my ($self, $line) = @_;
 891         do_more($self, $line . "\r\n");
 892 }
 893
 894 sub do_write ($$) {
 895         my ($self, $data) = @_;
 896         my $done = $self->write($data);
 897         return if $self->{closed};
 898
 899         # Do not watch for readability if we have data in the queue,
 900         # instead re-enable watching for readability when we can
 901         $self->watch_read(0) if (!$done || $self->{long_res});
 902
 903         $done;
 904 }
 905
 906 sub err ($$;@) {
 907         my ($self, $fmt, @args) = @_;
 908         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 909 }
 910
 911 sub out ($$;@) {
 912         my ($self, $fmt, @args) = @_;
 913         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 914 }
 915
 916 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 917
 918 sub do_more ($$) {
 919         my ($self, $data) = @_;
 920         if (MSG_MORE && !$self->{write_buf_size}) {
 921                 my $n = send($self->{sock}, $data, MSG_MORE);
 922                 if (defined $n) {
 923                         my $dlen = length($data);
 924                         return 1 if $n == $dlen; # all done!
 925                         $data = substr($data, $n, $dlen - $n);
 926                 }
 927         }
 928         do_write($self, $data);
 929 }
 930
 931 # callbacks for Danga::Socket
 932
 933 sub event_hup { $_[0]->close }
 934 sub event_err { $_[0]->close }
 935
 936 sub event_write {
 937         my ($self) = @_;
 938         update_idle_time($self);
 939         # only continue watching for readability when we are done writing:
 940         if ($self->write(undef) == 1 && !$self->{long_res}) {
 941                 $self->watch_read(1);
 942         }
 943 }
 944
 945 sub event_read {
 946         my ($self) = @_;
 947         use constant LINE_MAX => 512; # RFC 977 section 2.3
 948         my $r = 1;
 949
 950         my $buf = $self->read(LINE_MAX) or return $self->close;
 951         $self->{rbuf} .= $$buf;
 952         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 953                 my $line = $1;
 954                 return $self->close if $line =~ /[[:cntrl:]]/s;
 955                 my $t0 = now();
 956                 my $fd = $self->{fd};
 957                 $r = eval { process_line($self, $line) };
 958                 my $d = $self->{long_res} ?
 959                         " deferred[$fd]" : '';
 960                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 961         }
 962
 963         return $self->close if $r < 0;
 964         my $len = length($self->{rbuf});
 965         return $self->close if ($len >= LINE_MAX);
 966         update_idle_time($self);
 967 }
 968
 969 sub watch_read {
 970         my ($self, $bool) = @_;
 971         my $rv = $self->SUPER::watch_read($bool);
 972         if ($bool && $self->{rbuf} ne '') {
 973                 # Force another read if there is a pipelined request.
 974                 # We don't know if the socket has anything for us to read,
 975                 # and we must double-check again by the time the timer fires
 976                 # in case we really did dispatch a read event and started
 977                 # another long response.
 978                 push @$nextq, $self;
 979                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 980         }
 981         $rv;
 982 }
 983
 984 sub not_idle_long ($$) {
 985         my ($self, $now) = @_;
 986         defined(my $fd = $self->{fd}) or return;
 987         my $ary = $EXPMAP->{$fd} or return;
 988         my $exp_at = $ary->[0] + $EXPTIME;
 989         $exp_at > $now;
 990 }
 991
 992 # for graceful shutdown in PublicInbox::Daemon:
 993 sub busy {
 994         my ($self, $now) = @_;
 995         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
 996          not_idle_long($self, $now));
 997 }
 998
 999 1;