lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27
  28 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_read($nntp);
  57
  58                         # maybe there's more pipelined data, or we'll have
  59                         # to register it for socket-readiness notifications
  60                         if (!$nntp->{long_res} && !$nntp->{closed}) {
  61                                 check_read($nntp);
  62                         }
  63                 }
  64         }
  65 }
  66
  67 sub update_idle_time ($) {
  68         my ($self) = @_;
  69         my $fd = $self->{fd};
  70         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  71 }
  72
  73 sub expire_old () {
  74         my $now = now();
  75         my $exp = $EXPTIME;
  76         my $old = $now - $exp;
  77         my $nr = 0;
  78         my %new;
  79         while (my ($fd, $v) = each %$EXPMAP) {
  80                 my ($idle_time, $nntp) = @$v;
  81                 if ($idle_time < $old) {
  82                         $nntp->close; # idempotent
  83                 } else {
  84                         ++$nr;
  85                         $new{$fd} = $v;
  86                 }
  87         }
  88         $EXPMAP = \%new;
  89         if ($nr) {
  90                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  91         } else {
  92                 $expt = undef;
  93                 # noop to kick outselves out of the loop ASAP so descriptors
  94                 # really get closed
  95                 PublicInbox::EvCleanup::asap(sub {});
  96         }
  97 }
  98
  99 sub new ($$$) {
 100         my ($class, $sock, $nntpd) = @_;
 101         my $self = fields::new($class);
 102         $self->SUPER::new($sock);
 103         $self->{nntpd} = $nntpd;
 104         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
 105         $self->{rbuf} = '';
 106         $self->watch_read(1);
 107         update_idle_time($self);
 108         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 109         $self;
 110 }
 111
 112 sub args_ok ($$) {
 113         my ($cb, $argc) = @_;
 114         my $tot = prototype $cb;
 115         my ($nreq, undef) = split(';', $tot);
 116         $nreq = ($nreq =~ tr/$//) - 1;
 117         $tot = ($tot =~ tr/$//) - 1;
 118         ($argc <= $tot && $argc >= $nreq);
 119 }
 120
 121 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 122 sub process_line ($$) {
 123         my ($self, $l) = @_;
 124         my ($req, @args) = split(/\s+/, $l);
 125         return 1 unless defined($req); # skip blank line
 126         $req = lc($req);
 127         $req = eval {
 128                 no strict 'refs';
 129                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 130         };
 131         return res($self, '500 command not recognized') unless $req;
 132         return res($self, r501) unless args_ok($req, scalar @args);
 133
 134         my $res = eval { $req->($self, @args) };
 135         my $err = $@;
 136         if ($err && !$self->{closed}) {
 137                 local $/ = "\n";
 138                 chomp($l);
 139                 err($self, 'error from: %s (%s)', $l, $err);
 140                 $res = '503 program fault - command not performed';
 141         }
 142         return 0 unless defined $res;
 143         res($self, $res);
 144 }
 145
 146 sub cmd_mode ($$) {
 147         my ($self, $arg) = @_;
 148         $arg = uc $arg;
 149         return r501 unless $arg eq 'READER';
 150         '201 Posting prohibited';
 151 }
 152
 153 sub cmd_slave ($) { '202 slave status noted' }
 154
 155 sub cmd_xgtitle ($;$) {
 156         my ($self, $wildmat) = @_;
 157         more($self, '282 list of groups and descriptions follows');
 158         list_newsgroups($self, $wildmat);
 159         '.'
 160 }
 161
 162 sub list_overview_fmt ($) {
 163         my ($self) = @_;
 164         do_more($self, $OVERVIEW_FMT);
 165 }
 166
 167 sub list_headers ($;$) {
 168         my ($self) = @_;
 169         do_more($self, $LIST_HEADERS);
 170 }
 171
 172 sub list_active ($;$) {
 173         my ($self, $wildmat) = @_;
 174         wildmat2re($wildmat);
 175         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                 $ng->{newsgroup} =~ $wildmat or next;
 177                 group_line($self, $ng);
 178         }
 179 }
 180
 181 sub list_active_times ($;$) {
 182         my ($self, $wildmat) = @_;
 183         wildmat2re($wildmat);
 184         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 185                 $ng->{newsgroup} =~ $wildmat or next;
 186                 my $c = eval { $ng->mm->created_at } || time;
 187                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 188         }
 189 }
 190
 191 sub list_newsgroups ($;$) {
 192         my ($self, $wildmat) = @_;
 193         wildmat2re($wildmat);
 194         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 195                 $ng->{newsgroup} =~ $wildmat or next;
 196                 my $d = $ng->description;
 197                 more($self, "$ng->{newsgroup} $d");
 198         }
 199 }
 200
 201 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 202 sub cmd_list ($;$$) {
 203         my ($self, @args) = @_;
 204         if (scalar @args) {
 205                 my $arg = shift @args;
 206                 $arg =~ tr/A-Z./a-z_/;
 207                 $arg = "list_$arg";
 208                 return r501 if $DISABLED{$arg};
 209
 210                 $arg = eval {
 211                         no strict 'refs';
 212                         *{$arg}{CODE};
 213                 };
 214                 return r501 unless $arg && args_ok($arg, scalar @args);
 215                 more($self, '215 information follows');
 216                 $arg->($self, @args);
 217         } else {
 218                 more($self, '215 list of newsgroups follows');
 219                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 220                         group_line($self, $ng);
 221                 }
 222         }
 223         '.'
 224 }
 225
 226 sub cmd_listgroup ($;$) {
 227         my ($self, $group) = @_;
 228         if (defined $group) {
 229                 my $res = cmd_group($self, $group);
 230                 return $res if ($res !~ /\A211 /);
 231                 more($self, $res);
 232         }
 233
 234         $self->{ng} or return '412 no newsgroup selected';
 235         my $n = 0;
 236         long_response($self, sub {
 237                 my $ary = $self->{ng}->mm->ids_after(\$n);
 238                 scalar @$ary or return;
 239                 more($self, join("\r\n", @$ary));
 240                 1;
 241         });
 242 }
 243
 244 sub parse_time ($$;$) {
 245         my ($date, $time, $gmt) = @_;
 246         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 247         if (defined $gmt) {
 248                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 249                 $gmt = 1;
 250         }
 251         my @now = $gmt ? gmtime : localtime;
 252         my ($YYYY, $MM, $DD);
 253         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 254                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 255         } else { # legacy clients send YYMMDD
 256                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 257                 my $cur_year = $now[5] + 1900;
 258                 if ($YYYY > $cur_year) {
 259                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 260                 }
 261         }
 262         if ($gmt) {
 263                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 264         } else {
 265                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 266         }
 267 }
 268
 269 sub group_line ($$) {
 270         my ($self, $ng) = @_;
 271         my ($min, $max) = $ng->mm->minmax;
 272         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 273 }
 274
 275 sub cmd_newgroups ($$$;$$) {
 276         my ($self, $date, $time, $gmt, $dists) = @_;
 277         my $ts = eval { parse_time($date, $time, $gmt) };
 278         return r501 if $@;
 279
 280         # TODO dists
 281         more($self, '231 list of new newsgroups follows');
 282         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 283                 my $c = eval { $ng->mm->created_at } || 0;
 284                 next unless $c > $ts;
 285                 group_line($self, $ng);
 286         }
 287         '.'
 288 }
 289
 290 sub wildmat2re (;$) {
 291         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 292         my %keep;
 293         my $salt = rand;
 294         my $tmp = $_[0];
 295
 296         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 297                 my $orig = $1;
 298                 my $key = sha1_hex($orig . $salt);
 299                 $orig =~ s/([^\w\-])+/\Q$1/g;
 300                 $keep{$key} = $orig;
 301                 $key
 302                 #gex;
 303         my %map = ('*' => '.*', '?' => '.' );
 304         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 305         if (scalar %keep) {
 306                 $tmp =~ s#([a-f0-9]{40})#
 307                         my $orig = $keep{$1};
 308                         defined $orig ? $orig : $1;
 309                         #ge;
 310         }
 311         $_[0] = qr/\A$tmp\z/;
 312 }
 313
 314 sub ngpat2re (;$) {
 315         return $_[0] = qr/\A\z/ unless defined $_[0];
 316         my %map = ('*' => '.*', ',' => '|');
 317         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 318         $_[0] = qr/\A(?:$_[0])\z/;
 319 }
 320
 321 sub cmd_newnews ($$$$;$$) {
 322         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 323         my $ts = eval { parse_time($date, $time, $gmt) };
 324         return r501 if $@;
 325         more($self, '230 list of new articles by message-id follows');
 326         my ($keep, $skip) = split('!', $newsgroups, 2);
 327         ngpat2re($keep);
 328         ngpat2re($skip);
 329         my @srch;
 330         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 331                 $ng->{newsgroup} =~ $keep or next;
 332                 $ng->{newsgroup} =~ $skip and next;
 333                 my $srch = $ng->search or next;
 334                 push @srch, $srch;
 335         };
 336         return '.' unless @srch;
 337
 338         my $prev = 0;
 339         long_response($self, sub {
 340                 my $srch = $srch[0];
 341                 my $msgs = $srch->query_ts($ts, $prev);
 342                 if (scalar @$msgs) {
 343                         more($self, '<' .
 344                                 join(">\r\n<", map { $_->mid } @$msgs ).
 345                                 '>');
 346                         $prev = $msgs->[-1]->{num};
 347                 } else {
 348                         shift @srch;
 349                         if (@srch) { # continue onto next newsgroup
 350                                 $prev = 0;
 351                                 return 1;
 352                         } else { # break out of the long response.
 353                                 return;
 354                         }
 355                 }
 356         });
 357 }
 358
 359 sub cmd_group ($$) {
 360         my ($self, $group) = @_;
 361         my $no_such = '411 no such news group';
 362         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 363
 364         $self->{ng} = $ng;
 365         my ($min, $max) = $ng->mm->minmax;
 366         $min ||= 0;
 367         $max ||= 0;
 368         $self->{article} = $min;
 369         my $est_size = $max - $min;
 370         "211 $est_size $min $max $group";
 371 }
 372
 373 sub article_adj ($$) {
 374         my ($self, $off) = @_;
 375         my $ng = $self->{ng} or return '412 no newsgroup selected';
 376
 377         my $n = $self->{article};
 378         defined $n or return '420 no current article has been selected';
 379
 380         $n += $off;
 381         my $mid = $ng->mm->mid_for($n);
 382         unless ($mid) {
 383                 $n = $off > 0 ? 'next' : 'previous';
 384                 return "421 no $n article in this group";
 385         }
 386         $self->{article} = $n;
 387         "223 $n <$mid> article retrieved - request text separately";
 388 }
 389
 390 sub cmd_next ($) { article_adj($_[0], 1) }
 391 sub cmd_last ($) { article_adj($_[0], -1) }
 392
 393 # We want to encourage using email and CC-ing everybody involved to avoid
 394 # the single-point-of-failure a single server provides.
 395 sub cmd_post ($) {
 396         my ($self) = @_;
 397         my $ng = $self->{ng};
 398         $ng ? "440 mailto:$ng->{-primary_address} to post"
 399                 : '440 posting not allowed'
 400 }
 401
 402 sub cmd_quit ($) {
 403         my ($self) = @_;
 404         res($self, '205 closing connection - goodbye!');
 405         $self->close;
 406         undef;
 407 }
 408
 409 sub header_append ($$$) {
 410         my ($hdr, $k, $v) = @_;
 411         my @v = $hdr->header($k);
 412         foreach (@v) {
 413                 return if $v eq $_;
 414         }
 415         $hdr->header_set($k, @v, $v);
 416 }
 417
 418 sub xref ($$$$) {
 419         my ($self, $ng, $n, $mid) = @_;
 420         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 421
 422         # num_for is pretty cheap and sometimes we'll lookup the existence
 423         # of an article without getting even the OVER info.  In other words,
 424         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 425         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 426         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 427                 next if $ng eq $other;
 428                 my $num = eval { $other->mm->num_for($mid) } or next;
 429                 $ret .= " $other->{newsgroup}:$num";
 430         }
 431         $ret;
 432 }
 433
 434 sub set_nntp_headers ($$$$$) {
 435         my ($self, $hdr, $ng, $n, $mid) = @_;
 436
 437         # clobber some
 438         my $xref = xref($self, $ng, $n, $mid);
 439         $hdr->header_set('Xref', $xref);
 440         $xref =~ s/:\d+//g;
 441         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 442         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 443         if (my $url = $ng->base_url) {
 444                 $mid = mid_escape($mid);
 445                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 446                 header_append($hdr, 'List-Archive', "<$url>");
 447         }
 448 }
 449
 450 sub art_lookup ($$$) {
 451         my ($self, $art, $set_headers) = @_;
 452         my $ng = $self->{ng};
 453         my ($n, $mid);
 454         my $err;
 455         if (defined $art) {
 456                 if ($art =~ /\A\d+\z/o) {
 457                         $err = '423 no such article number in this group';
 458                         $n = int($art);
 459                         goto find_mid;
 460                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 461                         $mid = $1;
 462                         $err = r430;
 463                         $n = $ng->mm->num_for($mid) if $ng;
 464                         goto found if defined $n;
 465                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 466                                 $n = $g->mm->num_for($mid);
 467                                 if (defined $n) {
 468                                         $ng = $g;
 469                                         goto found;
 470                                 }
 471                         }
 472                         return $err;
 473                 } else {
 474                         return r501;
 475                 }
 476         } else {
 477                 $err = '420 no current article has been selected';
 478                 $n = $self->{article};
 479                 defined $n or return $err;
 480 find_mid:
 481                 $ng or return '412 no newsgroup has been selected';
 482                 $mid = $ng->mm->mid_for($n);
 483                 defined $mid or return $err;
 484         }
 485 found:
 486         my $smsg = $ng->search->{over_ro}->get_art($n) or return $err;
 487         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 488         my $s = Email::Simple->new($msg);
 489         if ($set_headers) {
 490                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 491
 492                 # must be last
 493                 $s->body_set('') if ($set_headers == 2);
 494         }
 495         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 496 }
 497
 498 sub simple_body_write ($$) {
 499         my ($self, $s) = @_;
 500         my $body = $s->body;
 501         $s->body_set('');
 502         $body =~ s/^\./../smg;
 503         $body =~ s/(?<!\r)\n/\r\n/sg;
 504         do_more($self, $body);
 505         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 506         '.'
 507 }
 508
 509 sub set_art {
 510         my ($self, $art) = @_;
 511         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 512 }
 513
 514 sub _header ($) {
 515         my $hdr = $_[0]->header_obj->as_string;
 516         utf8::encode($hdr);
 517         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 518         $hdr
 519 }
 520
 521 sub cmd_article ($;$) {
 522         my ($self, $art) = @_;
 523         my $r = art_lookup($self, $art, 1);
 524         return $r unless ref $r;
 525         my ($n, $mid, $s) = @$r;
 526         set_art($self, $art);
 527         more($self, "220 $n <$mid> article retrieved - head and body follow");
 528         do_more($self, _header($s));
 529         do_more($self, "\r\n");
 530         simple_body_write($self, $s);
 531 }
 532
 533 sub cmd_head ($;$) {
 534         my ($self, $art) = @_;
 535         my $r = art_lookup($self, $art, 2);
 536         return $r unless ref $r;
 537         my ($n, $mid, $s) = @$r;
 538         set_art($self, $art);
 539         more($self, "221 $n <$mid> article retrieved - head follows");
 540         do_more($self, _header($s));
 541         '.'
 542 }
 543
 544 sub cmd_body ($;$) {
 545         my ($self, $art) = @_;
 546         my $r = art_lookup($self, $art, 0);
 547         return $r unless ref $r;
 548         my ($n, $mid, $s) = @$r;
 549         set_art($self, $art);
 550         more($self, "222 $n <$mid> article retrieved - body follows");
 551         simple_body_write($self, $s);
 552 }
 553
 554 sub cmd_stat ($;$) {
 555         my ($self, $art) = @_;
 556         my $r = art_lookup($self, $art, 0);
 557         return $r unless ref $r;
 558         my ($n, $mid, undef) = @$r;
 559         set_art($self, $art);
 560         "223 $n <$mid> article retrieved - request text separately";
 561 }
 562
 563 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 564
 565 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 566
 567 sub cmd_help ($) {
 568         my ($self) = @_;
 569         more($self, '100 help text follows');
 570         '.'
 571 }
 572
 573 sub get_range ($$) {
 574         my ($self, $range) = @_;
 575         my $ng = $self->{ng} or return '412 no news group has been selected';
 576         defined $range or return '420 No article(s) selected';
 577         my ($beg, $end);
 578         my ($min, $max) = $ng->mm->minmax;
 579         if ($range =~ /\A(\d+)\z/) {
 580                 $beg = $end = $1;
 581         } elsif ($range =~ /\A(\d+)-\z/) {
 582                 ($beg, $end) = ($1, $max);
 583         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 584                 ($beg, $end) = ($1, $2);
 585         } else {
 586                 return r501;
 587         }
 588         $beg = $min if ($beg < $min);
 589         $end = $max if ($end > $max);
 590         return '420 No article(s) selected' if ($beg > $end);
 591         [ $beg, $end ];
 592 }
 593
 594 sub long_response ($$) {
 595         my ($self, $cb) = @_;
 596         die "BUG: nested long response" if $self->{long_res};
 597
 598         my $fd = $self->{fd};
 599         defined $fd or return;
 600         # make sure we disable reading during a long response,
 601         # clients should not be sending us stuff and making us do more
 602         # work while we are stream a response to them
 603         $self->watch_read(0);
 604         my $t0 = now();
 605         $self->{long_res} = sub {
 606                 my $more = eval { $cb->() };
 607                 if ($@ || $self->{closed}) {
 608                         $self->{long_res} = undef;
 609
 610                         if ($@) {
 611                                 err($self,
 612                                     "%s during long response[$fd] - %0.6f",
 613                                     $@, now() - $t0);
 614                         }
 615                         if ($self->{closed}) {
 616                                 out($self, " deferred[$fd] aborted - %0.6f",
 617                                            now() - $t0);
 618                         } else {
 619                                 update_idle_time($self);
 620                                 check_read($self);
 621                         }
 622                 } elsif ($more) { # $self->{write_buf_size}:
 623                         # no recursion, schedule another call ASAP
 624                         # but only after all pending writes are done
 625                         update_idle_time($self);
 626
 627                         push @$nextq, $self;
 628                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 629                 } else { # all done!
 630                         $self->{long_res} = undef;
 631                         check_read($self);
 632                         res($self, '.');
 633                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 634                 }
 635         };
 636         $self->{long_res}->(); # kick off!
 637         undef;
 638 }
 639
 640 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 641         my ($self, $xhdr, $range) = @_;
 642
 643         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 644                 my ($ng, $n) = mid_lookup($self, $1);
 645                 return r430 unless $n;
 646                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 647         } else { # numeric range
 648                 $range = $self->{article} unless defined $range;
 649                 my $r = get_range($self, $range);
 650                 return $r unless ref $r;
 651                 my $mm = $self->{ng}->mm;
 652                 my ($beg, $end) = @$r;
 653                 more($self, $xhdr ? r221 : r225);
 654                 long_response($self, sub {
 655                         my $r = $mm->msg_range(\$beg, $end);
 656                         @$r or return;
 657                         more($self, join("\r\n", map {
 658                                 "$_->[0] <$_->[1]>"
 659                         } @$r));
 660                         1;
 661                 });
 662         }
 663 }
 664
 665 sub mid_lookup ($$) {
 666         my ($self, $mid) = @_;
 667         my $self_ng = $self->{ng};
 668         if ($self_ng) {
 669                 my $n = $self_ng->mm->num_for($mid);
 670                 return ($self_ng, $n) if defined $n;
 671         }
 672         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 673                 next if defined $self_ng && $ng eq $self_ng;
 674                 my $n = $ng->mm->num_for($mid);
 675                 return ($ng, $n) if defined $n;
 676         }
 677         (undef, undef);
 678 }
 679
 680 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 681         my ($self, $xhdr, $range) = @_;
 682
 683         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 684                 my $mid = $1;
 685                 my ($ng, $n) = mid_lookup($self, $mid);
 686                 return r430 unless $n;
 687                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 688                                 xref($self, $ng, $n, $mid));
 689         } else { # numeric range
 690                 $range = $self->{article} unless defined $range;
 691                 my $r = get_range($self, $range);
 692                 return $r unless ref $r;
 693                 my $ng = $self->{ng};
 694                 my $mm = $ng->mm;
 695                 my ($beg, $end) = @$r;
 696                 more($self, $xhdr ? r221 : r225);
 697                 long_response($self, sub {
 698                         my $r = $mm->msg_range(\$beg, $end);
 699                         @$r or return;
 700                         more($self, join("\r\n", map {
 701                                 my $num = $_->[0];
 702                                 "$num ".xref($self, $ng, $num, $_->[1]);
 703                         } @$r));
 704                         1;
 705                 });
 706         }
 707 }
 708
 709 sub search_header_for {
 710         my ($srch, $num, $field) = @_;
 711         my $smsg = $srch->{over_ro}->get_art($num) or return;
 712         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 713         $smsg->{$field};
 714 }
 715
 716 sub hdr_searchmsg ($$$$) {
 717         my ($self, $xhdr, $field, $range) = @_;
 718         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 719                 my ($ng, $n) = mid_lookup($self, $1);
 720                 return r430 unless defined $n;
 721                 my $v = search_header_for($ng->search, $n, $field);
 722                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 723         } else { # numeric range
 724                 $range = $self->{article} unless defined $range;
 725                 my $srch = $self->{ng}->search;
 726                 my $mm = $self->{ng}->mm;
 727                 my $r = get_range($self, $range);
 728                 return $r unless ref $r;
 729                 my ($beg, $end) = @$r;
 730                 more($self, $xhdr ? r221 : r225);
 731                 my $cur = $beg;
 732                 long_response($self, sub {
 733                         my $msgs = $srch->query_xover($cur, $end);
 734                         my $nr = scalar @$msgs or return;
 735                         my $tmp = '';
 736                         foreach my $s (@$msgs) {
 737                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 738                         }
 739                         utf8::encode($tmp);
 740                         do_more($self, $tmp);
 741                         $cur = $msgs->[-1]->{num} + 1;
 742                 });
 743         }
 744 }
 745
 746 sub do_hdr ($$$;$) {
 747         my ($self, $xhdr, $header, $range) = @_;
 748         my $sub = lc $header;
 749         if ($sub eq 'message-id') {
 750                 hdr_message_id($self, $xhdr, $range);
 751         } elsif ($sub eq 'xref') {
 752                 hdr_xref($self, $xhdr, $range);
 753         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 754                                 bytes|lines)\z/x) {
 755                 hdr_searchmsg($self, $xhdr, $sub, $range);
 756         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 757                 hdr_searchmsg($self, $xhdr, $1, $range);
 758         } else {
 759                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 760         }
 761 }
 762
 763 # RFC 3977
 764 sub cmd_hdr ($$;$) {
 765         my ($self, $header, $range) = @_;
 766         do_hdr($self, 0, $header, $range);
 767 }
 768
 769 # RFC 2980
 770 sub cmd_xhdr ($$;$) {
 771         my ($self, $header, $range) = @_;
 772         do_hdr($self, 1, $header, $range);
 773 }
 774
 775 sub hdr_mid_prefix ($$$$$) {
 776         my ($self, $xhdr, $ng, $n, $mid) = @_;
 777         return $mid if $xhdr;
 778
 779         # HDR for RFC 3977 users
 780         if (my $self_ng = $self->{ng}) {
 781                 ($self_ng eq $ng) ? $n : '0';
 782         } else {
 783                 '0';
 784         }
 785 }
 786
 787 sub hdr_mid_response ($$$$$$) {
 788         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 789         my $res = '';
 790         if ($xhdr) {
 791                 $res .= r221 . "\r\n";
 792                 $res .= "$mid $v\r\n";
 793         } else {
 794                 $res .= r225 . "\r\n";
 795                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 796                 $res .= "$pfx $v\r\n";
 797         }
 798         res($self, $res .= '.');
 799         undef;
 800 }
 801
 802 sub cmd_xrover ($;$) {
 803         my ($self, $range) = @_;
 804         my $ng = $self->{ng} or return '412 no newsgroup selected';
 805         (defined $range && $range =~ /[<>]/) and
 806                 return '420 No article(s) selected'; # no message IDs
 807
 808         $range = $self->{article} unless defined $range;
 809         my $r = get_range($self, $range);
 810         return $r unless ref $r;
 811         my ($beg, $end) = @$r;
 812         my $mm = $ng->mm;
 813         my $srch = $ng->search;
 814         more($self, '224 Overview information follows');
 815
 816         long_response($self, sub {
 817                 my $h = search_header_for($srch, $beg, 'references');
 818                 more($self, "$beg $h") if defined($h);
 819                 $beg++ < $end;
 820         });
 821 }
 822
 823 sub over_line ($$$$) {
 824         my ($self, $ng, $num, $smsg) = @_;
 825         # n.b. field access and procedural calls can be
 826         # 10%-15% faster than OO method calls:
 827         my $s = join("\t", $num,
 828                 $smsg->{subject},
 829                 $smsg->{from},
 830                 PublicInbox::SearchMsg::date($smsg),
 831                 "<$smsg->{mid}>",
 832                 $smsg->{references},
 833                 $smsg->{bytes},
 834                 $smsg->{lines},
 835                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 836         utf8::encode($s);
 837         $s
 838 }
 839
 840 sub cmd_over ($;$) {
 841         my ($self, $range) = @_;
 842         if ($range && $range =~ /\A<(.+)>\z/) {
 843                 my ($ng, $n) = mid_lookup($self, $1);
 844                 defined $n or return r430;
 845                 my $smsg = $ng->search->{over_ro}->get_art($n) or return r430;
 846                 more($self, '224 Overview information follows (multi-line)');
 847
 848                 # Only set article number column if it's the current group
 849                 my $self_ng = $self->{ng};
 850                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 851                 more($self, over_line($self, $ng, $n, $smsg));
 852                 '.';
 853         } else {
 854                 cmd_xover($self, $range);
 855         }
 856 }
 857
 858 sub cmd_xover ($;$) {
 859         my ($self, $range) = @_;
 860         $range = $self->{article} unless defined $range;
 861         my $r = get_range($self, $range);
 862         return $r unless ref $r;
 863         my ($beg, $end) = @$r;
 864         more($self, "224 Overview information follows for $beg to $end");
 865         my $srch = $self->{ng}->search;
 866         my $cur = $beg;
 867         long_response($self, sub {
 868                 my $msgs = $srch->query_xover($cur, $end);
 869                 my $nr = scalar @$msgs or return;
 870
 871                 # OVERVIEW.FMT
 872                 more($self, join("\r\n", map {
 873                         over_line($self, $self->{ng}, $_->{num}, $_);
 874                         } @$msgs));
 875                 $cur = $msgs->[-1]->{num} + 1;
 876         });
 877 }
 878
 879 sub cmd_xpath ($$) {
 880         my ($self, $mid) = @_;
 881         return r501 unless $mid =~ /\A<(.+)>\z/;
 882         $mid = $1;
 883         my @paths;
 884         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 885                 my $n = $ng->mm->num_for($mid);
 886                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 887         }
 888         return '430 no such article on server' unless @paths;
 889         '223 '.join(' ', @paths);
 890 }
 891
 892 sub res ($$) {
 893         my ($self, $line) = @_;
 894         do_write($self, $line . "\r\n");
 895 }
 896
 897 sub more ($$) {
 898         my ($self, $line) = @_;
 899         do_more($self, $line . "\r\n");
 900 }
 901
 902 sub do_write ($$) {
 903         my ($self, $data) = @_;
 904         my $done = $self->write($data);
 905         return 0 if $self->{closed};
 906
 907         # Do not watch for readability if we have data in the queue,
 908         # instead re-enable watching for readability when we can
 909         $self->watch_read(0) if (!$done || $self->{long_res});
 910
 911         $done;
 912 }
 913
 914 sub err ($$;@) {
 915         my ($self, $fmt, @args) = @_;
 916         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 917 }
 918
 919 sub out ($$;@) {
 920         my ($self, $fmt, @args) = @_;
 921         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 922 }
 923
 924 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 925
 926 sub do_more ($$) {
 927         my ($self, $data) = @_;
 928         if (MSG_MORE && !$self->{write_buf_size}) {
 929                 my $n = send($self->{sock}, $data, MSG_MORE);
 930                 if (defined $n) {
 931                         my $dlen = length($data);
 932                         return 1 if $n == $dlen; # all done!
 933                         $data = substr($data, $n, $dlen - $n);
 934                 }
 935         }
 936         do_write($self, $data);
 937 }
 938
 939 # callbacks for PublicInbox::DS
 940
 941 sub event_hup { $_[0]->close }
 942 sub event_err { $_[0]->close }
 943
 944 sub event_write {
 945         my ($self) = @_;
 946         update_idle_time($self);
 947         # only continue watching for readability when we are done writing:
 948         if ($self->write(undef) == 1 && !$self->{long_res}) {
 949                 $self->watch_read(1);
 950         }
 951 }
 952
 953 sub event_read {
 954         my ($self) = @_;
 955         use constant LINE_MAX => 512; # RFC 977 section 2.3
 956
 957         if (index($self->{rbuf}, "\n") < 0) {
 958                 my $buf = $self->read(LINE_MAX) or return $self->close;
 959                 $self->{rbuf} .= $$buf;
 960         }
 961         my $r = 1;
 962         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]*)\r?\n//) {
 963                 my $line = $1;
 964                 return $self->close if $line =~ /[[:cntrl:]]/s;
 965                 my $t0 = now();
 966                 my $fd = $self->{fd};
 967                 $r = eval { process_line($self, $line) };
 968                 my $d = $self->{long_res} ?
 969                         " deferred[$fd]" : '';
 970                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 971         }
 972
 973         return $self->close if $r < 0;
 974         my $len = length($self->{rbuf});
 975         return $self->close if ($len >= LINE_MAX);
 976         update_idle_time($self);
 977 }
 978
 979 sub check_read {
 980         my ($self) = @_;
 981         if (index($self->{rbuf}, "\n") >= 0) {
 982                 # Force another read if there is a pipelined request.
 983                 # We don't know if the socket has anything for us to read,
 984                 # and we must double-check again by the time the timer fires
 985                 # in case we really did dispatch a read event and started
 986                 # another long response.
 987                 push @$nextq, $self;
 988                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 989         } else {
 990                 # no pipelined requests available, let the kernel know
 991                 # to wake us up if there's more
 992                 $self->watch_read(1); # PublicInbox::DS::watch_read
 993         }
 994 }
 995
 996 sub not_idle_long ($$) {
 997         my ($self, $now) = @_;
 998         defined(my $fd = $self->{fd}) or return;
 999         my $ary = $EXPMAP->{$fd} or return;
1000         my $exp_at = $ary->[0] + $EXPTIME;
1001         $exp_at > $now;
1002 }
1003
1004 # for graceful shutdown in PublicInbox::Daemon:
1005 sub busy {
1006         my ($self, $now) = @_;
1007         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
1008          not_idle_long($self, $now));
1009 }
1010
1011 1;