lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  38
  39 my $EXPMAP; # fd -> [ idle_time, $self ]
  40 my $expt;
  41 our $EXPTIME = 180; # 3 minutes
  42 my $nextt;
  43
  44 my $nextq = [];
  45 sub next_tick () {
  46         $nextt = undef;
  47         my $q = $nextq;
  48         $nextq = [];
  49         foreach my $nntp (@$q) {
  50                 # for request && response protocols, always finish writing
  51                 # before finishing reading:
  52                 if (my $long_cb = $nntp->{long_res}) {
  53                         $nntp->write($long_cb);
  54                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  55                         event_read($nntp);
  56                 }
  57         }
  58 }
  59
  60 sub update_idle_time ($) {
  61         my ($self) = @_;
  62         my $fd = $self->{fd};
  63         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  64 }
  65
  66 sub expire_old () {
  67         my $now = now();
  68         my $exp = $EXPTIME;
  69         my $old = $now - $exp;
  70         my $nr = 0;
  71         my %new;
  72         while (my ($fd, $v) = each %$EXPMAP) {
  73                 my ($idle_time, $nntp) = @$v;
  74                 if ($idle_time < $old) {
  75                         $nntp->close; # idempotent
  76                 } else {
  77                         ++$nr;
  78                         $new{$fd} = $v;
  79                 }
  80         }
  81         $EXPMAP = \%new;
  82         if ($nr) {
  83                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  84         } else {
  85                 $expt = undef;
  86                 # noop to kick outselves out of the loop ASAP so descriptors
  87                 # really get closed
  88                 PublicInbox::EvCleanup::asap(sub {});
  89         }
  90 }
  91
  92 sub new ($$$) {
  93         my ($class, $sock, $nntpd) = @_;
  94         my $self = fields::new($class);
  95         $self->SUPER::new($sock);
  96         $self->{nntpd} = $nntpd;
  97         res($self, '201 server ready - post via email');
  98         $self->{rbuf} = '';
  99         $self->watch_read(1);
 100         update_idle_time($self);
 101         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 102         $self;
 103 }
 104
 105 sub args_ok ($$) {
 106         my ($cb, $argc) = @_;
 107         my $tot = prototype $cb;
 108         my ($nreq, undef) = split(';', $tot);
 109         $nreq = ($nreq =~ tr/$//) - 1;
 110         $tot = ($tot =~ tr/$//) - 1;
 111         ($argc <= $tot && $argc >= $nreq);
 112 }
 113
 114 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 115 sub process_line ($$) {
 116         my ($self, $l) = @_;
 117         my ($req, @args) = split(/\s+/, $l);
 118         $req = lc($req);
 119         $req = eval {
 120                 no strict 'refs';
 121                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 122         };
 123         return res($self, '500 command not recognized') unless $req;
 124         return res($self, r501) unless args_ok($req, scalar @args);
 125
 126         my $res = eval { $req->($self, @args) };
 127         my $err = $@;
 128         if ($err && !$self->{closed}) {
 129                 local $/ = "\n";
 130                 chomp($l);
 131                 err($self, 'error from: %s (%s)', $l, $err);
 132                 $res = '503 program fault - command not performed';
 133         }
 134         return 0 unless defined $res;
 135         res($self, $res);
 136 }
 137
 138 sub cmd_mode ($$) {
 139         my ($self, $arg) = @_;
 140         $arg = uc $arg;
 141         return r501 unless $arg eq 'READER';
 142         '201 Posting prohibited';
 143 }
 144
 145 sub cmd_slave ($) { '202 slave status noted' }
 146
 147 sub cmd_xgtitle ($;$) {
 148         my ($self, $wildmat) = @_;
 149         more($self, '282 list of groups and descriptions follows');
 150         list_newsgroups($self, $wildmat);
 151         '.'
 152 }
 153
 154 sub list_overview_fmt ($) {
 155         my ($self) = @_;
 156         do_more($self, $OVERVIEW_FMT);
 157 }
 158
 159 sub list_headers ($;$) {
 160         my ($self) = @_;
 161         do_more($self, $LIST_HEADERS);
 162 }
 163
 164 sub list_active ($;$) {
 165         my ($self, $wildmat) = @_;
 166         wildmat2re($wildmat);
 167         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 168                 $ng->{newsgroup} =~ $wildmat or next;
 169                 group_line($self, $ng);
 170         }
 171 }
 172
 173 sub list_active_times ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 my $c = eval { $ng->mm->created_at } || time;
 179                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 180         }
 181 }
 182
 183 sub list_newsgroups ($;$) {
 184         my ($self, $wildmat) = @_;
 185         wildmat2re($wildmat);
 186         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                 $ng->{newsgroup} =~ $wildmat or next;
 188                 my $d = $ng->description;
 189                 more($self, "$ng->{newsgroup} $d");
 190         }
 191 }
 192
 193 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 194 sub cmd_list ($;$$) {
 195         my ($self, @args) = @_;
 196         if (scalar @args) {
 197                 my $arg = shift @args;
 198                 $arg =~ tr/A-Z./a-z_/;
 199                 $arg = "list_$arg";
 200                 return r501 if $DISABLED{$arg};
 201
 202                 $arg = eval {
 203                         no strict 'refs';
 204                         *{$arg}{CODE};
 205                 };
 206                 return r501 unless $arg && args_ok($arg, scalar @args);
 207                 more($self, '215 information follows');
 208                 $arg->($self, @args);
 209         } else {
 210                 more($self, '215 list of newsgroups follows');
 211                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                         group_line($self, $ng);
 213                 }
 214         }
 215         '.'
 216 }
 217
 218 sub cmd_listgroup ($;$) {
 219         my ($self, $group) = @_;
 220         if (defined $group) {
 221                 my $res = cmd_group($self, $group);
 222                 return $res if ($res !~ /\A211 /);
 223                 more($self, $res);
 224         }
 225
 226         $self->{ng} or return '412 no newsgroup selected';
 227         my $n = 0;
 228         long_response($self, 0, long_response_limit, sub {
 229                 my ($i) = @_;
 230                 my $ary = $self->{ng}->mm->ids_after(\$n);
 231                 scalar @$ary or return ($$i = long_response_limit);
 232                 more($self, join("\r\n", @$ary));
 233         });
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my @now = $gmt ? gmtime : localtime;
 244         my ($YYYY, $MM, $DD);
 245         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 246                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 247         } else { # legacy clients send YYMMDD
 248                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my $cur_year = $now[5] + 1900;
 250                 if ($YYYY > $cur_year) {
 251                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 252                 }
 253         }
 254         if ($gmt) {
 255                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 256         } else {
 257                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 258         }
 259 }
 260
 261 sub group_line ($$) {
 262         my ($self, $ng) = @_;
 263         my ($min, $max) = $ng->mm->minmax;
 264         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 265 }
 266
 267 sub cmd_newgroups ($$$;$$) {
 268         my ($self, $date, $time, $gmt, $dists) = @_;
 269         my $ts = eval { parse_time($date, $time, $gmt) };
 270         return r501 if $@;
 271
 272         # TODO dists
 273         more($self, '231 list of new newsgroups follows');
 274         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 275                 my $c = eval { $ng->mm->created_at } || 0;
 276                 next unless $c > $ts;
 277                 group_line($self, $ng);
 278         }
 279         '.'
 280 }
 281
 282 sub wildmat2re (;$) {
 283         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 284         my %keep;
 285         my $salt = rand;
 286         my $tmp = $_[0];
 287
 288         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 289                 my $orig = $1;
 290                 my $key = sha1_hex($orig . $salt);
 291                 $orig =~ s/([^\w\-])+/\Q$1/g;
 292                 $keep{$key} = $orig;
 293                 $key
 294                 #gex;
 295         my %map = ('*' => '.*', '?' => '.' );
 296         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 297         if (scalar %keep) {
 298                 $tmp =~ s#([a-f0-9]{40})#
 299                         my $orig = $keep{$1};
 300                         defined $orig ? $orig : $1;
 301                         #ge;
 302         }
 303         $_[0] = qr/\A$tmp\z/;
 304 }
 305
 306 sub ngpat2re (;$) {
 307         return $_[0] = qr/\A\z/ unless defined $_[0];
 308         my %map = ('*' => '.*', ',' => '|');
 309         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 310         $_[0] = qr/\A(?:$_[0])\z/;
 311 }
 312
 313 sub cmd_newnews ($$$$;$$) {
 314         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 315         my $ts = eval { parse_time($date, $time, $gmt) };
 316         return r501 if $@;
 317         more($self, '230 list of new articles by message-id follows');
 318         my ($keep, $skip) = split('!', $newsgroups, 2);
 319         ngpat2re($keep);
 320         ngpat2re($skip);
 321         my @srch;
 322         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 323                 $ng->{newsgroup} =~ $keep or next;
 324                 $ng->{newsgroup} =~ $skip and next;
 325                 my $srch = $ng->search or next;
 326                 push @srch, $srch;
 327         };
 328         return '.' unless @srch;
 329
 330         my $prev = 0;
 331         long_response($self, 0, long_response_limit, sub {
 332                 my ($i) = @_;
 333                 my $srch = $srch[0];
 334                 my $msgs = $srch->query_ts($ts, $prev);
 335                 if (scalar @$msgs) {
 336                         more($self, '<' .
 337                                 join(">\r\n<", map { $_->mid } @$msgs ).
 338                                 '>');
 339                         $prev = $msgs->[-1]->{num};
 340                 } else {
 341                         shift @srch;
 342                         if (@srch) { # continue onto next newsgroup
 343                                 $prev = 0;
 344                         } else { # break out of the long response.
 345                                 $$i = long_response_limit;
 346                         }
 347                 }
 348         });
 349 }
 350
 351 sub cmd_group ($$) {
 352         my ($self, $group) = @_;
 353         my $no_such = '411 no such news group';
 354         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 355
 356         $self->{ng} = $ng;
 357         my ($min, $max) = $ng->mm->minmax;
 358         $min ||= 0;
 359         $max ||= 0;
 360         $self->{article} = $min;
 361         my $est_size = $max - $min;
 362         "211 $est_size $min $max $group";
 363 }
 364
 365 sub article_adj ($$) {
 366         my ($self, $off) = @_;
 367         my $ng = $self->{ng} or return '412 no newsgroup selected';
 368
 369         my $n = $self->{article};
 370         defined $n or return '420 no current article has been selected';
 371
 372         $n += $off;
 373         my $mid = $ng->mm->mid_for($n);
 374         unless ($mid) {
 375                 $n = $off > 0 ? 'next' : 'previous';
 376                 return "421 no $n article in this group";
 377         }
 378         $self->{article} = $n;
 379         "223 $n <$mid> article retrieved - request text separately";
 380 }
 381
 382 sub cmd_next ($) { article_adj($_[0], 1) }
 383 sub cmd_last ($) { article_adj($_[0], -1) }
 384
 385 # We want to encourage using email and CC-ing everybody involved to avoid
 386 # the single-point-of-failure a single server provides.
 387 sub cmd_post ($) {
 388         my ($self) = @_;
 389         my $ng = $self->{ng};
 390         $ng ? "440 mailto:$ng->{-primary_address} to post"
 391                 : '440 posting not allowed'
 392 }
 393
 394 sub cmd_quit ($) {
 395         my ($self) = @_;
 396         res($self, '205 closing connection - goodbye!');
 397         $self->close;
 398         undef;
 399 }
 400
 401 sub header_append ($$$) {
 402         my ($hdr, $k, $v) = @_;
 403         my @v = $hdr->header($k);
 404         foreach (@v) {
 405                 return if $v eq $_;
 406         }
 407         $hdr->header_set($k, @v, $v);
 408 }
 409
 410 sub set_nntp_headers {
 411         my ($hdr, $ng, $n, $mid) = @_;
 412
 413         # clobber some
 414         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 415         $hdr->header_set('Xref', xref($ng, $n));
 416         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 417         if (my $url = $ng->base_url) {
 418                 $mid = mid_escape($mid);
 419                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 420                 header_append($hdr, 'List-Archive', "<$url>");
 421         }
 422 }
 423
 424 sub art_lookup ($$$) {
 425         my ($self, $art, $set_headers) = @_;
 426         my $ng = $self->{ng};
 427         my ($n, $mid);
 428         my $err;
 429         if (defined $art) {
 430                 if ($art =~ /\A\d+\z/o) {
 431                         $err = '423 no such article number in this group';
 432                         $n = int($art);
 433                         goto find_mid;
 434                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 435                         $mid = $1;
 436                         $err = r430;
 437                         $n = $ng->mm->num_for($mid) if $ng;
 438                         goto found if defined $n;
 439                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 440                                 $n = $g->mm->num_for($mid);
 441                                 if (defined $n) {
 442                                         $ng = $g;
 443                                         goto found;
 444                                 }
 445                         }
 446                         return $err;
 447                 } else {
 448                         return r501;
 449                 }
 450         } else {
 451                 $err = '420 no current article has been selected';
 452                 $n = $self->{article};
 453                 defined $n or return $err;
 454 find_mid:
 455                 $ng or return '412 no newsgroup has been selected';
 456                 $mid = $ng->mm->mid_for($n);
 457                 defined $mid or return $err;
 458         }
 459 found:
 460         my $smsg = $ng->search->{over_ro}->get_art($n) or return $err;
 461         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 462         my $s = Email::Simple->new($msg);
 463         if ($set_headers) {
 464                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 465
 466                 # must be last
 467                 $s->body_set('') if ($set_headers == 2);
 468         }
 469         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 470 }
 471
 472 sub simple_body_write ($$) {
 473         my ($self, $s) = @_;
 474         my $body = $s->body;
 475         $s->body_set('');
 476         $body =~ s/^\./../smg;
 477         $body =~ s/(?<!\r)\n/\r\n/sg;
 478         do_more($self, $body);
 479         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 480         '.'
 481 }
 482
 483 sub set_art {
 484         my ($self, $art) = @_;
 485         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 486 }
 487
 488 sub _header ($) {
 489         my $hdr = $_[0]->header_obj->as_string;
 490         utf8::encode($hdr);
 491         $hdr
 492 }
 493
 494 sub cmd_article ($;$) {
 495         my ($self, $art) = @_;
 496         my $r = art_lookup($self, $art, 1);
 497         return $r unless ref $r;
 498         my ($n, $mid, $s) = @$r;
 499         set_art($self, $art);
 500         more($self, "220 $n <$mid> article retrieved - head and body follow");
 501         do_more($self, _header($s));
 502         do_more($self, "\r\n");
 503         simple_body_write($self, $s);
 504 }
 505
 506 sub cmd_head ($;$) {
 507         my ($self, $art) = @_;
 508         my $r = art_lookup($self, $art, 2);
 509         return $r unless ref $r;
 510         my ($n, $mid, $s) = @$r;
 511         set_art($self, $art);
 512         more($self, "221 $n <$mid> article retrieved - head follows");
 513         do_more($self, _header($s));
 514         '.'
 515 }
 516
 517 sub cmd_body ($;$) {
 518         my ($self, $art) = @_;
 519         my $r = art_lookup($self, $art, 0);
 520         return $r unless ref $r;
 521         my ($n, $mid, $s) = @$r;
 522         set_art($self, $art);
 523         more($self, "222 $n <$mid> article retrieved - body follows");
 524         simple_body_write($self, $s);
 525 }
 526
 527 sub cmd_stat ($;$) {
 528         my ($self, $art) = @_;
 529         my $r = art_lookup($self, $art, 0);
 530         return $r unless ref $r;
 531         my ($n, $mid, undef) = @$r;
 532         set_art($self, $art);
 533         "223 $n <$mid> article retrieved - request text separately";
 534 }
 535
 536 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 537
 538 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 539
 540 sub cmd_help ($) {
 541         my ($self) = @_;
 542         more($self, '100 help text follows');
 543         '.'
 544 }
 545
 546 sub get_range ($$) {
 547         my ($self, $range) = @_;
 548         my $ng = $self->{ng} or return '412 no news group has been selected';
 549         defined $range or return '420 No article(s) selected';
 550         my ($beg, $end);
 551         my ($min, $max) = $ng->mm->minmax;
 552         if ($range =~ /\A(\d+)\z/) {
 553                 $beg = $end = $1;
 554         } elsif ($range =~ /\A(\d+)-\z/) {
 555                 ($beg, $end) = ($1, $max);
 556         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 557                 ($beg, $end) = ($1, $2);
 558         } else {
 559                 return r501;
 560         }
 561         $beg = $min if ($beg < $min);
 562         $end = $max if ($end > $max);
 563         return '420 No article(s) selected' if ($beg > $end);
 564         [ $beg, $end ];
 565 }
 566
 567 sub long_response ($$$$) {
 568         my ($self, $beg, $end, $cb) = @_;
 569         die "BUG: nested long response" if $self->{long_res};
 570
 571         my $fd = $self->{fd};
 572         defined $fd or return;
 573         # make sure we disable reading during a long response,
 574         # clients should not be sending us stuff and making us do more
 575         # work while we are stream a response to them
 576         $self->watch_read(0);
 577         my $t0 = now();
 578         $self->{long_res} = sub {
 579                 # limit our own running time for fairness with other
 580                 # clients and to avoid buffering too much:
 581                 my $lim = $end == long_response_limit ? 1 : 100;
 582
 583                 my $err;
 584                 do {
 585                         eval { $cb->(\$beg) };
 586                 } until (($err = $@) || $self->{closed} ||
 587                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 588
 589                 if ($err || $self->{closed}) {
 590                         $self->{long_res} = undef;
 591
 592                         if ($err) {
 593                                 err($self,
 594                                     "%s during long response[$fd] - %0.6f",
 595                                     $err, now() - $t0);
 596                         }
 597                         if ($self->{closed}) {
 598                                 out($self, " deferred[$fd] aborted - %0.6f",
 599                                            now() - $t0);
 600                         } else {
 601                                 update_idle_time($self);
 602                                 $self->watch_read(1);
 603                         }
 604                 } elsif (!$lim || $self->{write_buf_size}) {
 605                         # no recursion, schedule another call ASAP
 606                         # but only after all pending writes are done
 607                         update_idle_time($self);
 608
 609                         push @$nextq, $self;
 610                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 611                 } else { # all done!
 612                         $self->{long_res} = undef;
 613                         $self->watch_read(1);
 614                         res($self, '.');
 615                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 616                 }
 617         };
 618         $self->{long_res}->(); # kick off!
 619         undef;
 620 }
 621
 622 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 623         my ($self, $xhdr, $range) = @_;
 624
 625         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 626                 my ($ng, $n) = mid_lookup($self, $1);
 627                 return r430 unless $n;
 628                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 629         } else { # numeric range
 630                 $range = $self->{article} unless defined $range;
 631                 my $r = get_range($self, $range);
 632                 return $r unless ref $r;
 633                 my $mm = $self->{ng}->mm;
 634                 my ($beg, $end) = @$r;
 635                 more($self, $xhdr ? r221 : r225);
 636                 long_response($self, $beg, $end, sub {
 637                         my ($i) = @_;
 638                         my $mid = $mm->mid_for($$i);
 639                         more($self, "$$i <$mid>") if defined $mid;
 640                 });
 641         }
 642 }
 643
 644 sub xref ($$) {
 645         my ($ng, $n) = @_;
 646         "$ng->{domain} $ng->{newsgroup}:$n"
 647 }
 648
 649 sub mid_lookup ($$) {
 650         my ($self, $mid) = @_;
 651         my $self_ng = $self->{ng};
 652         if ($self_ng) {
 653                 my $n = $self_ng->mm->num_for($mid);
 654                 return ($self_ng, $n) if defined $n;
 655         }
 656         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 657                 next if defined $self_ng && $ng eq $self_ng;
 658                 my $n = $ng->mm->num_for($mid);
 659                 return ($ng, $n) if defined $n;
 660         }
 661         (undef, undef);
 662 }
 663
 664 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 665         my ($self, $xhdr, $range) = @_;
 666
 667         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 668                 my ($ng, $n) = mid_lookup($self, $1);
 669                 return r430 unless $n;
 670                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 671         } else { # numeric range
 672                 $range = $self->{article} unless defined $range;
 673                 my $r = get_range($self, $range);
 674                 return $r unless ref $r;
 675                 my $ng = $self->{ng};
 676                 my $mm = $ng->mm;
 677                 my ($beg, $end) = @$r;
 678                 more($self, $xhdr ? r221 : r225);
 679                 long_response($self, $beg, $end, sub {
 680                         my ($i) = @_;
 681                         my $mid = $mm->mid_for($$i);
 682                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 683                 });
 684         }
 685 }
 686
 687 sub search_header_for {
 688         my ($srch, $num, $field) = @_;
 689         my $smsg = $srch->{over_ro}->get_art($num) or return;
 690         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 691         $smsg->{$field};
 692 }
 693
 694 sub hdr_searchmsg ($$$$) {
 695         my ($self, $xhdr, $field, $range) = @_;
 696         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 697                 my ($ng, $n) = mid_lookup($self, $1);
 698                 return r430 unless defined $n;
 699                 my $v = search_header_for($ng->search, $n, $field);
 700                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 701         } else { # numeric range
 702                 $range = $self->{article} unless defined $range;
 703                 my $srch = $self->{ng}->search;
 704                 my $mm = $self->{ng}->mm;
 705                 my $r = get_range($self, $range);
 706                 return $r unless ref $r;
 707                 my ($beg, $end) = @$r;
 708                 more($self, $xhdr ? r221 : r225);
 709                 my $cur = $beg;
 710                 long_response($self, 0, long_response_limit, sub {
 711                         my ($i) = @_;
 712                         my $msgs = $srch->query_xover($cur, $end);
 713                         my $nr = scalar @$msgs or
 714                                         return ($$i = long_response_limit);
 715                         my $tmp = '';
 716                         foreach my $s (@$msgs) {
 717                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 718                         }
 719                         utf8::encode($tmp);
 720                         do_more($self, $tmp);
 721                         $cur = $msgs->[-1]->{num} + 1;
 722                 });
 723         }
 724 }
 725
 726 sub do_hdr ($$$;$) {
 727         my ($self, $xhdr, $header, $range) = @_;
 728         my $sub = lc $header;
 729         if ($sub eq 'message-id') {
 730                 hdr_message_id($self, $xhdr, $range);
 731         } elsif ($sub eq 'xref') {
 732                 hdr_xref($self, $xhdr, $range);
 733         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 734                                 bytes|lines)\z/x) {
 735                 hdr_searchmsg($self, $xhdr, $sub, $range);
 736         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 737                 hdr_searchmsg($self, $xhdr, $1, $range);
 738         } else {
 739                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 740         }
 741 }
 742
 743 # RFC 3977
 744 sub cmd_hdr ($$;$) {
 745         my ($self, $header, $range) = @_;
 746         do_hdr($self, 0, $header, $range);
 747 }
 748
 749 # RFC 2980
 750 sub cmd_xhdr ($$;$) {
 751         my ($self, $header, $range) = @_;
 752         do_hdr($self, 1, $header, $range);
 753 }
 754
 755 sub hdr_mid_prefix ($$$$$) {
 756         my ($self, $xhdr, $ng, $n, $mid) = @_;
 757         return $mid if $xhdr;
 758
 759         # HDR for RFC 3977 users
 760         if (my $self_ng = $self->{ng}) {
 761                 ($self_ng eq $ng) ? $n : '0';
 762         } else {
 763                 '0';
 764         }
 765 }
 766
 767 sub hdr_mid_response ($$$$$$) {
 768         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 769         my $res = '';
 770         if ($xhdr) {
 771                 $res .= r221 . "\r\n";
 772                 $res .= "$mid $v\r\n";
 773         } else {
 774                 $res .= r225 . "\r\n";
 775                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 776                 $res .= "$pfx $v\r\n";
 777         }
 778         res($self, $res .= '.');
 779         undef;
 780 }
 781
 782 sub cmd_xrover ($;$) {
 783         my ($self, $range) = @_;
 784         my $ng = $self->{ng} or return '412 no newsgroup selected';
 785         (defined $range && $range =~ /[<>]/) and
 786                 return '420 No article(s) selected'; # no message IDs
 787
 788         $range = $self->{article} unless defined $range;
 789         my $r = get_range($self, $range);
 790         return $r unless ref $r;
 791         my ($beg, $end) = @$r;
 792         my $mm = $ng->mm;
 793         my $srch = $ng->search;
 794         more($self, '224 Overview information follows');
 795         long_response($self, $beg, $end, sub {
 796                 my ($i) = @_;
 797                 my $num = $$i;
 798                 my $h = search_header_for($srch, $num, 'references');
 799                 defined $h or return;
 800                 more($self, "$num $h");
 801         });
 802 }
 803
 804 sub over_line ($$) {
 805         my ($num, $smsg) = @_;
 806         # n.b. field access and procedural calls can be
 807         # 10%-15% faster than OO method calls:
 808         my $s = join("\t", $num,
 809                 $smsg->{subject},
 810                 $smsg->{from},
 811                 PublicInbox::SearchMsg::date($smsg),
 812                 "<$smsg->{mid}>",
 813                 $smsg->{references},
 814                 $smsg->{bytes},
 815                 $smsg->{lines});
 816         utf8::encode($s);
 817         $s
 818 }
 819
 820 sub cmd_over ($;$) {
 821         my ($self, $range) = @_;
 822         if ($range && $range =~ /\A<(.+)>\z/) {
 823                 my ($ng, $n) = mid_lookup($self, $1);
 824                 defined $n or return r430;
 825                 my $smsg = $ng->search->{over_ro}->get_art($n) or return r430;
 826                 more($self, '224 Overview information follows (multi-line)');
 827
 828                 # Only set article number column if it's the current group
 829                 my $self_ng = $self->{ng};
 830                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 831                 more($self, over_line($n, $smsg));
 832                 '.';
 833         } else {
 834                 cmd_xover($self, $range);
 835         }
 836 }
 837
 838 sub cmd_xover ($;$) {
 839         my ($self, $range) = @_;
 840         $range = $self->{article} unless defined $range;
 841         my $r = get_range($self, $range);
 842         return $r unless ref $r;
 843         my ($beg, $end) = @$r;
 844         more($self, "224 Overview information follows for $beg to $end");
 845         my $srch = $self->{ng}->search;
 846         my $cur = $beg;
 847         long_response($self, 0, long_response_limit, sub {
 848                 my ($i) = @_;
 849                 my $msgs = $srch->query_xover($cur, $end);
 850                 my $nr = scalar @$msgs or return ($$i = long_response_limit);
 851
 852                 # OVERVIEW.FMT
 853                 more($self, join("\r\n", map {
 854                         over_line($_->{num}, $_);
 855                         } @$msgs));
 856                 $cur = $msgs->[-1]->{num} + 1;
 857                 1;
 858         });
 859 }
 860
 861 sub cmd_xpath ($$) {
 862         my ($self, $mid) = @_;
 863         return r501 unless $mid =~ /\A<(.+)>\z/;
 864         $mid = $1;
 865         my @paths;
 866         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 867                 my $n = $ng->mm->num_for($mid);
 868                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 869         }
 870         return '430 no such article on server' unless @paths;
 871         '223 '.join(' ', @paths);
 872 }
 873
 874 sub res ($$) {
 875         my ($self, $line) = @_;
 876         do_write($self, $line . "\r\n");
 877 }
 878
 879 sub more ($$) {
 880         my ($self, $line) = @_;
 881         do_more($self, $line . "\r\n");
 882 }
 883
 884 sub do_write ($$) {
 885         my ($self, $data) = @_;
 886         my $done = $self->write($data);
 887         return if $self->{closed};
 888
 889         # Do not watch for readability if we have data in the queue,
 890         # instead re-enable watching for readability when we can
 891         $self->watch_read(0) if (!$done || $self->{long_res});
 892
 893         $done;
 894 }
 895
 896 sub err ($$;@) {
 897         my ($self, $fmt, @args) = @_;
 898         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 899 }
 900
 901 sub out ($$;@) {
 902         my ($self, $fmt, @args) = @_;
 903         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 904 }
 905
 906 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 907
 908 sub do_more ($$) {
 909         my ($self, $data) = @_;
 910         if (MSG_MORE && !$self->{write_buf_size}) {
 911                 my $n = send($self->{sock}, $data, MSG_MORE);
 912                 if (defined $n) {
 913                         my $dlen = length($data);
 914                         return 1 if $n == $dlen; # all done!
 915                         $data = substr($data, $n, $dlen - $n);
 916                 }
 917         }
 918         do_write($self, $data);
 919 }
 920
 921 # callbacks for Danga::Socket
 922
 923 sub event_hup { $_[0]->close }
 924 sub event_err { $_[0]->close }
 925
 926 sub event_write {
 927         my ($self) = @_;
 928         update_idle_time($self);
 929         # only continue watching for readability when we are done writing:
 930         if ($self->write(undef) == 1 && !$self->{long_res}) {
 931                 $self->watch_read(1);
 932         }
 933 }
 934
 935 sub event_read {
 936         my ($self) = @_;
 937         use constant LINE_MAX => 512; # RFC 977 section 2.3
 938         my $r = 1;
 939
 940         my $buf = $self->read(LINE_MAX) or return $self->close;
 941         $self->{rbuf} .= $$buf;
 942         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 943                 my $line = $1;
 944                 return $self->close if $line =~ /[[:cntrl:]]/s;
 945                 my $t0 = now();
 946                 my $fd = $self->{fd};
 947                 $r = eval { process_line($self, $line) };
 948                 my $d = $self->{long_res} ?
 949                         " deferred[$fd]" : '';
 950                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 951         }
 952
 953         return $self->close if $r < 0;
 954         my $len = length($self->{rbuf});
 955         return $self->close if ($len >= LINE_MAX);
 956         update_idle_time($self);
 957 }
 958
 959 sub watch_read {
 960         my ($self, $bool) = @_;
 961         my $rv = $self->SUPER::watch_read($bool);
 962         if ($bool && $self->{rbuf} ne '') {
 963                 # Force another read if there is a pipelined request.
 964                 # We don't know if the socket has anything for us to read,
 965                 # and we must double-check again by the time the timer fires
 966                 # in case we really did dispatch a read event and started
 967                 # another long response.
 968                 push @$nextq, $self;
 969                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 970         }
 971         $rv;
 972 }
 973
 974 sub not_idle_long ($$) {
 975         my ($self, $now) = @_;
 976         defined(my $fd = $self->{fd}) or return;
 977         my $ary = $EXPMAP->{$fd} or return;
 978         my $exp_at = $ary->[0] + $EXPTIME;
 979         $exp_at > $now;
 980 }
 981
 982 # for graceful shutdown in PublicInbox::Daemon:
 983 sub busy {
 984         my ($self, $now) = @_;
 985         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
 986          not_idle_long($self, $now));
 987 }
 988
 989 1;