lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 # LISTGROUP could get pretty bad, too...
  38 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  39
  40 my $EXPMAP; # fd -> [ idle_time, $self ]
  41 my $expt;
  42 our $EXPTIME = 180; # 3 minutes
  43 my $nextt;
  44
  45 my $nextq = [];
  46 sub next_tick () {
  47         $nextt = undef;
  48         my $q = $nextq;
  49         $nextq = [];
  50         foreach my $nntp (@$q) {
  51                 # for request && response protocols, always finish writing
  52                 # before finishing reading:
  53                 if (my $long_cb = $nntp->{long_res}) {
  54                         $nntp->write($long_cb);
  55                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  56                         event_read($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub update_idle_time ($) {
  62         my ($self) = @_;
  63         my $fd = $self->{fd};
  64         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  65 }
  66
  67 sub expire_old () {
  68         my $now = now();
  69         my $exp = $EXPTIME;
  70         my $old = $now - $exp;
  71         my $nr = 0;
  72         my %new;
  73         while (my ($fd, $v) = each %$EXPMAP) {
  74                 my ($idle_time, $nntp) = @$v;
  75                 if ($idle_time < $old) {
  76                         $nntp->close; # idempotent
  77                 } else {
  78                         ++$nr;
  79                         $new{$fd} = $v;
  80                 }
  81         }
  82         $EXPMAP = \%new;
  83         if ($nr) {
  84                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  85         } else {
  86                 $expt = undef;
  87                 # noop to kick outselves out of the loop ASAP so descriptors
  88                 # really get closed
  89                 PublicInbox::EvCleanup::asap(sub {});
  90         }
  91 }
  92
  93 sub new ($$$) {
  94         my ($class, $sock, $nntpd) = @_;
  95         my $self = fields::new($class);
  96         $self->SUPER::new($sock);
  97         $self->{nntpd} = $nntpd;
  98         res($self, '201 server ready - post via email');
  99         $self->{rbuf} = '';
 100         $self->watch_read(1);
 101         update_idle_time($self);
 102         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 103         $self;
 104 }
 105
 106 sub args_ok ($$) {
 107         my ($cb, $argc) = @_;
 108         my $tot = prototype $cb;
 109         my ($nreq, undef) = split(';', $tot);
 110         $nreq = ($nreq =~ tr/$//) - 1;
 111         $tot = ($tot =~ tr/$//) - 1;
 112         ($argc <= $tot && $argc >= $nreq);
 113 }
 114
 115 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 116 sub process_line ($$) {
 117         my ($self, $l) = @_;
 118         my ($req, @args) = split(/\s+/, $l);
 119         return unless defined($req);
 120         $req = lc($req);
 121         $req = eval {
 122                 no strict 'refs';
 123                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 124         };
 125         return res($self, '500 command not recognized') unless $req;
 126         return res($self, r501) unless args_ok($req, scalar @args);
 127
 128         my $res = eval { $req->($self, @args) };
 129         my $err = $@;
 130         if ($err && !$self->{closed}) {
 131                 local $/ = "\n";
 132                 chomp($l);
 133                 err($self, 'error from: %s (%s)', $l, $err);
 134                 $res = '503 program fault - command not performed';
 135         }
 136         return 0 unless defined $res;
 137         res($self, $res);
 138 }
 139
 140 sub cmd_mode ($$) {
 141         my ($self, $arg) = @_;
 142         $arg = uc $arg;
 143         return r501 unless $arg eq 'READER';
 144         '201 Posting prohibited';
 145 }
 146
 147 sub cmd_slave ($) { '202 slave status noted' }
 148
 149 sub cmd_xgtitle ($;$) {
 150         my ($self, $wildmat) = @_;
 151         more($self, '282 list of groups and descriptions follows');
 152         list_newsgroups($self, $wildmat);
 153         '.'
 154 }
 155
 156 sub list_overview_fmt ($) {
 157         my ($self) = @_;
 158         do_more($self, $OVERVIEW_FMT);
 159 }
 160
 161 sub list_headers ($;$) {
 162         my ($self) = @_;
 163         do_more($self, $LIST_HEADERS);
 164 }
 165
 166 sub list_active ($;$) {
 167         my ($self, $wildmat) = @_;
 168         wildmat2re($wildmat);
 169         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 170                 $ng->{newsgroup} =~ $wildmat or next;
 171                 group_line($self, $ng);
 172         }
 173 }
 174
 175 sub list_active_times ($;$) {
 176         my ($self, $wildmat) = @_;
 177         wildmat2re($wildmat);
 178         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 179                 $ng->{newsgroup} =~ $wildmat or next;
 180                 my $c = eval { $ng->mm->created_at } || time;
 181                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 182         }
 183 }
 184
 185 sub list_newsgroups ($;$) {
 186         my ($self, $wildmat) = @_;
 187         wildmat2re($wildmat);
 188         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 189                 $ng->{newsgroup} =~ $wildmat or next;
 190                 my $d = $ng->description;
 191                 more($self, "$ng->{newsgroup} $d");
 192         }
 193 }
 194
 195 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 196 sub cmd_list ($;$$) {
 197         my ($self, @args) = @_;
 198         if (scalar @args) {
 199                 my $arg = shift @args;
 200                 $arg =~ tr/A-Z./a-z_/;
 201                 $arg = "list_$arg";
 202                 return r501 if $DISABLED{$arg};
 203
 204                 $arg = eval {
 205                         no strict 'refs';
 206                         *{$arg}{CODE};
 207                 };
 208                 return r501 unless $arg && args_ok($arg, scalar @args);
 209                 more($self, '215 information follows');
 210                 $arg->($self, @args);
 211         } else {
 212                 more($self, '215 list of newsgroups follows');
 213                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 214                         group_line($self, $ng);
 215                 }
 216         }
 217         '.'
 218 }
 219
 220 sub cmd_listgroup ($;$) {
 221         my ($self, $group) = @_;
 222         if (defined $group) {
 223                 my $res = cmd_group($self, $group);
 224                 return $res if ($res !~ /\A211 /);
 225                 more($self, $res);
 226         }
 227
 228         $self->{ng} or return '412 no newsgroup selected';
 229         long_response($self, 0, long_response_limit, sub {
 230                 my ($i) = @_;
 231                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 232                         my ($ary) = @_;
 233                         more($self, join("\r\n", @$ary));
 234                 });
 235
 236                 # -1 to adjust for implicit increment in long_response
 237                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 238         });
 239 }
 240
 241 sub parse_time ($$;$) {
 242         my ($date, $time, $gmt) = @_;
 243         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 244         if (defined $gmt) {
 245                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 246                 $gmt = 1;
 247         }
 248         my @now = $gmt ? gmtime : localtime;
 249         my ($YYYY, $MM, $DD);
 250         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 251                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 252         } else { # legacy clients send YYMMDD
 253                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 254                 my $cur_year = $now[5] + 1900;
 255                 if ($YYYY > $cur_year) {
 256                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 257                 }
 258         }
 259         if ($gmt) {
 260                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 261         } else {
 262                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 263         }
 264 }
 265
 266 sub group_line ($$) {
 267         my ($self, $ng) = @_;
 268         my ($min, $max) = $ng->mm->minmax;
 269         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 270 }
 271
 272 sub cmd_newgroups ($$$;$$) {
 273         my ($self, $date, $time, $gmt, $dists) = @_;
 274         my $ts = eval { parse_time($date, $time, $gmt) };
 275         return r501 if $@;
 276
 277         # TODO dists
 278         more($self, '231 list of new newsgroups follows');
 279         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 280                 my $c = eval { $ng->mm->created_at } || 0;
 281                 next unless $c > $ts;
 282                 group_line($self, $ng);
 283         }
 284         '.'
 285 }
 286
 287 sub wildmat2re (;$) {
 288         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 289         my %keep;
 290         my $salt = rand;
 291         my $tmp = $_[0];
 292
 293         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 294                 my $orig = $1;
 295                 my $key = sha1_hex($orig . $salt);
 296                 $orig =~ s/([^\w\-])+/\Q$1/g;
 297                 $keep{$key} = $orig;
 298                 $key
 299                 #gex;
 300         my %map = ('*' => '.*', '?' => '.' );
 301         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 302         if (scalar %keep) {
 303                 $tmp =~ s#([a-f0-9]{40})#
 304                         my $orig = $keep{$1};
 305                         defined $orig ? $orig : $1;
 306                         #ge;
 307         }
 308         $_[0] = qr/\A$tmp\z/;
 309 }
 310
 311 sub ngpat2re (;$) {
 312         return $_[0] = qr/\A\z/ unless defined $_[0];
 313         my %map = ('*' => '.*', ',' => '|');
 314         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 315         $_[0] = qr/\A(?:$_[0])\z/;
 316 }
 317
 318 sub cmd_newnews ($$$$;$$) {
 319         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 320         my $ts = eval { parse_time($date, $time, $gmt) };
 321         return r501 if $@;
 322         more($self, '230 list of new articles by message-id follows');
 323         my ($keep, $skip) = split('!', $newsgroups, 2);
 324         ngpat2re($keep);
 325         ngpat2re($skip);
 326         my @srch;
 327         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 328                 $ng->{newsgroup} =~ $keep or next;
 329                 $ng->{newsgroup} =~ $skip and next;
 330                 my $srch = $ng->search or next;
 331                 push @srch, $srch;
 332         };
 333         return '.' unless @srch;
 334
 335         $ts .= '..';
 336         my $opts = { asc => 1, limit => 1000, offset => 0 };
 337         long_response($self, 0, long_response_limit, sub {
 338                 my ($i) = @_;
 339                 my $srch = $srch[0];
 340                 my $res = $srch->query_ts($ts, $opts);
 341                 my $msgs = $res->{msgs};
 342                 if (my $nr = scalar @$msgs) {
 343                         more($self, '<' .
 344                                 join(">\r\n<", map { $_->mid } @$msgs ).
 345                                 '>');
 346                         $opts->{offset} += $nr;
 347                 } else {
 348                         shift @srch;
 349                         if (@srch) { # continue onto next newsgroup
 350                                 $opts->{offset} = 0;
 351                         } else { # break out of the long response.
 352                                 $$i = long_response_limit;
 353                         }
 354                 }
 355         });
 356 }
 357
 358 sub cmd_group ($$) {
 359         my ($self, $group) = @_;
 360         my $no_such = '411 no such news group';
 361         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 362
 363         $self->{ng} = $ng;
 364         my ($min, $max) = $ng->mm->minmax;
 365         $min ||= 0;
 366         $max ||= 0;
 367         $self->{article} = $min;
 368         my $est_size = $max - $min;
 369         "211 $est_size $min $max $group";
 370 }
 371
 372 sub article_adj ($$) {
 373         my ($self, $off) = @_;
 374         my $ng = $self->{ng} or return '412 no newsgroup selected';
 375
 376         my $n = $self->{article};
 377         defined $n or return '420 no current article has been selected';
 378
 379         $n += $off;
 380         my $mid = $ng->mm->mid_for($n);
 381         unless ($mid) {
 382                 $n = $off > 0 ? 'next' : 'previous';
 383                 return "421 no $n article in this group";
 384         }
 385         $self->{article} = $n;
 386         "223 $n <$mid> article retrieved - request text separately";
 387 }
 388
 389 sub cmd_next ($) { article_adj($_[0], 1) }
 390 sub cmd_last ($) { article_adj($_[0], -1) }
 391
 392 # We want to encourage using email and CC-ing everybody involved to avoid
 393 # the single-point-of-failure a single server provides.
 394 sub cmd_post ($) {
 395         my ($self) = @_;
 396         my $ng = $self->{ng};
 397         $ng ? "440 mailto:$ng->{-primary_address} to post"
 398                 : '440 posting not allowed'
 399 }
 400
 401 sub cmd_quit ($) {
 402         my ($self) = @_;
 403         res($self, '205 closing connection - goodbye!');
 404         $self->close;
 405         undef;
 406 }
 407
 408 sub header_append ($$$) {
 409         my ($hdr, $k, $v) = @_;
 410         my @v = $hdr->header($k);
 411         foreach (@v) {
 412                 return if $v eq $_;
 413         }
 414         $hdr->header_set($k, @v, $v);
 415 }
 416
 417 sub set_nntp_headers {
 418         my ($hdr, $ng, $n, $mid) = @_;
 419
 420         # clobber some
 421         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 422         $hdr->header_set('Xref', xref($ng, $n));
 423         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 424         if (my $url = $ng->base_url) {
 425                 $mid = mid_escape($mid);
 426                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 427                 header_append($hdr, 'List-Archive', "<$url>");
 428         }
 429 }
 430
 431 sub art_lookup ($$$) {
 432         my ($self, $art, $set_headers) = @_;
 433         my $ng = $self->{ng};
 434         my ($n, $mid);
 435         my $err;
 436         if (defined $art) {
 437                 if ($art =~ /\A\d+\z/o) {
 438                         $err = '423 no such article number in this group';
 439                         $n = int($art);
 440                         goto find_mid;
 441                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 442                         $mid = $1;
 443                         $err = r430;
 444                         $n = $ng->mm->num_for($mid) if $ng;
 445                         goto found if defined $n;
 446                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 447                                 $n = $g->mm->num_for($mid);
 448                                 if (defined $n) {
 449                                         $ng = $g;
 450                                         goto found;
 451                                 }
 452                         }
 453                         return $err;
 454                 } else {
 455                         return r501;
 456                 }
 457         } else {
 458                 $err = '420 no current article has been selected';
 459                 $n = $self->{article};
 460                 defined $n or return $err;
 461 find_mid:
 462                 $ng or return '412 no newsgroup has been selected';
 463                 $mid = $ng->mm->mid_for($n);
 464                 defined $mid or return $err;
 465         }
 466 found:
 467         my $bytes;
 468         my $s = eval { $ng->msg_by_mid($mid, \$bytes) } or return $err;
 469         $s = Email::Simple->new($s);
 470         my $lines;
 471         if ($set_headers) {
 472                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 473                 $lines = $s->body =~ tr!\n!\n!;
 474
 475                 # must be last
 476                 $s->body_set('') if ($set_headers == 2);
 477         }
 478         [ $n, $mid, $s, $bytes, $lines, $ng ];
 479 }
 480
 481 sub simple_body_write ($$) {
 482         my ($self, $s) = @_;
 483         my $body = $s->body;
 484         $s->body_set('');
 485         $body =~ s/^\./../smg;
 486         $body =~ s/(?<!\r)\n/\r\n/sg;
 487         do_more($self, $body);
 488         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 489         '.'
 490 }
 491
 492 sub set_art {
 493         my ($self, $art) = @_;
 494         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 495 }
 496
 497 sub _header ($) {
 498         my $hdr = $_[0]->header_obj->as_string;
 499         utf8::encode($hdr);
 500         $hdr
 501 }
 502
 503 sub cmd_article ($;$) {
 504         my ($self, $art) = @_;
 505         my $r = art_lookup($self, $art, 1);
 506         return $r unless ref $r;
 507         my ($n, $mid, $s) = @$r;
 508         set_art($self, $art);
 509         more($self, "220 $n <$mid> article retrieved - head and body follow");
 510         do_more($self, _header($s));
 511         do_more($self, "\r\n");
 512         simple_body_write($self, $s);
 513 }
 514
 515 sub cmd_head ($;$) {
 516         my ($self, $art) = @_;
 517         my $r = art_lookup($self, $art, 2);
 518         return $r unless ref $r;
 519         my ($n, $mid, $s) = @$r;
 520         set_art($self, $art);
 521         more($self, "221 $n <$mid> article retrieved - head follows");
 522         do_more($self, _header($s));
 523         '.'
 524 }
 525
 526 sub cmd_body ($;$) {
 527         my ($self, $art) = @_;
 528         my $r = art_lookup($self, $art, 0);
 529         return $r unless ref $r;
 530         my ($n, $mid, $s) = @$r;
 531         set_art($self, $art);
 532         more($self, "222 $n <$mid> article retrieved - body follows");
 533         simple_body_write($self, $s);
 534 }
 535
 536 sub cmd_stat ($;$) {
 537         my ($self, $art) = @_;
 538         my $r = art_lookup($self, $art, 0);
 539         return $r unless ref $r;
 540         my ($n, $mid, undef) = @$r;
 541         set_art($self, $art);
 542         "223 $n <$mid> article retrieved - request text separately";
 543 }
 544
 545 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 546
 547 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 548
 549 sub cmd_help ($) {
 550         my ($self) = @_;
 551         more($self, '100 help text follows');
 552         '.'
 553 }
 554
 555 sub get_range ($$) {
 556         my ($self, $range) = @_;
 557         my $ng = $self->{ng} or return '412 no news group has been selected';
 558         defined $range or return '420 No article(s) selected';
 559         my ($beg, $end);
 560         my ($min, $max) = $ng->mm->minmax;
 561         if ($range =~ /\A(\d+)\z/) {
 562                 $beg = $end = $1;
 563         } elsif ($range =~ /\A(\d+)-\z/) {
 564                 ($beg, $end) = ($1, $max);
 565         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 566                 ($beg, $end) = ($1, $2);
 567         } else {
 568                 return r501;
 569         }
 570         $beg = $min if ($beg < $min);
 571         $end = $max if ($end > $max);
 572         return '420 No article(s) selected' if ($beg > $end);
 573         [ $beg, $end ];
 574 }
 575
 576 sub long_response ($$$$) {
 577         my ($self, $beg, $end, $cb) = @_;
 578         die "BUG: nested long response" if $self->{long_res};
 579
 580         my $fd = $self->{fd};
 581         defined $fd or return;
 582         # make sure we disable reading during a long response,
 583         # clients should not be sending us stuff and making us do more
 584         # work while we are stream a response to them
 585         $self->watch_read(0);
 586         my $t0 = now();
 587         $self->{long_res} = sub {
 588                 # limit our own running time for fairness with other
 589                 # clients and to avoid buffering too much:
 590                 my $lim = 100;
 591
 592                 my $err;
 593                 do {
 594                         eval { $cb->(\$beg, \$lim) };
 595                 } until (($err = $@) || $self->{closed} ||
 596                          ++$beg > $end || --$lim < 0 ||
 597                          $self->{write_buf_size});
 598
 599                 if ($err || $self->{closed}) {
 600                         $self->{long_res} = undef;
 601
 602                         if ($err) {
 603                                 err($self,
 604                                     "%s during long response[$fd] - %0.6f",
 605                                     $err, now() - $t0);
 606                         }
 607                         if ($self->{closed}) {
 608                                 out($self, " deferred[$fd] aborted - %0.6f",
 609                                            now() - $t0);
 610                         } else {
 611                                 update_idle_time($self);
 612                                 $self->watch_read(1);
 613                         }
 614                 } elsif ($lim < 0 || $self->{write_buf_size}) {
 615                         # no recursion, schedule another call ASAP
 616                         # but only after all pending writes are done
 617                         update_idle_time($self);
 618
 619                         push @$nextq, $self;
 620                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 621                 } else { # all done!
 622                         $self->{long_res} = undef;
 623                         $self->watch_read(1);
 624                         res($self, '.');
 625                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 626                 }
 627         };
 628         $self->{long_res}->(); # kick off!
 629         undef;
 630 }
 631
 632 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 633         my ($self, $xhdr, $range) = @_;
 634
 635         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 636                 my ($ng, $n) = mid_lookup($self, $1);
 637                 return r430 unless $n;
 638                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 639         } else { # numeric range
 640                 $range = $self->{article} unless defined $range;
 641                 my $r = get_range($self, $range);
 642                 return $r unless ref $r;
 643                 my $mm = $self->{ng}->mm;
 644                 my ($beg, $end) = @$r;
 645                 more($self, $xhdr ? r221 : r225);
 646                 long_response($self, $beg, $end, sub {
 647                         my ($i) = @_;
 648                         my $mid = $mm->mid_for($$i);
 649                         more($self, "$$i <$mid>") if defined $mid;
 650                 });
 651         }
 652 }
 653
 654 sub xref ($$) {
 655         my ($ng, $n) = @_;
 656         "$ng->{domain} $ng->{newsgroup}:$n"
 657 }
 658
 659 sub mid_lookup ($$) {
 660         my ($self, $mid) = @_;
 661         my $self_ng = $self->{ng};
 662         if ($self_ng) {
 663                 my $n = $self_ng->mm->num_for($mid);
 664                 return ($self_ng, $n) if defined $n;
 665         }
 666         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 667                 next if defined $self_ng && $ng eq $self_ng;
 668                 my $n = $ng->mm->num_for($mid);
 669                 return ($ng, $n) if defined $n;
 670         }
 671         (undef, undef);
 672 }
 673
 674 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 675         my ($self, $xhdr, $range) = @_;
 676
 677         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 678                 my ($ng, $n) = mid_lookup($self, $1);
 679                 return r430 unless $n;
 680                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 681         } else { # numeric range
 682                 $range = $self->{article} unless defined $range;
 683                 my $r = get_range($self, $range);
 684                 return $r unless ref $r;
 685                 my $ng = $self->{ng};
 686                 my $mm = $ng->mm;
 687                 my ($beg, $end) = @$r;
 688                 more($self, $xhdr ? r221 : r225);
 689                 long_response($self, $beg, $end, sub {
 690                         my ($i) = @_;
 691                         my $mid = $mm->mid_for($$i);
 692                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 693                 });
 694         }
 695 }
 696
 697 sub search_header_for {
 698         my ($srch, $mid, $field) = @_;
 699         my $smsg = $srch->lookup_mail($mid) or return;
 700         $smsg->$field;
 701 }
 702
 703 sub hdr_searchmsg ($$$$) {
 704         my ($self, $xhdr, $field, $range) = @_;
 705         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 706                 my ($ng, $n) = mid_lookup($self, $1);
 707                 return r430 unless $n;
 708                 my $v = search_header_for($ng->search, $range, $field);
 709                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 710         } else { # numeric range
 711                 $range = $self->{article} unless defined $range;
 712                 my $srch = $self->{ng}->search;
 713                 my $mm = $self->{ng}->mm;
 714                 my $r = get_range($self, $range);
 715                 return $r unless ref $r;
 716                 my ($beg, $end) = @$r;
 717                 more($self, $xhdr ? r221 : r225);
 718                 my $off = 0;
 719                 long_response($self, $beg, $end, sub {
 720                         my ($i, $lim) = @_;
 721                         my $res = $srch->query_xover($beg, $end, $off);
 722                         my $msgs = $res->{msgs};
 723                         my $nr = scalar @$msgs or return;
 724                         $off += $nr;
 725                         $$lim -= $nr;
 726                         my $tmp = '';
 727                         foreach my $s (@$msgs) {
 728                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 729                         }
 730                         utf8::encode($tmp);
 731                         do_more($self, $tmp);
 732                         # -1 to adjust for implicit increment in long_response
 733                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 734                 });
 735         }
 736 }
 737
 738 sub do_hdr ($$$;$) {
 739         my ($self, $xhdr, $header, $range) = @_;
 740         my $sub = lc $header;
 741         if ($sub eq 'message-id') {
 742                 hdr_message_id($self, $xhdr, $range);
 743         } elsif ($sub eq 'xref') {
 744                 hdr_xref($self, $xhdr, $range);
 745         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 746                                 bytes|lines)\z/x) {
 747                 hdr_searchmsg($self, $xhdr, $sub, $range);
 748         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 749                 hdr_searchmsg($self, $xhdr, $1, $range);
 750         } else {
 751                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 752         }
 753 }
 754
 755 # RFC 3977
 756 sub cmd_hdr ($$;$) {
 757         my ($self, $header, $range) = @_;
 758         do_hdr($self, 0, $header, $range);
 759 }
 760
 761 # RFC 2980
 762 sub cmd_xhdr ($$;$) {
 763         my ($self, $header, $range) = @_;
 764         do_hdr($self, 1, $header, $range);
 765 }
 766
 767 sub hdr_mid_prefix ($$$$$) {
 768         my ($self, $xhdr, $ng, $n, $mid) = @_;
 769         return $mid if $xhdr;
 770
 771         # HDR for RFC 3977 users
 772         if (my $self_ng = $self->{ng}) {
 773                 ($self_ng eq $ng) ? $n : '0';
 774         } else {
 775                 '0';
 776         }
 777 }
 778
 779 sub hdr_mid_response ($$$$$$) {
 780         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 781         my $res = '';
 782         if ($xhdr) {
 783                 $res .= r221 . "\r\n";
 784                 $res .= "$mid $v\r\n";
 785         } else {
 786                 $res .= r225 . "\r\n";
 787                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 788                 $res .= "$pfx $v\r\n";
 789         }
 790         res($self, $res .= '.');
 791         undef;
 792 }
 793
 794 sub cmd_xrover ($;$) {
 795         my ($self, $range) = @_;
 796         my $ng = $self->{ng} or return '412 no newsgroup selected';
 797         (defined $range && $range =~ /[<>]/) and
 798                 return '420 No article(s) selected'; # no message IDs
 799
 800         $range = $self->{article} unless defined $range;
 801         my $r = get_range($self, $range);
 802         return $r unless ref $r;
 803         my ($beg, $end) = @$r;
 804         my $mm = $ng->mm;
 805         my $srch = $ng->search;
 806         more($self, '224 Overview information follows');
 807         long_response($self, $beg, $end, sub {
 808                 my ($i) = @_;
 809                 my $mid = $mm->mid_for($$i) or return;
 810                 my $h = search_header_for($srch, $mid, 'references');
 811                 more($self, "$$i $h");
 812         });
 813 }
 814
 815 sub over_line ($$) {
 816         my ($num, $smsg) = @_;
 817         # n.b. field access and procedural calls can be
 818         # 10%-15% faster than OO method calls:
 819         my $s = join("\t", $num,
 820                 $smsg->{subject},
 821                 $smsg->{from},
 822                 PublicInbox::SearchMsg::date($smsg),
 823                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 824                 $smsg->{references},
 825                 PublicInbox::SearchMsg::bytes($smsg),
 826                 PublicInbox::SearchMsg::lines($smsg));
 827         utf8::encode($s);
 828         $s
 829 }
 830
 831 sub cmd_over ($;$) {
 832         my ($self, $range) = @_;
 833         if ($range && $range =~ /\A<(.+)>\z/) {
 834                 my ($ng, $n) = mid_lookup($self, $1);
 835                 my $smsg = $ng->search->lookup_mail($range) or
 836                         return '430 No article with that message-id';
 837                 more($self, '224 Overview information follows (multi-line)');
 838
 839                 # Only set article number column if it's the current group
 840                 my $self_ng = $self->{ng};
 841                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 842                 more($self, over_line($n, $smsg));
 843                 '.';
 844         } else {
 845                 cmd_xover($self, $range);
 846         }
 847 }
 848
 849 sub cmd_xover ($;$) {
 850         my ($self, $range) = @_;
 851         $range = $self->{article} unless defined $range;
 852         my $r = get_range($self, $range);
 853         return $r unless ref $r;
 854         my ($beg, $end) = @$r;
 855         more($self, "224 Overview information follows for $beg to $end");
 856         my $srch = $self->{ng}->search;
 857         my $off = 0;
 858         long_response($self, $beg, $end, sub {
 859                 my ($i, $lim) = @_;
 860                 my $res = $srch->query_xover($beg, $end, $off);
 861                 my $msgs = $res->{msgs};
 862                 my $nr = scalar @$msgs or return;
 863                 $off += $nr;
 864                 $$lim -= $nr;
 865
 866                 # OVERVIEW.FMT
 867                 more($self, join("\r\n", map {
 868                         over_line(PublicInbox::SearchMsg::num($_), $_);
 869                         } @$msgs));
 870
 871                 # -1 to adjust for implicit increment in long_response
 872                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 873         });
 874 }
 875
 876 sub cmd_xpath ($$) {
 877         my ($self, $mid) = @_;
 878         return r501 unless $mid =~ /\A<(.+)>\z/;
 879         $mid = $1;
 880         my @paths;
 881         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 882                 my $n = $ng->mm->num_for($mid);
 883                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 884         }
 885         return '430 no such article on server' unless @paths;
 886         '223 '.join(' ', @paths);
 887 }
 888
 889 sub res ($$) {
 890         my ($self, $line) = @_;
 891         do_write($self, $line . "\r\n");
 892 }
 893
 894 sub more ($$) {
 895         my ($self, $line) = @_;
 896         do_more($self, $line . "\r\n");
 897 }
 898
 899 sub do_write ($$) {
 900         my ($self, $data) = @_;
 901         my $done = $self->write($data);
 902         return if $self->{closed};
 903
 904         # Do not watch for readability if we have data in the queue,
 905         # instead re-enable watching for readability when we can
 906         $self->watch_read(0) if (!$done || $self->{long_res});
 907
 908         $done;
 909 }
 910
 911 sub err ($$;@) {
 912         my ($self, $fmt, @args) = @_;
 913         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 914 }
 915
 916 sub out ($$;@) {
 917         my ($self, $fmt, @args) = @_;
 918         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 919 }
 920
 921 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 922
 923 sub do_more ($$) {
 924         my ($self, $data) = @_;
 925         if (MSG_MORE && !$self->{write_buf_size}) {
 926                 my $n = send($self->{sock}, $data, MSG_MORE);
 927                 if (defined $n) {
 928                         my $dlen = length($data);
 929                         return 1 if $n == $dlen; # all done!
 930                         $data = substr($data, $n, $dlen - $n);
 931                 }
 932         }
 933         do_write($self, $data);
 934 }
 935
 936 # callbacks for Danga::Socket
 937
 938 sub event_hup { $_[0]->close }
 939 sub event_err { $_[0]->close }
 940
 941 sub event_write {
 942         my ($self) = @_;
 943         update_idle_time($self);
 944         # only continue watching for readability when we are done writing:
 945         if ($self->write(undef) == 1 && !$self->{long_res}) {
 946                 $self->watch_read(1);
 947         }
 948 }
 949
 950 sub event_read {
 951         my ($self) = @_;
 952         use constant LINE_MAX => 512; # RFC 977 section 2.3
 953
 954         if (index($self->{rbuf}, "\n") < 0) {
 955                 my $buf = $self->read(LINE_MAX) or return $self->close;
 956                 $self->{rbuf} .= $$buf;
 957         }
 958         my $r = 1;
 959         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]*)\r?\n//) {
 960                 my $line = $1;
 961                 return $self->close if $line =~ /[[:cntrl:]]/s;
 962                 my $t0 = now();
 963                 my $fd = $self->{fd};
 964                 $r = eval { process_line($self, $line) };
 965                 my $d = $self->{long_res} ?
 966                         " deferred[$fd]" : '';
 967                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 968         }
 969
 970         return $self->close if $r < 0;
 971         my $len = length($self->{rbuf});
 972         return $self->close if ($len >= LINE_MAX);
 973         update_idle_time($self);
 974 }
 975
 976 sub watch_read {
 977         my ($self, $bool) = @_;
 978         my $rv = $self->SUPER::watch_read($bool);
 979         if ($bool && index($self->{rbuf}, "\n") >= 0) {
 980                 # Force another read if there is a pipelined request.
 981                 # We don't know if the socket has anything for us to read,
 982                 # and we must double-check again by the time the timer fires
 983                 # in case we really did dispatch a read event and started
 984                 # another long response.
 985                 push @$nextq, $self;
 986                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 987         }
 988         $rv;
 989 }
 990
 991 sub not_idle_long ($$) {
 992         my ($self, $now) = @_;
 993         defined(my $fd = $self->{fd}) or return;
 994         my $ary = $EXPMAP->{$fd} or return;
 995         my $exp_at = $ary->[0] + $EXPTIME;
 996         $exp_at > $now;
 997 }
 998
 999 # for graceful shutdown in PublicInbox::Daemon:
1000 sub busy {
1001         my ($self, $now) = @_;
1002         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
1003          not_idle_long($self, $now));
1004 }
1005
1006 1;