lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  38
  39 my $EXPMAP; # fd -> [ idle_time, $self ]
  40 my $expt;
  41 our $EXPTIME = 180; # 3 minutes
  42 my $nextt;
  43
  44 my $nextq = [];
  45 sub next_tick () {
  46         $nextt = undef;
  47         my $q = $nextq;
  48         $nextq = [];
  49         foreach my $nntp (@$q) {
  50                 # for request && response protocols, always finish writing
  51                 # before finishing reading:
  52                 if (my $long_cb = $nntp->{long_res}) {
  53                         $nntp->write($long_cb);
  54                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  55                         event_read($nntp);
  56                 }
  57         }
  58 }
  59
  60 sub update_idle_time ($) {
  61         my ($self) = @_;
  62         my $fd = $self->{fd};
  63         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  64 }
  65
  66 sub expire_old () {
  67         my $now = now();
  68         my $exp = $EXPTIME;
  69         my $old = $now - $exp;
  70         my $nr = 0;
  71         my %new;
  72         while (my ($fd, $v) = each %$EXPMAP) {
  73                 my ($idle_time, $nntp) = @$v;
  74                 if ($idle_time < $old) {
  75                         $nntp->close; # idempotent
  76                 } else {
  77                         ++$nr;
  78                         $new{$fd} = $v;
  79                 }
  80         }
  81         $EXPMAP = \%new;
  82         if ($nr) {
  83                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  84         } else {
  85                 $expt = undef;
  86                 # noop to kick outselves out of the loop ASAP so descriptors
  87                 # really get closed
  88                 PublicInbox::EvCleanup::asap(sub {});
  89         }
  90 }
  91
  92 sub new ($$$) {
  93         my ($class, $sock, $nntpd) = @_;
  94         my $self = fields::new($class);
  95         $self->SUPER::new($sock);
  96         $self->{nntpd} = $nntpd;
  97         res($self, '201 server ready - post via email');
  98         $self->{rbuf} = '';
  99         $self->watch_read(1);
 100         update_idle_time($self);
 101         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 102         $self;
 103 }
 104
 105 sub args_ok ($$) {
 106         my ($cb, $argc) = @_;
 107         my $tot = prototype $cb;
 108         my ($nreq, undef) = split(';', $tot);
 109         $nreq = ($nreq =~ tr/$//) - 1;
 110         $tot = ($tot =~ tr/$//) - 1;
 111         ($argc <= $tot && $argc >= $nreq);
 112 }
 113
 114 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 115 sub process_line ($$) {
 116         my ($self, $l) = @_;
 117         my ($req, @args) = split(/\s+/, $l);
 118         return unless defined($req);
 119         $req = lc($req);
 120         $req = eval {
 121                 no strict 'refs';
 122                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 123         };
 124         return res($self, '500 command not recognized') unless $req;
 125         return res($self, r501) unless args_ok($req, scalar @args);
 126
 127         my $res = eval { $req->($self, @args) };
 128         my $err = $@;
 129         if ($err && !$self->{closed}) {
 130                 local $/ = "\n";
 131                 chomp($l);
 132                 err($self, 'error from: %s (%s)', $l, $err);
 133                 $res = '503 program fault - command not performed';
 134         }
 135         return 0 unless defined $res;
 136         res($self, $res);
 137 }
 138
 139 sub cmd_mode ($$) {
 140         my ($self, $arg) = @_;
 141         $arg = uc $arg;
 142         return r501 unless $arg eq 'READER';
 143         '201 Posting prohibited';
 144 }
 145
 146 sub cmd_slave ($) { '202 slave status noted' }
 147
 148 sub cmd_xgtitle ($;$) {
 149         my ($self, $wildmat) = @_;
 150         more($self, '282 list of groups and descriptions follows');
 151         list_newsgroups($self, $wildmat);
 152         '.'
 153 }
 154
 155 sub list_overview_fmt ($) {
 156         my ($self) = @_;
 157         do_more($self, $OVERVIEW_FMT);
 158 }
 159
 160 sub list_headers ($;$) {
 161         my ($self) = @_;
 162         do_more($self, $LIST_HEADERS);
 163 }
 164
 165 sub list_active ($;$) {
 166         my ($self, $wildmat) = @_;
 167         wildmat2re($wildmat);
 168         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 169                 $ng->{newsgroup} =~ $wildmat or next;
 170                 group_line($self, $ng);
 171         }
 172 }
 173
 174 sub list_active_times ($;$) {
 175         my ($self, $wildmat) = @_;
 176         wildmat2re($wildmat);
 177         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 178                 $ng->{newsgroup} =~ $wildmat or next;
 179                 my $c = eval { $ng->mm->created_at } || time;
 180                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 181         }
 182 }
 183
 184 sub list_newsgroups ($;$) {
 185         my ($self, $wildmat) = @_;
 186         wildmat2re($wildmat);
 187         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 188                 $ng->{newsgroup} =~ $wildmat or next;
 189                 my $d = $ng->description;
 190                 more($self, "$ng->{newsgroup} $d");
 191         }
 192 }
 193
 194 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 195 sub cmd_list ($;$$) {
 196         my ($self, @args) = @_;
 197         if (scalar @args) {
 198                 my $arg = shift @args;
 199                 $arg =~ tr/A-Z./a-z_/;
 200                 $arg = "list_$arg";
 201                 return r501 if $DISABLED{$arg};
 202
 203                 $arg = eval {
 204                         no strict 'refs';
 205                         *{$arg}{CODE};
 206                 };
 207                 return r501 unless $arg && args_ok($arg, scalar @args);
 208                 more($self, '215 information follows');
 209                 $arg->($self, @args);
 210         } else {
 211                 more($self, '215 list of newsgroups follows');
 212                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 213                         group_line($self, $ng);
 214                 }
 215         }
 216         '.'
 217 }
 218
 219 sub cmd_listgroup ($;$) {
 220         my ($self, $group) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226
 227         $self->{ng} or return '412 no newsgroup selected';
 228         my $n = 0;
 229         long_response($self, sub {
 230                 my $ary = $self->{ng}->mm->ids_after(\$n);
 231                 scalar @$ary or return;
 232                 more($self, join("\r\n", @$ary));
 233                 1;
 234         });
 235 }
 236
 237 sub parse_time ($$;$) {
 238         my ($date, $time, $gmt) = @_;
 239         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 240         if (defined $gmt) {
 241                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 242                 $gmt = 1;
 243         }
 244         my @now = $gmt ? gmtime : localtime;
 245         my ($YYYY, $MM, $DD);
 246         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 247                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 248         } else { # legacy clients send YYMMDD
 249                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 250                 my $cur_year = $now[5] + 1900;
 251                 if ($YYYY > $cur_year) {
 252                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 253                 }
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ng) = @_;
 264         my ($min, $max) = $ng->mm->minmax;
 265         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 266 }
 267
 268 sub cmd_newgroups ($$$;$$) {
 269         my ($self, $date, $time, $gmt, $dists) = @_;
 270         my $ts = eval { parse_time($date, $time, $gmt) };
 271         return r501 if $@;
 272
 273         # TODO dists
 274         more($self, '231 list of new newsgroups follows');
 275         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 276                 my $c = eval { $ng->mm->created_at } || 0;
 277                 next unless $c > $ts;
 278                 group_line($self, $ng);
 279         }
 280         '.'
 281 }
 282
 283 sub wildmat2re (;$) {
 284         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 285         my %keep;
 286         my $salt = rand;
 287         my $tmp = $_[0];
 288
 289         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 290                 my $orig = $1;
 291                 my $key = sha1_hex($orig . $salt);
 292                 $orig =~ s/([^\w\-])+/\Q$1/g;
 293                 $keep{$key} = $orig;
 294                 $key
 295                 #gex;
 296         my %map = ('*' => '.*', '?' => '.' );
 297         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 298         if (scalar %keep) {
 299                 $tmp =~ s#([a-f0-9]{40})#
 300                         my $orig = $keep{$1};
 301                         defined $orig ? $orig : $1;
 302                         #ge;
 303         }
 304         $_[0] = qr/\A$tmp\z/;
 305 }
 306
 307 sub ngpat2re (;$) {
 308         return $_[0] = qr/\A\z/ unless defined $_[0];
 309         my %map = ('*' => '.*', ',' => '|');
 310         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 311         $_[0] = qr/\A(?:$_[0])\z/;
 312 }
 313
 314 sub cmd_newnews ($$$$;$$) {
 315         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 316         my $ts = eval { parse_time($date, $time, $gmt) };
 317         return r501 if $@;
 318         more($self, '230 list of new articles by message-id follows');
 319         my ($keep, $skip) = split('!', $newsgroups, 2);
 320         ngpat2re($keep);
 321         ngpat2re($skip);
 322         my @srch;
 323         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 324                 $ng->{newsgroup} =~ $keep or next;
 325                 $ng->{newsgroup} =~ $skip and next;
 326                 my $srch = $ng->search or next;
 327                 push @srch, $srch;
 328         };
 329         return '.' unless @srch;
 330
 331         my $prev = 0;
 332         long_response($self, sub {
 333                 my $srch = $srch[0];
 334                 my $msgs = $srch->query_ts($ts, $prev);
 335                 if (scalar @$msgs) {
 336                         more($self, '<' .
 337                                 join(">\r\n<", map { $_->mid } @$msgs ).
 338                                 '>');
 339                         $prev = $msgs->[-1]->{num};
 340                 } else {
 341                         shift @srch;
 342                         if (@srch) { # continue onto next newsgroup
 343                                 $prev = 0;
 344                                 return 1;
 345                         } else { # break out of the long response.
 346                                 return;
 347                         }
 348                 }
 349         });
 350 }
 351
 352 sub cmd_group ($$) {
 353         my ($self, $group) = @_;
 354         my $no_such = '411 no such news group';
 355         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 356
 357         $self->{ng} = $ng;
 358         my ($min, $max) = $ng->mm->minmax;
 359         $min ||= 0;
 360         $max ||= 0;
 361         $self->{article} = $min;
 362         my $est_size = $max - $min;
 363         "211 $est_size $min $max $group";
 364 }
 365
 366 sub article_adj ($$) {
 367         my ($self, $off) = @_;
 368         my $ng = $self->{ng} or return '412 no newsgroup selected';
 369
 370         my $n = $self->{article};
 371         defined $n or return '420 no current article has been selected';
 372
 373         $n += $off;
 374         my $mid = $ng->mm->mid_for($n);
 375         unless ($mid) {
 376                 $n = $off > 0 ? 'next' : 'previous';
 377                 return "421 no $n article in this group";
 378         }
 379         $self->{article} = $n;
 380         "223 $n <$mid> article retrieved - request text separately";
 381 }
 382
 383 sub cmd_next ($) { article_adj($_[0], 1) }
 384 sub cmd_last ($) { article_adj($_[0], -1) }
 385
 386 # We want to encourage using email and CC-ing everybody involved to avoid
 387 # the single-point-of-failure a single server provides.
 388 sub cmd_post ($) {
 389         my ($self) = @_;
 390         my $ng = $self->{ng};
 391         $ng ? "440 mailto:$ng->{-primary_address} to post"
 392                 : '440 posting not allowed'
 393 }
 394
 395 sub cmd_quit ($) {
 396         my ($self) = @_;
 397         res($self, '205 closing connection - goodbye!');
 398         $self->close;
 399         undef;
 400 }
 401
 402 sub header_append ($$$) {
 403         my ($hdr, $k, $v) = @_;
 404         my @v = $hdr->header($k);
 405         foreach (@v) {
 406                 return if $v eq $_;
 407         }
 408         $hdr->header_set($k, @v, $v);
 409 }
 410
 411 sub xref ($$$$) {
 412         my ($self, $ng, $n, $mid) = @_;
 413         my $ret = "$ng->{domain} $ng->{newsgroup}:$n";
 414
 415         # num_for is pretty cheap and sometimes we'll lookup the existence
 416         # of an article without getting even the OVER info.  In other words,
 417         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 418         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 419         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 420                 next if $ng eq $other;
 421                 my $num = eval { $other->mm->num_for($mid) } or next;
 422                 $ret .= " $other->{newsgroup}:$num";
 423         }
 424         $ret;
 425 }
 426
 427 sub set_nntp_headers ($$$$$) {
 428         my ($self, $hdr, $ng, $n, $mid) = @_;
 429
 430         # clobber some
 431         my $xref = xref($self, $ng, $n, $mid);
 432         $hdr->header_set('Xref', $xref);
 433         $xref =~ s/:\d+//g;
 434         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 435         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 436         if (my $url = $ng->base_url) {
 437                 $mid = mid_escape($mid);
 438                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 439                 header_append($hdr, 'List-Archive', "<$url>");
 440         }
 441 }
 442
 443 sub art_lookup ($$$) {
 444         my ($self, $art, $set_headers) = @_;
 445         my $ng = $self->{ng};
 446         my ($n, $mid);
 447         my $err;
 448         if (defined $art) {
 449                 if ($art =~ /\A\d+\z/o) {
 450                         $err = '423 no such article number in this group';
 451                         $n = int($art);
 452                         goto find_mid;
 453                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 454                         $mid = $1;
 455                         $err = r430;
 456                         $n = $ng->mm->num_for($mid) if $ng;
 457                         goto found if defined $n;
 458                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 459                                 $n = $g->mm->num_for($mid);
 460                                 if (defined $n) {
 461                                         $ng = $g;
 462                                         goto found;
 463                                 }
 464                         }
 465                         return $err;
 466                 } else {
 467                         return r501;
 468                 }
 469         } else {
 470                 $err = '420 no current article has been selected';
 471                 $n = $self->{article};
 472                 defined $n or return $err;
 473 find_mid:
 474                 $ng or return '412 no newsgroup has been selected';
 475                 $mid = $ng->mm->mid_for($n);
 476                 defined $mid or return $err;
 477         }
 478 found:
 479         my $smsg = $ng->search->{over_ro}->get_art($n) or return $err;
 480         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 481         my $s = Email::Simple->new($msg);
 482         if ($set_headers) {
 483                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 484
 485                 # must be last
 486                 $s->body_set('') if ($set_headers == 2);
 487         }
 488         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 489 }
 490
 491 sub simple_body_write ($$) {
 492         my ($self, $s) = @_;
 493         my $body = $s->body;
 494         $s->body_set('');
 495         $body =~ s/^\./../smg;
 496         $body =~ s/(?<!\r)\n/\r\n/sg;
 497         do_more($self, $body);
 498         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 499         '.'
 500 }
 501
 502 sub set_art {
 503         my ($self, $art) = @_;
 504         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 505 }
 506
 507 sub _header ($) {
 508         my $hdr = $_[0]->header_obj->as_string;
 509         utf8::encode($hdr);
 510         $hdr
 511 }
 512
 513 sub cmd_article ($;$) {
 514         my ($self, $art) = @_;
 515         my $r = art_lookup($self, $art, 1);
 516         return $r unless ref $r;
 517         my ($n, $mid, $s) = @$r;
 518         set_art($self, $art);
 519         more($self, "220 $n <$mid> article retrieved - head and body follow");
 520         do_more($self, _header($s));
 521         do_more($self, "\r\n");
 522         simple_body_write($self, $s);
 523 }
 524
 525 sub cmd_head ($;$) {
 526         my ($self, $art) = @_;
 527         my $r = art_lookup($self, $art, 2);
 528         return $r unless ref $r;
 529         my ($n, $mid, $s) = @$r;
 530         set_art($self, $art);
 531         more($self, "221 $n <$mid> article retrieved - head follows");
 532         do_more($self, _header($s));
 533         '.'
 534 }
 535
 536 sub cmd_body ($;$) {
 537         my ($self, $art) = @_;
 538         my $r = art_lookup($self, $art, 0);
 539         return $r unless ref $r;
 540         my ($n, $mid, $s) = @$r;
 541         set_art($self, $art);
 542         more($self, "222 $n <$mid> article retrieved - body follows");
 543         simple_body_write($self, $s);
 544 }
 545
 546 sub cmd_stat ($;$) {
 547         my ($self, $art) = @_;
 548         my $r = art_lookup($self, $art, 0);
 549         return $r unless ref $r;
 550         my ($n, $mid, undef) = @$r;
 551         set_art($self, $art);
 552         "223 $n <$mid> article retrieved - request text separately";
 553 }
 554
 555 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 556
 557 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 558
 559 sub cmd_help ($) {
 560         my ($self) = @_;
 561         more($self, '100 help text follows');
 562         '.'
 563 }
 564
 565 sub get_range ($$) {
 566         my ($self, $range) = @_;
 567         my $ng = $self->{ng} or return '412 no news group has been selected';
 568         defined $range or return '420 No article(s) selected';
 569         my ($beg, $end);
 570         my ($min, $max) = $ng->mm->minmax;
 571         if ($range =~ /\A(\d+)\z/) {
 572                 $beg = $end = $1;
 573         } elsif ($range =~ /\A(\d+)-\z/) {
 574                 ($beg, $end) = ($1, $max);
 575         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 576                 ($beg, $end) = ($1, $2);
 577         } else {
 578                 return r501;
 579         }
 580         $beg = $min if ($beg < $min);
 581         $end = $max if ($end > $max);
 582         return '420 No article(s) selected' if ($beg > $end);
 583         [ $beg, $end ];
 584 }
 585
 586 sub long_response ($$) {
 587         my ($self, $cb) = @_;
 588         die "BUG: nested long response" if $self->{long_res};
 589
 590         my $fd = $self->{fd};
 591         defined $fd or return;
 592         # make sure we disable reading during a long response,
 593         # clients should not be sending us stuff and making us do more
 594         # work while we are stream a response to them
 595         $self->watch_read(0);
 596         my $t0 = now();
 597         $self->{long_res} = sub {
 598                 my $more = eval { $cb->() };
 599                 if ($@ || $self->{closed}) {
 600                         $self->{long_res} = undef;
 601
 602                         if ($@) {
 603                                 err($self,
 604                                     "%s during long response[$fd] - %0.6f",
 605                                     $@, now() - $t0);
 606                         }
 607                         if ($self->{closed}) {
 608                                 out($self, " deferred[$fd] aborted - %0.6f",
 609                                            now() - $t0);
 610                         } else {
 611                                 update_idle_time($self);
 612                                 $self->watch_read(1);
 613                         }
 614                 } elsif ($more) { # $self->{write_buf_size}:
 615                         # no recursion, schedule another call ASAP
 616                         # but only after all pending writes are done
 617                         update_idle_time($self);
 618
 619                         push @$nextq, $self;
 620                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 621                 } else { # all done!
 622                         $self->{long_res} = undef;
 623                         $self->watch_read(1);
 624                         res($self, '.');
 625                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 626                 }
 627         };
 628         $self->{long_res}->(); # kick off!
 629         undef;
 630 }
 631
 632 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 633         my ($self, $xhdr, $range) = @_;
 634
 635         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 636                 my ($ng, $n) = mid_lookup($self, $1);
 637                 return r430 unless $n;
 638                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 639         } else { # numeric range
 640                 $range = $self->{article} unless defined $range;
 641                 my $r = get_range($self, $range);
 642                 return $r unless ref $r;
 643                 my $mm = $self->{ng}->mm;
 644                 my ($beg, $end) = @$r;
 645                 more($self, $xhdr ? r221 : r225);
 646                 long_response($self, sub {
 647                         my $r = $mm->msg_range(\$beg, $end);
 648                         @$r or return;
 649                         more($self, join("\r\n", map {
 650                                 "$_->[0] <$_->[1]>"
 651                         } @$r));
 652                         1;
 653                 });
 654         }
 655 }
 656
 657 sub mid_lookup ($$) {
 658         my ($self, $mid) = @_;
 659         my $self_ng = $self->{ng};
 660         if ($self_ng) {
 661                 my $n = $self_ng->mm->num_for($mid);
 662                 return ($self_ng, $n) if defined $n;
 663         }
 664         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 665                 next if defined $self_ng && $ng eq $self_ng;
 666                 my $n = $ng->mm->num_for($mid);
 667                 return ($ng, $n) if defined $n;
 668         }
 669         (undef, undef);
 670 }
 671
 672 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 673         my ($self, $xhdr, $range) = @_;
 674
 675         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 676                 my $mid = $1;
 677                 my ($ng, $n) = mid_lookup($self, $mid);
 678                 return r430 unless $n;
 679                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 680                                 xref($self, $ng, $n, $mid));
 681         } else { # numeric range
 682                 $range = $self->{article} unless defined $range;
 683                 my $r = get_range($self, $range);
 684                 return $r unless ref $r;
 685                 my $ng = $self->{ng};
 686                 my $mm = $ng->mm;
 687                 my ($beg, $end) = @$r;
 688                 more($self, $xhdr ? r221 : r225);
 689                 long_response($self, sub {
 690                         my $r = $mm->msg_range(\$beg, $end);
 691                         @$r or return;
 692                         more($self, join("\r\n", map {
 693                                 my $num = $_->[0];
 694                                 "$num ".xref($self, $ng, $num, $_->[1]);
 695                         } @$r));
 696                         1;
 697                 });
 698         }
 699 }
 700
 701 sub search_header_for {
 702         my ($srch, $num, $field) = @_;
 703         my $smsg = $srch->{over_ro}->get_art($num) or return;
 704         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 705         $smsg->{$field};
 706 }
 707
 708 sub hdr_searchmsg ($$$$) {
 709         my ($self, $xhdr, $field, $range) = @_;
 710         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 711                 my ($ng, $n) = mid_lookup($self, $1);
 712                 return r430 unless defined $n;
 713                 my $v = search_header_for($ng->search, $n, $field);
 714                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 715         } else { # numeric range
 716                 $range = $self->{article} unless defined $range;
 717                 my $srch = $self->{ng}->search;
 718                 my $mm = $self->{ng}->mm;
 719                 my $r = get_range($self, $range);
 720                 return $r unless ref $r;
 721                 my ($beg, $end) = @$r;
 722                 more($self, $xhdr ? r221 : r225);
 723                 my $cur = $beg;
 724                 long_response($self, sub {
 725                         my $msgs = $srch->query_xover($cur, $end);
 726                         my $nr = scalar @$msgs or return;
 727                         my $tmp = '';
 728                         foreach my $s (@$msgs) {
 729                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 730                         }
 731                         utf8::encode($tmp);
 732                         do_more($self, $tmp);
 733                         $cur = $msgs->[-1]->{num} + 1;
 734                 });
 735         }
 736 }
 737
 738 sub do_hdr ($$$;$) {
 739         my ($self, $xhdr, $header, $range) = @_;
 740         my $sub = lc $header;
 741         if ($sub eq 'message-id') {
 742                 hdr_message_id($self, $xhdr, $range);
 743         } elsif ($sub eq 'xref') {
 744                 hdr_xref($self, $xhdr, $range);
 745         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 746                                 bytes|lines)\z/x) {
 747                 hdr_searchmsg($self, $xhdr, $sub, $range);
 748         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 749                 hdr_searchmsg($self, $xhdr, $1, $range);
 750         } else {
 751                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 752         }
 753 }
 754
 755 # RFC 3977
 756 sub cmd_hdr ($$;$) {
 757         my ($self, $header, $range) = @_;
 758         do_hdr($self, 0, $header, $range);
 759 }
 760
 761 # RFC 2980
 762 sub cmd_xhdr ($$;$) {
 763         my ($self, $header, $range) = @_;
 764         do_hdr($self, 1, $header, $range);
 765 }
 766
 767 sub hdr_mid_prefix ($$$$$) {
 768         my ($self, $xhdr, $ng, $n, $mid) = @_;
 769         return $mid if $xhdr;
 770
 771         # HDR for RFC 3977 users
 772         if (my $self_ng = $self->{ng}) {
 773                 ($self_ng eq $ng) ? $n : '0';
 774         } else {
 775                 '0';
 776         }
 777 }
 778
 779 sub hdr_mid_response ($$$$$$) {
 780         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 781         my $res = '';
 782         if ($xhdr) {
 783                 $res .= r221 . "\r\n";
 784                 $res .= "$mid $v\r\n";
 785         } else {
 786                 $res .= r225 . "\r\n";
 787                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 788                 $res .= "$pfx $v\r\n";
 789         }
 790         res($self, $res .= '.');
 791         undef;
 792 }
 793
 794 sub cmd_xrover ($;$) {
 795         my ($self, $range) = @_;
 796         my $ng = $self->{ng} or return '412 no newsgroup selected';
 797         (defined $range && $range =~ /[<>]/) and
 798                 return '420 No article(s) selected'; # no message IDs
 799
 800         $range = $self->{article} unless defined $range;
 801         my $r = get_range($self, $range);
 802         return $r unless ref $r;
 803         my ($beg, $end) = @$r;
 804         my $mm = $ng->mm;
 805         my $srch = $ng->search;
 806         more($self, '224 Overview information follows');
 807
 808         long_response($self, sub {
 809                 my $h = search_header_for($srch, $beg, 'references');
 810                 more($self, "$beg $h") if defined($h);
 811                 $beg++ < $end;
 812         });
 813 }
 814
 815 sub over_line ($$) {
 816         my ($num, $smsg) = @_;
 817         # n.b. field access and procedural calls can be
 818         # 10%-15% faster than OO method calls:
 819         my $s = join("\t", $num,
 820                 $smsg->{subject},
 821                 $smsg->{from},
 822                 PublicInbox::SearchMsg::date($smsg),
 823                 "<$smsg->{mid}>",
 824                 $smsg->{references},
 825                 $smsg->{bytes},
 826                 $smsg->{lines});
 827         utf8::encode($s);
 828         $s
 829 }
 830
 831 sub cmd_over ($;$) {
 832         my ($self, $range) = @_;
 833         if ($range && $range =~ /\A<(.+)>\z/) {
 834                 my ($ng, $n) = mid_lookup($self, $1);
 835                 defined $n or return r430;
 836                 my $smsg = $ng->search->{over_ro}->get_art($n) or return r430;
 837                 more($self, '224 Overview information follows (multi-line)');
 838
 839                 # Only set article number column if it's the current group
 840                 my $self_ng = $self->{ng};
 841                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 842                 more($self, over_line($n, $smsg));
 843                 '.';
 844         } else {
 845                 cmd_xover($self, $range);
 846         }
 847 }
 848
 849 sub cmd_xover ($;$) {
 850         my ($self, $range) = @_;
 851         $range = $self->{article} unless defined $range;
 852         my $r = get_range($self, $range);
 853         return $r unless ref $r;
 854         my ($beg, $end) = @$r;
 855         more($self, "224 Overview information follows for $beg to $end");
 856         my $srch = $self->{ng}->search;
 857         my $cur = $beg;
 858         long_response($self, sub {
 859                 my $msgs = $srch->query_xover($cur, $end);
 860                 my $nr = scalar @$msgs or return;
 861
 862                 # OVERVIEW.FMT
 863                 more($self, join("\r\n", map {
 864                         over_line($_->{num}, $_);
 865                         } @$msgs));
 866                 $cur = $msgs->[-1]->{num} + 1;
 867         });
 868 }
 869
 870 sub cmd_xpath ($$) {
 871         my ($self, $mid) = @_;
 872         return r501 unless $mid =~ /\A<(.+)>\z/;
 873         $mid = $1;
 874         my @paths;
 875         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 876                 my $n = $ng->mm->num_for($mid);
 877                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 878         }
 879         return '430 no such article on server' unless @paths;
 880         '223 '.join(' ', @paths);
 881 }
 882
 883 sub res ($$) {
 884         my ($self, $line) = @_;
 885         do_write($self, $line . "\r\n");
 886 }
 887
 888 sub more ($$) {
 889         my ($self, $line) = @_;
 890         do_more($self, $line . "\r\n");
 891 }
 892
 893 sub do_write ($$) {
 894         my ($self, $data) = @_;
 895         my $done = $self->write($data);
 896         return if $self->{closed};
 897
 898         # Do not watch for readability if we have data in the queue,
 899         # instead re-enable watching for readability when we can
 900         $self->watch_read(0) if (!$done || $self->{long_res});
 901
 902         $done;
 903 }
 904
 905 sub err ($$;@) {
 906         my ($self, $fmt, @args) = @_;
 907         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 908 }
 909
 910 sub out ($$;@) {
 911         my ($self, $fmt, @args) = @_;
 912         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 913 }
 914
 915 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 916
 917 sub do_more ($$) {
 918         my ($self, $data) = @_;
 919         if (MSG_MORE && !$self->{write_buf_size}) {
 920                 my $n = send($self->{sock}, $data, MSG_MORE);
 921                 if (defined $n) {
 922                         my $dlen = length($data);
 923                         return 1 if $n == $dlen; # all done!
 924                         $data = substr($data, $n, $dlen - $n);
 925                 }
 926         }
 927         do_write($self, $data);
 928 }
 929
 930 # callbacks for Danga::Socket
 931
 932 sub event_hup { $_[0]->close }
 933 sub event_err { $_[0]->close }
 934
 935 sub event_write {
 936         my ($self) = @_;
 937         update_idle_time($self);
 938         # only continue watching for readability when we are done writing:
 939         if ($self->write(undef) == 1 && !$self->{long_res}) {
 940                 $self->watch_read(1);
 941         }
 942 }
 943
 944 sub event_read {
 945         my ($self) = @_;
 946         use constant LINE_MAX => 512; # RFC 977 section 2.3
 947
 948         if (index($self->{rbuf}, "\n") < 0) {
 949                 my $buf = $self->read(LINE_MAX) or return $self->close;
 950                 $self->{rbuf} .= $$buf;
 951         }
 952         my $r = 1;
 953         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]*)\r?\n//) {
 954                 my $line = $1;
 955                 return $self->close if $line =~ /[[:cntrl:]]/s;
 956                 my $t0 = now();
 957                 my $fd = $self->{fd};
 958                 $r = eval { process_line($self, $line) };
 959                 my $d = $self->{long_res} ?
 960                         " deferred[$fd]" : '';
 961                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 962         }
 963
 964         return $self->close if $r < 0;
 965         my $len = length($self->{rbuf});
 966         return $self->close if ($len >= LINE_MAX);
 967         update_idle_time($self);
 968 }
 969
 970 sub watch_read {
 971         my ($self, $bool) = @_;
 972         my $rv = $self->SUPER::watch_read($bool);
 973         if ($bool && index($self->{rbuf}, "\n") >= 0) {
 974                 # Force another read if there is a pipelined request.
 975                 # We don't know if the socket has anything for us to read,
 976                 # and we must double-check again by the time the timer fires
 977                 # in case we really did dispatch a read event and started
 978                 # another long response.
 979                 push @$nextq, $self;
 980                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 981         }
 982         $rv;
 983 }
 984
 985 sub not_idle_long ($$) {
 986         my ($self, $now) = @_;
 987         defined(my $fd = $self->{fd}) or return;
 988         my $ary = $EXPMAP->{$fd} or return;
 989         my $exp_at = $ary->[0] + $EXPTIME;
 990         $exp_at > $now;
 991 }
 992
 993 # for graceful shutdown in PublicInbox::Daemon:
 994 sub busy {
 995         my ($self, $now) = @_;
 996         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
 997          not_idle_long($self, $now));
 998 }
 999
1000 1;