lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  38
  39 my $EXPMAP; # fd -> [ idle_time, $self ]
  40 my $expt;
  41 our $EXPTIME = 180; # 3 minutes
  42 my $nextt;
  43
  44 my $nextq = [];
  45 sub next_tick () {
  46         $nextt = undef;
  47         my $q = $nextq;
  48         $nextq = [];
  49         foreach my $nntp (@$q) {
  50                 # for request && response protocols, always finish writing
  51                 # before finishing reading:
  52                 if (my $long_cb = $nntp->{long_res}) {
  53                         $nntp->write($long_cb);
  54                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  55                         event_read($nntp);
  56                 }
  57         }
  58 }
  59
  60 sub update_idle_time ($) {
  61         my ($self) = @_;
  62         my $fd = $self->{fd};
  63         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  64 }
  65
  66 sub expire_old () {
  67         my $now = now();
  68         my $exp = $EXPTIME;
  69         my $old = $now - $exp;
  70         my $nr = 0;
  71         my %new;
  72         while (my ($fd, $v) = each %$EXPMAP) {
  73                 my ($idle_time, $nntp) = @$v;
  74                 if ($idle_time < $old) {
  75                         $nntp->close; # idempotent
  76                 } else {
  77                         ++$nr;
  78                         $new{$fd} = $v;
  79                 }
  80         }
  81         $EXPMAP = \%new;
  82         if ($nr) {
  83                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  84         } else {
  85                 $expt = undef;
  86                 # noop to kick outselves out of the loop ASAP so descriptors
  87                 # really get closed
  88                 PublicInbox::EvCleanup::asap(sub {});
  89         }
  90 }
  91
  92 sub new ($$$) {
  93         my ($class, $sock, $nntpd) = @_;
  94         my $self = fields::new($class);
  95         $self->SUPER::new($sock);
  96         $self->{nntpd} = $nntpd;
  97         res($self, '201 server ready - post via email');
  98         $self->{rbuf} = '';
  99         $self->watch_read(1);
 100         update_idle_time($self);
 101         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 102         $self;
 103 }
 104
 105 sub args_ok ($$) {
 106         my ($cb, $argc) = @_;
 107         my $tot = prototype $cb;
 108         my ($nreq, undef) = split(';', $tot);
 109         $nreq = ($nreq =~ tr/$//) - 1;
 110         $tot = ($tot =~ tr/$//) - 1;
 111         ($argc <= $tot && $argc >= $nreq);
 112 }
 113
 114 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 115 sub process_line ($$) {
 116         my ($self, $l) = @_;
 117         my ($req, @args) = split(/\s+/, $l);
 118         $req = lc($req);
 119         $req = eval {
 120                 no strict 'refs';
 121                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 122         };
 123         return res($self, '500 command not recognized') unless $req;
 124         return res($self, r501) unless args_ok($req, scalar @args);
 125
 126         my $res = eval { $req->($self, @args) };
 127         my $err = $@;
 128         if ($err && !$self->{closed}) {
 129                 local $/ = "\n";
 130                 chomp($l);
 131                 err($self, 'error from: %s (%s)', $l, $err);
 132                 $res = '503 program fault - command not performed';
 133         }
 134         return 0 unless defined $res;
 135         res($self, $res);
 136 }
 137
 138 sub cmd_mode ($$) {
 139         my ($self, $arg) = @_;
 140         $arg = uc $arg;
 141         return r501 unless $arg eq 'READER';
 142         '201 Posting prohibited';
 143 }
 144
 145 sub cmd_slave ($) { '202 slave status noted' }
 146
 147 sub cmd_xgtitle ($;$) {
 148         my ($self, $wildmat) = @_;
 149         more($self, '282 list of groups and descriptions follows');
 150         list_newsgroups($self, $wildmat);
 151         '.'
 152 }
 153
 154 sub list_overview_fmt ($) {
 155         my ($self) = @_;
 156         do_more($self, $OVERVIEW_FMT);
 157 }
 158
 159 sub list_headers ($;$) {
 160         my ($self) = @_;
 161         do_more($self, $LIST_HEADERS);
 162 }
 163
 164 sub list_active ($;$) {
 165         my ($self, $wildmat) = @_;
 166         wildmat2re($wildmat);
 167         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 168                 $ng->{newsgroup} =~ $wildmat or next;
 169                 group_line($self, $ng);
 170         }
 171 }
 172
 173 sub list_active_times ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 my $c = eval { $ng->mm->created_at } || time;
 179                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 180         }
 181 }
 182
 183 sub list_newsgroups ($;$) {
 184         my ($self, $wildmat) = @_;
 185         wildmat2re($wildmat);
 186         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                 $ng->{newsgroup} =~ $wildmat or next;
 188                 my $d = $ng->description;
 189                 more($self, "$ng->{newsgroup} $d");
 190         }
 191 }
 192
 193 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 194 sub cmd_list ($;$$) {
 195         my ($self, @args) = @_;
 196         if (scalar @args) {
 197                 my $arg = shift @args;
 198                 $arg =~ tr/A-Z./a-z_/;
 199                 $arg = "list_$arg";
 200                 return r501 if $DISABLED{$arg};
 201
 202                 $arg = eval {
 203                         no strict 'refs';
 204                         *{$arg}{CODE};
 205                 };
 206                 return r501 unless $arg && args_ok($arg, scalar @args);
 207                 more($self, '215 information follows');
 208                 $arg->($self, @args);
 209         } else {
 210                 more($self, '215 list of newsgroups follows');
 211                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                         group_line($self, $ng);
 213                 }
 214         }
 215         '.'
 216 }
 217
 218 sub cmd_listgroup ($;$) {
 219         my ($self, $group) = @_;
 220         if (defined $group) {
 221                 my $res = cmd_group($self, $group);
 222                 return $res if ($res !~ /\A211 /);
 223                 more($self, $res);
 224         }
 225
 226         $self->{ng} or return '412 no newsgroup selected';
 227         my $n = 0;
 228         long_response($self, sub {
 229                 my $ary = $self->{ng}->mm->ids_after(\$n);
 230                 scalar @$ary or return;
 231                 more($self, join("\r\n", @$ary));
 232                 1;
 233         });
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my @now = $gmt ? gmtime : localtime;
 244         my ($YYYY, $MM, $DD);
 245         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 246                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 247         } else { # legacy clients send YYMMDD
 248                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my $cur_year = $now[5] + 1900;
 250                 if ($YYYY > $cur_year) {
 251                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 252                 }
 253         }
 254         if ($gmt) {
 255                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 256         } else {
 257                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 258         }
 259 }
 260
 261 sub group_line ($$) {
 262         my ($self, $ng) = @_;
 263         my ($min, $max) = $ng->mm->minmax;
 264         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 265 }
 266
 267 sub cmd_newgroups ($$$;$$) {
 268         my ($self, $date, $time, $gmt, $dists) = @_;
 269         my $ts = eval { parse_time($date, $time, $gmt) };
 270         return r501 if $@;
 271
 272         # TODO dists
 273         more($self, '231 list of new newsgroups follows');
 274         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 275                 my $c = eval { $ng->mm->created_at } || 0;
 276                 next unless $c > $ts;
 277                 group_line($self, $ng);
 278         }
 279         '.'
 280 }
 281
 282 sub wildmat2re (;$) {
 283         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 284         my %keep;
 285         my $salt = rand;
 286         my $tmp = $_[0];
 287
 288         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 289                 my $orig = $1;
 290                 my $key = sha1_hex($orig . $salt);
 291                 $orig =~ s/([^\w\-])+/\Q$1/g;
 292                 $keep{$key} = $orig;
 293                 $key
 294                 #gex;
 295         my %map = ('*' => '.*', '?' => '.' );
 296         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 297         if (scalar %keep) {
 298                 $tmp =~ s#([a-f0-9]{40})#
 299                         my $orig = $keep{$1};
 300                         defined $orig ? $orig : $1;
 301                         #ge;
 302         }
 303         $_[0] = qr/\A$tmp\z/;
 304 }
 305
 306 sub ngpat2re (;$) {
 307         return $_[0] = qr/\A\z/ unless defined $_[0];
 308         my %map = ('*' => '.*', ',' => '|');
 309         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 310         $_[0] = qr/\A(?:$_[0])\z/;
 311 }
 312
 313 sub cmd_newnews ($$$$;$$) {
 314         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 315         my $ts = eval { parse_time($date, $time, $gmt) };
 316         return r501 if $@;
 317         more($self, '230 list of new articles by message-id follows');
 318         my ($keep, $skip) = split('!', $newsgroups, 2);
 319         ngpat2re($keep);
 320         ngpat2re($skip);
 321         my @srch;
 322         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 323                 $ng->{newsgroup} =~ $keep or next;
 324                 $ng->{newsgroup} =~ $skip and next;
 325                 my $srch = $ng->search or next;
 326                 push @srch, $srch;
 327         };
 328         return '.' unless @srch;
 329
 330         my $prev = 0;
 331         long_response($self, sub {
 332                 my $srch = $srch[0];
 333                 my $msgs = $srch->query_ts($ts, $prev);
 334                 if (scalar @$msgs) {
 335                         more($self, '<' .
 336                                 join(">\r\n<", map { $_->mid } @$msgs ).
 337                                 '>');
 338                         $prev = $msgs->[-1]->{num};
 339                 } else {
 340                         shift @srch;
 341                         if (@srch) { # continue onto next newsgroup
 342                                 $prev = 0;
 343                                 return 1;
 344                         } else { # break out of the long response.
 345                                 return;
 346                         }
 347                 }
 348         });
 349 }
 350
 351 sub cmd_group ($$) {
 352         my ($self, $group) = @_;
 353         my $no_such = '411 no such news group';
 354         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 355
 356         $self->{ng} = $ng;
 357         my ($min, $max) = $ng->mm->minmax;
 358         $min ||= 0;
 359         $max ||= 0;
 360         $self->{article} = $min;
 361         my $est_size = $max - $min;
 362         "211 $est_size $min $max $group";
 363 }
 364
 365 sub article_adj ($$) {
 366         my ($self, $off) = @_;
 367         my $ng = $self->{ng} or return '412 no newsgroup selected';
 368
 369         my $n = $self->{article};
 370         defined $n or return '420 no current article has been selected';
 371
 372         $n += $off;
 373         my $mid = $ng->mm->mid_for($n);
 374         unless ($mid) {
 375                 $n = $off > 0 ? 'next' : 'previous';
 376                 return "421 no $n article in this group";
 377         }
 378         $self->{article} = $n;
 379         "223 $n <$mid> article retrieved - request text separately";
 380 }
 381
 382 sub cmd_next ($) { article_adj($_[0], 1) }
 383 sub cmd_last ($) { article_adj($_[0], -1) }
 384
 385 # We want to encourage using email and CC-ing everybody involved to avoid
 386 # the single-point-of-failure a single server provides.
 387 sub cmd_post ($) {
 388         my ($self) = @_;
 389         my $ng = $self->{ng};
 390         $ng ? "440 mailto:$ng->{-primary_address} to post"
 391                 : '440 posting not allowed'
 392 }
 393
 394 sub cmd_quit ($) {
 395         my ($self) = @_;
 396         res($self, '205 closing connection - goodbye!');
 397         $self->close;
 398         undef;
 399 }
 400
 401 sub header_append ($$$) {
 402         my ($hdr, $k, $v) = @_;
 403         my @v = $hdr->header($k);
 404         foreach (@v) {
 405                 return if $v eq $_;
 406         }
 407         $hdr->header_set($k, @v, $v);
 408 }
 409
 410 sub set_nntp_headers {
 411         my ($hdr, $ng, $n, $mid) = @_;
 412
 413         # clobber some
 414         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 415         $hdr->header_set('Xref', xref($ng, $n));
 416         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 417         if (my $url = $ng->base_url) {
 418                 $mid = mid_escape($mid);
 419                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 420                 header_append($hdr, 'List-Archive', "<$url>");
 421         }
 422 }
 423
 424 sub art_lookup ($$$) {
 425         my ($self, $art, $set_headers) = @_;
 426         my $ng = $self->{ng};
 427         my ($n, $mid);
 428         my $err;
 429         if (defined $art) {
 430                 if ($art =~ /\A\d+\z/o) {
 431                         $err = '423 no such article number in this group';
 432                         $n = int($art);
 433                         goto find_mid;
 434                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 435                         $mid = $1;
 436                         $err = r430;
 437                         $n = $ng->mm->num_for($mid) if $ng;
 438                         goto found if defined $n;
 439                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 440                                 $n = $g->mm->num_for($mid);
 441                                 if (defined $n) {
 442                                         $ng = $g;
 443                                         goto found;
 444                                 }
 445                         }
 446                         return $err;
 447                 } else {
 448                         return r501;
 449                 }
 450         } else {
 451                 $err = '420 no current article has been selected';
 452                 $n = $self->{article};
 453                 defined $n or return $err;
 454 find_mid:
 455                 $ng or return '412 no newsgroup has been selected';
 456                 $mid = $ng->mm->mid_for($n);
 457                 defined $mid or return $err;
 458         }
 459 found:
 460         my $smsg = $ng->search->{over_ro}->get_art($n) or return $err;
 461         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 462         my $s = Email::Simple->new($msg);
 463         if ($set_headers) {
 464                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 465
 466                 # must be last
 467                 $s->body_set('') if ($set_headers == 2);
 468         }
 469         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 470 }
 471
 472 sub simple_body_write ($$) {
 473         my ($self, $s) = @_;
 474         my $body = $s->body;
 475         $s->body_set('');
 476         $body =~ s/^\./../smg;
 477         $body =~ s/(?<!\r)\n/\r\n/sg;
 478         do_more($self, $body);
 479         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 480         '.'
 481 }
 482
 483 sub set_art {
 484         my ($self, $art) = @_;
 485         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 486 }
 487
 488 sub _header ($) {
 489         my $hdr = $_[0]->header_obj->as_string;
 490         utf8::encode($hdr);
 491         $hdr
 492 }
 493
 494 sub cmd_article ($;$) {
 495         my ($self, $art) = @_;
 496         my $r = art_lookup($self, $art, 1);
 497         return $r unless ref $r;
 498         my ($n, $mid, $s) = @$r;
 499         set_art($self, $art);
 500         more($self, "220 $n <$mid> article retrieved - head and body follow");
 501         do_more($self, _header($s));
 502         do_more($self, "\r\n");
 503         simple_body_write($self, $s);
 504 }
 505
 506 sub cmd_head ($;$) {
 507         my ($self, $art) = @_;
 508         my $r = art_lookup($self, $art, 2);
 509         return $r unless ref $r;
 510         my ($n, $mid, $s) = @$r;
 511         set_art($self, $art);
 512         more($self, "221 $n <$mid> article retrieved - head follows");
 513         do_more($self, _header($s));
 514         '.'
 515 }
 516
 517 sub cmd_body ($;$) {
 518         my ($self, $art) = @_;
 519         my $r = art_lookup($self, $art, 0);
 520         return $r unless ref $r;
 521         my ($n, $mid, $s) = @$r;
 522         set_art($self, $art);
 523         more($self, "222 $n <$mid> article retrieved - body follows");
 524         simple_body_write($self, $s);
 525 }
 526
 527 sub cmd_stat ($;$) {
 528         my ($self, $art) = @_;
 529         my $r = art_lookup($self, $art, 0);
 530         return $r unless ref $r;
 531         my ($n, $mid, undef) = @$r;
 532         set_art($self, $art);
 533         "223 $n <$mid> article retrieved - request text separately";
 534 }
 535
 536 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 537
 538 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 539
 540 sub cmd_help ($) {
 541         my ($self) = @_;
 542         more($self, '100 help text follows');
 543         '.'
 544 }
 545
 546 sub get_range ($$) {
 547         my ($self, $range) = @_;
 548         my $ng = $self->{ng} or return '412 no news group has been selected';
 549         defined $range or return '420 No article(s) selected';
 550         my ($beg, $end);
 551         my ($min, $max) = $ng->mm->minmax;
 552         if ($range =~ /\A(\d+)\z/) {
 553                 $beg = $end = $1;
 554         } elsif ($range =~ /\A(\d+)-\z/) {
 555                 ($beg, $end) = ($1, $max);
 556         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 557                 ($beg, $end) = ($1, $2);
 558         } else {
 559                 return r501;
 560         }
 561         $beg = $min if ($beg < $min);
 562         $end = $max if ($end > $max);
 563         return '420 No article(s) selected' if ($beg > $end);
 564         [ $beg, $end ];
 565 }
 566
 567 sub long_response ($$) {
 568         my ($self, $cb) = @_;
 569         die "BUG: nested long response" if $self->{long_res};
 570
 571         my $fd = $self->{fd};
 572         defined $fd or return;
 573         # make sure we disable reading during a long response,
 574         # clients should not be sending us stuff and making us do more
 575         # work while we are stream a response to them
 576         $self->watch_read(0);
 577         my $t0 = now();
 578         $self->{long_res} = sub {
 579                 my $more = eval { $cb->() };
 580                 if ($@ || $self->{closed}) {
 581                         $self->{long_res} = undef;
 582
 583                         if ($@) {
 584                                 err($self,
 585                                     "%s during long response[$fd] - %0.6f",
 586                                     $@, now() - $t0);
 587                         }
 588                         if ($self->{closed}) {
 589                                 out($self, " deferred[$fd] aborted - %0.6f",
 590                                            now() - $t0);
 591                         } else {
 592                                 update_idle_time($self);
 593                                 $self->watch_read(1);
 594                         }
 595                 } elsif ($more) { # $self->{write_buf_size}:
 596                         # no recursion, schedule another call ASAP
 597                         # but only after all pending writes are done
 598                         update_idle_time($self);
 599
 600                         push @$nextq, $self;
 601                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 602                 } else { # all done!
 603                         $self->{long_res} = undef;
 604                         $self->watch_read(1);
 605                         res($self, '.');
 606                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 607                 }
 608         };
 609         $self->{long_res}->(); # kick off!
 610         undef;
 611 }
 612
 613 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 614         my ($self, $xhdr, $range) = @_;
 615
 616         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 617                 my ($ng, $n) = mid_lookup($self, $1);
 618                 return r430 unless $n;
 619                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 620         } else { # numeric range
 621                 $range = $self->{article} unless defined $range;
 622                 my $r = get_range($self, $range);
 623                 return $r unless ref $r;
 624                 my $mm = $self->{ng}->mm;
 625                 my ($beg, $end) = @$r;
 626                 more($self, $xhdr ? r221 : r225);
 627                 long_response($self, sub {
 628                         my $r = $mm->msg_range(\$beg, $end);
 629                         @$r or return;
 630                         more($self, join("\r\n", map {
 631                                 "$_->[0] <$_->[1]>"
 632                         } @$r));
 633                         1;
 634                 });
 635         }
 636 }
 637
 638 sub xref ($$) {
 639         my ($ng, $n) = @_;
 640         "$ng->{domain} $ng->{newsgroup}:$n"
 641 }
 642
 643 sub mid_lookup ($$) {
 644         my ($self, $mid) = @_;
 645         my $self_ng = $self->{ng};
 646         if ($self_ng) {
 647                 my $n = $self_ng->mm->num_for($mid);
 648                 return ($self_ng, $n) if defined $n;
 649         }
 650         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 651                 next if defined $self_ng && $ng eq $self_ng;
 652                 my $n = $ng->mm->num_for($mid);
 653                 return ($ng, $n) if defined $n;
 654         }
 655         (undef, undef);
 656 }
 657
 658 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 659         my ($self, $xhdr, $range) = @_;
 660
 661         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 662                 my ($ng, $n) = mid_lookup($self, $1);
 663                 return r430 unless $n;
 664                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 665         } else { # numeric range
 666                 $range = $self->{article} unless defined $range;
 667                 my $r = get_range($self, $range);
 668                 return $r unless ref $r;
 669                 my $ng = $self->{ng};
 670                 my $mm = $ng->mm;
 671                 my ($beg, $end) = @$r;
 672                 more($self, $xhdr ? r221 : r225);
 673                 long_response($self, sub {
 674                         my $r = $mm->msg_range(\$beg, $end);
 675                         @$r or return;
 676                         more($self, join("\r\n", map {
 677                                 # TODO: use $_->[1] (mid) to fill
 678                                 # Xref: from other inboxes
 679                                 my $num = $_->[0];
 680                                 "$num ".xref($ng, $num);
 681                         } @$r));
 682                         1;
 683                 });
 684         }
 685 }
 686
 687 sub search_header_for {
 688         my ($srch, $num, $field) = @_;
 689         my $smsg = $srch->{over_ro}->get_art($num) or return;
 690         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 691         $smsg->{$field};
 692 }
 693
 694 sub hdr_searchmsg ($$$$) {
 695         my ($self, $xhdr, $field, $range) = @_;
 696         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 697                 my ($ng, $n) = mid_lookup($self, $1);
 698                 return r430 unless defined $n;
 699                 my $v = search_header_for($ng->search, $n, $field);
 700                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 701         } else { # numeric range
 702                 $range = $self->{article} unless defined $range;
 703                 my $srch = $self->{ng}->search;
 704                 my $mm = $self->{ng}->mm;
 705                 my $r = get_range($self, $range);
 706                 return $r unless ref $r;
 707                 my ($beg, $end) = @$r;
 708                 more($self, $xhdr ? r221 : r225);
 709                 my $cur = $beg;
 710                 long_response($self, sub {
 711                         my $msgs = $srch->query_xover($cur, $end);
 712                         my $nr = scalar @$msgs or return;
 713                         my $tmp = '';
 714                         foreach my $s (@$msgs) {
 715                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 716                         }
 717                         utf8::encode($tmp);
 718                         do_more($self, $tmp);
 719                         $cur = $msgs->[-1]->{num} + 1;
 720                 });
 721         }
 722 }
 723
 724 sub do_hdr ($$$;$) {
 725         my ($self, $xhdr, $header, $range) = @_;
 726         my $sub = lc $header;
 727         if ($sub eq 'message-id') {
 728                 hdr_message_id($self, $xhdr, $range);
 729         } elsif ($sub eq 'xref') {
 730                 hdr_xref($self, $xhdr, $range);
 731         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 732                                 bytes|lines)\z/x) {
 733                 hdr_searchmsg($self, $xhdr, $sub, $range);
 734         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 735                 hdr_searchmsg($self, $xhdr, $1, $range);
 736         } else {
 737                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 738         }
 739 }
 740
 741 # RFC 3977
 742 sub cmd_hdr ($$;$) {
 743         my ($self, $header, $range) = @_;
 744         do_hdr($self, 0, $header, $range);
 745 }
 746
 747 # RFC 2980
 748 sub cmd_xhdr ($$;$) {
 749         my ($self, $header, $range) = @_;
 750         do_hdr($self, 1, $header, $range);
 751 }
 752
 753 sub hdr_mid_prefix ($$$$$) {
 754         my ($self, $xhdr, $ng, $n, $mid) = @_;
 755         return $mid if $xhdr;
 756
 757         # HDR for RFC 3977 users
 758         if (my $self_ng = $self->{ng}) {
 759                 ($self_ng eq $ng) ? $n : '0';
 760         } else {
 761                 '0';
 762         }
 763 }
 764
 765 sub hdr_mid_response ($$$$$$) {
 766         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 767         my $res = '';
 768         if ($xhdr) {
 769                 $res .= r221 . "\r\n";
 770                 $res .= "$mid $v\r\n";
 771         } else {
 772                 $res .= r225 . "\r\n";
 773                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 774                 $res .= "$pfx $v\r\n";
 775         }
 776         res($self, $res .= '.');
 777         undef;
 778 }
 779
 780 sub cmd_xrover ($;$) {
 781         my ($self, $range) = @_;
 782         my $ng = $self->{ng} or return '412 no newsgroup selected';
 783         (defined $range && $range =~ /[<>]/) and
 784                 return '420 No article(s) selected'; # no message IDs
 785
 786         $range = $self->{article} unless defined $range;
 787         my $r = get_range($self, $range);
 788         return $r unless ref $r;
 789         my ($beg, $end) = @$r;
 790         my $mm = $ng->mm;
 791         my $srch = $ng->search;
 792         more($self, '224 Overview information follows');
 793
 794         long_response($self, sub {
 795                 my $h = search_header_for($srch, $beg, 'references');
 796                 more($self, "$beg $h") if defined($h);
 797                 $beg++ < $end;
 798         });
 799 }
 800
 801 sub over_line ($$) {
 802         my ($num, $smsg) = @_;
 803         # n.b. field access and procedural calls can be
 804         # 10%-15% faster than OO method calls:
 805         my $s = join("\t", $num,
 806                 $smsg->{subject},
 807                 $smsg->{from},
 808                 PublicInbox::SearchMsg::date($smsg),
 809                 "<$smsg->{mid}>",
 810                 $smsg->{references},
 811                 $smsg->{bytes},
 812                 $smsg->{lines});
 813         utf8::encode($s);
 814         $s
 815 }
 816
 817 sub cmd_over ($;$) {
 818         my ($self, $range) = @_;
 819         if ($range && $range =~ /\A<(.+)>\z/) {
 820                 my ($ng, $n) = mid_lookup($self, $1);
 821                 defined $n or return r430;
 822                 my $smsg = $ng->search->{over_ro}->get_art($n) or return r430;
 823                 more($self, '224 Overview information follows (multi-line)');
 824
 825                 # Only set article number column if it's the current group
 826                 my $self_ng = $self->{ng};
 827                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 828                 more($self, over_line($n, $smsg));
 829                 '.';
 830         } else {
 831                 cmd_xover($self, $range);
 832         }
 833 }
 834
 835 sub cmd_xover ($;$) {
 836         my ($self, $range) = @_;
 837         $range = $self->{article} unless defined $range;
 838         my $r = get_range($self, $range);
 839         return $r unless ref $r;
 840         my ($beg, $end) = @$r;
 841         more($self, "224 Overview information follows for $beg to $end");
 842         my $srch = $self->{ng}->search;
 843         my $cur = $beg;
 844         long_response($self, sub {
 845                 my $msgs = $srch->query_xover($cur, $end);
 846                 my $nr = scalar @$msgs or return;
 847
 848                 # OVERVIEW.FMT
 849                 more($self, join("\r\n", map {
 850                         over_line($_->{num}, $_);
 851                         } @$msgs));
 852                 $cur = $msgs->[-1]->{num} + 1;
 853         });
 854 }
 855
 856 sub cmd_xpath ($$) {
 857         my ($self, $mid) = @_;
 858         return r501 unless $mid =~ /\A<(.+)>\z/;
 859         $mid = $1;
 860         my @paths;
 861         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 862                 my $n = $ng->mm->num_for($mid);
 863                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 864         }
 865         return '430 no such article on server' unless @paths;
 866         '223 '.join(' ', @paths);
 867 }
 868
 869 sub res ($$) {
 870         my ($self, $line) = @_;
 871         do_write($self, $line . "\r\n");
 872 }
 873
 874 sub more ($$) {
 875         my ($self, $line) = @_;
 876         do_more($self, $line . "\r\n");
 877 }
 878
 879 sub do_write ($$) {
 880         my ($self, $data) = @_;
 881         my $done = $self->write($data);
 882         return if $self->{closed};
 883
 884         # Do not watch for readability if we have data in the queue,
 885         # instead re-enable watching for readability when we can
 886         $self->watch_read(0) if (!$done || $self->{long_res});
 887
 888         $done;
 889 }
 890
 891 sub err ($$;@) {
 892         my ($self, $fmt, @args) = @_;
 893         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 894 }
 895
 896 sub out ($$;@) {
 897         my ($self, $fmt, @args) = @_;
 898         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 899 }
 900
 901 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 902
 903 sub do_more ($$) {
 904         my ($self, $data) = @_;
 905         if (MSG_MORE && !$self->{write_buf_size}) {
 906                 my $n = send($self->{sock}, $data, MSG_MORE);
 907                 if (defined $n) {
 908                         my $dlen = length($data);
 909                         return 1 if $n == $dlen; # all done!
 910                         $data = substr($data, $n, $dlen - $n);
 911                 }
 912         }
 913         do_write($self, $data);
 914 }
 915
 916 # callbacks for Danga::Socket
 917
 918 sub event_hup { $_[0]->close }
 919 sub event_err { $_[0]->close }
 920
 921 sub event_write {
 922         my ($self) = @_;
 923         update_idle_time($self);
 924         # only continue watching for readability when we are done writing:
 925         if ($self->write(undef) == 1 && !$self->{long_res}) {
 926                 $self->watch_read(1);
 927         }
 928 }
 929
 930 sub event_read {
 931         my ($self) = @_;
 932         use constant LINE_MAX => 512; # RFC 977 section 2.3
 933         my $r = 1;
 934
 935         my $buf = $self->read(LINE_MAX) or return $self->close;
 936         $self->{rbuf} .= $$buf;
 937         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 938                 my $line = $1;
 939                 return $self->close if $line =~ /[[:cntrl:]]/s;
 940                 my $t0 = now();
 941                 my $fd = $self->{fd};
 942                 $r = eval { process_line($self, $line) };
 943                 my $d = $self->{long_res} ?
 944                         " deferred[$fd]" : '';
 945                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 946         }
 947
 948         return $self->close if $r < 0;
 949         my $len = length($self->{rbuf});
 950         return $self->close if ($len >= LINE_MAX);
 951         update_idle_time($self);
 952 }
 953
 954 sub watch_read {
 955         my ($self, $bool) = @_;
 956         my $rv = $self->SUPER::watch_read($bool);
 957         if ($bool && $self->{rbuf} ne '') {
 958                 # Force another read if there is a pipelined request.
 959                 # We don't know if the socket has anything for us to read,
 960                 # and we must double-check again by the time the timer fires
 961                 # in case we really did dispatch a read event and started
 962                 # another long response.
 963                 push @$nextq, $self;
 964                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 965         }
 966         $rv;
 967 }
 968
 969 sub not_idle_long ($$) {
 970         my ($self, $now) = @_;
 971         defined(my $fd = $self->{fd}) or return;
 972         my $ary = $EXPMAP->{$fd} or return;
 973         my $exp_at = $ary->[0] + $EXPTIME;
 974         $exp_at > $now;
 975 }
 976
 977 # for graceful shutdown in PublicInbox::Daemon:
 978 sub busy {
 979         my ($self, $now) = @_;
 980         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
 981          not_idle_long($self, $now));
 982 }
 983
 984 1;