lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27
  28 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_read($nntp);
  57
  58                         # maybe there's more pipelined data, or we'll have
  59                         # to register it for socket-readiness notifications
  60                         if (!$nntp->{long_res} && !$nntp->{closed}) {
  61                                 check_read($nntp);
  62                         }
  63                 }
  64         }
  65 }
  66
  67 sub update_idle_time ($) {
  68         my ($self) = @_;
  69         my $sock = $self->{sock} or return;
  70         my $fd = fileno($sock);
  71         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  72 }
  73
  74 sub expire_old () {
  75         my $now = now();
  76         my $exp = $EXPTIME;
  77         my $old = $now - $exp;
  78         my $nr = 0;
  79         my %new;
  80         while (my ($fd, $v) = each %$EXPMAP) {
  81                 my ($idle_time, $nntp) = @$v;
  82                 if ($idle_time < $old) {
  83                         $nntp->close; # idempotent
  84                 } else {
  85                         ++$nr;
  86                         $new{$fd} = $v;
  87                 }
  88         }
  89         $EXPMAP = \%new;
  90         if ($nr) {
  91                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  92         } else {
  93                 $expt = undef;
  94                 # noop to kick outselves out of the loop ASAP so descriptors
  95                 # really get closed
  96                 PublicInbox::EvCleanup::asap(sub {});
  97         }
  98 }
  99
 100 sub new ($$$) {
 101         my ($class, $sock, $nntpd) = @_;
 102         my $self = fields::new($class);
 103         $self->SUPER::new($sock);
 104         $self->{nntpd} = $nntpd;
 105         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
 106         $self->{rbuf} = '';
 107         $self->watch_read(1);
 108         update_idle_time($self);
 109         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 110         $self;
 111 }
 112
 113 sub args_ok ($$) {
 114         my ($cb, $argc) = @_;
 115         my $tot = prototype $cb;
 116         my ($nreq, undef) = split(';', $tot);
 117         $nreq = ($nreq =~ tr/$//) - 1;
 118         $tot = ($tot =~ tr/$//) - 1;
 119         ($argc <= $tot && $argc >= $nreq);
 120 }
 121
 122 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 123 sub process_line ($$) {
 124         my ($self, $l) = @_;
 125         my ($req, @args) = split(/[ \t]/, $l);
 126         return 1 unless defined($req); # skip blank line
 127         $req = lc($req);
 128         $req = eval {
 129                 no strict 'refs';
 130                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 131         };
 132         return res($self, '500 command not recognized') unless $req;
 133         return res($self, r501) unless args_ok($req, scalar @args);
 134
 135         my $res = eval { $req->($self, @args) };
 136         my $err = $@;
 137         if ($err && !$self->{closed}) {
 138                 local $/ = "\n";
 139                 chomp($l);
 140                 err($self, 'error from: %s (%s)', $l, $err);
 141                 $res = '503 program fault - command not performed';
 142         }
 143         return 0 unless defined $res;
 144         res($self, $res);
 145 }
 146
 147 sub cmd_mode ($$) {
 148         my ($self, $arg) = @_;
 149         $arg = uc $arg;
 150         return r501 unless $arg eq 'READER';
 151         '201 Posting prohibited';
 152 }
 153
 154 sub cmd_slave ($) { '202 slave status noted' }
 155
 156 sub cmd_xgtitle ($;$) {
 157         my ($self, $wildmat) = @_;
 158         more($self, '282 list of groups and descriptions follows');
 159         list_newsgroups($self, $wildmat);
 160         '.'
 161 }
 162
 163 sub list_overview_fmt ($) {
 164         my ($self) = @_;
 165         do_more($self, $OVERVIEW_FMT);
 166 }
 167
 168 sub list_headers ($;$) {
 169         my ($self) = @_;
 170         do_more($self, $LIST_HEADERS);
 171 }
 172
 173 sub list_active ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 group_line($self, $ng);
 179         }
 180 }
 181
 182 sub list_active_times ($;$) {
 183         my ($self, $wildmat) = @_;
 184         wildmat2re($wildmat);
 185         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 186                 $ng->{newsgroup} =~ $wildmat or next;
 187                 my $c = eval { $ng->mm->created_at } || time;
 188                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 189         }
 190 }
 191
 192 sub list_newsgroups ($;$) {
 193         my ($self, $wildmat) = @_;
 194         wildmat2re($wildmat);
 195         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 196                 $ng->{newsgroup} =~ $wildmat or next;
 197                 my $d = $ng->description;
 198                 more($self, "$ng->{newsgroup} $d");
 199         }
 200 }
 201
 202 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 203 sub cmd_list ($;$$) {
 204         my ($self, @args) = @_;
 205         if (scalar @args) {
 206                 my $arg = shift @args;
 207                 $arg =~ tr/A-Z./a-z_/;
 208                 $arg = "list_$arg";
 209                 return r501 if $DISABLED{$arg};
 210
 211                 $arg = eval {
 212                         no strict 'refs';
 213                         *{$arg}{CODE};
 214                 };
 215                 return r501 unless $arg && args_ok($arg, scalar @args);
 216                 more($self, '215 information follows');
 217                 $arg->($self, @args);
 218         } else {
 219                 more($self, '215 list of newsgroups follows');
 220                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 221                         group_line($self, $ng);
 222                 }
 223         }
 224         '.'
 225 }
 226
 227 sub cmd_listgroup ($;$) {
 228         my ($self, $group) = @_;
 229         if (defined $group) {
 230                 my $res = cmd_group($self, $group);
 231                 return $res if ($res !~ /\A211 /);
 232                 more($self, $res);
 233         }
 234
 235         $self->{ng} or return '412 no newsgroup selected';
 236         my $n = 0;
 237         long_response($self, sub {
 238                 my $ary = $self->{ng}->mm->ids_after(\$n);
 239                 scalar @$ary or return;
 240                 more($self, join("\r\n", @$ary));
 241                 1;
 242         });
 243 }
 244
 245 sub parse_time ($$;$) {
 246         my ($date, $time, $gmt) = @_;
 247         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 248         if (defined $gmt) {
 249                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 250                 $gmt = 1;
 251         }
 252         my @now = $gmt ? gmtime : localtime;
 253         my ($YYYY, $MM, $DD);
 254         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 255                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 256         } else { # legacy clients send YYMMDD
 257                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 258                 my $cur_year = $now[5] + 1900;
 259                 if ($YYYY > $cur_year) {
 260                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 261                 }
 262         }
 263         if ($gmt) {
 264                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 265         } else {
 266                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 267         }
 268 }
 269
 270 sub group_line ($$) {
 271         my ($self, $ng) = @_;
 272         my ($min, $max) = $ng->mm->minmax;
 273         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 274 }
 275
 276 sub cmd_newgroups ($$$;$$) {
 277         my ($self, $date, $time, $gmt, $dists) = @_;
 278         my $ts = eval { parse_time($date, $time, $gmt) };
 279         return r501 if $@;
 280
 281         # TODO dists
 282         more($self, '231 list of new newsgroups follows');
 283         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 284                 my $c = eval { $ng->mm->created_at } || 0;
 285                 next unless $c > $ts;
 286                 group_line($self, $ng);
 287         }
 288         '.'
 289 }
 290
 291 sub wildmat2re (;$) {
 292         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 293         my %keep;
 294         my $salt = rand;
 295         my $tmp = $_[0];
 296
 297         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 298                 my $orig = $1;
 299                 my $key = sha1_hex($orig . $salt);
 300                 $orig =~ s/([^\w\-])+/\Q$1/g;
 301                 $keep{$key} = $orig;
 302                 $key
 303                 #gex;
 304         my %map = ('*' => '.*', '?' => '.' );
 305         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 306         if (scalar %keep) {
 307                 $tmp =~ s#([a-f0-9]{40})#
 308                         my $orig = $keep{$1};
 309                         defined $orig ? $orig : $1;
 310                         #ge;
 311         }
 312         $_[0] = qr/\A$tmp\z/;
 313 }
 314
 315 sub ngpat2re (;$) {
 316         return $_[0] = qr/\A\z/ unless defined $_[0];
 317         my %map = ('*' => '.*', ',' => '|');
 318         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 319         $_[0] = qr/\A(?:$_[0])\z/;
 320 }
 321
 322 sub cmd_newnews ($$$$;$$) {
 323         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 324         my $ts = eval { parse_time($date, $time, $gmt) };
 325         return r501 if $@;
 326         more($self, '230 list of new articles by message-id follows');
 327         my ($keep, $skip) = split('!', $newsgroups, 2);
 328         ngpat2re($keep);
 329         ngpat2re($skip);
 330         my @over;
 331         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 332                 $ng->{newsgroup} =~ $keep or next;
 333                 $ng->{newsgroup} =~ $skip and next;
 334                 my $over = $ng->over or next;
 335                 push @over, $over;
 336         };
 337         return '.' unless @over;
 338
 339         my $prev = 0;
 340         long_response($self, sub {
 341                 my $over = $over[0];
 342                 my $msgs = $over->query_ts($ts, $prev);
 343                 if (scalar @$msgs) {
 344                         more($self, '<' .
 345                                 join(">\r\n<", map { $_->mid } @$msgs ).
 346                                 '>');
 347                         $prev = $msgs->[-1]->{num};
 348                 } else {
 349                         shift @over;
 350                         if (@over) { # continue onto next newsgroup
 351                                 $prev = 0;
 352                                 return 1;
 353                         } else { # break out of the long response.
 354                                 return;
 355                         }
 356                 }
 357         });
 358 }
 359
 360 sub cmd_group ($$) {
 361         my ($self, $group) = @_;
 362         my $no_such = '411 no such news group';
 363         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 364
 365         $self->{ng} = $ng;
 366         my ($min, $max) = $ng->mm->minmax;
 367         $min ||= 0;
 368         $max ||= 0;
 369         $self->{article} = $min;
 370         my $est_size = $max - $min;
 371         "211 $est_size $min $max $group";
 372 }
 373
 374 sub article_adj ($$) {
 375         my ($self, $off) = @_;
 376         my $ng = $self->{ng} or return '412 no newsgroup selected';
 377
 378         my $n = $self->{article};
 379         defined $n or return '420 no current article has been selected';
 380
 381         $n += $off;
 382         my $mid = $ng->mm->mid_for($n);
 383         unless ($mid) {
 384                 $n = $off > 0 ? 'next' : 'previous';
 385                 return "421 no $n article in this group";
 386         }
 387         $self->{article} = $n;
 388         "223 $n <$mid> article retrieved - request text separately";
 389 }
 390
 391 sub cmd_next ($) { article_adj($_[0], 1) }
 392 sub cmd_last ($) { article_adj($_[0], -1) }
 393
 394 # We want to encourage using email and CC-ing everybody involved to avoid
 395 # the single-point-of-failure a single server provides.
 396 sub cmd_post ($) {
 397         my ($self) = @_;
 398         my $ng = $self->{ng};
 399         $ng ? "440 mailto:$ng->{-primary_address} to post"
 400                 : '440 posting not allowed'
 401 }
 402
 403 sub cmd_quit ($) {
 404         my ($self) = @_;
 405         res($self, '205 closing connection - goodbye!');
 406         $self->close;
 407         undef;
 408 }
 409
 410 sub header_append ($$$) {
 411         my ($hdr, $k, $v) = @_;
 412         my @v = $hdr->header($k);
 413         foreach (@v) {
 414                 return if $v eq $_;
 415         }
 416         $hdr->header_set($k, @v, $v);
 417 }
 418
 419 sub xref ($$$$) {
 420         my ($self, $ng, $n, $mid) = @_;
 421         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 422
 423         # num_for is pretty cheap and sometimes we'll lookup the existence
 424         # of an article without getting even the OVER info.  In other words,
 425         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 426         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 427         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 428                 next if $ng eq $other;
 429                 my $num = eval { $other->mm->num_for($mid) } or next;
 430                 $ret .= " $other->{newsgroup}:$num";
 431         }
 432         $ret;
 433 }
 434
 435 sub set_nntp_headers ($$$$$) {
 436         my ($self, $hdr, $ng, $n, $mid) = @_;
 437
 438         # why? leafnode requires a Path: header for some inexplicable
 439         # reason.  We'll fake the shortest one possible.
 440         $hdr->header_set('Path', 'y');
 441
 442         # leafnode (and maybe other NNTP clients) have trouble dealing
 443         # with v2 messages which have multiple Message-IDs (either due
 444         # to our own content-based dedupe or buggy git-send-email versions).
 445         my @mids = $hdr->header('Message-ID');
 446         if (scalar(@mids) > 1) {
 447                 my $mid0 = "<$mid>";
 448                 $hdr->header_set('Message-ID', $mid0);
 449                 my @alt = $hdr->header('X-Alt-Message-ID');
 450                 my %seen = map { $_ => 1 } (@alt, $mid0);
 451                 foreach my $m (@mids) {
 452                         next if $seen{$m}++;
 453                         push @alt, $m;
 454                 }
 455                 $hdr->header_set('X-Alt-Message-ID', @alt);
 456         }
 457
 458         # clobber some
 459         my $xref = xref($self, $ng, $n, $mid);
 460         $hdr->header_set('Xref', $xref);
 461         $xref =~ s/:[0-9]+//g;
 462         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 463         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 464         if (my $url = $ng->base_url) {
 465                 $mid = mid_escape($mid);
 466                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 467                 header_append($hdr, 'List-Archive', "<$url>");
 468         }
 469 }
 470
 471 sub art_lookup ($$$) {
 472         my ($self, $art, $set_headers) = @_;
 473         my $ng = $self->{ng};
 474         my ($n, $mid);
 475         my $err;
 476         if (defined $art) {
 477                 if ($art =~ /\A[0-9]+\z/) {
 478                         $err = '423 no such article number in this group';
 479                         $n = int($art);
 480                         goto find_mid;
 481                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 482                         $mid = $1;
 483                         $err = r430;
 484                         $n = $ng->mm->num_for($mid) if $ng;
 485                         goto found if defined $n;
 486                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 487                                 $n = $g->mm->num_for($mid);
 488                                 if (defined $n) {
 489                                         $ng = $g;
 490                                         goto found;
 491                                 }
 492                         }
 493                         return $err;
 494                 } else {
 495                         return r501;
 496                 }
 497         } else {
 498                 $err = '420 no current article has been selected';
 499                 $n = $self->{article};
 500                 defined $n or return $err;
 501 find_mid:
 502                 $ng or return '412 no newsgroup has been selected';
 503                 $mid = $ng->mm->mid_for($n);
 504                 defined $mid or return $err;
 505         }
 506 found:
 507         my $smsg = $ng->over->get_art($n) or return $err;
 508         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 509         my $s = Email::Simple->new($msg);
 510         if ($set_headers) {
 511                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 512
 513                 # must be last
 514                 $s->body_set('') if ($set_headers == 2);
 515         }
 516         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 517 }
 518
 519 sub simple_body_write ($$) {
 520         my ($self, $s) = @_;
 521         my $body = $s->body;
 522         $s->body_set('');
 523         $body =~ s/^\./../smg;
 524         $body =~ s/(?<!\r)\n/\r\n/sg;
 525         do_more($self, $body);
 526         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 527         '.'
 528 }
 529
 530 sub set_art {
 531         my ($self, $art) = @_;
 532         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 533 }
 534
 535 sub _header ($) {
 536         my $hdr = $_[0]->header_obj->as_string;
 537         utf8::encode($hdr);
 538         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 539
 540         # for leafnode compatibility, we need to ensure Message-ID headers
 541         # are only a single line.  We can't subclass Email::Simple::Header
 542         # and override _default_fold_at in here, either; since that won't
 543         # affect messages already in the archive.
 544         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 545
 546         $hdr
 547 }
 548
 549 sub cmd_article ($;$) {
 550         my ($self, $art) = @_;
 551         my $r = art_lookup($self, $art, 1);
 552         return $r unless ref $r;
 553         my ($n, $mid, $s) = @$r;
 554         set_art($self, $art);
 555         more($self, "220 $n <$mid> article retrieved - head and body follow");
 556         do_more($self, _header($s));
 557         do_more($self, "\r\n");
 558         simple_body_write($self, $s);
 559 }
 560
 561 sub cmd_head ($;$) {
 562         my ($self, $art) = @_;
 563         my $r = art_lookup($self, $art, 2);
 564         return $r unless ref $r;
 565         my ($n, $mid, $s) = @$r;
 566         set_art($self, $art);
 567         more($self, "221 $n <$mid> article retrieved - head follows");
 568         do_more($self, _header($s));
 569         '.'
 570 }
 571
 572 sub cmd_body ($;$) {
 573         my ($self, $art) = @_;
 574         my $r = art_lookup($self, $art, 0);
 575         return $r unless ref $r;
 576         my ($n, $mid, $s) = @$r;
 577         set_art($self, $art);
 578         more($self, "222 $n <$mid> article retrieved - body follows");
 579         simple_body_write($self, $s);
 580 }
 581
 582 sub cmd_stat ($;$) {
 583         my ($self, $art) = @_;
 584         my $r = art_lookup($self, $art, 0);
 585         return $r unless ref $r;
 586         my ($n, $mid, undef) = @$r;
 587         set_art($self, $art);
 588         "223 $n <$mid> article retrieved - request text separately";
 589 }
 590
 591 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 592
 593 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 594
 595 sub cmd_help ($) {
 596         my ($self) = @_;
 597         more($self, '100 help text follows');
 598         '.'
 599 }
 600
 601 sub get_range ($$) {
 602         my ($self, $range) = @_;
 603         my $ng = $self->{ng} or return '412 no news group has been selected';
 604         defined $range or return '420 No article(s) selected';
 605         my ($beg, $end);
 606         my ($min, $max) = $ng->mm->minmax;
 607         if ($range =~ /\A([0-9]+)\z/) {
 608                 $beg = $end = $1;
 609         } elsif ($range =~ /\A([0-9]+)-\z/) {
 610                 ($beg, $end) = ($1, $max);
 611         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 612                 ($beg, $end) = ($1, $2);
 613         } else {
 614                 return r501;
 615         }
 616         $beg = $min if ($beg < $min);
 617         $end = $max if ($end > $max);
 618         return '420 No article(s) selected' if ($beg > $end);
 619         [ $beg, $end ];
 620 }
 621
 622 sub long_response ($$) {
 623         my ($self, $cb) = @_;
 624         die "BUG: nested long response" if $self->{long_res};
 625
 626         my $fd = fileno($self->{sock});
 627         defined $fd or return;
 628         # make sure we disable reading during a long response,
 629         # clients should not be sending us stuff and making us do more
 630         # work while we are stream a response to them
 631         $self->watch_read(0);
 632         my $t0 = now();
 633         $self->{long_res} = sub {
 634                 my $more = eval { $cb->() };
 635                 if ($@ || $self->{closed}) {
 636                         $self->{long_res} = undef;
 637
 638                         if ($@) {
 639                                 err($self,
 640                                     "%s during long response[$fd] - %0.6f",
 641                                     $@, now() - $t0);
 642                         }
 643                         if ($self->{closed}) {
 644                                 out($self, " deferred[$fd] aborted - %0.6f",
 645                                            now() - $t0);
 646                         } else {
 647                                 update_idle_time($self);
 648                                 check_read($self);
 649                         }
 650                 } elsif ($more) { # scalar @{$self->{wbuf}}:
 651                         # no recursion, schedule another call ASAP
 652                         # but only after all pending writes are done
 653                         update_idle_time($self);
 654
 655                         push @$nextq, $self;
 656                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 657                 } else { # all done!
 658                         $self->{long_res} = undef;
 659                         check_read($self);
 660                         res($self, '.');
 661                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 662                 }
 663         };
 664         $self->{long_res}->(); # kick off!
 665         undef;
 666 }
 667
 668 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 669         my ($self, $xhdr, $range) = @_;
 670
 671         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 672                 my ($ng, $n) = mid_lookup($self, $1);
 673                 return r430 unless $n;
 674                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 675         } else { # numeric range
 676                 $range = $self->{article} unless defined $range;
 677                 my $r = get_range($self, $range);
 678                 return $r unless ref $r;
 679                 my $mm = $self->{ng}->mm;
 680                 my ($beg, $end) = @$r;
 681                 more($self, $xhdr ? r221 : r225);
 682                 long_response($self, sub {
 683                         my $r = $mm->msg_range(\$beg, $end);
 684                         @$r or return;
 685                         more($self, join("\r\n", map {
 686                                 "$_->[0] <$_->[1]>"
 687                         } @$r));
 688                         1;
 689                 });
 690         }
 691 }
 692
 693 sub mid_lookup ($$) {
 694         my ($self, $mid) = @_;
 695         my $self_ng = $self->{ng};
 696         if ($self_ng) {
 697                 my $n = $self_ng->mm->num_for($mid);
 698                 return ($self_ng, $n) if defined $n;
 699         }
 700         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 701                 next if defined $self_ng && $ng eq $self_ng;
 702                 my $n = $ng->mm->num_for($mid);
 703                 return ($ng, $n) if defined $n;
 704         }
 705         (undef, undef);
 706 }
 707
 708 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 709         my ($self, $xhdr, $range) = @_;
 710
 711         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 712                 my $mid = $1;
 713                 my ($ng, $n) = mid_lookup($self, $mid);
 714                 return r430 unless $n;
 715                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 716                                 xref($self, $ng, $n, $mid));
 717         } else { # numeric range
 718                 $range = $self->{article} unless defined $range;
 719                 my $r = get_range($self, $range);
 720                 return $r unless ref $r;
 721                 my $ng = $self->{ng};
 722                 my $mm = $ng->mm;
 723                 my ($beg, $end) = @$r;
 724                 more($self, $xhdr ? r221 : r225);
 725                 long_response($self, sub {
 726                         my $r = $mm->msg_range(\$beg, $end);
 727                         @$r or return;
 728                         more($self, join("\r\n", map {
 729                                 my $num = $_->[0];
 730                                 "$num ".xref($self, $ng, $num, $_->[1]);
 731                         } @$r));
 732                         1;
 733                 });
 734         }
 735 }
 736
 737 sub over_header_for {
 738         my ($over, $num, $field) = @_;
 739         my $smsg = $over->get_art($num) or return;
 740         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 741         $smsg->{$field};
 742 }
 743
 744 sub hdr_searchmsg ($$$$) {
 745         my ($self, $xhdr, $field, $range) = @_;
 746         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 747                 my ($ng, $n) = mid_lookup($self, $1);
 748                 return r430 unless defined $n;
 749                 my $v = over_header_for($ng->over, $n, $field);
 750                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 751         } else { # numeric range
 752                 $range = $self->{article} unless defined $range;
 753                 my $over = $self->{ng}->over;
 754                 my $mm = $self->{ng}->mm;
 755                 my $r = get_range($self, $range);
 756                 return $r unless ref $r;
 757                 my ($beg, $end) = @$r;
 758                 more($self, $xhdr ? r221 : r225);
 759                 my $cur = $beg;
 760                 long_response($self, sub {
 761                         my $msgs = $over->query_xover($cur, $end);
 762                         my $nr = scalar @$msgs or return;
 763                         my $tmp = '';
 764                         foreach my $s (@$msgs) {
 765                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 766                         }
 767                         utf8::encode($tmp);
 768                         do_more($self, $tmp);
 769                         $cur = $msgs->[-1]->{num} + 1;
 770                 });
 771         }
 772 }
 773
 774 sub do_hdr ($$$;$) {
 775         my ($self, $xhdr, $header, $range) = @_;
 776         my $sub = lc $header;
 777         if ($sub eq 'message-id') {
 778                 hdr_message_id($self, $xhdr, $range);
 779         } elsif ($sub eq 'xref') {
 780                 hdr_xref($self, $xhdr, $range);
 781         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 782                                 bytes|lines)\z/x) {
 783                 hdr_searchmsg($self, $xhdr, $sub, $range);
 784         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 785                 hdr_searchmsg($self, $xhdr, $1, $range);
 786         } else {
 787                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 788         }
 789 }
 790
 791 # RFC 3977
 792 sub cmd_hdr ($$;$) {
 793         my ($self, $header, $range) = @_;
 794         do_hdr($self, 0, $header, $range);
 795 }
 796
 797 # RFC 2980
 798 sub cmd_xhdr ($$;$) {
 799         my ($self, $header, $range) = @_;
 800         do_hdr($self, 1, $header, $range);
 801 }
 802
 803 sub hdr_mid_prefix ($$$$$) {
 804         my ($self, $xhdr, $ng, $n, $mid) = @_;
 805         return $mid if $xhdr;
 806
 807         # HDR for RFC 3977 users
 808         if (my $self_ng = $self->{ng}) {
 809                 ($self_ng eq $ng) ? $n : '0';
 810         } else {
 811                 '0';
 812         }
 813 }
 814
 815 sub hdr_mid_response ($$$$$$) {
 816         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 817         my $res = '';
 818         if ($xhdr) {
 819                 $res .= r221 . "\r\n";
 820                 $res .= "$mid $v\r\n";
 821         } else {
 822                 $res .= r225 . "\r\n";
 823                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 824                 $res .= "$pfx $v\r\n";
 825         }
 826         res($self, $res .= '.');
 827         undef;
 828 }
 829
 830 sub cmd_xrover ($;$) {
 831         my ($self, $range) = @_;
 832         my $ng = $self->{ng} or return '412 no newsgroup selected';
 833         (defined $range && $range =~ /[<>]/) and
 834                 return '420 No article(s) selected'; # no message IDs
 835
 836         $range = $self->{article} unless defined $range;
 837         my $r = get_range($self, $range);
 838         return $r unless ref $r;
 839         my ($beg, $end) = @$r;
 840         my $mm = $ng->mm;
 841         my $over = $ng->over;
 842         more($self, '224 Overview information follows');
 843
 844         long_response($self, sub {
 845                 my $h = over_header_for($over, $beg, 'references');
 846                 more($self, "$beg $h") if defined($h);
 847                 $beg++ < $end;
 848         });
 849 }
 850
 851 sub over_line ($$$$) {
 852         my ($self, $ng, $num, $smsg) = @_;
 853         # n.b. field access and procedural calls can be
 854         # 10%-15% faster than OO method calls:
 855         my $s = join("\t", $num,
 856                 $smsg->{subject},
 857                 $smsg->{from},
 858                 PublicInbox::SearchMsg::date($smsg),
 859                 "<$smsg->{mid}>",
 860                 $smsg->{references},
 861                 $smsg->{bytes},
 862                 $smsg->{lines},
 863                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 864         utf8::encode($s);
 865         $s
 866 }
 867
 868 sub cmd_over ($;$) {
 869         my ($self, $range) = @_;
 870         if ($range && $range =~ /\A<(.+)>\z/) {
 871                 my ($ng, $n) = mid_lookup($self, $1);
 872                 defined $n or return r430;
 873                 my $smsg = $ng->over->get_art($n) or return r430;
 874                 more($self, '224 Overview information follows (multi-line)');
 875
 876                 # Only set article number column if it's the current group
 877                 my $self_ng = $self->{ng};
 878                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 879                 more($self, over_line($self, $ng, $n, $smsg));
 880                 '.';
 881         } else {
 882                 cmd_xover($self, $range);
 883         }
 884 }
 885
 886 sub cmd_xover ($;$) {
 887         my ($self, $range) = @_;
 888         $range = $self->{article} unless defined $range;
 889         my $r = get_range($self, $range);
 890         return $r unless ref $r;
 891         my ($beg, $end) = @$r;
 892         more($self, "224 Overview information follows for $beg to $end");
 893         my $over = $self->{ng}->over;
 894         my $cur = $beg;
 895         long_response($self, sub {
 896                 my $msgs = $over->query_xover($cur, $end);
 897                 my $nr = scalar @$msgs or return;
 898
 899                 # OVERVIEW.FMT
 900                 more($self, join("\r\n", map {
 901                         over_line($self, $self->{ng}, $_->{num}, $_);
 902                         } @$msgs));
 903                 $cur = $msgs->[-1]->{num} + 1;
 904         });
 905 }
 906
 907 sub cmd_xpath ($$) {
 908         my ($self, $mid) = @_;
 909         return r501 unless $mid =~ /\A<(.+)>\z/;
 910         $mid = $1;
 911         my @paths;
 912         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 913                 my $n = $ng->mm->num_for($mid);
 914                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 915         }
 916         return '430 no such article on server' unless @paths;
 917         '223 '.join(' ', @paths);
 918 }
 919
 920 sub res ($$) {
 921         my ($self, $line) = @_;
 922         do_write($self, $line . "\r\n");
 923 }
 924
 925 sub more ($$) {
 926         my ($self, $line) = @_;
 927         do_more($self, $line . "\r\n");
 928 }
 929
 930 sub do_write ($$) {
 931         my ($self, $data) = @_;
 932         my $done = $self->write($data);
 933         return 0 if $self->{closed};
 934
 935         # Do not watch for readability if we have data in the queue,
 936         # instead re-enable watching for readability when we can
 937         $self->watch_read(0) if (!$done || $self->{long_res});
 938
 939         $done;
 940 }
 941
 942 sub err ($$;@) {
 943         my ($self, $fmt, @args) = @_;
 944         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 945 }
 946
 947 sub out ($$;@) {
 948         my ($self, $fmt, @args) = @_;
 949         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 950 }
 951
 952 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 953
 954 sub do_more ($$) {
 955         my ($self, $data) = @_;
 956         if (MSG_MORE && !scalar(@{$self->{wbuf}})) {
 957                 my $n = send($self->{sock}, $data, MSG_MORE);
 958                 if (defined $n) {
 959                         my $dlen = length($data);
 960                         return 1 if $n == $dlen; # all done!
 961                         $data = substr($data, $n, $dlen - $n);
 962                 }
 963         }
 964         do_write($self, $data);
 965 }
 966
 967 sub event_write {
 968         my ($self) = @_;
 969         update_idle_time($self);
 970         # only continue watching for readability when we are done writing:
 971         if ($self->write(undef) == 1 && !$self->{long_res}) {
 972                 $self->watch_read(1);
 973         }
 974 }
 975
 976 sub event_read {
 977         my ($self) = @_;
 978         use constant LINE_MAX => 512; # RFC 977 section 2.3
 979         my $rbuf = \($self->{rbuf});
 980         my $r;
 981
 982         if (index($$rbuf, "\n") < 0) {
 983                 my $off = length($$rbuf);
 984                 $r = sysread($self->{sock}, $$rbuf, LINE_MAX, $off);
 985                 unless (defined $r) {
 986                         return if $!{EAGAIN};
 987                         return $self->close;
 988                 }
 989                 return $self->close if $r == 0;
 990         }
 991         $r = 1;
 992         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 993                 my $line = $1;
 994                 return $self->close if $line =~ /[[:cntrl:]]/s;
 995                 my $t0 = now();
 996                 my $fd = fileno($self->{sock});
 997                 $r = eval { process_line($self, $line) };
 998                 my $d = $self->{long_res} ?
 999                         " deferred[$fd]" : '';
1000                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
1001         }
1002
1003         return $self->close if $r < 0;
1004         my $len = length($$rbuf);
1005         return $self->close if ($len >= LINE_MAX);
1006         update_idle_time($self);
1007 }
1008
1009 sub check_read {
1010         my ($self) = @_;
1011         if (index($self->{rbuf}, "\n") >= 0) {
1012                 # Force another read if there is a pipelined request.
1013                 # We don't know if the socket has anything for us to read,
1014                 # and we must double-check again by the time the timer fires
1015                 # in case we really did dispatch a read event and started
1016                 # another long response.
1017                 push @$nextq, $self;
1018                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
1019         } else {
1020                 # no pipelined requests available, let the kernel know
1021                 # to wake us up if there's more
1022                 $self->watch_read(1); # PublicInbox::DS::watch_read
1023         }
1024 }
1025
1026 sub not_idle_long ($$) {
1027         my ($self, $now) = @_;
1028         my $sock = $self->{sock} or return;
1029         defined(my $fd = fileno($sock)) or return;
1030         my $ary = $EXPMAP->{$fd} or return;
1031         my $exp_at = $ary->[0] + $EXPTIME;
1032         $exp_at > $now;
1033 }
1034
1035 # for graceful shutdown in PublicInbox::Daemon:
1036 sub busy {
1037         my ($self, $now) = @_;
1038         ($self->{rbuf} ne '' || $self->{long_res} ||
1039                 scalar(@{$self->{wbuf}}) || not_idle_long($self, $now));
1040 }
1041
1042 1;