lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  38
  39 my $EXPMAP; # fd -> [ idle_time, $self ]
  40 my $expt;
  41 our $EXPTIME = 180; # 3 minutes
  42 my $nextt;
  43
  44 my $nextq = [];
  45 sub next_tick () {
  46         $nextt = undef;
  47         my $q = $nextq;
  48         $nextq = [];
  49         foreach my $nntp (@$q) {
  50                 # for request && response protocols, always finish writing
  51                 # before finishing reading:
  52                 if (my $long_cb = $nntp->{long_res}) {
  53                         $nntp->write($long_cb);
  54                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  55                         event_read($nntp);
  56                 }
  57         }
  58 }
  59
  60 sub update_idle_time ($) {
  61         my ($self) = @_;
  62         my $fd = $self->{fd};
  63         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  64 }
  65
  66 sub expire_old () {
  67         my $now = now();
  68         my $exp = $EXPTIME;
  69         my $old = $now - $exp;
  70         my $nr = 0;
  71         my %new;
  72         while (my ($fd, $v) = each %$EXPMAP) {
  73                 my ($idle_time, $nntp) = @$v;
  74                 if ($idle_time < $old) {
  75                         $nntp->close; # idempotent
  76                 } else {
  77                         ++$nr;
  78                         $new{$fd} = $v;
  79                 }
  80         }
  81         $EXPMAP = \%new;
  82         if ($nr) {
  83                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  84         } else {
  85                 $expt = undef;
  86                 # noop to kick outselves out of the loop ASAP so descriptors
  87                 # really get closed
  88                 PublicInbox::EvCleanup::asap(sub {});
  89         }
  90 }
  91
  92 sub new ($$$) {
  93         my ($class, $sock, $nntpd) = @_;
  94         my $self = fields::new($class);
  95         $self->SUPER::new($sock);
  96         $self->{nntpd} = $nntpd;
  97         res($self, '201 server ready - post via email');
  98         $self->{rbuf} = '';
  99         $self->watch_read(1);
 100         update_idle_time($self);
 101         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 102         $self;
 103 }
 104
 105 sub args_ok ($$) {
 106         my ($cb, $argc) = @_;
 107         my $tot = prototype $cb;
 108         my ($nreq, undef) = split(';', $tot);
 109         $nreq = ($nreq =~ tr/$//) - 1;
 110         $tot = ($tot =~ tr/$//) - 1;
 111         ($argc <= $tot && $argc >= $nreq);
 112 }
 113
 114 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 115 sub process_line ($$) {
 116         my ($self, $l) = @_;
 117         my ($req, @args) = split(/\s+/, $l);
 118         $req = lc($req);
 119         $req = eval {
 120                 no strict 'refs';
 121                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 122         };
 123         return res($self, '500 command not recognized') unless $req;
 124         return res($self, r501) unless args_ok($req, scalar @args);
 125
 126         my $res = eval { $req->($self, @args) };
 127         my $err = $@;
 128         if ($err && !$self->{closed}) {
 129                 local $/ = "\n";
 130                 chomp($l);
 131                 err($self, 'error from: %s (%s)', $l, $err);
 132                 $res = '503 program fault - command not performed';
 133         }
 134         return 0 unless defined $res;
 135         res($self, $res);
 136 }
 137
 138 sub cmd_mode ($$) {
 139         my ($self, $arg) = @_;
 140         $arg = uc $arg;
 141         return r501 unless $arg eq 'READER';
 142         '201 Posting prohibited';
 143 }
 144
 145 sub cmd_slave ($) { '202 slave status noted' }
 146
 147 sub cmd_xgtitle ($;$) {
 148         my ($self, $wildmat) = @_;
 149         more($self, '282 list of groups and descriptions follows');
 150         list_newsgroups($self, $wildmat);
 151         '.'
 152 }
 153
 154 sub list_overview_fmt ($) {
 155         my ($self) = @_;
 156         do_more($self, $OVERVIEW_FMT);
 157 }
 158
 159 sub list_headers ($;$) {
 160         my ($self) = @_;
 161         do_more($self, $LIST_HEADERS);
 162 }
 163
 164 sub list_active ($;$) {
 165         my ($self, $wildmat) = @_;
 166         wildmat2re($wildmat);
 167         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 168                 $ng->{newsgroup} =~ $wildmat or next;
 169                 group_line($self, $ng);
 170         }
 171 }
 172
 173 sub list_active_times ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 my $c = eval { $ng->mm->created_at } || time;
 179                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 180         }
 181 }
 182
 183 sub list_newsgroups ($;$) {
 184         my ($self, $wildmat) = @_;
 185         wildmat2re($wildmat);
 186         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                 $ng->{newsgroup} =~ $wildmat or next;
 188                 my $d = $ng->description;
 189                 more($self, "$ng->{newsgroup} $d");
 190         }
 191 }
 192
 193 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 194 sub cmd_list ($;$$) {
 195         my ($self, @args) = @_;
 196         if (scalar @args) {
 197                 my $arg = shift @args;
 198                 $arg =~ tr/A-Z./a-z_/;
 199                 $arg = "list_$arg";
 200                 return r501 if $DISABLED{$arg};
 201
 202                 $arg = eval {
 203                         no strict 'refs';
 204                         *{$arg}{CODE};
 205                 };
 206                 return r501 unless $arg && args_ok($arg, scalar @args);
 207                 more($self, '215 information follows');
 208                 $arg->($self, @args);
 209         } else {
 210                 more($self, '215 list of newsgroups follows');
 211                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                         group_line($self, $ng);
 213                 }
 214         }
 215         '.'
 216 }
 217
 218 sub cmd_listgroup ($;$) {
 219         my ($self, $group) = @_;
 220         if (defined $group) {
 221                 my $res = cmd_group($self, $group);
 222                 return $res if ($res !~ /\A211 /);
 223                 more($self, $res);
 224         }
 225
 226         $self->{ng} or return '412 no newsgroup selected';
 227         my $n = 0;
 228         long_response($self, sub {
 229                 my $ary = $self->{ng}->mm->ids_after(\$n);
 230                 scalar @$ary or return;
 231                 more($self, join("\r\n", @$ary));
 232                 1;
 233         });
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my @now = $gmt ? gmtime : localtime;
 244         my ($YYYY, $MM, $DD);
 245         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 246                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 247         } else { # legacy clients send YYMMDD
 248                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my $cur_year = $now[5] + 1900;
 250                 if ($YYYY > $cur_year) {
 251                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 252                 }
 253         }
 254         if ($gmt) {
 255                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 256         } else {
 257                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 258         }
 259 }
 260
 261 sub group_line ($$) {
 262         my ($self, $ng) = @_;
 263         my ($min, $max) = $ng->mm->minmax;
 264         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 265 }
 266
 267 sub cmd_newgroups ($$$;$$) {
 268         my ($self, $date, $time, $gmt, $dists) = @_;
 269         my $ts = eval { parse_time($date, $time, $gmt) };
 270         return r501 if $@;
 271
 272         # TODO dists
 273         more($self, '231 list of new newsgroups follows');
 274         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 275                 my $c = eval { $ng->mm->created_at } || 0;
 276                 next unless $c > $ts;
 277                 group_line($self, $ng);
 278         }
 279         '.'
 280 }
 281
 282 sub wildmat2re (;$) {
 283         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 284         my %keep;
 285         my $salt = rand;
 286         my $tmp = $_[0];
 287
 288         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 289                 my $orig = $1;
 290                 my $key = sha1_hex($orig . $salt);
 291                 $orig =~ s/([^\w\-])+/\Q$1/g;
 292                 $keep{$key} = $orig;
 293                 $key
 294                 #gex;
 295         my %map = ('*' => '.*', '?' => '.' );
 296         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 297         if (scalar %keep) {
 298                 $tmp =~ s#([a-f0-9]{40})#
 299                         my $orig = $keep{$1};
 300                         defined $orig ? $orig : $1;
 301                         #ge;
 302         }
 303         $_[0] = qr/\A$tmp\z/;
 304 }
 305
 306 sub ngpat2re (;$) {
 307         return $_[0] = qr/\A\z/ unless defined $_[0];
 308         my %map = ('*' => '.*', ',' => '|');
 309         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 310         $_[0] = qr/\A(?:$_[0])\z/;
 311 }
 312
 313 sub cmd_newnews ($$$$;$$) {
 314         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 315         my $ts = eval { parse_time($date, $time, $gmt) };
 316         return r501 if $@;
 317         more($self, '230 list of new articles by message-id follows');
 318         my ($keep, $skip) = split('!', $newsgroups, 2);
 319         ngpat2re($keep);
 320         ngpat2re($skip);
 321         my @srch;
 322         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 323                 $ng->{newsgroup} =~ $keep or next;
 324                 $ng->{newsgroup} =~ $skip and next;
 325                 my $srch = $ng->search or next;
 326                 push @srch, $srch;
 327         };
 328         return '.' unless @srch;
 329
 330         my $prev = 0;
 331         long_response($self, sub {
 332                 my $srch = $srch[0];
 333                 my $msgs = $srch->query_ts($ts, $prev);
 334                 if (scalar @$msgs) {
 335                         more($self, '<' .
 336                                 join(">\r\n<", map { $_->mid } @$msgs ).
 337                                 '>');
 338                         $prev = $msgs->[-1]->{num};
 339                 } else {
 340                         shift @srch;
 341                         if (@srch) { # continue onto next newsgroup
 342                                 $prev = 0;
 343                                 return 1;
 344                         } else { # break out of the long response.
 345                                 return;
 346                         }
 347                 }
 348         });
 349 }
 350
 351 sub cmd_group ($$) {
 352         my ($self, $group) = @_;
 353         my $no_such = '411 no such news group';
 354         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 355
 356         $self->{ng} = $ng;
 357         my ($min, $max) = $ng->mm->minmax;
 358         $min ||= 0;
 359         $max ||= 0;
 360         $self->{article} = $min;
 361         my $est_size = $max - $min;
 362         "211 $est_size $min $max $group";
 363 }
 364
 365 sub article_adj ($$) {
 366         my ($self, $off) = @_;
 367         my $ng = $self->{ng} or return '412 no newsgroup selected';
 368
 369         my $n = $self->{article};
 370         defined $n or return '420 no current article has been selected';
 371
 372         $n += $off;
 373         my $mid = $ng->mm->mid_for($n);
 374         unless ($mid) {
 375                 $n = $off > 0 ? 'next' : 'previous';
 376                 return "421 no $n article in this group";
 377         }
 378         $self->{article} = $n;
 379         "223 $n <$mid> article retrieved - request text separately";
 380 }
 381
 382 sub cmd_next ($) { article_adj($_[0], 1) }
 383 sub cmd_last ($) { article_adj($_[0], -1) }
 384
 385 # We want to encourage using email and CC-ing everybody involved to avoid
 386 # the single-point-of-failure a single server provides.
 387 sub cmd_post ($) {
 388         my ($self) = @_;
 389         my $ng = $self->{ng};
 390         $ng ? "440 mailto:$ng->{-primary_address} to post"
 391                 : '440 posting not allowed'
 392 }
 393
 394 sub cmd_quit ($) {
 395         my ($self) = @_;
 396         res($self, '205 closing connection - goodbye!');
 397         $self->close;
 398         undef;
 399 }
 400
 401 sub header_append ($$$) {
 402         my ($hdr, $k, $v) = @_;
 403         my @v = $hdr->header($k);
 404         foreach (@v) {
 405                 return if $v eq $_;
 406         }
 407         $hdr->header_set($k, @v, $v);
 408 }
 409
 410 sub xref ($$$$) {
 411         my ($self, $ng, $n, $mid) = @_;
 412         my $ret = "$ng->{domain} $ng->{newsgroup}:$n";
 413
 414         # num_for is pretty cheap and sometimes we'll lookup the existence
 415         # of an article without getting even the OVER info.  In other words,
 416         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 417         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 418         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 419                 next if $ng eq $other;
 420                 my $num = eval { $other->mm->num_for($mid) } or next;
 421                 $ret .= " $other->{newsgroup}:$num";
 422         }
 423         $ret;
 424 }
 425
 426 sub set_nntp_headers ($$$$$) {
 427         my ($self, $hdr, $ng, $n, $mid) = @_;
 428
 429         # clobber some
 430         my $xref = xref($self, $ng, $n, $mid);
 431         $hdr->header_set('Xref', $xref);
 432         $xref =~ s/:\d+//g;
 433         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 434         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 435         if (my $url = $ng->base_url) {
 436                 $mid = mid_escape($mid);
 437                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 438                 header_append($hdr, 'List-Archive', "<$url>");
 439         }
 440 }
 441
 442 sub art_lookup ($$$) {
 443         my ($self, $art, $set_headers) = @_;
 444         my $ng = $self->{ng};
 445         my ($n, $mid);
 446         my $err;
 447         if (defined $art) {
 448                 if ($art =~ /\A\d+\z/o) {
 449                         $err = '423 no such article number in this group';
 450                         $n = int($art);
 451                         goto find_mid;
 452                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 453                         $mid = $1;
 454                         $err = r430;
 455                         $n = $ng->mm->num_for($mid) if $ng;
 456                         goto found if defined $n;
 457                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 458                                 $n = $g->mm->num_for($mid);
 459                                 if (defined $n) {
 460                                         $ng = $g;
 461                                         goto found;
 462                                 }
 463                         }
 464                         return $err;
 465                 } else {
 466                         return r501;
 467                 }
 468         } else {
 469                 $err = '420 no current article has been selected';
 470                 $n = $self->{article};
 471                 defined $n or return $err;
 472 find_mid:
 473                 $ng or return '412 no newsgroup has been selected';
 474                 $mid = $ng->mm->mid_for($n);
 475                 defined $mid or return $err;
 476         }
 477 found:
 478         my $smsg = $ng->search->{over_ro}->get_art($n) or return $err;
 479         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 480         my $s = Email::Simple->new($msg);
 481         if ($set_headers) {
 482                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 483
 484                 # must be last
 485                 $s->body_set('') if ($set_headers == 2);
 486         }
 487         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 488 }
 489
 490 sub simple_body_write ($$) {
 491         my ($self, $s) = @_;
 492         my $body = $s->body;
 493         $s->body_set('');
 494         $body =~ s/^\./../smg;
 495         $body =~ s/(?<!\r)\n/\r\n/sg;
 496         do_more($self, $body);
 497         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 498         '.'
 499 }
 500
 501 sub set_art {
 502         my ($self, $art) = @_;
 503         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 504 }
 505
 506 sub _header ($) {
 507         my $hdr = $_[0]->header_obj->as_string;
 508         utf8::encode($hdr);
 509         $hdr
 510 }
 511
 512 sub cmd_article ($;$) {
 513         my ($self, $art) = @_;
 514         my $r = art_lookup($self, $art, 1);
 515         return $r unless ref $r;
 516         my ($n, $mid, $s) = @$r;
 517         set_art($self, $art);
 518         more($self, "220 $n <$mid> article retrieved - head and body follow");
 519         do_more($self, _header($s));
 520         do_more($self, "\r\n");
 521         simple_body_write($self, $s);
 522 }
 523
 524 sub cmd_head ($;$) {
 525         my ($self, $art) = @_;
 526         my $r = art_lookup($self, $art, 2);
 527         return $r unless ref $r;
 528         my ($n, $mid, $s) = @$r;
 529         set_art($self, $art);
 530         more($self, "221 $n <$mid> article retrieved - head follows");
 531         do_more($self, _header($s));
 532         '.'
 533 }
 534
 535 sub cmd_body ($;$) {
 536         my ($self, $art) = @_;
 537         my $r = art_lookup($self, $art, 0);
 538         return $r unless ref $r;
 539         my ($n, $mid, $s) = @$r;
 540         set_art($self, $art);
 541         more($self, "222 $n <$mid> article retrieved - body follows");
 542         simple_body_write($self, $s);
 543 }
 544
 545 sub cmd_stat ($;$) {
 546         my ($self, $art) = @_;
 547         my $r = art_lookup($self, $art, 0);
 548         return $r unless ref $r;
 549         my ($n, $mid, undef) = @$r;
 550         set_art($self, $art);
 551         "223 $n <$mid> article retrieved - request text separately";
 552 }
 553
 554 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 555
 556 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 557
 558 sub cmd_help ($) {
 559         my ($self) = @_;
 560         more($self, '100 help text follows');
 561         '.'
 562 }
 563
 564 sub get_range ($$) {
 565         my ($self, $range) = @_;
 566         my $ng = $self->{ng} or return '412 no news group has been selected';
 567         defined $range or return '420 No article(s) selected';
 568         my ($beg, $end);
 569         my ($min, $max) = $ng->mm->minmax;
 570         if ($range =~ /\A(\d+)\z/) {
 571                 $beg = $end = $1;
 572         } elsif ($range =~ /\A(\d+)-\z/) {
 573                 ($beg, $end) = ($1, $max);
 574         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 575                 ($beg, $end) = ($1, $2);
 576         } else {
 577                 return r501;
 578         }
 579         $beg = $min if ($beg < $min);
 580         $end = $max if ($end > $max);
 581         return '420 No article(s) selected' if ($beg > $end);
 582         [ $beg, $end ];
 583 }
 584
 585 sub long_response ($$) {
 586         my ($self, $cb) = @_;
 587         die "BUG: nested long response" if $self->{long_res};
 588
 589         my $fd = $self->{fd};
 590         defined $fd or return;
 591         # make sure we disable reading during a long response,
 592         # clients should not be sending us stuff and making us do more
 593         # work while we are stream a response to them
 594         $self->watch_read(0);
 595         my $t0 = now();
 596         $self->{long_res} = sub {
 597                 my $more = eval { $cb->() };
 598                 if ($@ || $self->{closed}) {
 599                         $self->{long_res} = undef;
 600
 601                         if ($@) {
 602                                 err($self,
 603                                     "%s during long response[$fd] - %0.6f",
 604                                     $@, now() - $t0);
 605                         }
 606                         if ($self->{closed}) {
 607                                 out($self, " deferred[$fd] aborted - %0.6f",
 608                                            now() - $t0);
 609                         } else {
 610                                 update_idle_time($self);
 611                                 $self->watch_read(1);
 612                         }
 613                 } elsif ($more) { # $self->{write_buf_size}:
 614                         # no recursion, schedule another call ASAP
 615                         # but only after all pending writes are done
 616                         update_idle_time($self);
 617
 618                         push @$nextq, $self;
 619                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 620                 } else { # all done!
 621                         $self->{long_res} = undef;
 622                         $self->watch_read(1);
 623                         res($self, '.');
 624                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 625                 }
 626         };
 627         $self->{long_res}->(); # kick off!
 628         undef;
 629 }
 630
 631 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 632         my ($self, $xhdr, $range) = @_;
 633
 634         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 635                 my ($ng, $n) = mid_lookup($self, $1);
 636                 return r430 unless $n;
 637                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 638         } else { # numeric range
 639                 $range = $self->{article} unless defined $range;
 640                 my $r = get_range($self, $range);
 641                 return $r unless ref $r;
 642                 my $mm = $self->{ng}->mm;
 643                 my ($beg, $end) = @$r;
 644                 more($self, $xhdr ? r221 : r225);
 645                 long_response($self, sub {
 646                         my $r = $mm->msg_range(\$beg, $end);
 647                         @$r or return;
 648                         more($self, join("\r\n", map {
 649                                 "$_->[0] <$_->[1]>"
 650                         } @$r));
 651                         1;
 652                 });
 653         }
 654 }
 655
 656 sub mid_lookup ($$) {
 657         my ($self, $mid) = @_;
 658         my $self_ng = $self->{ng};
 659         if ($self_ng) {
 660                 my $n = $self_ng->mm->num_for($mid);
 661                 return ($self_ng, $n) if defined $n;
 662         }
 663         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 664                 next if defined $self_ng && $ng eq $self_ng;
 665                 my $n = $ng->mm->num_for($mid);
 666                 return ($ng, $n) if defined $n;
 667         }
 668         (undef, undef);
 669 }
 670
 671 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 672         my ($self, $xhdr, $range) = @_;
 673
 674         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 675                 my $mid = $1;
 676                 my ($ng, $n) = mid_lookup($self, $mid);
 677                 return r430 unless $n;
 678                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 679                                 xref($self, $ng, $n, $mid));
 680         } else { # numeric range
 681                 $range = $self->{article} unless defined $range;
 682                 my $r = get_range($self, $range);
 683                 return $r unless ref $r;
 684                 my $ng = $self->{ng};
 685                 my $mm = $ng->mm;
 686                 my ($beg, $end) = @$r;
 687                 more($self, $xhdr ? r221 : r225);
 688                 long_response($self, sub {
 689                         my $r = $mm->msg_range(\$beg, $end);
 690                         @$r or return;
 691                         more($self, join("\r\n", map {
 692                                 my $num = $_->[0];
 693                                 "$num ".xref($self, $ng, $num, $_->[1]);
 694                         } @$r));
 695                         1;
 696                 });
 697         }
 698 }
 699
 700 sub search_header_for {
 701         my ($srch, $num, $field) = @_;
 702         my $smsg = $srch->{over_ro}->get_art($num) or return;
 703         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 704         $smsg->{$field};
 705 }
 706
 707 sub hdr_searchmsg ($$$$) {
 708         my ($self, $xhdr, $field, $range) = @_;
 709         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 710                 my ($ng, $n) = mid_lookup($self, $1);
 711                 return r430 unless defined $n;
 712                 my $v = search_header_for($ng->search, $n, $field);
 713                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 714         } else { # numeric range
 715                 $range = $self->{article} unless defined $range;
 716                 my $srch = $self->{ng}->search;
 717                 my $mm = $self->{ng}->mm;
 718                 my $r = get_range($self, $range);
 719                 return $r unless ref $r;
 720                 my ($beg, $end) = @$r;
 721                 more($self, $xhdr ? r221 : r225);
 722                 my $cur = $beg;
 723                 long_response($self, sub {
 724                         my $msgs = $srch->query_xover($cur, $end);
 725                         my $nr = scalar @$msgs or return;
 726                         my $tmp = '';
 727                         foreach my $s (@$msgs) {
 728                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 729                         }
 730                         utf8::encode($tmp);
 731                         do_more($self, $tmp);
 732                         $cur = $msgs->[-1]->{num} + 1;
 733                 });
 734         }
 735 }
 736
 737 sub do_hdr ($$$;$) {
 738         my ($self, $xhdr, $header, $range) = @_;
 739         my $sub = lc $header;
 740         if ($sub eq 'message-id') {
 741                 hdr_message_id($self, $xhdr, $range);
 742         } elsif ($sub eq 'xref') {
 743                 hdr_xref($self, $xhdr, $range);
 744         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 745                                 bytes|lines)\z/x) {
 746                 hdr_searchmsg($self, $xhdr, $sub, $range);
 747         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 748                 hdr_searchmsg($self, $xhdr, $1, $range);
 749         } else {
 750                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 751         }
 752 }
 753
 754 # RFC 3977
 755 sub cmd_hdr ($$;$) {
 756         my ($self, $header, $range) = @_;
 757         do_hdr($self, 0, $header, $range);
 758 }
 759
 760 # RFC 2980
 761 sub cmd_xhdr ($$;$) {
 762         my ($self, $header, $range) = @_;
 763         do_hdr($self, 1, $header, $range);
 764 }
 765
 766 sub hdr_mid_prefix ($$$$$) {
 767         my ($self, $xhdr, $ng, $n, $mid) = @_;
 768         return $mid if $xhdr;
 769
 770         # HDR for RFC 3977 users
 771         if (my $self_ng = $self->{ng}) {
 772                 ($self_ng eq $ng) ? $n : '0';
 773         } else {
 774                 '0';
 775         }
 776 }
 777
 778 sub hdr_mid_response ($$$$$$) {
 779         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 780         my $res = '';
 781         if ($xhdr) {
 782                 $res .= r221 . "\r\n";
 783                 $res .= "$mid $v\r\n";
 784         } else {
 785                 $res .= r225 . "\r\n";
 786                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 787                 $res .= "$pfx $v\r\n";
 788         }
 789         res($self, $res .= '.');
 790         undef;
 791 }
 792
 793 sub cmd_xrover ($;$) {
 794         my ($self, $range) = @_;
 795         my $ng = $self->{ng} or return '412 no newsgroup selected';
 796         (defined $range && $range =~ /[<>]/) and
 797                 return '420 No article(s) selected'; # no message IDs
 798
 799         $range = $self->{article} unless defined $range;
 800         my $r = get_range($self, $range);
 801         return $r unless ref $r;
 802         my ($beg, $end) = @$r;
 803         my $mm = $ng->mm;
 804         my $srch = $ng->search;
 805         more($self, '224 Overview information follows');
 806
 807         long_response($self, sub {
 808                 my $h = search_header_for($srch, $beg, 'references');
 809                 more($self, "$beg $h") if defined($h);
 810                 $beg++ < $end;
 811         });
 812 }
 813
 814 sub over_line ($$) {
 815         my ($num, $smsg) = @_;
 816         # n.b. field access and procedural calls can be
 817         # 10%-15% faster than OO method calls:
 818         my $s = join("\t", $num,
 819                 $smsg->{subject},
 820                 $smsg->{from},
 821                 PublicInbox::SearchMsg::date($smsg),
 822                 "<$smsg->{mid}>",
 823                 $smsg->{references},
 824                 $smsg->{bytes},
 825                 $smsg->{lines});
 826         utf8::encode($s);
 827         $s
 828 }
 829
 830 sub cmd_over ($;$) {
 831         my ($self, $range) = @_;
 832         if ($range && $range =~ /\A<(.+)>\z/) {
 833                 my ($ng, $n) = mid_lookup($self, $1);
 834                 defined $n or return r430;
 835                 my $smsg = $ng->search->{over_ro}->get_art($n) or return r430;
 836                 more($self, '224 Overview information follows (multi-line)');
 837
 838                 # Only set article number column if it's the current group
 839                 my $self_ng = $self->{ng};
 840                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 841                 more($self, over_line($n, $smsg));
 842                 '.';
 843         } else {
 844                 cmd_xover($self, $range);
 845         }
 846 }
 847
 848 sub cmd_xover ($;$) {
 849         my ($self, $range) = @_;
 850         $range = $self->{article} unless defined $range;
 851         my $r = get_range($self, $range);
 852         return $r unless ref $r;
 853         my ($beg, $end) = @$r;
 854         more($self, "224 Overview information follows for $beg to $end");
 855         my $srch = $self->{ng}->search;
 856         my $cur = $beg;
 857         long_response($self, sub {
 858                 my $msgs = $srch->query_xover($cur, $end);
 859                 my $nr = scalar @$msgs or return;
 860
 861                 # OVERVIEW.FMT
 862                 more($self, join("\r\n", map {
 863                         over_line($_->{num}, $_);
 864                         } @$msgs));
 865                 $cur = $msgs->[-1]->{num} + 1;
 866         });
 867 }
 868
 869 sub cmd_xpath ($$) {
 870         my ($self, $mid) = @_;
 871         return r501 unless $mid =~ /\A<(.+)>\z/;
 872         $mid = $1;
 873         my @paths;
 874         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 875                 my $n = $ng->mm->num_for($mid);
 876                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 877         }
 878         return '430 no such article on server' unless @paths;
 879         '223 '.join(' ', @paths);
 880 }
 881
 882 sub res ($$) {
 883         my ($self, $line) = @_;
 884         do_write($self, $line . "\r\n");
 885 }
 886
 887 sub more ($$) {
 888         my ($self, $line) = @_;
 889         do_more($self, $line . "\r\n");
 890 }
 891
 892 sub do_write ($$) {
 893         my ($self, $data) = @_;
 894         my $done = $self->write($data);
 895         return if $self->{closed};
 896
 897         # Do not watch for readability if we have data in the queue,
 898         # instead re-enable watching for readability when we can
 899         $self->watch_read(0) if (!$done || $self->{long_res});
 900
 901         $done;
 902 }
 903
 904 sub err ($$;@) {
 905         my ($self, $fmt, @args) = @_;
 906         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 907 }
 908
 909 sub out ($$;@) {
 910         my ($self, $fmt, @args) = @_;
 911         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 912 }
 913
 914 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 915
 916 sub do_more ($$) {
 917         my ($self, $data) = @_;
 918         if (MSG_MORE && !$self->{write_buf_size}) {
 919                 my $n = send($self->{sock}, $data, MSG_MORE);
 920                 if (defined $n) {
 921                         my $dlen = length($data);
 922                         return 1 if $n == $dlen; # all done!
 923                         $data = substr($data, $n, $dlen - $n);
 924                 }
 925         }
 926         do_write($self, $data);
 927 }
 928
 929 # callbacks for Danga::Socket
 930
 931 sub event_hup { $_[0]->close }
 932 sub event_err { $_[0]->close }
 933
 934 sub event_write {
 935         my ($self) = @_;
 936         update_idle_time($self);
 937         # only continue watching for readability when we are done writing:
 938         if ($self->write(undef) == 1 && !$self->{long_res}) {
 939                 $self->watch_read(1);
 940         }
 941 }
 942
 943 sub event_read {
 944         my ($self) = @_;
 945         use constant LINE_MAX => 512; # RFC 977 section 2.3
 946         my $r = 1;
 947
 948         my $buf = $self->read(LINE_MAX) or return $self->close;
 949         $self->{rbuf} .= $$buf;
 950         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 951                 my $line = $1;
 952                 return $self->close if $line =~ /[[:cntrl:]]/s;
 953                 my $t0 = now();
 954                 my $fd = $self->{fd};
 955                 $r = eval { process_line($self, $line) };
 956                 my $d = $self->{long_res} ?
 957                         " deferred[$fd]" : '';
 958                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 959         }
 960
 961         return $self->close if $r < 0;
 962         my $len = length($self->{rbuf});
 963         return $self->close if ($len >= LINE_MAX);
 964         update_idle_time($self);
 965 }
 966
 967 sub watch_read {
 968         my ($self, $bool) = @_;
 969         my $rv = $self->SUPER::watch_read($bool);
 970         if ($bool && $self->{rbuf} ne '') {
 971                 # Force another read if there is a pipelined request.
 972                 # We don't know if the socket has anything for us to read,
 973                 # and we must double-check again by the time the timer fires
 974                 # in case we really did dispatch a read event and started
 975                 # another long response.
 976                 push @$nextq, $self;
 977                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 978         }
 979         $rv;
 980 }
 981
 982 sub not_idle_long ($$) {
 983         my ($self, $now) = @_;
 984         defined(my $fd = $self->{fd}) or return;
 985         my $ary = $EXPMAP->{$fd} or return;
 986         my $exp_at = $ary->[0] + $EXPTIME;
 987         $exp_at > $now;
 988 }
 989
 990 # for graceful shutdown in PublicInbox::Daemon:
 991 sub busy {
 992         my ($self, $now) = @_;
 993         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
 994          not_idle_long($self, $now));
 995 }
 996
 997 1;