lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26         long_response_limit => 0xffffffff,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  33 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  34                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  35
  36 # disable commands with easy DoS potential:
  37 # LISTGROUP could get pretty bad, too...
  38 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  39
  40 my $EXPMAP; # fd -> [ idle_time, $self ]
  41 my $expt;
  42 our $EXPTIME = 180; # 3 minutes
  43 my $nextt;
  44
  45 my $nextq = [];
  46 sub next_tick () {
  47         $nextt = undef;
  48         my $q = $nextq;
  49         $nextq = [];
  50         foreach my $nntp (@$q) {
  51                 # for request && response protocols, always finish writing
  52                 # before finishing reading:
  53                 if (my $long_cb = $nntp->{long_res}) {
  54                         $nntp->write($long_cb);
  55                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  56                         event_read($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub update_idle_time ($) {
  62         my ($self) = @_;
  63         my $fd = $self->{fd};
  64         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  65 }
  66
  67 sub expire_old () {
  68         my $now = now();
  69         my $exp = $EXPTIME;
  70         my $old = $now - $exp;
  71         my $nr = 0;
  72         my %new;
  73         while (my ($fd, $v) = each %$EXPMAP) {
  74                 my ($idle_time, $nntp) = @$v;
  75                 if ($idle_time < $old) {
  76                         $nntp->close; # idempotent
  77                 } else {
  78                         ++$nr;
  79                         $new{$fd} = $v;
  80                 }
  81         }
  82         $EXPMAP = \%new;
  83         if ($nr) {
  84                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  85         } else {
  86                 $expt = undef;
  87                 # noop to kick outselves out of the loop ASAP so descriptors
  88                 # really get closed
  89                 PublicInbox::EvCleanup::asap(sub {});
  90         }
  91 }
  92
  93 sub new ($$$) {
  94         my ($class, $sock, $nntpd) = @_;
  95         my $self = fields::new($class);
  96         $self->SUPER::new($sock);
  97         $self->{nntpd} = $nntpd;
  98         res($self, '201 server ready - post via email');
  99         $self->{rbuf} = '';
 100         $self->watch_read(1);
 101         update_idle_time($self);
 102         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 103         $self;
 104 }
 105
 106 sub args_ok ($$) {
 107         my ($cb, $argc) = @_;
 108         my $tot = prototype $cb;
 109         my ($nreq, undef) = split(';', $tot);
 110         $nreq = ($nreq =~ tr/$//) - 1;
 111         $tot = ($tot =~ tr/$//) - 1;
 112         ($argc <= $tot && $argc >= $nreq);
 113 }
 114
 115 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 116 sub process_line ($$) {
 117         my ($self, $l) = @_;
 118         my ($req, @args) = split(/\s+/, $l);
 119         $req = lc($req);
 120         $req = eval {
 121                 no strict 'refs';
 122                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 123         };
 124         return res($self, '500 command not recognized') unless $req;
 125         return res($self, r501) unless args_ok($req, scalar @args);
 126
 127         my $res = eval { $req->($self, @args) };
 128         my $err = $@;
 129         if ($err && !$self->{closed}) {
 130                 local $/ = "\n";
 131                 chomp($l);
 132                 err($self, 'error from: %s (%s)', $l, $err);
 133                 $res = '503 program fault - command not performed';
 134         }
 135         return 0 unless defined $res;
 136         res($self, $res);
 137 }
 138
 139 sub cmd_mode ($$) {
 140         my ($self, $arg) = @_;
 141         $arg = uc $arg;
 142         return r501 unless $arg eq 'READER';
 143         '201 Posting prohibited';
 144 }
 145
 146 sub cmd_slave ($) { '202 slave status noted' }
 147
 148 sub cmd_xgtitle ($;$) {
 149         my ($self, $wildmat) = @_;
 150         more($self, '282 list of groups and descriptions follows');
 151         list_newsgroups($self, $wildmat);
 152         '.'
 153 }
 154
 155 sub list_overview_fmt ($) {
 156         my ($self) = @_;
 157         do_more($self, $OVERVIEW_FMT);
 158 }
 159
 160 sub list_headers ($;$) {
 161         my ($self) = @_;
 162         do_more($self, $LIST_HEADERS);
 163 }
 164
 165 sub list_active ($;$) {
 166         my ($self, $wildmat) = @_;
 167         wildmat2re($wildmat);
 168         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 169                 $ng->{newsgroup} =~ $wildmat or next;
 170                 group_line($self, $ng);
 171         }
 172 }
 173
 174 sub list_active_times ($;$) {
 175         my ($self, $wildmat) = @_;
 176         wildmat2re($wildmat);
 177         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 178                 $ng->{newsgroup} =~ $wildmat or next;
 179                 my $c = eval { $ng->mm->created_at } || time;
 180                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 181         }
 182 }
 183
 184 sub list_newsgroups ($;$) {
 185         my ($self, $wildmat) = @_;
 186         wildmat2re($wildmat);
 187         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 188                 $ng->{newsgroup} =~ $wildmat or next;
 189                 my $d = $ng->description;
 190                 more($self, "$ng->{newsgroup} $d");
 191         }
 192 }
 193
 194 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 195 sub cmd_list ($;$$) {
 196         my ($self, @args) = @_;
 197         if (scalar @args) {
 198                 my $arg = shift @args;
 199                 $arg =~ tr/A-Z./a-z_/;
 200                 $arg = "list_$arg";
 201                 return r501 if $DISABLED{$arg};
 202
 203                 $arg = eval {
 204                         no strict 'refs';
 205                         *{$arg}{CODE};
 206                 };
 207                 return r501 unless $arg && args_ok($arg, scalar @args);
 208                 more($self, '215 information follows');
 209                 $arg->($self, @args);
 210         } else {
 211                 more($self, '215 list of newsgroups follows');
 212                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 213                         group_line($self, $ng);
 214                 }
 215         }
 216         '.'
 217 }
 218
 219 sub cmd_listgroup ($;$) {
 220         my ($self, $group) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226
 227         $self->{ng} or return '412 no newsgroup selected';
 228         long_response($self, 0, long_response_limit, sub {
 229                 my ($i) = @_;
 230                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 231                         my ($ary) = @_;
 232                         more($self, join("\r\n", @$ary));
 233                 });
 234
 235                 # -1 to adjust for implicit increment in long_response
 236                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 237         });
 238 }
 239
 240 sub parse_time ($$;$) {
 241         my ($date, $time, $gmt) = @_;
 242         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 243         if (defined $gmt) {
 244                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 245                 $gmt = 1;
 246         }
 247         my @now = $gmt ? gmtime : localtime;
 248         my ($YYYY, $MM, $DD);
 249         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 250                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 251         } else { # legacy clients send YYMMDD
 252                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 253                 my $cur_year = $now[5] + 1900;
 254                 if ($YYYY > $cur_year) {
 255                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 256                 }
 257         }
 258         if ($gmt) {
 259                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 260         } else {
 261                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 262         }
 263 }
 264
 265 sub group_line ($$) {
 266         my ($self, $ng) = @_;
 267         my ($min, $max) = $ng->mm->minmax;
 268         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 269 }
 270
 271 sub cmd_newgroups ($$$;$$) {
 272         my ($self, $date, $time, $gmt, $dists) = @_;
 273         my $ts = eval { parse_time($date, $time, $gmt) };
 274         return r501 if $@;
 275
 276         # TODO dists
 277         more($self, '231 list of new newsgroups follows');
 278         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 279                 my $c = eval { $ng->mm->created_at } || 0;
 280                 next unless $c > $ts;
 281                 group_line($self, $ng);
 282         }
 283         '.'
 284 }
 285
 286 sub wildmat2re (;$) {
 287         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 288         my %keep;
 289         my $salt = rand;
 290         my $tmp = $_[0];
 291
 292         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 293                 my $orig = $1;
 294                 my $key = sha1_hex($orig . $salt);
 295                 $orig =~ s/([^\w\-])+/\Q$1/g;
 296                 $keep{$key} = $orig;
 297                 $key
 298                 #gex;
 299         my %map = ('*' => '.*', '?' => '.' );
 300         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 301         if (scalar %keep) {
 302                 $tmp =~ s#([a-f0-9]{40})#
 303                         my $orig = $keep{$1};
 304                         defined $orig ? $orig : $1;
 305                         #ge;
 306         }
 307         $_[0] = qr/\A$tmp\z/;
 308 }
 309
 310 sub ngpat2re (;$) {
 311         return $_[0] = qr/\A\z/ unless defined $_[0];
 312         my %map = ('*' => '.*', ',' => '|');
 313         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 314         $_[0] = qr/\A(?:$_[0])\z/;
 315 }
 316
 317 sub cmd_newnews ($$$$;$$) {
 318         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 319         my $ts = eval { parse_time($date, $time, $gmt) };
 320         return r501 if $@;
 321         more($self, '230 list of new articles by message-id follows');
 322         my ($keep, $skip) = split('!', $newsgroups, 2);
 323         ngpat2re($keep);
 324         ngpat2re($skip);
 325         my @srch;
 326         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 327                 $ng->{newsgroup} =~ $keep or next;
 328                 $ng->{newsgroup} =~ $skip and next;
 329                 my $srch = $ng->search or next;
 330                 push @srch, $srch;
 331         };
 332         return '.' unless @srch;
 333
 334         $ts .= '..';
 335         my $opts = { asc => 1, limit => 1000, offset => 0 };
 336         long_response($self, 0, long_response_limit, sub {
 337                 my ($i) = @_;
 338                 my $srch = $srch[0];
 339                 my $res = $srch->query_ts($ts, $opts);
 340                 my $msgs = $res->{msgs};
 341                 if (my $nr = scalar @$msgs) {
 342                         more($self, '<' .
 343                                 join(">\r\n<", map { $_->mid } @$msgs ).
 344                                 '>');
 345                         $opts->{offset} += $nr;
 346                 } else {
 347                         shift @srch;
 348                         if (@srch) { # continue onto next newsgroup
 349                                 $opts->{offset} = 0;
 350                         } else { # break out of the long response.
 351                                 $$i = long_response_limit;
 352                         }
 353                 }
 354         });
 355 }
 356
 357 sub cmd_group ($$) {
 358         my ($self, $group) = @_;
 359         my $no_such = '411 no such news group';
 360         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 361
 362         $self->{ng} = $ng;
 363         my ($min, $max) = $ng->mm->minmax;
 364         $min ||= 0;
 365         $max ||= 0;
 366         $self->{article} = $min;
 367         my $est_size = $max - $min;
 368         "211 $est_size $min $max $group";
 369 }
 370
 371 sub article_adj ($$) {
 372         my ($self, $off) = @_;
 373         my $ng = $self->{ng} or return '412 no newsgroup selected';
 374
 375         my $n = $self->{article};
 376         defined $n or return '420 no current article has been selected';
 377
 378         $n += $off;
 379         my $mid = $ng->mm->mid_for($n);
 380         unless ($mid) {
 381                 $n = $off > 0 ? 'next' : 'previous';
 382                 return "421 no $n article in this group";
 383         }
 384         $self->{article} = $n;
 385         "223 $n <$mid> article retrieved - request text separately";
 386 }
 387
 388 sub cmd_next ($) { article_adj($_[0], 1) }
 389 sub cmd_last ($) { article_adj($_[0], -1) }
 390
 391 # We want to encourage using email and CC-ing everybody involved to avoid
 392 # the single-point-of-failure a single server provides.
 393 sub cmd_post ($) {
 394         my ($self) = @_;
 395         my $ng = $self->{ng};
 396         $ng ? "440 mailto:$ng->{-primary_address} to post"
 397                 : '440 posting not allowed'
 398 }
 399
 400 sub cmd_quit ($) {
 401         my ($self) = @_;
 402         res($self, '205 closing connection - goodbye!');
 403         $self->close;
 404         undef;
 405 }
 406
 407 sub header_append ($$$) {
 408         my ($hdr, $k, $v) = @_;
 409         my @v = $hdr->header($k);
 410         foreach (@v) {
 411                 return if $v eq $_;
 412         }
 413         $hdr->header_set($k, @v, $v);
 414 }
 415
 416 sub set_nntp_headers {
 417         my ($hdr, $ng, $n, $mid) = @_;
 418
 419         # clobber some
 420         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 421         $hdr->header_set('Xref', xref($ng, $n));
 422         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 423         if (my $url = $ng->base_url) {
 424                 $mid = mid_escape($mid);
 425                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 426                 header_append($hdr, 'List-Archive', "<$url>");
 427         }
 428 }
 429
 430 sub art_lookup ($$$) {
 431         my ($self, $art, $set_headers) = @_;
 432         my $ng = $self->{ng};
 433         my ($n, $mid);
 434         my $err;
 435         if (defined $art) {
 436                 if ($art =~ /\A\d+\z/o) {
 437                         $err = '423 no such article number in this group';
 438                         $n = int($art);
 439                         goto find_mid;
 440                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 441                         $mid = $1;
 442                         $err = r430;
 443                         $n = $ng->mm->num_for($mid) if $ng;
 444                         goto found if defined $n;
 445                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 446                                 $n = $g->mm->num_for($mid);
 447                                 if (defined $n) {
 448                                         $ng = $g;
 449                                         goto found;
 450                                 }
 451                         }
 452                         return $err;
 453                 } else {
 454                         return r501;
 455                 }
 456         } else {
 457                 $err = '420 no current article has been selected';
 458                 $n = $self->{article};
 459                 defined $n or return $err;
 460 find_mid:
 461                 $ng or return '412 no newsgroup has been selected';
 462                 $mid = $ng->mm->mid_for($n);
 463                 defined $mid or return $err;
 464         }
 465 found:
 466         my $smsg = $ng->search->lookup_article($n) or return $err;
 467         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 468         my $s = Email::Simple->new($msg);
 469         if ($set_headers) {
 470                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 471
 472                 # must be last
 473                 $s->body_set('') if ($set_headers == 2);
 474         }
 475         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 476 }
 477
 478 sub simple_body_write ($$) {
 479         my ($self, $s) = @_;
 480         my $body = $s->body;
 481         $s->body_set('');
 482         $body =~ s/^\./../smg;
 483         $body =~ s/(?<!\r)\n/\r\n/sg;
 484         do_more($self, $body);
 485         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 486         '.'
 487 }
 488
 489 sub set_art {
 490         my ($self, $art) = @_;
 491         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 492 }
 493
 494 sub _header ($) {
 495         my $hdr = $_[0]->header_obj->as_string;
 496         utf8::encode($hdr);
 497         $hdr
 498 }
 499
 500 sub cmd_article ($;$) {
 501         my ($self, $art) = @_;
 502         my $r = art_lookup($self, $art, 1);
 503         return $r unless ref $r;
 504         my ($n, $mid, $s) = @$r;
 505         set_art($self, $art);
 506         more($self, "220 $n <$mid> article retrieved - head and body follow");
 507         do_more($self, _header($s));
 508         do_more($self, "\r\n");
 509         simple_body_write($self, $s);
 510 }
 511
 512 sub cmd_head ($;$) {
 513         my ($self, $art) = @_;
 514         my $r = art_lookup($self, $art, 2);
 515         return $r unless ref $r;
 516         my ($n, $mid, $s) = @$r;
 517         set_art($self, $art);
 518         more($self, "221 $n <$mid> article retrieved - head follows");
 519         do_more($self, _header($s));
 520         '.'
 521 }
 522
 523 sub cmd_body ($;$) {
 524         my ($self, $art) = @_;
 525         my $r = art_lookup($self, $art, 0);
 526         return $r unless ref $r;
 527         my ($n, $mid, $s) = @$r;
 528         set_art($self, $art);
 529         more($self, "222 $n <$mid> article retrieved - body follows");
 530         simple_body_write($self, $s);
 531 }
 532
 533 sub cmd_stat ($;$) {
 534         my ($self, $art) = @_;
 535         my $r = art_lookup($self, $art, 0);
 536         return $r unless ref $r;
 537         my ($n, $mid, undef) = @$r;
 538         set_art($self, $art);
 539         "223 $n <$mid> article retrieved - request text separately";
 540 }
 541
 542 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 543
 544 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 545
 546 sub cmd_help ($) {
 547         my ($self) = @_;
 548         more($self, '100 help text follows');
 549         '.'
 550 }
 551
 552 sub get_range ($$) {
 553         my ($self, $range) = @_;
 554         my $ng = $self->{ng} or return '412 no news group has been selected';
 555         defined $range or return '420 No article(s) selected';
 556         my ($beg, $end);
 557         my ($min, $max) = $ng->mm->minmax;
 558         if ($range =~ /\A(\d+)\z/) {
 559                 $beg = $end = $1;
 560         } elsif ($range =~ /\A(\d+)-\z/) {
 561                 ($beg, $end) = ($1, $max);
 562         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 563                 ($beg, $end) = ($1, $2);
 564         } else {
 565                 return r501;
 566         }
 567         $beg = $min if ($beg < $min);
 568         $end = $max if ($end > $max);
 569         return '420 No article(s) selected' if ($beg > $end);
 570         [ $beg, $end ];
 571 }
 572
 573 sub long_response ($$$$) {
 574         my ($self, $beg, $end, $cb) = @_;
 575         die "BUG: nested long response" if $self->{long_res};
 576
 577         my $fd = $self->{fd};
 578         defined $fd or return;
 579         # make sure we disable reading during a long response,
 580         # clients should not be sending us stuff and making us do more
 581         # work while we are stream a response to them
 582         $self->watch_read(0);
 583         my $t0 = now();
 584         $self->{long_res} = sub {
 585                 # limit our own running time for fairness with other
 586                 # clients and to avoid buffering too much:
 587                 my $lim = 100;
 588
 589                 my $err;
 590                 do {
 591                         eval { $cb->(\$beg) };
 592                 } until (($err = $@) || $self->{closed} ||
 593                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 594
 595                 if ($err || $self->{closed}) {
 596                         $self->{long_res} = undef;
 597
 598                         if ($err) {
 599                                 err($self,
 600                                     "%s during long response[$fd] - %0.6f",
 601                                     $err, now() - $t0);
 602                         }
 603                         if ($self->{closed}) {
 604                                 out($self, " deferred[$fd] aborted - %0.6f",
 605                                            now() - $t0);
 606                         } else {
 607                                 update_idle_time($self);
 608                                 $self->watch_read(1);
 609                         }
 610                 } elsif (!$lim || $self->{write_buf_size}) {
 611                         # no recursion, schedule another call ASAP
 612                         # but only after all pending writes are done
 613                         update_idle_time($self);
 614
 615                         push @$nextq, $self;
 616                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 617                 } else { # all done!
 618                         $self->{long_res} = undef;
 619                         $self->watch_read(1);
 620                         res($self, '.');
 621                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 622                 }
 623         };
 624         $self->{long_res}->(); # kick off!
 625         undef;
 626 }
 627
 628 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 629         my ($self, $xhdr, $range) = @_;
 630
 631         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 632                 my ($ng, $n) = mid_lookup($self, $1);
 633                 return r430 unless $n;
 634                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 635         } else { # numeric range
 636                 $range = $self->{article} unless defined $range;
 637                 my $r = get_range($self, $range);
 638                 return $r unless ref $r;
 639                 my $mm = $self->{ng}->mm;
 640                 my ($beg, $end) = @$r;
 641                 more($self, $xhdr ? r221 : r225);
 642                 long_response($self, $beg, $end, sub {
 643                         my ($i) = @_;
 644                         my $mid = $mm->mid_for($$i);
 645                         more($self, "$$i <$mid>") if defined $mid;
 646                 });
 647         }
 648 }
 649
 650 sub xref ($$) {
 651         my ($ng, $n) = @_;
 652         "$ng->{domain} $ng->{newsgroup}:$n"
 653 }
 654
 655 sub mid_lookup ($$) {
 656         my ($self, $mid) = @_;
 657         my $self_ng = $self->{ng};
 658         if ($self_ng) {
 659                 my $n = $self_ng->mm->num_for($mid);
 660                 return ($self_ng, $n) if defined $n;
 661         }
 662         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 663                 next if defined $self_ng && $ng eq $self_ng;
 664                 my $n = $ng->mm->num_for($mid);
 665                 return ($ng, $n) if defined $n;
 666         }
 667         (undef, undef);
 668 }
 669
 670 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 671         my ($self, $xhdr, $range) = @_;
 672
 673         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 674                 my ($ng, $n) = mid_lookup($self, $1);
 675                 return r430 unless $n;
 676                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 677         } else { # numeric range
 678                 $range = $self->{article} unless defined $range;
 679                 my $r = get_range($self, $range);
 680                 return $r unless ref $r;
 681                 my $ng = $self->{ng};
 682                 my $mm = $ng->mm;
 683                 my ($beg, $end) = @$r;
 684                 more($self, $xhdr ? r221 : r225);
 685                 long_response($self, $beg, $end, sub {
 686                         my ($i) = @_;
 687                         my $mid = $mm->mid_for($$i);
 688                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 689                 });
 690         }
 691 }
 692
 693 sub search_header_for {
 694         my ($srch, $num, $field) = @_;
 695         my $smsg = $srch->lookup_article($num) or return;
 696         $smsg->$field;
 697 }
 698
 699 sub hdr_searchmsg ($$$$) {
 700         my ($self, $xhdr, $field, $range) = @_;
 701         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 702                 my ($ng, $n) = mid_lookup($self, $1);
 703                 return r430 unless defined $n;
 704                 my $v = search_header_for($ng->search, $n, $field);
 705                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 706         } else { # numeric range
 707                 $range = $self->{article} unless defined $range;
 708                 my $srch = $self->{ng}->search;
 709                 my $mm = $self->{ng}->mm;
 710                 my $r = get_range($self, $range);
 711                 return $r unless ref $r;
 712                 my ($beg, $end) = @$r;
 713                 more($self, $xhdr ? r221 : r225);
 714                 my $off = 0;
 715                 long_response($self, $beg, $end, sub {
 716                         my ($i) = @_;
 717                         my $res = $srch->query_xover($beg, $end, $off);
 718                         my $msgs = $res->{msgs};
 719                         my $nr = scalar @$msgs or return;
 720                         $off += $nr;
 721                         my $tmp = '';
 722                         foreach my $s (@$msgs) {
 723                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 724                         }
 725                         utf8::encode($tmp);
 726                         do_more($self, $tmp);
 727                         # -1 to adjust for implicit increment in long_response
 728                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 729                 });
 730         }
 731 }
 732
 733 sub do_hdr ($$$;$) {
 734         my ($self, $xhdr, $header, $range) = @_;
 735         my $sub = lc $header;
 736         if ($sub eq 'message-id') {
 737                 hdr_message_id($self, $xhdr, $range);
 738         } elsif ($sub eq 'xref') {
 739                 hdr_xref($self, $xhdr, $range);
 740         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 741                                 bytes|lines)\z/x) {
 742                 hdr_searchmsg($self, $xhdr, $sub, $range);
 743         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 744                 hdr_searchmsg($self, $xhdr, $1, $range);
 745         } else {
 746                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 747         }
 748 }
 749
 750 # RFC 3977
 751 sub cmd_hdr ($$;$) {
 752         my ($self, $header, $range) = @_;
 753         do_hdr($self, 0, $header, $range);
 754 }
 755
 756 # RFC 2980
 757 sub cmd_xhdr ($$;$) {
 758         my ($self, $header, $range) = @_;
 759         do_hdr($self, 1, $header, $range);
 760 }
 761
 762 sub hdr_mid_prefix ($$$$$) {
 763         my ($self, $xhdr, $ng, $n, $mid) = @_;
 764         return $mid if $xhdr;
 765
 766         # HDR for RFC 3977 users
 767         if (my $self_ng = $self->{ng}) {
 768                 ($self_ng eq $ng) ? $n : '0';
 769         } else {
 770                 '0';
 771         }
 772 }
 773
 774 sub hdr_mid_response ($$$$$$) {
 775         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 776         my $res = '';
 777         if ($xhdr) {
 778                 $res .= r221 . "\r\n";
 779                 $res .= "$mid $v\r\n";
 780         } else {
 781                 $res .= r225 . "\r\n";
 782                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 783                 $res .= "$pfx $v\r\n";
 784         }
 785         res($self, $res .= '.');
 786         undef;
 787 }
 788
 789 sub cmd_xrover ($;$) {
 790         my ($self, $range) = @_;
 791         my $ng = $self->{ng} or return '412 no newsgroup selected';
 792         (defined $range && $range =~ /[<>]/) and
 793                 return '420 No article(s) selected'; # no message IDs
 794
 795         $range = $self->{article} unless defined $range;
 796         my $r = get_range($self, $range);
 797         return $r unless ref $r;
 798         my ($beg, $end) = @$r;
 799         my $mm = $ng->mm;
 800         my $srch = $ng->search;
 801         more($self, '224 Overview information follows');
 802         long_response($self, $beg, $end, sub {
 803                 my ($i) = @_;
 804                 my $num = $$i;
 805                 my $h = search_header_for($srch, $num, 'references');
 806                 defined $h or return;
 807                 more($self, "$num $h");
 808         });
 809 }
 810
 811 sub over_line ($$) {
 812         my ($num, $smsg) = @_;
 813         # n.b. field access and procedural calls can be
 814         # 10%-15% faster than OO method calls:
 815         my $s = join("\t", $num,
 816                 $smsg->{subject},
 817                 $smsg->{from},
 818                 PublicInbox::SearchMsg::date($smsg),
 819                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 820                 $smsg->{references},
 821                 PublicInbox::SearchMsg::bytes($smsg),
 822                 PublicInbox::SearchMsg::lines($smsg));
 823         utf8::encode($s);
 824         $s
 825 }
 826
 827 sub cmd_over ($;$) {
 828         my ($self, $range) = @_;
 829         if ($range && $range =~ /\A<(.+)>\z/) {
 830                 my ($ng, $n) = mid_lookup($self, $1);
 831                 defined $n or return r430;
 832                 my $smsg = $ng->search->lookup_article($n) or return r430;
 833                 more($self, '224 Overview information follows (multi-line)');
 834
 835                 # Only set article number column if it's the current group
 836                 my $self_ng = $self->{ng};
 837                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 838                 more($self, over_line($n, $smsg));
 839                 '.';
 840         } else {
 841                 cmd_xover($self, $range);
 842         }
 843 }
 844
 845 sub cmd_xover ($;$) {
 846         my ($self, $range) = @_;
 847         $range = $self->{article} unless defined $range;
 848         my $r = get_range($self, $range);
 849         return $r unless ref $r;
 850         my ($beg, $end) = @$r;
 851         more($self, "224 Overview information follows for $beg to $end");
 852         my $srch = $self->{ng}->search;
 853         my $off = 0;
 854         long_response($self, $beg, $end, sub {
 855                 my ($i) = @_;
 856                 my $res = $srch->query_xover($beg, $end, $off);
 857                 my $msgs = $res->{msgs};
 858                 my $nr = scalar @$msgs or return;
 859                 $off += $nr;
 860
 861                 # OVERVIEW.FMT
 862                 more($self, join("\r\n", map {
 863                         over_line(PublicInbox::SearchMsg::num($_), $_);
 864                         } @$msgs));
 865
 866                 # -1 to adjust for implicit increment in long_response
 867                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 868         });
 869 }
 870
 871 sub cmd_xpath ($$) {
 872         my ($self, $mid) = @_;
 873         return r501 unless $mid =~ /\A<(.+)>\z/;
 874         $mid = $1;
 875         my @paths;
 876         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 877                 my $n = $ng->mm->num_for($mid);
 878                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 879         }
 880         return '430 no such article on server' unless @paths;
 881         '223 '.join(' ', @paths);
 882 }
 883
 884 sub res ($$) {
 885         my ($self, $line) = @_;
 886         do_write($self, $line . "\r\n");
 887 }
 888
 889 sub more ($$) {
 890         my ($self, $line) = @_;
 891         do_more($self, $line . "\r\n");
 892 }
 893
 894 sub do_write ($$) {
 895         my ($self, $data) = @_;
 896         my $done = $self->write($data);
 897         return if $self->{closed};
 898
 899         # Do not watch for readability if we have data in the queue,
 900         # instead re-enable watching for readability when we can
 901         $self->watch_read(0) if (!$done || $self->{long_res});
 902
 903         $done;
 904 }
 905
 906 sub err ($$;@) {
 907         my ($self, $fmt, @args) = @_;
 908         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 909 }
 910
 911 sub out ($$;@) {
 912         my ($self, $fmt, @args) = @_;
 913         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 914 }
 915
 916 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 917
 918 sub do_more ($$) {
 919         my ($self, $data) = @_;
 920         if (MSG_MORE && !$self->{write_buf_size}) {
 921                 my $n = send($self->{sock}, $data, MSG_MORE);
 922                 if (defined $n) {
 923                         my $dlen = length($data);
 924                         return 1 if $n == $dlen; # all done!
 925                         $data = substr($data, $n, $dlen - $n);
 926                 }
 927         }
 928         do_write($self, $data);
 929 }
 930
 931 # callbacks for Danga::Socket
 932
 933 sub event_hup { $_[0]->close }
 934 sub event_err { $_[0]->close }
 935
 936 sub event_write {
 937         my ($self) = @_;
 938         update_idle_time($self);
 939         # only continue watching for readability when we are done writing:
 940         if ($self->write(undef) == 1 && !$self->{long_res}) {
 941                 $self->watch_read(1);
 942         }
 943 }
 944
 945 sub event_read {
 946         my ($self) = @_;
 947         use constant LINE_MAX => 512; # RFC 977 section 2.3
 948         my $r = 1;
 949
 950         my $buf = $self->read(LINE_MAX) or return $self->close;
 951         $self->{rbuf} .= $$buf;
 952         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 953                 my $line = $1;
 954                 return $self->close if $line =~ /[[:cntrl:]]/s;
 955                 my $t0 = now();
 956                 my $fd = $self->{fd};
 957                 $r = eval { process_line($self, $line) };
 958                 my $d = $self->{long_res} ?
 959                         " deferred[$fd]" : '';
 960                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 961         }
 962
 963         return $self->close if $r < 0;
 964         my $len = length($self->{rbuf});
 965         return $self->close if ($len >= LINE_MAX);
 966         update_idle_time($self);
 967 }
 968
 969 sub watch_read {
 970         my ($self, $bool) = @_;
 971         my $rv = $self->SUPER::watch_read($bool);
 972         if ($bool && $self->{rbuf} ne '') {
 973                 # Force another read if there is a pipelined request.
 974                 # We don't know if the socket has anything for us to read,
 975                 # and we must double-check again by the time the timer fires
 976                 # in case we really did dispatch a read event and started
 977                 # another long response.
 978                 push @$nextq, $self;
 979                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 980         }
 981         $rv;
 982 }
 983
 984 sub not_idle_long ($$) {
 985         my ($self, $now) = @_;
 986         defined(my $fd = $self->{fd}) or return;
 987         my $ary = $EXPMAP->{$fd} or return;
 988         my $exp_at = $ary->[0] + $EXPTIME;
 989         $exp_at > $now;
 990 }
 991
 992 # for graceful shutdown in PublicInbox::Daemon:
 993 sub busy {
 994         my ($self, $now) = @_;
 995         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
 996          not_idle_long($self, $now));
 997 }
 998
 999 1;