lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime ualarm CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         long_response_limit => 0xffffffff,
  18 };
  19
  20 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  21
  22 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  23 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  24
  25 # disable commands with easy DoS potential:
  26 # LISTGROUP could get pretty bad, too...
  27 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  28
  29 sub new ($$$) {
  30         my ($class, $sock, $nntpd) = @_;
  31         my $self = fields::new($class);
  32         binmode $sock, ':utf8'; # RFC 3977
  33         $self->SUPER::new($sock);
  34         $self->{nntpd} = $nntpd;
  35         res($self, '201 server ready - post via email');
  36         $self->{rbuf} = '';
  37         $self->watch_read(1);
  38         $self;
  39 }
  40
  41 sub args_ok ($$) {
  42         my ($cb, $argc) = @_;
  43         my $tot = prototype $cb;
  44         my ($nreq, undef) = split(';', $tot);
  45         $nreq = ($nreq =~ tr/$//) - 1;
  46         $tot = ($tot =~ tr/$//) - 1;
  47         ($argc <= $tot && $argc >= $nreq);
  48 }
  49
  50 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  51 sub process_line ($$) {
  52         my ($self, $l) = @_;
  53         my ($req, @args) = split(/\s+/, $l);
  54         $req = lc($req);
  55         $req = eval {
  56                 no strict 'refs';
  57                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  58         };
  59         return res($self, '500 command not recognized') unless $req;
  60         return res($self, r501) unless args_ok($req, scalar @args);
  61
  62         my $res = eval { $req->($self, @args) };
  63         my $err = $@;
  64         if ($err && !$self->{closed}) {
  65                 chomp($l = Dumper(\$l));
  66                 err($self, "error from: $l $err");
  67                 $res = '503 program fault - command not performed';
  68         }
  69         return 0 unless defined $res;
  70         res($self, $res);
  71 }
  72
  73 sub cmd_mode ($$) {
  74         my ($self, $arg) = @_;
  75         $arg = uc $arg;
  76         return r501 unless $arg eq 'READER';
  77         '200 reader status acknowledged';
  78 }
  79
  80 sub cmd_slave ($) { '202 slave status noted' }
  81
  82 sub cmd_xgtitle ($;$) {
  83         my ($self, $wildmat) = @_;
  84         more($self, '282 list of groups and descriptions follows');
  85         list_newsgroups($self, $wildmat);
  86         '.'
  87 }
  88
  89 sub list_overview_fmt ($$) {
  90         my ($self) = @_;
  91         more($self, $_ . ':') foreach @OVERVIEW;
  92 }
  93
  94 sub list_active ($;$) {
  95         my ($self, $wildmat) = @_;
  96         wildmat2re($wildmat);
  97         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
  98                 $ng->{name} =~ $wildmat or next;
  99                 group_line($self, $ng);
 100         }
 101 }
 102
 103 sub list_active_times ($;$) {
 104         my ($self, $wildmat) = @_;
 105         wildmat2re($wildmat);
 106         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 107                 $ng->{name} =~ $wildmat or next;
 108                 my $c = eval { $ng->mm->created_at } || time;
 109                 more($self, "$ng->{name} $c $ng->{address}");
 110         }
 111 }
 112
 113 sub list_newsgroups ($;$) {
 114         my ($self, $wildmat) = @_;
 115         wildmat2re($wildmat);
 116         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 117                 $ng->{name} =~ $wildmat or next;
 118                 my $d = $ng->description;
 119                 more($self, "$ng->{name} $d");
 120         }
 121 }
 122
 123 # LIST SUBSCRIPTIONS not supported
 124 sub cmd_list ($;$$) {
 125         my ($self, @args) = @_;
 126         if (scalar @args) {
 127                 my $arg = shift @args;
 128                 $arg =~ tr/A-Z./a-z_/;
 129                 $arg = "list_$arg";
 130                 return '503 function not performed' if $DISABLED{$arg};
 131
 132                 $arg = eval {
 133                         no strict 'refs';
 134                         *{$arg}{CODE};
 135                 };
 136                 return r501 unless $arg && args_ok($arg, scalar @args);
 137                 more($self, '215 information follows');
 138                 $arg->($self, @args);
 139         } else {
 140                 more($self, '215 list of newsgroups follows');
 141                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 142                         group_line($self, $ng);
 143                 }
 144         }
 145         '.'
 146 }
 147
 148 sub cmd_listgroup ($;$) {
 149         my ($self, $group) = @_;
 150         if (defined $group) {
 151                 my $res = cmd_group($self, $group);
 152                 return $res if ($res !~ /\A211 /);
 153                 more($self, $res);
 154         }
 155
 156         $self->{ng} or return '412 no newsgroup selected';
 157         $self->long_response(0, long_response_limit, sub {
 158                 my ($i) = @_;
 159                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 160                         my ($ary) = @_;
 161                         more($self, join("\r\n", @$ary));
 162                 });
 163
 164                 # -1 to adjust for implicit increment in long_response
 165                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 166         });
 167 }
 168
 169 sub parse_time ($$;$) {
 170         my ($date, $time, $gmt) = @_;
 171         use Time::Local qw();
 172         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 173         if (defined $gmt) {
 174                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 175                 $gmt = 1;
 176         }
 177         my @now = $gmt ? gmtime : localtime;
 178         my ($YYYY, $MM, $DD);
 179         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 180                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 181         } else { # legacy clients send YYMMDD
 182                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 183                 if ($YYYY > strftime('%y', @now)) {
 184                         my $cur_year = $now[5] + 1900;
 185                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 186                 }
 187         }
 188         if ($gmt) {
 189                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 190         } else {
 191                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 192         }
 193 }
 194
 195 sub group_line ($$) {
 196         my ($self, $ng) = @_;
 197         my ($min, $max) = $ng->mm->minmax;
 198         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 199 }
 200
 201 sub cmd_newgroups ($$$;$$) {
 202         my ($self, $date, $time, $gmt, $dists) = @_;
 203         my $ts = eval { parse_time($date, $time, $gmt) };
 204         return r501 if $@;
 205
 206         # TODO dists
 207         more($self, '231 list of new newsgroups follows');
 208         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 209                 my $c = eval { $ng->mm->created_at } || 0;
 210                 next unless $c > $ts;
 211                 group_line($self, $ng);
 212         }
 213         '.'
 214 }
 215
 216 sub wildmat2re (;$) {
 217         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 218         my %keep;
 219         my $salt = rand;
 220         use Digest::SHA qw(sha1_hex);
 221         my $tmp = $_[0];
 222
 223         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 224                 my $orig = $1;
 225                 my $key = sha1_hex($orig . $salt);
 226                 $orig =~ s/([^\w\-])+/\Q$1/g;
 227                 $keep{$key} = $orig;
 228                 $key
 229                 #gex;
 230         my %map = ('*' => '.*', '?' => '.' );
 231         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 232         if (scalar %keep) {
 233                 $tmp =~ s#([a-f0-9]{40})#
 234                         my $orig = $keep{$1};
 235                         defined $orig ? $orig : $1;
 236                         #ge;
 237         }
 238         $_[0] = qr/\A$tmp\z/;
 239 }
 240
 241 sub ngpat2re (;$) {
 242         return $_[0] = qr/\A\z/ unless defined $_[0];
 243         my %map = ('*' => '.*', ',' => '|');
 244         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 245         $_[0] = qr/\A(?:$_[0])\z/;
 246 }
 247
 248 sub cmd_newnews ($$$$;$$) {
 249         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 250         my $ts = eval { parse_time($date, $time, $gmt) };
 251         return r501 if $@;
 252         more($self, '230 list of new articles by message-id follows');
 253         my ($keep, $skip) = split('!', $newsgroups, 2);
 254         ngpat2re($keep);
 255         ngpat2re($skip);
 256         my @srch;
 257         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 258                 $ng->{name} =~ $keep or next;
 259                 $ng->{name} =~ $skip and next;
 260                 my $srch = $ng->search or next;
 261                 push @srch, $srch;
 262         };
 263         return '.' unless @srch;
 264
 265         $ts .= '..';
 266         my $opts = { asc => 1, limit => 1000, offset => 0 };
 267         $self->long_response(0, long_response_limit, sub {
 268                 my ($i) = @_;
 269                 my $srch = $srch[0];
 270                 my $res = $srch->query($ts, $opts);
 271                 my $msgs = $res->{msgs};
 272                 if (my $nr = scalar @$msgs) {
 273                         more($self, '<' .
 274                                 join(">\r\n<", map { $_->mid } @$msgs ).
 275                                 '>');
 276                         $opts->{offset} += $nr;
 277                 } else {
 278                         shift @srch;
 279                         if (@srch) { # continue onto next newsgroup
 280                                 $opts->{offset} = 0;
 281                         } else { # break out of the long response.
 282                                 $$i = long_response_limit;
 283                         }
 284                 }
 285         });
 286 }
 287
 288 sub cmd_group ($$) {
 289         my ($self, $group) = @_;
 290         my $no_such = '411 no such news group';
 291         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 292
 293         $self->{ng} = $ng;
 294         my ($min, $max) = $ng->mm->minmax;
 295         $min ||= 0;
 296         $max ||= 0;
 297         $self->{article} = $min;
 298         my $est_size = $max - $min;
 299         "211 $est_size $min $max $group";
 300 }
 301
 302 sub article_adj ($$) {
 303         my ($self, $off) = @_;
 304         my $ng = $self->{ng} or return '412 no newsgroup selected';
 305
 306         my $n = $self->{article};
 307         defined $n or return '420 no current article has been selected';
 308
 309         $n += $off;
 310         my $mid = $ng->mm->mid_for($n);
 311         unless ($mid) {
 312                 $n = $off > 0 ? 'next' : 'previous';
 313                 return "421 no $n article in this group";
 314         }
 315         $self->{article} = $n;
 316         "223 $n <$mid> article retrieved - request text separately";
 317 }
 318
 319 sub cmd_next ($) { article_adj($_[0], 1) }
 320 sub cmd_last ($) { article_adj($_[0], -1) }
 321
 322 # We want to encourage using email and CC-ing everybody involved to avoid
 323 # the single-point-of-failure a single server provides.
 324 sub cmd_post ($) {
 325         my ($self) = @_;
 326         my $ng = $self->{ng};
 327         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 328 }
 329
 330 sub cmd_quit ($) {
 331         my ($self) = @_;
 332         res($self, '205 closing connection - goodbye!');
 333         $self->close;
 334         undef;
 335 }
 336
 337 sub art_lookup ($$$) {
 338         my ($self, $art, $set_headers) = @_;
 339         my $ng = $self->{ng};
 340         my ($n, $mid);
 341         my $err;
 342         if (defined $art) {
 343                 if ($art =~ /\A\d+\z/o) {
 344                         $err = '423 no such article number in this group';
 345                         $n = int($art);
 346                         goto find_mid;
 347                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 348                         $mid = $1;
 349                         $err = '430 no such article found';
 350                         $n = $ng->mm->num_for($mid) if $ng;
 351                         goto found if defined $n;
 352                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 353                                 $n = $g->mm->num_for($mid);
 354                                 if (defined $n) {
 355                                         $ng = $g;
 356                                         goto found;
 357                                 }
 358                         }
 359                         return $err;
 360                 } else {
 361                         return r501;
 362                 }
 363         } else {
 364                 $err = '420 no current article has been selected';
 365                 $n = $self->{article};
 366                 defined $n or return $err;
 367 find_mid:
 368                 $ng or return '412 no newsgroup has been selected';
 369                 $mid = $ng->mm->mid_for($n);
 370                 defined $mid or return $err;
 371         }
 372 found:
 373         my $o = 'HEAD:' . mid2path($mid);
 374         my $bytes;
 375         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 376         return $err unless $s;
 377         if ($set_headers) {
 378                 $s->header_set('Newsgroups', $ng->{name});
 379                 $s->header_set('Lines', $s->body =~ tr!\n!\n!);
 380                 $s->header_set('Xref', xref($ng, $n));
 381
 382                 # must be last
 383                 if ($set_headers == 2) {
 384                         $s->header_set('Bytes', $bytes);
 385                         $s->body_set('');
 386                 }
 387         }
 388         [ $n, $mid, $s ];
 389 }
 390
 391 sub simple_body_write ($$) {
 392         my ($self, $s) = @_;
 393         my $body = $s->body;
 394         $s->body_set('');
 395         $body =~ s/^\./../smg;
 396         do_more($self, $body);
 397         '.'
 398 }
 399
 400 sub header_str ($) {
 401         my ($s) = @_;
 402         my $h = $s->header_obj;
 403         $h->header_set('Bytes');
 404         $h->as_string
 405 }
 406
 407 sub set_art {
 408         my ($self, $art) = @_;
 409         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 410 }
 411
 412 sub cmd_article ($;$) {
 413         my ($self, $art) = @_;
 414         my $r = $self->art_lookup($art, 1);
 415         return $r unless ref $r;
 416         my ($n, $mid, $s) = @$r;
 417         set_art($self, $art);
 418         more($self, "220 $n <$mid> article retrieved - head and body follow");
 419         do_more($self, header_str($s));
 420         do_more($self, "\r\n");
 421         simple_body_write($self, $s);
 422 }
 423
 424 sub cmd_head ($;$) {
 425         my ($self, $art) = @_;
 426         my $r = $self->art_lookup($art, 2);
 427         return $r unless ref $r;
 428         my ($n, $mid, $s) = @$r;
 429         set_art($self, $art);
 430         more($self, "221 $n <$mid> article retrieved - head follows");
 431         do_more($self, header_str($s));
 432         '.'
 433 }
 434
 435 sub cmd_body ($;$) {
 436         my ($self, $art) = @_;
 437         my $r = $self->art_lookup($art, 0);
 438         return $r unless ref $r;
 439         my ($n, $mid, $s) = @$r;
 440         set_art($self, $art);
 441         more($self, "222 $n <$mid> article retrieved - body follows");
 442         simple_body_write($self, $s);
 443 }
 444
 445 sub cmd_stat ($;$) {
 446         my ($self, $art) = @_;
 447         my $r = $self->art_lookup($art, 0);
 448         return $r unless ref $r;
 449         my ($n, $mid, undef) = @$r;
 450         set_art($self, $art);
 451         "223 $n <$mid> article retrieved - request text separately";
 452 }
 453
 454 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 455
 456 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 457
 458 sub cmd_help ($) {
 459         my ($self) = @_;
 460         more($self, '100 help text follows');
 461         '.'
 462 }
 463
 464 sub get_range ($$) {
 465         my ($self, $range) = @_;
 466         my $ng = $self->{ng} or return '412 no news group has been selected';
 467         defined $range or return '420 No article(s) selected';
 468         my ($beg, $end);
 469         my ($min, $max) = $ng->mm->minmax;
 470         if ($range =~ /\A(\d+)\z/) {
 471                 $beg = $end = $1;
 472         } elsif ($range =~ /\A(\d+)-\z/) {
 473                 ($beg, $end) = ($1, $max);
 474         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 475                 ($beg, $end) = ($1, $2);
 476         } else {
 477                 return r501;
 478         }
 479         $beg = $min if ($beg < $min);
 480         $end = $max if ($end > $max);
 481         return '420 No article(s) selected' if ($beg > $end);
 482         [ $beg, $end ];
 483 }
 484
 485 sub xhdr ($$) {
 486         my ($r, $header) = @_;
 487         $r = $r->[2]->header_obj->header($header);
 488         defined $r or return;
 489         $r =~ s/[\r\n\t]+/ /sg;
 490         $r;
 491 }
 492
 493 sub long_response ($$$$) {
 494         my ($self, $beg, $end, $cb) = @_;
 495         die "BUG: nested long response" if $self->{long_res};
 496
 497         # make sure we disable reading during a long response,
 498         # clients should not be sending us stuff and making us do more
 499         # work while we are stream a response to them
 500         $self->watch_read(0);
 501         my $fd = fileno $self->{sock};
 502         my $t0 = now();
 503         $self->{long_res} = sub {
 504                 # limit our own running time for fairness with other
 505                 # clients and to avoid buffering too much:
 506                 my $yield;
 507                 local $SIG{ALRM} = sub { $yield = 1 };
 508                 ualarm(100000);
 509
 510                 my $err;
 511                 do {
 512                         eval { $cb->(\$beg) };
 513                 } until (($err = $@) || $self->{closed} || $yield ||
 514                          $self->{write_buf_size} || ++$beg > $end);
 515                 ualarm(0);
 516
 517                 if ($err || $self->{closed}) {
 518                         $self->{long_res} = undef;
 519
 520                         if ($err) {
 521                                 err($self,
 522                                     "$err during long response[$fd] - %0.6f",
 523                                         now() - $t0);
 524                         }
 525                         if ($self->{closed}) {
 526                                 out($self, " deferred[$fd] aborted - %0.6f",
 527                                            now() - $t0);
 528                         } else {
 529                                 $self->watch_read(1);
 530                         }
 531                 } elsif ($yield || $self->{write_buf_size}) {
 532                         # no recursion, schedule another call ASAP
 533                         # but only after all pending writes are done
 534                         Danga::Socket->AddTimer(0, sub {
 535                                 $self->write($self->{long_res});
 536                         });
 537                 } else { # all done!
 538                         $self->{long_res} = undef;
 539                         $self->watch_read(1);
 540                         res($self, '.');
 541                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 542                 }
 543         };
 544         $self->{long_res}->(); # kick off!
 545         undef;
 546 }
 547
 548 sub xhdr_message_id ($$) { # optimize XHDR Message-ID [range] for slrnpull.
 549         my ($self, $range) = @_;
 550
 551         my $mm = $self->{ng}->mm;
 552         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 553                 my $n = $mm->num_for($range);
 554                 more($self, '221 Header follows');
 555                 more($self, "<$range> <$range>") if defined $n;
 556                 '.';
 557         } else { # numeric range
 558                 $range = $self->{article} unless defined $range;
 559                 my $r = get_range($self, $range);
 560                 return $r unless ref $r;
 561                 my ($beg, $end) = @$r;
 562                 more($self, '221 Header follows');
 563                 $self->long_response($beg, $end, sub {
 564                         my ($i) = @_;
 565                         my $mid = $mm->mid_for($$i);
 566                         more($self, "$$i <$mid>") if defined $mid;
 567                 });
 568         }
 569 }
 570
 571 sub xref ($$) {
 572         my ($ng, $n) = @_;
 573         "$ng->{domain} $ng->{name}:$n"
 574 }
 575
 576 sub xhdr_xref ($$) { # optimize XHDR Xref [range] for rtin
 577         my ($self, $range) = @_;
 578
 579         my $ng = $self->{ng};
 580         my $mm = $ng->mm;
 581         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 582                 my $n = $mm->num_for($range);
 583                 more($self, '221 Header follows');
 584                 more($self, "<$range> ".xref($ng, $n)) if defined $n;
 585                 '.';
 586         } else { # numeric range
 587                 $range = $self->{article} unless defined $range;
 588                 my $r = get_range($self, $range);
 589                 return $r unless ref $r;
 590                 my ($beg, $end) = @$r;
 591                 more($self, '221 Header follows');
 592                 $self->long_response($beg, $end, sub {
 593                         my ($i) = @_;
 594                         my $mid = $mm->mid_for($$i);
 595                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 596                 });
 597         }
 598 }
 599
 600 sub header_obj_for {
 601         my ($srch, $mid) = @_;
 602         eval {
 603                 my $smsg = $srch->lookup_message($mid);
 604                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 605                 $smsg->mini_mime->header_obj;
 606         };
 607 };
 608
 609 sub xhdr_searchmsg ($$$) {
 610         my ($self, $sub, $range) = @_;
 611         my $srch = $self->{ng}->search;
 612         my $emit = ($sub eq 'date') ? sub {
 613                 my ($pfx, $m) = @_;
 614                 my @t = gmtime($m->header('X-PI-TS'));
 615                 more($self, "$pfx ". strftime('%a, %d %b %Y %T %z', @t));
 616         } : sub {
 617                 my ($pfx, $m) = @_;
 618                 my $h = $m->header($sub);
 619                 more($self, "$pfx $h") if defined $h;
 620         };
 621
 622         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 623                 more($self, '221 Header follows');
 624                 my $m = header_obj_for($srch, $1);
 625                 $emit->($range, $m) if defined $m;
 626                 '.';
 627         } else { # numeric range
 628                 $range = $self->{article} unless defined $range;
 629                 my $mm = $self->{ng}->mm;
 630                 my $r = get_range($self, $range);
 631                 return $r unless ref $r;
 632                 my ($beg, $end) = @$r;
 633                 more($self, '221 Header follows');
 634                 $self->long_response($beg, $end, sub {
 635                         my ($i) = @_;
 636                         my $mid = $mm->mid_for($$i) or return;
 637                         my $m = header_obj_for($srch, $mid) or return;
 638                         $emit->($$i, $m);
 639                 });
 640         }
 641 }
 642
 643 sub cmd_xhdr ($$;$) {
 644         my ($self, $header, $range) = @_;
 645         my $ng = $self->{ng};
 646         defined $ng or return '412 no news group currently selected';
 647         my $sub = lc $header;
 648         if ($sub eq 'message-id') {
 649                 xhdr_message_id($self, $range);
 650         } elsif ($sub eq 'xref') {
 651                 xhdr_xref($self, $range);
 652         } elsif ($sub =~ /\A(subject|references|date)\z/ && $ng->search) {
 653                 xhdr_searchmsg($self, $sub, $range);
 654         } else {
 655                 xhdr_slow($self, $header, $range);
 656         }
 657 }
 658
 659 sub xhdr_slow ($$$) {
 660         my ($self, $header, $range) = @_;
 661
 662         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 663                 my $r = $self->art_lookup($range, 2);
 664                 return $r unless ref $r;
 665                 more($self, '221 Header follows');
 666                 if (defined($r = xhdr($r, $header))) {
 667                         more($self, "<$range> $r");
 668                 }
 669                 '.';
 670         } else { # numeric range
 671                 $range = $self->{article} unless defined $range;
 672                 my $r = get_range($self, $range);
 673                 return $r unless ref $r;
 674                 my ($beg, $end) = @$r;
 675                 more($self, '221 Header follows');
 676                 $self->long_response($beg, $end, sub {
 677                         my ($i) = @_;
 678                         $r = $self->art_lookup($$i, 2);
 679                         return unless ref $r;
 680                         defined($r = xhdr($r, $header)) or return;
 681                         more($self, "$$i $r");
 682                 });
 683         }
 684 }
 685
 686 sub cmd_xrover ($;$) {
 687         my ($self, $range) = @_;
 688         my $ng = $self->{ng} or return '412 no newsgroup selected';
 689         (defined $range && $range =~ /[<>]/) and
 690                 return '420 No article(s) selected'; # no message IDs
 691
 692         $range = $self->{article} unless defined $range;
 693         my $r = get_range($self, $range);
 694         return $r unless ref $r;
 695         my ($beg, $end) = @$r;
 696         my $mm = $ng->mm;
 697         my $srch = $ng->search;
 698         more($self, '224 Overview information follows');
 699         $self->long_response($beg, $end, sub {
 700                 my ($i) = @_;
 701                 my $mid = $mm->mid_for($$i) or return;
 702                 my $m = header_obj_for($srch, $mid) or return;
 703                 my $h = $m->header('references');
 704                 more($self, "$$i $h") if defined $h;
 705         });
 706 }
 707
 708 sub cmd_xover ($;$) {
 709         my ($self, $range) = @_;
 710         $range = $self->{article} unless defined $range;
 711         my $r = get_range($self, $range);
 712         return $r unless ref $r;
 713         my ($beg, $end) = @$r;
 714         more($self, "224 Overview information follows for $beg to $end");
 715         $self->long_response($beg, $end, sub {
 716                 my ($i) = @_;
 717                 my $r = $self->art_lookup($$i, 2);
 718                 return unless ref $r;
 719                 more($self, join("\t", $r->[0],
 720                                 map {
 721                                         my $h = xhdr($r, $_);
 722                                         defined $h ? $h : '';
 723                                 } @OVERVIEW ));
 724         });
 725 }
 726
 727 sub cmd_xpath ($$) {
 728         my ($self, $mid) = @_;
 729         return r501 unless $mid =~ /\A<(.+)>\z/;
 730         $mid = $1;
 731         my @paths;
 732         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 733                 my $n = $ng->mm->num_for($mid);
 734                 push @paths, "$ng->{name}/$n" if defined $n;
 735         }
 736         return '430 no such article on server' unless @paths;
 737         '223 '.join(' ', @paths);
 738 }
 739
 740 sub res ($$) {
 741         my ($self, $line) = @_;
 742         do_write($self, $line . "\r\n");
 743 }
 744
 745 sub more ($$) {
 746         my ($self, $line) = @_;
 747         do_more($self, $line . "\r\n");
 748 }
 749
 750 sub do_write ($$) {
 751         my ($self, $data) = @_;
 752         my $done = $self->write($data);
 753         die if $self->{closed};
 754
 755         # Do not watch for readability if we have data in the queue,
 756         # instead re-enable watching for readability when we can
 757         $self->watch_read(0) if (!$done || $self->{long_res});
 758
 759         $done;
 760 }
 761
 762 sub err ($$;@) {
 763         my ($self, $fmt, @args) = @_;
 764         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 765 }
 766
 767 sub out ($$;@) {
 768         my ($self, $fmt, @args) = @_;
 769         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 770 }
 771
 772 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 773
 774 sub do_more ($$) {
 775         my ($self, $data) = @_;
 776         if (MSG_MORE && !$self->{write_buf_size}) {
 777                 my $n = send($self->{sock}, $data, MSG_MORE);
 778                 if (defined $n) {
 779                         my $dlen = length($data);
 780                         return 1 if $n == $dlen; # all done!
 781                         $data = substr($data, $n, $dlen - $n);
 782                 }
 783         }
 784         $self->do_write($data);
 785 }
 786
 787 # callbacks for by Danga::Socket
 788
 789 sub event_hup { $_[0]->close }
 790 sub event_err { $_[0]->close }
 791
 792 sub event_write {
 793         my ($self) = @_;
 794         # only continue watching for readability when we are done writing:
 795         if ($self->write(undef) == 1 && !$self->{long_res}) {
 796                 $self->watch_read(1);
 797         }
 798 }
 799
 800 sub event_read {
 801         my ($self) = @_;
 802         use constant LINE_MAX => 512; # RFC 977 section 2.3
 803         my $line;
 804         my $r = 1;
 805 again:
 806         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 807                 $line = $1;
 808                 my $t0 = now();
 809                 $r = eval { $self->process_line($line) };
 810                 my $d = $self->{long_res} ?
 811                         ' deferred['.fileno($self->{sock}).']' : '';
 812                 out($self, "$line - %0.6f$d", now() - $t0);
 813         }
 814         unless (defined $line) {
 815                 my $buf = $self->read(LINE_MAX) or return $self->close;
 816                 $self->{rbuf} .= $$buf;
 817                 goto again;
 818         }
 819
 820         return $self->close if $r < 0;
 821         my $len = length($self->{rbuf});
 822         return $self->close if ($len >= LINE_MAX);
 823 }
 824
 825 sub watch_read {
 826         my ($self, $bool) = @_;
 827         my $rv = $self->SUPER::watch_read($bool);
 828         if ($bool && $self->{rbuf} ne '') {
 829                 # Force another read if there is a pipelined request.
 830                 # We don't know if the socket has anything for us to read,
 831                 # and we must double-check again by the time the timer fires
 832                 # in case we really did dispatch a read event and started
 833                 # another long response.
 834                 Danga::Socket->AddTimer(0, sub {
 835                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 836                                 $self->event_read;
 837                         }
 838                 });
 839         }
 840         $rv;
 841 }
 842
 843 1;