lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime ualarm CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         r221 => '221 Header follows',
  18         r224 => '224 Overview information follows (multi-line)',
  19         r430 => '430 No article with that message-id',
  20         long_response_limit => 0xffffffff,
  21 };
  22
  23 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  24
  25 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  26 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  27
  28 # disable commands with easy DoS potential:
  29 # LISTGROUP could get pretty bad, too...
  30 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  31
  32 sub new ($$$) {
  33         my ($class, $sock, $nntpd) = @_;
  34         my $self = fields::new($class);
  35         binmode $sock, ':utf8'; # RFC 3977
  36         $self->SUPER::new($sock);
  37         $self->{nntpd} = $nntpd;
  38         res($self, '201 server ready - post via email');
  39         $self->{rbuf} = '';
  40         $self->watch_read(1);
  41         $self;
  42 }
  43
  44 sub args_ok ($$) {
  45         my ($cb, $argc) = @_;
  46         my $tot = prototype $cb;
  47         my ($nreq, undef) = split(';', $tot);
  48         $nreq = ($nreq =~ tr/$//) - 1;
  49         $tot = ($tot =~ tr/$//) - 1;
  50         ($argc <= $tot && $argc >= $nreq);
  51 }
  52
  53 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  54 sub process_line ($$) {
  55         my ($self, $l) = @_;
  56         my ($req, @args) = split(/\s+/, $l);
  57         $req = lc($req);
  58         $req = eval {
  59                 no strict 'refs';
  60                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  61         };
  62         return res($self, '500 command not recognized') unless $req;
  63         return res($self, r501) unless args_ok($req, scalar @args);
  64
  65         my $res = eval { $req->($self, @args) };
  66         my $err = $@;
  67         if ($err && !$self->{closed}) {
  68                 chomp($l = Dumper(\$l));
  69                 err($self, "error from: $l $err");
  70                 $res = '503 program fault - command not performed';
  71         }
  72         return 0 unless defined $res;
  73         res($self, $res);
  74 }
  75
  76 sub cmd_mode ($$) {
  77         my ($self, $arg) = @_;
  78         $arg = uc $arg;
  79         return r501 unless $arg eq 'READER';
  80         '200 reader status acknowledged';
  81 }
  82
  83 sub cmd_slave ($) { '202 slave status noted' }
  84
  85 sub cmd_xgtitle ($;$) {
  86         my ($self, $wildmat) = @_;
  87         more($self, '282 list of groups and descriptions follows');
  88         list_newsgroups($self, $wildmat);
  89         '.'
  90 }
  91
  92 sub list_overview_fmt ($$) {
  93         my ($self) = @_;
  94         more($self, $_ . ':') foreach @OVERVIEW;
  95 }
  96
  97 sub list_active ($;$) {
  98         my ($self, $wildmat) = @_;
  99         wildmat2re($wildmat);
 100         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 101                 $ng->{name} =~ $wildmat or next;
 102                 group_line($self, $ng);
 103         }
 104 }
 105
 106 sub list_active_times ($;$) {
 107         my ($self, $wildmat) = @_;
 108         wildmat2re($wildmat);
 109         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 110                 $ng->{name} =~ $wildmat or next;
 111                 my $c = eval { $ng->mm->created_at } || time;
 112                 more($self, "$ng->{name} $c $ng->{address}");
 113         }
 114 }
 115
 116 sub list_newsgroups ($;$) {
 117         my ($self, $wildmat) = @_;
 118         wildmat2re($wildmat);
 119         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 120                 $ng->{name} =~ $wildmat or next;
 121                 my $d = $ng->description;
 122                 more($self, "$ng->{name} $d");
 123         }
 124 }
 125
 126 # LIST SUBSCRIPTIONS not supported
 127 sub cmd_list ($;$$) {
 128         my ($self, @args) = @_;
 129         if (scalar @args) {
 130                 my $arg = shift @args;
 131                 $arg =~ tr/A-Z./a-z_/;
 132                 $arg = "list_$arg";
 133                 return '503 function not performed' if $DISABLED{$arg};
 134
 135                 $arg = eval {
 136                         no strict 'refs';
 137                         *{$arg}{CODE};
 138                 };
 139                 return r501 unless $arg && args_ok($arg, scalar @args);
 140                 more($self, '215 information follows');
 141                 $arg->($self, @args);
 142         } else {
 143                 more($self, '215 list of newsgroups follows');
 144                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 145                         group_line($self, $ng);
 146                 }
 147         }
 148         '.'
 149 }
 150
 151 sub cmd_listgroup ($;$) {
 152         my ($self, $group) = @_;
 153         if (defined $group) {
 154                 my $res = cmd_group($self, $group);
 155                 return $res if ($res !~ /\A211 /);
 156                 more($self, $res);
 157         }
 158
 159         $self->{ng} or return '412 no newsgroup selected';
 160         $self->long_response(0, long_response_limit, sub {
 161                 my ($i) = @_;
 162                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 163                         my ($ary) = @_;
 164                         more($self, join("\r\n", @$ary));
 165                 });
 166
 167                 # -1 to adjust for implicit increment in long_response
 168                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 169         });
 170 }
 171
 172 sub parse_time ($$;$) {
 173         my ($date, $time, $gmt) = @_;
 174         use Time::Local qw();
 175         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 176         if (defined $gmt) {
 177                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 178                 $gmt = 1;
 179         }
 180         my @now = $gmt ? gmtime : localtime;
 181         my ($YYYY, $MM, $DD);
 182         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 183                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 184         } else { # legacy clients send YYMMDD
 185                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 186                 if ($YYYY > strftime('%y', @now)) {
 187                         my $cur_year = $now[5] + 1900;
 188                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 189                 }
 190         }
 191         if ($gmt) {
 192                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 193         } else {
 194                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 195         }
 196 }
 197
 198 sub group_line ($$) {
 199         my ($self, $ng) = @_;
 200         my ($min, $max) = $ng->mm->minmax;
 201         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 202 }
 203
 204 sub cmd_newgroups ($$$;$$) {
 205         my ($self, $date, $time, $gmt, $dists) = @_;
 206         my $ts = eval { parse_time($date, $time, $gmt) };
 207         return r501 if $@;
 208
 209         # TODO dists
 210         more($self, '231 list of new newsgroups follows');
 211         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 212                 my $c = eval { $ng->mm->created_at } || 0;
 213                 next unless $c > $ts;
 214                 group_line($self, $ng);
 215         }
 216         '.'
 217 }
 218
 219 sub wildmat2re (;$) {
 220         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 221         my %keep;
 222         my $salt = rand;
 223         use Digest::SHA qw(sha1_hex);
 224         my $tmp = $_[0];
 225
 226         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 227                 my $orig = $1;
 228                 my $key = sha1_hex($orig . $salt);
 229                 $orig =~ s/([^\w\-])+/\Q$1/g;
 230                 $keep{$key} = $orig;
 231                 $key
 232                 #gex;
 233         my %map = ('*' => '.*', '?' => '.' );
 234         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 235         if (scalar %keep) {
 236                 $tmp =~ s#([a-f0-9]{40})#
 237                         my $orig = $keep{$1};
 238                         defined $orig ? $orig : $1;
 239                         #ge;
 240         }
 241         $_[0] = qr/\A$tmp\z/;
 242 }
 243
 244 sub ngpat2re (;$) {
 245         return $_[0] = qr/\A\z/ unless defined $_[0];
 246         my %map = ('*' => '.*', ',' => '|');
 247         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 248         $_[0] = qr/\A(?:$_[0])\z/;
 249 }
 250
 251 sub cmd_newnews ($$$$;$$) {
 252         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 253         my $ts = eval { parse_time($date, $time, $gmt) };
 254         return r501 if $@;
 255         more($self, '230 list of new articles by message-id follows');
 256         my ($keep, $skip) = split('!', $newsgroups, 2);
 257         ngpat2re($keep);
 258         ngpat2re($skip);
 259         my @srch;
 260         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 261                 $ng->{name} =~ $keep or next;
 262                 $ng->{name} =~ $skip and next;
 263                 my $srch = $ng->search or next;
 264                 push @srch, $srch;
 265         };
 266         return '.' unless @srch;
 267
 268         $ts .= '..';
 269         my $opts = { asc => 1, limit => 1000, offset => 0 };
 270         $self->long_response(0, long_response_limit, sub {
 271                 my ($i) = @_;
 272                 my $srch = $srch[0];
 273                 my $res = $srch->query($ts, $opts);
 274                 my $msgs = $res->{msgs};
 275                 if (my $nr = scalar @$msgs) {
 276                         more($self, '<' .
 277                                 join(">\r\n<", map { $_->mid } @$msgs ).
 278                                 '>');
 279                         $opts->{offset} += $nr;
 280                 } else {
 281                         shift @srch;
 282                         if (@srch) { # continue onto next newsgroup
 283                                 $opts->{offset} = 0;
 284                         } else { # break out of the long response.
 285                                 $$i = long_response_limit;
 286                         }
 287                 }
 288         });
 289 }
 290
 291 sub cmd_group ($$) {
 292         my ($self, $group) = @_;
 293         my $no_such = '411 no such news group';
 294         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 295
 296         $self->{ng} = $ng;
 297         my ($min, $max) = $ng->mm->minmax;
 298         $min ||= 0;
 299         $max ||= 0;
 300         $self->{article} = $min;
 301         my $est_size = $max - $min;
 302         "211 $est_size $min $max $group";
 303 }
 304
 305 sub article_adj ($$) {
 306         my ($self, $off) = @_;
 307         my $ng = $self->{ng} or return '412 no newsgroup selected';
 308
 309         my $n = $self->{article};
 310         defined $n or return '420 no current article has been selected';
 311
 312         $n += $off;
 313         my $mid = $ng->mm->mid_for($n);
 314         unless ($mid) {
 315                 $n = $off > 0 ? 'next' : 'previous';
 316                 return "421 no $n article in this group";
 317         }
 318         $self->{article} = $n;
 319         "223 $n <$mid> article retrieved - request text separately";
 320 }
 321
 322 sub cmd_next ($) { article_adj($_[0], 1) }
 323 sub cmd_last ($) { article_adj($_[0], -1) }
 324
 325 # We want to encourage using email and CC-ing everybody involved to avoid
 326 # the single-point-of-failure a single server provides.
 327 sub cmd_post ($) {
 328         my ($self) = @_;
 329         my $ng = $self->{ng};
 330         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 331 }
 332
 333 sub cmd_quit ($) {
 334         my ($self) = @_;
 335         res($self, '205 closing connection - goodbye!');
 336         $self->close;
 337         undef;
 338 }
 339
 340 sub art_lookup ($$$) {
 341         my ($self, $art, $set_headers) = @_;
 342         my $ng = $self->{ng};
 343         my ($n, $mid);
 344         my $err;
 345         if (defined $art) {
 346                 if ($art =~ /\A\d+\z/o) {
 347                         $err = '423 no such article number in this group';
 348                         $n = int($art);
 349                         goto find_mid;
 350                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 351                         $mid = $1;
 352                         $err = r430;
 353                         $n = $ng->mm->num_for($mid) if $ng;
 354                         goto found if defined $n;
 355                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 356                                 $n = $g->mm->num_for($mid);
 357                                 if (defined $n) {
 358                                         $ng = $g;
 359                                         goto found;
 360                                 }
 361                         }
 362                         return $err;
 363                 } else {
 364                         return r501;
 365                 }
 366         } else {
 367                 $err = '420 no current article has been selected';
 368                 $n = $self->{article};
 369                 defined $n or return $err;
 370 find_mid:
 371                 $ng or return '412 no newsgroup has been selected';
 372                 $mid = $ng->mm->mid_for($n);
 373                 defined $mid or return $err;
 374         }
 375 found:
 376         my $o = 'HEAD:' . mid2path($mid);
 377         my $bytes;
 378         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 379         return $err unless $s;
 380         my $lines;
 381         if ($set_headers) {
 382                 $s->header_set('Newsgroups', $ng->{name});
 383                 $s->header_set('Xref', xref($ng, $n));
 384                 $lines = $s->body =~ tr!\n!\n!;
 385
 386                 # must be last
 387                 $s->body_set('') if ($set_headers == 2);
 388         }
 389         [ $n, $mid, $s, $bytes, $lines, $ng ];
 390 }
 391
 392 sub simple_body_write ($$) {
 393         my ($self, $s) = @_;
 394         my $body = $s->body;
 395         $s->body_set('');
 396         $body =~ s/^\./../smg;
 397         $body =~ s/(?<!\r)\n/\r\n/sg;
 398         do_more($self, $body);
 399         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 400         '.'
 401 }
 402
 403 sub set_art {
 404         my ($self, $art) = @_;
 405         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 406 }
 407
 408 sub cmd_article ($;$) {
 409         my ($self, $art) = @_;
 410         my $r = $self->art_lookup($art, 1);
 411         return $r unless ref $r;
 412         my ($n, $mid, $s) = @$r;
 413         set_art($self, $art);
 414         more($self, "220 $n <$mid> article retrieved - head and body follow");
 415         do_more($self, $s->header_obj->as_string);
 416         do_more($self, "\r\n");
 417         simple_body_write($self, $s);
 418 }
 419
 420 sub cmd_head ($;$) {
 421         my ($self, $art) = @_;
 422         my $r = $self->art_lookup($art, 2);
 423         return $r unless ref $r;
 424         my ($n, $mid, $s) = @$r;
 425         set_art($self, $art);
 426         more($self, "221 $n <$mid> article retrieved - head follows");
 427         do_more($self, $s->header_obj->as_string);
 428         '.'
 429 }
 430
 431 sub cmd_body ($;$) {
 432         my ($self, $art) = @_;
 433         my $r = $self->art_lookup($art, 0);
 434         return $r unless ref $r;
 435         my ($n, $mid, $s) = @$r;
 436         set_art($self, $art);
 437         more($self, "222 $n <$mid> article retrieved - body follows");
 438         simple_body_write($self, $s);
 439 }
 440
 441 sub cmd_stat ($;$) {
 442         my ($self, $art) = @_;
 443         my $r = $self->art_lookup($art, 0);
 444         return $r unless ref $r;
 445         my ($n, $mid, undef) = @$r;
 446         set_art($self, $art);
 447         "223 $n <$mid> article retrieved - request text separately";
 448 }
 449
 450 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 451
 452 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 453
 454 sub cmd_help ($) {
 455         my ($self) = @_;
 456         more($self, '100 help text follows');
 457         '.'
 458 }
 459
 460 sub get_range ($$) {
 461         my ($self, $range) = @_;
 462         my $ng = $self->{ng} or return '412 no news group has been selected';
 463         defined $range or return '420 No article(s) selected';
 464         my ($beg, $end);
 465         my ($min, $max) = $ng->mm->minmax;
 466         if ($range =~ /\A(\d+)\z/) {
 467                 $beg = $end = $1;
 468         } elsif ($range =~ /\A(\d+)-\z/) {
 469                 ($beg, $end) = ($1, $max);
 470         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 471                 ($beg, $end) = ($1, $2);
 472         } else {
 473                 return r501;
 474         }
 475         $beg = $min if ($beg < $min);
 476         $end = $max if ($end > $max);
 477         return '420 No article(s) selected' if ($beg > $end);
 478         [ $beg, $end ];
 479 }
 480
 481 sub hdr_val ($$) {
 482         my ($r, $header) = @_;
 483         return $r->[3] if $header =~ /\A:?bytes\z/i;
 484         return $r->[4] if $header =~ /\A:?lines\z/i;
 485         $r = $r->[2]->header_obj->header($header);
 486         defined $r or return;
 487         $r =~ s/[\r\n\t]+/ /sg;
 488         $r;
 489 }
 490
 491 sub long_response ($$$$) {
 492         my ($self, $beg, $end, $cb) = @_;
 493         die "BUG: nested long response" if $self->{long_res};
 494
 495         # make sure we disable reading during a long response,
 496         # clients should not be sending us stuff and making us do more
 497         # work while we are stream a response to them
 498         $self->watch_read(0);
 499         my $fd = fileno $self->{sock};
 500         my $t0 = now();
 501         $self->{long_res} = sub {
 502                 # limit our own running time for fairness with other
 503                 # clients and to avoid buffering too much:
 504                 my $yield;
 505                 local $SIG{ALRM} = sub { $yield = 1 };
 506                 ualarm(100000);
 507
 508                 my $err;
 509                 do {
 510                         eval { $cb->(\$beg) };
 511                 } until (($err = $@) || $self->{closed} || $yield ||
 512                          $self->{write_buf_size} || ++$beg > $end);
 513                 ualarm(0);
 514
 515                 if ($err || $self->{closed}) {
 516                         $self->{long_res} = undef;
 517
 518                         if ($err) {
 519                                 err($self,
 520                                     "$err during long response[$fd] - %0.6f",
 521                                         now() - $t0);
 522                         }
 523                         if ($self->{closed}) {
 524                                 out($self, " deferred[$fd] aborted - %0.6f",
 525                                            now() - $t0);
 526                         } else {
 527                                 $self->watch_read(1);
 528                         }
 529                 } elsif ($yield || $self->{write_buf_size}) {
 530                         # no recursion, schedule another call ASAP
 531                         # but only after all pending writes are done
 532                         Danga::Socket->AddTimer(0, sub {
 533                                 $self->write($self->{long_res});
 534                         });
 535                 } else { # all done!
 536                         $self->{long_res} = undef;
 537                         $self->watch_read(1);
 538                         res($self, '.');
 539                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 540                 }
 541         };
 542         $self->{long_res}->(); # kick off!
 543         undef;
 544 }
 545
 546 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 547         my ($self, $xhdr, $range) = @_;
 548
 549         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 550                 my ($ng, $n) = mid_lookup($self, $1);
 551                 return r430 unless $n;
 552                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 553         } else { # numeric range
 554                 $range = $self->{article} unless defined $range;
 555                 my $r = get_range($self, $range);
 556                 return $r unless ref $r;
 557                 my $mm = $self->{ng}->mm;
 558                 my ($beg, $end) = @$r;
 559                 more($self, '221 Header follows');
 560                 $self->long_response($beg, $end, sub {
 561                         my ($i) = @_;
 562                         my $mid = $mm->mid_for($$i);
 563                         more($self, "$$i <$mid>") if defined $mid;
 564                 });
 565         }
 566 }
 567
 568 sub xref ($$) {
 569         my ($ng, $n) = @_;
 570         "$ng->{domain} $ng->{name}:$n"
 571 }
 572
 573 sub mid_lookup ($$) {
 574         my ($self, $mid) = @_;
 575         my $self_ng = $self->{ng};
 576         if ($self_ng) {
 577                 my $n = $self_ng->mm->num_for($mid);
 578                 return ($self_ng, $n) if defined $n;
 579         }
 580         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 581                 next if defined $self_ng && $ng eq $self_ng;
 582                 my $n = $ng->mm->num_for($mid);
 583                 return ($ng, $n) if defined $n;
 584         }
 585         (undef, undef);
 586 }
 587
 588 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 589         my ($self, $xhdr, $range) = @_;
 590
 591         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 592                 my ($ng, $n) = mid_lookup($self, $1);
 593                 return r430 unless $n;
 594                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 595         } else { # numeric range
 596                 $range = $self->{article} unless defined $range;
 597                 my $r = get_range($self, $range);
 598                 return $r unless ref $r;
 599                 my $ng = $self->{ng};
 600                 my $mm = $ng->mm;
 601                 my ($beg, $end) = @$r;
 602                 more($self, '221 Header follows');
 603                 $self->long_response($beg, $end, sub {
 604                         my ($i) = @_;
 605                         my $mid = $mm->mid_for($$i);
 606                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 607                 });
 608         }
 609 }
 610
 611 sub header_obj_for {
 612         my ($srch, $mid) = @_;
 613         eval {
 614                 my $smsg = $srch->lookup_message($mid);
 615                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 616                 $smsg->mini_mime->header_obj;
 617         };
 618 };
 619
 620 sub hdr_searchmsg ($$$$) {
 621         my ($self, $xhdr, $hdr, $range) = @_;
 622         my $filter;
 623         if ($hdr eq 'date') {
 624                 $hdr = 'X-PI-TS';
 625                 $filter = sub ($) {
 626                         strftime('%a, %d %b %Y %T %z', gmtime($_[0]));
 627                 };
 628         }
 629
 630         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 631                 my ($ng, $n) = mid_lookup($self, $1);
 632                 return r430 unless $n;
 633                 if (my $srch = $ng->search) {
 634                         my $m = header_obj_for($srch, $range);
 635                         my $v = $m->header($hdr);
 636                         $v = $filter->($v) if defined $v && $filter;
 637                         hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 638                 } else {
 639                         hdr_slow($self, $xhdr, $hdr, $range);
 640                 }
 641         } else { # numeric range
 642                 $range = $self->{article} unless defined $range;
 643                 my $srch = $self->{ng}->search or
 644                                 return hdr_slow($self, $xhdr, $hdr, $range);
 645                 my $mm = $self->{ng}->mm;
 646                 my $r = get_range($self, $range);
 647                 return $r unless ref $r;
 648                 my ($beg, $end) = @$r;
 649                 more($self, '221 Header follows');
 650                 $self->long_response($beg, $end, sub {
 651                         my ($i) = @_;
 652                         my $mid = $mm->mid_for($$i) or return;
 653                         my $m = header_obj_for($srch, $mid) or return;
 654                         my $v = $m->header($hdr);
 655                         defined $v or return;
 656                         $v = $filter->($v) if $filter;
 657                         more($self, "$$i $v");
 658                 });
 659         }
 660 }
 661
 662 sub do_hdr ($$$;$) {
 663         my ($self, $xhdr, $header, $range) = @_;
 664         my $sub = lc $header;
 665         if ($sub eq 'message-id') {
 666                 hdr_message_id($self, $xhdr, $range);
 667         } elsif ($sub eq 'xref') {
 668                 hdr_xref($self, $xhdr, $range);
 669         } elsif ($sub =~ /\A(subject|references|date)\z/) {
 670                 hdr_searchmsg($self, $xhdr, $sub, $range);
 671         } else {
 672                 hdr_slow($self, $xhdr, $header, $range);
 673         }
 674 }
 675
 676 # RFC 3977
 677 sub cmd_hdr ($$;$) {
 678         my ($self, $header, $range) = @_;
 679         do_hdr($self, 0, $header, $range);
 680 }
 681
 682 # RFC 2980
 683 sub cmd_xhdr ($$;$) {
 684         my ($self, $header, $range) = @_;
 685         do_hdr($self, 1, $header, $range);
 686 }
 687
 688 sub hdr_mid_prefix ($$$$$) {
 689         my ($self, $xhdr, $ng, $n, $mid) = @_;
 690         return $mid if $xhdr;
 691
 692         # HDR for RFC 3977 users
 693         if (my $self_ng = $self->{ng}) {
 694                 ($self_ng eq $ng) ? $n : '0';
 695         } else {
 696                 '0';
 697         }
 698 }
 699
 700 sub hdr_mid_response ($$$$$$) {
 701         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 702         my $res = '';
 703         if ($xhdr) {
 704                 $res .= r221 . "\r\n";
 705                 $res .= "$mid $v\r\n" if defined $v;
 706         } else {
 707                 $res .= r224 . "\r\n";
 708                 if (defined $v) {
 709                         my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 710                         $res .= "$pfx $v\r\n";
 711                 }
 712         }
 713         res($self, $res .= '.');
 714         undef;
 715 }
 716
 717 sub hdr_slow ($$$$) {
 718         my ($self, $xhdr, $header, $range) = @_;
 719
 720         if (defined $range && $range =~ /\A<.+>\z/) { # Message-ID
 721                 my $r = $self->art_lookup($range, 2);
 722                 return $r unless ref $r;
 723                 my ($n, $ng) = ($r->[0], $r->[5]);
 724                 my $v = hdr_val($r, $header);
 725                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 726         } else { # numeric range
 727                 $range = $self->{article} unless defined $range;
 728                 my $r = get_range($self, $range);
 729                 return $r unless ref $r;
 730                 my ($beg, $end) = @$r;
 731                 more($self, $xhdr ? r221 : r224);
 732                 $self->long_response($beg, $end, sub {
 733                         my ($i) = @_;
 734                         $r = $self->art_lookup($$i, 2);
 735                         return unless ref $r;
 736                         defined($r = hdr_val($r, $header)) or return;
 737                         more($self, "$$i $r");
 738                 });
 739         }
 740 }
 741
 742 sub cmd_xrover ($;$) {
 743         my ($self, $range) = @_;
 744         my $ng = $self->{ng} or return '412 no newsgroup selected';
 745         (defined $range && $range =~ /[<>]/) and
 746                 return '420 No article(s) selected'; # no message IDs
 747
 748         $range = $self->{article} unless defined $range;
 749         my $r = get_range($self, $range);
 750         return $r unless ref $r;
 751         my ($beg, $end) = @$r;
 752         my $mm = $ng->mm;
 753         my $srch = $ng->search;
 754         more($self, '224 Overview information follows');
 755         $self->long_response($beg, $end, sub {
 756                 my ($i) = @_;
 757                 my $mid = $mm->mid_for($$i) or return;
 758                 my $m = header_obj_for($srch, $mid) or return;
 759                 my $h = $m->header('references');
 760                 more($self, "$$i $h") if defined $h;
 761         });
 762 }
 763
 764 sub over_line ($$) {
 765         my ($self, $r) = @_;
 766
 767         more($self, join("\t", $r->[0], map {
 768                                 my $h = hdr_val($r, $_);
 769                                 defined $h ? $h : '';
 770                         } @OVERVIEW ));
 771 }
 772
 773 sub cmd_over ($;$) {
 774         my ($self, $range) = @_;
 775         if ($range && $range =~ /\A<.+>\z/) {
 776                 my $r = $self->art_lookup($range, 2);
 777                 return '430 No article with that message-id' unless ref $r;
 778                 more($self, '224 Overview information follows (multi-line)');
 779
 780                 # Only set article number column if it's the current group
 781                 my $ng = $self->{ng};
 782                 $r->[0] = 0 if (!$ng || $ng ne $r->[5]);
 783                 over_line($self, $r);
 784                 '.';
 785         } else {
 786                 cmd_xover($self, $range);
 787         }
 788 }
 789
 790 sub cmd_xover ($;$) {
 791         my ($self, $range) = @_;
 792         $range = $self->{article} unless defined $range;
 793         my $r = get_range($self, $range);
 794         return $r unless ref $r;
 795         my ($beg, $end) = @$r;
 796         more($self, "224 Overview information follows for $beg to $end");
 797         $self->long_response($beg, $end, sub {
 798                 my ($i) = @_;
 799                 my $r = $self->art_lookup($$i, 2);
 800                 return unless ref $r;
 801                 over_line($self, $r);
 802         });
 803 }
 804
 805 sub cmd_xpath ($$) {
 806         my ($self, $mid) = @_;
 807         return r501 unless $mid =~ /\A<(.+)>\z/;
 808         $mid = $1;
 809         my @paths;
 810         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 811                 my $n = $ng->mm->num_for($mid);
 812                 push @paths, "$ng->{name}/$n" if defined $n;
 813         }
 814         return '430 no such article on server' unless @paths;
 815         '223 '.join(' ', @paths);
 816 }
 817
 818 sub res ($$) {
 819         my ($self, $line) = @_;
 820         do_write($self, $line . "\r\n");
 821 }
 822
 823 sub more ($$) {
 824         my ($self, $line) = @_;
 825         do_more($self, $line . "\r\n");
 826 }
 827
 828 sub do_write ($$) {
 829         my ($self, $data) = @_;
 830         my $done = $self->write($data);
 831         die if $self->{closed};
 832
 833         # Do not watch for readability if we have data in the queue,
 834         # instead re-enable watching for readability when we can
 835         $self->watch_read(0) if (!$done || $self->{long_res});
 836
 837         $done;
 838 }
 839
 840 sub err ($$;@) {
 841         my ($self, $fmt, @args) = @_;
 842         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 843 }
 844
 845 sub out ($$;@) {
 846         my ($self, $fmt, @args) = @_;
 847         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 848 }
 849
 850 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 851
 852 sub do_more ($$) {
 853         my ($self, $data) = @_;
 854         if (MSG_MORE && !$self->{write_buf_size}) {
 855                 my $n = send($self->{sock}, $data, MSG_MORE);
 856                 if (defined $n) {
 857                         my $dlen = length($data);
 858                         return 1 if $n == $dlen; # all done!
 859                         $data = substr($data, $n, $dlen - $n);
 860                 }
 861         }
 862         $self->do_write($data);
 863 }
 864
 865 # callbacks for by Danga::Socket
 866
 867 sub event_hup { $_[0]->close }
 868 sub event_err { $_[0]->close }
 869
 870 sub event_write {
 871         my ($self) = @_;
 872         # only continue watching for readability when we are done writing:
 873         if ($self->write(undef) == 1 && !$self->{long_res}) {
 874                 $self->watch_read(1);
 875         }
 876 }
 877
 878 sub event_read {
 879         my ($self) = @_;
 880         use constant LINE_MAX => 512; # RFC 977 section 2.3
 881         my $r = 1;
 882
 883         my $buf = $self->read(LINE_MAX) or return $self->close;
 884         $self->{rbuf} .= $$buf;
 885         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 886                 my $line = $1;
 887                 my $t0 = now();
 888                 $r = eval { $self->process_line($line) };
 889                 my $d = $self->{long_res} ?
 890                         ' deferred['.fileno($self->{sock}).']' : '';
 891                 out($self, "$line - %0.6f$d", now() - $t0);
 892         }
 893
 894         return $self->close if $r < 0;
 895         my $len = length($self->{rbuf});
 896         return $self->close if ($len >= LINE_MAX);
 897 }
 898
 899 sub watch_read {
 900         my ($self, $bool) = @_;
 901         my $rv = $self->SUPER::watch_read($bool);
 902         if ($bool && $self->{rbuf} ne '') {
 903                 # Force another read if there is a pipelined request.
 904                 # We don't know if the socket has anything for us to read,
 905                 # and we must double-check again by the time the timer fires
 906                 # in case we really did dispatch a read event and started
 907                 # another long response.
 908                 Danga::Socket->AddTimer(0, sub {
 909                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 910                                 $self->event_read;
 911                         }
 912                 });
 913         }
 914         $rv;
 915 }
 916
 917 sub busy () {
 918         my ($self) = @_;
 919         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 920 }
 921
 922 1;