lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use constant {
  20         LINE_MAX => 512, # RFC 977 section 2.3
  21         r501 => '501 command syntax error',
  22         r502 => '502 Command unavailable',
  23         r221 => '221 Header follows',
  24         r224 => '224 Overview information follows (multi-line)',
  25         r225 => '225 Headers follow (multi-line)',
  26         r430 => '430 No article with that message-id',
  27 };
  28 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  29 use Errno qw(EAGAIN);
  30
  31 my @OVERVIEW = qw(Subject From Date Message-ID References);
  32 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  33                 "Xref:full\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36 my $CAPABILITIES = <<"";
  37 101 Capability list:\r
  38 VERSION 2\r
  39 READER\r
  40 NEWNEWS\r
  41 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  42 HDR\r
  43 OVER\r
  44
  45 my $have_deflate;
  46 my $EXPMAP; # fd -> [ idle_time, $self ]
  47 my $expt;
  48 our $EXPTIME = 180; # 3 minutes
  49
  50 sub update_idle_time ($) {
  51         my ($self) = @_;
  52         my $sock = $self->{sock} or return;
  53         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  54 }
  55
  56 sub expire_old () {
  57         my $now = now();
  58         my $exp = $EXPTIME;
  59         my $old = $now - $exp;
  60         my %new;
  61         while (my ($fd, $v) = each %$EXPMAP) {
  62                 my ($idle_time, $nntp) = @$v;
  63                 if ($idle_time < $old) {
  64                         if (!$nntp->shutdn) {
  65                                 $new{$fd} = $v;
  66                         }
  67                 } else {
  68                         $new{$fd} = $v;
  69                 }
  70         }
  71         $EXPMAP = \%new;
  72         $expt = scalar(keys %new) ? PublicInbox::DS::later(*expire_old)
  73                                   : undef;
  74 }
  75
  76 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  77
  78 sub new ($$$) {
  79         my ($class, $sock, $nntpd) = @_;
  80         my $self = fields::new($class);
  81         my $ev = EPOLLIN;
  82         my $wbuf;
  83         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  84                 return CORE::close($sock) if $! != EAGAIN;
  85                 $ev = PublicInbox::TLS::epollbit();
  86                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  87         }
  88         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  89         $self->{nntpd} = $nntpd;
  90         if ($wbuf) {
  91                 $self->{wbuf} = $wbuf;
  92         } else {
  93                 greet($self);
  94         }
  95         update_idle_time($self);
  96         $expt ||= PublicInbox::DS::later(*expire_old);
  97         $self;
  98 }
  99
 100 sub args_ok ($$) {
 101         my ($cb, $argc) = @_;
 102         my $tot = prototype $cb;
 103         my ($nreq, undef) = split(';', $tot);
 104         $nreq = ($nreq =~ tr/$//) - 1;
 105         $tot = ($tot =~ tr/$//) - 1;
 106         ($argc <= $tot && $argc >= $nreq);
 107 }
 108
 109 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 110 sub process_line ($$) {
 111         my ($self, $l) = @_;
 112         my ($req, @args) = split(/[ \t]/, $l);
 113         return 1 unless defined($req); # skip blank line
 114         $req = eval {
 115                 no strict 'refs';
 116                 *{'cmd_'.lc($req)}{CODE};
 117         };
 118         return res($self, '500 command not recognized') unless $req;
 119         return res($self, r501) unless args_ok($req, scalar @args);
 120
 121         my $res = eval { $req->($self, @args) };
 122         my $err = $@;
 123         if ($err && $self->{sock}) {
 124                 local $/ = "\n";
 125                 chomp($l);
 126                 err($self, 'error from: %s (%s)', $l, $err);
 127                 $res = '503 program fault - command not performed';
 128         }
 129         return 0 unless defined $res;
 130         res($self, $res);
 131 }
 132
 133 # The keyword argument is not used (rfc3977 5.2.2)
 134 sub cmd_capabilities ($;$) {
 135         my ($self, undef) = @_;
 136         my $res = $CAPABILITIES;
 137         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 138                         $self->{nntpd}->{accept_tls}) {
 139                 $res .= "STARTTLS\r\n";
 140         }
 141         $res .= '.';
 142 }
 143
 144 sub cmd_mode ($$) {
 145         my ($self, $arg) = @_;
 146         $arg = uc $arg;
 147         return r501 unless $arg eq 'READER';
 148         '201 Posting prohibited';
 149 }
 150
 151 sub cmd_slave ($) { '202 slave status noted' }
 152
 153 sub cmd_xgtitle ($;$) {
 154         my ($self, $wildmat) = @_;
 155         more($self, '282 list of groups and descriptions follows');
 156         list_newsgroups($self, $wildmat);
 157         '.'
 158 }
 159
 160 sub list_overview_fmt ($) {
 161         my ($self) = @_;
 162         $self->msg_more($OVERVIEW_FMT);
 163 }
 164
 165 sub list_headers ($;$) {
 166         my ($self) = @_;
 167         $self->msg_more($LIST_HEADERS);
 168 }
 169
 170 sub list_active ($;$) {
 171         my ($self, $wildmat) = @_;
 172         wildmat2re($wildmat);
 173         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 174                 $ng->{newsgroup} =~ $wildmat or next;
 175                 group_line($self, $ng);
 176         }
 177 }
 178
 179 sub list_active_times ($;$) {
 180         my ($self, $wildmat) = @_;
 181         wildmat2re($wildmat);
 182         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 183                 $ng->{newsgroup} =~ $wildmat or next;
 184                 my $c = eval { $ng->mm->created_at } || time;
 185                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 186         }
 187 }
 188
 189 sub list_newsgroups ($;$) {
 190         my ($self, $wildmat) = @_;
 191         wildmat2re($wildmat);
 192         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 193                 $ng->{newsgroup} =~ $wildmat or next;
 194                 my $d = $ng->description;
 195                 more($self, "$ng->{newsgroup} $d");
 196         }
 197 }
 198
 199 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 200 sub cmd_list ($;$$) {
 201         my ($self, @args) = @_;
 202         if (scalar @args) {
 203                 my $arg = shift @args;
 204                 $arg =~ tr/A-Z./a-z_/;
 205                 $arg = "list_$arg";
 206
 207                 $arg = eval {
 208                         no strict 'refs';
 209                         *{$arg}{CODE};
 210                 };
 211                 return r501 unless $arg && args_ok($arg, scalar @args);
 212                 more($self, '215 information follows');
 213                 $arg->($self, @args);
 214         } else {
 215                 more($self, '215 list of newsgroups follows');
 216                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 217                         group_line($self, $ng);
 218                 }
 219         }
 220         '.'
 221 }
 222
 223 sub cmd_listgroup ($;$$) {
 224         my ($self, $group, $range) = @_;
 225         if (defined $group) {
 226                 my $res = cmd_group($self, $group);
 227                 return $res if ($res !~ /\A211 /);
 228                 more($self, $res);
 229         }
 230         my $ng = $self->{ng} or return '412 no newsgroup selected';
 231         my $mm = $ng->mm;
 232         if (defined $range) {
 233                 my $r = get_range($self, $range);
 234                 return $r unless ref $r;
 235                 my ($beg, $end) = @$r;
 236                 long_response($self, sub {
 237                         $r = $mm->msg_range(\$beg, $end, 'num');
 238                         scalar(@$r) or return;
 239                         more($self, join("\r\n", map { $_->[0] } @$r));
 240                         1;
 241                 });
 242         } else { # grab every article number
 243                 my $n = 0;
 244                 long_response($self, sub {
 245                         my $ary = $mm->ids_after(\$n);
 246                         scalar(@$ary) or return;
 247                         more($self, join("\r\n", @$ary));
 248                         1;
 249                 });
 250         }
 251 }
 252
 253 sub parse_time ($$;$) {
 254         my ($date, $time, $gmt) = @_;
 255         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 256         if (defined $gmt) {
 257                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 258                 $gmt = 1;
 259         }
 260         my @now = $gmt ? gmtime : localtime;
 261         my ($YYYY, $MM, $DD);
 262         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 263                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 264         } else { # legacy clients send YYMMDD
 265                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 266                 my $cur_year = $now[5] + 1900;
 267                 if ($YYYY > $cur_year) {
 268                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 269                 }
 270         }
 271         if ($gmt) {
 272                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 273         } else {
 274                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 275         }
 276 }
 277
 278 sub group_line ($$) {
 279         my ($self, $ng) = @_;
 280         my ($min, $max) = $ng->mm->minmax;
 281         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 282 }
 283
 284 sub cmd_newgroups ($$$;$$) {
 285         my ($self, $date, $time, $gmt, $dists) = @_;
 286         my $ts = eval { parse_time($date, $time, $gmt) };
 287         return r501 if $@;
 288
 289         # TODO dists
 290         more($self, '231 list of new newsgroups follows');
 291         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 292                 my $c = eval { $ng->mm->created_at } || 0;
 293                 next unless $c > $ts;
 294                 group_line($self, $ng);
 295         }
 296         '.'
 297 }
 298
 299 sub wildmat2re (;$) {
 300         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 301         my %keep;
 302         my $salt = rand;
 303         my $tmp = $_[0];
 304
 305         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 306                 my $orig = $1;
 307                 my $key = sha1_hex($orig . $salt);
 308                 $orig =~ s/([^\w\-])+/\Q$1/g;
 309                 $keep{$key} = $orig;
 310                 $key
 311                 #gex;
 312         my %map = ('*' => '.*', '?' => '.' );
 313         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 314         if (scalar %keep) {
 315                 $tmp =~ s#([a-f0-9]{40})#
 316                         my $orig = $keep{$1};
 317                         defined $orig ? $orig : $1;
 318                         #ge;
 319         }
 320         $_[0] = qr/\A$tmp\z/;
 321 }
 322
 323 sub ngpat2re (;$) {
 324         return $_[0] = qr/\A\z/ unless defined $_[0];
 325         my %map = ('*' => '.*', ',' => '|');
 326         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 327         $_[0] = qr/\A(?:$_[0])\z/;
 328 }
 329
 330 sub cmd_newnews ($$$$;$$) {
 331         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 332         my $ts = eval { parse_time($date, $time, $gmt) };
 333         return r501 if $@;
 334         more($self, '230 list of new articles by message-id follows');
 335         my ($keep, $skip) = split('!', $newsgroups, 2);
 336         ngpat2re($keep);
 337         ngpat2re($skip);
 338         my @over;
 339         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 340                 $ng->{newsgroup} =~ $keep or next;
 341                 $ng->{newsgroup} =~ $skip and next;
 342                 my $over = $ng->over or next;
 343                 push @over, $over;
 344         };
 345         return '.' unless @over;
 346
 347         my $prev = 0;
 348         long_response($self, sub {
 349                 my $over = $over[0];
 350                 my $msgs = $over->query_ts($ts, $prev);
 351                 if (scalar @$msgs) {
 352                         more($self, '<' .
 353                                 join(">\r\n<", map { $_->mid } @$msgs ).
 354                                 '>');
 355                         $prev = $msgs->[-1]->{num};
 356                 } else {
 357                         shift @over;
 358                         if (@over) { # continue onto next newsgroup
 359                                 $prev = 0;
 360                                 return 1;
 361                         } else { # break out of the long response.
 362                                 return;
 363                         }
 364                 }
 365         });
 366 }
 367
 368 sub cmd_group ($$) {
 369         my ($self, $group) = @_;
 370         my $no_such = '411 no such news group';
 371         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 372
 373         $self->{ng} = $ng;
 374         my ($min, $max) = $ng->mm->minmax;
 375         $min ||= 0;
 376         $max ||= 0;
 377         $self->{article} = $min;
 378         my $est_size = $max - $min;
 379         "211 $est_size $min $max $group";
 380 }
 381
 382 sub article_adj ($$) {
 383         my ($self, $off) = @_;
 384         my $ng = $self->{ng} or return '412 no newsgroup selected';
 385
 386         my $n = $self->{article};
 387         defined $n or return '420 no current article has been selected';
 388
 389         $n += $off;
 390         my $mid = $ng->mm->mid_for($n);
 391         unless ($mid) {
 392                 $n = $off > 0 ? 'next' : 'previous';
 393                 return "421 no $n article in this group";
 394         }
 395         $self->{article} = $n;
 396         "223 $n <$mid> article retrieved - request text separately";
 397 }
 398
 399 sub cmd_next ($) { article_adj($_[0], 1) }
 400 sub cmd_last ($) { article_adj($_[0], -1) }
 401
 402 # We want to encourage using email and CC-ing everybody involved to avoid
 403 # the single-point-of-failure a single server provides.
 404 sub cmd_post ($) {
 405         my ($self) = @_;
 406         my $ng = $self->{ng};
 407         $ng ? "440 mailto:$ng->{-primary_address} to post"
 408                 : '440 posting not allowed'
 409 }
 410
 411 sub cmd_quit ($) {
 412         my ($self) = @_;
 413         res($self, '205 closing connection - goodbye!');
 414         $self->shutdn;
 415         undef;
 416 }
 417
 418 sub header_append ($$$) {
 419         my ($hdr, $k, $v) = @_;
 420         my @v = $hdr->header($k);
 421         foreach (@v) {
 422                 return if $v eq $_;
 423         }
 424         $hdr->header_set($k, @v, $v);
 425 }
 426
 427 sub xref ($$$$) {
 428         my ($self, $ng, $n, $mid) = @_;
 429         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 430
 431         # num_for is pretty cheap and sometimes we'll lookup the existence
 432         # of an article without getting even the OVER info.  In other words,
 433         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 434         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 435         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 436                 next if $ng eq $other;
 437                 my $num = eval { $other->mm->num_for($mid) } or next;
 438                 $ret .= " $other->{newsgroup}:$num";
 439         }
 440         $ret;
 441 }
 442
 443 sub set_nntp_headers ($$$$$) {
 444         my ($self, $hdr, $ng, $n, $mid) = @_;
 445
 446         # why? leafnode requires a Path: header for some inexplicable
 447         # reason.  We'll fake the shortest one possible.
 448         $hdr->header_set('Path', 'y');
 449
 450         # leafnode (and maybe other NNTP clients) have trouble dealing
 451         # with v2 messages which have multiple Message-IDs (either due
 452         # to our own content-based dedupe or buggy git-send-email versions).
 453         my @mids = $hdr->header('Message-ID');
 454         if (scalar(@mids) > 1) {
 455                 my $mid0 = "<$mid>";
 456                 $hdr->header_set('Message-ID', $mid0);
 457                 my @alt = $hdr->header('X-Alt-Message-ID');
 458                 my %seen = map { $_ => 1 } (@alt, $mid0);
 459                 foreach my $m (@mids) {
 460                         next if $seen{$m}++;
 461                         push @alt, $m;
 462                 }
 463                 $hdr->header_set('X-Alt-Message-ID', @alt);
 464         }
 465
 466         # clobber some
 467         my $xref = xref($self, $ng, $n, $mid);
 468         $hdr->header_set('Xref', $xref);
 469         $xref =~ s/:[0-9]+//g;
 470         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 471         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 472         if (my $url = $ng->base_url) {
 473                 $mid = mid_escape($mid);
 474                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 475                 header_append($hdr, 'List-Archive', "<$url>");
 476         }
 477 }
 478
 479 sub art_lookup ($$$) {
 480         my ($self, $art, $set_headers) = @_;
 481         my $ng = $self->{ng};
 482         my ($n, $mid);
 483         my $err;
 484         if (defined $art) {
 485                 if ($art =~ /\A[0-9]+\z/) {
 486                         $err = '423 no such article number in this group';
 487                         $n = int($art);
 488                         goto find_mid;
 489                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 490                         $mid = $1;
 491                         $err = r430;
 492                         $n = $ng->mm->num_for($mid) if $ng;
 493                         goto found if defined $n;
 494                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 495                                 $n = $g->mm->num_for($mid);
 496                                 if (defined $n) {
 497                                         $ng = $g;
 498                                         goto found;
 499                                 }
 500                         }
 501                         return $err;
 502                 } else {
 503                         return r501;
 504                 }
 505         } else {
 506                 $err = '420 no current article has been selected';
 507                 $n = $self->{article};
 508                 defined $n or return $err;
 509 find_mid:
 510                 $ng or return '412 no newsgroup has been selected';
 511                 $mid = $ng->mm->mid_for($n);
 512                 defined $mid or return $err;
 513         }
 514 found:
 515         my $smsg = $ng->over->get_art($n) or return $err;
 516         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 517
 518         # Email::Simple->new will modify $msg in-place as documented
 519         # in its manpage, so what's left is the body and we won't need
 520         # to call Email::Simple::body(), later
 521         my $hdr = Email::Simple->new($msg)->header_obj;
 522         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 523         [ $n, $mid, $msg, $hdr ];
 524 }
 525
 526 sub msg_body_write ($$) {
 527         my ($self, $msg) = @_;
 528
 529         # these can momentarily double the memory consumption :<
 530         $$msg =~ s/^\./../smg;
 531         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 532         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 533         $self->msg_more($$msg);
 534         '.'
 535 }
 536
 537 sub set_art {
 538         my ($self, $art) = @_;
 539         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 540 }
 541
 542 sub msg_hdr_write ($$$) {
 543         my ($self, $hdr, $body_follows) = @_;
 544         $hdr = $hdr->as_string;
 545         utf8::encode($hdr);
 546         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 547
 548         # for leafnode compatibility, we need to ensure Message-ID headers
 549         # are only a single line.  We can't subclass Email::Simple::Header
 550         # and override _default_fold_at in here, either; since that won't
 551         # affect messages already in the archive.
 552         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 553         $hdr .= "\r\n" if $body_follows;
 554         $self->msg_more($hdr);
 555 }
 556
 557 sub cmd_article ($;$) {
 558         my ($self, $art) = @_;
 559         my $r = art_lookup($self, $art, 1);
 560         return $r unless ref $r;
 561         my ($n, $mid, $msg, $hdr) = @$r;
 562         set_art($self, $art);
 563         more($self, "220 $n <$mid> article retrieved - head and body follow");
 564         msg_hdr_write($self, $hdr, 1);
 565         msg_body_write($self, $msg);
 566 }
 567
 568 sub cmd_head ($;$) {
 569         my ($self, $art) = @_;
 570         my $r = art_lookup($self, $art, 2);
 571         return $r unless ref $r;
 572         my ($n, $mid, undef, $hdr) = @$r;
 573         set_art($self, $art);
 574         more($self, "221 $n <$mid> article retrieved - head follows");
 575         msg_hdr_write($self, $hdr, 0);
 576         '.'
 577 }
 578
 579 sub cmd_body ($;$) {
 580         my ($self, $art) = @_;
 581         my $r = art_lookup($self, $art, 0);
 582         return $r unless ref $r;
 583         my ($n, $mid, $msg) = @$r;
 584         set_art($self, $art);
 585         more($self, "222 $n <$mid> article retrieved - body follows");
 586         msg_body_write($self, $msg);
 587 }
 588
 589 sub cmd_stat ($;$) {
 590         my ($self, $art) = @_;
 591         my $r = art_lookup($self, $art, 0);
 592         return $r unless ref $r;
 593         my ($n, $mid) = @$r;
 594         set_art($self, $art);
 595         "223 $n <$mid> article retrieved - request text separately";
 596 }
 597
 598 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 599
 600 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 601
 602 sub cmd_help ($) {
 603         my ($self) = @_;
 604         more($self, '100 help text follows');
 605         '.'
 606 }
 607
 608 sub get_range ($$) {
 609         my ($self, $range) = @_;
 610         my $ng = $self->{ng} or return '412 no news group has been selected';
 611         defined $range or return '420 No article(s) selected';
 612         my ($beg, $end);
 613         my ($min, $max) = $ng->mm->minmax;
 614         if ($range =~ /\A([0-9]+)\z/) {
 615                 $beg = $end = $1;
 616         } elsif ($range =~ /\A([0-9]+)-\z/) {
 617                 ($beg, $end) = ($1, $max);
 618         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 619                 ($beg, $end) = ($1, $2);
 620         } else {
 621                 return r501;
 622         }
 623         $beg = $min if ($beg < $min);
 624         $end = $max if ($end > $max);
 625         return '420 No article(s) selected' if ($beg > $end);
 626         [ $beg, $end ];
 627 }
 628
 629 sub long_response ($$) {
 630         my ($self, $cb) = @_; # cb returns true if more, false if done
 631
 632         my $fd = fileno($self->{sock});
 633         defined $fd or return;
 634         # make sure we disable reading during a long response,
 635         # clients should not be sending us stuff and making us do more
 636         # work while we are stream a response to them
 637         my $t0 = now();
 638         my $long_cb; # DANGER: self-referential
 639         $long_cb = sub {
 640                 # wbuf is unset or empty, here; $cb may add to it
 641                 my $more = eval { $cb->() };
 642                 if ($@ || !$self->{sock}) { # something bad happened...
 643                         $long_cb = undef;
 644                         my $diff = now() - $t0;
 645                         if ($@) {
 646                                 err($self,
 647                                     "%s during long response[$fd] - %0.6f",
 648                                     $@, $diff);
 649                         }
 650                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 651                         $self->close;
 652                 } elsif ($more) { # $self->{wbuf}:
 653                         update_idle_time($self);
 654
 655                         # COMPRESS users all share the same DEFLATE context.
 656                         # Flush it here to ensure clients don't see
 657                         # each other's data
 658                         $self->zflush;
 659
 660                         # no recursion, schedule another call ASAP
 661                         # but only after all pending writes are done
 662                         my $wbuf = $self->{wbuf} ||= [];
 663                         push @$wbuf, $long_cb;
 664
 665                         # wbuf may be populated by $cb, no need to rearm if so:
 666                         $self->requeue if scalar(@$wbuf) == 1;
 667                 } else { # all done!
 668                         $long_cb = undef;
 669                         res($self, '.');
 670                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 671                         my $wbuf = $self->{wbuf};
 672                         $self->requeue unless $wbuf && @$wbuf;
 673                 }
 674         };
 675         $self->write($long_cb); # kick off!
 676         undef;
 677 }
 678
 679 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 680         my ($self, $xhdr, $range) = @_;
 681
 682         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 683                 my ($ng, $n) = mid_lookup($self, $1);
 684                 return r430 unless $n;
 685                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 686         } else { # numeric range
 687                 $range = $self->{article} unless defined $range;
 688                 my $r = get_range($self, $range);
 689                 return $r unless ref $r;
 690                 my $mm = $self->{ng}->mm;
 691                 my ($beg, $end) = @$r;
 692                 more($self, $xhdr ? r221 : r225);
 693                 long_response($self, sub {
 694                         my $r = $mm->msg_range(\$beg, $end);
 695                         @$r or return;
 696                         more($self, join("\r\n", map {
 697                                 "$_->[0] <$_->[1]>"
 698                         } @$r));
 699                         1;
 700                 });
 701         }
 702 }
 703
 704 sub mid_lookup ($$) {
 705         my ($self, $mid) = @_;
 706         my $self_ng = $self->{ng};
 707         if ($self_ng) {
 708                 my $n = $self_ng->mm->num_for($mid);
 709                 return ($self_ng, $n) if defined $n;
 710         }
 711         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 712                 next if defined $self_ng && $ng eq $self_ng;
 713                 my $n = $ng->mm->num_for($mid);
 714                 return ($ng, $n) if defined $n;
 715         }
 716         (undef, undef);
 717 }
 718
 719 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 720         my ($self, $xhdr, $range) = @_;
 721
 722         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 723                 my $mid = $1;
 724                 my ($ng, $n) = mid_lookup($self, $mid);
 725                 return r430 unless $n;
 726                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 727                                 xref($self, $ng, $n, $mid));
 728         } else { # numeric range
 729                 $range = $self->{article} unless defined $range;
 730                 my $r = get_range($self, $range);
 731                 return $r unless ref $r;
 732                 my $ng = $self->{ng};
 733                 my $mm = $ng->mm;
 734                 my ($beg, $end) = @$r;
 735                 more($self, $xhdr ? r221 : r225);
 736                 long_response($self, sub {
 737                         my $r = $mm->msg_range(\$beg, $end);
 738                         @$r or return;
 739                         more($self, join("\r\n", map {
 740                                 my $num = $_->[0];
 741                                 "$num ".xref($self, $ng, $num, $_->[1]);
 742                         } @$r));
 743                         1;
 744                 });
 745         }
 746 }
 747
 748 sub over_header_for {
 749         my ($over, $num, $field) = @_;
 750         my $smsg = $over->get_art($num) or return;
 751         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 752         $smsg->{$field};
 753 }
 754
 755 sub hdr_searchmsg ($$$$) {
 756         my ($self, $xhdr, $field, $range) = @_;
 757         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 758                 my ($ng, $n) = mid_lookup($self, $1);
 759                 return r430 unless defined $n;
 760                 my $v = over_header_for($ng->over, $n, $field);
 761                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 762         } else { # numeric range
 763                 $range = $self->{article} unless defined $range;
 764                 my $over = $self->{ng}->over;
 765                 my $mm = $self->{ng}->mm;
 766                 my $r = get_range($self, $range);
 767                 return $r unless ref $r;
 768                 my ($beg, $end) = @$r;
 769                 more($self, $xhdr ? r221 : r225);
 770                 my $cur = $beg;
 771                 long_response($self, sub {
 772                         my $msgs = $over->query_xover($cur, $end);
 773                         my $nr = scalar @$msgs or return;
 774                         my $tmp = '';
 775                         foreach my $s (@$msgs) {
 776                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 777                         }
 778                         utf8::encode($tmp);
 779                         $self->msg_more($tmp);
 780                         $cur = $msgs->[-1]->{num} + 1;
 781                 });
 782         }
 783 }
 784
 785 sub do_hdr ($$$;$) {
 786         my ($self, $xhdr, $header, $range) = @_;
 787         my $sub = lc $header;
 788         if ($sub eq 'message-id') {
 789                 hdr_message_id($self, $xhdr, $range);
 790         } elsif ($sub eq 'xref') {
 791                 hdr_xref($self, $xhdr, $range);
 792         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 793                                 bytes|lines)\z/x) {
 794                 hdr_searchmsg($self, $xhdr, $sub, $range);
 795         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 796                 hdr_searchmsg($self, $xhdr, $1, $range);
 797         } else {
 798                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 799         }
 800 }
 801
 802 # RFC 3977
 803 sub cmd_hdr ($$;$) {
 804         my ($self, $header, $range) = @_;
 805         do_hdr($self, 0, $header, $range);
 806 }
 807
 808 # RFC 2980
 809 sub cmd_xhdr ($$;$) {
 810         my ($self, $header, $range) = @_;
 811         do_hdr($self, 1, $header, $range);
 812 }
 813
 814 sub hdr_mid_prefix ($$$$$) {
 815         my ($self, $xhdr, $ng, $n, $mid) = @_;
 816         return $mid if $xhdr;
 817
 818         # HDR for RFC 3977 users
 819         if (my $self_ng = $self->{ng}) {
 820                 ($self_ng eq $ng) ? $n : '0';
 821         } else {
 822                 '0';
 823         }
 824 }
 825
 826 sub hdr_mid_response ($$$$$$) {
 827         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 828         my $res = '';
 829         if ($xhdr) {
 830                 $res .= r221 . "\r\n";
 831                 $res .= "$mid $v\r\n";
 832         } else {
 833                 $res .= r225 . "\r\n";
 834                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 835                 $res .= "$pfx $v\r\n";
 836         }
 837         res($self, $res .= '.');
 838         undef;
 839 }
 840
 841 sub cmd_xrover ($;$) {
 842         my ($self, $range) = @_;
 843         my $ng = $self->{ng} or return '412 no newsgroup selected';
 844         (defined $range && $range =~ /[<>]/) and
 845                 return '420 No article(s) selected'; # no message IDs
 846
 847         $range = $self->{article} unless defined $range;
 848         my $r = get_range($self, $range);
 849         return $r unless ref $r;
 850         my ($beg, $end) = @$r;
 851         my $mm = $ng->mm;
 852         my $over = $ng->over;
 853         more($self, '224 Overview information follows');
 854
 855         long_response($self, sub {
 856                 my $h = over_header_for($over, $beg, 'references');
 857                 more($self, "$beg $h") if defined($h);
 858                 $beg++ < $end;
 859         });
 860 }
 861
 862 sub over_line ($$$$) {
 863         my ($self, $ng, $num, $smsg) = @_;
 864         # n.b. field access and procedural calls can be
 865         # 10%-15% faster than OO method calls:
 866         my $s = join("\t", $num,
 867                 $smsg->{subject},
 868                 $smsg->{from},
 869                 PublicInbox::SearchMsg::date($smsg),
 870                 "<$smsg->{mid}>",
 871                 $smsg->{references},
 872                 $smsg->{bytes},
 873                 $smsg->{lines},
 874                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 875         utf8::encode($s);
 876         $s
 877 }
 878
 879 sub cmd_over ($;$) {
 880         my ($self, $range) = @_;
 881         if ($range && $range =~ /\A<(.+)>\z/) {
 882                 my ($ng, $n) = mid_lookup($self, $1);
 883                 defined $n or return r430;
 884                 my $smsg = $ng->over->get_art($n) or return r430;
 885                 more($self, '224 Overview information follows (multi-line)');
 886
 887                 # Only set article number column if it's the current group
 888                 my $self_ng = $self->{ng};
 889                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 890                 more($self, over_line($self, $ng, $n, $smsg));
 891                 '.';
 892         } else {
 893                 cmd_xover($self, $range);
 894         }
 895 }
 896
 897 sub cmd_xover ($;$) {
 898         my ($self, $range) = @_;
 899         $range = $self->{article} unless defined $range;
 900         my $r = get_range($self, $range);
 901         return $r unless ref $r;
 902         my ($beg, $end) = @$r;
 903         more($self, "224 Overview information follows for $beg to $end");
 904         my $over = $self->{ng}->over;
 905         my $cur = $beg;
 906         long_response($self, sub {
 907                 my $msgs = $over->query_xover($cur, $end);
 908                 my $nr = scalar @$msgs or return;
 909
 910                 # OVERVIEW.FMT
 911                 more($self, join("\r\n", map {
 912                         over_line($self, $self->{ng}, $_->{num}, $_);
 913                         } @$msgs));
 914                 $cur = $msgs->[-1]->{num} + 1;
 915         });
 916 }
 917
 918 sub compressed { undef }
 919
 920 sub cmd_starttls ($) {
 921         my ($self) = @_;
 922         my $sock = $self->{sock} or return;
 923         # RFC 4642 2.2.1
 924         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 925         my $opt = $self->{nntpd}->{accept_tls} or
 926                 return '580 can not initiate TLS negotiation';
 927         res($self, '382 Continue with TLS negotiation');
 928         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 929         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 930         undef;
 931 }
 932
 933 # RFC 8054
 934 sub cmd_compress ($$) {
 935         my ($self, $alg) = @_;
 936         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 937         return r502 if $self->compressed || !$have_deflate;
 938         PublicInbox::NNTPdeflate->enable($self);
 939         $self->requeue;
 940         undef
 941 }
 942
 943 sub zflush {} # overridden by NNTPdeflate
 944
 945 sub cmd_xpath ($$) {
 946         my ($self, $mid) = @_;
 947         return r501 unless $mid =~ /\A<(.+)>\z/;
 948         $mid = $1;
 949         my @paths;
 950         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 951                 my $n = $ng->mm->num_for($mid);
 952                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 953         }
 954         return '430 no such article on server' unless @paths;
 955         '223 '.join(' ', @paths);
 956 }
 957
 958 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 959
 960 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 961
 962 sub do_write ($$) {
 963         my $self = $_[0];
 964         my $done = $self->write(\($_[1]));
 965         return 0 unless $self->{sock};
 966
 967         $done;
 968 }
 969
 970 sub err ($$;@) {
 971         my ($self, $fmt, @args) = @_;
 972         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 973 }
 974
 975 sub out ($$;@) {
 976         my ($self, $fmt, @args) = @_;
 977         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 978 }
 979
 980 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 981 sub event_step {
 982         my ($self) = @_;
 983
 984         return unless $self->flush_write && $self->{sock};
 985
 986         update_idle_time($self);
 987         # only read more requests if we've drained the write buffer,
 988         # otherwise we can be buffering infinitely w/o backpressure
 989
 990         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 991         my $r = 1;
 992
 993         if (index($$rbuf, "\n") < 0) {
 994                 my $off = bytes::length($$rbuf);
 995                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 996         }
 997         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 998                 my $line = $1;
 999                 return $self->close if $line =~ /[[:cntrl:]]/s;
1000                 my $t0 = now();
1001                 my $fd = fileno($self->{sock});
1002                 $r = eval { process_line($self, $line) };
1003                 my $pending = $self->{wbuf} ? ' pending' : '';
1004                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1005         }
1006
1007         return $self->close if $r < 0;
1008         my $len = bytes::length($$rbuf);
1009         return $self->close if ($len >= LINE_MAX);
1010         $self->rbuf_idle($rbuf);
1011         update_idle_time($self);
1012
1013         # maybe there's more pipelined data, or we'll have
1014         # to register it for socket-readiness notifications
1015         $self->requeue unless $self->{wbuf};
1016 }
1017
1018 sub not_idle_long ($$) {
1019         my ($self, $now) = @_;
1020         my $sock = $self->{sock} or return;
1021         my $ary = $EXPMAP->{fileno($sock)} or return;
1022         my $exp_at = $ary->[0] + $EXPTIME;
1023         $exp_at > $now;
1024 }
1025
1026 # for graceful shutdown in PublicInbox::Daemon:
1027 sub busy {
1028         my ($self, $now) = @_;
1029         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
1030 }
1031
1032 # this is an import to prevent "perl -c" from complaining about fields
1033 sub import {
1034         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
1035                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
1036 }
1037
1038 1;