lib/PublicInbox/NNTP.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ibx: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(PublicInbox::DS);
  14 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  15 use PublicInbox::Eml;
  16 use POSIX qw(strftime);
  17 use PublicInbox::DS qw(now);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use PublicInbox::GitAsyncCat;
  21 use PublicInbox::Address;
  22
  23 use constant {
  24         LINE_MAX => 512, # RFC 977 section 2.3
  25         r501 => '501 command syntax error',
  26         r502 => '502 Command unavailable',
  27         r221 => "221 Header follows\r\n",
  28         r224 => '224 Overview information follows (multi-line)',
  29         r225 => "225 Headers follow (multi-line)\r\n",
  30         r430 => '430 No article with that message-id',
  31 };
  32 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  33 use Errno qw(EAGAIN);
  34 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  35 my @OVERVIEW = qw(Subject From Date Message-ID References);
  36 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  37                 "Xref:full\r\n.";
  38 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  39                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  40 my $CAPABILITIES = <<"";
  41 101 Capability list:\r
  42 VERSION 2\r
  43 READER\r
  44 NEWNEWS\r
  45 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  46 HDR\r
  47 OVER\r
  48 COMPRESS DEFLATE\r
  49
  50 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  51
  52 sub new ($$$) {
  53         my ($class, $sock, $nntpd) = @_;
  54         my $self = bless { nntpd => $nntpd }, $class;
  55         my $ev = EPOLLIN;
  56         my $wbuf;
  57         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  58                 return CORE::close($sock) if $! != EAGAIN;
  59                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  60                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  61         }
  62         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  63         if ($wbuf) {
  64                 $self->{wbuf} = $wbuf;
  65         } else {
  66                 greet($self);
  67         }
  68         $self;
  69 }
  70
  71 sub args_ok ($$) {
  72         my ($cb, $argc) = @_;
  73         my $tot = prototype $cb;
  74         my ($nreq, undef) = split(/;/, $tot);
  75         $nreq = ($nreq =~ tr/$//) - 1;
  76         $tot = ($tot =~ tr/$//) - 1;
  77         ($argc <= $tot && $argc >= $nreq);
  78 }
  79
  80 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  81 sub process_line ($$) {
  82         my ($self, $l) = @_;
  83         my ($req, @args) = split(/[ \t]+/, $l);
  84         return 1 unless defined($req); # skip blank line
  85         $req = $self->can('cmd_'.lc($req)) //
  86                 return $self->write(\"500 command not recognized\r\n");
  87         return res($self, r501) unless args_ok($req, scalar @args);
  88
  89         my $res = eval { $req->($self, @args) };
  90         my $err = $@;
  91         if ($err && $self->{sock}) {
  92                 local $/ = "\n";
  93                 chomp($l);
  94                 err($self, 'error from: %s (%s)', $l, $err);
  95                 $res = '503 program fault - command not performed';
  96         }
  97         defined($res) ? res($self, $res) : 0;
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (!$self->{sock}->can('accept_SSL') &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 114 }
 115
 116 sub cmd_slave ($) { '202 slave status noted' }
 117
 118 sub cmd_xgtitle ($;$) {
 119         my ($self, $wildmat) = @_;
 120         more($self, '282 list of groups and descriptions follows');
 121         list_newsgroups($self, $wildmat);
 122 }
 123
 124 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 125
 126 sub list_headers ($;$) { $LIST_HEADERS }
 127
 128 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 129         my ($self, $groupnames) = @_;
 130         my @window = splice(@$groupnames, 0, 100) or return 0;
 131         my $ibx;
 132         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 135         }
 136         scalar(@$groupnames); # continue if there's more
 137 }
 138
 139 sub list_active ($;$) { # called by cmd_list
 140         my ($self, $wildmat) = @_;
 141         wildmat2re($wildmat);
 142         long_response($self, \&list_active_i, [
 143                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 144 }
 145
 146 sub list_active_times_i {
 147         my ($self, $groupnames) = @_;
 148         my @window = splice(@$groupnames, 0, 100) or return 0;
 149         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 150         for my $ngname (@window) {
 151                 my $ibx = $groups->{$ngname} or next;
 152                 my $c = eval { $ibx->uidvalidity } // time;
 153                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 154         }
 155         scalar(@$groupnames); # continue if there's more
 156 }
 157
 158 sub list_active_times ($;$) { # called by cmd_list
 159         my ($self, $wildmat) = @_;
 160         wildmat2re($wildmat);
 161         long_response($self, \&list_active_times_i, [
 162                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 163 }
 164
 165 sub list_newsgroups_i {
 166         my ($self, $groupnames) = @_;
 167         my @window = splice(@$groupnames, 0, 100) or return 0;
 168         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 169         my $ibx;
 170         for my $ngname (@window) {
 171                 $ibx = $groups->{$ngname} and
 172                         more($self, "$ngname ".$ibx->description);
 173         }
 174         scalar(@$groupnames); # continue if there's more
 175 }
 176
 177 sub list_newsgroups ($;$) { # called by cmd_list
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         long_response($self, \&list_newsgroups_i, [
 181                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 182 }
 183
 184 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 185 sub cmd_list ($;$$) {
 186         my ($self, @args) = @_;
 187         if (scalar @args) {
 188                 my $arg = shift @args;
 189                 $arg =~ tr/A-Z./a-z_/;
 190                 my $ret = $arg eq 'active';
 191                 $arg = "list_$arg";
 192                 $arg = $self->can($arg);
 193                 return r501 unless $arg && args_ok($arg, scalar @args);
 194                 more($self, '215 information follows');
 195                 $arg->($self, @args);
 196         } else {
 197                 more($self, '215 list of newsgroups follows');
 198                 long_response($self, \&list_active_i, [ # copy array
 199                         @{$self->{nntpd}->{groupnames}} ]);
 200         }
 201 }
 202
 203 sub listgroup_range_i {
 204         my ($self, $beg, $end) = @_;
 205         my $r = $self->{ibx}->mm(1)->msg_range($beg, $end, 'num');
 206         scalar(@$r) or return;
 207         $self->msg_more(join('', map { "$_->[0]\r\n" } @$r));
 208         1;
 209 }
 210
 211 sub listgroup_all_i {
 212         my ($self, $num) = @_;
 213         my $ary = $self->{ibx}->over(1)->ids_after($num);
 214         scalar(@$ary) or return;
 215         more($self, join("\r\n", @$ary));
 216         1;
 217 }
 218
 219 sub cmd_listgroup ($;$$) {
 220         my ($self, $group, $range) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226         $self->{ibx} or return '412 no newsgroup selected';
 227         if (defined $range) {
 228                 my $r = get_range($self, $range);
 229                 return $r unless ref $r;
 230                 long_response($self, \&listgroup_range_i, @$r);
 231         } else { # grab every article number
 232                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 233         }
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my ($YYYY, $MM, $DD);
 244         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 my $YY;
 248                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my @now = $gmt ? gmtime : localtime;
 250                 my $cur_year = $now[5] + 1900;
 251                 my $cur_cent = int($cur_year / 100) * 100;
 252                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 253                         ($YY + 1900) : ($YY + $cur_cent);
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ibx) = @_;
 264         my ($min, $max) = $ibx->mm(1)->minmax;
 265         more($self, "$ibx->{newsgroup} $max $min n");
 266 }
 267
 268 sub newgroups_i {
 269         my ($self, $ts, $i, $groupnames) = @_;
 270         my $end = $$i + 100;
 271         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 272         while ($$i < $end) {
 273                 my $ngname = $groupnames->[$$i++] // return;
 274                 my $ibx = $groups->{$ngname} or next; # expired on reload
 275                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 276                 group_line($self, $ibx);
 277         }
 278         1;
 279 }
 280
 281 sub cmd_newgroups ($$$;$$) {
 282         my ($self, $date, $time, $gmt, $dists) = @_;
 283         my $ts = eval { parse_time($date, $time, $gmt) };
 284         return r501 if $@;
 285
 286         # TODO dists
 287         more($self, '231 list of new newsgroups follows');
 288         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 289                                 $self->{nntpd}->{groupnames});
 290 }
 291
 292 sub wildmat2re (;$) {
 293         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 294         my %keep;
 295         my $salt = rand;
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub newnews_i {
 324         my ($self, $names, $ts, $prev) = @_;
 325         my $ngname = $names->[0];
 326         if (my $ibx = $self->{nntpd}->{pi_cfg}->{-by_newsgroup}->{$ngname}) {
 327                 if (my $over = $ibx->over) {
 328                         my $msgs = $over->query_ts($ts, $$prev);
 329                         if (scalar @$msgs) {
 330                                 $self->msg_more(join('', map {
 331                                                         "<$_->{mid}>\r\n";
 332                                                 } @$msgs));
 333                                 $$prev = $msgs->[-1]->{num};
 334                                 return 1; # continue on current group
 335                         }
 336                 }
 337         }
 338         shift @$names;
 339         if (@$names) { # continue onto next newsgroup
 340                 $$prev = 0;
 341                 1;
 342         } else { # all done, break out of the long_response
 343                 undef;
 344         }
 345 }
 346
 347 sub cmd_newnews ($$$$;$$) {
 348         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 349         my $ts = eval { parse_time($date, $time, $gmt) };
 350         return r501 if $@;
 351         more($self, '230 list of new articles by message-id follows');
 352         my ($keep, $skip) = split(/!/, $newsgroups, 2);
 353         ngpat2re($keep);
 354         ngpat2re($skip);
 355         my @names = grep(!/$skip/, grep(/$keep/,
 356                                 @{$self->{nntpd}->{groupnames}}));
 357         return '.' unless scalar(@names);
 358         my $prev = 0;
 359         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 360 }
 361
 362 sub cmd_group ($$) {
 363         my ($self, $group) = @_;
 364         my $nntpd = $self->{nntpd};
 365         my $ibx = $nntpd->{pi_cfg}->{-by_newsgroup}->{$group} or
 366                 return '411 no such news group';
 367         $nntpd->idler_start;
 368
 369         $self->{ibx} = $ibx;
 370         my ($min, $max) = $ibx->mm(1)->minmax;
 371         $self->{article} = $min;
 372         my $est_size = $max - $min;
 373         "211 $est_size $min $max $group";
 374 }
 375
 376 sub article_adj ($$) {
 377         my ($self, $off) = @_;
 378         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 379
 380         my $n = $self->{article};
 381         defined $n or return '420 no current article has been selected';
 382
 383         $n += $off;
 384         my $mid = $ibx->mm(1)->mid_for($n) // do {
 385                 $n = $off > 0 ? 'next' : 'previous';
 386                 return "421 no $n article in this group";
 387         };
 388         $self->{article} = $n;
 389         "223 $n <$mid> article retrieved - request text separately";
 390 }
 391
 392 sub cmd_next ($) { article_adj($_[0], 1) }
 393 sub cmd_last ($) { article_adj($_[0], -1) }
 394
 395 # We want to encourage using email and CC-ing everybody involved to avoid
 396 # the single-point-of-failure a single server provides.
 397 sub cmd_post ($) {
 398         my ($self) = @_;
 399         my $ibx = $self->{ibx};
 400         $ibx ? "440 mailto:$ibx->{-primary_address} to post"
 401                 : '440 posting not allowed'
 402 }
 403
 404 sub cmd_quit ($) {
 405         my ($self) = @_;
 406         $self->write(\"205 closing connection - goodbye!\r\n");
 407         $self->shutdn;
 408         undef;
 409 }
 410
 411 sub xref_by_tc ($$$) {
 412         my ($xref, $pi_cfg, $smsg) = @_;
 413         my $by_addr = $pi_cfg->{-by_addr};
 414         my $mid = $smsg->{mid};
 415         for my $f (qw(to cc)) {
 416                 my @ibxs = map {
 417                         $by_addr->{lc($_)} // ()
 418                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 419                 for my $ibx (@ibxs) {
 420                         $xref->{$ibx->{newsgroup}} //=
 421                                                 $ibx->mm(1)->num_for($mid);
 422                 }
 423         }
 424 }
 425
 426 sub xref ($$$) {
 427         my ($self, $cur_ibx, $smsg) = @_;
 428         my $nntpd = $self->{nntpd};
 429         my $cur_ng = $cur_ibx->{newsgroup};
 430         my $xref;
 431         if (my $ALL = $nntpd->{pi_cfg}->ALL) {
 432                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 433                 xref_by_tc($xref, $nntpd->{pi_cfg}, $smsg);
 434         } else { # slow path
 435                 $xref = { $cur_ng => $smsg->{num} };
 436                 my $mid = $smsg->{mid};
 437                 for my $ibx (values %{$nntpd->{pi_cfg}->{-by_newsgroup}}) {
 438                         $xref->{$ibx->{newsgroup}} //=
 439                                                  $ibx->mm(1)->num_for($mid);
 440                 }
 441         }
 442         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 443         for my $ng (sort keys %$xref) {
 444                 my $num = $xref->{$ng} // next;
 445                 $ret .= " $ng:$num";
 446         }
 447         $ret;
 448 }
 449
 450 sub set_nntp_headers ($$) {
 451         my ($hdr, $smsg) = @_;
 452         my ($mid) = $smsg->{mid};
 453
 454         # leafnode (and maybe other NNTP clients) have trouble dealing
 455         # with v2 messages which have multiple Message-IDs (either due
 456         # to our own content-based dedupe or buggy git-send-email versions).
 457         my @mids = $hdr->header_raw('Message-ID');
 458         if (scalar(@mids) > 1) {
 459                 my $mid0 = "<$mid>";
 460                 $hdr->header_set('Message-ID', $mid0);
 461                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 462                 my %seen = map { $_ => 1 } (@alt, $mid0);
 463                 push(@alt, grep { !$seen{$_}++ } @mids);
 464                 $hdr->header_set('X-Alt-Message-ID', @alt);
 465         }
 466
 467         # clobber some existing headers
 468         my $ibx = $smsg->{-ibx};
 469         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 470         $hdr->header_set('Xref', $xref);
 471
 472         # RFC 5536 3.1.4
 473         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 474         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 475         $newsgroups =~ tr/ /,/;
 476         $hdr->header_set('Newsgroups', $newsgroups);
 477
 478         # *something* here is required for leafnode, try to follow
 479         # RFC 5536 3.1.5...
 480         $hdr->header_set('Path', $server_name . '!not-for-mail');
 481 }
 482
 483 sub art_lookup ($$$) {
 484         my ($self, $art, $code) = @_;
 485         my ($ibx, $n);
 486         my $err;
 487         if (defined $art) {
 488                 if ($art =~ /\A[0-9]+\z/) {
 489                         $err = '423 no such article number in this group';
 490                         $n = int($art);
 491                         goto find_ibx;
 492                 } elsif ($art =~ $ONE_MSGID) {
 493                         ($ibx, $n) = mid_lookup($self, $1);
 494                         goto found if $ibx;
 495                         return r430;
 496                 } else {
 497                         return r501;
 498                 }
 499         } else {
 500                 $err = '420 no current article has been selected';
 501                 $n = $self->{article} // return $err;
 502 find_ibx:
 503                 $ibx = $self->{ibx} or
 504                                 return '412 no newsgroup has been selected';
 505         }
 506 found:
 507         my $smsg = $ibx->over(1)->get_art($n) or return $err;
 508         $smsg->{-ibx} = $ibx;
 509         if ($code == 223) { # STAT
 510                 set_art($self, $n);
 511                 "223 $n <$smsg->{mid}> article retrieved - " .
 512                         "request text separately";
 513         } else { # HEAD | BODY | ARTICLE
 514                 $smsg->{nntp} = $self;
 515                 $smsg->{nntp_code} = $code;
 516                 set_art($self, $art);
 517                 # this dereferences to `undef'
 518                 ${ibx_async_cat($ibx, $smsg->{blob}, \&blob_cb, $smsg)};
 519         }
 520 }
 521
 522 sub msg_body_write ($$) {
 523         my ($self, $msg) = @_;
 524
 525         # these can momentarily double the memory consumption :<
 526         $$msg =~ s/^\./../smg;
 527         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 528         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 529         $self->msg_more($$msg);
 530 }
 531
 532 sub set_art {
 533         my ($self, $art) = @_;
 534         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 535 }
 536
 537 sub msg_hdr_write ($$) {
 538         my ($eml, $smsg) = @_;
 539         set_nntp_headers($eml, $smsg);
 540
 541         my $hdr = $eml->{hdr} // \(my $x = '');
 542         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 543         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 544         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 545
 546         # for leafnode compatibility, we need to ensure Message-ID headers
 547         # are only a single line.
 548         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 549         $smsg->{nntp}->msg_more($$hdr);
 550 }
 551
 552 sub blob_cb { # called by git->cat_async via ibx_async_cat
 553         my ($bref, $oid, $type, $size, $smsg) = @_;
 554         my $self = $smsg->{nntp};
 555         my $code = $smsg->{nntp_code};
 556         if (!defined($oid)) {
 557                 # it's possible to have TOCTOU if an admin runs
 558                 # public-inbox-(edit|purge), just move onto the next message
 559                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 560                 return $self->requeue;
 561         } elsif ($smsg->{blob} ne $oid) {
 562                 $self->close;
 563                 die "BUG: $smsg->{blob} != $oid";
 564         }
 565         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 566         my $eml = PublicInbox::Eml->new($bref);
 567         if ($code == 220) {
 568                 more($self, $r .= 'head and body follow');
 569                 msg_hdr_write($eml, $smsg);
 570                 $self->msg_more("\r\n");
 571                 msg_body_write($self, $bref);
 572         } elsif ($code == 221) {
 573                 more($self, $r .= 'head follows');
 574                 msg_hdr_write($eml, $smsg);
 575         } elsif ($code == 222) {
 576                 more($self, $r .= 'body follows');
 577                 msg_body_write($self, $bref);
 578         } else {
 579                 $self->close;
 580                 die "BUG: bad code: $r";
 581         }
 582         $self->write(\".\r\n"); # flushes (includes ->zflush)
 583         $self->requeue;
 584 }
 585
 586 sub cmd_article ($;$) {
 587         my ($self, $art) = @_;
 588         art_lookup($self, $art, 220);
 589 }
 590
 591 sub cmd_head ($;$) {
 592         my ($self, $art) = @_;
 593         art_lookup($self, $art, 221);
 594 }
 595
 596 sub cmd_body ($;$) {
 597         my ($self, $art) = @_;
 598         art_lookup($self, $art, 222);
 599 }
 600
 601 sub cmd_stat ($;$) {
 602         my ($self, $art) = @_;
 603         art_lookup($self, $art, 223); # art may be msgid
 604 }
 605
 606 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 607
 608 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 609
 610 sub cmd_help ($) {
 611         my ($self) = @_;
 612         more($self, '100 help text follows');
 613         '.'
 614 }
 615
 616 sub get_range ($$) {
 617         my ($self, $range) = @_;
 618         my $ibx = $self->{ibx} or return '412 no news group has been selected';
 619         defined $range or return '420 No article(s) selected';
 620         my ($beg, $end);
 621         my ($min, $max) = $ibx->mm(1)->minmax;
 622         if ($range =~ /\A([0-9]+)\z/) {
 623                 $beg = $end = $1;
 624         } elsif ($range =~ /\A([0-9]+)-\z/) {
 625                 ($beg, $end) = ($1, $max);
 626         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 627                 ($beg, $end) = ($1, $2);
 628         } else {
 629                 return r501;
 630         }
 631         $beg = $min if ($beg < $min);
 632         $end = $max if ($end > $max);
 633         return '420 No article(s) selected' if ($beg > $end);
 634         [ \$beg, $end ];
 635 }
 636
 637 sub long_step {
 638         my ($self) = @_;
 639         # wbuf is unset or empty, here; {long} may add to it
 640         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 641         my $more = eval { $cb->($self, @args) };
 642         if ($@ || !$self->{sock}) { # something bad happened...
 643                 delete $self->{long_cb};
 644                 my $elapsed = now() - $t0;
 645                 if ($@) {
 646                         err($self,
 647                             "%s during long response[$fd] - %0.6f",
 648                             $@, $elapsed);
 649                 }
 650                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 651                 $self->close;
 652         } elsif ($more) { # $self->{wbuf}:
 653                 # COMPRESS users all share the same DEFLATE context.
 654                 # Flush it here to ensure clients don't see
 655                 # each other's data
 656                 $self->zflush;
 657
 658                 # no recursion, schedule another call ASAP, but only after
 659                 # all pending writes are done.  autovivify wbuf:
 660                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 661
 662                 # wbuf may be populated by $cb, no need to rearm if so:
 663                 $self->requeue if $new_size == 1;
 664         } else { # all done!
 665                 delete $self->{long_cb};
 666                 $self->write(\".\r\n");
 667                 my $elapsed = now() - $t0;
 668                 my $fd = fileno($self->{sock});
 669                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 670                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 671                 $self->requeue unless $wbuf && @$wbuf;
 672         }
 673 }
 674
 675 sub long_response ($$;@) {
 676         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 677
 678         my $sock = $self->{sock} or return;
 679         # make sure we disable reading during a long response,
 680         # clients should not be sending us stuff and making us do more
 681         # work while we are stream a response to them
 682         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 683         long_step($self); # kick off!
 684         undef;
 685 }
 686
 687 sub hdr_msgid_range_i {
 688         my ($self, $beg, $end) = @_;
 689         my $r = $self->{ibx}->mm(1)->msg_range($beg, $end);
 690         @$r or return;
 691         $self->msg_more(join('', map { "$_->[0] <$_->[1]>\r\n" } @$r));
 692         1;
 693 }
 694
 695 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 696         my ($self, $xhdr, $range) = @_;
 697
 698         if (defined $range && $range =~ $ONE_MSGID) {
 699                 my ($ibx, $n) = mid_lookup($self, $1);
 700                 return r430 unless $n;
 701                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $range);
 702         } else { # numeric range
 703                 $range = $self->{article} unless defined $range;
 704                 my $r = get_range($self, $range);
 705                 return $r unless ref $r;
 706                 $self->msg_more($xhdr ? r221 : r225);
 707                 long_response($self, \&hdr_msgid_range_i, @$r);
 708         }
 709 }
 710
 711 sub mid_lookup ($$) {
 712         my ($self, $mid) = @_;
 713         my $cur_ibx = $self->{ibx};
 714         if ($cur_ibx) {
 715                 my $n = $cur_ibx->mm(1)->num_for($mid);
 716                 return ($cur_ibx, $n) if defined $n;
 717         }
 718         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 719         if (my $ALL = $pi_cfg->ALL) {
 720                 my ($id, $prev);
 721                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 722                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 723                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 724                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 725                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 726                                 return ($ibx, $xnum) if $ibx;
 727                                 # fall through to trying all xref3s
 728                         } else {
 729                                 warn <<EOF;
 730 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 731 EOF
 732                         }
 733                         # try all xref3s
 734                         for my $x (@$xr3) {
 735                                 my ($ngname, $xnum) = split(/:/, $x);
 736                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 737                                 return ($ibx, $xnum) if $ibx;
 738                                 warn "W: `$ngname' does not exist for #$xnum\n";
 739                         }
 740                 }
 741                 # no warning here, $mid is just invalid
 742         } else { # slow path for non-ALL users
 743                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 744                         next if defined $cur_ibx && $ibx eq $cur_ibx;
 745                         my $n = $ibx->mm(1)->num_for($mid);
 746                         return ($ibx, $n) if defined $n;
 747                 }
 748         }
 749         (undef, undef);
 750 }
 751
 752 sub xref_range_i {
 753         my ($self, $beg, $end) = @_;
 754         my $ibx = $self->{ibx};
 755         my $msgs = $ibx->over(1)->query_xover($$beg, $end);
 756         scalar(@$msgs) or return;
 757         $$beg = $msgs->[-1]->{num} + 1;
 758         $self->msg_more(join('', map {
 759                 "$_->{num} ".xref($self, $ibx, $_) . "\r\n";
 760         } @$msgs));
 761         1;
 762 }
 763
 764 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 765         my ($self, $xhdr, $range) = @_;
 766
 767         if (defined $range && $range =~ $ONE_MSGID) {
 768                 my $mid = $1;
 769                 my ($ibx, $n) = mid_lookup($self, $mid);
 770                 return r430 unless $n;
 771                 my $smsg = $ibx->over(1)->get_art($n) or return;
 772                 hdr_mid_response($self, $xhdr, $ibx, $n, $range,
 773                                 xref($self, $ibx, $smsg));
 774         } else { # numeric range
 775                 $range = $self->{article} unless defined $range;
 776                 my $r = get_range($self, $range);
 777                 return $r unless ref $r;
 778                 $self->msg_more($xhdr ? r221 : r225);
 779                 long_response($self, \&xref_range_i, @$r);
 780         }
 781 }
 782
 783 sub over_header_for {
 784         my ($ibx, $num, $field) = @_;
 785         my $smsg = $ibx->over(1)->get_art($num) or return;
 786         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 787         $smsg->{$field};
 788 }
 789
 790 sub smsg_range_i {
 791         my ($self, $beg, $end, $field) = @_;
 792         my $msgs = $self->{ibx}->over(1)->query_xover($$beg, $end);
 793         scalar(@$msgs) or return;
 794         my $tmp = '';
 795
 796         # ->{$field} is faster than ->$field invocations, so favor that.
 797         if ($field eq 'date') {
 798                 for my $s (@$msgs) {
 799                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 800                 }
 801         } else {
 802                 for my $s (@$msgs) {
 803                         $tmp .= "$s->{num} $s->{$field}\r\n";
 804                 }
 805         }
 806         utf8::encode($tmp);
 807         $self->msg_more($tmp);
 808         $$beg = $msgs->[-1]->{num} + 1;
 809 }
 810
 811 sub hdr_smsg ($$$$) {
 812         my ($self, $xhdr, $field, $range) = @_;
 813         if (defined $range && $range =~ $ONE_MSGID) {
 814                 my ($ibx, $n) = mid_lookup($self, $1);
 815                 return r430 unless defined $n;
 816                 my $v = over_header_for($ibx, $n, $field);
 817                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $v);
 818         } else { # numeric range
 819                 $range = $self->{article} unless defined $range;
 820                 my $r = get_range($self, $range);
 821                 return $r unless ref $r;
 822                 $self->msg_more($xhdr ? r221 : r225);
 823                 long_response($self, \&smsg_range_i, @$r, $field);
 824         }
 825 }
 826
 827 sub do_hdr ($$$;$) {
 828         my ($self, $xhdr, $header, $range) = @_;
 829         my $sub = lc $header;
 830         if ($sub eq 'message-id') {
 831                 hdr_message_id($self, $xhdr, $range);
 832         } elsif ($sub eq 'xref') {
 833                 hdr_xref($self, $xhdr, $range);
 834         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 835                                 bytes|lines)\z/x) {
 836                 hdr_smsg($self, $xhdr, $sub, $range);
 837         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 838                 hdr_smsg($self, $xhdr, $1, $range);
 839         } else {
 840                 $xhdr ? (r221 . '.') : "503 HDR not permitted on $header";
 841         }
 842 }
 843
 844 # RFC 3977
 845 sub cmd_hdr ($$;$) {
 846         my ($self, $header, $range) = @_;
 847         do_hdr($self, 0, $header, $range);
 848 }
 849
 850 # RFC 2980
 851 sub cmd_xhdr ($$;$) {
 852         my ($self, $header, $range) = @_;
 853         do_hdr($self, 1, $header, $range);
 854 }
 855
 856 sub hdr_mid_prefix ($$$$$) {
 857         my ($self, $xhdr, $ibx, $n, $mid) = @_;
 858         return $mid if $xhdr;
 859
 860         # HDR for RFC 3977 users
 861         if (my $cur_ibx = $self->{ibx}) {
 862                 ($cur_ibx eq $ibx) ? $n : '0';
 863         } else {
 864                 '0';
 865         }
 866 }
 867
 868 sub hdr_mid_response ($$$$$$) {
 869         my ($self, $xhdr, $ibx, $n, $mid, $v) = @_;
 870         $self->write(($xhdr ? r221.$mid :
 871                    r225.hdr_mid_prefix($self, $xhdr, $ibx, $n, $mid)) .
 872                 " $v\r\n.\r\n");
 873         undef;
 874 }
 875
 876 sub xrover_i {
 877         my ($self, $beg, $end) = @_;
 878         my $h = over_header_for($self->{ibx}, $$beg, 'references');
 879         more($self, "$$beg $h") if defined($h);
 880         $$beg++ < $end;
 881 }
 882
 883 sub cmd_xrover ($;$) {
 884         my ($self, $range) = @_;
 885         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 886         (defined $range && $range =~ /[<>]/) and
 887                 return '420 No article(s) selected'; # no message IDs
 888
 889         $range = $self->{article} unless defined $range;
 890         my $r = get_range($self, $range);
 891         return $r unless ref $r;
 892         more($self, '224 Overview information follows');
 893         long_response($self, \&xrover_i, @$r);
 894 }
 895
 896 sub over_line ($$$) {
 897         my ($self, $ibx, $smsg) = @_;
 898         # n.b. field access and procedural calls can be
 899         # 10%-15% faster than OO method calls:
 900         my $s = join("\t", $smsg->{num},
 901                 $smsg->{subject},
 902                 $smsg->{from},
 903                 PublicInbox::Smsg::date($smsg),
 904                 "<$smsg->{mid}>",
 905                 $smsg->{references},
 906                 $smsg->{bytes},
 907                 $smsg->{lines},
 908                 "Xref: " . xref($self, $ibx, $smsg));
 909         utf8::encode($s);
 910         $s .= "\r\n";
 911 }
 912
 913 sub cmd_over ($;$) {
 914         my ($self, $range) = @_;
 915         if ($range && $range =~ $ONE_MSGID) {
 916                 my ($ibx, $n) = mid_lookup($self, $1);
 917                 defined $n or return r430;
 918                 my $smsg = $ibx->over(1)->get_art($n) or return r430;
 919                 more($self, '224 Overview information follows (multi-line)');
 920
 921                 # Only set article number column if it's the current group
 922                 # (RFC 3977 8.3.2)
 923                 my $cur_ibx = $self->{ibx};
 924                 if (!$cur_ibx || $cur_ibx ne $ibx) {
 925                         # set {-orig_num} for nntp_xref_for
 926                         $smsg->{-orig_num} = $smsg->{num};
 927                         $smsg->{num} = 0;
 928                 }
 929                 $self->msg_more(over_line($self, $ibx, $smsg));
 930                 '.';
 931         } else {
 932                 cmd_xover($self, $range);
 933         }
 934 }
 935
 936 sub xover_i {
 937         my ($self, $beg, $end) = @_;
 938         my $ibx = $self->{ibx};
 939         my $msgs = $ibx->over(1)->query_xover($$beg, $end);
 940         my $nr = scalar @$msgs or return;
 941
 942         # OVERVIEW.FMT
 943         $self->msg_more(join('', map {
 944                 over_line($self, $ibx, $_);
 945                 } @$msgs));
 946         $$beg = $msgs->[-1]->{num} + 1;
 947 }
 948
 949 sub cmd_xover ($;$) {
 950         my ($self, $range) = @_;
 951         $range = $self->{article} unless defined $range;
 952         my $r = get_range($self, $range);
 953         return $r unless ref $r;
 954         my ($beg, $end) = @$r;
 955         more($self, "224 Overview information follows for $$beg to $end");
 956         long_response($self, \&xover_i, @$r);
 957 }
 958
 959 sub compressed { undef }
 960
 961 sub cmd_starttls ($) {
 962         my ($self) = @_;
 963         my $sock = $self->{sock} or return;
 964         # RFC 4642 2.2.1
 965         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 966         my $opt = $self->{nntpd}->{accept_tls} or
 967                 return '580 can not initiate TLS negotiation';
 968         $self->write(\"382 Continue with TLS negotiation\r\n");
 969         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 970         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 971         undef;
 972 }
 973
 974 # RFC 8054
 975 sub cmd_compress ($$) {
 976         my ($self, $alg) = @_;
 977         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 978         return r502 if $self->compressed;
 979         PublicInbox::NNTPdeflate->enable($self);
 980         $self->requeue;
 981         undef
 982 }
 983
 984 sub zflush {} # overridden by NNTPdeflate
 985
 986 sub cmd_xpath ($$) {
 987         my ($self, $mid) = @_;
 988         return r501 unless $mid =~ $ONE_MSGID;
 989         $mid = $1;
 990         my @paths;
 991         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 992         my $groups = $pi_cfg->{-by_newsgroup};
 993         if (my $ALL = $pi_cfg->ALL) {
 994                 my ($id, $prev, %seen);
 995                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 996                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 997                         for my $x (@$xr3) {
 998                                 my ($ngname, $n) = split(/:/, $x);
 999                                 $x = "$ngname/$n";
1000                                 if ($groups->{$ngname} && !$seen{$x}++) {
1001                                         push(@paths, $x);
1002                                 }
1003                         }
1004                 }
1005         } else { # slow path, no point in using long_response
1006                 for my $ibx (values %$groups) {
1007                         my $n = $ibx->mm(1)->num_for($mid) // next;
1008                         push @paths, "$ibx->{newsgroup}/$n";
1009                 }
1010         }
1011         return '430 no such article on server' unless @paths;
1012         '223 '.join(' ', sort(@paths));
1013 }
1014
1015 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1016
1017 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1018
1019 sub do_write ($$) {
1020         my $self = $_[0];
1021         my $done = $self->write(\($_[1]));
1022         return 0 unless $self->{sock};
1023
1024         $done;
1025 }
1026
1027 sub err ($$;@) {
1028         my ($self, $fmt, @args) = @_;
1029         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1030 }
1031
1032 sub out ($$;@) {
1033         my ($self, $fmt, @args) = @_;
1034         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1035 }
1036
1037 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1038 sub event_step {
1039         my ($self) = @_;
1040
1041         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1042
1043         # only read more requests if we've drained the write buffer,
1044         # otherwise we can be buffering infinitely w/o backpressure
1045
1046         my $rbuf = $self->{rbuf} // \(my $x = '');
1047         my $line = index($$rbuf, "\n");
1048         while ($line < 0) {
1049                 return $self->close if length($$rbuf) >= LINE_MAX;
1050                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1051                 $line = index($$rbuf, "\n");
1052         }
1053         $line = substr($$rbuf, 0, $line + 1, '');
1054         $line =~ s/\r?\n\z//s;
1055         return $self->close if $line =~ /[[:cntrl:]]/s;
1056
1057         my $t0 = now();
1058         my $fd = fileno($self->{sock});
1059         my $r = eval { process_line($self, $line) };
1060         my $pending = $self->{wbuf} ? ' pending' : '';
1061         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1062         return $self->close if $r < 0;
1063         $self->rbuf_idle($rbuf);
1064
1065         # maybe there's more pipelined data, or we'll have
1066         # to register it for socket-readiness notifications
1067         $self->requeue unless $pending;
1068 }
1069
1070 sub busy { # for graceful shutdown in PublicInbox::Daemon:
1071         my ($self) = @_;
1072         defined($self->{rbuf}) || defined($self->{wbuf})
1073 }
1074
1075 1;