lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::MIME;
  15 use Data::Dumper qw(Dumper);
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $EXPTIMER;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $WEAKEN = {}; # string(nntpd) -> nntpd
  42 my $WEAKTIMER;
  43
  44 sub update_idle_time ($) {
  45         my ($self) = @_;
  46         my $tmp = $self->{sock} or return;
  47         $tmp = fileno($tmp);
  48         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  49 }
  50
  51 # reduce FD pressure by closing some "git cat-file --batch" processes
  52 # and unused FDs for msgmap and Xapian indices
  53 sub weaken_groups () {
  54         $WEAKTIMER = undef;
  55         foreach my $nntpd (values %$WEAKEN) {
  56                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  57         }
  58         $WEAKEN = {};
  59 }
  60
  61 sub expire_old () {
  62         my $now = now();
  63         my $exp = $EXPTIME;
  64         my $old = $now - $exp;
  65         my $next = $now + $exp;
  66         my $nr = 0;
  67         my %new;
  68         while (my ($fd, $v) = each %$EXPMAP) {
  69                 my ($idle_time, $nntp) = @$v;
  70                 if ($idle_time < $old) {
  71                         $nntp->close; # idempotent
  72                 } else {
  73                         my $nexp = $idle_time + $exp;
  74                         $next = $nexp if ($nexp < $next);
  75                         ++$nr;
  76                         $new{$fd} = $v;
  77                 }
  78         }
  79         $EXPMAP = \%new;
  80         if ($nr) {
  81                 $next -= $now;
  82                 $next = 0 if $next < 0;
  83                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
  84                 weaken_groups();
  85         } else {
  86                 $EXPTIMER = undef;
  87                 # noop to kick outselves out of the loop ASAP so descriptors
  88                 # really get closed
  89                 Danga::Socket->AddTimer(0, sub {});
  90
  91                 # grace period for reaping resources
  92                 $WEAKTIMER ||= Danga::Socket->AddTimer(30, *weaken_groups);
  93         }
  94 }
  95
  96 sub new ($$$) {
  97         my ($class, $sock, $nntpd) = @_;
  98         my $self = fields::new($class);
  99         binmode $sock, ':utf8'; # RFC 3977
 100         $self->SUPER::new($sock);
 101         $self->{nntpd} = $nntpd;
 102         res($self, '201 server ready - post via email');
 103         $self->{rbuf} = '';
 104         $self->watch_read(1);
 105         update_idle_time($self);
 106         $WEAKEN->{"$nntpd"} = $nntpd;
 107         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
 108         $self;
 109 }
 110
 111 sub args_ok ($$) {
 112         my ($cb, $argc) = @_;
 113         my $tot = prototype $cb;
 114         my ($nreq, undef) = split(';', $tot);
 115         $nreq = ($nreq =~ tr/$//) - 1;
 116         $tot = ($tot =~ tr/$//) - 1;
 117         ($argc <= $tot && $argc >= $nreq);
 118 }
 119
 120 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 121 sub process_line ($$) {
 122         my ($self, $l) = @_;
 123         my ($req, @args) = split(/\s+/, $l);
 124         $req = lc($req);
 125         $req = eval {
 126                 no strict 'refs';
 127                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 128         };
 129         return res($self, '500 command not recognized') unless $req;
 130         return res($self, r501) unless args_ok($req, scalar @args);
 131
 132         my $res = eval { $req->($self, @args) };
 133         my $err = $@;
 134         if ($err && !$self->{closed}) {
 135                 chomp($l = Dumper(\$l));
 136                 err($self, 'error from: %s (%s)', $l, $err);
 137                 $res = '503 program fault - command not performed';
 138         }
 139         return 0 unless defined $res;
 140         res($self, $res);
 141 }
 142
 143 sub cmd_mode ($$) {
 144         my ($self, $arg) = @_;
 145         $arg = uc $arg;
 146         return r501 unless $arg eq 'READER';
 147         '201 Posting prohibited';
 148 }
 149
 150 sub cmd_slave ($) { '202 slave status noted' }
 151
 152 sub cmd_xgtitle ($;$) {
 153         my ($self, $wildmat) = @_;
 154         more($self, '282 list of groups and descriptions follows');
 155         list_newsgroups($self, $wildmat);
 156         '.'
 157 }
 158
 159 sub list_overview_fmt ($) {
 160         my ($self) = @_;
 161         do_more($self, $OVERVIEW_FMT);
 162 }
 163
 164 sub list_headers ($;$) {
 165         my ($self) = @_;
 166         do_more($self, $LIST_HEADERS);
 167 }
 168
 169 sub list_active ($;$) {
 170         my ($self, $wildmat) = @_;
 171         wildmat2re($wildmat);
 172         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 173                 $ng->{name} =~ $wildmat or next;
 174                 group_line($self, $ng);
 175         }
 176 }
 177
 178 sub list_active_times ($;$) {
 179         my ($self, $wildmat) = @_;
 180         wildmat2re($wildmat);
 181         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 182                 $ng->{name} =~ $wildmat or next;
 183                 my $c = eval { $ng->mm->created_at } || time;
 184                 more($self, "$ng->{name} $c $ng->{address}");
 185         }
 186 }
 187
 188 sub list_newsgroups ($;$) {
 189         my ($self, $wildmat) = @_;
 190         wildmat2re($wildmat);
 191         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 192                 $ng->{name} =~ $wildmat or next;
 193                 my $d = $ng->description;
 194                 more($self, "$ng->{name} $d");
 195         }
 196 }
 197
 198 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 199 sub cmd_list ($;$$) {
 200         my ($self, @args) = @_;
 201         if (scalar @args) {
 202                 my $arg = shift @args;
 203                 $arg =~ tr/A-Z./a-z_/;
 204                 $arg = "list_$arg";
 205                 return r501 if $DISABLED{$arg};
 206
 207                 $arg = eval {
 208                         no strict 'refs';
 209                         *{$arg}{CODE};
 210                 };
 211                 return r501 unless $arg && args_ok($arg, scalar @args);
 212                 more($self, '215 information follows');
 213                 $arg->($self, @args);
 214         } else {
 215                 more($self, '215 list of newsgroups follows');
 216                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 217                         group_line($self, $ng);
 218                 }
 219         }
 220         '.'
 221 }
 222
 223 sub cmd_listgroup ($;$) {
 224         my ($self, $group) = @_;
 225         if (defined $group) {
 226                 my $res = cmd_group($self, $group);
 227                 return $res if ($res !~ /\A211 /);
 228                 more($self, $res);
 229         }
 230
 231         $self->{ng} or return '412 no newsgroup selected';
 232         long_response($self, 0, long_response_limit, sub {
 233                 my ($i) = @_;
 234                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 235                         my ($ary) = @_;
 236                         more($self, join("\r\n", @$ary));
 237                 });
 238
 239                 # -1 to adjust for implicit increment in long_response
 240                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 241         });
 242 }
 243
 244 sub parse_time ($$;$) {
 245         my ($date, $time, $gmt) = @_;
 246         use Time::Local qw();
 247         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 248         if (defined $gmt) {
 249                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 250                 $gmt = 1;
 251         }
 252         my @now = $gmt ? gmtime : localtime;
 253         my ($YYYY, $MM, $DD);
 254         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 255                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 256         } else { # legacy clients send YYMMDD
 257                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 258                 if ($YYYY > strftime('%y', @now)) {
 259                         my $cur_year = $now[5] + 1900;
 260                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 261                 }
 262         }
 263         if ($gmt) {
 264                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 265         } else {
 266                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 267         }
 268 }
 269
 270 sub group_line ($$) {
 271         my ($self, $ng) = @_;
 272         my ($min, $max) = $ng->mm->minmax;
 273         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 274 }
 275
 276 sub cmd_newgroups ($$$;$$) {
 277         my ($self, $date, $time, $gmt, $dists) = @_;
 278         my $ts = eval { parse_time($date, $time, $gmt) };
 279         return r501 if $@;
 280
 281         # TODO dists
 282         more($self, '231 list of new newsgroups follows');
 283         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 284                 my $c = eval { $ng->mm->created_at } || 0;
 285                 next unless $c > $ts;
 286                 group_line($self, $ng);
 287         }
 288         '.'
 289 }
 290
 291 sub wildmat2re (;$) {
 292         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 293         my %keep;
 294         my $salt = rand;
 295         use Digest::SHA qw(sha1_hex);
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub cmd_newnews ($$$$;$$) {
 324         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 325         my $ts = eval { parse_time($date, $time, $gmt) };
 326         return r501 if $@;
 327         more($self, '230 list of new articles by message-id follows');
 328         my ($keep, $skip) = split('!', $newsgroups, 2);
 329         ngpat2re($keep);
 330         ngpat2re($skip);
 331         my @srch;
 332         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 333                 $ng->{name} =~ $keep or next;
 334                 $ng->{name} =~ $skip and next;
 335                 my $srch = $ng->search or next;
 336                 push @srch, $srch;
 337         };
 338         return '.' unless @srch;
 339
 340         $ts .= '..';
 341         my $opts = { asc => 1, limit => 1000, offset => 0 };
 342         long_response($self, 0, long_response_limit, sub {
 343                 my ($i) = @_;
 344                 my $srch = $srch[0];
 345                 my $res = $srch->query($ts, $opts);
 346                 my $msgs = $res->{msgs};
 347                 if (my $nr = scalar @$msgs) {
 348                         more($self, '<' .
 349                                 join(">\r\n<", map { $_->mid } @$msgs ).
 350                                 '>');
 351                         $opts->{offset} += $nr;
 352                 } else {
 353                         shift @srch;
 354                         if (@srch) { # continue onto next newsgroup
 355                                 $opts->{offset} = 0;
 356                         } else { # break out of the long response.
 357                                 $$i = long_response_limit;
 358                         }
 359                 }
 360         });
 361 }
 362
 363 sub cmd_group ($$) {
 364         my ($self, $group) = @_;
 365         my $no_such = '411 no such news group';
 366         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 367
 368         $self->{ng} = $ng;
 369         my ($min, $max) = $ng->mm->minmax;
 370         $min ||= 0;
 371         $max ||= 0;
 372         $self->{article} = $min;
 373         my $est_size = $max - $min;
 374         "211 $est_size $min $max $group";
 375 }
 376
 377 sub article_adj ($$) {
 378         my ($self, $off) = @_;
 379         my $ng = $self->{ng} or return '412 no newsgroup selected';
 380
 381         my $n = $self->{article};
 382         defined $n or return '420 no current article has been selected';
 383
 384         $n += $off;
 385         my $mid = $ng->mm->mid_for($n);
 386         unless ($mid) {
 387                 $n = $off > 0 ? 'next' : 'previous';
 388                 return "421 no $n article in this group";
 389         }
 390         $self->{article} = $n;
 391         "223 $n <$mid> article retrieved - request text separately";
 392 }
 393
 394 sub cmd_next ($) { article_adj($_[0], 1) }
 395 sub cmd_last ($) { article_adj($_[0], -1) }
 396
 397 # We want to encourage using email and CC-ing everybody involved to avoid
 398 # the single-point-of-failure a single server provides.
 399 sub cmd_post ($) {
 400         my ($self) = @_;
 401         my $ng = $self->{ng};
 402         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 403 }
 404
 405 sub cmd_quit ($) {
 406         my ($self) = @_;
 407         res($self, '205 closing connection - goodbye!');
 408         $self->close;
 409         undef;
 410 }
 411
 412 sub art_lookup ($$$) {
 413         my ($self, $art, $set_headers) = @_;
 414         my $ng = $self->{ng};
 415         my ($n, $mid);
 416         my $err;
 417         if (defined $art) {
 418                 if ($art =~ /\A\d+\z/o) {
 419                         $err = '423 no such article number in this group';
 420                         $n = int($art);
 421                         goto find_mid;
 422                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 423                         $mid = $1;
 424                         $err = r430;
 425                         $n = $ng->mm->num_for($mid) if $ng;
 426                         goto found if defined $n;
 427                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 428                                 $n = $g->mm->num_for($mid);
 429                                 if (defined $n) {
 430                                         $ng = $g;
 431                                         goto found;
 432                                 }
 433                         }
 434                         return $err;
 435                 } else {
 436                         return r501;
 437                 }
 438         } else {
 439                 $err = '420 no current article has been selected';
 440                 $n = $self->{article};
 441                 defined $n or return $err;
 442 find_mid:
 443                 $ng or return '412 no newsgroup has been selected';
 444                 $mid = $ng->mm->mid_for($n);
 445                 defined $mid or return $err;
 446         }
 447 found:
 448         my $o = 'HEAD:' . mid2path($mid);
 449         my $bytes;
 450         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 451         return $err unless $s;
 452         my $lines;
 453         if ($set_headers) {
 454                 $s->header_set('Newsgroups', $ng->{name});
 455                 $s->header_set('Xref', xref($ng, $n));
 456                 $lines = $s->body =~ tr!\n!\n!;
 457
 458                 # must be last
 459                 $s->body_set('') if ($set_headers == 2);
 460         }
 461         [ $n, $mid, $s, $bytes, $lines, $ng ];
 462 }
 463
 464 sub simple_body_write ($$) {
 465         my ($self, $s) = @_;
 466         my $body = $s->body;
 467         $s->body_set('');
 468         $body =~ s/^\./../smg;
 469         $body =~ s/(?<!\r)\n/\r\n/sg;
 470         do_more($self, $body);
 471         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 472         '.'
 473 }
 474
 475 sub set_art {
 476         my ($self, $art) = @_;
 477         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 478 }
 479
 480 sub cmd_article ($;$) {
 481         my ($self, $art) = @_;
 482         my $r = art_lookup($self, $art, 1);
 483         return $r unless ref $r;
 484         my ($n, $mid, $s) = @$r;
 485         set_art($self, $art);
 486         more($self, "220 $n <$mid> article retrieved - head and body follow");
 487         do_more($self, $s->header_obj->as_string);
 488         do_more($self, "\r\n");
 489         simple_body_write($self, $s);
 490 }
 491
 492 sub cmd_head ($;$) {
 493         my ($self, $art) = @_;
 494         my $r = art_lookup($self, $art, 2);
 495         return $r unless ref $r;
 496         my ($n, $mid, $s) = @$r;
 497         set_art($self, $art);
 498         more($self, "221 $n <$mid> article retrieved - head follows");
 499         do_more($self, $s->header_obj->as_string);
 500         '.'
 501 }
 502
 503 sub cmd_body ($;$) {
 504         my ($self, $art) = @_;
 505         my $r = art_lookup($self, $art, 0);
 506         return $r unless ref $r;
 507         my ($n, $mid, $s) = @$r;
 508         set_art($self, $art);
 509         more($self, "222 $n <$mid> article retrieved - body follows");
 510         simple_body_write($self, $s);
 511 }
 512
 513 sub cmd_stat ($;$) {
 514         my ($self, $art) = @_;
 515         my $r = art_lookup($self, $art, 0);
 516         return $r unless ref $r;
 517         my ($n, $mid, undef) = @$r;
 518         set_art($self, $art);
 519         "223 $n <$mid> article retrieved - request text separately";
 520 }
 521
 522 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 523
 524 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 525
 526 sub cmd_help ($) {
 527         my ($self) = @_;
 528         more($self, '100 help text follows');
 529         '.'
 530 }
 531
 532 sub get_range ($$) {
 533         my ($self, $range) = @_;
 534         my $ng = $self->{ng} or return '412 no news group has been selected';
 535         defined $range or return '420 No article(s) selected';
 536         my ($beg, $end);
 537         my ($min, $max) = $ng->mm->minmax;
 538         if ($range =~ /\A(\d+)\z/) {
 539                 $beg = $end = $1;
 540         } elsif ($range =~ /\A(\d+)-\z/) {
 541                 ($beg, $end) = ($1, $max);
 542         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 543                 ($beg, $end) = ($1, $2);
 544         } else {
 545                 return r501;
 546         }
 547         $beg = $min if ($beg < $min);
 548         $end = $max if ($end > $max);
 549         return '420 No article(s) selected' if ($beg > $end);
 550         [ $beg, $end ];
 551 }
 552
 553 sub long_response ($$$$) {
 554         my ($self, $beg, $end, $cb) = @_;
 555         die "BUG: nested long response" if $self->{long_res};
 556
 557         my $fd = $self->{fd};
 558         defined $fd or return;
 559         # make sure we disable reading during a long response,
 560         # clients should not be sending us stuff and making us do more
 561         # work while we are stream a response to them
 562         $self->watch_read(0);
 563         my $t0 = now();
 564         $self->{long_res} = sub {
 565                 # limit our own running time for fairness with other
 566                 # clients and to avoid buffering too much:
 567                 my $lim = 100;
 568
 569                 my $err;
 570                 do {
 571                         eval { $cb->(\$beg) };
 572                 } until (($err = $@) || $self->{closed} ||
 573                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 574
 575                 if ($err || $self->{closed}) {
 576                         $self->{long_res} = undef;
 577
 578                         if ($err) {
 579                                 err($self,
 580                                     "%s during long response[$fd] - %0.6f",
 581                                     $err, now() - $t0);
 582                         }
 583                         if ($self->{closed}) {
 584                                 out($self, " deferred[$fd] aborted - %0.6f",
 585                                            now() - $t0);
 586                         } else {
 587                                 update_idle_time($self);
 588                                 $self->watch_read(1);
 589                         }
 590                 } elsif (!$lim || $self->{write_buf_size}) {
 591                         # no recursion, schedule another call ASAP
 592                         # but only after all pending writes are done
 593                         update_idle_time($self);
 594                         Danga::Socket->AddTimer(0, sub {
 595                                 $self->write($self->{long_res});
 596                         });
 597                 } else { # all done!
 598                         $self->{long_res} = undef;
 599                         $self->watch_read(1);
 600                         res($self, '.');
 601                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 602                 }
 603         };
 604         $self->{long_res}->(); # kick off!
 605         undef;
 606 }
 607
 608 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 609         my ($self, $xhdr, $range) = @_;
 610
 611         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 612                 my ($ng, $n) = mid_lookup($self, $1);
 613                 return r430 unless $n;
 614                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 615         } else { # numeric range
 616                 $range = $self->{article} unless defined $range;
 617                 my $r = get_range($self, $range);
 618                 return $r unless ref $r;
 619                 my $mm = $self->{ng}->mm;
 620                 my ($beg, $end) = @$r;
 621                 more($self, $xhdr ? r221 : r225);
 622                 long_response($self, $beg, $end, sub {
 623                         my ($i) = @_;
 624                         my $mid = $mm->mid_for($$i);
 625                         more($self, "$$i <$mid>") if defined $mid;
 626                 });
 627         }
 628 }
 629
 630 sub xref ($$) {
 631         my ($ng, $n) = @_;
 632         "$ng->{domain} $ng->{name}:$n"
 633 }
 634
 635 sub mid_lookup ($$) {
 636         my ($self, $mid) = @_;
 637         my $self_ng = $self->{ng};
 638         if ($self_ng) {
 639                 my $n = $self_ng->mm->num_for($mid);
 640                 return ($self_ng, $n) if defined $n;
 641         }
 642         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 643                 next if defined $self_ng && $ng eq $self_ng;
 644                 my $n = $ng->mm->num_for($mid);
 645                 return ($ng, $n) if defined $n;
 646         }
 647         (undef, undef);
 648 }
 649
 650 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 651         my ($self, $xhdr, $range) = @_;
 652
 653         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 654                 my ($ng, $n) = mid_lookup($self, $1);
 655                 return r430 unless $n;
 656                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 657         } else { # numeric range
 658                 $range = $self->{article} unless defined $range;
 659                 my $r = get_range($self, $range);
 660                 return $r unless ref $r;
 661                 my $ng = $self->{ng};
 662                 my $mm = $ng->mm;
 663                 my ($beg, $end) = @$r;
 664                 more($self, $xhdr ? r221 : r225);
 665                 long_response($self, $beg, $end, sub {
 666                         my ($i) = @_;
 667                         my $mid = $mm->mid_for($$i);
 668                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 669                 });
 670         }
 671 }
 672
 673 sub search_header_for {
 674         my ($srch, $mid, $field) = @_;
 675         my $smsg = $srch->lookup_message($mid) or return;
 676         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 677         $smsg->$field;
 678 }
 679
 680 sub hdr_searchmsg ($$$$) {
 681         my ($self, $xhdr, $field, $range) = @_;
 682         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 683                 my ($ng, $n) = mid_lookup($self, $1);
 684                 return r430 unless $n;
 685                 my $v = search_header_for($ng->search, $range, $field);
 686                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 687         } else { # numeric range
 688                 $range = $self->{article} unless defined $range;
 689                 my $srch = $self->{ng}->search;
 690                 my $mm = $self->{ng}->mm;
 691                 my $r = get_range($self, $range);
 692                 return $r unless ref $r;
 693                 my ($beg, $end) = @$r;
 694                 more($self, $xhdr ? r221 : r225);
 695                 my $off = 0;
 696                 long_response($self, $beg, $end, sub {
 697                         my ($i) = @_;
 698                         my $res = $srch->query_xover($beg, $end, $off);
 699                         my $msgs = $res->{msgs};
 700                         my $nr = scalar @$msgs or return;
 701                         $off += $nr;
 702                         my $tmp = '';
 703                         foreach my $s (@$msgs) {
 704                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 705                         }
 706                         do_more($self, $tmp);
 707                         # -1 to adjust for implicit increment in long_response
 708                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 709                 });
 710         }
 711 }
 712
 713 sub do_hdr ($$$;$) {
 714         my ($self, $xhdr, $header, $range) = @_;
 715         my $sub = lc $header;
 716         if ($sub eq 'message-id') {
 717                 hdr_message_id($self, $xhdr, $range);
 718         } elsif ($sub eq 'xref') {
 719                 hdr_xref($self, $xhdr, $range);
 720         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 721                                 bytes|lines)\z/x) {
 722                 hdr_searchmsg($self, $xhdr, $sub, $range);
 723         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 724                 hdr_searchmsg($self, $xhdr, $1, $range);
 725         } else {
 726                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 727         }
 728 }
 729
 730 # RFC 3977
 731 sub cmd_hdr ($$;$) {
 732         my ($self, $header, $range) = @_;
 733         do_hdr($self, 0, $header, $range);
 734 }
 735
 736 # RFC 2980
 737 sub cmd_xhdr ($$;$) {
 738         my ($self, $header, $range) = @_;
 739         do_hdr($self, 1, $header, $range);
 740 }
 741
 742 sub hdr_mid_prefix ($$$$$) {
 743         my ($self, $xhdr, $ng, $n, $mid) = @_;
 744         return $mid if $xhdr;
 745
 746         # HDR for RFC 3977 users
 747         if (my $self_ng = $self->{ng}) {
 748                 ($self_ng eq $ng) ? $n : '0';
 749         } else {
 750                 '0';
 751         }
 752 }
 753
 754 sub hdr_mid_response ($$$$$$) {
 755         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 756         my $res = '';
 757         if ($xhdr) {
 758                 $res .= r221 . "\r\n";
 759                 $res .= "$mid $v\r\n";
 760         } else {
 761                 $res .= r225 . "\r\n";
 762                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 763                 $res .= "$pfx $v\r\n";
 764         }
 765         res($self, $res .= '.');
 766         undef;
 767 }
 768
 769 sub cmd_xrover ($;$) {
 770         my ($self, $range) = @_;
 771         my $ng = $self->{ng} or return '412 no newsgroup selected';
 772         (defined $range && $range =~ /[<>]/) and
 773                 return '420 No article(s) selected'; # no message IDs
 774
 775         $range = $self->{article} unless defined $range;
 776         my $r = get_range($self, $range);
 777         return $r unless ref $r;
 778         my ($beg, $end) = @$r;
 779         my $mm = $ng->mm;
 780         my $srch = $ng->search;
 781         more($self, '224 Overview information follows');
 782         long_response($self, $beg, $end, sub {
 783                 my ($i) = @_;
 784                 my $mid = $mm->mid_for($$i) or return;
 785                 my $h = search_header_for($srch, $mid, 'references');
 786                 more($self, "$$i $h");
 787         });
 788 }
 789
 790 sub over_line ($$) {
 791         my ($num, $smsg) = @_;
 792         # n.b. field access and procedural calls can be
 793         # 10%-15% faster than OO method calls:
 794         join("\t", $num,
 795                 $smsg->{subject},
 796                 $smsg->{from},
 797                 PublicInbox::SearchMsg::date($smsg),
 798                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 799                 $smsg->{references},
 800                 PublicInbox::SearchMsg::bytes($smsg),
 801                 PublicInbox::SearchMsg::lines($smsg));
 802 }
 803
 804 sub cmd_over ($;$) {
 805         my ($self, $range) = @_;
 806         if ($range && $range =~ /\A<(.+)>\z/) {
 807                 my ($ng, $n) = mid_lookup($self, $1);
 808                 my $smsg = $ng->search->lookup_message($range) or
 809                         return '430 No article with that message-id';
 810                 more($self, '224 Overview information follows (multi-line)');
 811                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 812
 813                 # Only set article number column if it's the current group
 814                 my $self_ng = $self->{ng};
 815                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 816                 more($self, over_line($n, $smsg));
 817                 '.';
 818         } else {
 819                 cmd_xover($self, $range);
 820         }
 821 }
 822
 823 sub cmd_xover ($;$) {
 824         my ($self, $range) = @_;
 825         $range = $self->{article} unless defined $range;
 826         my $r = get_range($self, $range);
 827         return $r unless ref $r;
 828         my ($beg, $end) = @$r;
 829         more($self, "224 Overview information follows for $beg to $end");
 830         my $srch = $self->{ng}->search;
 831         my $off = 0;
 832         long_response($self, $beg, $end, sub {
 833                 my ($i) = @_;
 834                 my $res = $srch->query_xover($beg, $end, $off);
 835                 my $msgs = $res->{msgs};
 836                 my $nr = scalar @$msgs or return;
 837                 $off += $nr;
 838
 839                 # OVERVIEW.FMT
 840                 more($self, join("\r\n", map {
 841                         over_line(PublicInbox::SearchMsg::num($_), $_);
 842                         } @$msgs));
 843
 844                 # -1 to adjust for implicit increment in long_response
 845                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 846         });
 847 }
 848
 849 sub cmd_xpath ($$) {
 850         my ($self, $mid) = @_;
 851         return r501 unless $mid =~ /\A<(.+)>\z/;
 852         $mid = $1;
 853         my @paths;
 854         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 855                 my $n = $ng->mm->num_for($mid);
 856                 push @paths, "$ng->{name}/$n" if defined $n;
 857         }
 858         return '430 no such article on server' unless @paths;
 859         '223 '.join(' ', @paths);
 860 }
 861
 862 sub res ($$) {
 863         my ($self, $line) = @_;
 864         do_write($self, $line . "\r\n");
 865 }
 866
 867 sub more ($$) {
 868         my ($self, $line) = @_;
 869         do_more($self, $line . "\r\n");
 870 }
 871
 872 sub do_write ($$) {
 873         my ($self, $data) = @_;
 874         my $done = $self->write($data);
 875         die if $self->{closed};
 876
 877         # Do not watch for readability if we have data in the queue,
 878         # instead re-enable watching for readability when we can
 879         $self->watch_read(0) if (!$done || $self->{long_res});
 880
 881         $done;
 882 }
 883
 884 sub err ($$;@) {
 885         my ($self, $fmt, @args) = @_;
 886         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 887 }
 888
 889 sub out ($$;@) {
 890         my ($self, $fmt, @args) = @_;
 891         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 892 }
 893
 894 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 895
 896 sub do_more ($$) {
 897         my ($self, $data) = @_;
 898         if (MSG_MORE && !$self->{write_buf_size}) {
 899                 my $n = send($self->{sock}, $data, MSG_MORE);
 900                 if (defined $n) {
 901                         my $dlen = length($data);
 902                         return 1 if $n == $dlen; # all done!
 903                         $data = substr($data, $n, $dlen - $n);
 904                 }
 905         }
 906         do_write($self, $data);
 907 }
 908
 909 # callbacks for Danga::Socket
 910
 911 sub event_hup { $_[0]->close }
 912 sub event_err { $_[0]->close }
 913
 914 sub event_write {
 915         my ($self) = @_;
 916         update_idle_time($self);
 917         # only continue watching for readability when we are done writing:
 918         if ($self->write(undef) == 1 && !$self->{long_res}) {
 919                 $self->watch_read(1);
 920         }
 921 }
 922
 923 sub event_read {
 924         my ($self) = @_;
 925         use constant LINE_MAX => 512; # RFC 977 section 2.3
 926         my $r = 1;
 927
 928         my $buf = $self->read(LINE_MAX) or return $self->close;
 929         $self->{rbuf} .= $$buf;
 930         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 931                 my $line = $1;
 932                 my $t0 = now();
 933                 my $fd = $self->{fd};
 934                 $r = eval { process_line($self, $line) };
 935                 my $d = $self->{long_res} ?
 936                         " deferred[$fd]" : '';
 937                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 938         }
 939
 940         return $self->close if $r < 0;
 941         my $len = length($self->{rbuf});
 942         return $self->close if ($len >= LINE_MAX);
 943         update_idle_time($self);
 944 }
 945
 946 sub watch_read {
 947         my ($self, $bool) = @_;
 948         my $rv = $self->SUPER::watch_read($bool);
 949         if ($bool && $self->{rbuf} ne '') {
 950                 # Force another read if there is a pipelined request.
 951                 # We don't know if the socket has anything for us to read,
 952                 # and we must double-check again by the time the timer fires
 953                 # in case we really did dispatch a read event and started
 954                 # another long response.
 955                 Danga::Socket->AddTimer(0, sub {
 956                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 957                                 event_read($self);
 958                         }
 959                 });
 960         }
 961         $rv;
 962 }
 963
 964 # for graceful shutdown in PublicInbox::Daemon:
 965 sub busy () {
 966         my ($self) = @_;
 967         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 968 }
 969
 970 1;