lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime ualarm CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         long_response_limit => 0xffffffff,
  18 };
  19
  20 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  21
  22 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  23 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  24
  25 # disable commands with easy DoS potential:
  26 # LISTGROUP could get pretty bad, too...
  27 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  28
  29 sub new ($$$) {
  30         my ($class, $sock, $nntpd) = @_;
  31         my $self = fields::new($class);
  32         binmode $sock, ':utf8'; # RFC 3977
  33         $self->SUPER::new($sock);
  34         $self->{nntpd} = $nntpd;
  35         res($self, '201 server ready - post via email');
  36         $self->{rbuf} = '';
  37         $self->watch_read(1);
  38         $self;
  39 }
  40
  41 sub args_ok ($$) {
  42         my ($cb, $argc) = @_;
  43         my $tot = prototype $cb;
  44         my ($nreq, undef) = split(';', $tot);
  45         $nreq = ($nreq =~ tr/$//) - 1;
  46         $tot = ($tot =~ tr/$//) - 1;
  47         ($argc <= $tot && $argc >= $nreq);
  48 }
  49
  50 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  51 sub process_line ($$) {
  52         my ($self, $l) = @_;
  53         my ($req, @args) = split(/\s+/, $l);
  54         $req = lc($req);
  55         $req = eval {
  56                 no strict 'refs';
  57                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  58         };
  59         return res($self, '500 command not recognized') unless $req;
  60         return res($self, r501) unless args_ok($req, scalar @args);
  61
  62         my $res = eval { $req->($self, @args) };
  63         my $err = $@;
  64         if ($err && !$self->{closed}) {
  65                 chomp($l = Dumper(\$l));
  66                 err($self, "error from: $l $err");
  67                 $res = '503 program fault - command not performed';
  68         }
  69         return 0 unless defined $res;
  70         res($self, $res);
  71 }
  72
  73 sub cmd_mode ($$) {
  74         my ($self, $arg) = @_;
  75         $arg = uc $arg;
  76         return r501 unless $arg eq 'READER';
  77         '200 reader status acknowledged';
  78 }
  79
  80 sub cmd_slave ($) { '202 slave status noted' }
  81
  82 sub cmd_xgtitle ($;$) {
  83         my ($self, $wildmat) = @_;
  84         more($self, '282 list of groups and descriptions follows');
  85         list_newsgroups($self, $wildmat);
  86         '.'
  87 }
  88
  89 sub list_overview_fmt ($$) {
  90         my ($self) = @_;
  91         more($self, $_ . ':') foreach @OVERVIEW;
  92 }
  93
  94 sub list_active ($;$) {
  95         my ($self, $wildmat) = @_;
  96         wildmat2re($wildmat);
  97         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
  98                 $ng->{name} =~ $wildmat or next;
  99                 group_line($self, $ng);
 100         }
 101 }
 102
 103 sub list_active_times ($;$) {
 104         my ($self, $wildmat) = @_;
 105         wildmat2re($wildmat);
 106         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 107                 $ng->{name} =~ $wildmat or next;
 108                 my $c = eval { $ng->mm->created_at } || time;
 109                 more($self, "$ng->{name} $c $ng->{address}");
 110         }
 111 }
 112
 113 sub list_newsgroups ($;$) {
 114         my ($self, $wildmat) = @_;
 115         wildmat2re($wildmat);
 116         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 117                 $ng->{name} =~ $wildmat or next;
 118                 my $d = $ng->description;
 119                 more($self, "$ng->{name} $d");
 120         }
 121 }
 122
 123 # LIST SUBSCRIPTIONS not supported
 124 sub cmd_list ($;$$) {
 125         my ($self, @args) = @_;
 126         if (scalar @args) {
 127                 my $arg = shift @args;
 128                 $arg =~ tr/A-Z./a-z_/;
 129                 $arg = "list_$arg";
 130                 return '503 function not performed' if $DISABLED{$arg};
 131
 132                 $arg = eval {
 133                         no strict 'refs';
 134                         *{$arg}{CODE};
 135                 };
 136                 return r501 unless $arg && args_ok($arg, scalar @args);
 137                 more($self, '215 information follows');
 138                 $arg->($self, @args);
 139         } else {
 140                 more($self, '215 list of newsgroups follows');
 141                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 142                         group_line($self, $ng);
 143                 }
 144         }
 145         '.'
 146 }
 147
 148 sub cmd_listgroup ($;$) {
 149         my ($self, $group) = @_;
 150         if (defined $group) {
 151                 my $res = cmd_group($self, $group);
 152                 return $res if ($res !~ /\A211 /);
 153                 more($self, $res);
 154         }
 155
 156         $self->{ng} or return '412 no newsgroup selected';
 157         $self->long_response(0, long_response_limit, sub {
 158                 my ($i) = @_;
 159                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 160                         my ($ary) = @_;
 161                         more($self, join("\r\n", @$ary));
 162                 });
 163
 164                 # -1 to adjust for implicit increment in long_response
 165                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 166         });
 167 }
 168
 169 sub parse_time ($$;$) {
 170         my ($date, $time, $gmt) = @_;
 171         use Time::Local qw();
 172         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 173         if (defined $gmt) {
 174                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 175                 $gmt = 1;
 176         }
 177         my @now = $gmt ? gmtime : localtime;
 178         my ($YYYY, $MM, $DD);
 179         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 180                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 181         } else { # legacy clients send YYMMDD
 182                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 183                 if ($YYYY > strftime('%y', @now)) {
 184                         my $cur_year = $now[5] + 1900;
 185                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 186                 }
 187         }
 188         if ($gmt) {
 189                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 190         } else {
 191                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 192         }
 193 }
 194
 195 sub group_line ($$) {
 196         my ($self, $ng) = @_;
 197         my ($min, $max) = $ng->mm->minmax;
 198         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 199 }
 200
 201 sub cmd_newgroups ($$$;$$) {
 202         my ($self, $date, $time, $gmt, $dists) = @_;
 203         my $ts = eval { parse_time($date, $time, $gmt) };
 204         return r501 if $@;
 205
 206         # TODO dists
 207         more($self, '231 list of new newsgroups follows');
 208         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 209                 my $c = eval { $ng->mm->created_at } || 0;
 210                 next unless $c > $ts;
 211                 group_line($self, $ng);
 212         }
 213         '.'
 214 }
 215
 216 sub wildmat2re (;$) {
 217         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 218         my %keep;
 219         my $salt = rand;
 220         use Digest::SHA qw(sha1_hex);
 221         my $tmp = $_[0];
 222
 223         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 224                 my $orig = $1;
 225                 my $key = sha1_hex($orig . $salt);
 226                 $orig =~ s/([^\w\-])+/\Q$1/g;
 227                 $keep{$key} = $orig;
 228                 $key
 229                 #gex;
 230         my %map = ('*' => '.*', '?' => '.' );
 231         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 232         if (scalar %keep) {
 233                 $tmp =~ s#([a-f0-9]{40})#
 234                         my $orig = $keep{$1};
 235                         defined $orig ? $orig : $1;
 236                         #ge;
 237         }
 238         $_[0] = qr/\A$tmp\z/;
 239 }
 240
 241 sub ngpat2re (;$) {
 242         return $_[0] = qr/\A\z/ unless defined $_[0];
 243         my %map = ('*' => '.*', ',' => '|');
 244         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 245         $_[0] = qr/\A(?:$_[0])\z/;
 246 }
 247
 248 sub cmd_newnews ($$$$;$$) {
 249         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 250         my $ts = eval { parse_time($date, $time, $gmt) };
 251         return r501 if $@;
 252         more($self, '230 list of new articles by message-id follows');
 253         my ($keep, $skip) = split('!', $newsgroups, 2);
 254         ngpat2re($keep);
 255         ngpat2re($skip);
 256         my @srch;
 257         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 258                 $ng->{name} =~ $keep or next;
 259                 $ng->{name} =~ $skip and next;
 260                 my $srch = $ng->search or next;
 261                 push @srch, $srch;
 262         };
 263         return '.' unless @srch;
 264
 265         $ts .= '..';
 266         my $opts = { asc => 1, limit => 1000, offset => 0 };
 267         $self->long_response(0, long_response_limit, sub {
 268                 my ($i) = @_;
 269                 my $srch = $srch[0];
 270                 my $res = $srch->query($ts, $opts);
 271                 my $msgs = $res->{msgs};
 272                 if (my $nr = scalar @$msgs) {
 273                         more($self, '<' .
 274                                 join(">\r\n<", map { $_->mid } @$msgs ).
 275                                 '>');
 276                         $opts->{offset} += $nr;
 277                 } else {
 278                         shift @srch;
 279                         if (@srch) { # continue onto next newsgroup
 280                                 $opts->{offset} = 0;
 281                         } else { # break out of the long response.
 282                                 $$i = long_response_limit;
 283                         }
 284                 }
 285         });
 286 }
 287
 288 sub cmd_group ($$) {
 289         my ($self, $group) = @_;
 290         my $no_such = '411 no such news group';
 291         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 292
 293         $self->{ng} = $ng;
 294         my ($min, $max) = $ng->mm->minmax;
 295         $min ||= 0;
 296         $max ||= 0;
 297         $self->{article} = $min;
 298         my $est_size = $max - $min;
 299         "211 $est_size $min $max $group";
 300 }
 301
 302 sub article_adj ($$) {
 303         my ($self, $off) = @_;
 304         my $ng = $self->{ng} or return '412 no newsgroup selected';
 305
 306         my $n = $self->{article};
 307         defined $n or return '420 no current article has been selected';
 308
 309         $n += $off;
 310         my $mid = $ng->mm->mid_for($n);
 311         unless ($mid) {
 312                 $n = $off > 0 ? 'next' : 'previous';
 313                 return "421 no $n article in this group";
 314         }
 315         $self->{article} = $n;
 316         "223 $n <$mid> article retrieved - request text separately";
 317 }
 318
 319 sub cmd_next ($) { article_adj($_[0], 1) }
 320 sub cmd_last ($) { article_adj($_[0], -1) }
 321
 322 # We want to encourage using email and CC-ing everybody involved to avoid
 323 # the single-point-of-failure a single server provides.
 324 sub cmd_post ($) {
 325         my ($self) = @_;
 326         my $ng = $self->{ng};
 327         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 328 }
 329
 330 sub cmd_quit ($) {
 331         my ($self) = @_;
 332         res($self, '205 closing connection - goodbye!');
 333         $self->close;
 334         undef;
 335 }
 336
 337 sub art_lookup ($$$) {
 338         my ($self, $art, $set_headers) = @_;
 339         my $ng = $self->{ng};
 340         my ($n, $mid);
 341         my $err;
 342         if (defined $art) {
 343                 if ($art =~ /\A\d+\z/o) {
 344                         $err = '423 no such article number in this group';
 345                         $n = int($art);
 346                         goto find_mid;
 347                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 348                         $mid = $1;
 349                         $err = '430 no such article found';
 350                         $n = $ng->mm->num_for($mid) if $ng;
 351                         goto found if defined $n;
 352                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 353                                 $n = $g->mm->num_for($mid);
 354                                 if (defined $n) {
 355                                         $ng = $g;
 356                                         goto found;
 357                                 }
 358                         }
 359                         return $err;
 360                 } else {
 361                         return r501;
 362                 }
 363         } else {
 364                 $err = '420 no current article has been selected';
 365                 $n = $self->{article};
 366                 defined $n or return $err;
 367 find_mid:
 368                 $ng or return '412 no newsgroup has been selected';
 369                 $mid = $ng->mm->mid_for($n);
 370                 defined $mid or return $err;
 371         }
 372 found:
 373         my $o = 'HEAD:' . mid2path($mid);
 374         my $bytes;
 375         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 376         return $err unless $s;
 377         if ($set_headers) {
 378                 $s->header_set('Newsgroups', $ng->{name});
 379                 $s->header_set('Lines', $s->body =~ tr!\n!\n!);
 380                 $s->header_set('Xref', xref($ng, $n));
 381
 382                 # must be last
 383                 if ($set_headers == 2) {
 384                         $s->header_set('Bytes', $bytes);
 385                         $s->body_set('');
 386                 }
 387         }
 388         [ $n, $mid, $s ];
 389 }
 390
 391 sub simple_body_write ($$) {
 392         my ($self, $s) = @_;
 393         my $body = $s->body;
 394         $s->body_set('');
 395         $body =~ s/^\./../smg;
 396         $body =~ s/(?<!\r)\n/\r\n/sg;
 397         do_more($self, $body);
 398         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 399         '.'
 400 }
 401
 402 sub header_str ($) {
 403         my ($s) = @_;
 404         my $h = $s->header_obj;
 405         $h->header_set('Bytes');
 406         $h->as_string
 407 }
 408
 409 sub set_art {
 410         my ($self, $art) = @_;
 411         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 412 }
 413
 414 sub cmd_article ($;$) {
 415         my ($self, $art) = @_;
 416         my $r = $self->art_lookup($art, 1);
 417         return $r unless ref $r;
 418         my ($n, $mid, $s) = @$r;
 419         set_art($self, $art);
 420         more($self, "220 $n <$mid> article retrieved - head and body follow");
 421         do_more($self, header_str($s));
 422         do_more($self, "\r\n");
 423         simple_body_write($self, $s);
 424 }
 425
 426 sub cmd_head ($;$) {
 427         my ($self, $art) = @_;
 428         my $r = $self->art_lookup($art, 2);
 429         return $r unless ref $r;
 430         my ($n, $mid, $s) = @$r;
 431         set_art($self, $art);
 432         more($self, "221 $n <$mid> article retrieved - head follows");
 433         do_more($self, header_str($s));
 434         '.'
 435 }
 436
 437 sub cmd_body ($;$) {
 438         my ($self, $art) = @_;
 439         my $r = $self->art_lookup($art, 0);
 440         return $r unless ref $r;
 441         my ($n, $mid, $s) = @$r;
 442         set_art($self, $art);
 443         more($self, "222 $n <$mid> article retrieved - body follows");
 444         simple_body_write($self, $s);
 445 }
 446
 447 sub cmd_stat ($;$) {
 448         my ($self, $art) = @_;
 449         my $r = $self->art_lookup($art, 0);
 450         return $r unless ref $r;
 451         my ($n, $mid, undef) = @$r;
 452         set_art($self, $art);
 453         "223 $n <$mid> article retrieved - request text separately";
 454 }
 455
 456 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 457
 458 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 459
 460 sub cmd_help ($) {
 461         my ($self) = @_;
 462         more($self, '100 help text follows');
 463         '.'
 464 }
 465
 466 sub get_range ($$) {
 467         my ($self, $range) = @_;
 468         my $ng = $self->{ng} or return '412 no news group has been selected';
 469         defined $range or return '420 No article(s) selected';
 470         my ($beg, $end);
 471         my ($min, $max) = $ng->mm->minmax;
 472         if ($range =~ /\A(\d+)\z/) {
 473                 $beg = $end = $1;
 474         } elsif ($range =~ /\A(\d+)-\z/) {
 475                 ($beg, $end) = ($1, $max);
 476         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 477                 ($beg, $end) = ($1, $2);
 478         } else {
 479                 return r501;
 480         }
 481         $beg = $min if ($beg < $min);
 482         $end = $max if ($end > $max);
 483         return '420 No article(s) selected' if ($beg > $end);
 484         [ $beg, $end ];
 485 }
 486
 487 sub xhdr ($$) {
 488         my ($r, $header) = @_;
 489         $r = $r->[2]->header_obj->header($header);
 490         defined $r or return;
 491         $r =~ s/[\r\n\t]+/ /sg;
 492         $r;
 493 }
 494
 495 sub long_response ($$$$) {
 496         my ($self, $beg, $end, $cb) = @_;
 497         die "BUG: nested long response" if $self->{long_res};
 498
 499         # make sure we disable reading during a long response,
 500         # clients should not be sending us stuff and making us do more
 501         # work while we are stream a response to them
 502         $self->watch_read(0);
 503         my $fd = fileno $self->{sock};
 504         my $t0 = now();
 505         $self->{long_res} = sub {
 506                 # limit our own running time for fairness with other
 507                 # clients and to avoid buffering too much:
 508                 my $yield;
 509                 local $SIG{ALRM} = sub { $yield = 1 };
 510                 ualarm(100000);
 511
 512                 my $err;
 513                 do {
 514                         eval { $cb->(\$beg) };
 515                 } until (($err = $@) || $self->{closed} || $yield ||
 516                          $self->{write_buf_size} || ++$beg > $end);
 517                 ualarm(0);
 518
 519                 if ($err || $self->{closed}) {
 520                         $self->{long_res} = undef;
 521
 522                         if ($err) {
 523                                 err($self,
 524                                     "$err during long response[$fd] - %0.6f",
 525                                         now() - $t0);
 526                         }
 527                         if ($self->{closed}) {
 528                                 out($self, " deferred[$fd] aborted - %0.6f",
 529                                            now() - $t0);
 530                         } else {
 531                                 $self->watch_read(1);
 532                         }
 533                 } elsif ($yield || $self->{write_buf_size}) {
 534                         # no recursion, schedule another call ASAP
 535                         # but only after all pending writes are done
 536                         Danga::Socket->AddTimer(0, sub {
 537                                 $self->write($self->{long_res});
 538                         });
 539                 } else { # all done!
 540                         $self->{long_res} = undef;
 541                         $self->watch_read(1);
 542                         res($self, '.');
 543                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 544                 }
 545         };
 546         $self->{long_res}->(); # kick off!
 547         undef;
 548 }
 549
 550 sub xhdr_message_id ($$) { # optimize XHDR Message-ID [range] for slrnpull.
 551         my ($self, $range) = @_;
 552
 553         my $mm = $self->{ng}->mm;
 554         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 555                 my $n = $mm->num_for($range);
 556                 more($self, '221 Header follows');
 557                 more($self, "<$range> <$range>") if defined $n;
 558                 '.';
 559         } else { # numeric range
 560                 $range = $self->{article} unless defined $range;
 561                 my $r = get_range($self, $range);
 562                 return $r unless ref $r;
 563                 my ($beg, $end) = @$r;
 564                 more($self, '221 Header follows');
 565                 $self->long_response($beg, $end, sub {
 566                         my ($i) = @_;
 567                         my $mid = $mm->mid_for($$i);
 568                         more($self, "$$i <$mid>") if defined $mid;
 569                 });
 570         }
 571 }
 572
 573 sub xref ($$) {
 574         my ($ng, $n) = @_;
 575         "$ng->{domain} $ng->{name}:$n"
 576 }
 577
 578 sub xhdr_xref ($$) { # optimize XHDR Xref [range] for rtin
 579         my ($self, $range) = @_;
 580
 581         my $ng = $self->{ng};
 582         my $mm = $ng->mm;
 583         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 584                 my $n = $mm->num_for($range);
 585                 more($self, '221 Header follows');
 586                 more($self, "<$range> ".xref($ng, $n)) if defined $n;
 587                 '.';
 588         } else { # numeric range
 589                 $range = $self->{article} unless defined $range;
 590                 my $r = get_range($self, $range);
 591                 return $r unless ref $r;
 592                 my ($beg, $end) = @$r;
 593                 more($self, '221 Header follows');
 594                 $self->long_response($beg, $end, sub {
 595                         my ($i) = @_;
 596                         my $mid = $mm->mid_for($$i);
 597                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 598                 });
 599         }
 600 }
 601
 602 sub header_obj_for {
 603         my ($srch, $mid) = @_;
 604         eval {
 605                 my $smsg = $srch->lookup_message($mid);
 606                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 607                 $smsg->mini_mime->header_obj;
 608         };
 609 };
 610
 611 sub xhdr_searchmsg ($$$) {
 612         my ($self, $sub, $range) = @_;
 613         my $srch = $self->{ng}->search;
 614         my $emit = ($sub eq 'date') ? sub {
 615                 my ($pfx, $m) = @_;
 616                 my @t = gmtime($m->header('X-PI-TS'));
 617                 more($self, "$pfx ". strftime('%a, %d %b %Y %T %z', @t));
 618         } : sub {
 619                 my ($pfx, $m) = @_;
 620                 my $h = $m->header($sub);
 621                 more($self, "$pfx $h") if defined $h;
 622         };
 623
 624         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 625                 more($self, '221 Header follows');
 626                 my $m = header_obj_for($srch, $1);
 627                 $emit->($range, $m) if defined $m;
 628                 '.';
 629         } else { # numeric range
 630                 $range = $self->{article} unless defined $range;
 631                 my $mm = $self->{ng}->mm;
 632                 my $r = get_range($self, $range);
 633                 return $r unless ref $r;
 634                 my ($beg, $end) = @$r;
 635                 more($self, '221 Header follows');
 636                 $self->long_response($beg, $end, sub {
 637                         my ($i) = @_;
 638                         my $mid = $mm->mid_for($$i) or return;
 639                         my $m = header_obj_for($srch, $mid) or return;
 640                         $emit->($$i, $m);
 641                 });
 642         }
 643 }
 644
 645 sub cmd_xhdr ($$;$) {
 646         my ($self, $header, $range) = @_;
 647         my $ng = $self->{ng};
 648         defined $ng or return '412 no news group currently selected';
 649         my $sub = lc $header;
 650         if ($sub eq 'message-id') {
 651                 xhdr_message_id($self, $range);
 652         } elsif ($sub eq 'xref') {
 653                 xhdr_xref($self, $range);
 654         } elsif ($sub =~ /\A(subject|references|date)\z/ && $ng->search) {
 655                 xhdr_searchmsg($self, $sub, $range);
 656         } else {
 657                 xhdr_slow($self, $header, $range);
 658         }
 659 }
 660
 661 sub xhdr_slow ($$$) {
 662         my ($self, $header, $range) = @_;
 663
 664         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 665                 my $r = $self->art_lookup($range, 2);
 666                 return $r unless ref $r;
 667                 more($self, '221 Header follows');
 668                 if (defined($r = xhdr($r, $header))) {
 669                         more($self, "<$range> $r");
 670                 }
 671                 '.';
 672         } else { # numeric range
 673                 $range = $self->{article} unless defined $range;
 674                 my $r = get_range($self, $range);
 675                 return $r unless ref $r;
 676                 my ($beg, $end) = @$r;
 677                 more($self, '221 Header follows');
 678                 $self->long_response($beg, $end, sub {
 679                         my ($i) = @_;
 680                         $r = $self->art_lookup($$i, 2);
 681                         return unless ref $r;
 682                         defined($r = xhdr($r, $header)) or return;
 683                         more($self, "$$i $r");
 684                 });
 685         }
 686 }
 687
 688 sub cmd_xrover ($;$) {
 689         my ($self, $range) = @_;
 690         my $ng = $self->{ng} or return '412 no newsgroup selected';
 691         (defined $range && $range =~ /[<>]/) and
 692                 return '420 No article(s) selected'; # no message IDs
 693
 694         $range = $self->{article} unless defined $range;
 695         my $r = get_range($self, $range);
 696         return $r unless ref $r;
 697         my ($beg, $end) = @$r;
 698         my $mm = $ng->mm;
 699         my $srch = $ng->search;
 700         more($self, '224 Overview information follows');
 701         $self->long_response($beg, $end, sub {
 702                 my ($i) = @_;
 703                 my $mid = $mm->mid_for($$i) or return;
 704                 my $m = header_obj_for($srch, $mid) or return;
 705                 my $h = $m->header('references');
 706                 more($self, "$$i $h") if defined $h;
 707         });
 708 }
 709
 710 sub cmd_xover ($;$) {
 711         my ($self, $range) = @_;
 712         $range = $self->{article} unless defined $range;
 713         my $r = get_range($self, $range);
 714         return $r unless ref $r;
 715         my ($beg, $end) = @$r;
 716         more($self, "224 Overview information follows for $beg to $end");
 717         $self->long_response($beg, $end, sub {
 718                 my ($i) = @_;
 719                 my $r = $self->art_lookup($$i, 2);
 720                 return unless ref $r;
 721                 more($self, join("\t", $r->[0],
 722                                 map {
 723                                         my $h = xhdr($r, $_);
 724                                         defined $h ? $h : '';
 725                                 } @OVERVIEW ));
 726         });
 727 }
 728
 729 sub cmd_xpath ($$) {
 730         my ($self, $mid) = @_;
 731         return r501 unless $mid =~ /\A<(.+)>\z/;
 732         $mid = $1;
 733         my @paths;
 734         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 735                 my $n = $ng->mm->num_for($mid);
 736                 push @paths, "$ng->{name}/$n" if defined $n;
 737         }
 738         return '430 no such article on server' unless @paths;
 739         '223 '.join(' ', @paths);
 740 }
 741
 742 sub res ($$) {
 743         my ($self, $line) = @_;
 744         do_write($self, $line . "\r\n");
 745 }
 746
 747 sub more ($$) {
 748         my ($self, $line) = @_;
 749         do_more($self, $line . "\r\n");
 750 }
 751
 752 sub do_write ($$) {
 753         my ($self, $data) = @_;
 754         my $done = $self->write($data);
 755         die if $self->{closed};
 756
 757         # Do not watch for readability if we have data in the queue,
 758         # instead re-enable watching for readability when we can
 759         $self->watch_read(0) if (!$done || $self->{long_res});
 760
 761         $done;
 762 }
 763
 764 sub err ($$;@) {
 765         my ($self, $fmt, @args) = @_;
 766         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 767 }
 768
 769 sub out ($$;@) {
 770         my ($self, $fmt, @args) = @_;
 771         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 772 }
 773
 774 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 775
 776 sub do_more ($$) {
 777         my ($self, $data) = @_;
 778         if (MSG_MORE && !$self->{write_buf_size}) {
 779                 my $n = send($self->{sock}, $data, MSG_MORE);
 780                 if (defined $n) {
 781                         my $dlen = length($data);
 782                         return 1 if $n == $dlen; # all done!
 783                         $data = substr($data, $n, $dlen - $n);
 784                 }
 785         }
 786         $self->do_write($data);
 787 }
 788
 789 # callbacks for by Danga::Socket
 790
 791 sub event_hup { $_[0]->close }
 792 sub event_err { $_[0]->close }
 793
 794 sub event_write {
 795         my ($self) = @_;
 796         # only continue watching for readability when we are done writing:
 797         if ($self->write(undef) == 1 && !$self->{long_res}) {
 798                 $self->watch_read(1);
 799         }
 800 }
 801
 802 sub event_read {
 803         my ($self) = @_;
 804         use constant LINE_MAX => 512; # RFC 977 section 2.3
 805         my $line;
 806         my $r = 1;
 807 again:
 808         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 809                 $line = $1;
 810                 my $t0 = now();
 811                 $r = eval { $self->process_line($line) };
 812                 my $d = $self->{long_res} ?
 813                         ' deferred['.fileno($self->{sock}).']' : '';
 814                 out($self, "$line - %0.6f$d", now() - $t0);
 815         }
 816         unless (defined $line) {
 817                 my $buf = $self->read(LINE_MAX) or return $self->close;
 818                 $self->{rbuf} .= $$buf;
 819                 goto again;
 820         }
 821
 822         return $self->close if $r < 0;
 823         my $len = length($self->{rbuf});
 824         return $self->close if ($len >= LINE_MAX);
 825 }
 826
 827 sub watch_read {
 828         my ($self, $bool) = @_;
 829         my $rv = $self->SUPER::watch_read($bool);
 830         if ($bool && $self->{rbuf} ne '') {
 831                 # Force another read if there is a pipelined request.
 832                 # We don't know if the socket has anything for us to read,
 833                 # and we must double-check again by the time the timer fires
 834                 # in case we really did dispatch a read event and started
 835                 # another long response.
 836                 Danga::Socket->AddTimer(0, sub {
 837                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 838                                 $self->event_read;
 839                         }
 840                 });
 841         }
 842         $rv;
 843 }
 844
 845 1;