lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use PublicInbox::DS qw(now);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45
  46 my $have_deflate;
  47 my $EXPMAP; # fd -> [ idle_time, $self ]
  48 my $expt;
  49 our $EXPTIME = 180; # 3 minutes
  50
  51 sub update_idle_time ($) {
  52         my ($self) = @_;
  53         my $sock = $self->{sock} or return;
  54         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  55 }
  56
  57 sub expire_old () {
  58         my $now = now();
  59         my $exp = $EXPTIME;
  60         my $old = $now - $exp;
  61         my %new;
  62         while (my ($fd, $v) = each %$EXPMAP) {
  63                 my ($idle_time, $nntp) = @$v;
  64                 if ($idle_time < $old) {
  65                         if (!$nntp->shutdn) {
  66                                 $new{$fd} = $v;
  67                         }
  68                 } else {
  69                         $new{$fd} = $v;
  70                 }
  71         }
  72         $EXPMAP = \%new;
  73         $expt = scalar(keys %new) ? PublicInbox::EvCleanup::later(*expire_old)
  74                                   : undef;
  75 }
  76
  77 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  78
  79 sub new ($$$) {
  80         my ($class, $sock, $nntpd) = @_;
  81         my $self = fields::new($class);
  82         my $ev = EPOLLIN;
  83         my $wbuf;
  84         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  85                 return CORE::close($sock) if $! != EAGAIN;
  86                 $ev = PublicInbox::TLS::epollbit();
  87                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  88         }
  89         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  90         $self->{nntpd} = $nntpd;
  91         if ($wbuf) {
  92                 $self->{wbuf} = $wbuf;
  93         } else {
  94                 greet($self);
  95         }
  96         update_idle_time($self);
  97         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  98         $self;
  99 }
 100
 101 sub args_ok ($$) {
 102         my ($cb, $argc) = @_;
 103         my $tot = prototype $cb;
 104         my ($nreq, undef) = split(';', $tot);
 105         $nreq = ($nreq =~ tr/$//) - 1;
 106         $tot = ($tot =~ tr/$//) - 1;
 107         ($argc <= $tot && $argc >= $nreq);
 108 }
 109
 110 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 111 sub process_line ($$) {
 112         my ($self, $l) = @_;
 113         my ($req, @args) = split(/[ \t]/, $l);
 114         return 1 unless defined($req); # skip blank line
 115         $req = eval {
 116                 no strict 'refs';
 117                 *{'cmd_'.lc($req)}{CODE};
 118         };
 119         return res($self, '500 command not recognized') unless $req;
 120         return res($self, r501) unless args_ok($req, scalar @args);
 121
 122         my $res = eval { $req->($self, @args) };
 123         my $err = $@;
 124         if ($err && $self->{sock}) {
 125                 local $/ = "\n";
 126                 chomp($l);
 127                 err($self, 'error from: %s (%s)', $l, $err);
 128                 $res = '503 program fault - command not performed';
 129         }
 130         return 0 unless defined $res;
 131         res($self, $res);
 132 }
 133
 134 # The keyword argument is not used (rfc3977 5.2.2)
 135 sub cmd_capabilities ($;$) {
 136         my ($self, undef) = @_;
 137         my $res = $CAPABILITIES;
 138         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 139                         $self->{nntpd}->{accept_tls}) {
 140                 $res .= "STARTTLS\r\n";
 141         }
 142         $res .= '.';
 143 }
 144
 145 sub cmd_mode ($$) {
 146         my ($self, $arg) = @_;
 147         $arg = uc $arg;
 148         return r501 unless $arg eq 'READER';
 149         '201 Posting prohibited';
 150 }
 151
 152 sub cmd_slave ($) { '202 slave status noted' }
 153
 154 sub cmd_xgtitle ($;$) {
 155         my ($self, $wildmat) = @_;
 156         more($self, '282 list of groups and descriptions follows');
 157         list_newsgroups($self, $wildmat);
 158         '.'
 159 }
 160
 161 sub list_overview_fmt ($) {
 162         my ($self) = @_;
 163         $self->msg_more($OVERVIEW_FMT);
 164 }
 165
 166 sub list_headers ($;$) {
 167         my ($self) = @_;
 168         $self->msg_more($LIST_HEADERS);
 169 }
 170
 171 sub list_active ($;$) {
 172         my ($self, $wildmat) = @_;
 173         wildmat2re($wildmat);
 174         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 175                 $ng->{newsgroup} =~ $wildmat or next;
 176                 group_line($self, $ng);
 177         }
 178 }
 179
 180 sub list_active_times ($;$) {
 181         my ($self, $wildmat) = @_;
 182         wildmat2re($wildmat);
 183         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 184                 $ng->{newsgroup} =~ $wildmat or next;
 185                 my $c = eval { $ng->mm->created_at } || time;
 186                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 187         }
 188 }
 189
 190 sub list_newsgroups ($;$) {
 191         my ($self, $wildmat) = @_;
 192         wildmat2re($wildmat);
 193         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 194                 $ng->{newsgroup} =~ $wildmat or next;
 195                 my $d = $ng->description;
 196                 more($self, "$ng->{newsgroup} $d");
 197         }
 198 }
 199
 200 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 201 sub cmd_list ($;$$) {
 202         my ($self, @args) = @_;
 203         if (scalar @args) {
 204                 my $arg = shift @args;
 205                 $arg =~ tr/A-Z./a-z_/;
 206                 $arg = "list_$arg";
 207
 208                 $arg = eval {
 209                         no strict 'refs';
 210                         *{$arg}{CODE};
 211                 };
 212                 return r501 unless $arg && args_ok($arg, scalar @args);
 213                 more($self, '215 information follows');
 214                 $arg->($self, @args);
 215         } else {
 216                 more($self, '215 list of newsgroups follows');
 217                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 218                         group_line($self, $ng);
 219                 }
 220         }
 221         '.'
 222 }
 223
 224 sub cmd_listgroup ($;$$) {
 225         my ($self, $group, $range) = @_;
 226         if (defined $group) {
 227                 my $res = cmd_group($self, $group);
 228                 return $res if ($res !~ /\A211 /);
 229                 more($self, $res);
 230         }
 231         my $ng = $self->{ng} or return '412 no newsgroup selected';
 232         my $mm = $ng->mm;
 233         if (defined $range) {
 234                 my $r = get_range($self, $range);
 235                 return $r unless ref $r;
 236                 my ($beg, $end) = @$r;
 237                 long_response($self, sub {
 238                         $r = $mm->msg_range(\$beg, $end, 'num');
 239                         scalar(@$r) or return;
 240                         more($self, join("\r\n", map { $_->[0] } @$r));
 241                         1;
 242                 });
 243         } else { # grab every article number
 244                 my $n = 0;
 245                 long_response($self, sub {
 246                         my $ary = $mm->ids_after(\$n);
 247                         scalar(@$ary) or return;
 248                         more($self, join("\r\n", @$ary));
 249                         1;
 250                 });
 251         }
 252 }
 253
 254 sub parse_time ($$;$) {
 255         my ($date, $time, $gmt) = @_;
 256         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 257         if (defined $gmt) {
 258                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 259                 $gmt = 1;
 260         }
 261         my @now = $gmt ? gmtime : localtime;
 262         my ($YYYY, $MM, $DD);
 263         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 264                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 265         } else { # legacy clients send YYMMDD
 266                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 267                 my $cur_year = $now[5] + 1900;
 268                 if ($YYYY > $cur_year) {
 269                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 270                 }
 271         }
 272         if ($gmt) {
 273                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 274         } else {
 275                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 276         }
 277 }
 278
 279 sub group_line ($$) {
 280         my ($self, $ng) = @_;
 281         my ($min, $max) = $ng->mm->minmax;
 282         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 283 }
 284
 285 sub cmd_newgroups ($$$;$$) {
 286         my ($self, $date, $time, $gmt, $dists) = @_;
 287         my $ts = eval { parse_time($date, $time, $gmt) };
 288         return r501 if $@;
 289
 290         # TODO dists
 291         more($self, '231 list of new newsgroups follows');
 292         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 293                 my $c = eval { $ng->mm->created_at } || 0;
 294                 next unless $c > $ts;
 295                 group_line($self, $ng);
 296         }
 297         '.'
 298 }
 299
 300 sub wildmat2re (;$) {
 301         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 302         my %keep;
 303         my $salt = rand;
 304         my $tmp = $_[0];
 305
 306         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 307                 my $orig = $1;
 308                 my $key = sha1_hex($orig . $salt);
 309                 $orig =~ s/([^\w\-])+/\Q$1/g;
 310                 $keep{$key} = $orig;
 311                 $key
 312                 #gex;
 313         my %map = ('*' => '.*', '?' => '.' );
 314         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 315         if (scalar %keep) {
 316                 $tmp =~ s#([a-f0-9]{40})#
 317                         my $orig = $keep{$1};
 318                         defined $orig ? $orig : $1;
 319                         #ge;
 320         }
 321         $_[0] = qr/\A$tmp\z/;
 322 }
 323
 324 sub ngpat2re (;$) {
 325         return $_[0] = qr/\A\z/ unless defined $_[0];
 326         my %map = ('*' => '.*', ',' => '|');
 327         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 328         $_[0] = qr/\A(?:$_[0])\z/;
 329 }
 330
 331 sub cmd_newnews ($$$$;$$) {
 332         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 333         my $ts = eval { parse_time($date, $time, $gmt) };
 334         return r501 if $@;
 335         more($self, '230 list of new articles by message-id follows');
 336         my ($keep, $skip) = split('!', $newsgroups, 2);
 337         ngpat2re($keep);
 338         ngpat2re($skip);
 339         my @over;
 340         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 341                 $ng->{newsgroup} =~ $keep or next;
 342                 $ng->{newsgroup} =~ $skip and next;
 343                 my $over = $ng->over or next;
 344                 push @over, $over;
 345         };
 346         return '.' unless @over;
 347
 348         my $prev = 0;
 349         long_response($self, sub {
 350                 my $over = $over[0];
 351                 my $msgs = $over->query_ts($ts, $prev);
 352                 if (scalar @$msgs) {
 353                         more($self, '<' .
 354                                 join(">\r\n<", map { $_->mid } @$msgs ).
 355                                 '>');
 356                         $prev = $msgs->[-1]->{num};
 357                 } else {
 358                         shift @over;
 359                         if (@over) { # continue onto next newsgroup
 360                                 $prev = 0;
 361                                 return 1;
 362                         } else { # break out of the long response.
 363                                 return;
 364                         }
 365                 }
 366         });
 367 }
 368
 369 sub cmd_group ($$) {
 370         my ($self, $group) = @_;
 371         my $no_such = '411 no such news group';
 372         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 373
 374         $self->{ng} = $ng;
 375         my ($min, $max) = $ng->mm->minmax;
 376         $min ||= 0;
 377         $max ||= 0;
 378         $self->{article} = $min;
 379         my $est_size = $max - $min;
 380         "211 $est_size $min $max $group";
 381 }
 382
 383 sub article_adj ($$) {
 384         my ($self, $off) = @_;
 385         my $ng = $self->{ng} or return '412 no newsgroup selected';
 386
 387         my $n = $self->{article};
 388         defined $n or return '420 no current article has been selected';
 389
 390         $n += $off;
 391         my $mid = $ng->mm->mid_for($n);
 392         unless ($mid) {
 393                 $n = $off > 0 ? 'next' : 'previous';
 394                 return "421 no $n article in this group";
 395         }
 396         $self->{article} = $n;
 397         "223 $n <$mid> article retrieved - request text separately";
 398 }
 399
 400 sub cmd_next ($) { article_adj($_[0], 1) }
 401 sub cmd_last ($) { article_adj($_[0], -1) }
 402
 403 # We want to encourage using email and CC-ing everybody involved to avoid
 404 # the single-point-of-failure a single server provides.
 405 sub cmd_post ($) {
 406         my ($self) = @_;
 407         my $ng = $self->{ng};
 408         $ng ? "440 mailto:$ng->{-primary_address} to post"
 409                 : '440 posting not allowed'
 410 }
 411
 412 sub cmd_quit ($) {
 413         my ($self) = @_;
 414         res($self, '205 closing connection - goodbye!');
 415         $self->shutdn;
 416         undef;
 417 }
 418
 419 sub header_append ($$$) {
 420         my ($hdr, $k, $v) = @_;
 421         my @v = $hdr->header($k);
 422         foreach (@v) {
 423                 return if $v eq $_;
 424         }
 425         $hdr->header_set($k, @v, $v);
 426 }
 427
 428 sub xref ($$$$) {
 429         my ($self, $ng, $n, $mid) = @_;
 430         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 431
 432         # num_for is pretty cheap and sometimes we'll lookup the existence
 433         # of an article without getting even the OVER info.  In other words,
 434         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 435         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 436         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 437                 next if $ng eq $other;
 438                 my $num = eval { $other->mm->num_for($mid) } or next;
 439                 $ret .= " $other->{newsgroup}:$num";
 440         }
 441         $ret;
 442 }
 443
 444 sub set_nntp_headers ($$$$$) {
 445         my ($self, $hdr, $ng, $n, $mid) = @_;
 446
 447         # why? leafnode requires a Path: header for some inexplicable
 448         # reason.  We'll fake the shortest one possible.
 449         $hdr->header_set('Path', 'y');
 450
 451         # leafnode (and maybe other NNTP clients) have trouble dealing
 452         # with v2 messages which have multiple Message-IDs (either due
 453         # to our own content-based dedupe or buggy git-send-email versions).
 454         my @mids = $hdr->header('Message-ID');
 455         if (scalar(@mids) > 1) {
 456                 my $mid0 = "<$mid>";
 457                 $hdr->header_set('Message-ID', $mid0);
 458                 my @alt = $hdr->header('X-Alt-Message-ID');
 459                 my %seen = map { $_ => 1 } (@alt, $mid0);
 460                 foreach my $m (@mids) {
 461                         next if $seen{$m}++;
 462                         push @alt, $m;
 463                 }
 464                 $hdr->header_set('X-Alt-Message-ID', @alt);
 465         }
 466
 467         # clobber some
 468         my $xref = xref($self, $ng, $n, $mid);
 469         $hdr->header_set('Xref', $xref);
 470         $xref =~ s/:[0-9]+//g;
 471         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 472         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 473         if (my $url = $ng->base_url) {
 474                 $mid = mid_escape($mid);
 475                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 476                 header_append($hdr, 'List-Archive', "<$url>");
 477         }
 478 }
 479
 480 sub art_lookup ($$$) {
 481         my ($self, $art, $set_headers) = @_;
 482         my $ng = $self->{ng};
 483         my ($n, $mid);
 484         my $err;
 485         if (defined $art) {
 486                 if ($art =~ /\A[0-9]+\z/) {
 487                         $err = '423 no such article number in this group';
 488                         $n = int($art);
 489                         goto find_mid;
 490                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 491                         $mid = $1;
 492                         $err = r430;
 493                         $n = $ng->mm->num_for($mid) if $ng;
 494                         goto found if defined $n;
 495                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 496                                 $n = $g->mm->num_for($mid);
 497                                 if (defined $n) {
 498                                         $ng = $g;
 499                                         goto found;
 500                                 }
 501                         }
 502                         return $err;
 503                 } else {
 504                         return r501;
 505                 }
 506         } else {
 507                 $err = '420 no current article has been selected';
 508                 $n = $self->{article};
 509                 defined $n or return $err;
 510 find_mid:
 511                 $ng or return '412 no newsgroup has been selected';
 512                 $mid = $ng->mm->mid_for($n);
 513                 defined $mid or return $err;
 514         }
 515 found:
 516         my $smsg = $ng->over->get_art($n) or return $err;
 517         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 518
 519         # Email::Simple->new will modify $msg in-place as documented
 520         # in its manpage, so what's left is the body and we won't need
 521         # to call Email::Simple::body(), later
 522         my $hdr = Email::Simple->new($msg)->header_obj;
 523         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 524         [ $n, $mid, $msg, $hdr ];
 525 }
 526
 527 sub msg_body_write ($$) {
 528         my ($self, $msg) = @_;
 529
 530         # these can momentarily double the memory consumption :<
 531         $$msg =~ s/^\./../smg;
 532         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 533         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 534         $self->msg_more($$msg);
 535         '.'
 536 }
 537
 538 sub set_art {
 539         my ($self, $art) = @_;
 540         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 541 }
 542
 543 sub msg_hdr_write ($$$) {
 544         my ($self, $hdr, $body_follows) = @_;
 545         $hdr = $hdr->as_string;
 546         utf8::encode($hdr);
 547         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 548
 549         # for leafnode compatibility, we need to ensure Message-ID headers
 550         # are only a single line.  We can't subclass Email::Simple::Header
 551         # and override _default_fold_at in here, either; since that won't
 552         # affect messages already in the archive.
 553         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 554         $hdr .= "\r\n" if $body_follows;
 555         $self->msg_more($hdr);
 556 }
 557
 558 sub cmd_article ($;$) {
 559         my ($self, $art) = @_;
 560         my $r = art_lookup($self, $art, 1);
 561         return $r unless ref $r;
 562         my ($n, $mid, $msg, $hdr) = @$r;
 563         set_art($self, $art);
 564         more($self, "220 $n <$mid> article retrieved - head and body follow");
 565         msg_hdr_write($self, $hdr, 1);
 566         msg_body_write($self, $msg);
 567 }
 568
 569 sub cmd_head ($;$) {
 570         my ($self, $art) = @_;
 571         my $r = art_lookup($self, $art, 2);
 572         return $r unless ref $r;
 573         my ($n, $mid, undef, $hdr) = @$r;
 574         set_art($self, $art);
 575         more($self, "221 $n <$mid> article retrieved - head follows");
 576         msg_hdr_write($self, $hdr, 0);
 577         '.'
 578 }
 579
 580 sub cmd_body ($;$) {
 581         my ($self, $art) = @_;
 582         my $r = art_lookup($self, $art, 0);
 583         return $r unless ref $r;
 584         my ($n, $mid, $msg) = @$r;
 585         set_art($self, $art);
 586         more($self, "222 $n <$mid> article retrieved - body follows");
 587         msg_body_write($self, $msg);
 588 }
 589
 590 sub cmd_stat ($;$) {
 591         my ($self, $art) = @_;
 592         my $r = art_lookup($self, $art, 0);
 593         return $r unless ref $r;
 594         my ($n, $mid) = @$r;
 595         set_art($self, $art);
 596         "223 $n <$mid> article retrieved - request text separately";
 597 }
 598
 599 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 600
 601 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 602
 603 sub cmd_help ($) {
 604         my ($self) = @_;
 605         more($self, '100 help text follows');
 606         '.'
 607 }
 608
 609 sub get_range ($$) {
 610         my ($self, $range) = @_;
 611         my $ng = $self->{ng} or return '412 no news group has been selected';
 612         defined $range or return '420 No article(s) selected';
 613         my ($beg, $end);
 614         my ($min, $max) = $ng->mm->minmax;
 615         if ($range =~ /\A([0-9]+)\z/) {
 616                 $beg = $end = $1;
 617         } elsif ($range =~ /\A([0-9]+)-\z/) {
 618                 ($beg, $end) = ($1, $max);
 619         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 620                 ($beg, $end) = ($1, $2);
 621         } else {
 622                 return r501;
 623         }
 624         $beg = $min if ($beg < $min);
 625         $end = $max if ($end > $max);
 626         return '420 No article(s) selected' if ($beg > $end);
 627         [ $beg, $end ];
 628 }
 629
 630 sub long_response ($$) {
 631         my ($self, $cb) = @_; # cb returns true if more, false if done
 632
 633         my $fd = fileno($self->{sock});
 634         defined $fd or return;
 635         # make sure we disable reading during a long response,
 636         # clients should not be sending us stuff and making us do more
 637         # work while we are stream a response to them
 638         my $t0 = now();
 639         my $long_cb; # DANGER: self-referential
 640         $long_cb = sub {
 641                 # wbuf is unset or empty, here; $cb may add to it
 642                 my $more = eval { $cb->() };
 643                 if ($@ || !$self->{sock}) { # something bad happened...
 644                         $long_cb = undef;
 645                         my $diff = now() - $t0;
 646                         if ($@) {
 647                                 err($self,
 648                                     "%s during long response[$fd] - %0.6f",
 649                                     $@, $diff);
 650                         }
 651                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 652                         $self->close;
 653                 } elsif ($more) { # $self->{wbuf}:
 654                         update_idle_time($self);
 655
 656                         # COMPRESS users all share the same DEFLATE context.
 657                         # Flush it here to ensure clients don't see
 658                         # each other's data
 659                         $self->zflush;
 660
 661                         # no recursion, schedule another call ASAP
 662                         # but only after all pending writes are done
 663                         my $wbuf = $self->{wbuf} ||= [];
 664                         push @$wbuf, $long_cb;
 665
 666                         # wbuf may be populated by $cb, no need to rearm if so:
 667                         $self->requeue if scalar(@$wbuf) == 1;
 668                 } else { # all done!
 669                         $long_cb = undef;
 670                         res($self, '.');
 671                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 672                         my $wbuf = $self->{wbuf};
 673                         $self->requeue unless $wbuf && @$wbuf;
 674                 }
 675         };
 676         $self->write($long_cb); # kick off!
 677         undef;
 678 }
 679
 680 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 681         my ($self, $xhdr, $range) = @_;
 682
 683         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 684                 my ($ng, $n) = mid_lookup($self, $1);
 685                 return r430 unless $n;
 686                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 687         } else { # numeric range
 688                 $range = $self->{article} unless defined $range;
 689                 my $r = get_range($self, $range);
 690                 return $r unless ref $r;
 691                 my $mm = $self->{ng}->mm;
 692                 my ($beg, $end) = @$r;
 693                 more($self, $xhdr ? r221 : r225);
 694                 long_response($self, sub {
 695                         my $r = $mm->msg_range(\$beg, $end);
 696                         @$r or return;
 697                         more($self, join("\r\n", map {
 698                                 "$_->[0] <$_->[1]>"
 699                         } @$r));
 700                         1;
 701                 });
 702         }
 703 }
 704
 705 sub mid_lookup ($$) {
 706         my ($self, $mid) = @_;
 707         my $self_ng = $self->{ng};
 708         if ($self_ng) {
 709                 my $n = $self_ng->mm->num_for($mid);
 710                 return ($self_ng, $n) if defined $n;
 711         }
 712         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 713                 next if defined $self_ng && $ng eq $self_ng;
 714                 my $n = $ng->mm->num_for($mid);
 715                 return ($ng, $n) if defined $n;
 716         }
 717         (undef, undef);
 718 }
 719
 720 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 721         my ($self, $xhdr, $range) = @_;
 722
 723         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 724                 my $mid = $1;
 725                 my ($ng, $n) = mid_lookup($self, $mid);
 726                 return r430 unless $n;
 727                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 728                                 xref($self, $ng, $n, $mid));
 729         } else { # numeric range
 730                 $range = $self->{article} unless defined $range;
 731                 my $r = get_range($self, $range);
 732                 return $r unless ref $r;
 733                 my $ng = $self->{ng};
 734                 my $mm = $ng->mm;
 735                 my ($beg, $end) = @$r;
 736                 more($self, $xhdr ? r221 : r225);
 737                 long_response($self, sub {
 738                         my $r = $mm->msg_range(\$beg, $end);
 739                         @$r or return;
 740                         more($self, join("\r\n", map {
 741                                 my $num = $_->[0];
 742                                 "$num ".xref($self, $ng, $num, $_->[1]);
 743                         } @$r));
 744                         1;
 745                 });
 746         }
 747 }
 748
 749 sub over_header_for {
 750         my ($over, $num, $field) = @_;
 751         my $smsg = $over->get_art($num) or return;
 752         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 753         $smsg->{$field};
 754 }
 755
 756 sub hdr_searchmsg ($$$$) {
 757         my ($self, $xhdr, $field, $range) = @_;
 758         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 759                 my ($ng, $n) = mid_lookup($self, $1);
 760                 return r430 unless defined $n;
 761                 my $v = over_header_for($ng->over, $n, $field);
 762                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 763         } else { # numeric range
 764                 $range = $self->{article} unless defined $range;
 765                 my $over = $self->{ng}->over;
 766                 my $mm = $self->{ng}->mm;
 767                 my $r = get_range($self, $range);
 768                 return $r unless ref $r;
 769                 my ($beg, $end) = @$r;
 770                 more($self, $xhdr ? r221 : r225);
 771                 my $cur = $beg;
 772                 long_response($self, sub {
 773                         my $msgs = $over->query_xover($cur, $end);
 774                         my $nr = scalar @$msgs or return;
 775                         my $tmp = '';
 776                         foreach my $s (@$msgs) {
 777                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 778                         }
 779                         utf8::encode($tmp);
 780                         $self->msg_more($tmp);
 781                         $cur = $msgs->[-1]->{num} + 1;
 782                 });
 783         }
 784 }
 785
 786 sub do_hdr ($$$;$) {
 787         my ($self, $xhdr, $header, $range) = @_;
 788         my $sub = lc $header;
 789         if ($sub eq 'message-id') {
 790                 hdr_message_id($self, $xhdr, $range);
 791         } elsif ($sub eq 'xref') {
 792                 hdr_xref($self, $xhdr, $range);
 793         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 794                                 bytes|lines)\z/x) {
 795                 hdr_searchmsg($self, $xhdr, $sub, $range);
 796         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 797                 hdr_searchmsg($self, $xhdr, $1, $range);
 798         } else {
 799                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 800         }
 801 }
 802
 803 # RFC 3977
 804 sub cmd_hdr ($$;$) {
 805         my ($self, $header, $range) = @_;
 806         do_hdr($self, 0, $header, $range);
 807 }
 808
 809 # RFC 2980
 810 sub cmd_xhdr ($$;$) {
 811         my ($self, $header, $range) = @_;
 812         do_hdr($self, 1, $header, $range);
 813 }
 814
 815 sub hdr_mid_prefix ($$$$$) {
 816         my ($self, $xhdr, $ng, $n, $mid) = @_;
 817         return $mid if $xhdr;
 818
 819         # HDR for RFC 3977 users
 820         if (my $self_ng = $self->{ng}) {
 821                 ($self_ng eq $ng) ? $n : '0';
 822         } else {
 823                 '0';
 824         }
 825 }
 826
 827 sub hdr_mid_response ($$$$$$) {
 828         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 829         my $res = '';
 830         if ($xhdr) {
 831                 $res .= r221 . "\r\n";
 832                 $res .= "$mid $v\r\n";
 833         } else {
 834                 $res .= r225 . "\r\n";
 835                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 836                 $res .= "$pfx $v\r\n";
 837         }
 838         res($self, $res .= '.');
 839         undef;
 840 }
 841
 842 sub cmd_xrover ($;$) {
 843         my ($self, $range) = @_;
 844         my $ng = $self->{ng} or return '412 no newsgroup selected';
 845         (defined $range && $range =~ /[<>]/) and
 846                 return '420 No article(s) selected'; # no message IDs
 847
 848         $range = $self->{article} unless defined $range;
 849         my $r = get_range($self, $range);
 850         return $r unless ref $r;
 851         my ($beg, $end) = @$r;
 852         my $mm = $ng->mm;
 853         my $over = $ng->over;
 854         more($self, '224 Overview information follows');
 855
 856         long_response($self, sub {
 857                 my $h = over_header_for($over, $beg, 'references');
 858                 more($self, "$beg $h") if defined($h);
 859                 $beg++ < $end;
 860         });
 861 }
 862
 863 sub over_line ($$$$) {
 864         my ($self, $ng, $num, $smsg) = @_;
 865         # n.b. field access and procedural calls can be
 866         # 10%-15% faster than OO method calls:
 867         my $s = join("\t", $num,
 868                 $smsg->{subject},
 869                 $smsg->{from},
 870                 PublicInbox::SearchMsg::date($smsg),
 871                 "<$smsg->{mid}>",
 872                 $smsg->{references},
 873                 $smsg->{bytes},
 874                 $smsg->{lines},
 875                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 876         utf8::encode($s);
 877         $s
 878 }
 879
 880 sub cmd_over ($;$) {
 881         my ($self, $range) = @_;
 882         if ($range && $range =~ /\A<(.+)>\z/) {
 883                 my ($ng, $n) = mid_lookup($self, $1);
 884                 defined $n or return r430;
 885                 my $smsg = $ng->over->get_art($n) or return r430;
 886                 more($self, '224 Overview information follows (multi-line)');
 887
 888                 # Only set article number column if it's the current group
 889                 my $self_ng = $self->{ng};
 890                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 891                 more($self, over_line($self, $ng, $n, $smsg));
 892                 '.';
 893         } else {
 894                 cmd_xover($self, $range);
 895         }
 896 }
 897
 898 sub cmd_xover ($;$) {
 899         my ($self, $range) = @_;
 900         $range = $self->{article} unless defined $range;
 901         my $r = get_range($self, $range);
 902         return $r unless ref $r;
 903         my ($beg, $end) = @$r;
 904         more($self, "224 Overview information follows for $beg to $end");
 905         my $over = $self->{ng}->over;
 906         my $cur = $beg;
 907         long_response($self, sub {
 908                 my $msgs = $over->query_xover($cur, $end);
 909                 my $nr = scalar @$msgs or return;
 910
 911                 # OVERVIEW.FMT
 912                 more($self, join("\r\n", map {
 913                         over_line($self, $self->{ng}, $_->{num}, $_);
 914                         } @$msgs));
 915                 $cur = $msgs->[-1]->{num} + 1;
 916         });
 917 }
 918
 919 sub compressed { undef }
 920
 921 sub cmd_starttls ($) {
 922         my ($self) = @_;
 923         my $sock = $self->{sock} or return;
 924         # RFC 4642 2.2.1
 925         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 926         my $opt = $self->{nntpd}->{accept_tls} or
 927                 return '580 can not initiate TLS negotiation';
 928         res($self, '382 Continue with TLS negotiation');
 929         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 930         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 931         undef;
 932 }
 933
 934 # RFC 8054
 935 sub cmd_compress ($$) {
 936         my ($self, $alg) = @_;
 937         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 938         return r502 if $self->compressed || !$have_deflate;
 939         PublicInbox::NNTPdeflate->enable($self);
 940         $self->requeue;
 941         undef
 942 }
 943
 944 sub zflush {} # overridden by NNTPdeflate
 945
 946 sub cmd_xpath ($$) {
 947         my ($self, $mid) = @_;
 948         return r501 unless $mid =~ /\A<(.+)>\z/;
 949         $mid = $1;
 950         my @paths;
 951         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 952                 my $n = $ng->mm->num_for($mid);
 953                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 954         }
 955         return '430 no such article on server' unless @paths;
 956         '223 '.join(' ', @paths);
 957 }
 958
 959 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 960
 961 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 962
 963 sub do_write ($$) {
 964         my $self = $_[0];
 965         my $done = $self->write(\($_[1]));
 966         return 0 unless $self->{sock};
 967
 968         $done;
 969 }
 970
 971 sub err ($$;@) {
 972         my ($self, $fmt, @args) = @_;
 973         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 974 }
 975
 976 sub out ($$;@) {
 977         my ($self, $fmt, @args) = @_;
 978         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 979 }
 980
 981 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 982 sub event_step {
 983         my ($self) = @_;
 984
 985         return unless $self->flush_write && $self->{sock};
 986
 987         update_idle_time($self);
 988         # only read more requests if we've drained the write buffer,
 989         # otherwise we can be buffering infinitely w/o backpressure
 990
 991         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 992         my $r = 1;
 993
 994         if (index($$rbuf, "\n") < 0) {
 995                 my $off = bytes::length($$rbuf);
 996                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 997         }
 998         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 999                 my $line = $1;
1000                 return $self->close if $line =~ /[[:cntrl:]]/s;
1001                 my $t0 = now();
1002                 my $fd = fileno($self->{sock});
1003                 $r = eval { process_line($self, $line) };
1004                 my $pending = $self->{wbuf} ? ' pending' : '';
1005                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1006         }
1007
1008         return $self->close if $r < 0;
1009         my $len = bytes::length($$rbuf);
1010         return $self->close if ($len >= LINE_MAX);
1011         $self->rbuf_idle($rbuf);
1012         update_idle_time($self);
1013
1014         # maybe there's more pipelined data, or we'll have
1015         # to register it for socket-readiness notifications
1016         $self->requeue unless $self->{wbuf};
1017 }
1018
1019 sub not_idle_long ($$) {
1020         my ($self, $now) = @_;
1021         my $sock = $self->{sock} or return;
1022         my $ary = $EXPMAP->{fileno($sock)} or return;
1023         my $exp_at = $ary->[0] + $EXPTIME;
1024         $exp_at > $now;
1025 }
1026
1027 # for graceful shutdown in PublicInbox::Daemon:
1028 sub busy {
1029         my ($self, $now) = @_;
1030         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
1031 }
1032
1033 # this is an import to prevent "perl -c" from complaining about fields
1034 sub import {
1035         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
1036                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
1037 }
1038
1039 1;