lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng long_cb);
  10 use PublicInbox::MID qw(mid_escape);
  11 use Email::Simple;
  12 use POSIX qw(strftime);
  13 use PublicInbox::DS qw(now);
  14 use Digest::SHA qw(sha1_hex);
  15 use Time::Local qw(timegm timelocal);
  16 use constant {
  17         LINE_MAX => 512, # RFC 977 section 2.3
  18         r501 => '501 command syntax error',
  19         r502 => '502 Command unavailable',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24 };
  25 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  26 use Errno qw(EAGAIN);
  27
  28 my @OVERVIEW = qw(Subject From Date Message-ID References);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  30                 "Xref:full\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33 my $CAPABILITIES = <<"";
  34 101 Capability list:\r
  35 VERSION 2\r
  36 READER\r
  37 NEWNEWS\r
  38 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  39 HDR\r
  40 OVER\r
  41
  42 my $have_deflate;
  43
  44 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  45
  46 sub new ($$$) {
  47         my ($class, $sock, $nntpd) = @_;
  48         my $self = fields::new($class);
  49         my $ev = EPOLLIN;
  50         my $wbuf;
  51         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  52                 return CORE::close($sock) if $! != EAGAIN;
  53                 $ev = PublicInbox::TLS::epollbit();
  54                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  55         }
  56         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  57         $self->{nntpd} = $nntpd;
  58         if ($wbuf) {
  59                 $self->{wbuf} = $wbuf;
  60         } else {
  61                 greet($self);
  62         }
  63         $self->update_idle_time;
  64         $self;
  65 }
  66
  67 sub args_ok ($$) {
  68         my ($cb, $argc) = @_;
  69         my $tot = prototype $cb;
  70         my ($nreq, undef) = split(';', $tot);
  71         $nreq = ($nreq =~ tr/$//) - 1;
  72         $tot = ($tot =~ tr/$//) - 1;
  73         ($argc <= $tot && $argc >= $nreq);
  74 }
  75
  76 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  77 sub process_line ($$) {
  78         my ($self, $l) = @_;
  79         my ($req, @args) = split(/[ \t]/, $l);
  80         return 1 unless defined($req); # skip blank line
  81         $req = $self->can('cmd_'.lc($req));
  82         return res($self, '500 command not recognized') unless $req;
  83         return res($self, r501) unless args_ok($req, scalar @args);
  84
  85         my $res = eval { $req->($self, @args) };
  86         my $err = $@;
  87         if ($err && $self->{sock}) {
  88                 local $/ = "\n";
  89                 chomp($l);
  90                 err($self, 'error from: %s (%s)', $l, $err);
  91                 $res = '503 program fault - command not performed';
  92         }
  93         return 0 unless defined $res;
  94         res($self, $res);
  95 }
  96
  97 # The keyword argument is not used (rfc3977 5.2.2)
  98 sub cmd_capabilities ($;$) {
  99         my ($self, undef) = @_;
 100         my $res = $CAPABILITIES;
 101         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 102                         $self->{nntpd}->{accept_tls}) {
 103                 $res .= "STARTTLS\r\n";
 104         }
 105         $res .= '.';
 106 }
 107
 108 sub cmd_mode ($$) {
 109         my ($self, $arg) = @_;
 110         $arg = uc $arg;
 111         return r501 unless $arg eq 'READER';
 112         '201 Posting prohibited';
 113 }
 114
 115 sub cmd_slave ($) { '202 slave status noted' }
 116
 117 sub cmd_xgtitle ($;$) {
 118         my ($self, $wildmat) = @_;
 119         more($self, '282 list of groups and descriptions follows');
 120         list_newsgroups($self, $wildmat);
 121         '.'
 122 }
 123
 124 sub list_overview_fmt ($) {
 125         my ($self) = @_;
 126         $self->msg_more($OVERVIEW_FMT);
 127 }
 128
 129 sub list_headers ($;$) {
 130         my ($self) = @_;
 131         $self->msg_more($LIST_HEADERS);
 132 }
 133
 134 sub list_active ($;$) {
 135         my ($self, $wildmat) = @_;
 136         wildmat2re($wildmat);
 137         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 138                 $ng->{newsgroup} =~ $wildmat or next;
 139                 group_line($self, $ng);
 140         }
 141 }
 142
 143 sub list_active_times ($;$) {
 144         my ($self, $wildmat) = @_;
 145         wildmat2re($wildmat);
 146         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 147                 $ng->{newsgroup} =~ $wildmat or next;
 148                 my $c = eval { $ng->mm->created_at } || time;
 149                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 150         }
 151 }
 152
 153 sub list_newsgroups ($;$) {
 154         my ($self, $wildmat) = @_;
 155         wildmat2re($wildmat);
 156         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 157                 $ng->{newsgroup} =~ $wildmat or next;
 158                 my $d = $ng->description;
 159                 more($self, "$ng->{newsgroup} $d");
 160         }
 161 }
 162
 163 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 164 sub cmd_list ($;$$) {
 165         my ($self, @args) = @_;
 166         if (scalar @args) {
 167                 my $arg = shift @args;
 168                 $arg =~ tr/A-Z./a-z_/;
 169                 $arg = "list_$arg";
 170                 $arg = $self->can($arg);
 171                 return r501 unless $arg && args_ok($arg, scalar @args);
 172                 more($self, '215 information follows');
 173                 $arg->($self, @args);
 174         } else {
 175                 more($self, '215 list of newsgroups follows');
 176                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                         group_line($self, $ng);
 178                 }
 179         }
 180         '.'
 181 }
 182
 183 sub listgroup_range_i {
 184         my ($self, $beg, $end) = @_;
 185         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 186         scalar(@$r) or return;
 187         more($self, join("\r\n", map { $_->[0] } @$r));
 188         1;
 189 }
 190
 191 sub listgroup_all_i {
 192         my ($self, $num) = @_;
 193         my $ary = $self->{ng}->mm->ids_after($num);
 194         scalar(@$ary) or return;
 195         more($self, join("\r\n", @$ary));
 196         1;
 197 }
 198
 199 sub cmd_listgroup ($;$$) {
 200         my ($self, $group, $range) = @_;
 201         if (defined $group) {
 202                 my $res = cmd_group($self, $group);
 203                 return $res if ($res !~ /\A211 /);
 204                 more($self, $res);
 205         }
 206         $self->{ng} or return '412 no newsgroup selected';
 207         if (defined $range) {
 208                 my $r = get_range($self, $range);
 209                 return $r unless ref $r;
 210                 long_response($self, \&listgroup_range_i, @$r);
 211         } else { # grab every article number
 212                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 213         }
 214 }
 215
 216 sub parse_time ($$;$) {
 217         my ($date, $time, $gmt) = @_;
 218         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 219         if (defined $gmt) {
 220                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 221                 $gmt = 1;
 222         }
 223         my @now = $gmt ? gmtime : localtime;
 224         my ($YYYY, $MM, $DD);
 225         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 226                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 227         } else { # legacy clients send YYMMDD
 228                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 229                 my $cur_year = $now[5] + 1900;
 230                 if ($YYYY > $cur_year) {
 231                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 232                 }
 233         }
 234         if ($gmt) {
 235                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 236         } else {
 237                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 238         }
 239 }
 240
 241 sub group_line ($$) {
 242         my ($self, $ng) = @_;
 243         my ($min, $max) = $ng->mm->minmax;
 244         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 245 }
 246
 247 sub cmd_newgroups ($$$;$$) {
 248         my ($self, $date, $time, $gmt, $dists) = @_;
 249         my $ts = eval { parse_time($date, $time, $gmt) };
 250         return r501 if $@;
 251
 252         # TODO dists
 253         more($self, '231 list of new newsgroups follows');
 254         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 255                 my $c = eval { $ng->mm->created_at } || 0;
 256                 next unless $c > $ts;
 257                 group_line($self, $ng);
 258         }
 259         '.'
 260 }
 261
 262 sub wildmat2re (;$) {
 263         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 264         my %keep;
 265         my $salt = rand;
 266         my $tmp = $_[0];
 267
 268         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 269                 my $orig = $1;
 270                 my $key = sha1_hex($orig . $salt);
 271                 $orig =~ s/([^\w\-])+/\Q$1/g;
 272                 $keep{$key} = $orig;
 273                 $key
 274                 #gex;
 275         my %map = ('*' => '.*', '?' => '.' );
 276         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 277         if (scalar %keep) {
 278                 $tmp =~ s#([a-f0-9]{40})#
 279                         my $orig = $keep{$1};
 280                         defined $orig ? $orig : $1;
 281                         #ge;
 282         }
 283         $_[0] = qr/\A$tmp\z/;
 284 }
 285
 286 sub ngpat2re (;$) {
 287         return $_[0] = qr/\A\z/ unless defined $_[0];
 288         my %map = ('*' => '.*', ',' => '|');
 289         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 290         $_[0] = qr/\A(?:$_[0])\z/;
 291 }
 292
 293 sub cmd_newnews ($$$$;$$) {
 294         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 295         my $ts = eval { parse_time($date, $time, $gmt) };
 296         return r501 if $@;
 297         more($self, '230 list of new articles by message-id follows');
 298         my ($keep, $skip) = split('!', $newsgroups, 2);
 299         ngpat2re($keep);
 300         ngpat2re($skip);
 301         my @over;
 302         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 303                 $ng->{newsgroup} =~ $keep or next;
 304                 $ng->{newsgroup} =~ $skip and next;
 305                 my $over = $ng->over or next;
 306                 push @over, $over;
 307         };
 308         return '.' unless @over;
 309
 310         my $prev = 0;
 311         long_response($self, sub {
 312                 my $over = $over[0];
 313                 my $msgs = $over->query_ts($ts, $prev);
 314                 if (scalar @$msgs) {
 315                         more($self, '<' .
 316                                 join(">\r\n<", map { $_->mid } @$msgs ).
 317                                 '>');
 318                         $prev = $msgs->[-1]->{num};
 319                 } else {
 320                         shift @over;
 321                         if (@over) { # continue onto next newsgroup
 322                                 $prev = 0;
 323                                 return 1;
 324                         } else { # break out of the long response.
 325                                 return;
 326                         }
 327                 }
 328         });
 329 }
 330
 331 sub cmd_group ($$) {
 332         my ($self, $group) = @_;
 333         my $no_such = '411 no such news group';
 334         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 335
 336         $self->{ng} = $ng;
 337         my ($min, $max) = $ng->mm->minmax;
 338         $min ||= 0;
 339         $max ||= 0;
 340         $self->{article} = $min;
 341         my $est_size = $max - $min;
 342         "211 $est_size $min $max $group";
 343 }
 344
 345 sub article_adj ($$) {
 346         my ($self, $off) = @_;
 347         my $ng = $self->{ng} or return '412 no newsgroup selected';
 348
 349         my $n = $self->{article};
 350         defined $n or return '420 no current article has been selected';
 351
 352         $n += $off;
 353         my $mid = $ng->mm->mid_for($n);
 354         unless ($mid) {
 355                 $n = $off > 0 ? 'next' : 'previous';
 356                 return "421 no $n article in this group";
 357         }
 358         $self->{article} = $n;
 359         "223 $n <$mid> article retrieved - request text separately";
 360 }
 361
 362 sub cmd_next ($) { article_adj($_[0], 1) }
 363 sub cmd_last ($) { article_adj($_[0], -1) }
 364
 365 # We want to encourage using email and CC-ing everybody involved to avoid
 366 # the single-point-of-failure a single server provides.
 367 sub cmd_post ($) {
 368         my ($self) = @_;
 369         my $ng = $self->{ng};
 370         $ng ? "440 mailto:$ng->{-primary_address} to post"
 371                 : '440 posting not allowed'
 372 }
 373
 374 sub cmd_quit ($) {
 375         my ($self) = @_;
 376         res($self, '205 closing connection - goodbye!');
 377         $self->shutdn;
 378         undef;
 379 }
 380
 381 sub header_append ($$$) {
 382         my ($hdr, $k, $v) = @_;
 383         my @v = $hdr->header($k);
 384         foreach (@v) {
 385                 return if $v eq $_;
 386         }
 387         $hdr->header_set($k, @v, $v);
 388 }
 389
 390 sub xref ($$$$) {
 391         my ($self, $ng, $n, $mid) = @_;
 392         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 393
 394         # num_for is pretty cheap and sometimes we'll lookup the existence
 395         # of an article without getting even the OVER info.  In other words,
 396         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 397         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 398         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 399                 next if $ng eq $other;
 400                 my $num = eval { $other->mm->num_for($mid) } or next;
 401                 $ret .= " $other->{newsgroup}:$num";
 402         }
 403         $ret;
 404 }
 405
 406 sub set_nntp_headers ($$$$$) {
 407         my ($self, $hdr, $ng, $n, $mid) = @_;
 408
 409         # why? leafnode requires a Path: header for some inexplicable
 410         # reason.  We'll fake the shortest one possible.
 411         $hdr->header_set('Path', 'y');
 412
 413         # leafnode (and maybe other NNTP clients) have trouble dealing
 414         # with v2 messages which have multiple Message-IDs (either due
 415         # to our own content-based dedupe or buggy git-send-email versions).
 416         my @mids = $hdr->header('Message-ID');
 417         if (scalar(@mids) > 1) {
 418                 my $mid0 = "<$mid>";
 419                 $hdr->header_set('Message-ID', $mid0);
 420                 my @alt = $hdr->header('X-Alt-Message-ID');
 421                 my %seen = map { $_ => 1 } (@alt, $mid0);
 422                 foreach my $m (@mids) {
 423                         next if $seen{$m}++;
 424                         push @alt, $m;
 425                 }
 426                 $hdr->header_set('X-Alt-Message-ID', @alt);
 427         }
 428
 429         # clobber some
 430         my $xref = xref($self, $ng, $n, $mid);
 431         $hdr->header_set('Xref', $xref);
 432         $xref =~ s/:[0-9]+//g;
 433         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 434         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 435         if (my $url = $ng->base_url) {
 436                 $mid = mid_escape($mid);
 437                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 438                 header_append($hdr, 'List-Archive', "<$url>");
 439         }
 440 }
 441
 442 sub art_lookup ($$$) {
 443         my ($self, $art, $set_headers) = @_;
 444         my $ng = $self->{ng};
 445         my ($n, $mid);
 446         my $err;
 447         if (defined $art) {
 448                 if ($art =~ /\A[0-9]+\z/) {
 449                         $err = '423 no such article number in this group';
 450                         $n = int($art);
 451                         goto find_mid;
 452                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 453                         $mid = $1;
 454                         $err = r430;
 455                         $n = $ng->mm->num_for($mid) if $ng;
 456                         goto found if defined $n;
 457                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 458                                 $n = $g->mm->num_for($mid);
 459                                 if (defined $n) {
 460                                         $ng = $g;
 461                                         goto found;
 462                                 }
 463                         }
 464                         return $err;
 465                 } else {
 466                         return r501;
 467                 }
 468         } else {
 469                 $err = '420 no current article has been selected';
 470                 $n = $self->{article};
 471                 defined $n or return $err;
 472 find_mid:
 473                 $ng or return '412 no newsgroup has been selected';
 474                 $mid = $ng->mm->mid_for($n);
 475                 defined $mid or return $err;
 476         }
 477 found:
 478         my $smsg = $ng->over->get_art($n) or return $err;
 479         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 480
 481         # Email::Simple->new will modify $msg in-place as documented
 482         # in its manpage, so what's left is the body and we won't need
 483         # to call Email::Simple::body(), later
 484         my $hdr = Email::Simple->new($msg)->header_obj;
 485         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 486         [ $n, $mid, $msg, $hdr ];
 487 }
 488
 489 sub msg_body_write ($$) {
 490         my ($self, $msg) = @_;
 491
 492         # these can momentarily double the memory consumption :<
 493         $$msg =~ s/^\./../smg;
 494         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 495         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 496         $self->msg_more($$msg);
 497         '.'
 498 }
 499
 500 sub set_art {
 501         my ($self, $art) = @_;
 502         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 503 }
 504
 505 sub msg_hdr_write ($$$) {
 506         my ($self, $hdr, $body_follows) = @_;
 507         $hdr = $hdr->as_string;
 508         utf8::encode($hdr);
 509         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 510
 511         # for leafnode compatibility, we need to ensure Message-ID headers
 512         # are only a single line.  We can't subclass Email::Simple::Header
 513         # and override _default_fold_at in here, either; since that won't
 514         # affect messages already in the archive.
 515         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 516         $hdr .= "\r\n" if $body_follows;
 517         $self->msg_more($hdr);
 518 }
 519
 520 sub cmd_article ($;$) {
 521         my ($self, $art) = @_;
 522         my $r = art_lookup($self, $art, 1);
 523         return $r unless ref $r;
 524         my ($n, $mid, $msg, $hdr) = @$r;
 525         set_art($self, $art);
 526         more($self, "220 $n <$mid> article retrieved - head and body follow");
 527         msg_hdr_write($self, $hdr, 1);
 528         msg_body_write($self, $msg);
 529 }
 530
 531 sub cmd_head ($;$) {
 532         my ($self, $art) = @_;
 533         my $r = art_lookup($self, $art, 2);
 534         return $r unless ref $r;
 535         my ($n, $mid, undef, $hdr) = @$r;
 536         set_art($self, $art);
 537         more($self, "221 $n <$mid> article retrieved - head follows");
 538         msg_hdr_write($self, $hdr, 0);
 539         '.'
 540 }
 541
 542 sub cmd_body ($;$) {
 543         my ($self, $art) = @_;
 544         my $r = art_lookup($self, $art, 0);
 545         return $r unless ref $r;
 546         my ($n, $mid, $msg) = @$r;
 547         set_art($self, $art);
 548         more($self, "222 $n <$mid> article retrieved - body follows");
 549         msg_body_write($self, $msg);
 550 }
 551
 552 sub cmd_stat ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 0);
 555         return $r unless ref $r;
 556         my ($n, $mid) = @$r;
 557         set_art($self, $art);
 558         "223 $n <$mid> article retrieved - request text separately";
 559 }
 560
 561 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 562
 563 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 564
 565 sub cmd_help ($) {
 566         my ($self) = @_;
 567         more($self, '100 help text follows');
 568         '.'
 569 }
 570
 571 sub get_range ($$) {
 572         my ($self, $range) = @_;
 573         my $ng = $self->{ng} or return '412 no news group has been selected';
 574         defined $range or return '420 No article(s) selected';
 575         my ($beg, $end);
 576         my ($min, $max) = $ng->mm->minmax;
 577         if ($range =~ /\A([0-9]+)\z/) {
 578                 $beg = $end = $1;
 579         } elsif ($range =~ /\A([0-9]+)-\z/) {
 580                 ($beg, $end) = ($1, $max);
 581         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 582                 ($beg, $end) = ($1, $2);
 583         } else {
 584                 return r501;
 585         }
 586         $beg = $min if ($beg < $min);
 587         $end = $max if ($end > $max);
 588         return '420 No article(s) selected' if ($beg > $end);
 589         [ \$beg, $end ];
 590 }
 591
 592 sub long_step {
 593         my ($self) = @_;
 594         # wbuf is unset or empty, here; {long} may add to it
 595         my ($cb, $t0, @args) = @{$self->{long_cb}};
 596         my $more = eval { $cb->($self, @args) };
 597         if ($@ || !$self->{sock}) { # something bad happened...
 598                 delete $self->{long_cb};
 599                 my $elapsed = now() - $t0;
 600                 my $fd = fileno($self->{sock});
 601                 if ($@) {
 602                         err($self,
 603                             "%s during long response[$fd] - %0.6f",
 604                             $@, $elapsed);
 605                 }
 606                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 607                 $self->close;
 608         } elsif ($more) { # $self->{wbuf}:
 609                 $self->update_idle_time;
 610
 611                 # COMPRESS users all share the same DEFLATE context.
 612                 # Flush it here to ensure clients don't see
 613                 # each other's data
 614                 $self->zflush;
 615
 616                 # no recursion, schedule another call ASAP
 617                 # but only after all pending writes are done
 618                 my $wbuf = $self->{wbuf} ||= [];
 619                 push @$wbuf, \&long_step;
 620
 621                 # wbuf may be populated by $cb, no need to rearm if so:
 622                 $self->requeue if scalar(@$wbuf) == 1;
 623         } else { # all done!
 624                 delete $self->{long_cb};
 625                 res($self, '.');
 626                 my $elapsed = now() - $t0;
 627                 my $fd = fileno($self->{sock});
 628                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 629                 my $wbuf = $self->{wbuf};
 630                 $self->requeue unless $wbuf && @$wbuf;
 631         }
 632 }
 633
 634 sub long_response ($$;@) {
 635         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 636
 637         $self->{sock} or return;
 638         # make sure we disable reading during a long response,
 639         # clients should not be sending us stuff and making us do more
 640         # work while we are stream a response to them
 641         $self->{long_cb} = [ $cb, now(), @args ];
 642         long_step($self); # kick off!
 643         undef;
 644 }
 645
 646 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 647         my ($self, $xhdr, $range) = @_;
 648
 649         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 650                 my ($ng, $n) = mid_lookup($self, $1);
 651                 return r430 unless $n;
 652                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 653         } else { # numeric range
 654                 $range = $self->{article} unless defined $range;
 655                 my $r = get_range($self, $range);
 656                 return $r unless ref $r;
 657                 my $mm = $self->{ng}->mm;
 658                 my ($beg, $end) = @$r;
 659                 more($self, $xhdr ? r221 : r225);
 660                 long_response($self, sub {
 661                         my $r = $mm->msg_range($beg, $end);
 662                         @$r or return;
 663                         more($self, join("\r\n", map {
 664                                 "$_->[0] <$_->[1]>"
 665                         } @$r));
 666                         1;
 667                 });
 668         }
 669 }
 670
 671 sub mid_lookup ($$) {
 672         my ($self, $mid) = @_;
 673         my $self_ng = $self->{ng};
 674         if ($self_ng) {
 675                 my $n = $self_ng->mm->num_for($mid);
 676                 return ($self_ng, $n) if defined $n;
 677         }
 678         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 679                 next if defined $self_ng && $ng eq $self_ng;
 680                 my $n = $ng->mm->num_for($mid);
 681                 return ($ng, $n) if defined $n;
 682         }
 683         (undef, undef);
 684 }
 685
 686 sub xref_range_i {
 687         my ($self, $beg, $end) = @_;
 688         my $ng = $self->{ng};
 689         my $r = $ng->mm->msg_range($beg, $end);
 690         @$r or return;
 691         more($self, join("\r\n", map {
 692                 my $num = $_->[0];
 693                 "$num ".xref($self, $ng, $num, $_->[1]);
 694         } @$r));
 695         1;
 696 }
 697
 698 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 699         my ($self, $xhdr, $range) = @_;
 700
 701         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 702                 my $mid = $1;
 703                 my ($ng, $n) = mid_lookup($self, $mid);
 704                 return r430 unless $n;
 705                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 706                                 xref($self, $ng, $n, $mid));
 707         } else { # numeric range
 708                 $range = $self->{article} unless defined $range;
 709                 my $r = get_range($self, $range);
 710                 return $r unless ref $r;
 711                 more($self, $xhdr ? r221 : r225);
 712                 long_response($self, \&xref_range_i, @$r);
 713         }
 714 }
 715
 716 sub over_header_for {
 717         my ($over, $num, $field) = @_;
 718         my $smsg = $over->get_art($num) or return;
 719         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 720         $smsg->{$field};
 721 }
 722
 723 sub searchmsg_range_i {
 724         my ($self, $beg, $end, $field) = @_;
 725         my $over = $self->{ng}->over;
 726         my $msgs = $over->query_xover($$beg, $end);
 727         scalar(@$msgs) or return;
 728         my $tmp = '';
 729         foreach my $s (@$msgs) {
 730                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 731         }
 732         utf8::encode($tmp);
 733         $self->msg_more($tmp);
 734         $$beg = $msgs->[-1]->{num} + 1;
 735 }
 736
 737 sub hdr_searchmsg ($$$$) {
 738         my ($self, $xhdr, $field, $range) = @_;
 739         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 740                 my ($ng, $n) = mid_lookup($self, $1);
 741                 return r430 unless defined $n;
 742                 my $v = over_header_for($ng->over, $n, $field);
 743                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 744         } else { # numeric range
 745                 $range = $self->{article} unless defined $range;
 746                 my $r = get_range($self, $range);
 747                 return $r unless ref $r;
 748                 more($self, $xhdr ? r221 : r225);
 749                 long_response($self, \&searchmsg_range_i, @$r, $field);
 750         }
 751 }
 752
 753 sub do_hdr ($$$;$) {
 754         my ($self, $xhdr, $header, $range) = @_;
 755         my $sub = lc $header;
 756         if ($sub eq 'message-id') {
 757                 hdr_message_id($self, $xhdr, $range);
 758         } elsif ($sub eq 'xref') {
 759                 hdr_xref($self, $xhdr, $range);
 760         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 761                                 bytes|lines)\z/x) {
 762                 hdr_searchmsg($self, $xhdr, $sub, $range);
 763         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 764                 hdr_searchmsg($self, $xhdr, $1, $range);
 765         } else {
 766                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 767         }
 768 }
 769
 770 # RFC 3977
 771 sub cmd_hdr ($$;$) {
 772         my ($self, $header, $range) = @_;
 773         do_hdr($self, 0, $header, $range);
 774 }
 775
 776 # RFC 2980
 777 sub cmd_xhdr ($$;$) {
 778         my ($self, $header, $range) = @_;
 779         do_hdr($self, 1, $header, $range);
 780 }
 781
 782 sub hdr_mid_prefix ($$$$$) {
 783         my ($self, $xhdr, $ng, $n, $mid) = @_;
 784         return $mid if $xhdr;
 785
 786         # HDR for RFC 3977 users
 787         if (my $self_ng = $self->{ng}) {
 788                 ($self_ng eq $ng) ? $n : '0';
 789         } else {
 790                 '0';
 791         }
 792 }
 793
 794 sub hdr_mid_response ($$$$$$) {
 795         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 796         my $res = '';
 797         if ($xhdr) {
 798                 $res .= r221 . "\r\n";
 799                 $res .= "$mid $v\r\n";
 800         } else {
 801                 $res .= r225 . "\r\n";
 802                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 803                 $res .= "$pfx $v\r\n";
 804         }
 805         res($self, $res .= '.');
 806         undef;
 807 }
 808
 809 sub xrover_i {
 810         my ($self, $beg, $end) = @_;
 811         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 812         more($self, "$$beg $h") if defined($h);
 813         $$beg++ < $end;
 814 }
 815
 816 sub cmd_xrover ($;$) {
 817         my ($self, $range) = @_;
 818         my $ng = $self->{ng} or return '412 no newsgroup selected';
 819         (defined $range && $range =~ /[<>]/) and
 820                 return '420 No article(s) selected'; # no message IDs
 821
 822         $range = $self->{article} unless defined $range;
 823         my $r = get_range($self, $range);
 824         return $r unless ref $r;
 825         more($self, '224 Overview information follows');
 826         long_response($self, \&xrover_i, @$r);
 827 }
 828
 829 sub over_line ($$$$) {
 830         my ($self, $ng, $num, $smsg) = @_;
 831         # n.b. field access and procedural calls can be
 832         # 10%-15% faster than OO method calls:
 833         my $s = join("\t", $num,
 834                 $smsg->{subject},
 835                 $smsg->{from},
 836                 PublicInbox::SearchMsg::date($smsg),
 837                 "<$smsg->{mid}>",
 838                 $smsg->{references},
 839                 $smsg->{bytes},
 840                 $smsg->{lines},
 841                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 842         utf8::encode($s);
 843         $s
 844 }
 845
 846 sub cmd_over ($;$) {
 847         my ($self, $range) = @_;
 848         if ($range && $range =~ /\A<(.+)>\z/) {
 849                 my ($ng, $n) = mid_lookup($self, $1);
 850                 defined $n or return r430;
 851                 my $smsg = $ng->over->get_art($n) or return r430;
 852                 more($self, '224 Overview information follows (multi-line)');
 853
 854                 # Only set article number column if it's the current group
 855                 my $self_ng = $self->{ng};
 856                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 857                 more($self, over_line($self, $ng, $n, $smsg));
 858                 '.';
 859         } else {
 860                 cmd_xover($self, $range);
 861         }
 862 }
 863
 864 sub cmd_xover ($;$) {
 865         my ($self, $range) = @_;
 866         $range = $self->{article} unless defined $range;
 867         my $r = get_range($self, $range);
 868         return $r unless ref $r;
 869         my ($beg, $end) = @$r;
 870         more($self, "224 Overview information follows for $$beg to $end");
 871         my $over = $self->{ng}->over;
 872         my $cur = $$beg;
 873         long_response($self, sub {
 874                 my $msgs = $over->query_xover($cur, $end);
 875                 my $nr = scalar @$msgs or return;
 876
 877                 # OVERVIEW.FMT
 878                 more($self, join("\r\n", map {
 879                         over_line($self, $self->{ng}, $_->{num}, $_);
 880                         } @$msgs));
 881                 $cur = $msgs->[-1]->{num} + 1;
 882         });
 883 }
 884
 885 sub compressed { undef }
 886
 887 sub cmd_starttls ($) {
 888         my ($self) = @_;
 889         my $sock = $self->{sock} or return;
 890         # RFC 4642 2.2.1
 891         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 892         my $opt = $self->{nntpd}->{accept_tls} or
 893                 return '580 can not initiate TLS negotiation';
 894         res($self, '382 Continue with TLS negotiation');
 895         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 896         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 897         undef;
 898 }
 899
 900 # RFC 8054
 901 sub cmd_compress ($$) {
 902         my ($self, $alg) = @_;
 903         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 904         return r502 if $self->compressed || !$have_deflate;
 905         PublicInbox::NNTPdeflate->enable($self);
 906         $self->requeue;
 907         undef
 908 }
 909
 910 sub zflush {} # overridden by NNTPdeflate
 911
 912 sub cmd_xpath ($$) {
 913         my ($self, $mid) = @_;
 914         return r501 unless $mid =~ /\A<(.+)>\z/;
 915         $mid = $1;
 916         my @paths;
 917         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 918                 my $n = $ng->mm->num_for($mid);
 919                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 920         }
 921         return '430 no such article on server' unless @paths;
 922         '223 '.join(' ', @paths);
 923 }
 924
 925 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 926
 927 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 928
 929 sub do_write ($$) {
 930         my $self = $_[0];
 931         my $done = $self->write(\($_[1]));
 932         return 0 unless $self->{sock};
 933
 934         $done;
 935 }
 936
 937 sub err ($$;@) {
 938         my ($self, $fmt, @args) = @_;
 939         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 940 }
 941
 942 sub out ($$;@) {
 943         my ($self, $fmt, @args) = @_;
 944         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 945 }
 946
 947 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 948 sub event_step {
 949         my ($self) = @_;
 950
 951         return unless $self->flush_write && $self->{sock};
 952
 953         $self->update_idle_time;
 954         # only read more requests if we've drained the write buffer,
 955         # otherwise we can be buffering infinitely w/o backpressure
 956
 957         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 958         my $r = 1;
 959
 960         if (index($$rbuf, "\n") < 0) {
 961                 my $off = bytes::length($$rbuf);
 962                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 963         }
 964         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 965                 my $line = $1;
 966                 return $self->close if $line =~ /[[:cntrl:]]/s;
 967                 my $t0 = now();
 968                 my $fd = fileno($self->{sock});
 969                 $r = eval { process_line($self, $line) };
 970                 my $pending = $self->{wbuf} ? ' pending' : '';
 971                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 972         }
 973
 974         return $self->close if $r < 0;
 975         my $len = bytes::length($$rbuf);
 976         return $self->close if ($len >= LINE_MAX);
 977         $self->rbuf_idle($rbuf);
 978         $self->update_idle_time;
 979
 980         # maybe there's more pipelined data, or we'll have
 981         # to register it for socket-readiness notifications
 982         $self->requeue unless $self->{wbuf};
 983 }
 984
 985 # for graceful shutdown in PublicInbox::Daemon:
 986 sub busy {
 987         my ($self, $now) = @_;
 988         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 989 }
 990
 991 # this is an import to prevent "perl -c" from complaining about fields
 992 sub import {
 993         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 994                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
 995 }
 996
 997 1;