lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ibx: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use PublicInbox::Address;
  21
  22 use constant {
  23         LINE_MAX => 512, # RFC 977 section 2.3
  24         r501 => '501 command syntax error',
  25         r502 => '502 Command unavailable',
  26         r221 => '221 Header follows',
  27         r224 => '224 Overview information follows (multi-line)',
  28         r225 => '225 Headers follow (multi-line)',
  29         r430 => '430 No article with that message-id',
  30 };
  31 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  32 use Errno qw(EAGAIN);
  33 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  34 my @OVERVIEW = qw(Subject From Date Message-ID References);
  35 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  36                 "Xref:full\r\n.";
  37 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  38                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  39 my $CAPABILITIES = <<"";
  40 101 Capability list:\r
  41 VERSION 2\r
  42 READER\r
  43 NEWNEWS\r
  44 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  45 HDR\r
  46 OVER\r
  47 COMPRESS DEFLATE\r
  48
  49 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  50
  51 sub new ($$$) {
  52         my ($class, $sock, $nntpd) = @_;
  53         my $self = bless { nntpd => $nntpd }, $class;
  54         my $ev = EPOLLIN;
  55         my $wbuf;
  56         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  57                 return CORE::close($sock) if $! != EAGAIN;
  58                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  59                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  60         }
  61         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  62         if ($wbuf) {
  63                 $self->{wbuf} = $wbuf;
  64         } else {
  65                 greet($self);
  66         }
  67         $self->update_idle_time;
  68         $self;
  69 }
  70
  71 sub args_ok ($$) {
  72         my ($cb, $argc) = @_;
  73         my $tot = prototype $cb;
  74         my ($nreq, undef) = split(';', $tot);
  75         $nreq = ($nreq =~ tr/$//) - 1;
  76         $tot = ($tot =~ tr/$//) - 1;
  77         ($argc <= $tot && $argc >= $nreq);
  78 }
  79
  80 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  81 sub process_line ($$) {
  82         my ($self, $l) = @_;
  83         my ($req, @args) = split(/[ \t]+/, $l);
  84         return 1 unless defined($req); # skip blank line
  85         $req = $self->can('cmd_'.lc($req));
  86         return res($self, '500 command not recognized') unless $req;
  87         return res($self, r501) unless args_ok($req, scalar @args);
  88
  89         my $res = eval { $req->($self, @args) };
  90         my $err = $@;
  91         if ($err && $self->{sock}) {
  92                 local $/ = "\n";
  93                 chomp($l);
  94                 err($self, 'error from: %s (%s)', $l, $err);
  95                 $res = '503 program fault - command not performed';
  96         }
  97         defined($res) ? res($self, $res) : 0;
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (!$self->{sock}->can('accept_SSL') &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 114 }
 115
 116 sub cmd_slave ($) { '202 slave status noted' }
 117
 118 sub cmd_xgtitle ($;$) {
 119         my ($self, $wildmat) = @_;
 120         more($self, '282 list of groups and descriptions follows');
 121         list_newsgroups($self, $wildmat);
 122 }
 123
 124 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 125
 126 sub list_headers ($;$) { $LIST_HEADERS }
 127
 128 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 129         my ($self, $groupnames) = @_;
 130         my @window = splice(@$groupnames, 0, 100) or return 0;
 131         my $ibx;
 132         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 135         }
 136         scalar(@$groupnames); # continue if there's more
 137 }
 138
 139 sub list_active ($;$) { # called by cmd_list
 140         my ($self, $wildmat) = @_;
 141         wildmat2re($wildmat);
 142         long_response($self, \&list_active_i, [
 143                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 144 }
 145
 146 sub list_active_times_i {
 147         my ($self, $groupnames) = @_;
 148         my @window = splice(@$groupnames, 0, 100) or return 0;
 149         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 150         for my $ngname (@window) {
 151                 my $ibx = $groups->{$ngname} or next;
 152                 my $c = eval { $ibx->uidvalidity } // time;
 153                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 154         }
 155         scalar(@$groupnames); # continue if there's more
 156 }
 157
 158 sub list_active_times ($;$) { # called by cmd_list
 159         my ($self, $wildmat) = @_;
 160         wildmat2re($wildmat);
 161         long_response($self, \&list_active_times_i, [
 162                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 163 }
 164
 165 sub list_newsgroups_i {
 166         my ($self, $groupnames) = @_;
 167         my @window = splice(@$groupnames, 0, 100) or return 0;
 168         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 169         my $ibx;
 170         for my $ngname (@window) {
 171                 $ibx = $groups->{$ngname} and
 172                         more($self, "$ngname ".$ibx->description);
 173         }
 174         scalar(@$groupnames); # continue if there's more
 175 }
 176
 177 sub list_newsgroups ($;$) { # called by cmd_list
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         long_response($self, \&list_newsgroups_i, [
 181                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 182 }
 183
 184 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 185 sub cmd_list ($;$$) {
 186         my ($self, @args) = @_;
 187         if (scalar @args) {
 188                 my $arg = shift @args;
 189                 $arg =~ tr/A-Z./a-z_/;
 190                 my $ret = $arg eq 'active';
 191                 $arg = "list_$arg";
 192                 $arg = $self->can($arg);
 193                 return r501 unless $arg && args_ok($arg, scalar @args);
 194                 more($self, '215 information follows');
 195                 $arg->($self, @args);
 196         } else {
 197                 more($self, '215 list of newsgroups follows');
 198                 long_response($self, \&list_active_i, [ # copy array
 199                         @{$self->{nntpd}->{groupnames}} ]);
 200         }
 201 }
 202
 203 sub listgroup_range_i {
 204         my ($self, $beg, $end) = @_;
 205         my $r = $self->{ibx}->mm->msg_range($beg, $end, 'num');
 206         scalar(@$r) or return;
 207         $self->msg_more(join('', map { "$_->[0]\r\n" } @$r));
 208         1;
 209 }
 210
 211 sub listgroup_all_i {
 212         my ($self, $num) = @_;
 213         my $ary = $self->{ibx}->mm->ids_after($num);
 214         scalar(@$ary) or return;
 215         more($self, join("\r\n", @$ary));
 216         1;
 217 }
 218
 219 sub cmd_listgroup ($;$$) {
 220         my ($self, $group, $range) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226         $self->{ibx} or return '412 no newsgroup selected';
 227         if (defined $range) {
 228                 my $r = get_range($self, $range);
 229                 return $r unless ref $r;
 230                 long_response($self, \&listgroup_range_i, @$r);
 231         } else { # grab every article number
 232                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 233         }
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my ($YYYY, $MM, $DD);
 244         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 my $YY;
 248                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my @now = $gmt ? gmtime : localtime;
 250                 my $cur_year = $now[5] + 1900;
 251                 my $cur_cent = int($cur_year / 100) * 100;
 252                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 253                         ($YY + 1900) : ($YY + $cur_cent);
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ibx) = @_;
 264         my ($min, $max) = $ibx->mm->minmax;
 265         more($self, "$ibx->{newsgroup} $max $min n");
 266 }
 267
 268 sub newgroups_i {
 269         my ($self, $ts, $i, $groupnames) = @_;
 270         my $end = $$i + 100;
 271         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 272         while ($$i < $end) {
 273                 my $ngname = $groupnames->[$$i++] // return;
 274                 my $ibx = $groups->{$ngname} or next; # expired on reload
 275                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 276                 group_line($self, $ibx);
 277         }
 278         1;
 279 }
 280
 281 sub cmd_newgroups ($$$;$$) {
 282         my ($self, $date, $time, $gmt, $dists) = @_;
 283         my $ts = eval { parse_time($date, $time, $gmt) };
 284         return r501 if $@;
 285
 286         # TODO dists
 287         more($self, '231 list of new newsgroups follows');
 288         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 289                                 $self->{nntpd}->{groupnames});
 290 }
 291
 292 sub wildmat2re (;$) {
 293         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 294         my %keep;
 295         my $salt = rand;
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub newnews_i {
 324         my ($self, $names, $ts, $prev) = @_;
 325         my $ngname = $names->[0];
 326         if (my $ibx = $self->{nntpd}->{pi_cfg}->{-by_newsgroup}->{$ngname}) {
 327                 if (my $over = $ibx->over) {
 328                         my $msgs = $over->query_ts($ts, $$prev);
 329                         if (scalar @$msgs) {
 330                                 $self->msg_more(join('', map {
 331                                                         "<$_->{mid}>\r\n";
 332                                                 } @$msgs));
 333                                 $$prev = $msgs->[-1]->{num};
 334                                 return 1; # continue on current group
 335                         }
 336                 }
 337         }
 338         shift @$names;
 339         if (@$names) { # continue onto next newsgroup
 340                 $$prev = 0;
 341                 1;
 342         } else { # all done, break out of the long_response
 343                 undef;
 344         }
 345 }
 346
 347 sub cmd_newnews ($$$$;$$) {
 348         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 349         my $ts = eval { parse_time($date, $time, $gmt) };
 350         return r501 if $@;
 351         more($self, '230 list of new articles by message-id follows');
 352         my ($keep, $skip) = split('!', $newsgroups, 2);
 353         ngpat2re($keep);
 354         ngpat2re($skip);
 355         my @names = grep(!/$skip/, grep(/$keep/,
 356                                 @{$self->{nntpd}->{groupnames}}));
 357         return '.' unless scalar(@names);
 358         my $prev = 0;
 359         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 360 }
 361
 362 sub cmd_group ($$) {
 363         my ($self, $group) = @_;
 364         my $nntpd = $self->{nntpd};
 365         my $ibx = $nntpd->{pi_cfg}->{-by_newsgroup}->{$group} or
 366                 return '411 no such news group';
 367         $nntpd->idler_start;
 368
 369         $self->{ibx} = $ibx;
 370         my ($min, $max) = $ibx->mm->minmax;
 371         $self->{article} = $min;
 372         my $est_size = $max - $min;
 373         "211 $est_size $min $max $group";
 374 }
 375
 376 sub article_adj ($$) {
 377         my ($self, $off) = @_;
 378         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 379
 380         my $n = $self->{article};
 381         defined $n or return '420 no current article has been selected';
 382
 383         $n += $off;
 384         my $mid = $ibx->mm->mid_for($n);
 385         unless ($mid) {
 386                 $n = $off > 0 ? 'next' : 'previous';
 387                 return "421 no $n article in this group";
 388         }
 389         $self->{article} = $n;
 390         "223 $n <$mid> article retrieved - request text separately";
 391 }
 392
 393 sub cmd_next ($) { article_adj($_[0], 1) }
 394 sub cmd_last ($) { article_adj($_[0], -1) }
 395
 396 # We want to encourage using email and CC-ing everybody involved to avoid
 397 # the single-point-of-failure a single server provides.
 398 sub cmd_post ($) {
 399         my ($self) = @_;
 400         my $ibx = $self->{ibx};
 401         $ibx ? "440 mailto:$ibx->{-primary_address} to post"
 402                 : '440 posting not allowed'
 403 }
 404
 405 sub cmd_quit ($) {
 406         my ($self) = @_;
 407         res($self, '205 closing connection - goodbye!');
 408         $self->shutdn;
 409         undef;
 410 }
 411
 412 sub header_append ($$$) {
 413         my ($hdr, $k, $v) = @_;
 414         my @v = $hdr->header_raw($k);
 415         foreach (@v) {
 416                 return if $v eq $_;
 417         }
 418         $hdr->header_set($k, @v, $v);
 419 }
 420
 421 sub xref_by_tc ($$$) {
 422         my ($xref, $pi_cfg, $smsg) = @_;
 423         my $by_addr = $pi_cfg->{-by_addr};
 424         my $mid = $smsg->{mid};
 425         for my $f (qw(to cc)) {
 426                 my @ibxs = map {
 427                         $by_addr->{lc($_)} // ()
 428                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 429                 for my $ibx (@ibxs) {
 430                         my $ngname = $ibx->{newsgroup} // next;
 431                         next if defined $xref->{$ngname};
 432                         $xref->{$ngname} = eval { $ibx->mm->num_for($mid) };
 433                 }
 434         }
 435 }
 436
 437 sub xref ($$$) {
 438         my ($self, $cur_ibx, $smsg) = @_;
 439         my $nntpd = $self->{nntpd};
 440         my $cur_ng = $cur_ibx->{newsgroup};
 441         my $xref;
 442         if (my $ALL = $nntpd->{pi_cfg}->ALL) {
 443                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 444                 xref_by_tc($xref, $nntpd->{pi_cfg}, $smsg);
 445         } else { # slow path
 446                 $xref = { $cur_ng => $smsg->{num} };
 447                 my $mid = $smsg->{mid};
 448                 for my $ibx (values %{$nntpd->{pi_cfg}->{-by_newsgroup}}) {
 449                         next if defined($xref->{$ibx->{newsgroup}});
 450                         my $num = eval { $ibx->mm->num_for($mid) } // next;
 451                         $xref->{$ibx->{newsgroup}} = $num;
 452                 }
 453         }
 454         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 455         $ret .= " $_:$xref->{$_}" for (sort keys %$xref);
 456         $ret;
 457 }
 458
 459 sub set_nntp_headers ($$) {
 460         my ($hdr, $smsg) = @_;
 461         my ($mid) = $smsg->{mid};
 462
 463         # leafnode (and maybe other NNTP clients) have trouble dealing
 464         # with v2 messages which have multiple Message-IDs (either due
 465         # to our own content-based dedupe or buggy git-send-email versions).
 466         my @mids = $hdr->header_raw('Message-ID');
 467         if (scalar(@mids) > 1) {
 468                 my $mid0 = "<$mid>";
 469                 $hdr->header_set('Message-ID', $mid0);
 470                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 471                 my %seen = map { $_ => 1 } (@alt, $mid0);
 472                 push(@alt, grep { !$seen{$_}++ } @mids);
 473                 $hdr->header_set('X-Alt-Message-ID', @alt);
 474         }
 475
 476         # clobber some existing headers
 477         my $ibx = $smsg->{-ibx};
 478         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 479         $hdr->header_set('Xref', $xref);
 480
 481         # RFC 5536 3.1.4
 482         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 483         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 484         $newsgroups =~ tr/ /,/;
 485         $hdr->header_set('Newsgroups', $newsgroups);
 486
 487         # *something* here is required for leafnode, try to follow
 488         # RFC 5536 3.1.5...
 489         $hdr->header_set('Path', $server_name . '!not-for-mail');
 490 }
 491
 492 sub art_lookup ($$$) {
 493         my ($self, $art, $code) = @_;
 494         my ($ibx, $n);
 495         my $err;
 496         if (defined $art) {
 497                 if ($art =~ /\A[0-9]+\z/) {
 498                         $err = '423 no such article number in this group';
 499                         $n = int($art);
 500                         goto find_ibx;
 501                 } elsif ($art =~ $ONE_MSGID) {
 502                         ($ibx, $n) = mid_lookup($self, $1);
 503                         goto found if $ibx;
 504                         return r430;
 505                 } else {
 506                         return r501;
 507                 }
 508         } else {
 509                 $err = '420 no current article has been selected';
 510                 $n = $self->{article} // return $err;
 511 find_ibx:
 512                 $ibx = $self->{ibx} or
 513                                 return '412 no newsgroup has been selected';
 514         }
 515 found:
 516         my $smsg = $ibx->over->get_art($n) or return $err;
 517         $smsg->{-ibx} = $ibx;
 518         if ($code == 223) { # STAT
 519                 set_art($self, $n);
 520                 "223 $n <$smsg->{mid}> article retrieved - " .
 521                         "request text separately";
 522         } else { # HEAD | BODY | ARTICLE
 523                 $smsg->{nntp} = $self;
 524                 $smsg->{nntp_code} = $code;
 525                 set_art($self, $art);
 526                 # this dereferences to `undef'
 527                 ${git_async_cat($ibx->git, $smsg->{blob}, \&blob_cb, $smsg)};
 528         }
 529 }
 530
 531 sub msg_body_write ($$) {
 532         my ($self, $msg) = @_;
 533
 534         # these can momentarily double the memory consumption :<
 535         $$msg =~ s/^\./../smg;
 536         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 537         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 538         $self->msg_more($$msg);
 539 }
 540
 541 sub set_art {
 542         my ($self, $art) = @_;
 543         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 544 }
 545
 546 sub msg_hdr_write ($$) {
 547         my ($eml, $smsg) = @_;
 548         set_nntp_headers($eml, $smsg);
 549
 550         my $hdr = $eml->{hdr} // \(my $x = '');
 551         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 552         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 553         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 554
 555         # for leafnode compatibility, we need to ensure Message-ID headers
 556         # are only a single line.
 557         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 558         $smsg->{nntp}->msg_more($$hdr);
 559 }
 560
 561 sub blob_cb { # called by git->cat_async via git_async_cat
 562         my ($bref, $oid, $type, $size, $smsg) = @_;
 563         my $self = $smsg->{nntp};
 564         my $code = $smsg->{nntp_code};
 565         if (!defined($oid)) {
 566                 # it's possible to have TOCTOU if an admin runs
 567                 # public-inbox-(edit|purge), just move onto the next message
 568                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 569                 return $self->requeue;
 570         } elsif ($smsg->{blob} ne $oid) {
 571                 $self->close;
 572                 die "BUG: $smsg->{blob} != $oid";
 573         }
 574         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 575         my $eml = PublicInbox::Eml->new($bref);
 576         if ($code == 220) {
 577                 more($self, $r .= 'head and body follow');
 578                 msg_hdr_write($eml, $smsg);
 579                 $self->msg_more("\r\n");
 580                 msg_body_write($self, $bref);
 581         } elsif ($code == 221) {
 582                 more($self, $r .= 'head follows');
 583                 msg_hdr_write($eml, $smsg);
 584         } elsif ($code == 222) {
 585                 more($self, $r .= 'body follows');
 586                 msg_body_write($self, $bref);
 587         } else {
 588                 $self->close;
 589                 die "BUG: bad code: $r";
 590         }
 591         $self->write(\".\r\n"); # flushes (includes ->zflush)
 592         $self->requeue;
 593 }
 594
 595 sub cmd_article ($;$) {
 596         my ($self, $art) = @_;
 597         art_lookup($self, $art, 220);
 598 }
 599
 600 sub cmd_head ($;$) {
 601         my ($self, $art) = @_;
 602         art_lookup($self, $art, 221);
 603 }
 604
 605 sub cmd_body ($;$) {
 606         my ($self, $art) = @_;
 607         art_lookup($self, $art, 222);
 608 }
 609
 610 sub cmd_stat ($;$) {
 611         my ($self, $art) = @_;
 612         art_lookup($self, $art, 223); # art may be msgid
 613 }
 614
 615 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 616
 617 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 618
 619 sub cmd_help ($) {
 620         my ($self) = @_;
 621         more($self, '100 help text follows');
 622         '.'
 623 }
 624
 625 sub get_range ($$) {
 626         my ($self, $range) = @_;
 627         my $ibx = $self->{ibx} or return '412 no news group has been selected';
 628         defined $range or return '420 No article(s) selected';
 629         my ($beg, $end);
 630         my ($min, $max) = $ibx->mm->minmax;
 631         if ($range =~ /\A([0-9]+)\z/) {
 632                 $beg = $end = $1;
 633         } elsif ($range =~ /\A([0-9]+)-\z/) {
 634                 ($beg, $end) = ($1, $max);
 635         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 636                 ($beg, $end) = ($1, $2);
 637         } else {
 638                 return r501;
 639         }
 640         $beg = $min if ($beg < $min);
 641         $end = $max if ($end > $max);
 642         return '420 No article(s) selected' if ($beg > $end);
 643         [ \$beg, $end ];
 644 }
 645
 646 sub long_step {
 647         my ($self) = @_;
 648         # wbuf is unset or empty, here; {long} may add to it
 649         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 650         my $more = eval { $cb->($self, @args) };
 651         if ($@ || !$self->{sock}) { # something bad happened...
 652                 delete $self->{long_cb};
 653                 my $elapsed = now() - $t0;
 654                 if ($@) {
 655                         err($self,
 656                             "%s during long response[$fd] - %0.6f",
 657                             $@, $elapsed);
 658                 }
 659                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 660                 $self->close;
 661         } elsif ($more) { # $self->{wbuf}:
 662                 $self->update_idle_time;
 663
 664                 # COMPRESS users all share the same DEFLATE context.
 665                 # Flush it here to ensure clients don't see
 666                 # each other's data
 667                 $self->zflush;
 668
 669                 # no recursion, schedule another call ASAP, but only after
 670                 # all pending writes are done.  autovivify wbuf:
 671                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 672
 673                 # wbuf may be populated by $cb, no need to rearm if so:
 674                 $self->requeue if $new_size == 1;
 675         } else { # all done!
 676                 delete $self->{long_cb};
 677                 res($self, '.');
 678                 my $elapsed = now() - $t0;
 679                 my $fd = fileno($self->{sock});
 680                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 681                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 682                 $self->requeue unless $wbuf && @$wbuf;
 683         }
 684 }
 685
 686 sub long_response ($$;@) {
 687         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 688
 689         my $sock = $self->{sock} or return;
 690         # make sure we disable reading during a long response,
 691         # clients should not be sending us stuff and making us do more
 692         # work while we are stream a response to them
 693         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 694         long_step($self); # kick off!
 695         undef;
 696 }
 697
 698 sub hdr_msgid_range_i {
 699         my ($self, $beg, $end) = @_;
 700         my $r = $self->{ibx}->mm->msg_range($beg, $end);
 701         @$r or return;
 702         $self->msg_more(join('', map { "$_->[0] <$_->[1]>\r\n" } @$r));
 703         1;
 704 }
 705
 706 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 707         my ($self, $xhdr, $range) = @_;
 708
 709         if (defined $range && $range =~ $ONE_MSGID) {
 710                 my ($ibx, $n) = mid_lookup($self, $1);
 711                 return r430 unless $n;
 712                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $range);
 713         } else { # numeric range
 714                 $range = $self->{article} unless defined $range;
 715                 my $r = get_range($self, $range);
 716                 return $r unless ref $r;
 717                 more($self, $xhdr ? r221 : r225);
 718                 long_response($self, \&hdr_msgid_range_i, @$r);
 719         }
 720 }
 721
 722 sub mid_lookup ($$) {
 723         my ($self, $mid) = @_;
 724         my $cur_ibx = $self->{ibx};
 725         if ($cur_ibx) {
 726                 my $n = $cur_ibx->mm->num_for($mid);
 727                 return ($cur_ibx, $n) if defined $n;
 728         }
 729         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 730         if (my $ALL = $pi_cfg->ALL) {
 731                 my ($id, $prev);
 732                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 733                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 734                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 735                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 736                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 737                                 return ($ibx, $xnum) if $ibx;
 738                                 # fall through to trying all xref3s
 739                         } else {
 740                                 warn <<EOF;
 741 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 742 EOF
 743                         }
 744                         # try all xref3s
 745                         for my $x (@$xr3) {
 746                                 my ($ngname, $xnum) = split(/:/, $x);
 747                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 748                                 return ($ibx, $xnum) if $ibx;
 749                                 warn "W: `$ngname' does not exist for #$xnum\n";
 750                         }
 751                 }
 752                 # no warning here, $mid is just invalid
 753         } else { # slow path for non-ALL users
 754                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 755                         next if defined $cur_ibx && $ibx eq $cur_ibx;
 756                         my $n = $ibx->mm->num_for($mid);
 757                         return ($ibx, $n) if defined $n;
 758                 }
 759         }
 760         (undef, undef);
 761 }
 762
 763 sub xref_range_i {
 764         my ($self, $beg, $end) = @_;
 765         my $ibx = $self->{ibx};
 766         my $msgs = $ibx->over->query_xover($$beg, $end);
 767         scalar(@$msgs) or return;
 768         $$beg = $msgs->[-1]->{num} + 1;
 769         $self->msg_more(join('', map {
 770                 "$_->{num} ".xref($self, $ibx, $_) . "\r\n";
 771         } @$msgs));
 772         1;
 773 }
 774
 775 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 776         my ($self, $xhdr, $range) = @_;
 777
 778         if (defined $range && $range =~ $ONE_MSGID) {
 779                 my $mid = $1;
 780                 my ($ibx, $n) = mid_lookup($self, $mid);
 781                 return r430 unless $n;
 782                 my $smsg = $ibx->over->get_art($n) or return;
 783                 hdr_mid_response($self, $xhdr, $ibx, $n, $range,
 784                                 xref($self, $ibx, $smsg));
 785         } else { # numeric range
 786                 $range = $self->{article} unless defined $range;
 787                 my $r = get_range($self, $range);
 788                 return $r unless ref $r;
 789                 more($self, $xhdr ? r221 : r225);
 790                 long_response($self, \&xref_range_i, @$r);
 791         }
 792 }
 793
 794 sub over_header_for {
 795         my ($over, $num, $field) = @_;
 796         my $smsg = $over->get_art($num) or return;
 797         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 798         $smsg->{$field};
 799 }
 800
 801 sub smsg_range_i {
 802         my ($self, $beg, $end, $field) = @_;
 803         my $over = $self->{ibx}->over;
 804         my $msgs = $over->query_xover($$beg, $end);
 805         scalar(@$msgs) or return;
 806         my $tmp = '';
 807
 808         # ->{$field} is faster than ->$field invocations, so favor that.
 809         if ($field eq 'date') {
 810                 for my $s (@$msgs) {
 811                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 812                 }
 813         } else {
 814                 for my $s (@$msgs) {
 815                         $tmp .= "$s->{num} $s->{$field}\r\n";
 816                 }
 817         }
 818         utf8::encode($tmp);
 819         $self->msg_more($tmp);
 820         $$beg = $msgs->[-1]->{num} + 1;
 821 }
 822
 823 sub hdr_smsg ($$$$) {
 824         my ($self, $xhdr, $field, $range) = @_;
 825         if (defined $range && $range =~ $ONE_MSGID) {
 826                 my ($ibx, $n) = mid_lookup($self, $1);
 827                 return r430 unless defined $n;
 828                 my $v = over_header_for($ibx->over, $n, $field);
 829                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $v);
 830         } else { # numeric range
 831                 $range = $self->{article} unless defined $range;
 832                 my $r = get_range($self, $range);
 833                 return $r unless ref $r;
 834                 more($self, $xhdr ? r221 : r225);
 835                 long_response($self, \&smsg_range_i, @$r, $field);
 836         }
 837 }
 838
 839 sub do_hdr ($$$;$) {
 840         my ($self, $xhdr, $header, $range) = @_;
 841         my $sub = lc $header;
 842         if ($sub eq 'message-id') {
 843                 hdr_message_id($self, $xhdr, $range);
 844         } elsif ($sub eq 'xref') {
 845                 hdr_xref($self, $xhdr, $range);
 846         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 847                                 bytes|lines)\z/x) {
 848                 hdr_smsg($self, $xhdr, $sub, $range);
 849         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 850                 hdr_smsg($self, $xhdr, $1, $range);
 851         } else {
 852                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 853         }
 854 }
 855
 856 # RFC 3977
 857 sub cmd_hdr ($$;$) {
 858         my ($self, $header, $range) = @_;
 859         do_hdr($self, 0, $header, $range);
 860 }
 861
 862 # RFC 2980
 863 sub cmd_xhdr ($$;$) {
 864         my ($self, $header, $range) = @_;
 865         do_hdr($self, 1, $header, $range);
 866 }
 867
 868 sub hdr_mid_prefix ($$$$$) {
 869         my ($self, $xhdr, $ibx, $n, $mid) = @_;
 870         return $mid if $xhdr;
 871
 872         # HDR for RFC 3977 users
 873         if (my $cur_ibx = $self->{ibx}) {
 874                 ($cur_ibx eq $ibx) ? $n : '0';
 875         } else {
 876                 '0';
 877         }
 878 }
 879
 880 sub hdr_mid_response ($$$$$$) {
 881         my ($self, $xhdr, $ibx, $n, $mid, $v) = @_;
 882         my $res = '';
 883         if ($xhdr) {
 884                 $res .= r221 . "\r\n";
 885                 $res .= "$mid $v\r\n";
 886         } else {
 887                 $res .= r225 . "\r\n";
 888                 my $pfx = hdr_mid_prefix($self, $xhdr, $ibx, $n, $mid);
 889                 $res .= "$pfx $v\r\n";
 890         }
 891         res($self, $res .= '.');
 892         undef;
 893 }
 894
 895 sub xrover_i {
 896         my ($self, $beg, $end) = @_;
 897         my $h = over_header_for($self->{ibx}->over, $$beg, 'references');
 898         more($self, "$$beg $h") if defined($h);
 899         $$beg++ < $end;
 900 }
 901
 902 sub cmd_xrover ($;$) {
 903         my ($self, $range) = @_;
 904         my $ibx = $self->{ibx} or return '412 no newsgroup selected';
 905         (defined $range && $range =~ /[<>]/) and
 906                 return '420 No article(s) selected'; # no message IDs
 907
 908         $range = $self->{article} unless defined $range;
 909         my $r = get_range($self, $range);
 910         return $r unless ref $r;
 911         more($self, '224 Overview information follows');
 912         long_response($self, \&xrover_i, @$r);
 913 }
 914
 915 sub over_line ($$$) {
 916         my ($self, $ibx, $smsg) = @_;
 917         # n.b. field access and procedural calls can be
 918         # 10%-15% faster than OO method calls:
 919         my $s = join("\t", $smsg->{num},
 920                 $smsg->{subject},
 921                 $smsg->{from},
 922                 PublicInbox::Smsg::date($smsg),
 923                 "<$smsg->{mid}>",
 924                 $smsg->{references},
 925                 $smsg->{bytes},
 926                 $smsg->{lines},
 927                 "Xref: " . xref($self, $ibx, $smsg));
 928         utf8::encode($s);
 929         $s .= "\r\n";
 930 }
 931
 932 sub cmd_over ($;$) {
 933         my ($self, $range) = @_;
 934         if ($range && $range =~ $ONE_MSGID) {
 935                 my ($ibx, $n) = mid_lookup($self, $1);
 936                 defined $n or return r430;
 937                 my $smsg = $ibx->over->get_art($n) or return r430;
 938                 more($self, '224 Overview information follows (multi-line)');
 939
 940                 # Only set article number column if it's the current group
 941                 # (RFC 3977 8.3.2)
 942                 my $cur_ibx = $self->{ibx};
 943                 if (!$cur_ibx || $cur_ibx ne $ibx) {
 944                         # set {-orig_num} for nntp_xref_for
 945                         $smsg->{-orig_num} = $smsg->{num};
 946                         $smsg->{num} = 0;
 947                 }
 948                 $self->msg_more(over_line($self, $ibx, $smsg));
 949                 '.';
 950         } else {
 951                 cmd_xover($self, $range);
 952         }
 953 }
 954
 955 sub xover_i {
 956         my ($self, $beg, $end) = @_;
 957         my $ibx = $self->{ibx};
 958         my $msgs = $ibx->over->query_xover($$beg, $end);
 959         my $nr = scalar @$msgs or return;
 960
 961         # OVERVIEW.FMT
 962         $self->msg_more(join('', map {
 963                 over_line($self, $ibx, $_);
 964                 } @$msgs));
 965         $$beg = $msgs->[-1]->{num} + 1;
 966 }
 967
 968 sub cmd_xover ($;$) {
 969         my ($self, $range) = @_;
 970         $range = $self->{article} unless defined $range;
 971         my $r = get_range($self, $range);
 972         return $r unless ref $r;
 973         my ($beg, $end) = @$r;
 974         more($self, "224 Overview information follows for $$beg to $end");
 975         long_response($self, \&xover_i, @$r);
 976 }
 977
 978 sub compressed { undef }
 979
 980 sub cmd_starttls ($) {
 981         my ($self) = @_;
 982         my $sock = $self->{sock} or return;
 983         # RFC 4642 2.2.1
 984         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 985         my $opt = $self->{nntpd}->{accept_tls} or
 986                 return '580 can not initiate TLS negotiation';
 987         res($self, '382 Continue with TLS negotiation');
 988         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 989         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 990         undef;
 991 }
 992
 993 # RFC 8054
 994 sub cmd_compress ($$) {
 995         my ($self, $alg) = @_;
 996         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 997         return r502 if $self->compressed;
 998         PublicInbox::NNTPdeflate->enable($self);
 999         $self->requeue;
1000         undef
1001 }
1002
1003 sub zflush {} # overridden by NNTPdeflate
1004
1005 sub cmd_xpath ($$) {
1006         my ($self, $mid) = @_;
1007         return r501 unless $mid =~ $ONE_MSGID;
1008         $mid = $1;
1009         my @paths;
1010         my $pi_cfg = $self->{nntpd}->{pi_cfg};
1011         my $groups = $pi_cfg->{-by_newsgroup};
1012         if (my $ALL = $pi_cfg->ALL) {
1013                 my ($id, $prev, %seen);
1014                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
1015                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
1016                         for my $x (@$xr3) {
1017                                 my ($ngname, $n) = split(/:/, $x);
1018                                 $x = "$ngname/$n";
1019                                 if ($groups->{$ngname} && !$seen{$x}++) {
1020                                         push(@paths, $x);
1021                                 }
1022                         }
1023                 }
1024         } else { # slow path, no point in using long_response
1025                 for my $ibx (values %$groups) {
1026                         my $n = $ibx->mm->num_for($mid) // next;
1027                         push @paths, "$ibx->{newsgroup}/$n";
1028                 }
1029         }
1030         return '430 no such article on server' unless @paths;
1031         '223 '.join(' ', sort(@paths));
1032 }
1033
1034 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1035
1036 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1037
1038 sub do_write ($$) {
1039         my $self = $_[0];
1040         my $done = $self->write(\($_[1]));
1041         return 0 unless $self->{sock};
1042
1043         $done;
1044 }
1045
1046 sub err ($$;@) {
1047         my ($self, $fmt, @args) = @_;
1048         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1049 }
1050
1051 sub out ($$;@) {
1052         my ($self, $fmt, @args) = @_;
1053         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1054 }
1055
1056 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1057 sub event_step {
1058         my ($self) = @_;
1059
1060         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1061
1062         $self->update_idle_time;
1063         # only read more requests if we've drained the write buffer,
1064         # otherwise we can be buffering infinitely w/o backpressure
1065
1066         my $rbuf = $self->{rbuf} // \(my $x = '');
1067         my $line = index($$rbuf, "\n");
1068         while ($line < 0) {
1069                 return $self->close if length($$rbuf) >= LINE_MAX;
1070                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1071                 $line = index($$rbuf, "\n");
1072         }
1073         $line = substr($$rbuf, 0, $line + 1, '');
1074         $line =~ s/\r?\n\z//s;
1075         return $self->close if $line =~ /[[:cntrl:]]/s;
1076
1077         my $t0 = now();
1078         my $fd = fileno($self->{sock});
1079         my $r = eval { process_line($self, $line) };
1080         my $pending = $self->{wbuf} ? ' pending' : '';
1081         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1082         return $self->close if $r < 0;
1083         $self->rbuf_idle($rbuf);
1084         $self->update_idle_time;
1085
1086         # maybe there's more pipelined data, or we'll have
1087         # to register it for socket-readiness notifications
1088         $self->requeue unless $pending;
1089 }
1090
1091 # for graceful shutdown in PublicInbox::Daemon:
1092 sub busy {
1093         my ($self, $now) = @_;
1094         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1095 }
1096
1097 1;