lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::MIME;
  15 use Data::Dumper qw(Dumper);
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $EXPTIMER;
  40 our $EXPTIME = 180; # 3 minutes
  41
  42 sub update_idle_time ($) {
  43         my ($self) = @_;
  44         my $tmp = $self->{sock} or return;
  45         $tmp = fileno($tmp);
  46         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  47 }
  48
  49 sub expire_old () {
  50         my $now = now();
  51         my $exp = $EXPTIME;
  52         my $old = $now - $exp;
  53         my $next = $now + $exp;
  54         my $nr = 0;
  55         my %new;
  56         while (my ($fd, $v) = each %$EXPMAP) {
  57                 my ($idle_time, $nntp) = @$v;
  58                 if ($idle_time < $old) {
  59                         $nntp->close; # idempotent
  60                 } else {
  61                         my $nexp = $idle_time + $exp;
  62                         $next = $nexp if ($nexp < $next);
  63                         ++$nr;
  64                         $new{$fd} = $v;
  65                 }
  66         }
  67         $EXPMAP = \%new;
  68         if ($nr) {
  69                 $next -= $now;
  70                 $next = 0 if $next < 0;
  71                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
  72         } else {
  73                 $EXPTIMER = undef;
  74                 # noop to kick outselves out of the loop so descriptors
  75                 # really get closed
  76                 Danga::Socket->AddTimer(0, sub {});
  77         }
  78 }
  79
  80 sub new ($$$) {
  81         my ($class, $sock, $nntpd) = @_;
  82         my $self = fields::new($class);
  83         binmode $sock, ':utf8'; # RFC 3977
  84         $self->SUPER::new($sock);
  85         $self->{nntpd} = $nntpd;
  86         res($self, '201 server ready - post via email');
  87         $self->{rbuf} = '';
  88         $self->watch_read(1);
  89         update_idle_time($self);
  90         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
  91         $self;
  92 }
  93
  94 sub args_ok ($$) {
  95         my ($cb, $argc) = @_;
  96         my $tot = prototype $cb;
  97         my ($nreq, undef) = split(';', $tot);
  98         $nreq = ($nreq =~ tr/$//) - 1;
  99         $tot = ($tot =~ tr/$//) - 1;
 100         ($argc <= $tot && $argc >= $nreq);
 101 }
 102
 103 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 104 sub process_line ($$) {
 105         my ($self, $l) = @_;
 106         my ($req, @args) = split(/\s+/, $l);
 107         $req = lc($req);
 108         $req = eval {
 109                 no strict 'refs';
 110                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 111         };
 112         return res($self, '500 command not recognized') unless $req;
 113         return res($self, r501) unless args_ok($req, scalar @args);
 114
 115         my $res = eval { $req->($self, @args) };
 116         my $err = $@;
 117         if ($err && !$self->{closed}) {
 118                 chomp($l = Dumper(\$l));
 119                 err($self, 'error from: %s (%s)', $l, $err);
 120                 $res = '503 program fault - command not performed';
 121         }
 122         return 0 unless defined $res;
 123         res($self, $res);
 124 }
 125
 126 sub cmd_mode ($$) {
 127         my ($self, $arg) = @_;
 128         $arg = uc $arg;
 129         return r501 unless $arg eq 'READER';
 130         '201 Posting prohibited';
 131 }
 132
 133 sub cmd_slave ($) { '202 slave status noted' }
 134
 135 sub cmd_xgtitle ($;$) {
 136         my ($self, $wildmat) = @_;
 137         more($self, '282 list of groups and descriptions follows');
 138         list_newsgroups($self, $wildmat);
 139         '.'
 140 }
 141
 142 sub list_overview_fmt ($) {
 143         my ($self) = @_;
 144         do_more($self, $OVERVIEW_FMT);
 145 }
 146
 147 sub list_headers ($;$) {
 148         my ($self) = @_;
 149         do_more($self, $LIST_HEADERS);
 150 }
 151
 152 sub list_active ($;$) {
 153         my ($self, $wildmat) = @_;
 154         wildmat2re($wildmat);
 155         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 156                 $ng->{name} =~ $wildmat or next;
 157                 group_line($self, $ng);
 158         }
 159 }
 160
 161 sub list_active_times ($;$) {
 162         my ($self, $wildmat) = @_;
 163         wildmat2re($wildmat);
 164         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 165                 $ng->{name} =~ $wildmat or next;
 166                 my $c = eval { $ng->mm->created_at } || time;
 167                 more($self, "$ng->{name} $c $ng->{address}");
 168         }
 169 }
 170
 171 sub list_newsgroups ($;$) {
 172         my ($self, $wildmat) = @_;
 173         wildmat2re($wildmat);
 174         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 175                 $ng->{name} =~ $wildmat or next;
 176                 my $d = $ng->description;
 177                 more($self, "$ng->{name} $d");
 178         }
 179 }
 180
 181 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 182 sub cmd_list ($;$$) {
 183         my ($self, @args) = @_;
 184         if (scalar @args) {
 185                 my $arg = shift @args;
 186                 $arg =~ tr/A-Z./a-z_/;
 187                 $arg = "list_$arg";
 188                 return r501 if $DISABLED{$arg};
 189
 190                 $arg = eval {
 191                         no strict 'refs';
 192                         *{$arg}{CODE};
 193                 };
 194                 return r501 unless $arg && args_ok($arg, scalar @args);
 195                 more($self, '215 information follows');
 196                 $arg->($self, @args);
 197         } else {
 198                 more($self, '215 list of newsgroups follows');
 199                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 200                         group_line($self, $ng);
 201                 }
 202         }
 203         '.'
 204 }
 205
 206 sub cmd_listgroup ($;$) {
 207         my ($self, $group) = @_;
 208         if (defined $group) {
 209                 my $res = cmd_group($self, $group);
 210                 return $res if ($res !~ /\A211 /);
 211                 more($self, $res);
 212         }
 213
 214         $self->{ng} or return '412 no newsgroup selected';
 215         $self->long_response(0, long_response_limit, sub {
 216                 my ($i) = @_;
 217                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 218                         my ($ary) = @_;
 219                         more($self, join("\r\n", @$ary));
 220                 });
 221
 222                 # -1 to adjust for implicit increment in long_response
 223                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 224         });
 225 }
 226
 227 sub parse_time ($$;$) {
 228         my ($date, $time, $gmt) = @_;
 229         use Time::Local qw();
 230         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 231         if (defined $gmt) {
 232                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 233                 $gmt = 1;
 234         }
 235         my @now = $gmt ? gmtime : localtime;
 236         my ($YYYY, $MM, $DD);
 237         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 238                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 239         } else { # legacy clients send YYMMDD
 240                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 241                 if ($YYYY > strftime('%y', @now)) {
 242                         my $cur_year = $now[5] + 1900;
 243                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 244                 }
 245         }
 246         if ($gmt) {
 247                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 248         } else {
 249                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 250         }
 251 }
 252
 253 sub group_line ($$) {
 254         my ($self, $ng) = @_;
 255         my ($min, $max) = $ng->mm->minmax;
 256         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 257 }
 258
 259 sub cmd_newgroups ($$$;$$) {
 260         my ($self, $date, $time, $gmt, $dists) = @_;
 261         my $ts = eval { parse_time($date, $time, $gmt) };
 262         return r501 if $@;
 263
 264         # TODO dists
 265         more($self, '231 list of new newsgroups follows');
 266         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 267                 my $c = eval { $ng->mm->created_at } || 0;
 268                 next unless $c > $ts;
 269                 group_line($self, $ng);
 270         }
 271         '.'
 272 }
 273
 274 sub wildmat2re (;$) {
 275         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 276         my %keep;
 277         my $salt = rand;
 278         use Digest::SHA qw(sha1_hex);
 279         my $tmp = $_[0];
 280
 281         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 282                 my $orig = $1;
 283                 my $key = sha1_hex($orig . $salt);
 284                 $orig =~ s/([^\w\-])+/\Q$1/g;
 285                 $keep{$key} = $orig;
 286                 $key
 287                 #gex;
 288         my %map = ('*' => '.*', '?' => '.' );
 289         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 290         if (scalar %keep) {
 291                 $tmp =~ s#([a-f0-9]{40})#
 292                         my $orig = $keep{$1};
 293                         defined $orig ? $orig : $1;
 294                         #ge;
 295         }
 296         $_[0] = qr/\A$tmp\z/;
 297 }
 298
 299 sub ngpat2re (;$) {
 300         return $_[0] = qr/\A\z/ unless defined $_[0];
 301         my %map = ('*' => '.*', ',' => '|');
 302         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 303         $_[0] = qr/\A(?:$_[0])\z/;
 304 }
 305
 306 sub cmd_newnews ($$$$;$$) {
 307         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 308         my $ts = eval { parse_time($date, $time, $gmt) };
 309         return r501 if $@;
 310         more($self, '230 list of new articles by message-id follows');
 311         my ($keep, $skip) = split('!', $newsgroups, 2);
 312         ngpat2re($keep);
 313         ngpat2re($skip);
 314         my @srch;
 315         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 316                 $ng->{name} =~ $keep or next;
 317                 $ng->{name} =~ $skip and next;
 318                 my $srch = $ng->search or next;
 319                 push @srch, $srch;
 320         };
 321         return '.' unless @srch;
 322
 323         $ts .= '..';
 324         my $opts = { asc => 1, limit => 1000, offset => 0 };
 325         $self->long_response(0, long_response_limit, sub {
 326                 my ($i) = @_;
 327                 my $srch = $srch[0];
 328                 my $res = $srch->query($ts, $opts);
 329                 my $msgs = $res->{msgs};
 330                 if (my $nr = scalar @$msgs) {
 331                         more($self, '<' .
 332                                 join(">\r\n<", map { $_->mid } @$msgs ).
 333                                 '>');
 334                         $opts->{offset} += $nr;
 335                 } else {
 336                         shift @srch;
 337                         if (@srch) { # continue onto next newsgroup
 338                                 $opts->{offset} = 0;
 339                         } else { # break out of the long response.
 340                                 $$i = long_response_limit;
 341                         }
 342                 }
 343         });
 344 }
 345
 346 sub cmd_group ($$) {
 347         my ($self, $group) = @_;
 348         my $no_such = '411 no such news group';
 349         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 350
 351         $self->{ng} = $ng;
 352         my ($min, $max) = $ng->mm->minmax;
 353         $min ||= 0;
 354         $max ||= 0;
 355         $self->{article} = $min;
 356         my $est_size = $max - $min;
 357         "211 $est_size $min $max $group";
 358 }
 359
 360 sub article_adj ($$) {
 361         my ($self, $off) = @_;
 362         my $ng = $self->{ng} or return '412 no newsgroup selected';
 363
 364         my $n = $self->{article};
 365         defined $n or return '420 no current article has been selected';
 366
 367         $n += $off;
 368         my $mid = $ng->mm->mid_for($n);
 369         unless ($mid) {
 370                 $n = $off > 0 ? 'next' : 'previous';
 371                 return "421 no $n article in this group";
 372         }
 373         $self->{article} = $n;
 374         "223 $n <$mid> article retrieved - request text separately";
 375 }
 376
 377 sub cmd_next ($) { article_adj($_[0], 1) }
 378 sub cmd_last ($) { article_adj($_[0], -1) }
 379
 380 # We want to encourage using email and CC-ing everybody involved to avoid
 381 # the single-point-of-failure a single server provides.
 382 sub cmd_post ($) {
 383         my ($self) = @_;
 384         my $ng = $self->{ng};
 385         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 386 }
 387
 388 sub cmd_quit ($) {
 389         my ($self) = @_;
 390         res($self, '205 closing connection - goodbye!');
 391         $self->close;
 392         undef;
 393 }
 394
 395 sub art_lookup ($$$) {
 396         my ($self, $art, $set_headers) = @_;
 397         my $ng = $self->{ng};
 398         my ($n, $mid);
 399         my $err;
 400         if (defined $art) {
 401                 if ($art =~ /\A\d+\z/o) {
 402                         $err = '423 no such article number in this group';
 403                         $n = int($art);
 404                         goto find_mid;
 405                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 406                         $mid = $1;
 407                         $err = r430;
 408                         $n = $ng->mm->num_for($mid) if $ng;
 409                         goto found if defined $n;
 410                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 411                                 $n = $g->mm->num_for($mid);
 412                                 if (defined $n) {
 413                                         $ng = $g;
 414                                         goto found;
 415                                 }
 416                         }
 417                         return $err;
 418                 } else {
 419                         return r501;
 420                 }
 421         } else {
 422                 $err = '420 no current article has been selected';
 423                 $n = $self->{article};
 424                 defined $n or return $err;
 425 find_mid:
 426                 $ng or return '412 no newsgroup has been selected';
 427                 $mid = $ng->mm->mid_for($n);
 428                 defined $mid or return $err;
 429         }
 430 found:
 431         my $o = 'HEAD:' . mid2path($mid);
 432         my $bytes;
 433         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 434         return $err unless $s;
 435         my $lines;
 436         if ($set_headers) {
 437                 $s->header_set('Newsgroups', $ng->{name});
 438                 $s->header_set('Xref', xref($ng, $n));
 439                 $lines = $s->body =~ tr!\n!\n!;
 440
 441                 # must be last
 442                 $s->body_set('') if ($set_headers == 2);
 443         }
 444         [ $n, $mid, $s, $bytes, $lines, $ng ];
 445 }
 446
 447 sub simple_body_write ($$) {
 448         my ($self, $s) = @_;
 449         my $body = $s->body;
 450         $s->body_set('');
 451         $body =~ s/^\./../smg;
 452         $body =~ s/(?<!\r)\n/\r\n/sg;
 453         do_more($self, $body);
 454         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 455         '.'
 456 }
 457
 458 sub set_art {
 459         my ($self, $art) = @_;
 460         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 461 }
 462
 463 sub cmd_article ($;$) {
 464         my ($self, $art) = @_;
 465         my $r = $self->art_lookup($art, 1);
 466         return $r unless ref $r;
 467         my ($n, $mid, $s) = @$r;
 468         set_art($self, $art);
 469         more($self, "220 $n <$mid> article retrieved - head and body follow");
 470         do_more($self, $s->header_obj->as_string);
 471         do_more($self, "\r\n");
 472         simple_body_write($self, $s);
 473 }
 474
 475 sub cmd_head ($;$) {
 476         my ($self, $art) = @_;
 477         my $r = $self->art_lookup($art, 2);
 478         return $r unless ref $r;
 479         my ($n, $mid, $s) = @$r;
 480         set_art($self, $art);
 481         more($self, "221 $n <$mid> article retrieved - head follows");
 482         do_more($self, $s->header_obj->as_string);
 483         '.'
 484 }
 485
 486 sub cmd_body ($;$) {
 487         my ($self, $art) = @_;
 488         my $r = $self->art_lookup($art, 0);
 489         return $r unless ref $r;
 490         my ($n, $mid, $s) = @$r;
 491         set_art($self, $art);
 492         more($self, "222 $n <$mid> article retrieved - body follows");
 493         simple_body_write($self, $s);
 494 }
 495
 496 sub cmd_stat ($;$) {
 497         my ($self, $art) = @_;
 498         my $r = $self->art_lookup($art, 0);
 499         return $r unless ref $r;
 500         my ($n, $mid, undef) = @$r;
 501         set_art($self, $art);
 502         "223 $n <$mid> article retrieved - request text separately";
 503 }
 504
 505 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 506
 507 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 508
 509 sub cmd_help ($) {
 510         my ($self) = @_;
 511         more($self, '100 help text follows');
 512         '.'
 513 }
 514
 515 sub get_range ($$) {
 516         my ($self, $range) = @_;
 517         my $ng = $self->{ng} or return '412 no news group has been selected';
 518         defined $range or return '420 No article(s) selected';
 519         my ($beg, $end);
 520         my ($min, $max) = $ng->mm->minmax;
 521         if ($range =~ /\A(\d+)\z/) {
 522                 $beg = $end = $1;
 523         } elsif ($range =~ /\A(\d+)-\z/) {
 524                 ($beg, $end) = ($1, $max);
 525         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 526                 ($beg, $end) = ($1, $2);
 527         } else {
 528                 return r501;
 529         }
 530         $beg = $min if ($beg < $min);
 531         $end = $max if ($end > $max);
 532         return '420 No article(s) selected' if ($beg > $end);
 533         [ $beg, $end ];
 534 }
 535
 536 sub hdr_val ($$) {
 537         my ($r, $header) = @_;
 538         return $r->[3] if $header =~ /\A:?bytes\z/i;
 539         return $r->[4] if $header =~ /\A:?lines\z/i;
 540         $r = $r->[2]->header_obj->header($header);
 541         defined $r or return;
 542         $r =~ s/[\r\n\t]+/ /sg;
 543         $r;
 544 }
 545
 546 sub long_response ($$$$) {
 547         my ($self, $beg, $end, $cb) = @_;
 548         die "BUG: nested long response" if $self->{long_res};
 549
 550         my $fd = $self->{fd};
 551         defined $fd or return;
 552         # make sure we disable reading during a long response,
 553         # clients should not be sending us stuff and making us do more
 554         # work while we are stream a response to them
 555         $self->watch_read(0);
 556         my $t0 = now();
 557         $self->{long_res} = sub {
 558                 # limit our own running time for fairness with other
 559                 # clients and to avoid buffering too much:
 560                 my $lim = 100;
 561
 562                 my $err;
 563                 do {
 564                         eval { $cb->(\$beg) };
 565                 } until (($err = $@) || $self->{closed} ||
 566                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 567
 568                 if ($err || $self->{closed}) {
 569                         $self->{long_res} = undef;
 570
 571                         if ($err) {
 572                                 err($self,
 573                                     "%s during long response[$fd] - %0.6f",
 574                                     $err, now() - $t0);
 575                         }
 576                         if ($self->{closed}) {
 577                                 out($self, " deferred[$fd] aborted - %0.6f",
 578                                            now() - $t0);
 579                         } else {
 580                                 update_idle_time($self);
 581                                 $self->watch_read(1);
 582                         }
 583                 } elsif (!$lim || $self->{write_buf_size}) {
 584                         # no recursion, schedule another call ASAP
 585                         # but only after all pending writes are done
 586                         update_idle_time($self);
 587                         Danga::Socket->AddTimer(0, sub {
 588                                 $self->write($self->{long_res});
 589                         });
 590                 } else { # all done!
 591                         $self->{long_res} = undef;
 592                         $self->watch_read(1);
 593                         res($self, '.');
 594                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 595                 }
 596         };
 597         $self->{long_res}->(); # kick off!
 598         undef;
 599 }
 600
 601 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 602         my ($self, $xhdr, $range) = @_;
 603
 604         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 605                 my ($ng, $n) = mid_lookup($self, $1);
 606                 return r430 unless $n;
 607                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 608         } else { # numeric range
 609                 $range = $self->{article} unless defined $range;
 610                 my $r = get_range($self, $range);
 611                 return $r unless ref $r;
 612                 my $mm = $self->{ng}->mm;
 613                 my ($beg, $end) = @$r;
 614                 more($self, $xhdr ? r221 : r225);
 615                 $self->long_response($beg, $end, sub {
 616                         my ($i) = @_;
 617                         my $mid = $mm->mid_for($$i);
 618                         more($self, "$$i <$mid>") if defined $mid;
 619                 });
 620         }
 621 }
 622
 623 sub xref ($$) {
 624         my ($ng, $n) = @_;
 625         "$ng->{domain} $ng->{name}:$n"
 626 }
 627
 628 sub mid_lookup ($$) {
 629         my ($self, $mid) = @_;
 630         my $self_ng = $self->{ng};
 631         if ($self_ng) {
 632                 my $n = $self_ng->mm->num_for($mid);
 633                 return ($self_ng, $n) if defined $n;
 634         }
 635         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 636                 next if defined $self_ng && $ng eq $self_ng;
 637                 my $n = $ng->mm->num_for($mid);
 638                 return ($ng, $n) if defined $n;
 639         }
 640         (undef, undef);
 641 }
 642
 643 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 644         my ($self, $xhdr, $range) = @_;
 645
 646         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 647                 my ($ng, $n) = mid_lookup($self, $1);
 648                 return r430 unless $n;
 649                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 650         } else { # numeric range
 651                 $range = $self->{article} unless defined $range;
 652                 my $r = get_range($self, $range);
 653                 return $r unless ref $r;
 654                 my $ng = $self->{ng};
 655                 my $mm = $ng->mm;
 656                 my ($beg, $end) = @$r;
 657                 more($self, $xhdr ? r221 : r225);
 658                 $self->long_response($beg, $end, sub {
 659                         my ($i) = @_;
 660                         my $mid = $mm->mid_for($$i);
 661                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 662                 });
 663         }
 664 }
 665
 666 sub search_header_for {
 667         my ($srch, $mid, $field) = @_;
 668         my $smsg = $srch->lookup_message($mid) or return;
 669         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 670         $smsg->$field;
 671 }
 672
 673 sub hdr_searchmsg ($$$$) {
 674         my ($self, $xhdr, $field, $range) = @_;
 675         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 676                 my ($ng, $n) = mid_lookup($self, $1);
 677                 return r430 unless $n;
 678                 my $v = search_header_for($ng->search, $range, $field);
 679                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 680         } else { # numeric range
 681                 $range = $self->{article} unless defined $range;
 682                 my $srch = $self->{ng}->search;
 683                 my $mm = $self->{ng}->mm;
 684                 my $r = get_range($self, $range);
 685                 return $r unless ref $r;
 686                 my ($beg, $end) = @$r;
 687                 more($self, $xhdr ? r221 : r225);
 688                 my $off = 0;
 689                 $self->long_response($beg, $end, sub {
 690                         my ($i) = @_;
 691                         my $res = $srch->query_xover($beg, $end, $off);
 692                         my $msgs = $res->{msgs};
 693                         my $nr = scalar @$msgs or return;
 694                         $off += $nr;
 695                         my $tmp = '';
 696                         foreach my $s (@$msgs) {
 697                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 698                         }
 699                         do_more($self, $tmp);
 700                         # -1 to adjust for implicit increment in long_response
 701                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 702                 });
 703         }
 704 }
 705
 706 sub do_hdr ($$$;$) {
 707         my ($self, $xhdr, $header, $range) = @_;
 708         my $sub = lc $header;
 709         if ($sub eq 'message-id') {
 710                 hdr_message_id($self, $xhdr, $range);
 711         } elsif ($sub eq 'xref') {
 712                 hdr_xref($self, $xhdr, $range);
 713         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 714                                 bytes|lines)\z/x) {
 715                 hdr_searchmsg($self, $xhdr, $sub, $range);
 716         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 717                 hdr_searchmsg($self, $xhdr, $1, $range);
 718         } else {
 719                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 720         }
 721 }
 722
 723 # RFC 3977
 724 sub cmd_hdr ($$;$) {
 725         my ($self, $header, $range) = @_;
 726         do_hdr($self, 0, $header, $range);
 727 }
 728
 729 # RFC 2980
 730 sub cmd_xhdr ($$;$) {
 731         my ($self, $header, $range) = @_;
 732         do_hdr($self, 1, $header, $range);
 733 }
 734
 735 sub hdr_mid_prefix ($$$$$) {
 736         my ($self, $xhdr, $ng, $n, $mid) = @_;
 737         return $mid if $xhdr;
 738
 739         # HDR for RFC 3977 users
 740         if (my $self_ng = $self->{ng}) {
 741                 ($self_ng eq $ng) ? $n : '0';
 742         } else {
 743                 '0';
 744         }
 745 }
 746
 747 sub hdr_mid_response ($$$$$$) {
 748         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 749         my $res = '';
 750         if ($xhdr) {
 751                 $res .= r221 . "\r\n";
 752                 $res .= "$mid $v\r\n";
 753         } else {
 754                 $res .= r225 . "\r\n";
 755                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 756                 $res .= "$pfx $v\r\n";
 757         }
 758         res($self, $res .= '.');
 759         undef;
 760 }
 761
 762 sub cmd_xrover ($;$) {
 763         my ($self, $range) = @_;
 764         my $ng = $self->{ng} or return '412 no newsgroup selected';
 765         (defined $range && $range =~ /[<>]/) and
 766                 return '420 No article(s) selected'; # no message IDs
 767
 768         $range = $self->{article} unless defined $range;
 769         my $r = get_range($self, $range);
 770         return $r unless ref $r;
 771         my ($beg, $end) = @$r;
 772         my $mm = $ng->mm;
 773         my $srch = $ng->search;
 774         more($self, '224 Overview information follows');
 775         $self->long_response($beg, $end, sub {
 776                 my ($i) = @_;
 777                 my $mid = $mm->mid_for($$i) or return;
 778                 my $h = search_header_for($srch, $mid, 'references');
 779                 more($self, "$$i $h");
 780         });
 781 }
 782
 783 sub over_line ($$) {
 784         my ($num, $smsg) = @_;
 785         # n.b. field access and procedural calls can be
 786         # 10%-15% faster than OO method calls:
 787         join("\t", $num,
 788                 $smsg->{subject},
 789                 $smsg->{from},
 790                 PublicInbox::SearchMsg::date($smsg),
 791                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 792                 $smsg->{references},
 793                 PublicInbox::SearchMsg::bytes($smsg),
 794                 PublicInbox::SearchMsg::lines($smsg));
 795 }
 796
 797 sub cmd_over ($;$) {
 798         my ($self, $range) = @_;
 799         if ($range && $range =~ /\A<(.+)>\z/) {
 800                 my ($ng, $n) = mid_lookup($self, $1);
 801                 my $smsg = $ng->search->lookup_message($range) or
 802                         return '430 No article with that message-id';
 803                 more($self, '224 Overview information follows (multi-line)');
 804                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 805
 806                 # Only set article number column if it's the current group
 807                 my $self_ng = $self->{ng};
 808                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 809                 more($self, over_line($n, $smsg));
 810                 '.';
 811         } else {
 812                 cmd_xover($self, $range);
 813         }
 814 }
 815
 816 sub cmd_xover ($;$) {
 817         my ($self, $range) = @_;
 818         $range = $self->{article} unless defined $range;
 819         my $r = get_range($self, $range);
 820         return $r unless ref $r;
 821         my ($beg, $end) = @$r;
 822         more($self, "224 Overview information follows for $beg to $end");
 823         my $srch = $self->{ng}->search;
 824         my $off = 0;
 825         $self->long_response($beg, $end, sub {
 826                 my ($i) = @_;
 827                 my $res = $srch->query_xover($beg, $end, $off);
 828                 my $msgs = $res->{msgs};
 829                 my $nr = scalar @$msgs or return;
 830                 $off += $nr;
 831
 832                 # OVERVIEW.FMT
 833                 more($self, join("\r\n", map {
 834                         over_line(PublicInbox::SearchMsg::num($_), $_);
 835                         } @$msgs));
 836
 837                 # -1 to adjust for implicit increment in long_response
 838                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 839         });
 840 }
 841
 842 sub cmd_xpath ($$) {
 843         my ($self, $mid) = @_;
 844         return r501 unless $mid =~ /\A<(.+)>\z/;
 845         $mid = $1;
 846         my @paths;
 847         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 848                 my $n = $ng->mm->num_for($mid);
 849                 push @paths, "$ng->{name}/$n" if defined $n;
 850         }
 851         return '430 no such article on server' unless @paths;
 852         '223 '.join(' ', @paths);
 853 }
 854
 855 sub res ($$) {
 856         my ($self, $line) = @_;
 857         do_write($self, $line . "\r\n");
 858 }
 859
 860 sub more ($$) {
 861         my ($self, $line) = @_;
 862         do_more($self, $line . "\r\n");
 863 }
 864
 865 sub do_write ($$) {
 866         my ($self, $data) = @_;
 867         my $done = $self->write($data);
 868         die if $self->{closed};
 869
 870         # Do not watch for readability if we have data in the queue,
 871         # instead re-enable watching for readability when we can
 872         $self->watch_read(0) if (!$done || $self->{long_res});
 873
 874         $done;
 875 }
 876
 877 sub err ($$;@) {
 878         my ($self, $fmt, @args) = @_;
 879         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 880 }
 881
 882 sub out ($$;@) {
 883         my ($self, $fmt, @args) = @_;
 884         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 885 }
 886
 887 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 888
 889 sub do_more ($$) {
 890         my ($self, $data) = @_;
 891         if (MSG_MORE && !$self->{write_buf_size}) {
 892                 my $n = send($self->{sock}, $data, MSG_MORE);
 893                 if (defined $n) {
 894                         my $dlen = length($data);
 895                         return 1 if $n == $dlen; # all done!
 896                         $data = substr($data, $n, $dlen - $n);
 897                 }
 898         }
 899         $self->do_write($data);
 900 }
 901
 902 # callbacks for Danga::Socket
 903
 904 sub event_hup { $_[0]->close }
 905 sub event_err { $_[0]->close }
 906
 907 sub event_write {
 908         my ($self) = @_;
 909         update_idle_time($self);
 910         # only continue watching for readability when we are done writing:
 911         if ($self->write(undef) == 1 && !$self->{long_res}) {
 912                 $self->watch_read(1);
 913         }
 914 }
 915
 916 sub event_read {
 917         my ($self) = @_;
 918         use constant LINE_MAX => 512; # RFC 977 section 2.3
 919         my $r = 1;
 920
 921         my $buf = $self->read(LINE_MAX) or return $self->close;
 922         $self->{rbuf} .= $$buf;
 923         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 924                 my $line = $1;
 925                 my $t0 = now();
 926                 my $fd = $self->{fd};
 927                 $r = eval { $self->process_line($line) };
 928                 my $d = $self->{long_res} ?
 929                         " deferred[$fd]" : '';
 930                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 931         }
 932
 933         return $self->close if $r < 0;
 934         my $len = length($self->{rbuf});
 935         return $self->close if ($len >= LINE_MAX);
 936         update_idle_time($self);
 937 }
 938
 939 sub watch_read {
 940         my ($self, $bool) = @_;
 941         my $rv = $self->SUPER::watch_read($bool);
 942         if ($bool && $self->{rbuf} ne '') {
 943                 # Force another read if there is a pipelined request.
 944                 # We don't know if the socket has anything for us to read,
 945                 # and we must double-check again by the time the timer fires
 946                 # in case we really did dispatch a read event and started
 947                 # another long response.
 948                 Danga::Socket->AddTimer(0, sub {
 949                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 950                                 $self->event_read;
 951                         }
 952                 });
 953         }
 954         $rv;
 955 }
 956
 957 # for graceful shutdown in PublicInbox::Daemon:
 958 sub busy () {
 959         my ($self) = @_;
 960         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 961 }
 962
 963 1;