lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Search;
   9 use PublicInbox::Msgmap;
  10 use PublicInbox::GitCatFile;
  11 use PublicInbox::MID qw(mid2path);
  12 use Email::MIME;
  13 use Data::Dumper qw(Dumper);
  14 use POSIX qw(strftime);
  15 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  16 use constant {
  17         r501 => '501 command syntax error',
  18         r221 => '221 Header follows',
  19         r224 => '224 Overview information follows (multi-line)',
  20         r225 => '225 Headers follow (multi-line)',
  21         r430 => '430 No article with that message-id',
  22         long_response_limit => 0xffffffff,
  23 };
  24
  25 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  26
  27 my @OVERVIEW = qw(Subject From Date Message-ID References);
  28 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  29 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  30                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  31
  32 # disable commands with easy DoS potential:
  33 # LISTGROUP could get pretty bad, too...
  34 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  35
  36 sub new ($$$) {
  37         my ($class, $sock, $nntpd) = @_;
  38         my $self = fields::new($class);
  39         binmode $sock, ':utf8'; # RFC 3977
  40         $self->SUPER::new($sock);
  41         $self->{nntpd} = $nntpd;
  42         res($self, '201 server ready - post via email');
  43         $self->{rbuf} = '';
  44         $self->watch_read(1);
  45         $self;
  46 }
  47
  48 sub args_ok ($$) {
  49         my ($cb, $argc) = @_;
  50         my $tot = prototype $cb;
  51         my ($nreq, undef) = split(';', $tot);
  52         $nreq = ($nreq =~ tr/$//) - 1;
  53         $tot = ($tot =~ tr/$//) - 1;
  54         ($argc <= $tot && $argc >= $nreq);
  55 }
  56
  57 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  58 sub process_line ($$) {
  59         my ($self, $l) = @_;
  60         my ($req, @args) = split(/\s+/, $l);
  61         $req = lc($req);
  62         $req = eval {
  63                 no strict 'refs';
  64                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  65         };
  66         return res($self, '500 command not recognized') unless $req;
  67         return res($self, r501) unless args_ok($req, scalar @args);
  68
  69         my $res = eval { $req->($self, @args) };
  70         my $err = $@;
  71         if ($err && !$self->{closed}) {
  72                 chomp($l = Dumper(\$l));
  73                 err($self, "error from: $l $err");
  74                 $res = '503 program fault - command not performed';
  75         }
  76         return 0 unless defined $res;
  77         res($self, $res);
  78 }
  79
  80 sub cmd_mode ($$) {
  81         my ($self, $arg) = @_;
  82         $arg = uc $arg;
  83         return r501 unless $arg eq 'READER';
  84         '201 Posting prohibited';
  85 }
  86
  87 sub cmd_slave ($) { '202 slave status noted' }
  88
  89 sub cmd_xgtitle ($;$) {
  90         my ($self, $wildmat) = @_;
  91         more($self, '282 list of groups and descriptions follows');
  92         list_newsgroups($self, $wildmat);
  93         '.'
  94 }
  95
  96 sub list_overview_fmt ($) {
  97         my ($self) = @_;
  98         do_more($self, $OVERVIEW_FMT);
  99 }
 100
 101 sub list_headers ($;$) {
 102         my ($self) = @_;
 103         do_more($self, $LIST_HEADERS);
 104 }
 105
 106 sub list_active ($;$) {
 107         my ($self, $wildmat) = @_;
 108         wildmat2re($wildmat);
 109         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 110                 $ng->{name} =~ $wildmat or next;
 111                 group_line($self, $ng);
 112         }
 113 }
 114
 115 sub list_active_times ($;$) {
 116         my ($self, $wildmat) = @_;
 117         wildmat2re($wildmat);
 118         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 119                 $ng->{name} =~ $wildmat or next;
 120                 my $c = eval { $ng->mm->created_at } || time;
 121                 more($self, "$ng->{name} $c $ng->{address}");
 122         }
 123 }
 124
 125 sub list_newsgroups ($;$) {
 126         my ($self, $wildmat) = @_;
 127         wildmat2re($wildmat);
 128         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 129                 $ng->{name} =~ $wildmat or next;
 130                 my $d = $ng->description;
 131                 more($self, "$ng->{name} $d");
 132         }
 133 }
 134
 135 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 136 sub cmd_list ($;$$) {
 137         my ($self, @args) = @_;
 138         if (scalar @args) {
 139                 my $arg = shift @args;
 140                 $arg =~ tr/A-Z./a-z_/;
 141                 $arg = "list_$arg";
 142                 return r501 if $DISABLED{$arg};
 143
 144                 $arg = eval {
 145                         no strict 'refs';
 146                         *{$arg}{CODE};
 147                 };
 148                 return r501 unless $arg && args_ok($arg, scalar @args);
 149                 more($self, '215 information follows');
 150                 $arg->($self, @args);
 151         } else {
 152                 more($self, '215 list of newsgroups follows');
 153                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 154                         group_line($self, $ng);
 155                 }
 156         }
 157         '.'
 158 }
 159
 160 sub cmd_listgroup ($;$) {
 161         my ($self, $group) = @_;
 162         if (defined $group) {
 163                 my $res = cmd_group($self, $group);
 164                 return $res if ($res !~ /\A211 /);
 165                 more($self, $res);
 166         }
 167
 168         $self->{ng} or return '412 no newsgroup selected';
 169         $self->long_response(0, long_response_limit, sub {
 170                 my ($i) = @_;
 171                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 172                         my ($ary) = @_;
 173                         more($self, join("\r\n", @$ary));
 174                 });
 175
 176                 # -1 to adjust for implicit increment in long_response
 177                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 178         });
 179 }
 180
 181 sub parse_time ($$;$) {
 182         my ($date, $time, $gmt) = @_;
 183         use Time::Local qw();
 184         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 185         if (defined $gmt) {
 186                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 187                 $gmt = 1;
 188         }
 189         my @now = $gmt ? gmtime : localtime;
 190         my ($YYYY, $MM, $DD);
 191         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 192                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 193         } else { # legacy clients send YYMMDD
 194                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 195                 if ($YYYY > strftime('%y', @now)) {
 196                         my $cur_year = $now[5] + 1900;
 197                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 198                 }
 199         }
 200         if ($gmt) {
 201                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 202         } else {
 203                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 204         }
 205 }
 206
 207 sub group_line ($$) {
 208         my ($self, $ng) = @_;
 209         my ($min, $max) = $ng->mm->minmax;
 210         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 211 }
 212
 213 sub cmd_newgroups ($$$;$$) {
 214         my ($self, $date, $time, $gmt, $dists) = @_;
 215         my $ts = eval { parse_time($date, $time, $gmt) };
 216         return r501 if $@;
 217
 218         # TODO dists
 219         more($self, '231 list of new newsgroups follows');
 220         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 221                 my $c = eval { $ng->mm->created_at } || 0;
 222                 next unless $c > $ts;
 223                 group_line($self, $ng);
 224         }
 225         '.'
 226 }
 227
 228 sub wildmat2re (;$) {
 229         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 230         my %keep;
 231         my $salt = rand;
 232         use Digest::SHA qw(sha1_hex);
 233         my $tmp = $_[0];
 234
 235         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 236                 my $orig = $1;
 237                 my $key = sha1_hex($orig . $salt);
 238                 $orig =~ s/([^\w\-])+/\Q$1/g;
 239                 $keep{$key} = $orig;
 240                 $key
 241                 #gex;
 242         my %map = ('*' => '.*', '?' => '.' );
 243         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 244         if (scalar %keep) {
 245                 $tmp =~ s#([a-f0-9]{40})#
 246                         my $orig = $keep{$1};
 247                         defined $orig ? $orig : $1;
 248                         #ge;
 249         }
 250         $_[0] = qr/\A$tmp\z/;
 251 }
 252
 253 sub ngpat2re (;$) {
 254         return $_[0] = qr/\A\z/ unless defined $_[0];
 255         my %map = ('*' => '.*', ',' => '|');
 256         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 257         $_[0] = qr/\A(?:$_[0])\z/;
 258 }
 259
 260 sub cmd_newnews ($$$$;$$) {
 261         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 262         my $ts = eval { parse_time($date, $time, $gmt) };
 263         return r501 if $@;
 264         more($self, '230 list of new articles by message-id follows');
 265         my ($keep, $skip) = split('!', $newsgroups, 2);
 266         ngpat2re($keep);
 267         ngpat2re($skip);
 268         my @srch;
 269         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 270                 $ng->{name} =~ $keep or next;
 271                 $ng->{name} =~ $skip and next;
 272                 my $srch = $ng->search or next;
 273                 push @srch, $srch;
 274         };
 275         return '.' unless @srch;
 276
 277         $ts .= '..';
 278         my $opts = { asc => 1, limit => 1000, offset => 0 };
 279         $self->long_response(0, long_response_limit, sub {
 280                 my ($i) = @_;
 281                 my $srch = $srch[0];
 282                 my $res = $srch->query($ts, $opts);
 283                 my $msgs = $res->{msgs};
 284                 if (my $nr = scalar @$msgs) {
 285                         more($self, '<' .
 286                                 join(">\r\n<", map { $_->mid } @$msgs ).
 287                                 '>');
 288                         $opts->{offset} += $nr;
 289                 } else {
 290                         shift @srch;
 291                         if (@srch) { # continue onto next newsgroup
 292                                 $opts->{offset} = 0;
 293                         } else { # break out of the long response.
 294                                 $$i = long_response_limit;
 295                         }
 296                 }
 297         });
 298 }
 299
 300 sub cmd_group ($$) {
 301         my ($self, $group) = @_;
 302         my $no_such = '411 no such news group';
 303         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 304
 305         $self->{ng} = $ng;
 306         my ($min, $max) = $ng->mm->minmax;
 307         $min ||= 0;
 308         $max ||= 0;
 309         $self->{article} = $min;
 310         my $est_size = $max - $min;
 311         "211 $est_size $min $max $group";
 312 }
 313
 314 sub article_adj ($$) {
 315         my ($self, $off) = @_;
 316         my $ng = $self->{ng} or return '412 no newsgroup selected';
 317
 318         my $n = $self->{article};
 319         defined $n or return '420 no current article has been selected';
 320
 321         $n += $off;
 322         my $mid = $ng->mm->mid_for($n);
 323         unless ($mid) {
 324                 $n = $off > 0 ? 'next' : 'previous';
 325                 return "421 no $n article in this group";
 326         }
 327         $self->{article} = $n;
 328         "223 $n <$mid> article retrieved - request text separately";
 329 }
 330
 331 sub cmd_next ($) { article_adj($_[0], 1) }
 332 sub cmd_last ($) { article_adj($_[0], -1) }
 333
 334 # We want to encourage using email and CC-ing everybody involved to avoid
 335 # the single-point-of-failure a single server provides.
 336 sub cmd_post ($) {
 337         my ($self) = @_;
 338         my $ng = $self->{ng};
 339         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 340 }
 341
 342 sub cmd_quit ($) {
 343         my ($self) = @_;
 344         res($self, '205 closing connection - goodbye!');
 345         $self->close;
 346         undef;
 347 }
 348
 349 sub art_lookup ($$$) {
 350         my ($self, $art, $set_headers) = @_;
 351         my $ng = $self->{ng};
 352         my ($n, $mid);
 353         my $err;
 354         if (defined $art) {
 355                 if ($art =~ /\A\d+\z/o) {
 356                         $err = '423 no such article number in this group';
 357                         $n = int($art);
 358                         goto find_mid;
 359                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 360                         $mid = $1;
 361                         $err = r430;
 362                         $n = $ng->mm->num_for($mid) if $ng;
 363                         goto found if defined $n;
 364                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 365                                 $n = $g->mm->num_for($mid);
 366                                 if (defined $n) {
 367                                         $ng = $g;
 368                                         goto found;
 369                                 }
 370                         }
 371                         return $err;
 372                 } else {
 373                         return r501;
 374                 }
 375         } else {
 376                 $err = '420 no current article has been selected';
 377                 $n = $self->{article};
 378                 defined $n or return $err;
 379 find_mid:
 380                 $ng or return '412 no newsgroup has been selected';
 381                 $mid = $ng->mm->mid_for($n);
 382                 defined $mid or return $err;
 383         }
 384 found:
 385         my $o = 'HEAD:' . mid2path($mid);
 386         my $bytes;
 387         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 388         return $err unless $s;
 389         my $lines;
 390         if ($set_headers) {
 391                 $s->header_set('Newsgroups', $ng->{name});
 392                 $s->header_set('Xref', xref($ng, $n));
 393                 $lines = $s->body =~ tr!\n!\n!;
 394
 395                 # must be last
 396                 $s->body_set('') if ($set_headers == 2);
 397         }
 398         [ $n, $mid, $s, $bytes, $lines, $ng ];
 399 }
 400
 401 sub simple_body_write ($$) {
 402         my ($self, $s) = @_;
 403         my $body = $s->body;
 404         $s->body_set('');
 405         $body =~ s/^\./../smg;
 406         $body =~ s/(?<!\r)\n/\r\n/sg;
 407         do_more($self, $body);
 408         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 409         '.'
 410 }
 411
 412 sub set_art {
 413         my ($self, $art) = @_;
 414         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 415 }
 416
 417 sub cmd_article ($;$) {
 418         my ($self, $art) = @_;
 419         my $r = $self->art_lookup($art, 1);
 420         return $r unless ref $r;
 421         my ($n, $mid, $s) = @$r;
 422         set_art($self, $art);
 423         more($self, "220 $n <$mid> article retrieved - head and body follow");
 424         do_more($self, $s->header_obj->as_string);
 425         do_more($self, "\r\n");
 426         simple_body_write($self, $s);
 427 }
 428
 429 sub cmd_head ($;$) {
 430         my ($self, $art) = @_;
 431         my $r = $self->art_lookup($art, 2);
 432         return $r unless ref $r;
 433         my ($n, $mid, $s) = @$r;
 434         set_art($self, $art);
 435         more($self, "221 $n <$mid> article retrieved - head follows");
 436         do_more($self, $s->header_obj->as_string);
 437         '.'
 438 }
 439
 440 sub cmd_body ($;$) {
 441         my ($self, $art) = @_;
 442         my $r = $self->art_lookup($art, 0);
 443         return $r unless ref $r;
 444         my ($n, $mid, $s) = @$r;
 445         set_art($self, $art);
 446         more($self, "222 $n <$mid> article retrieved - body follows");
 447         simple_body_write($self, $s);
 448 }
 449
 450 sub cmd_stat ($;$) {
 451         my ($self, $art) = @_;
 452         my $r = $self->art_lookup($art, 0);
 453         return $r unless ref $r;
 454         my ($n, $mid, undef) = @$r;
 455         set_art($self, $art);
 456         "223 $n <$mid> article retrieved - request text separately";
 457 }
 458
 459 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 460
 461 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 462
 463 sub cmd_help ($) {
 464         my ($self) = @_;
 465         more($self, '100 help text follows');
 466         '.'
 467 }
 468
 469 sub get_range ($$) {
 470         my ($self, $range) = @_;
 471         my $ng = $self->{ng} or return '412 no news group has been selected';
 472         defined $range or return '420 No article(s) selected';
 473         my ($beg, $end);
 474         my ($min, $max) = $ng->mm->minmax;
 475         if ($range =~ /\A(\d+)\z/) {
 476                 $beg = $end = $1;
 477         } elsif ($range =~ /\A(\d+)-\z/) {
 478                 ($beg, $end) = ($1, $max);
 479         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 480                 ($beg, $end) = ($1, $2);
 481         } else {
 482                 return r501;
 483         }
 484         $beg = $min if ($beg < $min);
 485         $end = $max if ($end > $max);
 486         return '420 No article(s) selected' if ($beg > $end);
 487         [ $beg, $end ];
 488 }
 489
 490 sub hdr_val ($$) {
 491         my ($r, $header) = @_;
 492         return $r->[3] if $header =~ /\A:?bytes\z/i;
 493         return $r->[4] if $header =~ /\A:?lines\z/i;
 494         $r = $r->[2]->header_obj->header($header);
 495         defined $r or return;
 496         $r =~ s/[\r\n\t]+/ /sg;
 497         $r;
 498 }
 499
 500 sub long_response ($$$$) {
 501         my ($self, $beg, $end, $cb) = @_;
 502         die "BUG: nested long response" if $self->{long_res};
 503
 504         my $fd = $self->{fd};
 505         defined $fd or return;
 506         # make sure we disable reading during a long response,
 507         # clients should not be sending us stuff and making us do more
 508         # work while we are stream a response to them
 509         $self->watch_read(0);
 510         my $t0 = now();
 511         $self->{long_res} = sub {
 512                 # limit our own running time for fairness with other
 513                 # clients and to avoid buffering too much:
 514                 my $lim = 100;
 515
 516                 my $err;
 517                 do {
 518                         eval { $cb->(\$beg) };
 519                 } until (($err = $@) || $self->{closed} ||
 520                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 521
 522                 if ($err || $self->{closed}) {
 523                         $self->{long_res} = undef;
 524
 525                         if ($err) {
 526                                 err($self,
 527                                     "$err during long response[$fd] - %0.6f",
 528                                         now() - $t0);
 529                         }
 530                         if ($self->{closed}) {
 531                                 out($self, " deferred[$fd] aborted - %0.6f",
 532                                            now() - $t0);
 533                         } else {
 534                                 $self->watch_read(1);
 535                         }
 536                 } elsif (!$lim || $self->{write_buf_size}) {
 537                         # no recursion, schedule another call ASAP
 538                         # but only after all pending writes are done
 539                         Danga::Socket->AddTimer(0, sub {
 540                                 $self->write($self->{long_res});
 541                         });
 542                 } else { # all done!
 543                         $self->{long_res} = undef;
 544                         $self->watch_read(1);
 545                         res($self, '.');
 546                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 547                 }
 548         };
 549         $self->{long_res}->(); # kick off!
 550         undef;
 551 }
 552
 553 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 554         my ($self, $xhdr, $range) = @_;
 555
 556         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 557                 my ($ng, $n) = mid_lookup($self, $1);
 558                 return r430 unless $n;
 559                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 560         } else { # numeric range
 561                 $range = $self->{article} unless defined $range;
 562                 my $r = get_range($self, $range);
 563                 return $r unless ref $r;
 564                 my $mm = $self->{ng}->mm;
 565                 my ($beg, $end) = @$r;
 566                 more($self, $xhdr ? r221 : r225);
 567                 $self->long_response($beg, $end, sub {
 568                         my ($i) = @_;
 569                         my $mid = $mm->mid_for($$i);
 570                         more($self, "$$i <$mid>") if defined $mid;
 571                 });
 572         }
 573 }
 574
 575 sub xref ($$) {
 576         my ($ng, $n) = @_;
 577         "$ng->{domain} $ng->{name}:$n"
 578 }
 579
 580 sub mid_lookup ($$) {
 581         my ($self, $mid) = @_;
 582         my $self_ng = $self->{ng};
 583         if ($self_ng) {
 584                 my $n = $self_ng->mm->num_for($mid);
 585                 return ($self_ng, $n) if defined $n;
 586         }
 587         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 588                 next if defined $self_ng && $ng eq $self_ng;
 589                 my $n = $ng->mm->num_for($mid);
 590                 return ($ng, $n) if defined $n;
 591         }
 592         (undef, undef);
 593 }
 594
 595 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 596         my ($self, $xhdr, $range) = @_;
 597
 598         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 599                 my ($ng, $n) = mid_lookup($self, $1);
 600                 return r430 unless $n;
 601                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 602         } else { # numeric range
 603                 $range = $self->{article} unless defined $range;
 604                 my $r = get_range($self, $range);
 605                 return $r unless ref $r;
 606                 my $ng = $self->{ng};
 607                 my $mm = $ng->mm;
 608                 my ($beg, $end) = @$r;
 609                 more($self, $xhdr ? r221 : r225);
 610                 $self->long_response($beg, $end, sub {
 611                         my ($i) = @_;
 612                         my $mid = $mm->mid_for($$i);
 613                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 614                 });
 615         }
 616 }
 617
 618 sub search_header_for {
 619         my ($srch, $mid, $field) = @_;
 620         my $smsg = $srch->lookup_message($mid) or return;
 621         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 622         $smsg->$field;
 623 }
 624
 625 sub hdr_searchmsg ($$$$) {
 626         my ($self, $xhdr, $field, $range) = @_;
 627         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 628                 my ($ng, $n) = mid_lookup($self, $1);
 629                 return r430 unless $n;
 630                 my $v = search_header_for($ng->search, $range, $field);
 631                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 632         } else { # numeric range
 633                 $range = $self->{article} unless defined $range;
 634                 my $srch = $self->{ng}->search;
 635                 my $mm = $self->{ng}->mm;
 636                 my $r = get_range($self, $range);
 637                 return $r unless ref $r;
 638                 my ($beg, $end) = @$r;
 639                 more($self, $xhdr ? r221 : r225);
 640                 my $off = 0;
 641                 $self->long_response($beg, $end, sub {
 642                         my ($i) = @_;
 643                         my $res = $srch->query_xover($beg, $end, $off);
 644                         my $msgs = $res->{msgs};
 645                         my $nr = scalar @$msgs or return;
 646                         $off += $nr;
 647                         my $tmp = '';
 648                         foreach my $s (@$msgs) {
 649                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 650                         }
 651                         do_more($self, $tmp);
 652                         # -1 to adjust for implicit increment in long_response
 653                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 654                 });
 655         }
 656 }
 657
 658 sub do_hdr ($$$;$) {
 659         my ($self, $xhdr, $header, $range) = @_;
 660         my $sub = lc $header;
 661         if ($sub eq 'message-id') {
 662                 hdr_message_id($self, $xhdr, $range);
 663         } elsif ($sub eq 'xref') {
 664                 hdr_xref($self, $xhdr, $range);
 665         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 666                                 bytes|lines)\z/x) {
 667                 hdr_searchmsg($self, $xhdr, $sub, $range);
 668         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 669                 hdr_searchmsg($self, $xhdr, $1, $range);
 670         } else {
 671                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 672         }
 673 }
 674
 675 # RFC 3977
 676 sub cmd_hdr ($$;$) {
 677         my ($self, $header, $range) = @_;
 678         do_hdr($self, 0, $header, $range);
 679 }
 680
 681 # RFC 2980
 682 sub cmd_xhdr ($$;$) {
 683         my ($self, $header, $range) = @_;
 684         do_hdr($self, 1, $header, $range);
 685 }
 686
 687 sub hdr_mid_prefix ($$$$$) {
 688         my ($self, $xhdr, $ng, $n, $mid) = @_;
 689         return $mid if $xhdr;
 690
 691         # HDR for RFC 3977 users
 692         if (my $self_ng = $self->{ng}) {
 693                 ($self_ng eq $ng) ? $n : '0';
 694         } else {
 695                 '0';
 696         }
 697 }
 698
 699 sub hdr_mid_response ($$$$$$) {
 700         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 701         my $res = '';
 702         if ($xhdr) {
 703                 $res .= r221 . "\r\n";
 704                 $res .= "$mid $v\r\n";
 705         } else {
 706                 $res .= r225 . "\r\n";
 707                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 708                 $res .= "$pfx $v\r\n";
 709         }
 710         res($self, $res .= '.');
 711         undef;
 712 }
 713
 714 sub cmd_xrover ($;$) {
 715         my ($self, $range) = @_;
 716         my $ng = $self->{ng} or return '412 no newsgroup selected';
 717         (defined $range && $range =~ /[<>]/) and
 718                 return '420 No article(s) selected'; # no message IDs
 719
 720         $range = $self->{article} unless defined $range;
 721         my $r = get_range($self, $range);
 722         return $r unless ref $r;
 723         my ($beg, $end) = @$r;
 724         my $mm = $ng->mm;
 725         my $srch = $ng->search;
 726         more($self, '224 Overview information follows');
 727         $self->long_response($beg, $end, sub {
 728                 my ($i) = @_;
 729                 my $mid = $mm->mid_for($$i) or return;
 730                 my $h = search_header_for($srch, $mid, 'references');
 731                 more($self, "$$i $h");
 732         });
 733 }
 734
 735 sub over_line ($$) {
 736         my ($num, $smsg) = @_;
 737         # n.b. field access and procedural calls can be
 738         # 10%-15% faster than OO method calls:
 739         join("\t", $num,
 740                 $smsg->{subject},
 741                 $smsg->{from},
 742                 PublicInbox::SearchMsg::date($smsg),
 743                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 744                 $smsg->{references},
 745                 PublicInbox::SearchMsg::bytes($smsg),
 746                 PublicInbox::SearchMsg::lines($smsg));
 747 }
 748
 749 sub cmd_over ($;$) {
 750         my ($self, $range) = @_;
 751         if ($range && $range =~ /\A<(.+)>\z/) {
 752                 my ($ng, $n) = mid_lookup($self, $1);
 753                 my $smsg = $ng->search->lookup_message($range) or
 754                         return '430 No article with that message-id';
 755                 more($self, '224 Overview information follows (multi-line)');
 756                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 757
 758                 # Only set article number column if it's the current group
 759                 my $self_ng = $self->{ng};
 760                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 761                 more($self, over_line($n, $smsg));
 762                 '.';
 763         } else {
 764                 cmd_xover($self, $range);
 765         }
 766 }
 767
 768 sub cmd_xover ($;$) {
 769         my ($self, $range) = @_;
 770         $range = $self->{article} unless defined $range;
 771         my $r = get_range($self, $range);
 772         return $r unless ref $r;
 773         my ($beg, $end) = @$r;
 774         more($self, "224 Overview information follows for $beg to $end");
 775         my $srch = $self->{ng}->search;
 776         my $off = 0;
 777         $self->long_response($beg, $end, sub {
 778                 my ($i) = @_;
 779                 my $res = $srch->query_xover($beg, $end, $off);
 780                 my $msgs = $res->{msgs};
 781                 my $nr = scalar @$msgs or return;
 782                 $off += $nr;
 783
 784                 # OVERVIEW.FMT
 785                 more($self, join("\r\n", map {
 786                         over_line(PublicInbox::SearchMsg::num($_), $_);
 787                         } @$msgs));
 788
 789                 # -1 to adjust for implicit increment in long_response
 790                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 791         });
 792 }
 793
 794 sub cmd_xpath ($$) {
 795         my ($self, $mid) = @_;
 796         return r501 unless $mid =~ /\A<(.+)>\z/;
 797         $mid = $1;
 798         my @paths;
 799         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 800                 my $n = $ng->mm->num_for($mid);
 801                 push @paths, "$ng->{name}/$n" if defined $n;
 802         }
 803         return '430 no such article on server' unless @paths;
 804         '223 '.join(' ', @paths);
 805 }
 806
 807 sub res ($$) {
 808         my ($self, $line) = @_;
 809         do_write($self, $line . "\r\n");
 810 }
 811
 812 sub more ($$) {
 813         my ($self, $line) = @_;
 814         do_more($self, $line . "\r\n");
 815 }
 816
 817 sub do_write ($$) {
 818         my ($self, $data) = @_;
 819         my $done = $self->write($data);
 820         die if $self->{closed};
 821
 822         # Do not watch for readability if we have data in the queue,
 823         # instead re-enable watching for readability when we can
 824         $self->watch_read(0) if (!$done || $self->{long_res});
 825
 826         $done;
 827 }
 828
 829 sub err ($$;@) {
 830         my ($self, $fmt, @args) = @_;
 831         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 832 }
 833
 834 sub out ($$;@) {
 835         my ($self, $fmt, @args) = @_;
 836         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 837 }
 838
 839 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 840
 841 sub do_more ($$) {
 842         my ($self, $data) = @_;
 843         if (MSG_MORE && !$self->{write_buf_size}) {
 844                 my $n = send($self->{sock}, $data, MSG_MORE);
 845                 if (defined $n) {
 846                         my $dlen = length($data);
 847                         return 1 if $n == $dlen; # all done!
 848                         $data = substr($data, $n, $dlen - $n);
 849                 }
 850         }
 851         $self->do_write($data);
 852 }
 853
 854 # callbacks for by Danga::Socket
 855
 856 sub event_hup { $_[0]->close }
 857 sub event_err { $_[0]->close }
 858
 859 sub event_write {
 860         my ($self) = @_;
 861         # only continue watching for readability when we are done writing:
 862         if ($self->write(undef) == 1 && !$self->{long_res}) {
 863                 $self->watch_read(1);
 864         }
 865 }
 866
 867 sub event_read {
 868         my ($self) = @_;
 869         use constant LINE_MAX => 512; # RFC 977 section 2.3
 870         my $r = 1;
 871
 872         my $buf = $self->read(LINE_MAX) or return $self->close;
 873         $self->{rbuf} .= $$buf;
 874         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 875                 my $line = $1;
 876                 my $t0 = now();
 877                 my $fd = $self->{fd};
 878                 $r = eval { $self->process_line($line) };
 879                 my $d = $self->{long_res} ?
 880                         " deferred[$fd]" : '';
 881                 out($self, "[$fd] $line - %0.6f$d", now() - $t0);
 882         }
 883
 884         return $self->close if $r < 0;
 885         my $len = length($self->{rbuf});
 886         return $self->close if ($len >= LINE_MAX);
 887 }
 888
 889 sub watch_read {
 890         my ($self, $bool) = @_;
 891         my $rv = $self->SUPER::watch_read($bool);
 892         if ($bool && $self->{rbuf} ne '') {
 893                 # Force another read if there is a pipelined request.
 894                 # We don't know if the socket has anything for us to read,
 895                 # and we must double-check again by the time the timer fires
 896                 # in case we really did dispatch a read event and started
 897                 # another long response.
 898                 Danga::Socket->AddTimer(0, sub {
 899                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 900                                 $self->event_read;
 901                         }
 902                 });
 903         }
 904         $rv;
 905 }
 906
 907 sub busy () {
 908         my ($self) = @_;
 909         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 910 }
 911
 912 1;