lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng long_cb);
  10 use PublicInbox::MID qw(mid_escape);
  11 use Email::Simple;
  12 use POSIX qw(strftime);
  13 use PublicInbox::DS qw(now);
  14 use Digest::SHA qw(sha1_hex);
  15 use Time::Local qw(timegm timelocal);
  16 use constant {
  17         LINE_MAX => 512, # RFC 977 section 2.3
  18         r501 => '501 command syntax error',
  19         r502 => '502 Command unavailable',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24 };
  25 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  26 use Errno qw(EAGAIN);
  27
  28 my @OVERVIEW = qw(Subject From Date Message-ID References);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  30                 "Xref:full\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33 my $CAPABILITIES = <<"";
  34 101 Capability list:\r
  35 VERSION 2\r
  36 READER\r
  37 NEWNEWS\r
  38 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  39 HDR\r
  40 OVER\r
  41
  42 my $have_deflate;
  43
  44 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  45
  46 sub new ($$$) {
  47         my ($class, $sock, $nntpd) = @_;
  48         my $self = fields::new($class);
  49         my $ev = EPOLLIN;
  50         my $wbuf;
  51         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  52                 return CORE::close($sock) if $! != EAGAIN;
  53                 $ev = PublicInbox::TLS::epollbit();
  54                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  55         }
  56         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  57         $self->{nntpd} = $nntpd;
  58         if ($wbuf) {
  59                 $self->{wbuf} = $wbuf;
  60         } else {
  61                 greet($self);
  62         }
  63         $self->update_idle_time;
  64         $self;
  65 }
  66
  67 sub args_ok ($$) {
  68         my ($cb, $argc) = @_;
  69         my $tot = prototype $cb;
  70         my ($nreq, undef) = split(';', $tot);
  71         $nreq = ($nreq =~ tr/$//) - 1;
  72         $tot = ($tot =~ tr/$//) - 1;
  73         ($argc <= $tot && $argc >= $nreq);
  74 }
  75
  76 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  77 sub process_line ($$) {
  78         my ($self, $l) = @_;
  79         my ($req, @args) = split(/[ \t]/, $l);
  80         return 1 unless defined($req); # skip blank line
  81         $req = $self->can('cmd_'.lc($req));
  82         return res($self, '500 command not recognized') unless $req;
  83         return res($self, r501) unless args_ok($req, scalar @args);
  84
  85         my $res = eval { $req->($self, @args) };
  86         my $err = $@;
  87         if ($err && $self->{sock}) {
  88                 local $/ = "\n";
  89                 chomp($l);
  90                 err($self, 'error from: %s (%s)', $l, $err);
  91                 $res = '503 program fault - command not performed';
  92         }
  93         return 0 unless defined $res;
  94         res($self, $res);
  95 }
  96
  97 # The keyword argument is not used (rfc3977 5.2.2)
  98 sub cmd_capabilities ($;$) {
  99         my ($self, undef) = @_;
 100         my $res = $CAPABILITIES;
 101         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 102                         $self->{nntpd}->{accept_tls}) {
 103                 $res .= "STARTTLS\r\n";
 104         }
 105         $res .= '.';
 106 }
 107
 108 sub cmd_mode ($$) {
 109         my ($self, $arg) = @_;
 110         $arg = uc $arg;
 111         return r501 unless $arg eq 'READER';
 112         '201 Posting prohibited';
 113 }
 114
 115 sub cmd_slave ($) { '202 slave status noted' }
 116
 117 sub cmd_xgtitle ($;$) {
 118         my ($self, $wildmat) = @_;
 119         more($self, '282 list of groups and descriptions follows');
 120         list_newsgroups($self, $wildmat);
 121         '.'
 122 }
 123
 124 sub list_overview_fmt ($) {
 125         my ($self) = @_;
 126         $self->msg_more($OVERVIEW_FMT);
 127 }
 128
 129 sub list_headers ($;$) {
 130         my ($self) = @_;
 131         $self->msg_more($LIST_HEADERS);
 132 }
 133
 134 sub list_active ($;$) {
 135         my ($self, $wildmat) = @_;
 136         wildmat2re($wildmat);
 137         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 138                 $ng->{newsgroup} =~ $wildmat or next;
 139                 group_line($self, $ng);
 140         }
 141 }
 142
 143 sub list_active_times ($;$) {
 144         my ($self, $wildmat) = @_;
 145         wildmat2re($wildmat);
 146         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 147                 $ng->{newsgroup} =~ $wildmat or next;
 148                 my $c = eval { $ng->mm->created_at } || time;
 149                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 150         }
 151 }
 152
 153 sub list_newsgroups ($;$) {
 154         my ($self, $wildmat) = @_;
 155         wildmat2re($wildmat);
 156         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 157                 $ng->{newsgroup} =~ $wildmat or next;
 158                 my $d = $ng->description;
 159                 more($self, "$ng->{newsgroup} $d");
 160         }
 161 }
 162
 163 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 164 sub cmd_list ($;$$) {
 165         my ($self, @args) = @_;
 166         if (scalar @args) {
 167                 my $arg = shift @args;
 168                 $arg =~ tr/A-Z./a-z_/;
 169                 $arg = "list_$arg";
 170                 $arg = $self->can($arg);
 171                 return r501 unless $arg && args_ok($arg, scalar @args);
 172                 more($self, '215 information follows');
 173                 $arg->($self, @args);
 174         } else {
 175                 more($self, '215 list of newsgroups follows');
 176                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                         group_line($self, $ng);
 178                 }
 179         }
 180         '.'
 181 }
 182
 183 sub cmd_listgroup ($;$$) {
 184         my ($self, $group, $range) = @_;
 185         if (defined $group) {
 186                 my $res = cmd_group($self, $group);
 187                 return $res if ($res !~ /\A211 /);
 188                 more($self, $res);
 189         }
 190         my $ng = $self->{ng} or return '412 no newsgroup selected';
 191         my $mm = $ng->mm;
 192         if (defined $range) {
 193                 my $r = get_range($self, $range);
 194                 return $r unless ref $r;
 195                 my ($beg, $end) = @$r;
 196                 long_response($self, sub {
 197                         $r = $mm->msg_range($beg, $end, 'num');
 198                         scalar(@$r) or return;
 199                         more($self, join("\r\n", map { $_->[0] } @$r));
 200                         1;
 201                 });
 202         } else { # grab every article number
 203                 my $n = 0;
 204                 long_response($self, sub {
 205                         my $ary = $mm->ids_after(\$n);
 206                         scalar(@$ary) or return;
 207                         more($self, join("\r\n", @$ary));
 208                         1;
 209                 });
 210         }
 211 }
 212
 213 sub parse_time ($$;$) {
 214         my ($date, $time, $gmt) = @_;
 215         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 216         if (defined $gmt) {
 217                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 218                 $gmt = 1;
 219         }
 220         my @now = $gmt ? gmtime : localtime;
 221         my ($YYYY, $MM, $DD);
 222         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 223                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 224         } else { # legacy clients send YYMMDD
 225                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 226                 my $cur_year = $now[5] + 1900;
 227                 if ($YYYY > $cur_year) {
 228                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 229                 }
 230         }
 231         if ($gmt) {
 232                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 233         } else {
 234                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 235         }
 236 }
 237
 238 sub group_line ($$) {
 239         my ($self, $ng) = @_;
 240         my ($min, $max) = $ng->mm->minmax;
 241         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 242 }
 243
 244 sub cmd_newgroups ($$$;$$) {
 245         my ($self, $date, $time, $gmt, $dists) = @_;
 246         my $ts = eval { parse_time($date, $time, $gmt) };
 247         return r501 if $@;
 248
 249         # TODO dists
 250         more($self, '231 list of new newsgroups follows');
 251         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 252                 my $c = eval { $ng->mm->created_at } || 0;
 253                 next unless $c > $ts;
 254                 group_line($self, $ng);
 255         }
 256         '.'
 257 }
 258
 259 sub wildmat2re (;$) {
 260         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 261         my %keep;
 262         my $salt = rand;
 263         my $tmp = $_[0];
 264
 265         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 266                 my $orig = $1;
 267                 my $key = sha1_hex($orig . $salt);
 268                 $orig =~ s/([^\w\-])+/\Q$1/g;
 269                 $keep{$key} = $orig;
 270                 $key
 271                 #gex;
 272         my %map = ('*' => '.*', '?' => '.' );
 273         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 274         if (scalar %keep) {
 275                 $tmp =~ s#([a-f0-9]{40})#
 276                         my $orig = $keep{$1};
 277                         defined $orig ? $orig : $1;
 278                         #ge;
 279         }
 280         $_[0] = qr/\A$tmp\z/;
 281 }
 282
 283 sub ngpat2re (;$) {
 284         return $_[0] = qr/\A\z/ unless defined $_[0];
 285         my %map = ('*' => '.*', ',' => '|');
 286         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 287         $_[0] = qr/\A(?:$_[0])\z/;
 288 }
 289
 290 sub cmd_newnews ($$$$;$$) {
 291         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 292         my $ts = eval { parse_time($date, $time, $gmt) };
 293         return r501 if $@;
 294         more($self, '230 list of new articles by message-id follows');
 295         my ($keep, $skip) = split('!', $newsgroups, 2);
 296         ngpat2re($keep);
 297         ngpat2re($skip);
 298         my @over;
 299         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 300                 $ng->{newsgroup} =~ $keep or next;
 301                 $ng->{newsgroup} =~ $skip and next;
 302                 my $over = $ng->over or next;
 303                 push @over, $over;
 304         };
 305         return '.' unless @over;
 306
 307         my $prev = 0;
 308         long_response($self, sub {
 309                 my $over = $over[0];
 310                 my $msgs = $over->query_ts($ts, $prev);
 311                 if (scalar @$msgs) {
 312                         more($self, '<' .
 313                                 join(">\r\n<", map { $_->mid } @$msgs ).
 314                                 '>');
 315                         $prev = $msgs->[-1]->{num};
 316                 } else {
 317                         shift @over;
 318                         if (@over) { # continue onto next newsgroup
 319                                 $prev = 0;
 320                                 return 1;
 321                         } else { # break out of the long response.
 322                                 return;
 323                         }
 324                 }
 325         });
 326 }
 327
 328 sub cmd_group ($$) {
 329         my ($self, $group) = @_;
 330         my $no_such = '411 no such news group';
 331         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 332
 333         $self->{ng} = $ng;
 334         my ($min, $max) = $ng->mm->minmax;
 335         $min ||= 0;
 336         $max ||= 0;
 337         $self->{article} = $min;
 338         my $est_size = $max - $min;
 339         "211 $est_size $min $max $group";
 340 }
 341
 342 sub article_adj ($$) {
 343         my ($self, $off) = @_;
 344         my $ng = $self->{ng} or return '412 no newsgroup selected';
 345
 346         my $n = $self->{article};
 347         defined $n or return '420 no current article has been selected';
 348
 349         $n += $off;
 350         my $mid = $ng->mm->mid_for($n);
 351         unless ($mid) {
 352                 $n = $off > 0 ? 'next' : 'previous';
 353                 return "421 no $n article in this group";
 354         }
 355         $self->{article} = $n;
 356         "223 $n <$mid> article retrieved - request text separately";
 357 }
 358
 359 sub cmd_next ($) { article_adj($_[0], 1) }
 360 sub cmd_last ($) { article_adj($_[0], -1) }
 361
 362 # We want to encourage using email and CC-ing everybody involved to avoid
 363 # the single-point-of-failure a single server provides.
 364 sub cmd_post ($) {
 365         my ($self) = @_;
 366         my $ng = $self->{ng};
 367         $ng ? "440 mailto:$ng->{-primary_address} to post"
 368                 : '440 posting not allowed'
 369 }
 370
 371 sub cmd_quit ($) {
 372         my ($self) = @_;
 373         res($self, '205 closing connection - goodbye!');
 374         $self->shutdn;
 375         undef;
 376 }
 377
 378 sub header_append ($$$) {
 379         my ($hdr, $k, $v) = @_;
 380         my @v = $hdr->header($k);
 381         foreach (@v) {
 382                 return if $v eq $_;
 383         }
 384         $hdr->header_set($k, @v, $v);
 385 }
 386
 387 sub xref ($$$$) {
 388         my ($self, $ng, $n, $mid) = @_;
 389         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 390
 391         # num_for is pretty cheap and sometimes we'll lookup the existence
 392         # of an article without getting even the OVER info.  In other words,
 393         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 394         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 395         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 396                 next if $ng eq $other;
 397                 my $num = eval { $other->mm->num_for($mid) } or next;
 398                 $ret .= " $other->{newsgroup}:$num";
 399         }
 400         $ret;
 401 }
 402
 403 sub set_nntp_headers ($$$$$) {
 404         my ($self, $hdr, $ng, $n, $mid) = @_;
 405
 406         # why? leafnode requires a Path: header for some inexplicable
 407         # reason.  We'll fake the shortest one possible.
 408         $hdr->header_set('Path', 'y');
 409
 410         # leafnode (and maybe other NNTP clients) have trouble dealing
 411         # with v2 messages which have multiple Message-IDs (either due
 412         # to our own content-based dedupe or buggy git-send-email versions).
 413         my @mids = $hdr->header('Message-ID');
 414         if (scalar(@mids) > 1) {
 415                 my $mid0 = "<$mid>";
 416                 $hdr->header_set('Message-ID', $mid0);
 417                 my @alt = $hdr->header('X-Alt-Message-ID');
 418                 my %seen = map { $_ => 1 } (@alt, $mid0);
 419                 foreach my $m (@mids) {
 420                         next if $seen{$m}++;
 421                         push @alt, $m;
 422                 }
 423                 $hdr->header_set('X-Alt-Message-ID', @alt);
 424         }
 425
 426         # clobber some
 427         my $xref = xref($self, $ng, $n, $mid);
 428         $hdr->header_set('Xref', $xref);
 429         $xref =~ s/:[0-9]+//g;
 430         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 431         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 432         if (my $url = $ng->base_url) {
 433                 $mid = mid_escape($mid);
 434                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 435                 header_append($hdr, 'List-Archive', "<$url>");
 436         }
 437 }
 438
 439 sub art_lookup ($$$) {
 440         my ($self, $art, $set_headers) = @_;
 441         my $ng = $self->{ng};
 442         my ($n, $mid);
 443         my $err;
 444         if (defined $art) {
 445                 if ($art =~ /\A[0-9]+\z/) {
 446                         $err = '423 no such article number in this group';
 447                         $n = int($art);
 448                         goto find_mid;
 449                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 450                         $mid = $1;
 451                         $err = r430;
 452                         $n = $ng->mm->num_for($mid) if $ng;
 453                         goto found if defined $n;
 454                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 455                                 $n = $g->mm->num_for($mid);
 456                                 if (defined $n) {
 457                                         $ng = $g;
 458                                         goto found;
 459                                 }
 460                         }
 461                         return $err;
 462                 } else {
 463                         return r501;
 464                 }
 465         } else {
 466                 $err = '420 no current article has been selected';
 467                 $n = $self->{article};
 468                 defined $n or return $err;
 469 find_mid:
 470                 $ng or return '412 no newsgroup has been selected';
 471                 $mid = $ng->mm->mid_for($n);
 472                 defined $mid or return $err;
 473         }
 474 found:
 475         my $smsg = $ng->over->get_art($n) or return $err;
 476         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 477
 478         # Email::Simple->new will modify $msg in-place as documented
 479         # in its manpage, so what's left is the body and we won't need
 480         # to call Email::Simple::body(), later
 481         my $hdr = Email::Simple->new($msg)->header_obj;
 482         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 483         [ $n, $mid, $msg, $hdr ];
 484 }
 485
 486 sub msg_body_write ($$) {
 487         my ($self, $msg) = @_;
 488
 489         # these can momentarily double the memory consumption :<
 490         $$msg =~ s/^\./../smg;
 491         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 492         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 493         $self->msg_more($$msg);
 494         '.'
 495 }
 496
 497 sub set_art {
 498         my ($self, $art) = @_;
 499         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 500 }
 501
 502 sub msg_hdr_write ($$$) {
 503         my ($self, $hdr, $body_follows) = @_;
 504         $hdr = $hdr->as_string;
 505         utf8::encode($hdr);
 506         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 507
 508         # for leafnode compatibility, we need to ensure Message-ID headers
 509         # are only a single line.  We can't subclass Email::Simple::Header
 510         # and override _default_fold_at in here, either; since that won't
 511         # affect messages already in the archive.
 512         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 513         $hdr .= "\r\n" if $body_follows;
 514         $self->msg_more($hdr);
 515 }
 516
 517 sub cmd_article ($;$) {
 518         my ($self, $art) = @_;
 519         my $r = art_lookup($self, $art, 1);
 520         return $r unless ref $r;
 521         my ($n, $mid, $msg, $hdr) = @$r;
 522         set_art($self, $art);
 523         more($self, "220 $n <$mid> article retrieved - head and body follow");
 524         msg_hdr_write($self, $hdr, 1);
 525         msg_body_write($self, $msg);
 526 }
 527
 528 sub cmd_head ($;$) {
 529         my ($self, $art) = @_;
 530         my $r = art_lookup($self, $art, 2);
 531         return $r unless ref $r;
 532         my ($n, $mid, undef, $hdr) = @$r;
 533         set_art($self, $art);
 534         more($self, "221 $n <$mid> article retrieved - head follows");
 535         msg_hdr_write($self, $hdr, 0);
 536         '.'
 537 }
 538
 539 sub cmd_body ($;$) {
 540         my ($self, $art) = @_;
 541         my $r = art_lookup($self, $art, 0);
 542         return $r unless ref $r;
 543         my ($n, $mid, $msg) = @$r;
 544         set_art($self, $art);
 545         more($self, "222 $n <$mid> article retrieved - body follows");
 546         msg_body_write($self, $msg);
 547 }
 548
 549 sub cmd_stat ($;$) {
 550         my ($self, $art) = @_;
 551         my $r = art_lookup($self, $art, 0);
 552         return $r unless ref $r;
 553         my ($n, $mid) = @$r;
 554         set_art($self, $art);
 555         "223 $n <$mid> article retrieved - request text separately";
 556 }
 557
 558 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 559
 560 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 561
 562 sub cmd_help ($) {
 563         my ($self) = @_;
 564         more($self, '100 help text follows');
 565         '.'
 566 }
 567
 568 sub get_range ($$) {
 569         my ($self, $range) = @_;
 570         my $ng = $self->{ng} or return '412 no news group has been selected';
 571         defined $range or return '420 No article(s) selected';
 572         my ($beg, $end);
 573         my ($min, $max) = $ng->mm->minmax;
 574         if ($range =~ /\A([0-9]+)\z/) {
 575                 $beg = $end = $1;
 576         } elsif ($range =~ /\A([0-9]+)-\z/) {
 577                 ($beg, $end) = ($1, $max);
 578         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 579                 ($beg, $end) = ($1, $2);
 580         } else {
 581                 return r501;
 582         }
 583         $beg = $min if ($beg < $min);
 584         $end = $max if ($end > $max);
 585         return '420 No article(s) selected' if ($beg > $end);
 586         [ \$beg, $end ];
 587 }
 588
 589 sub long_step {
 590         my ($self) = @_;
 591         # wbuf is unset or empty, here; {long} may add to it
 592         my ($cb, $t0, @args) = @{$self->{long_cb}};
 593         my $more = eval { $cb->($self, @args) };
 594         if ($@ || !$self->{sock}) { # something bad happened...
 595                 delete $self->{long_cb};
 596                 my $elapsed = now() - $t0;
 597                 my $fd = fileno($self->{sock});
 598                 if ($@) {
 599                         err($self,
 600                             "%s during long response[$fd] - %0.6f",
 601                             $@, $elapsed);
 602                 }
 603                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 604                 $self->close;
 605         } elsif ($more) { # $self->{wbuf}:
 606                 $self->update_idle_time;
 607
 608                 # COMPRESS users all share the same DEFLATE context.
 609                 # Flush it here to ensure clients don't see
 610                 # each other's data
 611                 $self->zflush;
 612
 613                 # no recursion, schedule another call ASAP
 614                 # but only after all pending writes are done
 615                 my $wbuf = $self->{wbuf} ||= [];
 616                 push @$wbuf, \&long_step;
 617
 618                 # wbuf may be populated by $cb, no need to rearm if so:
 619                 $self->requeue if scalar(@$wbuf) == 1;
 620         } else { # all done!
 621                 delete $self->{long_cb};
 622                 res($self, '.');
 623                 my $elapsed = now() - $t0;
 624                 my $fd = fileno($self->{sock});
 625                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 626                 my $wbuf = $self->{wbuf};
 627                 $self->requeue unless $wbuf && @$wbuf;
 628         }
 629 }
 630
 631 sub long_response ($$;@) {
 632         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 633
 634         $self->{sock} or return;
 635         # make sure we disable reading during a long response,
 636         # clients should not be sending us stuff and making us do more
 637         # work while we are stream a response to them
 638         $self->{long_cb} = [ $cb, now(), @args ];
 639         long_step($self); # kick off!
 640         undef;
 641 }
 642
 643 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 644         my ($self, $xhdr, $range) = @_;
 645
 646         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 647                 my ($ng, $n) = mid_lookup($self, $1);
 648                 return r430 unless $n;
 649                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 650         } else { # numeric range
 651                 $range = $self->{article} unless defined $range;
 652                 my $r = get_range($self, $range);
 653                 return $r unless ref $r;
 654                 my $mm = $self->{ng}->mm;
 655                 my ($beg, $end) = @$r;
 656                 more($self, $xhdr ? r221 : r225);
 657                 long_response($self, sub {
 658                         my $r = $mm->msg_range($beg, $end);
 659                         @$r or return;
 660                         more($self, join("\r\n", map {
 661                                 "$_->[0] <$_->[1]>"
 662                         } @$r));
 663                         1;
 664                 });
 665         }
 666 }
 667
 668 sub mid_lookup ($$) {
 669         my ($self, $mid) = @_;
 670         my $self_ng = $self->{ng};
 671         if ($self_ng) {
 672                 my $n = $self_ng->mm->num_for($mid);
 673                 return ($self_ng, $n) if defined $n;
 674         }
 675         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 676                 next if defined $self_ng && $ng eq $self_ng;
 677                 my $n = $ng->mm->num_for($mid);
 678                 return ($ng, $n) if defined $n;
 679         }
 680         (undef, undef);
 681 }
 682
 683 sub xref_range_i {
 684         my ($self, $beg, $end) = @_;
 685         my $ng = $self->{ng};
 686         my $r = $ng->mm->msg_range($beg, $end);
 687         @$r or return;
 688         more($self, join("\r\n", map {
 689                 my $num = $_->[0];
 690                 "$num ".xref($self, $ng, $num, $_->[1]);
 691         } @$r));
 692         1;
 693 }
 694
 695 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 696         my ($self, $xhdr, $range) = @_;
 697
 698         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 699                 my $mid = $1;
 700                 my ($ng, $n) = mid_lookup($self, $mid);
 701                 return r430 unless $n;
 702                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 703                                 xref($self, $ng, $n, $mid));
 704         } else { # numeric range
 705                 $range = $self->{article} unless defined $range;
 706                 my $r = get_range($self, $range);
 707                 return $r unless ref $r;
 708                 more($self, $xhdr ? r221 : r225);
 709                 long_response($self, \&xref_range_i, @$r);
 710         }
 711 }
 712
 713 sub over_header_for {
 714         my ($over, $num, $field) = @_;
 715         my $smsg = $over->get_art($num) or return;
 716         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 717         $smsg->{$field};
 718 }
 719
 720 sub hdr_searchmsg ($$$$) {
 721         my ($self, $xhdr, $field, $range) = @_;
 722         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 723                 my ($ng, $n) = mid_lookup($self, $1);
 724                 return r430 unless defined $n;
 725                 my $v = over_header_for($ng->over, $n, $field);
 726                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 727         } else { # numeric range
 728                 $range = $self->{article} unless defined $range;
 729                 my $over = $self->{ng}->over;
 730                 my $mm = $self->{ng}->mm;
 731                 my $r = get_range($self, $range);
 732                 return $r unless ref $r;
 733                 my ($beg, $end) = @$r;
 734                 more($self, $xhdr ? r221 : r225);
 735                 my $cur = $$beg;
 736                 long_response($self, sub {
 737                         my $msgs = $over->query_xover($cur, $end);
 738                         my $nr = scalar @$msgs or return;
 739                         my $tmp = '';
 740                         foreach my $s (@$msgs) {
 741                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 742                         }
 743                         utf8::encode($tmp);
 744                         $self->msg_more($tmp);
 745                         $cur = $msgs->[-1]->{num} + 1;
 746                 });
 747         }
 748 }
 749
 750 sub do_hdr ($$$;$) {
 751         my ($self, $xhdr, $header, $range) = @_;
 752         my $sub = lc $header;
 753         if ($sub eq 'message-id') {
 754                 hdr_message_id($self, $xhdr, $range);
 755         } elsif ($sub eq 'xref') {
 756                 hdr_xref($self, $xhdr, $range);
 757         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 758                                 bytes|lines)\z/x) {
 759                 hdr_searchmsg($self, $xhdr, $sub, $range);
 760         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 761                 hdr_searchmsg($self, $xhdr, $1, $range);
 762         } else {
 763                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 764         }
 765 }
 766
 767 # RFC 3977
 768 sub cmd_hdr ($$;$) {
 769         my ($self, $header, $range) = @_;
 770         do_hdr($self, 0, $header, $range);
 771 }
 772
 773 # RFC 2980
 774 sub cmd_xhdr ($$;$) {
 775         my ($self, $header, $range) = @_;
 776         do_hdr($self, 1, $header, $range);
 777 }
 778
 779 sub hdr_mid_prefix ($$$$$) {
 780         my ($self, $xhdr, $ng, $n, $mid) = @_;
 781         return $mid if $xhdr;
 782
 783         # HDR for RFC 3977 users
 784         if (my $self_ng = $self->{ng}) {
 785                 ($self_ng eq $ng) ? $n : '0';
 786         } else {
 787                 '0';
 788         }
 789 }
 790
 791 sub hdr_mid_response ($$$$$$) {
 792         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 793         my $res = '';
 794         if ($xhdr) {
 795                 $res .= r221 . "\r\n";
 796                 $res .= "$mid $v\r\n";
 797         } else {
 798                 $res .= r225 . "\r\n";
 799                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 800                 $res .= "$pfx $v\r\n";
 801         }
 802         res($self, $res .= '.');
 803         undef;
 804 }
 805
 806 sub cmd_xrover ($;$) {
 807         my ($self, $range) = @_;
 808         my $ng = $self->{ng} or return '412 no newsgroup selected';
 809         (defined $range && $range =~ /[<>]/) and
 810                 return '420 No article(s) selected'; # no message IDs
 811
 812         $range = $self->{article} unless defined $range;
 813         my $r = get_range($self, $range);
 814         return $r unless ref $r;
 815         my ($beg, $end) = @$r;
 816         my $mm = $ng->mm;
 817         my $over = $ng->over;
 818         more($self, '224 Overview information follows');
 819
 820         long_response($self, sub {
 821                 my $h = over_header_for($over, $$beg, 'references');
 822                 more($self, "$$beg $h") if defined($h);
 823                 $$beg++ < $end;
 824         });
 825 }
 826
 827 sub over_line ($$$$) {
 828         my ($self, $ng, $num, $smsg) = @_;
 829         # n.b. field access and procedural calls can be
 830         # 10%-15% faster than OO method calls:
 831         my $s = join("\t", $num,
 832                 $smsg->{subject},
 833                 $smsg->{from},
 834                 PublicInbox::SearchMsg::date($smsg),
 835                 "<$smsg->{mid}>",
 836                 $smsg->{references},
 837                 $smsg->{bytes},
 838                 $smsg->{lines},
 839                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 840         utf8::encode($s);
 841         $s
 842 }
 843
 844 sub cmd_over ($;$) {
 845         my ($self, $range) = @_;
 846         if ($range && $range =~ /\A<(.+)>\z/) {
 847                 my ($ng, $n) = mid_lookup($self, $1);
 848                 defined $n or return r430;
 849                 my $smsg = $ng->over->get_art($n) or return r430;
 850                 more($self, '224 Overview information follows (multi-line)');
 851
 852                 # Only set article number column if it's the current group
 853                 my $self_ng = $self->{ng};
 854                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 855                 more($self, over_line($self, $ng, $n, $smsg));
 856                 '.';
 857         } else {
 858                 cmd_xover($self, $range);
 859         }
 860 }
 861
 862 sub cmd_xover ($;$) {
 863         my ($self, $range) = @_;
 864         $range = $self->{article} unless defined $range;
 865         my $r = get_range($self, $range);
 866         return $r unless ref $r;
 867         my ($beg, $end) = @$r;
 868         more($self, "224 Overview information follows for $$beg to $end");
 869         my $over = $self->{ng}->over;
 870         my $cur = $$beg;
 871         long_response($self, sub {
 872                 my $msgs = $over->query_xover($cur, $end);
 873                 my $nr = scalar @$msgs or return;
 874
 875                 # OVERVIEW.FMT
 876                 more($self, join("\r\n", map {
 877                         over_line($self, $self->{ng}, $_->{num}, $_);
 878                         } @$msgs));
 879                 $cur = $msgs->[-1]->{num} + 1;
 880         });
 881 }
 882
 883 sub compressed { undef }
 884
 885 sub cmd_starttls ($) {
 886         my ($self) = @_;
 887         my $sock = $self->{sock} or return;
 888         # RFC 4642 2.2.1
 889         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 890         my $opt = $self->{nntpd}->{accept_tls} or
 891                 return '580 can not initiate TLS negotiation';
 892         res($self, '382 Continue with TLS negotiation');
 893         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 894         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 895         undef;
 896 }
 897
 898 # RFC 8054
 899 sub cmd_compress ($$) {
 900         my ($self, $alg) = @_;
 901         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 902         return r502 if $self->compressed || !$have_deflate;
 903         PublicInbox::NNTPdeflate->enable($self);
 904         $self->requeue;
 905         undef
 906 }
 907
 908 sub zflush {} # overridden by NNTPdeflate
 909
 910 sub cmd_xpath ($$) {
 911         my ($self, $mid) = @_;
 912         return r501 unless $mid =~ /\A<(.+)>\z/;
 913         $mid = $1;
 914         my @paths;
 915         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 916                 my $n = $ng->mm->num_for($mid);
 917                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 918         }
 919         return '430 no such article on server' unless @paths;
 920         '223 '.join(' ', @paths);
 921 }
 922
 923 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 924
 925 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 926
 927 sub do_write ($$) {
 928         my $self = $_[0];
 929         my $done = $self->write(\($_[1]));
 930         return 0 unless $self->{sock};
 931
 932         $done;
 933 }
 934
 935 sub err ($$;@) {
 936         my ($self, $fmt, @args) = @_;
 937         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 938 }
 939
 940 sub out ($$;@) {
 941         my ($self, $fmt, @args) = @_;
 942         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 943 }
 944
 945 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 946 sub event_step {
 947         my ($self) = @_;
 948
 949         return unless $self->flush_write && $self->{sock};
 950
 951         $self->update_idle_time;
 952         # only read more requests if we've drained the write buffer,
 953         # otherwise we can be buffering infinitely w/o backpressure
 954
 955         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 956         my $r = 1;
 957
 958         if (index($$rbuf, "\n") < 0) {
 959                 my $off = bytes::length($$rbuf);
 960                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 961         }
 962         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 963                 my $line = $1;
 964                 return $self->close if $line =~ /[[:cntrl:]]/s;
 965                 my $t0 = now();
 966                 my $fd = fileno($self->{sock});
 967                 $r = eval { process_line($self, $line) };
 968                 my $pending = $self->{wbuf} ? ' pending' : '';
 969                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 970         }
 971
 972         return $self->close if $r < 0;
 973         my $len = bytes::length($$rbuf);
 974         return $self->close if ($len >= LINE_MAX);
 975         $self->rbuf_idle($rbuf);
 976         $self->update_idle_time;
 977
 978         # maybe there's more pipelined data, or we'll have
 979         # to register it for socket-readiness notifications
 980         $self->requeue unless $self->{wbuf};
 981 }
 982
 983 # for graceful shutdown in PublicInbox::Daemon:
 984 sub busy {
 985         my ($self, $now) = @_;
 986         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 987 }
 988
 989 # this is an import to prevent "perl -c" from complaining about fields
 990 sub import {
 991         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 992                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
 993 }
 994
 995 1;