lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 use Email::Simple;
  15 use Data::Dumper qw(Dumper);
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use URI::Escape qw(uri_escape_utf8);
  19 use constant {
  20         r501 => '501 command syntax error',
  21         r221 => '221 Header follows',
  22         r224 => '224 Overview information follows (multi-line)',
  23         r225 => '225 Headers follow (multi-line)',
  24         r430 => '430 No article with that message-id',
  25         long_response_limit => 0xffffffff,
  26 };
  27
  28 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 # LISTGROUP could get pretty bad, too...
  37 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  38
  39 my $EXPMAP; # fd -> [ idle_time, $self ]
  40 my $EXPTIMER;
  41 our $EXPTIME = 180; # 3 minutes
  42 my $WEAKEN = {}; # string(nntpd) -> nntpd
  43 my $WEAKTIMER;
  44
  45 my $next_tick;
  46 my $nextq = [];
  47 sub next_tick () {
  48         $next_tick = undef;
  49         my $q = $nextq;
  50         $nextq = [];
  51         foreach my $nntp (@$q) {
  52                 # for request && response protocols, always finish writing
  53                 # before finishing reading:
  54                 if (my $long_cb = $nntp->{long_res}) {
  55                         $nntp->write($long_cb);
  56                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  57                         event_read($nntp);
  58                 }
  59         }
  60 }
  61
  62 sub update_idle_time ($) {
  63         my ($self) = @_;
  64         my $tmp = $self->{sock} or return;
  65         $tmp = fileno($tmp);
  66         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  67 }
  68
  69 # reduce FD pressure by closing some "git cat-file --batch" processes
  70 # and unused FDs for msgmap and Xapian indices
  71 sub weaken_groups () {
  72         $WEAKTIMER = undef;
  73         foreach my $nntpd (values %$WEAKEN) {
  74                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  75         }
  76         $WEAKEN = {};
  77 }
  78
  79 sub expire_old () {
  80         my $now = now();
  81         my $exp = $EXPTIME;
  82         my $old = $now - $exp;
  83         my $next = $now + $exp;
  84         my $nr = 0;
  85         my %new;
  86         while (my ($fd, $v) = each %$EXPMAP) {
  87                 my ($idle_time, $nntp) = @$v;
  88                 if ($idle_time < $old) {
  89                         $nntp->close; # idempotent
  90                 } else {
  91                         my $nexp = $idle_time + $exp;
  92                         $next = $nexp if ($nexp < $next);
  93                         ++$nr;
  94                         $new{$fd} = $v;
  95                 }
  96         }
  97         $EXPMAP = \%new;
  98         if ($nr) {
  99                 $next -= $now;
 100                 $next = 0 if $next < 0;
 101                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
 102                 weaken_groups();
 103         } else {
 104                 $EXPTIMER = undef;
 105                 # noop to kick outselves out of the loop ASAP so descriptors
 106                 # really get closed
 107                 Danga::Socket->AddTimer(0, sub {});
 108
 109                 # grace period for reaping resources
 110                 $WEAKTIMER ||= Danga::Socket->AddTimer(30, *weaken_groups);
 111         }
 112 }
 113
 114 sub new ($$$) {
 115         my ($class, $sock, $nntpd) = @_;
 116         my $self = fields::new($class);
 117         $self->SUPER::new($sock);
 118         $self->{nntpd} = $nntpd;
 119         res($self, '201 server ready - post via email');
 120         $self->{rbuf} = '';
 121         $self->watch_read(1);
 122         update_idle_time($self);
 123         $WEAKEN->{"$nntpd"} = $nntpd;
 124         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
 125         $self;
 126 }
 127
 128 sub args_ok ($$) {
 129         my ($cb, $argc) = @_;
 130         my $tot = prototype $cb;
 131         my ($nreq, undef) = split(';', $tot);
 132         $nreq = ($nreq =~ tr/$//) - 1;
 133         $tot = ($tot =~ tr/$//) - 1;
 134         ($argc <= $tot && $argc >= $nreq);
 135 }
 136
 137 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 138 sub process_line ($$) {
 139         my ($self, $l) = @_;
 140         my ($req, @args) = split(/\s+/, $l);
 141         $req = lc($req);
 142         $req = eval {
 143                 no strict 'refs';
 144                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 145         };
 146         return res($self, '500 command not recognized') unless $req;
 147         return res($self, r501) unless args_ok($req, scalar @args);
 148
 149         my $res = eval { $req->($self, @args) };
 150         my $err = $@;
 151         if ($err && !$self->{closed}) {
 152                 chomp($l = Dumper(\$l));
 153                 err($self, 'error from: %s (%s)', $l, $err);
 154                 $res = '503 program fault - command not performed';
 155         }
 156         return 0 unless defined $res;
 157         res($self, $res);
 158 }
 159
 160 sub cmd_mode ($$) {
 161         my ($self, $arg) = @_;
 162         $arg = uc $arg;
 163         return r501 unless $arg eq 'READER';
 164         '201 Posting prohibited';
 165 }
 166
 167 sub cmd_slave ($) { '202 slave status noted' }
 168
 169 sub cmd_xgtitle ($;$) {
 170         my ($self, $wildmat) = @_;
 171         more($self, '282 list of groups and descriptions follows');
 172         list_newsgroups($self, $wildmat);
 173         '.'
 174 }
 175
 176 sub list_overview_fmt ($) {
 177         my ($self) = @_;
 178         do_more($self, $OVERVIEW_FMT);
 179 }
 180
 181 sub list_headers ($;$) {
 182         my ($self) = @_;
 183         do_more($self, $LIST_HEADERS);
 184 }
 185
 186 sub list_active ($;$) {
 187         my ($self, $wildmat) = @_;
 188         wildmat2re($wildmat);
 189         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 190                 $ng->{name} =~ $wildmat or next;
 191                 group_line($self, $ng);
 192         }
 193 }
 194
 195 sub list_active_times ($;$) {
 196         my ($self, $wildmat) = @_;
 197         wildmat2re($wildmat);
 198         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 199                 $ng->{name} =~ $wildmat or next;
 200                 my $c = eval { $ng->mm->created_at } || time;
 201                 more($self, "$ng->{name} $c $ng->{address}");
 202         }
 203 }
 204
 205 sub list_newsgroups ($;$) {
 206         my ($self, $wildmat) = @_;
 207         wildmat2re($wildmat);
 208         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 209                 $ng->{name} =~ $wildmat or next;
 210                 my $d = $ng->description;
 211                 more($self, "$ng->{name} $d");
 212         }
 213 }
 214
 215 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 216 sub cmd_list ($;$$) {
 217         my ($self, @args) = @_;
 218         if (scalar @args) {
 219                 my $arg = shift @args;
 220                 $arg =~ tr/A-Z./a-z_/;
 221                 $arg = "list_$arg";
 222                 return r501 if $DISABLED{$arg};
 223
 224                 $arg = eval {
 225                         no strict 'refs';
 226                         *{$arg}{CODE};
 227                 };
 228                 return r501 unless $arg && args_ok($arg, scalar @args);
 229                 more($self, '215 information follows');
 230                 $arg->($self, @args);
 231         } else {
 232                 more($self, '215 list of newsgroups follows');
 233                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 234                         group_line($self, $ng);
 235                 }
 236         }
 237         '.'
 238 }
 239
 240 sub cmd_listgroup ($;$) {
 241         my ($self, $group) = @_;
 242         if (defined $group) {
 243                 my $res = cmd_group($self, $group);
 244                 return $res if ($res !~ /\A211 /);
 245                 more($self, $res);
 246         }
 247
 248         $self->{ng} or return '412 no newsgroup selected';
 249         long_response($self, 0, long_response_limit, sub {
 250                 my ($i) = @_;
 251                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 252                         my ($ary) = @_;
 253                         more($self, join("\r\n", @$ary));
 254                 });
 255
 256                 # -1 to adjust for implicit increment in long_response
 257                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 258         });
 259 }
 260
 261 sub parse_time ($$;$) {
 262         my ($date, $time, $gmt) = @_;
 263         use Time::Local qw();
 264         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 265         if (defined $gmt) {
 266                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 267                 $gmt = 1;
 268         }
 269         my @now = $gmt ? gmtime : localtime;
 270         my ($YYYY, $MM, $DD);
 271         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 272                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 273         } else { # legacy clients send YYMMDD
 274                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 275                 if ($YYYY > strftime('%y', @now)) {
 276                         my $cur_year = $now[5] + 1900;
 277                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 278                 }
 279         }
 280         if ($gmt) {
 281                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 282         } else {
 283                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 284         }
 285 }
 286
 287 sub group_line ($$) {
 288         my ($self, $ng) = @_;
 289         my ($min, $max) = $ng->mm->minmax;
 290         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 291 }
 292
 293 sub cmd_newgroups ($$$;$$) {
 294         my ($self, $date, $time, $gmt, $dists) = @_;
 295         my $ts = eval { parse_time($date, $time, $gmt) };
 296         return r501 if $@;
 297
 298         # TODO dists
 299         more($self, '231 list of new newsgroups follows');
 300         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 301                 my $c = eval { $ng->mm->created_at } || 0;
 302                 next unless $c > $ts;
 303                 group_line($self, $ng);
 304         }
 305         '.'
 306 }
 307
 308 sub wildmat2re (;$) {
 309         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 310         my %keep;
 311         my $salt = rand;
 312         use Digest::SHA qw(sha1_hex);
 313         my $tmp = $_[0];
 314
 315         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 316                 my $orig = $1;
 317                 my $key = sha1_hex($orig . $salt);
 318                 $orig =~ s/([^\w\-])+/\Q$1/g;
 319                 $keep{$key} = $orig;
 320                 $key
 321                 #gex;
 322         my %map = ('*' => '.*', '?' => '.' );
 323         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 324         if (scalar %keep) {
 325                 $tmp =~ s#([a-f0-9]{40})#
 326                         my $orig = $keep{$1};
 327                         defined $orig ? $orig : $1;
 328                         #ge;
 329         }
 330         $_[0] = qr/\A$tmp\z/;
 331 }
 332
 333 sub ngpat2re (;$) {
 334         return $_[0] = qr/\A\z/ unless defined $_[0];
 335         my %map = ('*' => '.*', ',' => '|');
 336         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 337         $_[0] = qr/\A(?:$_[0])\z/;
 338 }
 339
 340 sub cmd_newnews ($$$$;$$) {
 341         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 342         my $ts = eval { parse_time($date, $time, $gmt) };
 343         return r501 if $@;
 344         more($self, '230 list of new articles by message-id follows');
 345         my ($keep, $skip) = split('!', $newsgroups, 2);
 346         ngpat2re($keep);
 347         ngpat2re($skip);
 348         my @srch;
 349         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 350                 $ng->{name} =~ $keep or next;
 351                 $ng->{name} =~ $skip and next;
 352                 my $srch = $ng->search or next;
 353                 push @srch, $srch;
 354         };
 355         return '.' unless @srch;
 356
 357         $ts .= '..';
 358         my $opts = { asc => 1, limit => 1000, offset => 0 };
 359         long_response($self, 0, long_response_limit, sub {
 360                 my ($i) = @_;
 361                 my $srch = $srch[0];
 362                 my $res = $srch->query($ts, $opts);
 363                 my $msgs = $res->{msgs};
 364                 if (my $nr = scalar @$msgs) {
 365                         more($self, '<' .
 366                                 join(">\r\n<", map { $_->mid } @$msgs ).
 367                                 '>');
 368                         $opts->{offset} += $nr;
 369                 } else {
 370                         shift @srch;
 371                         if (@srch) { # continue onto next newsgroup
 372                                 $opts->{offset} = 0;
 373                         } else { # break out of the long response.
 374                                 $$i = long_response_limit;
 375                         }
 376                 }
 377         });
 378 }
 379
 380 sub cmd_group ($$) {
 381         my ($self, $group) = @_;
 382         my $no_such = '411 no such news group';
 383         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 384
 385         $self->{ng} = $ng;
 386         my ($min, $max) = $ng->mm->minmax;
 387         $min ||= 0;
 388         $max ||= 0;
 389         $self->{article} = $min;
 390         my $est_size = $max - $min;
 391         "211 $est_size $min $max $group";
 392 }
 393
 394 sub article_adj ($$) {
 395         my ($self, $off) = @_;
 396         my $ng = $self->{ng} or return '412 no newsgroup selected';
 397
 398         my $n = $self->{article};
 399         defined $n or return '420 no current article has been selected';
 400
 401         $n += $off;
 402         my $mid = $ng->mm->mid_for($n);
 403         unless ($mid) {
 404                 $n = $off > 0 ? 'next' : 'previous';
 405                 return "421 no $n article in this group";
 406         }
 407         $self->{article} = $n;
 408         "223 $n <$mid> article retrieved - request text separately";
 409 }
 410
 411 sub cmd_next ($) { article_adj($_[0], 1) }
 412 sub cmd_last ($) { article_adj($_[0], -1) }
 413
 414 # We want to encourage using email and CC-ing everybody involved to avoid
 415 # the single-point-of-failure a single server provides.
 416 sub cmd_post ($) {
 417         my ($self) = @_;
 418         my $ng = $self->{ng};
 419         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 420 }
 421
 422 sub cmd_quit ($) {
 423         my ($self) = @_;
 424         res($self, '205 closing connection - goodbye!');
 425         $self->close;
 426         undef;
 427 }
 428
 429 sub header_append ($$$) {
 430         my ($hdr, $k, $v) = @_;
 431         my @v = $hdr->header($k);
 432         foreach (@v) {
 433                 return if $v eq $_;
 434         }
 435         $hdr->header_set($k, @v, $v);
 436 }
 437
 438 sub set_nntp_headers {
 439         my ($hdr, $ng, $n, $mid) = @_;
 440
 441         # clobber some
 442         $hdr->header_set('Newsgroups', $ng->{name});
 443         $hdr->header_set('Xref', xref($ng, $n));
 444         header_append($hdr, 'List-Post', "<mailto:$ng->{address}>");
 445         if (my $url = $ng->{url}) {
 446                 $mid = uri_escape_utf8($mid);
 447                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 448                 header_append($hdr, 'List-Archive', "<$url>");
 449         }
 450 }
 451
 452 sub art_lookup ($$$) {
 453         my ($self, $art, $set_headers) = @_;
 454         my $ng = $self->{ng};
 455         my ($n, $mid);
 456         my $err;
 457         if (defined $art) {
 458                 if ($art =~ /\A\d+\z/o) {
 459                         $err = '423 no such article number in this group';
 460                         $n = int($art);
 461                         goto find_mid;
 462                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 463                         $mid = $1;
 464                         $err = r430;
 465                         $n = $ng->mm->num_for($mid) if $ng;
 466                         goto found if defined $n;
 467                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 468                                 $n = $g->mm->num_for($mid);
 469                                 if (defined $n) {
 470                                         $ng = $g;
 471                                         goto found;
 472                                 }
 473                         }
 474                         return $err;
 475                 } else {
 476                         return r501;
 477                 }
 478         } else {
 479                 $err = '420 no current article has been selected';
 480                 $n = $self->{article};
 481                 defined $n or return $err;
 482 find_mid:
 483                 $ng or return '412 no newsgroup has been selected';
 484                 $mid = $ng->mm->mid_for($n);
 485                 defined $mid or return $err;
 486         }
 487 found:
 488         my $o = 'HEAD:' . mid2path($mid);
 489         my $bytes;
 490         my $s = eval { Email::Simple->new($ng->gcf->cat_file($o, \$bytes)) };
 491         return $err unless $s;
 492         my $lines;
 493         if ($set_headers) {
 494                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 495                 $lines = $s->body =~ tr!\n!\n!;
 496
 497                 # must be last
 498                 $s->body_set('') if ($set_headers == 2);
 499         }
 500         [ $n, $mid, $s, $bytes, $lines, $ng ];
 501 }
 502
 503 sub simple_body_write ($$) {
 504         my ($self, $s) = @_;
 505         my $body = $s->body;
 506         $s->body_set('');
 507         $body =~ s/^\./../smg;
 508         $body =~ s/(?<!\r)\n/\r\n/sg;
 509         do_more($self, $body);
 510         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 511         '.'
 512 }
 513
 514 sub set_art {
 515         my ($self, $art) = @_;
 516         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 517 }
 518
 519 sub cmd_article ($;$) {
 520         my ($self, $art) = @_;
 521         my $r = art_lookup($self, $art, 1);
 522         return $r unless ref $r;
 523         my ($n, $mid, $s) = @$r;
 524         set_art($self, $art);
 525         more($self, "220 $n <$mid> article retrieved - head and body follow");
 526         do_more($self, $s->header_obj->as_string);
 527         do_more($self, "\r\n");
 528         simple_body_write($self, $s);
 529 }
 530
 531 sub cmd_head ($;$) {
 532         my ($self, $art) = @_;
 533         my $r = art_lookup($self, $art, 2);
 534         return $r unless ref $r;
 535         my ($n, $mid, $s) = @$r;
 536         set_art($self, $art);
 537         more($self, "221 $n <$mid> article retrieved - head follows");
 538         do_more($self, $s->header_obj->as_string);
 539         '.'
 540 }
 541
 542 sub cmd_body ($;$) {
 543         my ($self, $art) = @_;
 544         my $r = art_lookup($self, $art, 0);
 545         return $r unless ref $r;
 546         my ($n, $mid, $s) = @$r;
 547         set_art($self, $art);
 548         more($self, "222 $n <$mid> article retrieved - body follows");
 549         simple_body_write($self, $s);
 550 }
 551
 552 sub cmd_stat ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 0);
 555         return $r unless ref $r;
 556         my ($n, $mid, undef) = @$r;
 557         set_art($self, $art);
 558         "223 $n <$mid> article retrieved - request text separately";
 559 }
 560
 561 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 562
 563 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 564
 565 sub cmd_help ($) {
 566         my ($self) = @_;
 567         more($self, '100 help text follows');
 568         '.'
 569 }
 570
 571 sub get_range ($$) {
 572         my ($self, $range) = @_;
 573         my $ng = $self->{ng} or return '412 no news group has been selected';
 574         defined $range or return '420 No article(s) selected';
 575         my ($beg, $end);
 576         my ($min, $max) = $ng->mm->minmax;
 577         if ($range =~ /\A(\d+)\z/) {
 578                 $beg = $end = $1;
 579         } elsif ($range =~ /\A(\d+)-\z/) {
 580                 ($beg, $end) = ($1, $max);
 581         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 582                 ($beg, $end) = ($1, $2);
 583         } else {
 584                 return r501;
 585         }
 586         $beg = $min if ($beg < $min);
 587         $end = $max if ($end > $max);
 588         return '420 No article(s) selected' if ($beg > $end);
 589         [ $beg, $end ];
 590 }
 591
 592 sub long_response ($$$$) {
 593         my ($self, $beg, $end, $cb) = @_;
 594         die "BUG: nested long response" if $self->{long_res};
 595
 596         my $fd = $self->{fd};
 597         defined $fd or return;
 598         # make sure we disable reading during a long response,
 599         # clients should not be sending us stuff and making us do more
 600         # work while we are stream a response to them
 601         $self->watch_read(0);
 602         my $t0 = now();
 603         $self->{long_res} = sub {
 604                 # limit our own running time for fairness with other
 605                 # clients and to avoid buffering too much:
 606                 my $lim = 100;
 607
 608                 my $err;
 609                 do {
 610                         eval { $cb->(\$beg) };
 611                 } until (($err = $@) || $self->{closed} ||
 612                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 613
 614                 if ($err || $self->{closed}) {
 615                         $self->{long_res} = undef;
 616
 617                         if ($err) {
 618                                 err($self,
 619                                     "%s during long response[$fd] - %0.6f",
 620                                     $err, now() - $t0);
 621                         }
 622                         if ($self->{closed}) {
 623                                 out($self, " deferred[$fd] aborted - %0.6f",
 624                                            now() - $t0);
 625                         } else {
 626                                 update_idle_time($self);
 627                                 $self->watch_read(1);
 628                         }
 629                 } elsif (!$lim || $self->{write_buf_size}) {
 630                         # no recursion, schedule another call ASAP
 631                         # but only after all pending writes are done
 632                         update_idle_time($self);
 633
 634                         push @$nextq, $self;
 635                         $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
 636                 } else { # all done!
 637                         $self->{long_res} = undef;
 638                         $self->watch_read(1);
 639                         res($self, '.');
 640                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 641                 }
 642         };
 643         $self->{long_res}->(); # kick off!
 644         undef;
 645 }
 646
 647 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 648         my ($self, $xhdr, $range) = @_;
 649
 650         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 651                 my ($ng, $n) = mid_lookup($self, $1);
 652                 return r430 unless $n;
 653                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 654         } else { # numeric range
 655                 $range = $self->{article} unless defined $range;
 656                 my $r = get_range($self, $range);
 657                 return $r unless ref $r;
 658                 my $mm = $self->{ng}->mm;
 659                 my ($beg, $end) = @$r;
 660                 more($self, $xhdr ? r221 : r225);
 661                 long_response($self, $beg, $end, sub {
 662                         my ($i) = @_;
 663                         my $mid = $mm->mid_for($$i);
 664                         more($self, "$$i <$mid>") if defined $mid;
 665                 });
 666         }
 667 }
 668
 669 sub xref ($$) {
 670         my ($ng, $n) = @_;
 671         "$ng->{domain} $ng->{name}:$n"
 672 }
 673
 674 sub mid_lookup ($$) {
 675         my ($self, $mid) = @_;
 676         my $self_ng = $self->{ng};
 677         if ($self_ng) {
 678                 my $n = $self_ng->mm->num_for($mid);
 679                 return ($self_ng, $n) if defined $n;
 680         }
 681         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 682                 next if defined $self_ng && $ng eq $self_ng;
 683                 my $n = $ng->mm->num_for($mid);
 684                 return ($ng, $n) if defined $n;
 685         }
 686         (undef, undef);
 687 }
 688
 689 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 690         my ($self, $xhdr, $range) = @_;
 691
 692         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 693                 my ($ng, $n) = mid_lookup($self, $1);
 694                 return r430 unless $n;
 695                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 696         } else { # numeric range
 697                 $range = $self->{article} unless defined $range;
 698                 my $r = get_range($self, $range);
 699                 return $r unless ref $r;
 700                 my $ng = $self->{ng};
 701                 my $mm = $ng->mm;
 702                 my ($beg, $end) = @$r;
 703                 more($self, $xhdr ? r221 : r225);
 704                 long_response($self, $beg, $end, sub {
 705                         my ($i) = @_;
 706                         my $mid = $mm->mid_for($$i);
 707                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 708                 });
 709         }
 710 }
 711
 712 sub search_header_for {
 713         my ($srch, $mid, $field) = @_;
 714         my $smsg = $srch->lookup_message($mid) or return;
 715         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 716         $smsg->$field;
 717 }
 718
 719 sub hdr_searchmsg ($$$$) {
 720         my ($self, $xhdr, $field, $range) = @_;
 721         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 722                 my ($ng, $n) = mid_lookup($self, $1);
 723                 return r430 unless $n;
 724                 my $v = search_header_for($ng->search, $range, $field);
 725                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 726         } else { # numeric range
 727                 $range = $self->{article} unless defined $range;
 728                 my $srch = $self->{ng}->search;
 729                 my $mm = $self->{ng}->mm;
 730                 my $r = get_range($self, $range);
 731                 return $r unless ref $r;
 732                 my ($beg, $end) = @$r;
 733                 more($self, $xhdr ? r221 : r225);
 734                 my $off = 0;
 735                 long_response($self, $beg, $end, sub {
 736                         my ($i) = @_;
 737                         my $res = $srch->query_xover($beg, $end, $off);
 738                         my $msgs = $res->{msgs};
 739                         my $nr = scalar @$msgs or return;
 740                         $off += $nr;
 741                         my $tmp = '';
 742                         foreach my $s (@$msgs) {
 743                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 744                         }
 745                         do_more($self, $tmp);
 746                         # -1 to adjust for implicit increment in long_response
 747                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 748                 });
 749         }
 750 }
 751
 752 sub do_hdr ($$$;$) {
 753         my ($self, $xhdr, $header, $range) = @_;
 754         my $sub = lc $header;
 755         if ($sub eq 'message-id') {
 756                 hdr_message_id($self, $xhdr, $range);
 757         } elsif ($sub eq 'xref') {
 758                 hdr_xref($self, $xhdr, $range);
 759         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 760                                 bytes|lines)\z/x) {
 761                 hdr_searchmsg($self, $xhdr, $sub, $range);
 762         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 763                 hdr_searchmsg($self, $xhdr, $1, $range);
 764         } else {
 765                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 766         }
 767 }
 768
 769 # RFC 3977
 770 sub cmd_hdr ($$;$) {
 771         my ($self, $header, $range) = @_;
 772         do_hdr($self, 0, $header, $range);
 773 }
 774
 775 # RFC 2980
 776 sub cmd_xhdr ($$;$) {
 777         my ($self, $header, $range) = @_;
 778         do_hdr($self, 1, $header, $range);
 779 }
 780
 781 sub hdr_mid_prefix ($$$$$) {
 782         my ($self, $xhdr, $ng, $n, $mid) = @_;
 783         return $mid if $xhdr;
 784
 785         # HDR for RFC 3977 users
 786         if (my $self_ng = $self->{ng}) {
 787                 ($self_ng eq $ng) ? $n : '0';
 788         } else {
 789                 '0';
 790         }
 791 }
 792
 793 sub hdr_mid_response ($$$$$$) {
 794         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 795         my $res = '';
 796         if ($xhdr) {
 797                 $res .= r221 . "\r\n";
 798                 $res .= "$mid $v\r\n";
 799         } else {
 800                 $res .= r225 . "\r\n";
 801                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 802                 $res .= "$pfx $v\r\n";
 803         }
 804         res($self, $res .= '.');
 805         undef;
 806 }
 807
 808 sub cmd_xrover ($;$) {
 809         my ($self, $range) = @_;
 810         my $ng = $self->{ng} or return '412 no newsgroup selected';
 811         (defined $range && $range =~ /[<>]/) and
 812                 return '420 No article(s) selected'; # no message IDs
 813
 814         $range = $self->{article} unless defined $range;
 815         my $r = get_range($self, $range);
 816         return $r unless ref $r;
 817         my ($beg, $end) = @$r;
 818         my $mm = $ng->mm;
 819         my $srch = $ng->search;
 820         more($self, '224 Overview information follows');
 821         long_response($self, $beg, $end, sub {
 822                 my ($i) = @_;
 823                 my $mid = $mm->mid_for($$i) or return;
 824                 my $h = search_header_for($srch, $mid, 'references');
 825                 more($self, "$$i $h");
 826         });
 827 }
 828
 829 sub over_line ($$) {
 830         my ($num, $smsg) = @_;
 831         # n.b. field access and procedural calls can be
 832         # 10%-15% faster than OO method calls:
 833         join("\t", $num,
 834                 $smsg->{subject},
 835                 $smsg->{from},
 836                 PublicInbox::SearchMsg::date($smsg),
 837                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 838                 $smsg->{references},
 839                 PublicInbox::SearchMsg::bytes($smsg),
 840                 PublicInbox::SearchMsg::lines($smsg));
 841 }
 842
 843 sub cmd_over ($;$) {
 844         my ($self, $range) = @_;
 845         if ($range && $range =~ /\A<(.+)>\z/) {
 846                 my ($ng, $n) = mid_lookup($self, $1);
 847                 my $smsg = $ng->search->lookup_message($range) or
 848                         return '430 No article with that message-id';
 849                 more($self, '224 Overview information follows (multi-line)');
 850                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 851
 852                 # Only set article number column if it's the current group
 853                 my $self_ng = $self->{ng};
 854                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 855                 more($self, over_line($n, $smsg));
 856                 '.';
 857         } else {
 858                 cmd_xover($self, $range);
 859         }
 860 }
 861
 862 sub cmd_xover ($;$) {
 863         my ($self, $range) = @_;
 864         $range = $self->{article} unless defined $range;
 865         my $r = get_range($self, $range);
 866         return $r unless ref $r;
 867         my ($beg, $end) = @$r;
 868         more($self, "224 Overview information follows for $beg to $end");
 869         my $srch = $self->{ng}->search;
 870         my $off = 0;
 871         long_response($self, $beg, $end, sub {
 872                 my ($i) = @_;
 873                 my $res = $srch->query_xover($beg, $end, $off);
 874                 my $msgs = $res->{msgs};
 875                 my $nr = scalar @$msgs or return;
 876                 $off += $nr;
 877
 878                 # OVERVIEW.FMT
 879                 more($self, join("\r\n", map {
 880                         over_line(PublicInbox::SearchMsg::num($_), $_);
 881                         } @$msgs));
 882
 883                 # -1 to adjust for implicit increment in long_response
 884                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 885         });
 886 }
 887
 888 sub cmd_xpath ($$) {
 889         my ($self, $mid) = @_;
 890         return r501 unless $mid =~ /\A<(.+)>\z/;
 891         $mid = $1;
 892         my @paths;
 893         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 894                 my $n = $ng->mm->num_for($mid);
 895                 push @paths, "$ng->{name}/$n" if defined $n;
 896         }
 897         return '430 no such article on server' unless @paths;
 898         '223 '.join(' ', @paths);
 899 }
 900
 901 sub res ($$) {
 902         my ($self, $line) = @_;
 903         do_write($self, $line . "\r\n");
 904 }
 905
 906 sub more ($$) {
 907         my ($self, $line) = @_;
 908         do_more($self, $line . "\r\n");
 909 }
 910
 911 sub do_write ($$) {
 912         my ($self, $data) = @_;
 913         my $done = $self->write($data);
 914         die if $self->{closed};
 915
 916         # Do not watch for readability if we have data in the queue,
 917         # instead re-enable watching for readability when we can
 918         $self->watch_read(0) if (!$done || $self->{long_res});
 919
 920         $done;
 921 }
 922
 923 sub err ($$;@) {
 924         my ($self, $fmt, @args) = @_;
 925         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 926 }
 927
 928 sub out ($$;@) {
 929         my ($self, $fmt, @args) = @_;
 930         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 931 }
 932
 933 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 934
 935 sub do_more ($$) {
 936         my ($self, $data) = @_;
 937         if (MSG_MORE && !$self->{write_buf_size}) {
 938                 my $n = send($self->{sock}, $data, MSG_MORE);
 939                 if (defined $n) {
 940                         my $dlen = length($data);
 941                         return 1 if $n == $dlen; # all done!
 942                         $data = substr($data, $n, $dlen - $n);
 943                 }
 944         }
 945         do_write($self, $data);
 946 }
 947
 948 # callbacks for Danga::Socket
 949
 950 sub event_hup { $_[0]->close }
 951 sub event_err { $_[0]->close }
 952
 953 sub event_write {
 954         my ($self) = @_;
 955         update_idle_time($self);
 956         # only continue watching for readability when we are done writing:
 957         if ($self->write(undef) == 1 && !$self->{long_res}) {
 958                 $self->watch_read(1);
 959         }
 960 }
 961
 962 sub event_read {
 963         my ($self) = @_;
 964         use constant LINE_MAX => 512; # RFC 977 section 2.3
 965         my $r = 1;
 966
 967         my $buf = $self->read(LINE_MAX) or return $self->close;
 968         $self->{rbuf} .= $$buf;
 969         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 970                 my $line = $1;
 971                 my $t0 = now();
 972                 my $fd = $self->{fd};
 973                 $r = eval { process_line($self, $line) };
 974                 my $d = $self->{long_res} ?
 975                         " deferred[$fd]" : '';
 976                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 977         }
 978
 979         return $self->close if $r < 0;
 980         my $len = length($self->{rbuf});
 981         return $self->close if ($len >= LINE_MAX);
 982         update_idle_time($self);
 983 }
 984
 985 sub watch_read {
 986         my ($self, $bool) = @_;
 987         my $rv = $self->SUPER::watch_read($bool);
 988         if ($bool && $self->{rbuf} ne '') {
 989                 # Force another read if there is a pipelined request.
 990                 # We don't know if the socket has anything for us to read,
 991                 # and we must double-check again by the time the timer fires
 992                 # in case we really did dispatch a read event and started
 993                 # another long response.
 994                 push @$nextq, $self;
 995                 $next_tick ||= Danga::Socket->AddTimer(0, *next_tick);
 996         }
 997         $rv;
 998 }
 999
1000 # for graceful shutdown in PublicInbox::Daemon:
1001 sub busy () {
1002         my ($self) = @_;
1003         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1004 }
1005
1006 1;