lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34 my $CAPABILITIES = <<"";
  35 101 Capability list:\r
  36 VERSION 2\r
  37 READER\r
  38 NEWNEWS\r
  39 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  40 HDR\r
  41 OVER\r
  42
  43 my $EXPMAP; # fd -> [ idle_time, $self ]
  44 my $expt;
  45 our $EXPTIME = 180; # 3 minutes
  46
  47 sub update_idle_time ($) {
  48         my ($self) = @_;
  49         my $sock = $self->{sock} or return;
  50         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  51 }
  52
  53 sub expire_old () {
  54         my $now = now();
  55         my $exp = $EXPTIME;
  56         my $old = $now - $exp;
  57         my $nr = 0;
  58         my %new;
  59         while (my ($fd, $v) = each %$EXPMAP) {
  60                 my ($idle_time, $nntp) = @$v;
  61                 if ($idle_time < $old) {
  62                         if (!$nntp->shutdn) {
  63                                 ++$nr;
  64                                 $new{$fd} = $v;
  65                         }
  66                 } else {
  67                         ++$nr;
  68                         $new{$fd} = $v;
  69                 }
  70         }
  71         $EXPMAP = \%new;
  72         $expt = PublicInbox::EvCleanup::later(*expire_old) if $nr;
  73 }
  74
  75 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  76
  77 sub new ($$$) {
  78         my ($class, $sock, $nntpd) = @_;
  79         my $self = fields::new($class);
  80         my $ev = EPOLLIN;
  81         my $wbuf;
  82         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  83                 return CORE::close($sock) if $! != EAGAIN;
  84                 $ev = PublicInbox::TLS::epollbit();
  85                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  86         }
  87         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  88         $self->{nntpd} = $nntpd;
  89         if ($wbuf) {
  90                 $self->{wbuf} = $wbuf;
  91         } else {
  92                 greet($self);
  93         }
  94         update_idle_time($self);
  95         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  96         $self;
  97 }
  98
  99 sub args_ok ($$) {
 100         my ($cb, $argc) = @_;
 101         my $tot = prototype $cb;
 102         my ($nreq, undef) = split(';', $tot);
 103         $nreq = ($nreq =~ tr/$//) - 1;
 104         $tot = ($tot =~ tr/$//) - 1;
 105         ($argc <= $tot && $argc >= $nreq);
 106 }
 107
 108 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 109 sub process_line ($$) {
 110         my ($self, $l) = @_;
 111         my ($req, @args) = split(/[ \t]/, $l);
 112         return 1 unless defined($req); # skip blank line
 113         $req = eval {
 114                 no strict 'refs';
 115                 *{'cmd_'.lc($req)}{CODE};
 116         };
 117         return res($self, '500 command not recognized') unless $req;
 118         return res($self, r501) unless args_ok($req, scalar @args);
 119
 120         my $res = eval { $req->($self, @args) };
 121         my $err = $@;
 122         if ($err && $self->{sock}) {
 123                 local $/ = "\n";
 124                 chomp($l);
 125                 err($self, 'error from: %s (%s)', $l, $err);
 126                 $res = '503 program fault - command not performed';
 127         }
 128         return 0 unless defined $res;
 129         res($self, $res);
 130 }
 131
 132 # The keyword argument is not used (rfc3977 5.2.2)
 133 sub cmd_capabilities ($;$) {
 134         my ($self, undef) = @_;
 135         my $res = $CAPABILITIES;
 136         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 137                         $self->{nntpd}->{accept_tls}) {
 138                 $res .= "STARTTLS\r\n";
 139         }
 140         $res .= '.';
 141 }
 142
 143 sub cmd_mode ($$) {
 144         my ($self, $arg) = @_;
 145         $arg = uc $arg;
 146         return r501 unless $arg eq 'READER';
 147         '201 Posting prohibited';
 148 }
 149
 150 sub cmd_slave ($) { '202 slave status noted' }
 151
 152 sub cmd_xgtitle ($;$) {
 153         my ($self, $wildmat) = @_;
 154         more($self, '282 list of groups and descriptions follows');
 155         list_newsgroups($self, $wildmat);
 156         '.'
 157 }
 158
 159 sub list_overview_fmt ($) {
 160         my ($self) = @_;
 161         $self->msg_more($OVERVIEW_FMT);
 162 }
 163
 164 sub list_headers ($;$) {
 165         my ($self) = @_;
 166         $self->msg_more($LIST_HEADERS);
 167 }
 168
 169 sub list_active ($;$) {
 170         my ($self, $wildmat) = @_;
 171         wildmat2re($wildmat);
 172         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 173                 $ng->{newsgroup} =~ $wildmat or next;
 174                 group_line($self, $ng);
 175         }
 176 }
 177
 178 sub list_active_times ($;$) {
 179         my ($self, $wildmat) = @_;
 180         wildmat2re($wildmat);
 181         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 182                 $ng->{newsgroup} =~ $wildmat or next;
 183                 my $c = eval { $ng->mm->created_at } || time;
 184                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 185         }
 186 }
 187
 188 sub list_newsgroups ($;$) {
 189         my ($self, $wildmat) = @_;
 190         wildmat2re($wildmat);
 191         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 192                 $ng->{newsgroup} =~ $wildmat or next;
 193                 my $d = $ng->description;
 194                 more($self, "$ng->{newsgroup} $d");
 195         }
 196 }
 197
 198 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 199 sub cmd_list ($;$$) {
 200         my ($self, @args) = @_;
 201         if (scalar @args) {
 202                 my $arg = shift @args;
 203                 $arg =~ tr/A-Z./a-z_/;
 204                 $arg = "list_$arg";
 205
 206                 $arg = eval {
 207                         no strict 'refs';
 208                         *{$arg}{CODE};
 209                 };
 210                 return r501 unless $arg && args_ok($arg, scalar @args);
 211                 more($self, '215 information follows');
 212                 $arg->($self, @args);
 213         } else {
 214                 more($self, '215 list of newsgroups follows');
 215                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 216                         group_line($self, $ng);
 217                 }
 218         }
 219         '.'
 220 }
 221
 222 sub cmd_listgroup ($;$) {
 223         my ($self, $group) = @_;
 224         if (defined $group) {
 225                 my $res = cmd_group($self, $group);
 226                 return $res if ($res !~ /\A211 /);
 227                 more($self, $res);
 228         }
 229
 230         $self->{ng} or return '412 no newsgroup selected';
 231         my $n = 0;
 232         long_response($self, sub {
 233                 my $ary = $self->{ng}->mm->ids_after(\$n);
 234                 scalar @$ary or return;
 235                 more($self, join("\r\n", @$ary));
 236                 1;
 237         });
 238 }
 239
 240 sub parse_time ($$;$) {
 241         my ($date, $time, $gmt) = @_;
 242         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 243         if (defined $gmt) {
 244                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 245                 $gmt = 1;
 246         }
 247         my @now = $gmt ? gmtime : localtime;
 248         my ($YYYY, $MM, $DD);
 249         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 250                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 251         } else { # legacy clients send YYMMDD
 252                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 253                 my $cur_year = $now[5] + 1900;
 254                 if ($YYYY > $cur_year) {
 255                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 256                 }
 257         }
 258         if ($gmt) {
 259                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 260         } else {
 261                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 262         }
 263 }
 264
 265 sub group_line ($$) {
 266         my ($self, $ng) = @_;
 267         my ($min, $max) = $ng->mm->minmax;
 268         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 269 }
 270
 271 sub cmd_newgroups ($$$;$$) {
 272         my ($self, $date, $time, $gmt, $dists) = @_;
 273         my $ts = eval { parse_time($date, $time, $gmt) };
 274         return r501 if $@;
 275
 276         # TODO dists
 277         more($self, '231 list of new newsgroups follows');
 278         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 279                 my $c = eval { $ng->mm->created_at } || 0;
 280                 next unless $c > $ts;
 281                 group_line($self, $ng);
 282         }
 283         '.'
 284 }
 285
 286 sub wildmat2re (;$) {
 287         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 288         my %keep;
 289         my $salt = rand;
 290         my $tmp = $_[0];
 291
 292         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 293                 my $orig = $1;
 294                 my $key = sha1_hex($orig . $salt);
 295                 $orig =~ s/([^\w\-])+/\Q$1/g;
 296                 $keep{$key} = $orig;
 297                 $key
 298                 #gex;
 299         my %map = ('*' => '.*', '?' => '.' );
 300         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 301         if (scalar %keep) {
 302                 $tmp =~ s#([a-f0-9]{40})#
 303                         my $orig = $keep{$1};
 304                         defined $orig ? $orig : $1;
 305                         #ge;
 306         }
 307         $_[0] = qr/\A$tmp\z/;
 308 }
 309
 310 sub ngpat2re (;$) {
 311         return $_[0] = qr/\A\z/ unless defined $_[0];
 312         my %map = ('*' => '.*', ',' => '|');
 313         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 314         $_[0] = qr/\A(?:$_[0])\z/;
 315 }
 316
 317 sub cmd_newnews ($$$$;$$) {
 318         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 319         my $ts = eval { parse_time($date, $time, $gmt) };
 320         return r501 if $@;
 321         more($self, '230 list of new articles by message-id follows');
 322         my ($keep, $skip) = split('!', $newsgroups, 2);
 323         ngpat2re($keep);
 324         ngpat2re($skip);
 325         my @over;
 326         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 327                 $ng->{newsgroup} =~ $keep or next;
 328                 $ng->{newsgroup} =~ $skip and next;
 329                 my $over = $ng->over or next;
 330                 push @over, $over;
 331         };
 332         return '.' unless @over;
 333
 334         my $prev = 0;
 335         long_response($self, sub {
 336                 my $over = $over[0];
 337                 my $msgs = $over->query_ts($ts, $prev);
 338                 if (scalar @$msgs) {
 339                         more($self, '<' .
 340                                 join(">\r\n<", map { $_->mid } @$msgs ).
 341                                 '>');
 342                         $prev = $msgs->[-1]->{num};
 343                 } else {
 344                         shift @over;
 345                         if (@over) { # continue onto next newsgroup
 346                                 $prev = 0;
 347                                 return 1;
 348                         } else { # break out of the long response.
 349                                 return;
 350                         }
 351                 }
 352         });
 353 }
 354
 355 sub cmd_group ($$) {
 356         my ($self, $group) = @_;
 357         my $no_such = '411 no such news group';
 358         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 359
 360         $self->{ng} = $ng;
 361         my ($min, $max) = $ng->mm->minmax;
 362         $min ||= 0;
 363         $max ||= 0;
 364         $self->{article} = $min;
 365         my $est_size = $max - $min;
 366         "211 $est_size $min $max $group";
 367 }
 368
 369 sub article_adj ($$) {
 370         my ($self, $off) = @_;
 371         my $ng = $self->{ng} or return '412 no newsgroup selected';
 372
 373         my $n = $self->{article};
 374         defined $n or return '420 no current article has been selected';
 375
 376         $n += $off;
 377         my $mid = $ng->mm->mid_for($n);
 378         unless ($mid) {
 379                 $n = $off > 0 ? 'next' : 'previous';
 380                 return "421 no $n article in this group";
 381         }
 382         $self->{article} = $n;
 383         "223 $n <$mid> article retrieved - request text separately";
 384 }
 385
 386 sub cmd_next ($) { article_adj($_[0], 1) }
 387 sub cmd_last ($) { article_adj($_[0], -1) }
 388
 389 # We want to encourage using email and CC-ing everybody involved to avoid
 390 # the single-point-of-failure a single server provides.
 391 sub cmd_post ($) {
 392         my ($self) = @_;
 393         my $ng = $self->{ng};
 394         $ng ? "440 mailto:$ng->{-primary_address} to post"
 395                 : '440 posting not allowed'
 396 }
 397
 398 sub cmd_quit ($) {
 399         my ($self) = @_;
 400         res($self, '205 closing connection - goodbye!');
 401         $self->shutdn;
 402         undef;
 403 }
 404
 405 sub header_append ($$$) {
 406         my ($hdr, $k, $v) = @_;
 407         my @v = $hdr->header($k);
 408         foreach (@v) {
 409                 return if $v eq $_;
 410         }
 411         $hdr->header_set($k, @v, $v);
 412 }
 413
 414 sub xref ($$$$) {
 415         my ($self, $ng, $n, $mid) = @_;
 416         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 417
 418         # num_for is pretty cheap and sometimes we'll lookup the existence
 419         # of an article without getting even the OVER info.  In other words,
 420         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 421         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 422         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 423                 next if $ng eq $other;
 424                 my $num = eval { $other->mm->num_for($mid) } or next;
 425                 $ret .= " $other->{newsgroup}:$num";
 426         }
 427         $ret;
 428 }
 429
 430 sub set_nntp_headers ($$$$$) {
 431         my ($self, $hdr, $ng, $n, $mid) = @_;
 432
 433         # why? leafnode requires a Path: header for some inexplicable
 434         # reason.  We'll fake the shortest one possible.
 435         $hdr->header_set('Path', 'y');
 436
 437         # leafnode (and maybe other NNTP clients) have trouble dealing
 438         # with v2 messages which have multiple Message-IDs (either due
 439         # to our own content-based dedupe or buggy git-send-email versions).
 440         my @mids = $hdr->header('Message-ID');
 441         if (scalar(@mids) > 1) {
 442                 my $mid0 = "<$mid>";
 443                 $hdr->header_set('Message-ID', $mid0);
 444                 my @alt = $hdr->header('X-Alt-Message-ID');
 445                 my %seen = map { $_ => 1 } (@alt, $mid0);
 446                 foreach my $m (@mids) {
 447                         next if $seen{$m}++;
 448                         push @alt, $m;
 449                 }
 450                 $hdr->header_set('X-Alt-Message-ID', @alt);
 451         }
 452
 453         # clobber some
 454         my $xref = xref($self, $ng, $n, $mid);
 455         $hdr->header_set('Xref', $xref);
 456         $xref =~ s/:[0-9]+//g;
 457         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 458         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 459         if (my $url = $ng->base_url) {
 460                 $mid = mid_escape($mid);
 461                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 462                 header_append($hdr, 'List-Archive', "<$url>");
 463         }
 464 }
 465
 466 sub art_lookup ($$$) {
 467         my ($self, $art, $set_headers) = @_;
 468         my $ng = $self->{ng};
 469         my ($n, $mid);
 470         my $err;
 471         if (defined $art) {
 472                 if ($art =~ /\A[0-9]+\z/) {
 473                         $err = '423 no such article number in this group';
 474                         $n = int($art);
 475                         goto find_mid;
 476                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 477                         $mid = $1;
 478                         $err = r430;
 479                         $n = $ng->mm->num_for($mid) if $ng;
 480                         goto found if defined $n;
 481                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 482                                 $n = $g->mm->num_for($mid);
 483                                 if (defined $n) {
 484                                         $ng = $g;
 485                                         goto found;
 486                                 }
 487                         }
 488                         return $err;
 489                 } else {
 490                         return r501;
 491                 }
 492         } else {
 493                 $err = '420 no current article has been selected';
 494                 $n = $self->{article};
 495                 defined $n or return $err;
 496 find_mid:
 497                 $ng or return '412 no newsgroup has been selected';
 498                 $mid = $ng->mm->mid_for($n);
 499                 defined $mid or return $err;
 500         }
 501 found:
 502         my $smsg = $ng->over->get_art($n) or return $err;
 503         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 504
 505         # Email::Simple->new will modify $msg in-place as documented
 506         # in its manpage, so what's left is the body and we won't need
 507         # to call Email::Simple::body(), later
 508         my $hdr = Email::Simple->new($msg)->header_obj;
 509         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 510         [ $n, $mid, $msg, $hdr ];
 511 }
 512
 513 sub msg_body_write ($$) {
 514         my ($self, $msg) = @_;
 515
 516         # these can momentarily double the memory consumption :<
 517         $$msg =~ s/^\./../smg;
 518         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 519         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 520         $self->msg_more($$msg);
 521         '.'
 522 }
 523
 524 sub set_art {
 525         my ($self, $art) = @_;
 526         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 527 }
 528
 529 sub msg_hdr_write ($$$) {
 530         my ($self, $hdr, $body_follows) = @_;
 531         $hdr = $hdr->as_string;
 532         utf8::encode($hdr);
 533         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 534
 535         # for leafnode compatibility, we need to ensure Message-ID headers
 536         # are only a single line.  We can't subclass Email::Simple::Header
 537         # and override _default_fold_at in here, either; since that won't
 538         # affect messages already in the archive.
 539         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 540         $hdr .= "\r\n" if $body_follows;
 541         $self->msg_more($hdr);
 542 }
 543
 544 sub cmd_article ($;$) {
 545         my ($self, $art) = @_;
 546         my $r = art_lookup($self, $art, 1);
 547         return $r unless ref $r;
 548         my ($n, $mid, $msg, $hdr) = @$r;
 549         set_art($self, $art);
 550         more($self, "220 $n <$mid> article retrieved - head and body follow");
 551         msg_hdr_write($self, $hdr, 1);
 552         msg_body_write($self, $msg);
 553 }
 554
 555 sub cmd_head ($;$) {
 556         my ($self, $art) = @_;
 557         my $r = art_lookup($self, $art, 2);
 558         return $r unless ref $r;
 559         my ($n, $mid, undef, $hdr) = @$r;
 560         set_art($self, $art);
 561         more($self, "221 $n <$mid> article retrieved - head follows");
 562         msg_hdr_write($self, $hdr, 0);
 563         '.'
 564 }
 565
 566 sub cmd_body ($;$) {
 567         my ($self, $art) = @_;
 568         my $r = art_lookup($self, $art, 0);
 569         return $r unless ref $r;
 570         my ($n, $mid, $msg) = @$r;
 571         set_art($self, $art);
 572         more($self, "222 $n <$mid> article retrieved - body follows");
 573         msg_body_write($self, $msg);
 574 }
 575
 576 sub cmd_stat ($;$) {
 577         my ($self, $art) = @_;
 578         my $r = art_lookup($self, $art, 0);
 579         return $r unless ref $r;
 580         my ($n, $mid) = @$r;
 581         set_art($self, $art);
 582         "223 $n <$mid> article retrieved - request text separately";
 583 }
 584
 585 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 586
 587 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 588
 589 sub cmd_help ($) {
 590         my ($self) = @_;
 591         more($self, '100 help text follows');
 592         '.'
 593 }
 594
 595 sub get_range ($$) {
 596         my ($self, $range) = @_;
 597         my $ng = $self->{ng} or return '412 no news group has been selected';
 598         defined $range or return '420 No article(s) selected';
 599         my ($beg, $end);
 600         my ($min, $max) = $ng->mm->minmax;
 601         if ($range =~ /\A([0-9]+)\z/) {
 602                 $beg = $end = $1;
 603         } elsif ($range =~ /\A([0-9]+)-\z/) {
 604                 ($beg, $end) = ($1, $max);
 605         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 606                 ($beg, $end) = ($1, $2);
 607         } else {
 608                 return r501;
 609         }
 610         $beg = $min if ($beg < $min);
 611         $end = $max if ($end > $max);
 612         return '420 No article(s) selected' if ($beg > $end);
 613         [ $beg, $end ];
 614 }
 615
 616 sub long_response ($$) {
 617         my ($self, $cb) = @_; # cb returns true if more, false if done
 618
 619         my $fd = fileno($self->{sock});
 620         defined $fd or return;
 621         # make sure we disable reading during a long response,
 622         # clients should not be sending us stuff and making us do more
 623         # work while we are stream a response to them
 624         my $t0 = now();
 625         my $long_cb; # DANGER: self-referential
 626         $long_cb = sub {
 627                 # wbuf is unset or empty, here; $cb may add to it
 628                 my $more = eval { $cb->() };
 629                 if ($@ || !$self->{sock}) { # something bad happened...
 630                         $long_cb = undef;
 631                         my $diff = now() - $t0;
 632                         if ($@) {
 633                                 err($self,
 634                                     "%s during long response[$fd] - %0.6f",
 635                                     $@, $diff);
 636                         }
 637                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 638                         $self->close;
 639                 } elsif ($more) { # $self->{wbuf}:
 640                         update_idle_time($self);
 641
 642                         # no recursion, schedule another call ASAP
 643                         # but only after all pending writes are done
 644                         my $wbuf = $self->{wbuf} ||= [];
 645                         push @$wbuf, $long_cb;
 646
 647                         # wbuf may be populated by $cb, no need to rearm if so:
 648                         $self->requeue if scalar(@$wbuf) == 1;
 649                 } else { # all done!
 650                         $long_cb = undef;
 651                         res($self, '.');
 652                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 653                         $self->requeue unless $self->{wbuf};
 654                 }
 655         };
 656         $self->write($long_cb); # kick off!
 657         undef;
 658 }
 659
 660 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 661         my ($self, $xhdr, $range) = @_;
 662
 663         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 664                 my ($ng, $n) = mid_lookup($self, $1);
 665                 return r430 unless $n;
 666                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 667         } else { # numeric range
 668                 $range = $self->{article} unless defined $range;
 669                 my $r = get_range($self, $range);
 670                 return $r unless ref $r;
 671                 my $mm = $self->{ng}->mm;
 672                 my ($beg, $end) = @$r;
 673                 more($self, $xhdr ? r221 : r225);
 674                 long_response($self, sub {
 675                         my $r = $mm->msg_range(\$beg, $end);
 676                         @$r or return;
 677                         more($self, join("\r\n", map {
 678                                 "$_->[0] <$_->[1]>"
 679                         } @$r));
 680                         1;
 681                 });
 682         }
 683 }
 684
 685 sub mid_lookup ($$) {
 686         my ($self, $mid) = @_;
 687         my $self_ng = $self->{ng};
 688         if ($self_ng) {
 689                 my $n = $self_ng->mm->num_for($mid);
 690                 return ($self_ng, $n) if defined $n;
 691         }
 692         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 693                 next if defined $self_ng && $ng eq $self_ng;
 694                 my $n = $ng->mm->num_for($mid);
 695                 return ($ng, $n) if defined $n;
 696         }
 697         (undef, undef);
 698 }
 699
 700 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 701         my ($self, $xhdr, $range) = @_;
 702
 703         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 704                 my $mid = $1;
 705                 my ($ng, $n) = mid_lookup($self, $mid);
 706                 return r430 unless $n;
 707                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 708                                 xref($self, $ng, $n, $mid));
 709         } else { # numeric range
 710                 $range = $self->{article} unless defined $range;
 711                 my $r = get_range($self, $range);
 712                 return $r unless ref $r;
 713                 my $ng = $self->{ng};
 714                 my $mm = $ng->mm;
 715                 my ($beg, $end) = @$r;
 716                 more($self, $xhdr ? r221 : r225);
 717                 long_response($self, sub {
 718                         my $r = $mm->msg_range(\$beg, $end);
 719                         @$r or return;
 720                         more($self, join("\r\n", map {
 721                                 my $num = $_->[0];
 722                                 "$num ".xref($self, $ng, $num, $_->[1]);
 723                         } @$r));
 724                         1;
 725                 });
 726         }
 727 }
 728
 729 sub over_header_for {
 730         my ($over, $num, $field) = @_;
 731         my $smsg = $over->get_art($num) or return;
 732         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 733         $smsg->{$field};
 734 }
 735
 736 sub hdr_searchmsg ($$$$) {
 737         my ($self, $xhdr, $field, $range) = @_;
 738         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 739                 my ($ng, $n) = mid_lookup($self, $1);
 740                 return r430 unless defined $n;
 741                 my $v = over_header_for($ng->over, $n, $field);
 742                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 743         } else { # numeric range
 744                 $range = $self->{article} unless defined $range;
 745                 my $over = $self->{ng}->over;
 746                 my $mm = $self->{ng}->mm;
 747                 my $r = get_range($self, $range);
 748                 return $r unless ref $r;
 749                 my ($beg, $end) = @$r;
 750                 more($self, $xhdr ? r221 : r225);
 751                 my $cur = $beg;
 752                 long_response($self, sub {
 753                         my $msgs = $over->query_xover($cur, $end);
 754                         my $nr = scalar @$msgs or return;
 755                         my $tmp = '';
 756                         foreach my $s (@$msgs) {
 757                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 758                         }
 759                         utf8::encode($tmp);
 760                         $self->msg_more($tmp);
 761                         $cur = $msgs->[-1]->{num} + 1;
 762                 });
 763         }
 764 }
 765
 766 sub do_hdr ($$$;$) {
 767         my ($self, $xhdr, $header, $range) = @_;
 768         my $sub = lc $header;
 769         if ($sub eq 'message-id') {
 770                 hdr_message_id($self, $xhdr, $range);
 771         } elsif ($sub eq 'xref') {
 772                 hdr_xref($self, $xhdr, $range);
 773         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 774                                 bytes|lines)\z/x) {
 775                 hdr_searchmsg($self, $xhdr, $sub, $range);
 776         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 777                 hdr_searchmsg($self, $xhdr, $1, $range);
 778         } else {
 779                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 780         }
 781 }
 782
 783 # RFC 3977
 784 sub cmd_hdr ($$;$) {
 785         my ($self, $header, $range) = @_;
 786         do_hdr($self, 0, $header, $range);
 787 }
 788
 789 # RFC 2980
 790 sub cmd_xhdr ($$;$) {
 791         my ($self, $header, $range) = @_;
 792         do_hdr($self, 1, $header, $range);
 793 }
 794
 795 sub hdr_mid_prefix ($$$$$) {
 796         my ($self, $xhdr, $ng, $n, $mid) = @_;
 797         return $mid if $xhdr;
 798
 799         # HDR for RFC 3977 users
 800         if (my $self_ng = $self->{ng}) {
 801                 ($self_ng eq $ng) ? $n : '0';
 802         } else {
 803                 '0';
 804         }
 805 }
 806
 807 sub hdr_mid_response ($$$$$$) {
 808         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 809         my $res = '';
 810         if ($xhdr) {
 811                 $res .= r221 . "\r\n";
 812                 $res .= "$mid $v\r\n";
 813         } else {
 814                 $res .= r225 . "\r\n";
 815                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 816                 $res .= "$pfx $v\r\n";
 817         }
 818         res($self, $res .= '.');
 819         undef;
 820 }
 821
 822 sub cmd_xrover ($;$) {
 823         my ($self, $range) = @_;
 824         my $ng = $self->{ng} or return '412 no newsgroup selected';
 825         (defined $range && $range =~ /[<>]/) and
 826                 return '420 No article(s) selected'; # no message IDs
 827
 828         $range = $self->{article} unless defined $range;
 829         my $r = get_range($self, $range);
 830         return $r unless ref $r;
 831         my ($beg, $end) = @$r;
 832         my $mm = $ng->mm;
 833         my $over = $ng->over;
 834         more($self, '224 Overview information follows');
 835
 836         long_response($self, sub {
 837                 my $h = over_header_for($over, $beg, 'references');
 838                 more($self, "$beg $h") if defined($h);
 839                 $beg++ < $end;
 840         });
 841 }
 842
 843 sub over_line ($$$$) {
 844         my ($self, $ng, $num, $smsg) = @_;
 845         # n.b. field access and procedural calls can be
 846         # 10%-15% faster than OO method calls:
 847         my $s = join("\t", $num,
 848                 $smsg->{subject},
 849                 $smsg->{from},
 850                 PublicInbox::SearchMsg::date($smsg),
 851                 "<$smsg->{mid}>",
 852                 $smsg->{references},
 853                 $smsg->{bytes},
 854                 $smsg->{lines},
 855                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 856         utf8::encode($s);
 857         $s
 858 }
 859
 860 sub cmd_over ($;$) {
 861         my ($self, $range) = @_;
 862         if ($range && $range =~ /\A<(.+)>\z/) {
 863                 my ($ng, $n) = mid_lookup($self, $1);
 864                 defined $n or return r430;
 865                 my $smsg = $ng->over->get_art($n) or return r430;
 866                 more($self, '224 Overview information follows (multi-line)');
 867
 868                 # Only set article number column if it's the current group
 869                 my $self_ng = $self->{ng};
 870                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 871                 more($self, over_line($self, $ng, $n, $smsg));
 872                 '.';
 873         } else {
 874                 cmd_xover($self, $range);
 875         }
 876 }
 877
 878 sub cmd_xover ($;$) {
 879         my ($self, $range) = @_;
 880         $range = $self->{article} unless defined $range;
 881         my $r = get_range($self, $range);
 882         return $r unless ref $r;
 883         my ($beg, $end) = @$r;
 884         more($self, "224 Overview information follows for $beg to $end");
 885         my $over = $self->{ng}->over;
 886         my $cur = $beg;
 887         long_response($self, sub {
 888                 my $msgs = $over->query_xover($cur, $end);
 889                 my $nr = scalar @$msgs or return;
 890
 891                 # OVERVIEW.FMT
 892                 more($self, join("\r\n", map {
 893                         over_line($self, $self->{ng}, $_->{num}, $_);
 894                         } @$msgs));
 895                 $cur = $msgs->[-1]->{num} + 1;
 896         });
 897 }
 898
 899 sub cmd_starttls ($) {
 900         my ($self) = @_;
 901         my $sock = $self->{sock} or return;
 902         # RFC 4642 2.2.1
 903         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 904         my $opt = $self->{nntpd}->{accept_tls} or
 905                 return '580 can not initiate TLS negotiation';
 906         res($self, '382 Continue with TLS negotiation');
 907         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 908         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 909         undef;
 910 }
 911
 912 sub cmd_xpath ($$) {
 913         my ($self, $mid) = @_;
 914         return r501 unless $mid =~ /\A<(.+)>\z/;
 915         $mid = $1;
 916         my @paths;
 917         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 918                 my $n = $ng->mm->num_for($mid);
 919                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 920         }
 921         return '430 no such article on server' unless @paths;
 922         '223 '.join(' ', @paths);
 923 }
 924
 925 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 926
 927 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 928
 929 sub do_write ($$) {
 930         my $self = $_[0];
 931         my $done = $self->write(\($_[1]));
 932         return 0 unless $self->{sock};
 933
 934         $done;
 935 }
 936
 937 sub err ($$;@) {
 938         my ($self, $fmt, @args) = @_;
 939         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 940 }
 941
 942 sub out ($$;@) {
 943         my ($self, $fmt, @args) = @_;
 944         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 945 }
 946
 947 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 948 sub event_step {
 949         my ($self) = @_;
 950
 951         return unless $self->flush_write && $self->{sock};
 952
 953         update_idle_time($self);
 954         # only read more requests if we've drained the write buffer,
 955         # otherwise we can be buffering infinitely w/o backpressure
 956
 957         use constant LINE_MAX => 512; # RFC 977 section 2.3
 958         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 959         my $r = 1;
 960
 961         if (index($$rbuf, "\n") < 0) {
 962                 my $off = bytes::length($$rbuf);
 963                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 964         }
 965         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 966                 my $line = $1;
 967                 return $self->close if $line =~ /[[:cntrl:]]/s;
 968                 my $t0 = now();
 969                 my $fd = fileno($self->{sock});
 970                 $r = eval { process_line($self, $line) };
 971                 my $pending = $self->{wbuf} ? ' pending' : '';
 972                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 973         }
 974
 975         return $self->close if $r < 0;
 976         my $len = bytes::length($$rbuf);
 977         return $self->close if ($len >= LINE_MAX);
 978         $self->rbuf_idle($rbuf);
 979         update_idle_time($self);
 980
 981         # maybe there's more pipelined data, or we'll have
 982         # to register it for socket-readiness notifications
 983         $self->requeue unless $self->{wbuf};
 984 }
 985
 986 sub not_idle_long ($$) {
 987         my ($self, $now) = @_;
 988         my $sock = $self->{sock} or return;
 989         my $ary = $EXPMAP->{fileno($sock)} or return;
 990         my $exp_at = $ary->[0] + $EXPTIME;
 991         $exp_at > $now;
 992 }
 993
 994 # for graceful shutdown in PublicInbox::Daemon:
 995 sub busy {
 996         my ($self, $now) = @_;
 997         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
 998 }
 999
1000 1;