lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng long_cb);
  10 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  11 use PublicInbox::Eml;
  12 use POSIX qw(strftime);
  13 use PublicInbox::DS qw(now);
  14 use Digest::SHA qw(sha1_hex);
  15 use Time::Local qw(timegm timelocal);
  16 use constant {
  17         LINE_MAX => 512, # RFC 977 section 2.3
  18         r501 => '501 command syntax error',
  19         r502 => '502 Command unavailable',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24 };
  25 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  26 use Errno qw(EAGAIN);
  27 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  28 my @OVERVIEW = qw(Subject From Date Message-ID References);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  30                 "Xref:full\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33 my $CAPABILITIES = <<"";
  34 101 Capability list:\r
  35 VERSION 2\r
  36 READER\r
  37 NEWNEWS\r
  38 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  39 HDR\r
  40 OVER\r
  41 COMPRESS DEFLATE\r
  42
  43 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  44
  45 sub new ($$$) {
  46         my ($class, $sock, $nntpd) = @_;
  47         my $self = fields::new($class);
  48         my $ev = EPOLLIN;
  49         my $wbuf;
  50         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  51                 return CORE::close($sock) if $! != EAGAIN;
  52                 $ev = PublicInbox::TLS::epollbit();
  53                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  54         }
  55         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  56         $self->{nntpd} = $nntpd;
  57         if ($wbuf) {
  58                 $self->{wbuf} = $wbuf;
  59         } else {
  60                 greet($self);
  61         }
  62         $self->update_idle_time;
  63         $self;
  64 }
  65
  66 sub args_ok ($$) {
  67         my ($cb, $argc) = @_;
  68         my $tot = prototype $cb;
  69         my ($nreq, undef) = split(';', $tot);
  70         $nreq = ($nreq =~ tr/$//) - 1;
  71         $tot = ($tot =~ tr/$//) - 1;
  72         ($argc <= $tot && $argc >= $nreq);
  73 }
  74
  75 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  76 sub process_line ($$) {
  77         my ($self, $l) = @_;
  78         my ($req, @args) = split(/[ \t]+/, $l);
  79         return 1 unless defined($req); # skip blank line
  80         $req = $self->can('cmd_'.lc($req));
  81         return res($self, '500 command not recognized') unless $req;
  82         return res($self, r501) unless args_ok($req, scalar @args);
  83
  84         my $res = eval { $req->($self, @args) };
  85         my $err = $@;
  86         if ($err && $self->{sock}) {
  87                 local $/ = "\n";
  88                 chomp($l);
  89                 err($self, 'error from: %s (%s)', $l, $err);
  90                 $res = '503 program fault - command not performed';
  91         }
  92         return 0 unless defined $res;
  93         res($self, $res);
  94 }
  95
  96 # The keyword argument is not used (rfc3977 5.2.2)
  97 sub cmd_capabilities ($;$) {
  98         my ($self, undef) = @_;
  99         my $res = $CAPABILITIES;
 100         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 101                         $self->{nntpd}->{accept_tls}) {
 102                 $res .= "STARTTLS\r\n";
 103         }
 104         $res .= '.';
 105 }
 106
 107 sub cmd_mode ($$) {
 108         my ($self, $arg) = @_;
 109         $arg = uc $arg;
 110         return r501 unless $arg eq 'READER';
 111         '201 Posting prohibited';
 112 }
 113
 114 sub cmd_slave ($) { '202 slave status noted' }
 115
 116 sub cmd_xgtitle ($;$) {
 117         my ($self, $wildmat) = @_;
 118         more($self, '282 list of groups and descriptions follows');
 119         list_newsgroups($self, $wildmat);
 120         '.'
 121 }
 122
 123 sub list_overview_fmt ($) {
 124         my ($self) = @_;
 125         $self->msg_more($OVERVIEW_FMT);
 126 }
 127
 128 sub list_headers ($;$) {
 129         my ($self) = @_;
 130         $self->msg_more($LIST_HEADERS);
 131 }
 132
 133 sub list_active ($;$) {
 134         my ($self, $wildmat) = @_;
 135         wildmat2re($wildmat);
 136         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 137                 $ng->{newsgroup} =~ $wildmat or next;
 138                 group_line($self, $ng);
 139         }
 140 }
 141
 142 sub list_active_times ($;$) {
 143         my ($self, $wildmat) = @_;
 144         wildmat2re($wildmat);
 145         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 146                 $ng->{newsgroup} =~ $wildmat or next;
 147                 my $c = eval { $ng->mm->created_at } || time;
 148                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 149         }
 150 }
 151
 152 sub list_newsgroups ($;$) {
 153         my ($self, $wildmat) = @_;
 154         wildmat2re($wildmat);
 155         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 156                 $ng->{newsgroup} =~ $wildmat or next;
 157                 my $d = $ng->description;
 158                 more($self, "$ng->{newsgroup} $d");
 159         }
 160 }
 161
 162 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 163 sub cmd_list ($;$$) {
 164         my ($self, @args) = @_;
 165         if (scalar @args) {
 166                 my $arg = shift @args;
 167                 $arg =~ tr/A-Z./a-z_/;
 168                 $arg = "list_$arg";
 169                 $arg = $self->can($arg);
 170                 return r501 unless $arg && args_ok($arg, scalar @args);
 171                 more($self, '215 information follows');
 172                 $arg->($self, @args);
 173         } else {
 174                 more($self, '215 list of newsgroups follows');
 175                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                         group_line($self, $ng);
 177                 }
 178         }
 179         '.'
 180 }
 181
 182 sub listgroup_range_i {
 183         my ($self, $beg, $end) = @_;
 184         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 185         scalar(@$r) or return;
 186         more($self, join("\r\n", map { $_->[0] } @$r));
 187         1;
 188 }
 189
 190 sub listgroup_all_i {
 191         my ($self, $num) = @_;
 192         my $ary = $self->{ng}->mm->ids_after($num);
 193         scalar(@$ary) or return;
 194         more($self, join("\r\n", @$ary));
 195         1;
 196 }
 197
 198 sub cmd_listgroup ($;$$) {
 199         my ($self, $group, $range) = @_;
 200         if (defined $group) {
 201                 my $res = cmd_group($self, $group);
 202                 return $res if ($res !~ /\A211 /);
 203                 more($self, $res);
 204         }
 205         $self->{ng} or return '412 no newsgroup selected';
 206         if (defined $range) {
 207                 my $r = get_range($self, $range);
 208                 return $r unless ref $r;
 209                 long_response($self, \&listgroup_range_i, @$r);
 210         } else { # grab every article number
 211                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 212         }
 213 }
 214
 215 sub parse_time ($$;$) {
 216         my ($date, $time, $gmt) = @_;
 217         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 218         if (defined $gmt) {
 219                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 220                 $gmt = 1;
 221         }
 222         my ($YYYY, $MM, $DD);
 223         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 224                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 225         } else { # legacy clients send YYMMDD
 226                 my $YY;
 227                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 228                 my @now = $gmt ? gmtime : localtime;
 229                 my $cur_year = $now[5] + 1900;
 230                 my $cur_cent = int($cur_year / 100) * 100;
 231                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 232                         ($YY + 1900) : ($YY + $cur_cent);
 233         }
 234         if ($gmt) {
 235                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 236         } else {
 237                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 238         }
 239 }
 240
 241 sub group_line ($$) {
 242         my ($self, $ng) = @_;
 243         my ($min, $max) = $ng->mm->minmax;
 244         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 245 }
 246
 247 sub cmd_newgroups ($$$;$$) {
 248         my ($self, $date, $time, $gmt, $dists) = @_;
 249         my $ts = eval { parse_time($date, $time, $gmt) };
 250         return r501 if $@;
 251
 252         # TODO dists
 253         more($self, '231 list of new newsgroups follows');
 254         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 255                 my $c = eval { $ng->mm->created_at } || 0;
 256                 next unless $c > $ts;
 257                 group_line($self, $ng);
 258         }
 259         '.'
 260 }
 261
 262 sub wildmat2re (;$) {
 263         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 264         my %keep;
 265         my $salt = rand;
 266         my $tmp = $_[0];
 267
 268         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 269                 my $orig = $1;
 270                 my $key = sha1_hex($orig . $salt);
 271                 $orig =~ s/([^\w\-])+/\Q$1/g;
 272                 $keep{$key} = $orig;
 273                 $key
 274                 #gex;
 275         my %map = ('*' => '.*', '?' => '.' );
 276         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 277         if (scalar %keep) {
 278                 $tmp =~ s#([a-f0-9]{40})#
 279                         my $orig = $keep{$1};
 280                         defined $orig ? $orig : $1;
 281                         #ge;
 282         }
 283         $_[0] = qr/\A$tmp\z/;
 284 }
 285
 286 sub ngpat2re (;$) {
 287         return $_[0] = qr/\A\z/ unless defined $_[0];
 288         my %map = ('*' => '.*', ',' => '|');
 289         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 290         $_[0] = qr/\A(?:$_[0])\z/;
 291 }
 292
 293 sub newnews_i {
 294         my ($self, $overs, $ts, $prev) = @_;
 295         my $over = $overs->[0];
 296         my $msgs = $over->query_ts($ts, $$prev);
 297         if (scalar @$msgs) {
 298                 more($self, '<' .
 299                         join(">\r\n<", map { $_->{mid} } @$msgs ).
 300                         '>');
 301                 $$prev = $msgs->[-1]->{num};
 302         } else {
 303                 shift @$overs;
 304                 if (@$overs) { # continue onto next newsgroup
 305                         $$prev = 0;
 306                         return 1;
 307                 } else { # break out of the long response.
 308                         return;
 309                 }
 310         }
 311 }
 312
 313 sub cmd_newnews ($$$$;$$) {
 314         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 315         my $ts = eval { parse_time($date, $time, $gmt) };
 316         return r501 if $@;
 317         more($self, '230 list of new articles by message-id follows');
 318         my ($keep, $skip) = split('!', $newsgroups, 2);
 319         ngpat2re($keep);
 320         ngpat2re($skip);
 321         my @overs;
 322         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 323                 $ng->{newsgroup} =~ $keep or next;
 324                 $ng->{newsgroup} =~ $skip and next;
 325                 my $over = $ng->over or next;
 326                 push @overs, $over;
 327         };
 328         return '.' unless @overs;
 329
 330         my $prev = 0;
 331         long_response($self, \&newnews_i, \@overs, $ts, \$prev);
 332 }
 333
 334 sub cmd_group ($$) {
 335         my ($self, $group) = @_;
 336         my $no_such = '411 no such news group';
 337         my $nntpd = $self->{nntpd};
 338         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 339         $nntpd->idler_start;
 340
 341         $self->{ng} = $ng;
 342         my ($min, $max) = $ng->mm->minmax;
 343         $min ||= 0;
 344         $max ||= 0;
 345         $self->{article} = $min;
 346         my $est_size = $max - $min;
 347         "211 $est_size $min $max $group";
 348 }
 349
 350 sub article_adj ($$) {
 351         my ($self, $off) = @_;
 352         my $ng = $self->{ng} or return '412 no newsgroup selected';
 353
 354         my $n = $self->{article};
 355         defined $n or return '420 no current article has been selected';
 356
 357         $n += $off;
 358         my $mid = $ng->mm->mid_for($n);
 359         unless ($mid) {
 360                 $n = $off > 0 ? 'next' : 'previous';
 361                 return "421 no $n article in this group";
 362         }
 363         $self->{article} = $n;
 364         "223 $n <$mid> article retrieved - request text separately";
 365 }
 366
 367 sub cmd_next ($) { article_adj($_[0], 1) }
 368 sub cmd_last ($) { article_adj($_[0], -1) }
 369
 370 # We want to encourage using email and CC-ing everybody involved to avoid
 371 # the single-point-of-failure a single server provides.
 372 sub cmd_post ($) {
 373         my ($self) = @_;
 374         my $ng = $self->{ng};
 375         $ng ? "440 mailto:$ng->{-primary_address} to post"
 376                 : '440 posting not allowed'
 377 }
 378
 379 sub cmd_quit ($) {
 380         my ($self) = @_;
 381         res($self, '205 closing connection - goodbye!');
 382         $self->shutdn;
 383         undef;
 384 }
 385
 386 sub header_append ($$$) {
 387         my ($hdr, $k, $v) = @_;
 388         my @v = $hdr->header_raw($k);
 389         foreach (@v) {
 390                 return if $v eq $_;
 391         }
 392         $hdr->header_set($k, @v, $v);
 393 }
 394
 395 sub xref ($$$$) {
 396         my ($self, $ng, $n, $mid) = @_;
 397         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 398
 399         # num_for is pretty cheap and sometimes we'll lookup the existence
 400         # of an article without getting even the OVER info.  In other words,
 401         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 402         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 403         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 404                 next if $ng eq $other;
 405                 my $num = eval { $other->mm->num_for($mid) } or next;
 406                 $ret .= " $other->{newsgroup}:$num";
 407         }
 408         $ret;
 409 }
 410
 411 sub set_nntp_headers ($$$$$) {
 412         my ($self, $hdr, $ng, $n, $mid) = @_;
 413
 414         # why? leafnode requires a Path: header for some inexplicable
 415         # reason.  We'll fake the shortest one possible.
 416         $hdr->header_set('Path', 'y');
 417
 418         # leafnode (and maybe other NNTP clients) have trouble dealing
 419         # with v2 messages which have multiple Message-IDs (either due
 420         # to our own content-based dedupe or buggy git-send-email versions).
 421         my @mids = $hdr->header_raw('Message-ID');
 422         if (scalar(@mids) > 1) {
 423                 my $mid0 = "<$mid>";
 424                 $hdr->header_set('Message-ID', $mid0);
 425                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 426                 my %seen = map { $_ => 1 } (@alt, $mid0);
 427                 push(@alt, grep { !$seen{$_}++ } @mids);
 428                 $hdr->header_set('X-Alt-Message-ID', @alt);
 429         }
 430
 431         # clobber some
 432         my $xref = xref($self, $ng, $n, $mid);
 433         $hdr->header_set('Xref', $xref);
 434         $xref =~ s/:[0-9]+//g;
 435         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 436         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 437         if (my $url = $ng->base_url) {
 438                 $mid = mid_escape($mid);
 439                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 440                 header_append($hdr, 'List-Archive', "<$url>");
 441         }
 442 }
 443
 444 sub art_lookup ($$$) {
 445         my ($self, $art, $set_headers) = @_;
 446         my $ng = $self->{ng};
 447         my ($n, $mid);
 448         my $err;
 449         if (defined $art) {
 450                 if ($art =~ /\A[0-9]+\z/) {
 451                         $err = '423 no such article number in this group';
 452                         $n = int($art);
 453                         goto find_mid;
 454                 } elsif ($art =~ $ONE_MSGID) {
 455                         $mid = $1;
 456                         $err = r430;
 457                         $n = $ng->mm->num_for($mid) if $ng;
 458                         goto found if defined $n;
 459                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 460                                 $n = $g->mm->num_for($mid);
 461                                 if (defined $n) {
 462                                         $ng = $g;
 463                                         goto found;
 464                                 }
 465                         }
 466                         return $err;
 467                 } else {
 468                         return r501;
 469                 }
 470         } else {
 471                 $err = '420 no current article has been selected';
 472                 $n = $self->{article};
 473                 defined $n or return $err;
 474 find_mid:
 475                 $ng or return '412 no newsgroup has been selected';
 476                 $mid = $ng->mm->mid_for($n);
 477                 defined $mid or return $err;
 478         }
 479 found:
 480         my $smsg = $ng->over->get_art($n) or return $err;
 481         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 482
 483         # PublicInbox::Eml->new will modify $msg in-place, so what's
 484         # left is the body and we won't need to call ->body(), later
 485         my $hdr = PublicInbox::Eml->new($msg)->header_obj;
 486         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 487         [ $n, $mid, $msg, $hdr ];
 488 }
 489
 490 sub msg_body_write ($$) {
 491         my ($self, $msg) = @_;
 492
 493         # these can momentarily double the memory consumption :<
 494         $$msg =~ s/^\./../smg;
 495         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 496         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 497         $self->msg_more($$msg);
 498         '.'
 499 }
 500
 501 sub set_art {
 502         my ($self, $art) = @_;
 503         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 504 }
 505
 506 sub msg_hdr_write ($$$) {
 507         my ($self, $hdr, $body_follows) = @_;
 508         $hdr = $hdr->as_string;
 509         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 510         $hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 511         utf8::encode($hdr);
 512         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 513
 514         # for leafnode compatibility, we need to ensure Message-ID headers
 515         # are only a single line.
 516         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 517         $hdr .= "\r\n" if $body_follows;
 518         $self->msg_more($hdr);
 519 }
 520
 521 sub cmd_article ($;$) {
 522         my ($self, $art) = @_;
 523         my $r = art_lookup($self, $art, 1);
 524         return $r unless ref $r;
 525         my ($n, $mid, $msg, $hdr) = @$r;
 526         set_art($self, $art);
 527         more($self, "220 $n <$mid> article retrieved - head and body follow");
 528         msg_hdr_write($self, $hdr, 1);
 529         msg_body_write($self, $msg);
 530 }
 531
 532 sub cmd_head ($;$) {
 533         my ($self, $art) = @_;
 534         my $r = art_lookup($self, $art, 2);
 535         return $r unless ref $r;
 536         my ($n, $mid, undef, $hdr) = @$r;
 537         set_art($self, $art);
 538         more($self, "221 $n <$mid> article retrieved - head follows");
 539         msg_hdr_write($self, $hdr, 0);
 540         '.'
 541 }
 542
 543 sub cmd_body ($;$) {
 544         my ($self, $art) = @_;
 545         my $r = art_lookup($self, $art, 0);
 546         return $r unless ref $r;
 547         my ($n, $mid, $msg) = @$r;
 548         set_art($self, $art);
 549         more($self, "222 $n <$mid> article retrieved - body follows");
 550         msg_body_write($self, $msg);
 551 }
 552
 553 sub cmd_stat ($;$) {
 554         my ($self, $art) = @_;
 555         my $r = art_lookup($self, $art, 0);
 556         return $r unless ref $r;
 557         my ($n, $mid) = @$r;
 558         set_art($self, $art);
 559         "223 $n <$mid> article retrieved - request text separately";
 560 }
 561
 562 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 563
 564 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 565
 566 sub cmd_help ($) {
 567         my ($self) = @_;
 568         more($self, '100 help text follows');
 569         '.'
 570 }
 571
 572 sub get_range ($$) {
 573         my ($self, $range) = @_;
 574         my $ng = $self->{ng} or return '412 no news group has been selected';
 575         defined $range or return '420 No article(s) selected';
 576         my ($beg, $end);
 577         my ($min, $max) = $ng->mm->minmax;
 578         if ($range =~ /\A([0-9]+)\z/) {
 579                 $beg = $end = $1;
 580         } elsif ($range =~ /\A([0-9]+)-\z/) {
 581                 ($beg, $end) = ($1, $max);
 582         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 583                 ($beg, $end) = ($1, $2);
 584         } else {
 585                 return r501;
 586         }
 587         $beg = $min if ($beg < $min);
 588         $end = $max if ($end > $max);
 589         return '420 No article(s) selected' if ($beg > $end);
 590         [ \$beg, $end ];
 591 }
 592
 593 sub long_step {
 594         my ($self) = @_;
 595         # wbuf is unset or empty, here; {long} may add to it
 596         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 597         my $more = eval { $cb->($self, @args) };
 598         if ($@ || !$self->{sock}) { # something bad happened...
 599                 delete $self->{long_cb};
 600                 my $elapsed = now() - $t0;
 601                 if ($@) {
 602                         err($self,
 603                             "%s during long response[$fd] - %0.6f",
 604                             $@, $elapsed);
 605                 }
 606                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 607                 $self->close;
 608         } elsif ($more) { # $self->{wbuf}:
 609                 $self->update_idle_time;
 610
 611                 # COMPRESS users all share the same DEFLATE context.
 612                 # Flush it here to ensure clients don't see
 613                 # each other's data
 614                 $self->zflush;
 615
 616                 # no recursion, schedule another call ASAP, but only after
 617                 # all pending writes are done.  autovivify wbuf:
 618                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 619
 620                 # wbuf may be populated by $cb, no need to rearm if so:
 621                 $self->requeue if $new_size == 1;
 622         } else { # all done!
 623                 delete $self->{long_cb};
 624                 res($self, '.');
 625                 my $elapsed = now() - $t0;
 626                 my $fd = fileno($self->{sock});
 627                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 628                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 629                 $self->requeue unless $wbuf && @$wbuf;
 630         }
 631 }
 632
 633 sub long_response ($$;@) {
 634         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 635
 636         my $sock = $self->{sock} or return;
 637         # make sure we disable reading during a long response,
 638         # clients should not be sending us stuff and making us do more
 639         # work while we are stream a response to them
 640         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 641         long_step($self); # kick off!
 642         undef;
 643 }
 644
 645 sub hdr_msgid_range_i {
 646         my ($self, $beg, $end) = @_;
 647         my $r = $self->{ng}->mm->msg_range($beg, $end);
 648         @$r or return;
 649         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 650         1;
 651 }
 652
 653 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 654         my ($self, $xhdr, $range) = @_;
 655
 656         if (defined $range && $range =~ $ONE_MSGID) {
 657                 my ($ng, $n) = mid_lookup($self, $1);
 658                 return r430 unless $n;
 659                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 660         } else { # numeric range
 661                 $range = $self->{article} unless defined $range;
 662                 my $r = get_range($self, $range);
 663                 return $r unless ref $r;
 664                 more($self, $xhdr ? r221 : r225);
 665                 long_response($self, \&hdr_msgid_range_i, @$r);
 666         }
 667 }
 668
 669 sub mid_lookup ($$) {
 670         my ($self, $mid) = @_;
 671         my $self_ng = $self->{ng};
 672         if ($self_ng) {
 673                 my $n = $self_ng->mm->num_for($mid);
 674                 return ($self_ng, $n) if defined $n;
 675         }
 676         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 677                 next if defined $self_ng && $ng eq $self_ng;
 678                 my $n = $ng->mm->num_for($mid);
 679                 return ($ng, $n) if defined $n;
 680         }
 681         (undef, undef);
 682 }
 683
 684 sub xref_range_i {
 685         my ($self, $beg, $end) = @_;
 686         my $ng = $self->{ng};
 687         my $r = $ng->mm->msg_range($beg, $end);
 688         @$r or return;
 689         more($self, join("\r\n", map {
 690                 my $num = $_->[0];
 691                 "$num ".xref($self, $ng, $num, $_->[1]);
 692         } @$r));
 693         1;
 694 }
 695
 696 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 697         my ($self, $xhdr, $range) = @_;
 698
 699         if (defined $range && $range =~ $ONE_MSGID) {
 700                 my $mid = $1;
 701                 my ($ng, $n) = mid_lookup($self, $mid);
 702                 return r430 unless $n;
 703                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 704                                 xref($self, $ng, $n, $mid));
 705         } else { # numeric range
 706                 $range = $self->{article} unless defined $range;
 707                 my $r = get_range($self, $range);
 708                 return $r unless ref $r;
 709                 more($self, $xhdr ? r221 : r225);
 710                 long_response($self, \&xref_range_i, @$r);
 711         }
 712 }
 713
 714 sub over_header_for {
 715         my ($over, $num, $field) = @_;
 716         my $smsg = $over->get_art($num) or return;
 717         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 718         $smsg->{$field};
 719 }
 720
 721 sub smsg_range_i {
 722         my ($self, $beg, $end, $field) = @_;
 723         my $over = $self->{ng}->over;
 724         my $msgs = $over->query_xover($$beg, $end);
 725         scalar(@$msgs) or return;
 726         my $tmp = '';
 727
 728         # ->{$field} is faster than ->$field invocations, so favor that.
 729         if ($field eq 'date') {
 730                 for my $s (@$msgs) {
 731                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 732                 }
 733         } else {
 734                 for my $s (@$msgs) {
 735                         $tmp .= "$s->{num} $s->{$field}\r\n";
 736                 }
 737         }
 738         utf8::encode($tmp);
 739         $self->msg_more($tmp);
 740         $$beg = $msgs->[-1]->{num} + 1;
 741 }
 742
 743 sub hdr_smsg ($$$$) {
 744         my ($self, $xhdr, $field, $range) = @_;
 745         if (defined $range && $range =~ $ONE_MSGID) {
 746                 my ($ng, $n) = mid_lookup($self, $1);
 747                 return r430 unless defined $n;
 748                 my $v = over_header_for($ng->over, $n, $field);
 749                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 750         } else { # numeric range
 751                 $range = $self->{article} unless defined $range;
 752                 my $r = get_range($self, $range);
 753                 return $r unless ref $r;
 754                 more($self, $xhdr ? r221 : r225);
 755                 long_response($self, \&smsg_range_i, @$r, $field);
 756         }
 757 }
 758
 759 sub do_hdr ($$$;$) {
 760         my ($self, $xhdr, $header, $range) = @_;
 761         my $sub = lc $header;
 762         if ($sub eq 'message-id') {
 763                 hdr_message_id($self, $xhdr, $range);
 764         } elsif ($sub eq 'xref') {
 765                 hdr_xref($self, $xhdr, $range);
 766         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 767                                 bytes|lines)\z/x) {
 768                 hdr_smsg($self, $xhdr, $sub, $range);
 769         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 770                 hdr_smsg($self, $xhdr, $1, $range);
 771         } else {
 772                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 773         }
 774 }
 775
 776 # RFC 3977
 777 sub cmd_hdr ($$;$) {
 778         my ($self, $header, $range) = @_;
 779         do_hdr($self, 0, $header, $range);
 780 }
 781
 782 # RFC 2980
 783 sub cmd_xhdr ($$;$) {
 784         my ($self, $header, $range) = @_;
 785         do_hdr($self, 1, $header, $range);
 786 }
 787
 788 sub hdr_mid_prefix ($$$$$) {
 789         my ($self, $xhdr, $ng, $n, $mid) = @_;
 790         return $mid if $xhdr;
 791
 792         # HDR for RFC 3977 users
 793         if (my $self_ng = $self->{ng}) {
 794                 ($self_ng eq $ng) ? $n : '0';
 795         } else {
 796                 '0';
 797         }
 798 }
 799
 800 sub hdr_mid_response ($$$$$$) {
 801         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 802         my $res = '';
 803         if ($xhdr) {
 804                 $res .= r221 . "\r\n";
 805                 $res .= "$mid $v\r\n";
 806         } else {
 807                 $res .= r225 . "\r\n";
 808                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 809                 $res .= "$pfx $v\r\n";
 810         }
 811         res($self, $res .= '.');
 812         undef;
 813 }
 814
 815 sub xrover_i {
 816         my ($self, $beg, $end) = @_;
 817         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 818         more($self, "$$beg $h") if defined($h);
 819         $$beg++ < $end;
 820 }
 821
 822 sub cmd_xrover ($;$) {
 823         my ($self, $range) = @_;
 824         my $ng = $self->{ng} or return '412 no newsgroup selected';
 825         (defined $range && $range =~ /[<>]/) and
 826                 return '420 No article(s) selected'; # no message IDs
 827
 828         $range = $self->{article} unless defined $range;
 829         my $r = get_range($self, $range);
 830         return $r unless ref $r;
 831         more($self, '224 Overview information follows');
 832         long_response($self, \&xrover_i, @$r);
 833 }
 834
 835 sub over_line ($$$$) {
 836         my ($self, $ng, $num, $smsg) = @_;
 837         # n.b. field access and procedural calls can be
 838         # 10%-15% faster than OO method calls:
 839         my $s = join("\t", $num,
 840                 $smsg->{subject},
 841                 $smsg->{from},
 842                 PublicInbox::Smsg::date($smsg),
 843                 "<$smsg->{mid}>",
 844                 $smsg->{references},
 845                 $smsg->{bytes},
 846                 $smsg->{lines},
 847                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 848         utf8::encode($s);
 849         $s
 850 }
 851
 852 sub cmd_over ($;$) {
 853         my ($self, $range) = @_;
 854         if ($range && $range =~ $ONE_MSGID) {
 855                 my ($ng, $n) = mid_lookup($self, $1);
 856                 defined $n or return r430;
 857                 my $smsg = $ng->over->get_art($n) or return r430;
 858                 more($self, '224 Overview information follows (multi-line)');
 859
 860                 # Only set article number column if it's the current group
 861                 my $self_ng = $self->{ng};
 862                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 863                 more($self, over_line($self, $ng, $n, $smsg));
 864                 '.';
 865         } else {
 866                 cmd_xover($self, $range);
 867         }
 868 }
 869
 870 sub xover_i {
 871         my ($self, $beg, $end) = @_;
 872         my $ng = $self->{ng};
 873         my $msgs = $ng->over->query_xover($$beg, $end);
 874         my $nr = scalar @$msgs or return;
 875
 876         # OVERVIEW.FMT
 877         more($self, join("\r\n", map {
 878                 over_line($self, $ng, $_->{num}, $_);
 879                 } @$msgs));
 880         $$beg = $msgs->[-1]->{num} + 1;
 881 }
 882
 883 sub cmd_xover ($;$) {
 884         my ($self, $range) = @_;
 885         $range = $self->{article} unless defined $range;
 886         my $r = get_range($self, $range);
 887         return $r unless ref $r;
 888         my ($beg, $end) = @$r;
 889         more($self, "224 Overview information follows for $$beg to $end");
 890         long_response($self, \&xover_i, @$r);
 891 }
 892
 893 sub compressed { undef }
 894
 895 sub cmd_starttls ($) {
 896         my ($self) = @_;
 897         my $sock = $self->{sock} or return;
 898         # RFC 4642 2.2.1
 899         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 900         my $opt = $self->{nntpd}->{accept_tls} or
 901                 return '580 can not initiate TLS negotiation';
 902         res($self, '382 Continue with TLS negotiation');
 903         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 904         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 905         undef;
 906 }
 907
 908 # RFC 8054
 909 sub cmd_compress ($$) {
 910         my ($self, $alg) = @_;
 911         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 912         return r502 if $self->compressed;
 913         PublicInbox::NNTPdeflate->enable($self);
 914         $self->requeue;
 915         undef
 916 }
 917
 918 sub zflush {} # overridden by NNTPdeflate
 919
 920 sub cmd_xpath ($$) {
 921         my ($self, $mid) = @_;
 922         return r501 unless $mid =~ $ONE_MSGID;
 923         $mid = $1;
 924         my @paths;
 925         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 926                 my $n = $ng->mm->num_for($mid);
 927                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 928         }
 929         return '430 no such article on server' unless @paths;
 930         '223 '.join(' ', @paths);
 931 }
 932
 933 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 934
 935 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 936
 937 sub do_write ($$) {
 938         my $self = $_[0];
 939         my $done = $self->write(\($_[1]));
 940         return 0 unless $self->{sock};
 941
 942         $done;
 943 }
 944
 945 sub err ($$;@) {
 946         my ($self, $fmt, @args) = @_;
 947         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 948 }
 949
 950 sub out ($$;@) {
 951         my ($self, $fmt, @args) = @_;
 952         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 953 }
 954
 955 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 956 sub event_step {
 957         my ($self) = @_;
 958
 959         return unless $self->flush_write && $self->{sock};
 960
 961         $self->update_idle_time;
 962         # only read more requests if we've drained the write buffer,
 963         # otherwise we can be buffering infinitely w/o backpressure
 964
 965         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 966         my $r = 1;
 967
 968         if (index($$rbuf, "\n") < 0) {
 969                 my $off = bytes::length($$rbuf);
 970                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 971         }
 972         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 973                 my $line = $1;
 974                 return $self->close if $line =~ /[[:cntrl:]]/s;
 975                 my $t0 = now();
 976                 my $fd = fileno($self->{sock});
 977                 $r = eval { process_line($self, $line) };
 978                 my $pending = $self->{wbuf} ? ' pending' : '';
 979                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 980         }
 981
 982         return $self->close if $r < 0;
 983         my $len = bytes::length($$rbuf);
 984         return $self->close if ($len >= LINE_MAX);
 985         $self->rbuf_idle($rbuf);
 986         $self->update_idle_time;
 987
 988         # maybe there's more pipelined data, or we'll have
 989         # to register it for socket-readiness notifications
 990         $self->requeue unless $self->{wbuf};
 991 }
 992
 993 # for graceful shutdown in PublicInbox::Daemon:
 994 sub busy {
 995         my ($self, $now) = @_;
 996         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 997 }
 998
 999 1;