lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::Simple;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(gettimeofday tv_interval ualarm);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         long_response_limit => 0xffffffff,
  18 };
  19
  20 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  21 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  22
  23 # disable commands with easy DoS potential:
  24 # LISTGROUP could get pretty bad, too...
  25 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  26
  27 sub new ($$$) {
  28         my ($class, $sock, $nntpd) = @_;
  29         my $self = fields::new($class);
  30         $self->SUPER::new($sock);
  31         $self->{nntpd} = $nntpd;
  32         res($self, '201 server ready - post via email');
  33         $self->watch_read(1);
  34         $self;
  35 }
  36
  37 sub args_ok ($$) {
  38         my ($cb, $argc) = @_;
  39         my $tot = prototype $cb;
  40         my ($nreq, undef) = split(';', $tot);
  41         $nreq = ($nreq =~ tr/$//) - 1;
  42         $tot = ($tot =~ tr/$//) - 1;
  43         ($argc <= $tot && $argc >= $nreq);
  44 }
  45
  46 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  47 sub process_line ($$) {
  48         my ($self, $l) = @_;
  49         my ($req, @args) = split(/\s+/, $l);
  50         $req = lc($req);
  51         $req = eval {
  52                 no strict 'refs';
  53                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  54         };
  55         return res($self, '500 command not recognized') unless $req;
  56         return res($self, r501) unless args_ok($req, scalar @args);
  57
  58         my $res = eval { $req->($self, @args) };
  59         my $err = $@;
  60         if ($err && !$self->{closed}) {
  61                 chomp($l = Dumper(\$l));
  62                 warning('error from: ', $l, ' ', $err);
  63                 $res = '503 program fault - command not performed';
  64         }
  65         return 0 unless defined $res;
  66         res($self, $res);
  67 }
  68
  69 sub cmd_mode ($$) {
  70         my ($self, $arg) = @_;
  71         $arg = uc $arg;
  72         return r501 unless $arg eq 'READER';
  73         '200 reader status acknowledged';
  74 }
  75
  76 sub cmd_slave ($) { '202 slave status noted' }
  77
  78 sub cmd_xgtitle ($;$) {
  79         my ($self, $wildmat) = @_;
  80         more($self, '282 list of groups and descriptions follows');
  81         list_newsgroups($self, $wildmat);
  82         '.'
  83 }
  84
  85 sub list_overview_fmt ($$) {
  86         my ($self) = @_;
  87         more($self, $_ . ':') foreach @OVERVIEW;
  88 }
  89
  90 sub list_active ($;$) {
  91         my ($self, $wildmat) = @_;
  92         wildmat2re($wildmat);
  93         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
  94                 $ng->{name} =~ $wildmat or next;
  95                 group_line($self, $ng);
  96         }
  97 }
  98
  99 sub list_active_times ($;$) {
 100         my ($self, $wildmat) = @_;
 101         wildmat2re($wildmat);
 102         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 103                 $ng->{name} =~ $wildmat or next;
 104                 my $c = eval { $ng->mm->created_at } || time;
 105                 more($self, "$ng->{name} $c $ng->{address}");
 106         }
 107 }
 108
 109 sub list_newsgroups ($;$) {
 110         my ($self, $wildmat) = @_;
 111         wildmat2re($wildmat);
 112         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 113                 $ng->{name} =~ $wildmat or next;
 114                 my $d = $ng->description;
 115                 more($self, "$ng->{name} $d");
 116         }
 117 }
 118
 119 # LIST SUBSCRIPTIONS not supported
 120 sub cmd_list ($;$$) {
 121         my ($self, @args) = @_;
 122         if (scalar @args) {
 123                 my $arg = shift @args;
 124                 $arg =~ tr/A-Z./a-z_/;
 125                 $arg = "list_$arg";
 126                 return '503 function not performed' if $DISABLED{$arg};
 127
 128                 $arg = eval {
 129                         no strict 'refs';
 130                         *{$arg}{CODE};
 131                 };
 132                 return r501 unless $arg && args_ok($arg, scalar @args);
 133                 more($self, '215 information follows');
 134                 $arg->($self, @args);
 135         } else {
 136                 more($self, '215 list of newsgroups follows');
 137                 foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 138                         group_line($self, $ng);
 139                 }
 140         }
 141         '.'
 142 }
 143
 144 sub cmd_listgroup ($;$) {
 145         my ($self, $group) = @_;
 146         if (defined $group) {
 147                 my $res = cmd_group($self, $group);
 148                 return $res if ($res !~ /\A211 /);
 149                 more($self, $res);
 150         }
 151
 152         $self->{ng} or return '412 no newsgroup selected';
 153         $self->long_response(0, long_response_limit, sub {
 154                 my ($i) = @_;
 155                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 156                         my ($ary) = @_;
 157                         more($self, join("\r\n", @$ary));
 158                 });
 159
 160                 # -1 to adjust for implicit increment in long_response
 161                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 162         });
 163 }
 164
 165 sub parse_time ($$;$) {
 166         my ($date, $time, $gmt) = @_;
 167         use Time::Local qw();
 168         my ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 169         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 170         if (defined $gmt) {
 171                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 172                 $gmt = 1;
 173         }
 174         my @now = $gmt ? gmtime : localtime;
 175         if ($YY > strftime('%y', @now)) {
 176                 my $cur_year = $now[5] + 1900;
 177                 $YY += int($cur_year / 1000) * 1000 - 100;
 178         }
 179
 180         if ($gmt) {
 181                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YY);
 182         } else {
 183                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YY);
 184         }
 185 }
 186
 187 sub group_line ($$) {
 188         my ($self, $ng) = @_;
 189         my ($min, $max) = $ng->mm->minmax;
 190         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 191 }
 192
 193 sub cmd_newgroups ($$$;$$) {
 194         my ($self, $date, $time, $gmt, $dists) = @_;
 195         my $ts = eval { parse_time($date, $time, $gmt) };
 196         return r501 if $@;
 197
 198         # TODO dists
 199         more($self, '231 list of new newsgroups follows');
 200         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 201                 my $c = eval { $ng->mm->created_at } || 0;
 202                 next unless $c > $ts;
 203                 group_line($self, $ng);
 204         }
 205         '.'
 206 }
 207
 208 sub wildmat2re (;$) {
 209         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 210         my %keep;
 211         my $salt = rand;
 212         use Digest::SHA qw(sha1_hex);
 213         my $tmp = $_[0];
 214
 215         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 216                 my $orig = $1;
 217                 my $key = sha1_hex($orig . $salt);
 218                 $orig =~ s/([^\w\-])+/\Q$1/g;
 219                 $keep{$key} = $orig;
 220                 $key
 221                 #gex;
 222         my %map = ('*' => '.*', '?' => '.' );
 223         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 224         if (scalar %keep) {
 225                 $tmp =~ s#([a-f0-9]{40})#
 226                         my $orig = $keep{$1};
 227                         defined $orig ? $orig : $1;
 228                         #ge;
 229         }
 230         $_[0] = qr/\A$tmp\z/;
 231 }
 232
 233 sub ngpat2re (;$) {
 234         return $_[0] = qr/\A\z/ unless defined $_[0];
 235         my %map = ('*' => '.*', ',' => '|');
 236         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 237         $_[0] = qr/\A(?:$_[0])\z/;
 238 }
 239
 240 sub cmd_newnews ($$$$;$$) {
 241         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 242         my $ts = eval { parse_time($date, $time, $gmt) };
 243         return r501 if $@;
 244         more($self, '230 list of new articles by message-id follows');
 245         my ($keep, $skip) = split('!', $newsgroups, 2);
 246         ngpat2re($keep);
 247         ngpat2re($skip);
 248         my @srch;
 249         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 250                 $ng->{name} =~ $keep or next;
 251                 $ng->{name} =~ $skip and next;
 252                 my $srch = $ng->search or next;
 253                 push @srch, $srch;
 254         };
 255         return '.' unless @srch;
 256
 257         $ts .= '..';
 258         my $opts = { asc => 1, limit => 1000, offset => 0 };
 259         $self->long_response(0, long_response_limit, sub {
 260                 my ($i) = @_;
 261                 my $srch = $srch[0];
 262                 my $res = $srch->query($ts, $opts);
 263                 my $msgs = $res->{msgs};
 264                 if (my $nr = scalar @$msgs) {
 265                         more($self, '<' .
 266                                 join(">\r\n<", map { $_->mid } @$msgs ).
 267                                 '>');
 268                         $opts->{offset} += $nr;
 269                 } else {
 270                         shift @srch;
 271                         if (@srch) { # continue onto next newsgroup
 272                                 $opts->{offset} = 0;
 273                         } else { # break out of the long response.
 274                                 $$i = long_response_limit;
 275                         }
 276                 }
 277         });
 278 }
 279
 280 sub cmd_group ($$) {
 281         my ($self, $group) = @_;
 282         my $no_such = '411 no such news group';
 283         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 284
 285         $self->{ng} = $ng;
 286         my ($min, $max) = $ng->mm->minmax;
 287         $min ||= 0;
 288         $max ||= 0;
 289         $self->{article} = $min;
 290         my $est_size = $max - $min;
 291         "211 $est_size $min $max $group";
 292 }
 293
 294 sub article_adj ($$) {
 295         my ($self, $off) = @_;
 296         my $ng = $self->{ng} or return '412 no newsgroup selected';
 297
 298         my $n = $self->{article};
 299         defined $n or return '420 no current article has been selected';
 300
 301         $n += $off;
 302         my $mid = $ng->mm->mid_for($n);
 303         unless ($mid) {
 304                 $n = $off > 0 ? 'next' : 'previous';
 305                 return "421 no $n article in this group";
 306         }
 307         $self->{article} = $n;
 308         "223 $n <$mid> article retrieved - request text separately";
 309 }
 310
 311 sub cmd_next ($) { article_adj($_[0], 1) }
 312 sub cmd_last ($) { article_adj($_[0], -1) }
 313
 314 # We want to encourage using email and CC-ing everybody involved to avoid
 315 # the single-point-of-failure a single server provides.
 316 sub cmd_post ($) {
 317         my ($self) = @_;
 318         my $ng = $self->{ng};
 319         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 320 }
 321
 322 sub cmd_quit ($) {
 323         my ($self) = @_;
 324         res($self, '205 closing connection - goodbye!');
 325         $self->close;
 326         undef;
 327 }
 328
 329 sub art_lookup ($$$) {
 330         my ($self, $art, $set_headers) = @_;
 331         my $ng = $self->{ng} or return '412 no newsgroup has been selected';
 332         my ($n, $mid);
 333         my $err;
 334         if (defined $art) {
 335                 if ($art =~ /\A\d+\z/o) {
 336                         $err = '423 no such article number in this group';
 337                         $n = int($art);
 338                         goto find_mid;
 339                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 340                         $err = '430 no such article found';
 341                         $mid = $1;
 342                         $n = $ng->mm->num_for($mid);
 343                         defined $mid or return $err;
 344                 } else {
 345                         return r501;
 346                 }
 347         } else {
 348                 $err = '420 no current article has been selected';
 349                 $n = $self->{article};
 350                 defined $n or return $err;
 351 find_mid:
 352                 $mid = $ng->mm->mid_for($n);
 353                 defined $mid or return $err;
 354         }
 355
 356         my $o = 'HEAD:' . mid2path($mid);
 357         my $s = eval { Email::Simple->new($ng->gcf->cat_file($o)) };
 358         return $err unless $s;
 359         if ($set_headers) {
 360                 $s->header_set('Newsgroups', $ng->{name});
 361                 $s->header_set('Lines', $s->body =~ tr!\n!\n!);
 362                 $s->header_set('Xref', "$ng->{domain} $ng->{name}:$n");
 363
 364                 # must be last
 365                 if ($set_headers == 2) {
 366                         $s->header_set('Bytes', bytes::length($s->as_string));
 367                         $s->body_set('');
 368                 }
 369         }
 370         [ $n, $mid, $s ];
 371 }
 372
 373 sub simple_body_write ($$) {
 374         my ($self, $s) = @_;
 375         my $body = $s->body;
 376         $s->body_set('');
 377         $body =~ s/^\./../smg;
 378         do_more($self, $body);
 379         '.'
 380 }
 381
 382 sub header_str ($) {
 383         my ($s) = @_;
 384         my $h = $s->header_obj;
 385         $h->header_set('Bytes');
 386         $h->as_string
 387 }
 388
 389 sub cmd_article ($$) {
 390         my ($self, $art) = @_;
 391         my $r = $self->art_lookup($art, 1);
 392         return $r unless ref $r;
 393         my ($n, $mid, $s) = @$r;
 394         more($self, "220 $n <$mid> article retrieved - head and body follow");
 395         do_more($self, header_str($s));
 396         do_more($self, "\r\n");
 397         simple_body_write($self, $s);
 398 }
 399
 400 sub cmd_head ($$) {
 401         my ($self, $art) = @_;
 402         my $r = $self->art_lookup($art, 2);
 403         return $r unless ref $r;
 404         my ($n, $mid, $s) = @$r;
 405         more($self, "221 $n <$mid> article retrieved - head follows");
 406         do_more($self, header_str($s));
 407         '.'
 408 }
 409
 410 sub cmd_body ($$) {
 411         my ($self, $art) = @_;
 412         my $r = $self->art_lookup($art, 0);
 413         return $r unless ref $r;
 414         my ($n, $mid, $s) = @$r;
 415         more($self, "222 $n <$mid> article retrieved - body follows");
 416         simple_body_write($self, $s);
 417 }
 418
 419 sub cmd_stat ($$) {
 420         my ($self, $art) = @_;
 421         my $r = $self->art_lookup($art, 0);
 422         return $r unless ref $r;
 423         my ($n, $mid, undef) = @$r;
 424         "223 $n <$mid> article retrieved - request text separately";
 425 }
 426
 427 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 428
 429 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 430
 431 sub cmd_help ($) {
 432         my ($self) = @_;
 433         more($self, '100 help text follows');
 434         '.'
 435 }
 436
 437 sub get_range ($$) {
 438         my ($self, $range) = @_;
 439         my $ng = $self->{ng} or return '412 no news group has been selected';
 440         defined $range or return '420 No article(s) selected';
 441         my ($beg, $end);
 442         my ($min, $max) = $ng->mm->minmax;
 443         if ($range =~ /\A(\d+)\z/) {
 444                 $beg = $end = $1;
 445         } elsif ($range =~ /\A(\d+)-\z/) {
 446                 ($beg, $end) = ($1, $max);
 447         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 448                 ($beg, $end) = ($1, $2);
 449         } else {
 450                 return r501;
 451         }
 452         $beg = $min if ($beg < $min);
 453         $end = $max if ($end > $max);
 454         return '420 No article(s) selected' if ($beg > $end);
 455         [ $beg, $end ];
 456 }
 457
 458 sub xhdr ($$) {
 459         my ($r, $header) = @_;
 460         $r = $r->[2]->header_obj->header($header);
 461         defined $r or return;
 462         $r =~ s/[\r\n\t]+/ /sg;
 463         $r;
 464 }
 465
 466 sub long_response ($$$$) {
 467         my ($self, $beg, $end, $cb) = @_;
 468         die "BUG: nested long response" if $self->{long_res};
 469
 470         # make sure we disable reading during a long response,
 471         # clients should not be sending us stuff and making us do more
 472         # work while we are stream a response to them
 473         $self->watch_read(0);
 474         $self->{long_res} = sub {
 475                 # limit our own running time for fairness with other
 476                 # clients and to avoid buffering too much:
 477                 my $yield;
 478                 local $SIG{ALRM} = sub { $yield = 1 };
 479                 ualarm(100000);
 480
 481                 my $err;
 482                 do {
 483                         eval { $cb->(\$beg) };
 484                 } until (($err = $@) || $self->{closed} || $yield ||
 485                          $self->{write_buf_size} || ++$beg > $end);
 486                 ualarm(0);
 487
 488                 if ($err || $self->{closed}) {
 489                         $self->{long_res} = undef;
 490                         warning("$err during long response") if $err;
 491                         $self->watch_read(1) unless $self->{closed};
 492                 } elsif ($yield || $self->{write_buf_size}) {
 493                         # no recursion, schedule another call ASAP
 494                         # but only after all pending writes are done
 495                         Danga::Socket->AddTimer(0, sub {
 496                                 $self->write($self->{long_res});
 497                         });
 498                 } else { # all done!
 499                         $self->{long_res} = undef;
 500                         $self->watch_read(1);
 501                         res($self, '.');
 502                 }
 503         };
 504         $self->{long_res}->(); # kick off!
 505         undef;
 506 }
 507
 508 sub xhdr_message_id ($$) { # optimize XHDR Message-ID [range] for slrnpull.
 509         my ($self, $range) = @_;
 510
 511         my $mm = $self->{ng}->mm;
 512         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 513                 my $n = $mm->num_for($range);
 514                 more($self, '221 Header follows');
 515                 more($self, "<$range> <$range>") if defined $n;
 516                 '.';
 517         } else { # numeric range
 518                 $range = $self->{article} unless defined $range;
 519                 my $r = get_range($self, $range);
 520                 return $r unless ref $r;
 521                 my ($beg, $end) = @$r;
 522                 more($self, '221 Header follows');
 523                 $self->long_response($beg, $end, sub {
 524                         my ($i) = @_;
 525                         my $mid = $mm->mid_for($$i);
 526                         more($self, "$$i <$mid>") if defined $mid;
 527                 });
 528         }
 529 }
 530
 531 sub header_obj_for {
 532         my ($srch, $mid) = @_;
 533         eval {
 534                 my $smsg = $srch->lookup_message($mid);
 535                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 536                 $smsg->mini_mime->header_obj;
 537         };
 538 };
 539
 540 sub xhdr_searchmsg ($$$) {
 541         my ($self, $sub, $range) = @_;
 542         my $srch = $self->{ng}->search;
 543         my $emit = ($sub eq 'date') ? sub {
 544                 my ($pfx, $m) = @_;
 545                 my @t = gmtime($m->header('X-PI-TS'));
 546                 more($self, "$pfx ". strftime('%a, %d %b %Y %T %z', @t));
 547         } : sub {
 548                 my ($pfx, $m) = @_;
 549                 my $h = $m->header($sub);
 550                 more($self, "$pfx $h") if defined $h;
 551         };
 552
 553         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 554                 more($self, '221 Header follows');
 555                 my $m = header_obj_for($srch, $1);
 556                 $emit->($range, $m) if defined $m;
 557                 '.';
 558         } else { # numeric range
 559                 $range = $self->{article} unless defined $range;
 560                 my $mm = $self->{ng}->mm;
 561                 my $r = get_range($self, $range);
 562                 return $r unless ref $r;
 563                 my ($beg, $end) = @$r;
 564                 more($self, '221 Header follows');
 565                 $self->long_response($beg, $end, sub {
 566                         my ($i) = @_;
 567                         my $mid = $mm->mid_for($$i) or return;
 568                         my $m = header_obj_for($srch, $mid) or return;
 569                         $emit->($$i, $m);
 570                 });
 571         }
 572 }
 573
 574 sub cmd_xhdr ($$;$) {
 575         my ($self, $header, $range) = @_;
 576         my $ng = $self->{ng};
 577         defined $ng or return '412 no news group currently selected';
 578         my $sub = lc $header;
 579         if ($sub eq 'message-id') {
 580                 xhdr_message_id($self, $range);
 581         } elsif ($sub =~ /\A(subject|references|date)\z/ && $ng->search) {
 582                 xhdr_searchmsg($self, $sub, $range);
 583         } else {
 584                 xhdr_slow($self, $header, $range);
 585         }
 586 }
 587
 588 sub xhdr_slow ($$$) {
 589         my ($self, $header, $range) = @_;
 590
 591         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 592                 my $r = $self->art_lookup($range, 2);
 593                 return $r unless ref $r;
 594                 more($self, '221 Header follows');
 595                 if (defined($r = xhdr($r, $header))) {
 596                         more($self, "<$range> $r");
 597                 }
 598                 '.';
 599         } else { # numeric range
 600                 $range = $self->{article} unless defined $range;
 601                 my $r = get_range($self, $range);
 602                 return $r unless ref $r;
 603                 my ($beg, $end) = @$r;
 604                 more($self, '221 Header follows');
 605                 $self->long_response($beg, $end, sub {
 606                         my ($i) = @_;
 607                         $r = $self->art_lookup($$i, 2);
 608                         return unless ref $r;
 609                         defined($r = xhdr($r, $header)) or return;
 610                         more($self, "$$i $r");
 611                 });
 612         }
 613 }
 614
 615 sub cmd_xrover ($;$) {
 616         my ($self, $range) = @_;
 617         my $ng = $self->{ng} or return '412 no newsgroup selected';
 618         (defined $range && $range =~ /[<>]/) and
 619                 return '420 No article(s) selected'; # no message IDs
 620
 621         $range = $self->{article} unless defined $range;
 622         my $r = get_range($self, $range);
 623         return $r unless ref $r;
 624         my ($beg, $end) = @$r;
 625         my $mm = $ng->mm;
 626         my $srch = $ng->search;
 627         more($self, '224 Overview information follows');
 628         $self->long_response($beg, $end, sub {
 629                 my ($i) = @_;
 630                 my $mid = $mm->mid_for($$i) or return;
 631                 my $m = header_obj_for($srch, $mid) or return;
 632                 my $h = $m->header('references');
 633                 more($self, "$$i $h") if defined $h;
 634         });
 635 }
 636
 637 sub cmd_xover ($;$) {
 638         my ($self, $range) = @_;
 639         $range = $self->{article} unless defined $range;
 640         my $r = get_range($self, $range);
 641         return $r unless ref $r;
 642         my ($beg, $end) = @$r;
 643         more($self, "224 Overview information follows for $beg to $end");
 644         $self->long_response($beg, $end, sub {
 645                 my ($i) = @_;
 646                 my $r = $self->art_lookup($$i, 2);
 647                 return unless ref $r;
 648                 more($self, join("\t", $r->[0],
 649                                 map {
 650                                         my $h = xhdr($r, $_);
 651                                         defined $h ? $h : '';
 652                                 } @OVERVIEW ));
 653         });
 654 }
 655
 656 sub cmd_xpath ($$) {
 657         my ($self, $mid) = @_;
 658         return r501 unless $mid =~ /\A<(.+)>\z/;
 659         $mid = $1;
 660         my @paths;
 661         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 662                 my $n = $ng->mm->num_for($mid);
 663                 push @paths, "$ng->{name}/$n" if defined $n;
 664         }
 665         return '430 no such article on server' unless @paths;
 666         '223 '.join(' ', @paths);
 667 }
 668
 669 sub res ($$) {
 670         my ($self, $line) = @_;
 671         do_write($self, $line . "\r\n");
 672 }
 673
 674 sub more ($$) {
 675         my ($self, $line) = @_;
 676         do_more($self, $line . "\r\n");
 677 }
 678
 679 sub do_write ($$) {
 680         my ($self, $data) = @_;
 681         my $done = $self->write($data);
 682         die if $self->{closed};
 683
 684         # Do not watch for readability if we have data in the queue,
 685         # instead re-enable watching for readability when we can
 686         $self->watch_read(0) if (!$done || $self->{long_res});
 687
 688         $done;
 689 }
 690
 691 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 692
 693 sub do_more ($$) {
 694         my ($self, $data) = @_;
 695         if (MSG_MORE && !$self->{write_buf_size}) {
 696                 my $n = send($self->{sock}, $data, MSG_MORE);
 697                 if (defined $n) {
 698                         my $dlen = bytes::length($data);
 699                         return 1 if $n == $dlen; # all done!
 700                         $data = bytes::substr($data, $n, $dlen - $n);
 701                 }
 702         }
 703         $self->do_write($data);
 704 }
 705
 706 # callbacks for by Danga::Socket
 707
 708 sub event_hup { $_[0]->close }
 709 sub event_err { $_[0]->close }
 710
 711 sub event_write {
 712         my ($self) = @_;
 713         # only continue watching for readability when we are done writing:
 714         $self->write(undef) == 1 and $self->watch_read(1);
 715 }
 716
 717 sub event_read {
 718         my ($self) = @_;
 719         use constant LINE_MAX => 512; # RFC 977 section 2.3
 720         my $r = 1;
 721         my $buf = $self->read(LINE_MAX) or return $self->close;
 722         while ($r > 0 && $$buf =~ s/\A([^\r\n]+)\r?\n//) {
 723                 my $line = $1;
 724                 my $t0 = [ gettimeofday ];
 725                 $r = eval { $self->process_line($line) };
 726                 printf(STDERR "$line %0.6f\n",
 727                         tv_interval($t0, [gettimeofday]));
 728         }
 729         return $self->close if $r < 0;
 730         my $len = bytes::length($$buf);
 731         return $self->close if ($len >= LINE_MAX);
 732         $self->push_back_read($buf) if ($len);
 733 }
 734
 735 sub warning { print STDERR @_, "\n" }
 736
 737 1;