lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 my $EXPMAP; # fd -> [ idle_time, $self ]
  36 my $expt;
  37 our $EXPTIME = 180; # 3 minutes
  38
  39 sub update_idle_time ($) {
  40         my ($self) = @_;
  41         my $sock = $self->{sock} or return;
  42         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  43 }
  44
  45 sub expire_old () {
  46         my $now = now();
  47         my $exp = $EXPTIME;
  48         my $old = $now - $exp;
  49         my $nr = 0;
  50         my %new;
  51         while (my ($fd, $v) = each %$EXPMAP) {
  52                 my ($idle_time, $nntp) = @$v;
  53                 if ($idle_time < $old) {
  54                         if (!$nntp->shutdn) {
  55                                 ++$nr;
  56                                 $new{$fd} = $v;
  57                         }
  58                 } else {
  59                         ++$nr;
  60                         $new{$fd} = $v;
  61                 }
  62         }
  63         $EXPMAP = \%new;
  64         $expt = PublicInbox::EvCleanup::later(*expire_old) if $nr;
  65 }
  66
  67 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  68
  69 sub new ($$$) {
  70         my ($class, $sock, $nntpd) = @_;
  71         my $self = fields::new($class);
  72         my $ev = EPOLLIN;
  73         my $wbuf;
  74         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  75                 return CORE::close($sock) if $! != EAGAIN;
  76                 $ev = PublicInbox::TLS::epollbit();
  77                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  78         }
  79         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  80         $self->{nntpd} = $nntpd;
  81         if ($wbuf) {
  82                 $self->{wbuf} = $wbuf;
  83         } else {
  84                 greet($self);
  85         }
  86         update_idle_time($self);
  87         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  88         $self;
  89 }
  90
  91 sub args_ok ($$) {
  92         my ($cb, $argc) = @_;
  93         my $tot = prototype $cb;
  94         my ($nreq, undef) = split(';', $tot);
  95         $nreq = ($nreq =~ tr/$//) - 1;
  96         $tot = ($tot =~ tr/$//) - 1;
  97         ($argc <= $tot && $argc >= $nreq);
  98 }
  99
 100 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 101 sub process_line ($$) {
 102         my ($self, $l) = @_;
 103         my ($req, @args) = split(/[ \t]/, $l);
 104         return 1 unless defined($req); # skip blank line
 105         $req = eval {
 106                 no strict 'refs';
 107                 *{'cmd_'.lc($req)}{CODE};
 108         };
 109         return res($self, '500 command not recognized') unless $req;
 110         return res($self, r501) unless args_ok($req, scalar @args);
 111
 112         my $res = eval { $req->($self, @args) };
 113         my $err = $@;
 114         if ($err && $self->{sock}) {
 115                 local $/ = "\n";
 116                 chomp($l);
 117                 err($self, 'error from: %s (%s)', $l, $err);
 118                 $res = '503 program fault - command not performed';
 119         }
 120         return 0 unless defined $res;
 121         res($self, $res);
 122 }
 123
 124 sub cmd_mode ($$) {
 125         my ($self, $arg) = @_;
 126         $arg = uc $arg;
 127         return r501 unless $arg eq 'READER';
 128         '201 Posting prohibited';
 129 }
 130
 131 sub cmd_slave ($) { '202 slave status noted' }
 132
 133 sub cmd_xgtitle ($;$) {
 134         my ($self, $wildmat) = @_;
 135         more($self, '282 list of groups and descriptions follows');
 136         list_newsgroups($self, $wildmat);
 137         '.'
 138 }
 139
 140 sub list_overview_fmt ($) {
 141         my ($self) = @_;
 142         msg_more($self, $OVERVIEW_FMT);
 143 }
 144
 145 sub list_headers ($;$) {
 146         my ($self) = @_;
 147         msg_more($self, $LIST_HEADERS);
 148 }
 149
 150 sub list_active ($;$) {
 151         my ($self, $wildmat) = @_;
 152         wildmat2re($wildmat);
 153         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 154                 $ng->{newsgroup} =~ $wildmat or next;
 155                 group_line($self, $ng);
 156         }
 157 }
 158
 159 sub list_active_times ($;$) {
 160         my ($self, $wildmat) = @_;
 161         wildmat2re($wildmat);
 162         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 163                 $ng->{newsgroup} =~ $wildmat or next;
 164                 my $c = eval { $ng->mm->created_at } || time;
 165                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 166         }
 167 }
 168
 169 sub list_newsgroups ($;$) {
 170         my ($self, $wildmat) = @_;
 171         wildmat2re($wildmat);
 172         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 173                 $ng->{newsgroup} =~ $wildmat or next;
 174                 my $d = $ng->description;
 175                 more($self, "$ng->{newsgroup} $d");
 176         }
 177 }
 178
 179 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 180 sub cmd_list ($;$$) {
 181         my ($self, @args) = @_;
 182         if (scalar @args) {
 183                 my $arg = shift @args;
 184                 $arg =~ tr/A-Z./a-z_/;
 185                 $arg = "list_$arg";
 186
 187                 $arg = eval {
 188                         no strict 'refs';
 189                         *{$arg}{CODE};
 190                 };
 191                 return r501 unless $arg && args_ok($arg, scalar @args);
 192                 more($self, '215 information follows');
 193                 $arg->($self, @args);
 194         } else {
 195                 more($self, '215 list of newsgroups follows');
 196                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 197                         group_line($self, $ng);
 198                 }
 199         }
 200         '.'
 201 }
 202
 203 sub cmd_listgroup ($;$) {
 204         my ($self, $group) = @_;
 205         if (defined $group) {
 206                 my $res = cmd_group($self, $group);
 207                 return $res if ($res !~ /\A211 /);
 208                 more($self, $res);
 209         }
 210
 211         $self->{ng} or return '412 no newsgroup selected';
 212         my $n = 0;
 213         long_response($self, sub {
 214                 my $ary = $self->{ng}->mm->ids_after(\$n);
 215                 scalar @$ary or return;
 216                 more($self, join("\r\n", @$ary));
 217                 1;
 218         });
 219 }
 220
 221 sub parse_time ($$;$) {
 222         my ($date, $time, $gmt) = @_;
 223         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 224         if (defined $gmt) {
 225                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 226                 $gmt = 1;
 227         }
 228         my @now = $gmt ? gmtime : localtime;
 229         my ($YYYY, $MM, $DD);
 230         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 231                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 232         } else { # legacy clients send YYMMDD
 233                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 234                 my $cur_year = $now[5] + 1900;
 235                 if ($YYYY > $cur_year) {
 236                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 237                 }
 238         }
 239         if ($gmt) {
 240                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 241         } else {
 242                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 243         }
 244 }
 245
 246 sub group_line ($$) {
 247         my ($self, $ng) = @_;
 248         my ($min, $max) = $ng->mm->minmax;
 249         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 250 }
 251
 252 sub cmd_newgroups ($$$;$$) {
 253         my ($self, $date, $time, $gmt, $dists) = @_;
 254         my $ts = eval { parse_time($date, $time, $gmt) };
 255         return r501 if $@;
 256
 257         # TODO dists
 258         more($self, '231 list of new newsgroups follows');
 259         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 260                 my $c = eval { $ng->mm->created_at } || 0;
 261                 next unless $c > $ts;
 262                 group_line($self, $ng);
 263         }
 264         '.'
 265 }
 266
 267 sub wildmat2re (;$) {
 268         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 269         my %keep;
 270         my $salt = rand;
 271         my $tmp = $_[0];
 272
 273         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 274                 my $orig = $1;
 275                 my $key = sha1_hex($orig . $salt);
 276                 $orig =~ s/([^\w\-])+/\Q$1/g;
 277                 $keep{$key} = $orig;
 278                 $key
 279                 #gex;
 280         my %map = ('*' => '.*', '?' => '.' );
 281         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 282         if (scalar %keep) {
 283                 $tmp =~ s#([a-f0-9]{40})#
 284                         my $orig = $keep{$1};
 285                         defined $orig ? $orig : $1;
 286                         #ge;
 287         }
 288         $_[0] = qr/\A$tmp\z/;
 289 }
 290
 291 sub ngpat2re (;$) {
 292         return $_[0] = qr/\A\z/ unless defined $_[0];
 293         my %map = ('*' => '.*', ',' => '|');
 294         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 295         $_[0] = qr/\A(?:$_[0])\z/;
 296 }
 297
 298 sub cmd_newnews ($$$$;$$) {
 299         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 300         my $ts = eval { parse_time($date, $time, $gmt) };
 301         return r501 if $@;
 302         more($self, '230 list of new articles by message-id follows');
 303         my ($keep, $skip) = split('!', $newsgroups, 2);
 304         ngpat2re($keep);
 305         ngpat2re($skip);
 306         my @over;
 307         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 308                 $ng->{newsgroup} =~ $keep or next;
 309                 $ng->{newsgroup} =~ $skip and next;
 310                 my $over = $ng->over or next;
 311                 push @over, $over;
 312         };
 313         return '.' unless @over;
 314
 315         my $prev = 0;
 316         long_response($self, sub {
 317                 my $over = $over[0];
 318                 my $msgs = $over->query_ts($ts, $prev);
 319                 if (scalar @$msgs) {
 320                         more($self, '<' .
 321                                 join(">\r\n<", map { $_->mid } @$msgs ).
 322                                 '>');
 323                         $prev = $msgs->[-1]->{num};
 324                 } else {
 325                         shift @over;
 326                         if (@over) { # continue onto next newsgroup
 327                                 $prev = 0;
 328                                 return 1;
 329                         } else { # break out of the long response.
 330                                 return;
 331                         }
 332                 }
 333         });
 334 }
 335
 336 sub cmd_group ($$) {
 337         my ($self, $group) = @_;
 338         my $no_such = '411 no such news group';
 339         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 340
 341         $self->{ng} = $ng;
 342         my ($min, $max) = $ng->mm->minmax;
 343         $min ||= 0;
 344         $max ||= 0;
 345         $self->{article} = $min;
 346         my $est_size = $max - $min;
 347         "211 $est_size $min $max $group";
 348 }
 349
 350 sub article_adj ($$) {
 351         my ($self, $off) = @_;
 352         my $ng = $self->{ng} or return '412 no newsgroup selected';
 353
 354         my $n = $self->{article};
 355         defined $n or return '420 no current article has been selected';
 356
 357         $n += $off;
 358         my $mid = $ng->mm->mid_for($n);
 359         unless ($mid) {
 360                 $n = $off > 0 ? 'next' : 'previous';
 361                 return "421 no $n article in this group";
 362         }
 363         $self->{article} = $n;
 364         "223 $n <$mid> article retrieved - request text separately";
 365 }
 366
 367 sub cmd_next ($) { article_adj($_[0], 1) }
 368 sub cmd_last ($) { article_adj($_[0], -1) }
 369
 370 # We want to encourage using email and CC-ing everybody involved to avoid
 371 # the single-point-of-failure a single server provides.
 372 sub cmd_post ($) {
 373         my ($self) = @_;
 374         my $ng = $self->{ng};
 375         $ng ? "440 mailto:$ng->{-primary_address} to post"
 376                 : '440 posting not allowed'
 377 }
 378
 379 sub cmd_quit ($) {
 380         my ($self) = @_;
 381         res($self, '205 closing connection - goodbye!');
 382         $self->shutdn;
 383         undef;
 384 }
 385
 386 sub header_append ($$$) {
 387         my ($hdr, $k, $v) = @_;
 388         my @v = $hdr->header($k);
 389         foreach (@v) {
 390                 return if $v eq $_;
 391         }
 392         $hdr->header_set($k, @v, $v);
 393 }
 394
 395 sub xref ($$$$) {
 396         my ($self, $ng, $n, $mid) = @_;
 397         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 398
 399         # num_for is pretty cheap and sometimes we'll lookup the existence
 400         # of an article without getting even the OVER info.  In other words,
 401         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 402         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 403         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 404                 next if $ng eq $other;
 405                 my $num = eval { $other->mm->num_for($mid) } or next;
 406                 $ret .= " $other->{newsgroup}:$num";
 407         }
 408         $ret;
 409 }
 410
 411 sub set_nntp_headers ($$$$$) {
 412         my ($self, $hdr, $ng, $n, $mid) = @_;
 413
 414         # why? leafnode requires a Path: header for some inexplicable
 415         # reason.  We'll fake the shortest one possible.
 416         $hdr->header_set('Path', 'y');
 417
 418         # leafnode (and maybe other NNTP clients) have trouble dealing
 419         # with v2 messages which have multiple Message-IDs (either due
 420         # to our own content-based dedupe or buggy git-send-email versions).
 421         my @mids = $hdr->header('Message-ID');
 422         if (scalar(@mids) > 1) {
 423                 my $mid0 = "<$mid>";
 424                 $hdr->header_set('Message-ID', $mid0);
 425                 my @alt = $hdr->header('X-Alt-Message-ID');
 426                 my %seen = map { $_ => 1 } (@alt, $mid0);
 427                 foreach my $m (@mids) {
 428                         next if $seen{$m}++;
 429                         push @alt, $m;
 430                 }
 431                 $hdr->header_set('X-Alt-Message-ID', @alt);
 432         }
 433
 434         # clobber some
 435         my $xref = xref($self, $ng, $n, $mid);
 436         $hdr->header_set('Xref', $xref);
 437         $xref =~ s/:[0-9]+//g;
 438         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 439         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 440         if (my $url = $ng->base_url) {
 441                 $mid = mid_escape($mid);
 442                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 443                 header_append($hdr, 'List-Archive', "<$url>");
 444         }
 445 }
 446
 447 sub art_lookup ($$$) {
 448         my ($self, $art, $set_headers) = @_;
 449         my $ng = $self->{ng};
 450         my ($n, $mid);
 451         my $err;
 452         if (defined $art) {
 453                 if ($art =~ /\A[0-9]+\z/) {
 454                         $err = '423 no such article number in this group';
 455                         $n = int($art);
 456                         goto find_mid;
 457                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 458                         $mid = $1;
 459                         $err = r430;
 460                         $n = $ng->mm->num_for($mid) if $ng;
 461                         goto found if defined $n;
 462                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 463                                 $n = $g->mm->num_for($mid);
 464                                 if (defined $n) {
 465                                         $ng = $g;
 466                                         goto found;
 467                                 }
 468                         }
 469                         return $err;
 470                 } else {
 471                         return r501;
 472                 }
 473         } else {
 474                 $err = '420 no current article has been selected';
 475                 $n = $self->{article};
 476                 defined $n or return $err;
 477 find_mid:
 478                 $ng or return '412 no newsgroup has been selected';
 479                 $mid = $ng->mm->mid_for($n);
 480                 defined $mid or return $err;
 481         }
 482 found:
 483         my $smsg = $ng->over->get_art($n) or return $err;
 484         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 485
 486         # Email::Simple->new will modify $msg in-place as documented
 487         # in its manpage, so what's left is the body and we won't need
 488         # to call Email::Simple::body(), later
 489         my $hdr = Email::Simple->new($msg)->header_obj;
 490         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 491         [ $n, $mid, $msg, $hdr ];
 492 }
 493
 494 sub msg_body_write ($$) {
 495         my ($self, $msg) = @_;
 496
 497         # these can momentarily double the memory consumption :<
 498         $$msg =~ s/^\./../smg;
 499         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 500         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 501         msg_more($self, $$msg);
 502         '.'
 503 }
 504
 505 sub set_art {
 506         my ($self, $art) = @_;
 507         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 508 }
 509
 510 sub msg_hdr_write ($$$) {
 511         my ($self, $hdr, $body_follows) = @_;
 512         $hdr = $hdr->as_string;
 513         utf8::encode($hdr);
 514         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 515
 516         # for leafnode compatibility, we need to ensure Message-ID headers
 517         # are only a single line.  We can't subclass Email::Simple::Header
 518         # and override _default_fold_at in here, either; since that won't
 519         # affect messages already in the archive.
 520         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 521         $hdr .= "\r\n" if $body_follows;
 522         msg_more($self, $hdr);
 523 }
 524
 525 sub cmd_article ($;$) {
 526         my ($self, $art) = @_;
 527         my $r = art_lookup($self, $art, 1);
 528         return $r unless ref $r;
 529         my ($n, $mid, $msg, $hdr) = @$r;
 530         set_art($self, $art);
 531         more($self, "220 $n <$mid> article retrieved - head and body follow");
 532         msg_hdr_write($self, $hdr, 1);
 533         msg_body_write($self, $msg);
 534 }
 535
 536 sub cmd_head ($;$) {
 537         my ($self, $art) = @_;
 538         my $r = art_lookup($self, $art, 2);
 539         return $r unless ref $r;
 540         my ($n, $mid, undef, $hdr) = @$r;
 541         set_art($self, $art);
 542         more($self, "221 $n <$mid> article retrieved - head follows");
 543         msg_hdr_write($self, $hdr, 0);
 544         '.'
 545 }
 546
 547 sub cmd_body ($;$) {
 548         my ($self, $art) = @_;
 549         my $r = art_lookup($self, $art, 0);
 550         return $r unless ref $r;
 551         my ($n, $mid, $msg) = @$r;
 552         set_art($self, $art);
 553         more($self, "222 $n <$mid> article retrieved - body follows");
 554         msg_body_write($self, $msg);
 555 }
 556
 557 sub cmd_stat ($;$) {
 558         my ($self, $art) = @_;
 559         my $r = art_lookup($self, $art, 0);
 560         return $r unless ref $r;
 561         my ($n, $mid) = @$r;
 562         set_art($self, $art);
 563         "223 $n <$mid> article retrieved - request text separately";
 564 }
 565
 566 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 567
 568 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 569
 570 sub cmd_help ($) {
 571         my ($self) = @_;
 572         more($self, '100 help text follows');
 573         '.'
 574 }
 575
 576 sub get_range ($$) {
 577         my ($self, $range) = @_;
 578         my $ng = $self->{ng} or return '412 no news group has been selected';
 579         defined $range or return '420 No article(s) selected';
 580         my ($beg, $end);
 581         my ($min, $max) = $ng->mm->minmax;
 582         if ($range =~ /\A([0-9]+)\z/) {
 583                 $beg = $end = $1;
 584         } elsif ($range =~ /\A([0-9]+)-\z/) {
 585                 ($beg, $end) = ($1, $max);
 586         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 587                 ($beg, $end) = ($1, $2);
 588         } else {
 589                 return r501;
 590         }
 591         $beg = $min if ($beg < $min);
 592         $end = $max if ($end > $max);
 593         return '420 No article(s) selected' if ($beg > $end);
 594         [ $beg, $end ];
 595 }
 596
 597 sub long_response ($$) {
 598         my ($self, $cb) = @_; # cb returns true if more, false if done
 599
 600         my $fd = fileno($self->{sock});
 601         defined $fd or return;
 602         # make sure we disable reading during a long response,
 603         # clients should not be sending us stuff and making us do more
 604         # work while we are stream a response to them
 605         my $t0 = now();
 606         my $long_cb; # DANGER: self-referential
 607         $long_cb = sub {
 608                 # wbuf is unset or empty, here; $cb may add to it
 609                 my $more = eval { $cb->() };
 610                 if ($@ || !$self->{sock}) { # something bad happened...
 611                         $long_cb = undef;
 612                         my $diff = now() - $t0;
 613                         if ($@) {
 614                                 err($self,
 615                                     "%s during long response[$fd] - %0.6f",
 616                                     $@, $diff);
 617                         }
 618                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 619                         $self->close;
 620                 } elsif ($more) { # $self->{wbuf}:
 621                         update_idle_time($self);
 622
 623                         # no recursion, schedule another call ASAP
 624                         # but only after all pending writes are done
 625                         my $wbuf = $self->{wbuf} ||= [];
 626                         push @$wbuf, $long_cb;
 627
 628                         # wbuf may be populated by $cb, no need to rearm if so:
 629                         $self->requeue if scalar(@$wbuf) == 1;
 630                 } else { # all done!
 631                         $long_cb = undef;
 632                         res($self, '.');
 633                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 634                         $self->requeue unless $self->{wbuf};
 635                 }
 636         };
 637         $self->write($long_cb); # kick off!
 638         undef;
 639 }
 640
 641 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 642         my ($self, $xhdr, $range) = @_;
 643
 644         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 645                 my ($ng, $n) = mid_lookup($self, $1);
 646                 return r430 unless $n;
 647                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 648         } else { # numeric range
 649                 $range = $self->{article} unless defined $range;
 650                 my $r = get_range($self, $range);
 651                 return $r unless ref $r;
 652                 my $mm = $self->{ng}->mm;
 653                 my ($beg, $end) = @$r;
 654                 more($self, $xhdr ? r221 : r225);
 655                 long_response($self, sub {
 656                         my $r = $mm->msg_range(\$beg, $end);
 657                         @$r or return;
 658                         more($self, join("\r\n", map {
 659                                 "$_->[0] <$_->[1]>"
 660                         } @$r));
 661                         1;
 662                 });
 663         }
 664 }
 665
 666 sub mid_lookup ($$) {
 667         my ($self, $mid) = @_;
 668         my $self_ng = $self->{ng};
 669         if ($self_ng) {
 670                 my $n = $self_ng->mm->num_for($mid);
 671                 return ($self_ng, $n) if defined $n;
 672         }
 673         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 674                 next if defined $self_ng && $ng eq $self_ng;
 675                 my $n = $ng->mm->num_for($mid);
 676                 return ($ng, $n) if defined $n;
 677         }
 678         (undef, undef);
 679 }
 680
 681 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 682         my ($self, $xhdr, $range) = @_;
 683
 684         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 685                 my $mid = $1;
 686                 my ($ng, $n) = mid_lookup($self, $mid);
 687                 return r430 unless $n;
 688                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 689                                 xref($self, $ng, $n, $mid));
 690         } else { # numeric range
 691                 $range = $self->{article} unless defined $range;
 692                 my $r = get_range($self, $range);
 693                 return $r unless ref $r;
 694                 my $ng = $self->{ng};
 695                 my $mm = $ng->mm;
 696                 my ($beg, $end) = @$r;
 697                 more($self, $xhdr ? r221 : r225);
 698                 long_response($self, sub {
 699                         my $r = $mm->msg_range(\$beg, $end);
 700                         @$r or return;
 701                         more($self, join("\r\n", map {
 702                                 my $num = $_->[0];
 703                                 "$num ".xref($self, $ng, $num, $_->[1]);
 704                         } @$r));
 705                         1;
 706                 });
 707         }
 708 }
 709
 710 sub over_header_for {
 711         my ($over, $num, $field) = @_;
 712         my $smsg = $over->get_art($num) or return;
 713         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 714         $smsg->{$field};
 715 }
 716
 717 sub hdr_searchmsg ($$$$) {
 718         my ($self, $xhdr, $field, $range) = @_;
 719         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 720                 my ($ng, $n) = mid_lookup($self, $1);
 721                 return r430 unless defined $n;
 722                 my $v = over_header_for($ng->over, $n, $field);
 723                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 724         } else { # numeric range
 725                 $range = $self->{article} unless defined $range;
 726                 my $over = $self->{ng}->over;
 727                 my $mm = $self->{ng}->mm;
 728                 my $r = get_range($self, $range);
 729                 return $r unless ref $r;
 730                 my ($beg, $end) = @$r;
 731                 more($self, $xhdr ? r221 : r225);
 732                 my $cur = $beg;
 733                 long_response($self, sub {
 734                         my $msgs = $over->query_xover($cur, $end);
 735                         my $nr = scalar @$msgs or return;
 736                         my $tmp = '';
 737                         foreach my $s (@$msgs) {
 738                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 739                         }
 740                         utf8::encode($tmp);
 741                         msg_more($self, $tmp);
 742                         $cur = $msgs->[-1]->{num} + 1;
 743                 });
 744         }
 745 }
 746
 747 sub do_hdr ($$$;$) {
 748         my ($self, $xhdr, $header, $range) = @_;
 749         my $sub = lc $header;
 750         if ($sub eq 'message-id') {
 751                 hdr_message_id($self, $xhdr, $range);
 752         } elsif ($sub eq 'xref') {
 753                 hdr_xref($self, $xhdr, $range);
 754         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 755                                 bytes|lines)\z/x) {
 756                 hdr_searchmsg($self, $xhdr, $sub, $range);
 757         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 758                 hdr_searchmsg($self, $xhdr, $1, $range);
 759         } else {
 760                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 761         }
 762 }
 763
 764 # RFC 3977
 765 sub cmd_hdr ($$;$) {
 766         my ($self, $header, $range) = @_;
 767         do_hdr($self, 0, $header, $range);
 768 }
 769
 770 # RFC 2980
 771 sub cmd_xhdr ($$;$) {
 772         my ($self, $header, $range) = @_;
 773         do_hdr($self, 1, $header, $range);
 774 }
 775
 776 sub hdr_mid_prefix ($$$$$) {
 777         my ($self, $xhdr, $ng, $n, $mid) = @_;
 778         return $mid if $xhdr;
 779
 780         # HDR for RFC 3977 users
 781         if (my $self_ng = $self->{ng}) {
 782                 ($self_ng eq $ng) ? $n : '0';
 783         } else {
 784                 '0';
 785         }
 786 }
 787
 788 sub hdr_mid_response ($$$$$$) {
 789         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 790         my $res = '';
 791         if ($xhdr) {
 792                 $res .= r221 . "\r\n";
 793                 $res .= "$mid $v\r\n";
 794         } else {
 795                 $res .= r225 . "\r\n";
 796                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 797                 $res .= "$pfx $v\r\n";
 798         }
 799         res($self, $res .= '.');
 800         undef;
 801 }
 802
 803 sub cmd_xrover ($;$) {
 804         my ($self, $range) = @_;
 805         my $ng = $self->{ng} or return '412 no newsgroup selected';
 806         (defined $range && $range =~ /[<>]/) and
 807                 return '420 No article(s) selected'; # no message IDs
 808
 809         $range = $self->{article} unless defined $range;
 810         my $r = get_range($self, $range);
 811         return $r unless ref $r;
 812         my ($beg, $end) = @$r;
 813         my $mm = $ng->mm;
 814         my $over = $ng->over;
 815         more($self, '224 Overview information follows');
 816
 817         long_response($self, sub {
 818                 my $h = over_header_for($over, $beg, 'references');
 819                 more($self, "$beg $h") if defined($h);
 820                 $beg++ < $end;
 821         });
 822 }
 823
 824 sub over_line ($$$$) {
 825         my ($self, $ng, $num, $smsg) = @_;
 826         # n.b. field access and procedural calls can be
 827         # 10%-15% faster than OO method calls:
 828         my $s = join("\t", $num,
 829                 $smsg->{subject},
 830                 $smsg->{from},
 831                 PublicInbox::SearchMsg::date($smsg),
 832                 "<$smsg->{mid}>",
 833                 $smsg->{references},
 834                 $smsg->{bytes},
 835                 $smsg->{lines},
 836                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 837         utf8::encode($s);
 838         $s
 839 }
 840
 841 sub cmd_over ($;$) {
 842         my ($self, $range) = @_;
 843         if ($range && $range =~ /\A<(.+)>\z/) {
 844                 my ($ng, $n) = mid_lookup($self, $1);
 845                 defined $n or return r430;
 846                 my $smsg = $ng->over->get_art($n) or return r430;
 847                 more($self, '224 Overview information follows (multi-line)');
 848
 849                 # Only set article number column if it's the current group
 850                 my $self_ng = $self->{ng};
 851                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 852                 more($self, over_line($self, $ng, $n, $smsg));
 853                 '.';
 854         } else {
 855                 cmd_xover($self, $range);
 856         }
 857 }
 858
 859 sub cmd_xover ($;$) {
 860         my ($self, $range) = @_;
 861         $range = $self->{article} unless defined $range;
 862         my $r = get_range($self, $range);
 863         return $r unless ref $r;
 864         my ($beg, $end) = @$r;
 865         more($self, "224 Overview information follows for $beg to $end");
 866         my $over = $self->{ng}->over;
 867         my $cur = $beg;
 868         long_response($self, sub {
 869                 my $msgs = $over->query_xover($cur, $end);
 870                 my $nr = scalar @$msgs or return;
 871
 872                 # OVERVIEW.FMT
 873                 more($self, join("\r\n", map {
 874                         over_line($self, $self->{ng}, $_->{num}, $_);
 875                         } @$msgs));
 876                 $cur = $msgs->[-1]->{num} + 1;
 877         });
 878 }
 879
 880 sub cmd_starttls ($) {
 881         my ($self) = @_;
 882         my $sock = $self->{sock} or return;
 883         # RFC 4642 2.2.1
 884         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 885         my $opt = $self->{nntpd}->{accept_tls} or
 886                 return '580 can not initiate TLS negotiation';
 887         res($self, '382 Continue with TLS negotiation');
 888         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 889         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 890         undef;
 891 }
 892
 893 sub cmd_xpath ($$) {
 894         my ($self, $mid) = @_;
 895         return r501 unless $mid =~ /\A<(.+)>\z/;
 896         $mid = $1;
 897         my @paths;
 898         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 899                 my $n = $ng->mm->num_for($mid);
 900                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 901         }
 902         return '430 no such article on server' unless @paths;
 903         '223 '.join(' ', @paths);
 904 }
 905
 906 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 907
 908 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 909
 910 sub do_write ($$) {
 911         my $self = $_[0];
 912         my $done = $self->write(\($_[1]));
 913         return 0 unless $self->{sock};
 914
 915         $done;
 916 }
 917
 918 sub err ($$;@) {
 919         my ($self, $fmt, @args) = @_;
 920         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 921 }
 922
 923 sub out ($$;@) {
 924         my ($self, $fmt, @args) = @_;
 925         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 926 }
 927
 928 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 929 sub event_step {
 930         my ($self) = @_;
 931
 932         return unless $self->flush_write && $self->{sock};
 933
 934         update_idle_time($self);
 935         # only read more requests if we've drained the write buffer,
 936         # otherwise we can be buffering infinitely w/o backpressure
 937
 938         use constant LINE_MAX => 512; # RFC 977 section 2.3
 939         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 940         my $r = 1;
 941
 942         if (index($$rbuf, "\n") < 0) {
 943                 my $off = bytes::length($$rbuf);
 944                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 945         }
 946         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 947                 my $line = $1;
 948                 return $self->close if $line =~ /[[:cntrl:]]/s;
 949                 my $t0 = now();
 950                 my $fd = fileno($self->{sock});
 951                 $r = eval { process_line($self, $line) };
 952                 my $pending = $self->{wbuf} ? ' pending' : '';
 953                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 954         }
 955
 956         return $self->close if $r < 0;
 957         my $len = bytes::length($$rbuf);
 958         return $self->close if ($len >= LINE_MAX);
 959         $self->rbuf_idle($rbuf);
 960         update_idle_time($self);
 961
 962         # maybe there's more pipelined data, or we'll have
 963         # to register it for socket-readiness notifications
 964         $self->requeue unless $self->{wbuf};
 965 }
 966
 967 sub not_idle_long ($$) {
 968         my ($self, $now) = @_;
 969         my $sock = $self->{sock} or return;
 970         my $ary = $EXPMAP->{fileno($sock)} or return;
 971         my $exp_at = $ary->[0] + $EXPTIME;
 972         $exp_at > $now;
 973 }
 974
 975 # for graceful shutdown in PublicInbox::Daemon:
 976 sub busy {
 977         my ($self, $now) = @_;
 978         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
 979 }
 980
 981 1;