lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLOUT EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         event_step($_) for @$q;
  49 }
  50
  51 sub requeue ($) {
  52         push @$nextq, $_[0];
  53         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
  54 }
  55
  56 sub update_idle_time ($) {
  57         my ($self) = @_;
  58         my $sock = $self->{sock} or return;
  59         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  60 }
  61
  62 sub expire_old () {
  63         my $now = now();
  64         my $exp = $EXPTIME;
  65         my $old = $now - $exp;
  66         my $nr = 0;
  67         my $closed = 0;
  68         my %new;
  69         while (my ($fd, $v) = each %$EXPMAP) {
  70                 my ($idle_time, $nntp) = @$v;
  71                 if ($idle_time < $old) {
  72                         if ($nntp->shutdn) {
  73                                 $closed++;
  74                         } else {
  75                                 ++$nr;
  76                                 $new{$fd} = $v;
  77                         }
  78                 } else {
  79                         ++$nr;
  80                         $new{$fd} = $v;
  81                 }
  82         }
  83         $EXPMAP = \%new;
  84         if ($nr) {
  85                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  86         } else {
  87                 $expt = undef;
  88                 # noop to kick outselves out of the loop ASAP so descriptors
  89                 # really get closed
  90                 PublicInbox::EvCleanup::asap(sub {}) if $closed;
  91         }
  92 }
  93
  94 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  95
  96 sub new ($$$) {
  97         my ($class, $sock, $nntpd) = @_;
  98         my $self = fields::new($class);
  99         my $ev = EPOLLOUT | EPOLLONESHOT;
 100         my $wbuf = [];
 101         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
 102                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
 103                 $ev |= EPOLLONESHOT;
 104                 $wbuf->[0] = \&PublicInbox::DS::accept_tls_step;
 105         }
 106         $self->SUPER::new($sock, $ev);
 107         $self->{nntpd} = $nntpd;
 108         push @$wbuf, \&greet;
 109         $self->{wbuf} = $wbuf;
 110         $self->{rbuf} = '';
 111         update_idle_time($self);
 112         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 113         $self;
 114 }
 115
 116 sub args_ok ($$) {
 117         my ($cb, $argc) = @_;
 118         my $tot = prototype $cb;
 119         my ($nreq, undef) = split(';', $tot);
 120         $nreq = ($nreq =~ tr/$//) - 1;
 121         $tot = ($tot =~ tr/$//) - 1;
 122         ($argc <= $tot && $argc >= $nreq);
 123 }
 124
 125 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 126 sub process_line ($$) {
 127         my ($self, $l) = @_;
 128         my ($req, @args) = split(/[ \t]/, $l);
 129         return 1 unless defined($req); # skip blank line
 130         $req = lc($req);
 131         $req = eval {
 132                 no strict 'refs';
 133                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 134         };
 135         return res($self, '500 command not recognized') unless $req;
 136         return res($self, r501) unless args_ok($req, scalar @args);
 137
 138         my $res = eval { $req->($self, @args) };
 139         my $err = $@;
 140         if ($err && $self->{sock}) {
 141                 local $/ = "\n";
 142                 chomp($l);
 143                 err($self, 'error from: %s (%s)', $l, $err);
 144                 $res = '503 program fault - command not performed';
 145         }
 146         return 0 unless defined $res;
 147         res($self, $res);
 148 }
 149
 150 sub cmd_mode ($$) {
 151         my ($self, $arg) = @_;
 152         $arg = uc $arg;
 153         return r501 unless $arg eq 'READER';
 154         '201 Posting prohibited';
 155 }
 156
 157 sub cmd_slave ($) { '202 slave status noted' }
 158
 159 sub cmd_xgtitle ($;$) {
 160         my ($self, $wildmat) = @_;
 161         more($self, '282 list of groups and descriptions follows');
 162         list_newsgroups($self, $wildmat);
 163         '.'
 164 }
 165
 166 sub list_overview_fmt ($) {
 167         my ($self) = @_;
 168         msg_more($self, $OVERVIEW_FMT);
 169 }
 170
 171 sub list_headers ($;$) {
 172         my ($self) = @_;
 173         msg_more($self, $LIST_HEADERS);
 174 }
 175
 176 sub list_active ($;$) {
 177         my ($self, $wildmat) = @_;
 178         wildmat2re($wildmat);
 179         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 180                 $ng->{newsgroup} =~ $wildmat or next;
 181                 group_line($self, $ng);
 182         }
 183 }
 184
 185 sub list_active_times ($;$) {
 186         my ($self, $wildmat) = @_;
 187         wildmat2re($wildmat);
 188         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 189                 $ng->{newsgroup} =~ $wildmat or next;
 190                 my $c = eval { $ng->mm->created_at } || time;
 191                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 192         }
 193 }
 194
 195 sub list_newsgroups ($;$) {
 196         my ($self, $wildmat) = @_;
 197         wildmat2re($wildmat);
 198         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 199                 $ng->{newsgroup} =~ $wildmat or next;
 200                 my $d = $ng->description;
 201                 more($self, "$ng->{newsgroup} $d");
 202         }
 203 }
 204
 205 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 206 sub cmd_list ($;$$) {
 207         my ($self, @args) = @_;
 208         if (scalar @args) {
 209                 my $arg = shift @args;
 210                 $arg =~ tr/A-Z./a-z_/;
 211                 $arg = "list_$arg";
 212                 return r501 if $DISABLED{$arg};
 213
 214                 $arg = eval {
 215                         no strict 'refs';
 216                         *{$arg}{CODE};
 217                 };
 218                 return r501 unless $arg && args_ok($arg, scalar @args);
 219                 more($self, '215 information follows');
 220                 $arg->($self, @args);
 221         } else {
 222                 more($self, '215 list of newsgroups follows');
 223                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 224                         group_line($self, $ng);
 225                 }
 226         }
 227         '.'
 228 }
 229
 230 sub cmd_listgroup ($;$) {
 231         my ($self, $group) = @_;
 232         if (defined $group) {
 233                 my $res = cmd_group($self, $group);
 234                 return $res if ($res !~ /\A211 /);
 235                 more($self, $res);
 236         }
 237
 238         $self->{ng} or return '412 no newsgroup selected';
 239         my $n = 0;
 240         long_response($self, sub {
 241                 my $ary = $self->{ng}->mm->ids_after(\$n);
 242                 scalar @$ary or return;
 243                 more($self, join("\r\n", @$ary));
 244                 1;
 245         });
 246 }
 247
 248 sub parse_time ($$;$) {
 249         my ($date, $time, $gmt) = @_;
 250         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 251         if (defined $gmt) {
 252                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 253                 $gmt = 1;
 254         }
 255         my @now = $gmt ? gmtime : localtime;
 256         my ($YYYY, $MM, $DD);
 257         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 258                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 259         } else { # legacy clients send YYMMDD
 260                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 261                 my $cur_year = $now[5] + 1900;
 262                 if ($YYYY > $cur_year) {
 263                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 264                 }
 265         }
 266         if ($gmt) {
 267                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 268         } else {
 269                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 270         }
 271 }
 272
 273 sub group_line ($$) {
 274         my ($self, $ng) = @_;
 275         my ($min, $max) = $ng->mm->minmax;
 276         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 277 }
 278
 279 sub cmd_newgroups ($$$;$$) {
 280         my ($self, $date, $time, $gmt, $dists) = @_;
 281         my $ts = eval { parse_time($date, $time, $gmt) };
 282         return r501 if $@;
 283
 284         # TODO dists
 285         more($self, '231 list of new newsgroups follows');
 286         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 287                 my $c = eval { $ng->mm->created_at } || 0;
 288                 next unless $c > $ts;
 289                 group_line($self, $ng);
 290         }
 291         '.'
 292 }
 293
 294 sub wildmat2re (;$) {
 295         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 296         my %keep;
 297         my $salt = rand;
 298         my $tmp = $_[0];
 299
 300         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 301                 my $orig = $1;
 302                 my $key = sha1_hex($orig . $salt);
 303                 $orig =~ s/([^\w\-])+/\Q$1/g;
 304                 $keep{$key} = $orig;
 305                 $key
 306                 #gex;
 307         my %map = ('*' => '.*', '?' => '.' );
 308         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 309         if (scalar %keep) {
 310                 $tmp =~ s#([a-f0-9]{40})#
 311                         my $orig = $keep{$1};
 312                         defined $orig ? $orig : $1;
 313                         #ge;
 314         }
 315         $_[0] = qr/\A$tmp\z/;
 316 }
 317
 318 sub ngpat2re (;$) {
 319         return $_[0] = qr/\A\z/ unless defined $_[0];
 320         my %map = ('*' => '.*', ',' => '|');
 321         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 322         $_[0] = qr/\A(?:$_[0])\z/;
 323 }
 324
 325 sub cmd_newnews ($$$$;$$) {
 326         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 327         my $ts = eval { parse_time($date, $time, $gmt) };
 328         return r501 if $@;
 329         more($self, '230 list of new articles by message-id follows');
 330         my ($keep, $skip) = split('!', $newsgroups, 2);
 331         ngpat2re($keep);
 332         ngpat2re($skip);
 333         my @over;
 334         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 335                 $ng->{newsgroup} =~ $keep or next;
 336                 $ng->{newsgroup} =~ $skip and next;
 337                 my $over = $ng->over or next;
 338                 push @over, $over;
 339         };
 340         return '.' unless @over;
 341
 342         my $prev = 0;
 343         long_response($self, sub {
 344                 my $over = $over[0];
 345                 my $msgs = $over->query_ts($ts, $prev);
 346                 if (scalar @$msgs) {
 347                         more($self, '<' .
 348                                 join(">\r\n<", map { $_->mid } @$msgs ).
 349                                 '>');
 350                         $prev = $msgs->[-1]->{num};
 351                 } else {
 352                         shift @over;
 353                         if (@over) { # continue onto next newsgroup
 354                                 $prev = 0;
 355                                 return 1;
 356                         } else { # break out of the long response.
 357                                 return;
 358                         }
 359                 }
 360         });
 361 }
 362
 363 sub cmd_group ($$) {
 364         my ($self, $group) = @_;
 365         my $no_such = '411 no such news group';
 366         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 367
 368         $self->{ng} = $ng;
 369         my ($min, $max) = $ng->mm->minmax;
 370         $min ||= 0;
 371         $max ||= 0;
 372         $self->{article} = $min;
 373         my $est_size = $max - $min;
 374         "211 $est_size $min $max $group";
 375 }
 376
 377 sub article_adj ($$) {
 378         my ($self, $off) = @_;
 379         my $ng = $self->{ng} or return '412 no newsgroup selected';
 380
 381         my $n = $self->{article};
 382         defined $n or return '420 no current article has been selected';
 383
 384         $n += $off;
 385         my $mid = $ng->mm->mid_for($n);
 386         unless ($mid) {
 387                 $n = $off > 0 ? 'next' : 'previous';
 388                 return "421 no $n article in this group";
 389         }
 390         $self->{article} = $n;
 391         "223 $n <$mid> article retrieved - request text separately";
 392 }
 393
 394 sub cmd_next ($) { article_adj($_[0], 1) }
 395 sub cmd_last ($) { article_adj($_[0], -1) }
 396
 397 # We want to encourage using email and CC-ing everybody involved to avoid
 398 # the single-point-of-failure a single server provides.
 399 sub cmd_post ($) {
 400         my ($self) = @_;
 401         my $ng = $self->{ng};
 402         $ng ? "440 mailto:$ng->{-primary_address} to post"
 403                 : '440 posting not allowed'
 404 }
 405
 406 sub cmd_quit ($) {
 407         my ($self) = @_;
 408         res($self, '205 closing connection - goodbye!');
 409         $self->shutdn;
 410         undef;
 411 }
 412
 413 sub header_append ($$$) {
 414         my ($hdr, $k, $v) = @_;
 415         my @v = $hdr->header($k);
 416         foreach (@v) {
 417                 return if $v eq $_;
 418         }
 419         $hdr->header_set($k, @v, $v);
 420 }
 421
 422 sub xref ($$$$) {
 423         my ($self, $ng, $n, $mid) = @_;
 424         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 425
 426         # num_for is pretty cheap and sometimes we'll lookup the existence
 427         # of an article without getting even the OVER info.  In other words,
 428         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 429         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 430         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 431                 next if $ng eq $other;
 432                 my $num = eval { $other->mm->num_for($mid) } or next;
 433                 $ret .= " $other->{newsgroup}:$num";
 434         }
 435         $ret;
 436 }
 437
 438 sub set_nntp_headers ($$$$$) {
 439         my ($self, $hdr, $ng, $n, $mid) = @_;
 440
 441         # why? leafnode requires a Path: header for some inexplicable
 442         # reason.  We'll fake the shortest one possible.
 443         $hdr->header_set('Path', 'y');
 444
 445         # leafnode (and maybe other NNTP clients) have trouble dealing
 446         # with v2 messages which have multiple Message-IDs (either due
 447         # to our own content-based dedupe or buggy git-send-email versions).
 448         my @mids = $hdr->header('Message-ID');
 449         if (scalar(@mids) > 1) {
 450                 my $mid0 = "<$mid>";
 451                 $hdr->header_set('Message-ID', $mid0);
 452                 my @alt = $hdr->header('X-Alt-Message-ID');
 453                 my %seen = map { $_ => 1 } (@alt, $mid0);
 454                 foreach my $m (@mids) {
 455                         next if $seen{$m}++;
 456                         push @alt, $m;
 457                 }
 458                 $hdr->header_set('X-Alt-Message-ID', @alt);
 459         }
 460
 461         # clobber some
 462         my $xref = xref($self, $ng, $n, $mid);
 463         $hdr->header_set('Xref', $xref);
 464         $xref =~ s/:[0-9]+//g;
 465         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 466         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 467         if (my $url = $ng->base_url) {
 468                 $mid = mid_escape($mid);
 469                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 470                 header_append($hdr, 'List-Archive', "<$url>");
 471         }
 472 }
 473
 474 sub art_lookup ($$$) {
 475         my ($self, $art, $set_headers) = @_;
 476         my $ng = $self->{ng};
 477         my ($n, $mid);
 478         my $err;
 479         if (defined $art) {
 480                 if ($art =~ /\A[0-9]+\z/) {
 481                         $err = '423 no such article number in this group';
 482                         $n = int($art);
 483                         goto find_mid;
 484                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 485                         $mid = $1;
 486                         $err = r430;
 487                         $n = $ng->mm->num_for($mid) if $ng;
 488                         goto found if defined $n;
 489                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 490                                 $n = $g->mm->num_for($mid);
 491                                 if (defined $n) {
 492                                         $ng = $g;
 493                                         goto found;
 494                                 }
 495                         }
 496                         return $err;
 497                 } else {
 498                         return r501;
 499                 }
 500         } else {
 501                 $err = '420 no current article has been selected';
 502                 $n = $self->{article};
 503                 defined $n or return $err;
 504 find_mid:
 505                 $ng or return '412 no newsgroup has been selected';
 506                 $mid = $ng->mm->mid_for($n);
 507                 defined $mid or return $err;
 508         }
 509 found:
 510         my $smsg = $ng->over->get_art($n) or return $err;
 511         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 512         my $s = Email::Simple->new($msg);
 513         if ($set_headers) {
 514                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 515
 516                 # must be last
 517                 $s->body_set('') if ($set_headers == 2);
 518         }
 519         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 520 }
 521
 522 sub simple_body_write ($$) {
 523         my ($self, $s) = @_;
 524         my $body = $s->body;
 525         $s->body_set('');
 526         $body =~ s/^\./../smg;
 527         $body =~ s/(?<!\r)\n/\r\n/sg;
 528         msg_more($self, $body);
 529         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 530         '.'
 531 }
 532
 533 sub set_art {
 534         my ($self, $art) = @_;
 535         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 536 }
 537
 538 sub _header ($) {
 539         my $hdr = $_[0]->header_obj->as_string;
 540         utf8::encode($hdr);
 541         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 542
 543         # for leafnode compatibility, we need to ensure Message-ID headers
 544         # are only a single line.  We can't subclass Email::Simple::Header
 545         # and override _default_fold_at in here, either; since that won't
 546         # affect messages already in the archive.
 547         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 548
 549         $hdr
 550 }
 551
 552 sub cmd_article ($;$) {
 553         my ($self, $art) = @_;
 554         my $r = art_lookup($self, $art, 1);
 555         return $r unless ref $r;
 556         my ($n, $mid, $s) = @$r;
 557         set_art($self, $art);
 558         more($self, "220 $n <$mid> article retrieved - head and body follow");
 559         msg_more($self, _header($s));
 560         msg_more($self, "\r\n");
 561         simple_body_write($self, $s);
 562 }
 563
 564 sub cmd_head ($;$) {
 565         my ($self, $art) = @_;
 566         my $r = art_lookup($self, $art, 2);
 567         return $r unless ref $r;
 568         my ($n, $mid, $s) = @$r;
 569         set_art($self, $art);
 570         more($self, "221 $n <$mid> article retrieved - head follows");
 571         msg_more($self, _header($s));
 572         '.'
 573 }
 574
 575 sub cmd_body ($;$) {
 576         my ($self, $art) = @_;
 577         my $r = art_lookup($self, $art, 0);
 578         return $r unless ref $r;
 579         my ($n, $mid, $s) = @$r;
 580         set_art($self, $art);
 581         more($self, "222 $n <$mid> article retrieved - body follows");
 582         simple_body_write($self, $s);
 583 }
 584
 585 sub cmd_stat ($;$) {
 586         my ($self, $art) = @_;
 587         my $r = art_lookup($self, $art, 0);
 588         return $r unless ref $r;
 589         my ($n, $mid, undef) = @$r;
 590         set_art($self, $art);
 591         "223 $n <$mid> article retrieved - request text separately";
 592 }
 593
 594 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 595
 596 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 597
 598 sub cmd_help ($) {
 599         my ($self) = @_;
 600         more($self, '100 help text follows');
 601         '.'
 602 }
 603
 604 sub get_range ($$) {
 605         my ($self, $range) = @_;
 606         my $ng = $self->{ng} or return '412 no news group has been selected';
 607         defined $range or return '420 No article(s) selected';
 608         my ($beg, $end);
 609         my ($min, $max) = $ng->mm->minmax;
 610         if ($range =~ /\A([0-9]+)\z/) {
 611                 $beg = $end = $1;
 612         } elsif ($range =~ /\A([0-9]+)-\z/) {
 613                 ($beg, $end) = ($1, $max);
 614         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 615                 ($beg, $end) = ($1, $2);
 616         } else {
 617                 return r501;
 618         }
 619         $beg = $min if ($beg < $min);
 620         $end = $max if ($end > $max);
 621         return '420 No article(s) selected' if ($beg > $end);
 622         [ $beg, $end ];
 623 }
 624
 625 sub long_response ($$) {
 626         my ($self, $cb) = @_; # cb returns true if more, false if done
 627
 628         my $fd = fileno($self->{sock});
 629         defined $fd or return;
 630         # make sure we disable reading during a long response,
 631         # clients should not be sending us stuff and making us do more
 632         # work while we are stream a response to them
 633         my $t0 = now();
 634         my $long_cb; # DANGER: self-referential
 635         $long_cb = sub {
 636                 # wbuf is unset or empty, here; $cb may add to it
 637                 my $more = eval { $cb->() };
 638                 if ($@ || !$self->{sock}) { # something bad happened...
 639                         $long_cb = undef;
 640                         my $diff = now() - $t0;
 641                         if ($@) {
 642                                 err($self,
 643                                     "%s during long response[$fd] - %0.6f",
 644                                     $@, $diff);
 645                         }
 646                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 647                         $self->close;
 648                 } elsif ($more) { # $self->{wbuf}:
 649                         update_idle_time($self);
 650
 651                         # no recursion, schedule another call ASAP
 652                         # but only after all pending writes are done
 653                         my $wbuf = $self->{wbuf} ||= [];
 654                         push @$wbuf, $long_cb;
 655
 656                         # wbuf may be populated by $cb, no need to rearm if so:
 657                         requeue($self) if scalar(@$wbuf) == 1;
 658                 } else { # all done!
 659                         $long_cb = undef;
 660                         res($self, '.');
 661                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 662                         requeue($self) unless $self->{wbuf};
 663                 }
 664         };
 665         $self->write($long_cb); # kick off!
 666         undef;
 667 }
 668
 669 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 670         my ($self, $xhdr, $range) = @_;
 671
 672         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 673                 my ($ng, $n) = mid_lookup($self, $1);
 674                 return r430 unless $n;
 675                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 676         } else { # numeric range
 677                 $range = $self->{article} unless defined $range;
 678                 my $r = get_range($self, $range);
 679                 return $r unless ref $r;
 680                 my $mm = $self->{ng}->mm;
 681                 my ($beg, $end) = @$r;
 682                 more($self, $xhdr ? r221 : r225);
 683                 long_response($self, sub {
 684                         my $r = $mm->msg_range(\$beg, $end);
 685                         @$r or return;
 686                         more($self, join("\r\n", map {
 687                                 "$_->[0] <$_->[1]>"
 688                         } @$r));
 689                         1;
 690                 });
 691         }
 692 }
 693
 694 sub mid_lookup ($$) {
 695         my ($self, $mid) = @_;
 696         my $self_ng = $self->{ng};
 697         if ($self_ng) {
 698                 my $n = $self_ng->mm->num_for($mid);
 699                 return ($self_ng, $n) if defined $n;
 700         }
 701         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 702                 next if defined $self_ng && $ng eq $self_ng;
 703                 my $n = $ng->mm->num_for($mid);
 704                 return ($ng, $n) if defined $n;
 705         }
 706         (undef, undef);
 707 }
 708
 709 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 710         my ($self, $xhdr, $range) = @_;
 711
 712         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 713                 my $mid = $1;
 714                 my ($ng, $n) = mid_lookup($self, $mid);
 715                 return r430 unless $n;
 716                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 717                                 xref($self, $ng, $n, $mid));
 718         } else { # numeric range
 719                 $range = $self->{article} unless defined $range;
 720                 my $r = get_range($self, $range);
 721                 return $r unless ref $r;
 722                 my $ng = $self->{ng};
 723                 my $mm = $ng->mm;
 724                 my ($beg, $end) = @$r;
 725                 more($self, $xhdr ? r221 : r225);
 726                 long_response($self, sub {
 727                         my $r = $mm->msg_range(\$beg, $end);
 728                         @$r or return;
 729                         more($self, join("\r\n", map {
 730                                 my $num = $_->[0];
 731                                 "$num ".xref($self, $ng, $num, $_->[1]);
 732                         } @$r));
 733                         1;
 734                 });
 735         }
 736 }
 737
 738 sub over_header_for {
 739         my ($over, $num, $field) = @_;
 740         my $smsg = $over->get_art($num) or return;
 741         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 742         $smsg->{$field};
 743 }
 744
 745 sub hdr_searchmsg ($$$$) {
 746         my ($self, $xhdr, $field, $range) = @_;
 747         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 748                 my ($ng, $n) = mid_lookup($self, $1);
 749                 return r430 unless defined $n;
 750                 my $v = over_header_for($ng->over, $n, $field);
 751                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 752         } else { # numeric range
 753                 $range = $self->{article} unless defined $range;
 754                 my $over = $self->{ng}->over;
 755                 my $mm = $self->{ng}->mm;
 756                 my $r = get_range($self, $range);
 757                 return $r unless ref $r;
 758                 my ($beg, $end) = @$r;
 759                 more($self, $xhdr ? r221 : r225);
 760                 my $cur = $beg;
 761                 long_response($self, sub {
 762                         my $msgs = $over->query_xover($cur, $end);
 763                         my $nr = scalar @$msgs or return;
 764                         my $tmp = '';
 765                         foreach my $s (@$msgs) {
 766                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 767                         }
 768                         utf8::encode($tmp);
 769                         msg_more($self, $tmp);
 770                         $cur = $msgs->[-1]->{num} + 1;
 771                 });
 772         }
 773 }
 774
 775 sub do_hdr ($$$;$) {
 776         my ($self, $xhdr, $header, $range) = @_;
 777         my $sub = lc $header;
 778         if ($sub eq 'message-id') {
 779                 hdr_message_id($self, $xhdr, $range);
 780         } elsif ($sub eq 'xref') {
 781                 hdr_xref($self, $xhdr, $range);
 782         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 783                                 bytes|lines)\z/x) {
 784                 hdr_searchmsg($self, $xhdr, $sub, $range);
 785         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 786                 hdr_searchmsg($self, $xhdr, $1, $range);
 787         } else {
 788                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 789         }
 790 }
 791
 792 # RFC 3977
 793 sub cmd_hdr ($$;$) {
 794         my ($self, $header, $range) = @_;
 795         do_hdr($self, 0, $header, $range);
 796 }
 797
 798 # RFC 2980
 799 sub cmd_xhdr ($$;$) {
 800         my ($self, $header, $range) = @_;
 801         do_hdr($self, 1, $header, $range);
 802 }
 803
 804 sub hdr_mid_prefix ($$$$$) {
 805         my ($self, $xhdr, $ng, $n, $mid) = @_;
 806         return $mid if $xhdr;
 807
 808         # HDR for RFC 3977 users
 809         if (my $self_ng = $self->{ng}) {
 810                 ($self_ng eq $ng) ? $n : '0';
 811         } else {
 812                 '0';
 813         }
 814 }
 815
 816 sub hdr_mid_response ($$$$$$) {
 817         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 818         my $res = '';
 819         if ($xhdr) {
 820                 $res .= r221 . "\r\n";
 821                 $res .= "$mid $v\r\n";
 822         } else {
 823                 $res .= r225 . "\r\n";
 824                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 825                 $res .= "$pfx $v\r\n";
 826         }
 827         res($self, $res .= '.');
 828         undef;
 829 }
 830
 831 sub cmd_xrover ($;$) {
 832         my ($self, $range) = @_;
 833         my $ng = $self->{ng} or return '412 no newsgroup selected';
 834         (defined $range && $range =~ /[<>]/) and
 835                 return '420 No article(s) selected'; # no message IDs
 836
 837         $range = $self->{article} unless defined $range;
 838         my $r = get_range($self, $range);
 839         return $r unless ref $r;
 840         my ($beg, $end) = @$r;
 841         my $mm = $ng->mm;
 842         my $over = $ng->over;
 843         more($self, '224 Overview information follows');
 844
 845         long_response($self, sub {
 846                 my $h = over_header_for($over, $beg, 'references');
 847                 more($self, "$beg $h") if defined($h);
 848                 $beg++ < $end;
 849         });
 850 }
 851
 852 sub over_line ($$$$) {
 853         my ($self, $ng, $num, $smsg) = @_;
 854         # n.b. field access and procedural calls can be
 855         # 10%-15% faster than OO method calls:
 856         my $s = join("\t", $num,
 857                 $smsg->{subject},
 858                 $smsg->{from},
 859                 PublicInbox::SearchMsg::date($smsg),
 860                 "<$smsg->{mid}>",
 861                 $smsg->{references},
 862                 $smsg->{bytes},
 863                 $smsg->{lines},
 864                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 865         utf8::encode($s);
 866         $s
 867 }
 868
 869 sub cmd_over ($;$) {
 870         my ($self, $range) = @_;
 871         if ($range && $range =~ /\A<(.+)>\z/) {
 872                 my ($ng, $n) = mid_lookup($self, $1);
 873                 defined $n or return r430;
 874                 my $smsg = $ng->over->get_art($n) or return r430;
 875                 more($self, '224 Overview information follows (multi-line)');
 876
 877                 # Only set article number column if it's the current group
 878                 my $self_ng = $self->{ng};
 879                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 880                 more($self, over_line($self, $ng, $n, $smsg));
 881                 '.';
 882         } else {
 883                 cmd_xover($self, $range);
 884         }
 885 }
 886
 887 sub cmd_xover ($;$) {
 888         my ($self, $range) = @_;
 889         $range = $self->{article} unless defined $range;
 890         my $r = get_range($self, $range);
 891         return $r unless ref $r;
 892         my ($beg, $end) = @$r;
 893         more($self, "224 Overview information follows for $beg to $end");
 894         my $over = $self->{ng}->over;
 895         my $cur = $beg;
 896         long_response($self, sub {
 897                 my $msgs = $over->query_xover($cur, $end);
 898                 my $nr = scalar @$msgs or return;
 899
 900                 # OVERVIEW.FMT
 901                 more($self, join("\r\n", map {
 902                         over_line($self, $self->{ng}, $_->{num}, $_);
 903                         } @$msgs));
 904                 $cur = $msgs->[-1]->{num} + 1;
 905         });
 906 }
 907
 908 sub cmd_starttls ($) {
 909         my ($self) = @_;
 910         my $sock = $self->{sock} or return;
 911         # RFC 4642 2.2.1
 912         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 913         my $opt = $self->{nntpd}->{accept_tls} or
 914                 return '580 can not initiate TLS negotiation';
 915         res($self, '382 Continue with TLS negotiation');
 916         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 917         requeue($self) if PublicInbox::DS::accept_tls_step($self);
 918         undef;
 919 }
 920
 921 sub cmd_xpath ($$) {
 922         my ($self, $mid) = @_;
 923         return r501 unless $mid =~ /\A<(.+)>\z/;
 924         $mid = $1;
 925         my @paths;
 926         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 927                 my $n = $ng->mm->num_for($mid);
 928                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 929         }
 930         return '430 no such article on server' unless @paths;
 931         '223 '.join(' ', @paths);
 932 }
 933
 934 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 935
 936 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 937
 938 sub do_write ($$) {
 939         my $self = $_[0];
 940         my $done = $self->write(\($_[1]));
 941         return 0 unless $self->{sock};
 942
 943         $done;
 944 }
 945
 946 sub err ($$;@) {
 947         my ($self, $fmt, @args) = @_;
 948         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 949 }
 950
 951 sub out ($$;@) {
 952         my ($self, $fmt, @args) = @_;
 953         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 954 }
 955
 956 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 957 sub event_step {
 958         my ($self) = @_;
 959
 960         return unless $self->flush_write && $self->{sock};
 961
 962         update_idle_time($self);
 963         # only read more requests if we've drained the write buffer,
 964         # otherwise we can be buffering infinitely w/o backpressure
 965
 966         use constant LINE_MAX => 512; # RFC 977 section 2.3
 967         my $rbuf = \($self->{rbuf});
 968         my $r = 1;
 969
 970         if (index($$rbuf, "\n") < 0) {
 971                 my $off = bytes::length($$rbuf);
 972                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 973         }
 974         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 975                 my $line = $1;
 976                 return $self->close if $line =~ /[[:cntrl:]]/s;
 977                 my $t0 = now();
 978                 my $fd = fileno($self->{sock});
 979                 $r = eval { process_line($self, $line) };
 980                 my $pending = $self->{wbuf} ? ' pending' : '';
 981                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 982         }
 983
 984         return $self->close if $r < 0;
 985         my $len = bytes::length($$rbuf);
 986         return $self->close if ($len >= LINE_MAX);
 987         update_idle_time($self);
 988
 989         # maybe there's more pipelined data, or we'll have
 990         # to register it for socket-readiness notifications
 991         requeue($self) unless $self->{wbuf};
 992 }
 993
 994 sub not_idle_long ($$) {
 995         my ($self, $now) = @_;
 996         my $sock = $self->{sock} or return;
 997         my $ary = $EXPMAP->{fileno($sock)} or return;
 998         my $exp_at = $ary->[0] + $EXPTIME;
 999         $exp_at > $now;
1000 }
1001
1002 # for graceful shutdown in PublicInbox::Daemon:
1003 sub busy {
1004         my ($self, $now) = @_;
1005         ($self->{rbuf} ne '' || $self->{wbuf} || not_idle_long($self, $now));
1006 }
1007
1008 1;