lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n.";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         defined($res) ? res($self, $res) : 0;
  96 }
  97
  98 # The keyword argument is not used (rfc3977 5.2.2)
  99 sub cmd_capabilities ($;$) {
 100         my ($self, undef) = @_;
 101         my $res = $CAPABILITIES;
 102         if (!$self->{sock}->can('accept_SSL') &&
 103                         $self->{nntpd}->{accept_tls}) {
 104                 $res .= "STARTTLS\r\n";
 105         }
 106         $res .= '.';
 107 }
 108
 109 sub cmd_mode ($$) {
 110         my ($self, $arg) = @_;
 111         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 112 }
 113
 114 sub cmd_slave ($) { '202 slave status noted' }
 115
 116 sub cmd_xgtitle ($;$) {
 117         my ($self, $wildmat) = @_;
 118         more($self, '282 list of groups and descriptions follows');
 119         list_newsgroups($self, $wildmat);
 120 }
 121
 122 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 123
 124 sub list_headers ($;$) { $LIST_HEADERS }
 125
 126 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 127         my ($self, $groupnames) = @_;
 128         my @window = splice(@$groupnames, 0, 100) or return 0;
 129         my $ibx;
 130         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 131         for my $ngname (@window) {
 132                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 133         }
 134         scalar(@$groupnames); # continue if there's more
 135 }
 136
 137 sub list_active ($;$) { # called by cmd_list
 138         my ($self, $wildmat) = @_;
 139         wildmat2re($wildmat);
 140         long_response($self, \&list_active_i, [
 141                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 142 }
 143
 144 sub list_active_times_i {
 145         my ($self, $groupnames) = @_;
 146         my @window = splice(@$groupnames, 0, 100) or return 0;
 147         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 148         for my $ngname (@window) {
 149                 my $ibx = $groups->{$ngname} or next;
 150                 my $c = eval { $ibx->uidvalidity } // time;
 151                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 152         }
 153         scalar(@$groupnames); # continue if there's more
 154 }
 155
 156 sub list_active_times ($;$) { # called by cmd_list
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         long_response($self, \&list_active_times_i, [
 160                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 161 }
 162
 163 sub list_newsgroups_i {
 164         my ($self, $groupnames) = @_;
 165         my @window = splice(@$groupnames, 0, 100) or return 0;
 166         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 167         my $ibx;
 168         for my $ngname (@window) {
 169                 $ibx = $groups->{$ngname} and
 170                         more($self, "$ngname ".$ibx->description);
 171         }
 172         scalar(@$groupnames); # continue if there's more
 173 }
 174
 175 sub list_newsgroups ($;$) { # called by cmd_list
 176         my ($self, $wildmat) = @_;
 177         wildmat2re($wildmat);
 178         long_response($self, \&list_newsgroups_i, [
 179                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 180 }
 181
 182 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 183 sub cmd_list ($;$$) {
 184         my ($self, @args) = @_;
 185         if (scalar @args) {
 186                 my $arg = shift @args;
 187                 $arg =~ tr/A-Z./a-z_/;
 188                 my $ret = $arg eq 'active';
 189                 $arg = "list_$arg";
 190                 $arg = $self->can($arg);
 191                 return r501 unless $arg && args_ok($arg, scalar @args);
 192                 more($self, '215 information follows');
 193                 $arg->($self, @args);
 194         } else {
 195                 more($self, '215 list of newsgroups follows');
 196                 long_response($self, \&list_active_i, [ # copy array
 197                         @{$self->{nntpd}->{groupnames}} ]);
 198         }
 199 }
 200
 201 sub listgroup_range_i {
 202         my ($self, $beg, $end) = @_;
 203         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 204         scalar(@$r) or return;
 205         more($self, join("\r\n", map { $_->[0] } @$r));
 206         1;
 207 }
 208
 209 sub listgroup_all_i {
 210         my ($self, $num) = @_;
 211         my $ary = $self->{ng}->mm->ids_after($num);
 212         scalar(@$ary) or return;
 213         more($self, join("\r\n", @$ary));
 214         1;
 215 }
 216
 217 sub cmd_listgroup ($;$$) {
 218         my ($self, $group, $range) = @_;
 219         if (defined $group) {
 220                 my $res = cmd_group($self, $group);
 221                 return $res if ($res !~ /\A211 /);
 222                 more($self, $res);
 223         }
 224         $self->{ng} or return '412 no newsgroup selected';
 225         if (defined $range) {
 226                 my $r = get_range($self, $range);
 227                 return $r unless ref $r;
 228                 long_response($self, \&listgroup_range_i, @$r);
 229         } else { # grab every article number
 230                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 231         }
 232 }
 233
 234 sub parse_time ($$;$) {
 235         my ($date, $time, $gmt) = @_;
 236         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 237         if (defined $gmt) {
 238                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 239                 $gmt = 1;
 240         }
 241         my ($YYYY, $MM, $DD);
 242         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 243                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 244         } else { # legacy clients send YYMMDD
 245                 my $YY;
 246                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 247                 my @now = $gmt ? gmtime : localtime;
 248                 my $cur_year = $now[5] + 1900;
 249                 my $cur_cent = int($cur_year / 100) * 100;
 250                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 251                         ($YY + 1900) : ($YY + $cur_cent);
 252         }
 253         if ($gmt) {
 254                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 255         } else {
 256                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         }
 258 }
 259
 260 sub group_line ($$) {
 261         my ($self, $ng) = @_;
 262         my ($min, $max) = $ng->mm->minmax;
 263         more($self, "$ng->{newsgroup} $max $min n");
 264 }
 265
 266 sub cmd_newgroups ($$$;$$) {
 267         my ($self, $date, $time, $gmt, $dists) = @_;
 268         my $ts = eval { parse_time($date, $time, $gmt) };
 269         return r501 if $@;
 270
 271         # TODO dists
 272         more($self, '231 list of new newsgroups follows');
 273         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 274                 my $c = eval { $ng->uidvalidity } // 0;
 275                 next unless $c > $ts;
 276                 group_line($self, $ng);
 277         }
 278         '.'
 279 }
 280
 281 sub wildmat2re (;$) {
 282         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 283         my %keep;
 284         my $salt = rand;
 285         my $tmp = $_[0];
 286
 287         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 288                 my $orig = $1;
 289                 my $key = sha1_hex($orig . $salt);
 290                 $orig =~ s/([^\w\-])+/\Q$1/g;
 291                 $keep{$key} = $orig;
 292                 $key
 293                 #gex;
 294         my %map = ('*' => '.*', '?' => '.' );
 295         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 296         if (scalar %keep) {
 297                 $tmp =~ s#([a-f0-9]{40})#
 298                         my $orig = $keep{$1};
 299                         defined $orig ? $orig : $1;
 300                         #ge;
 301         }
 302         $_[0] = qr/\A$tmp\z/;
 303 }
 304
 305 sub ngpat2re (;$) {
 306         return $_[0] = qr/\A\z/ unless defined $_[0];
 307         my %map = ('*' => '.*', ',' => '|');
 308         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 309         $_[0] = qr/\A(?:$_[0])\z/;
 310 }
 311
 312 sub newnews_i {
 313         my ($self, $names, $ts, $prev) = @_;
 314         my $ngname = $names->[0];
 315         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 316                 if (my $over = $ibx->over) {
 317                         my $msgs = $over->query_ts($ts, $$prev);
 318                         if (scalar @$msgs) {
 319                                 more($self, '<' .
 320                                         join(">\r\n<",
 321                                                 map { $_->{mid} } @$msgs ) .
 322                                         '>');
 323                                 $$prev = $msgs->[-1]->{num};
 324                                 return 1; # continue on current group
 325                         }
 326                 }
 327         }
 328         shift @$names;
 329         if (@$names) { # continue onto next newsgroup
 330                 $$prev = 0;
 331                 1;
 332         } else { # all done, break out of the long_response
 333                 undef;
 334         }
 335 }
 336
 337 sub cmd_newnews ($$$$;$$) {
 338         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 339         my $ts = eval { parse_time($date, $time, $gmt) };
 340         return r501 if $@;
 341         more($self, '230 list of new articles by message-id follows');
 342         my ($keep, $skip) = split('!', $newsgroups, 2);
 343         ngpat2re($keep);
 344         ngpat2re($skip);
 345         my @names = grep(!/$skip/, grep(/$keep/,
 346                                 @{$self->{nntpd}->{groupnames}}));
 347         return '.' unless scalar(@names);
 348         my $prev = 0;
 349         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 350 }
 351
 352 sub cmd_group ($$) {
 353         my ($self, $group) = @_;
 354         my $no_such = '411 no such news group';
 355         my $nntpd = $self->{nntpd};
 356         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 357         $nntpd->idler_start;
 358
 359         $self->{ng} = $ng;
 360         my ($min, $max) = $ng->mm->minmax;
 361         $self->{article} = $min;
 362         my $est_size = $max - $min;
 363         "211 $est_size $min $max $group";
 364 }
 365
 366 sub article_adj ($$) {
 367         my ($self, $off) = @_;
 368         my $ng = $self->{ng} or return '412 no newsgroup selected';
 369
 370         my $n = $self->{article};
 371         defined $n or return '420 no current article has been selected';
 372
 373         $n += $off;
 374         my $mid = $ng->mm->mid_for($n);
 375         unless ($mid) {
 376                 $n = $off > 0 ? 'next' : 'previous';
 377                 return "421 no $n article in this group";
 378         }
 379         $self->{article} = $n;
 380         "223 $n <$mid> article retrieved - request text separately";
 381 }
 382
 383 sub cmd_next ($) { article_adj($_[0], 1) }
 384 sub cmd_last ($) { article_adj($_[0], -1) }
 385
 386 # We want to encourage using email and CC-ing everybody involved to avoid
 387 # the single-point-of-failure a single server provides.
 388 sub cmd_post ($) {
 389         my ($self) = @_;
 390         my $ng = $self->{ng};
 391         $ng ? "440 mailto:$ng->{-primary_address} to post"
 392                 : '440 posting not allowed'
 393 }
 394
 395 sub cmd_quit ($) {
 396         my ($self) = @_;
 397         res($self, '205 closing connection - goodbye!');
 398         $self->shutdn;
 399         undef;
 400 }
 401
 402 sub header_append ($$$) {
 403         my ($hdr, $k, $v) = @_;
 404         my @v = $hdr->header_raw($k);
 405         foreach (@v) {
 406                 return if $v eq $_;
 407         }
 408         $hdr->header_set($k, @v, $v);
 409 }
 410
 411 sub xref ($$$$) {
 412         my ($self, $ng, $n, $mid) = @_;
 413         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 414
 415         # num_for is pretty cheap and sometimes we'll lookup the existence
 416         # of an article without getting even the OVER info.  In other words,
 417         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 418         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 419         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 420                 next if $ng eq $other;
 421                 my $num = eval { $other->mm->num_for($mid) } or next;
 422                 $ret .= " $other->{newsgroup}:$num";
 423         }
 424         $ret;
 425 }
 426
 427 sub set_nntp_headers ($$) {
 428         my ($hdr, $smsg) = @_;
 429         my ($mid) = $smsg->{mid};
 430
 431         # leafnode (and maybe other NNTP clients) have trouble dealing
 432         # with v2 messages which have multiple Message-IDs (either due
 433         # to our own content-based dedupe or buggy git-send-email versions).
 434         my @mids = $hdr->header_raw('Message-ID');
 435         if (scalar(@mids) > 1) {
 436                 my $mid0 = "<$mid>";
 437                 $hdr->header_set('Message-ID', $mid0);
 438                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 439                 my %seen = map { $_ => 1 } (@alt, $mid0);
 440                 push(@alt, grep { !$seen{$_}++ } @mids);
 441                 $hdr->header_set('X-Alt-Message-ID', @alt);
 442         }
 443
 444         # clobber some existing headers
 445         my $ibx = $smsg->{-ibx};
 446         my $xref = xref($smsg->{nntp}, $ibx, $smsg->{num}, $mid);
 447         $hdr->header_set('Xref', $xref);
 448
 449         # RFC 5536 3.1.4
 450         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 451         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 452         $newsgroups =~ tr/ /,/;
 453         $hdr->header_set('Newsgroups', $newsgroups);
 454
 455         # *something* here is required for leafnode, try to follow
 456         # RFC 5536 3.1.5...
 457         $hdr->header_set('Path', $server_name . '!not-for-mail');
 458
 459         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 460         if (my $url = $ibx->base_url) {
 461                 $mid = mid_escape($mid);
 462                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 463                 header_append($hdr, 'List-Archive', "<$url>");
 464         }
 465 }
 466
 467 sub art_lookup ($$$) {
 468         my ($self, $art, $code) = @_;
 469         my $ng = $self->{ng};
 470         my ($n, $mid);
 471         my $err;
 472         if (defined $art) {
 473                 if ($art =~ /\A[0-9]+\z/) {
 474                         $err = '423 no such article number in this group';
 475                         $n = int($art);
 476                         goto find_mid;
 477                 } elsif ($art =~ $ONE_MSGID) {
 478                         $mid = $1;
 479                         $err = r430;
 480                         $n = $ng->mm->num_for($mid) if $ng;
 481                         goto found if defined $n;
 482                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 483                                 $n = $g->mm->num_for($mid);
 484                                 if (defined $n) {
 485                                         $ng = $g;
 486                                         goto found;
 487                                 }
 488                         }
 489                         return $err;
 490                 } else {
 491                         return r501;
 492                 }
 493         } else {
 494                 $err = '420 no current article has been selected';
 495                 $n = $self->{article};
 496                 defined $n or return $err;
 497 find_mid:
 498                 $ng or return '412 no newsgroup has been selected';
 499                 $mid = $ng->mm->mid_for($n);
 500                 defined $mid or return $err;
 501         }
 502 found:
 503         my $smsg = $ng->over->get_art($n) or return $err;
 504         $smsg->{-ibx} = $ng;
 505         if ($code == 223) { # STAT
 506                 set_art($self, $n);
 507                 "223 $n <$smsg->{mid}> article retrieved - " .
 508                         "request text separately";
 509         } else { # HEAD | BODY | ARTICLE
 510                 $smsg->{nntp} = $self;
 511                 $smsg->{nntp_code} = $code;
 512                 set_art($self, $art);
 513                 # this dereferences to `undef'
 514                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 515         }
 516 }
 517
 518 sub msg_body_write ($$) {
 519         my ($self, $msg) = @_;
 520
 521         # these can momentarily double the memory consumption :<
 522         $$msg =~ s/^\./../smg;
 523         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 524         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 525         $self->msg_more($$msg);
 526 }
 527
 528 sub set_art {
 529         my ($self, $art) = @_;
 530         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 531 }
 532
 533 sub msg_hdr_write ($$) {
 534         my ($eml, $smsg) = @_;
 535         set_nntp_headers($eml, $smsg);
 536
 537         my $hdr = $eml->{hdr} // \(my $x = '');
 538         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 539         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 540         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 541
 542         # for leafnode compatibility, we need to ensure Message-ID headers
 543         # are only a single line.
 544         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 545         $smsg->{nntp}->msg_more($$hdr);
 546 }
 547
 548 sub blob_cb { # called by git->cat_async via git_async_cat
 549         my ($bref, $oid, $type, $size, $smsg) = @_;
 550         my $self = $smsg->{nntp};
 551         my $code = $smsg->{nntp_code};
 552         if (!defined($oid)) {
 553                 # it's possible to have TOCTOU if an admin runs
 554                 # public-inbox-(edit|purge), just move onto the next message
 555                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 556                 return $self->requeue;
 557         } elsif ($smsg->{blob} ne $oid) {
 558                 $self->close;
 559                 die "BUG: $smsg->{blob} != $oid";
 560         }
 561         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 562         my $eml = PublicInbox::Eml->new($bref);
 563         if ($code == 220) {
 564                 more($self, $r .= 'head and body follow');
 565                 msg_hdr_write($eml, $smsg);
 566                 $self->msg_more("\r\n");
 567                 msg_body_write($self, $bref);
 568         } elsif ($code == 221) {
 569                 more($self, $r .= 'head follows');
 570                 msg_hdr_write($eml, $smsg);
 571         } elsif ($code == 222) {
 572                 more($self, $r .= 'body follows');
 573                 msg_body_write($self, $bref);
 574         } else {
 575                 $self->close;
 576                 die "BUG: bad code: $r";
 577         }
 578         $self->write(\".\r\n"); # flushes (includes ->zflush)
 579         $self->requeue;
 580 }
 581
 582 sub cmd_article ($;$) {
 583         my ($self, $art) = @_;
 584         art_lookup($self, $art, 220);
 585 }
 586
 587 sub cmd_head ($;$) {
 588         my ($self, $art) = @_;
 589         art_lookup($self, $art, 221);
 590 }
 591
 592 sub cmd_body ($;$) {
 593         my ($self, $art) = @_;
 594         art_lookup($self, $art, 222);
 595 }
 596
 597 sub cmd_stat ($;$) {
 598         my ($self, $art) = @_;
 599         art_lookup($self, $art, 223); # art may be msgid
 600 }
 601
 602 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 603
 604 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 605
 606 sub cmd_help ($) {
 607         my ($self) = @_;
 608         more($self, '100 help text follows');
 609         '.'
 610 }
 611
 612 sub get_range ($$) {
 613         my ($self, $range) = @_;
 614         my $ng = $self->{ng} or return '412 no news group has been selected';
 615         defined $range or return '420 No article(s) selected';
 616         my ($beg, $end);
 617         my ($min, $max) = $ng->mm->minmax;
 618         if ($range =~ /\A([0-9]+)\z/) {
 619                 $beg = $end = $1;
 620         } elsif ($range =~ /\A([0-9]+)-\z/) {
 621                 ($beg, $end) = ($1, $max);
 622         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 623                 ($beg, $end) = ($1, $2);
 624         } else {
 625                 return r501;
 626         }
 627         $beg = $min if ($beg < $min);
 628         $end = $max if ($end > $max);
 629         return '420 No article(s) selected' if ($beg > $end);
 630         [ \$beg, $end ];
 631 }
 632
 633 sub long_step {
 634         my ($self) = @_;
 635         # wbuf is unset or empty, here; {long} may add to it
 636         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 637         my $more = eval { $cb->($self, @args) };
 638         if ($@ || !$self->{sock}) { # something bad happened...
 639                 delete $self->{long_cb};
 640                 my $elapsed = now() - $t0;
 641                 if ($@) {
 642                         err($self,
 643                             "%s during long response[$fd] - %0.6f",
 644                             $@, $elapsed);
 645                 }
 646                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 647                 $self->close;
 648         } elsif ($more) { # $self->{wbuf}:
 649                 $self->update_idle_time;
 650
 651                 # COMPRESS users all share the same DEFLATE context.
 652                 # Flush it here to ensure clients don't see
 653                 # each other's data
 654                 $self->zflush;
 655
 656                 # no recursion, schedule another call ASAP, but only after
 657                 # all pending writes are done.  autovivify wbuf:
 658                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 659
 660                 # wbuf may be populated by $cb, no need to rearm if so:
 661                 $self->requeue if $new_size == 1;
 662         } else { # all done!
 663                 delete $self->{long_cb};
 664                 res($self, '.');
 665                 my $elapsed = now() - $t0;
 666                 my $fd = fileno($self->{sock});
 667                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 668                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 669                 $self->requeue unless $wbuf && @$wbuf;
 670         }
 671 }
 672
 673 sub long_response ($$;@) {
 674         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 675
 676         my $sock = $self->{sock} or return;
 677         # make sure we disable reading during a long response,
 678         # clients should not be sending us stuff and making us do more
 679         # work while we are stream a response to them
 680         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 681         long_step($self); # kick off!
 682         undef;
 683 }
 684
 685 sub hdr_msgid_range_i {
 686         my ($self, $beg, $end) = @_;
 687         my $r = $self->{ng}->mm->msg_range($beg, $end);
 688         @$r or return;
 689         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 690         1;
 691 }
 692
 693 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 694         my ($self, $xhdr, $range) = @_;
 695
 696         if (defined $range && $range =~ $ONE_MSGID) {
 697                 my ($ng, $n) = mid_lookup($self, $1);
 698                 return r430 unless $n;
 699                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 700         } else { # numeric range
 701                 $range = $self->{article} unless defined $range;
 702                 my $r = get_range($self, $range);
 703                 return $r unless ref $r;
 704                 more($self, $xhdr ? r221 : r225);
 705                 long_response($self, \&hdr_msgid_range_i, @$r);
 706         }
 707 }
 708
 709 sub mid_lookup ($$) {
 710         my ($self, $mid) = @_;
 711         my $self_ng = $self->{ng};
 712         if ($self_ng) {
 713                 my $n = $self_ng->mm->num_for($mid);
 714                 return ($self_ng, $n) if defined $n;
 715         }
 716         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 717                 next if defined $self_ng && $ng eq $self_ng;
 718                 my $n = $ng->mm->num_for($mid);
 719                 return ($ng, $n) if defined $n;
 720         }
 721         (undef, undef);
 722 }
 723
 724 sub xref_range_i {
 725         my ($self, $beg, $end) = @_;
 726         my $ng = $self->{ng};
 727         my $r = $ng->mm->msg_range($beg, $end);
 728         @$r or return;
 729         more($self, join("\r\n", map {
 730                 my $num = $_->[0];
 731                 "$num ".xref($self, $ng, $num, $_->[1]);
 732         } @$r));
 733         1;
 734 }
 735
 736 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 737         my ($self, $xhdr, $range) = @_;
 738
 739         if (defined $range && $range =~ $ONE_MSGID) {
 740                 my $mid = $1;
 741                 my ($ng, $n) = mid_lookup($self, $mid);
 742                 return r430 unless $n;
 743                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 744                                 xref($self, $ng, $n, $mid));
 745         } else { # numeric range
 746                 $range = $self->{article} unless defined $range;
 747                 my $r = get_range($self, $range);
 748                 return $r unless ref $r;
 749                 more($self, $xhdr ? r221 : r225);
 750                 long_response($self, \&xref_range_i, @$r);
 751         }
 752 }
 753
 754 sub over_header_for {
 755         my ($over, $num, $field) = @_;
 756         my $smsg = $over->get_art($num) or return;
 757         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 758         $smsg->{$field};
 759 }
 760
 761 sub smsg_range_i {
 762         my ($self, $beg, $end, $field) = @_;
 763         my $over = $self->{ng}->over;
 764         my $msgs = $over->query_xover($$beg, $end);
 765         scalar(@$msgs) or return;
 766         my $tmp = '';
 767
 768         # ->{$field} is faster than ->$field invocations, so favor that.
 769         if ($field eq 'date') {
 770                 for my $s (@$msgs) {
 771                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 772                 }
 773         } else {
 774                 for my $s (@$msgs) {
 775                         $tmp .= "$s->{num} $s->{$field}\r\n";
 776                 }
 777         }
 778         utf8::encode($tmp);
 779         $self->msg_more($tmp);
 780         $$beg = $msgs->[-1]->{num} + 1;
 781 }
 782
 783 sub hdr_smsg ($$$$) {
 784         my ($self, $xhdr, $field, $range) = @_;
 785         if (defined $range && $range =~ $ONE_MSGID) {
 786                 my ($ng, $n) = mid_lookup($self, $1);
 787                 return r430 unless defined $n;
 788                 my $v = over_header_for($ng->over, $n, $field);
 789                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 790         } else { # numeric range
 791                 $range = $self->{article} unless defined $range;
 792                 my $r = get_range($self, $range);
 793                 return $r unless ref $r;
 794                 more($self, $xhdr ? r221 : r225);
 795                 long_response($self, \&smsg_range_i, @$r, $field);
 796         }
 797 }
 798
 799 sub do_hdr ($$$;$) {
 800         my ($self, $xhdr, $header, $range) = @_;
 801         my $sub = lc $header;
 802         if ($sub eq 'message-id') {
 803                 hdr_message_id($self, $xhdr, $range);
 804         } elsif ($sub eq 'xref') {
 805                 hdr_xref($self, $xhdr, $range);
 806         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 807                                 bytes|lines)\z/x) {
 808                 hdr_smsg($self, $xhdr, $sub, $range);
 809         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 810                 hdr_smsg($self, $xhdr, $1, $range);
 811         } else {
 812                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 813         }
 814 }
 815
 816 # RFC 3977
 817 sub cmd_hdr ($$;$) {
 818         my ($self, $header, $range) = @_;
 819         do_hdr($self, 0, $header, $range);
 820 }
 821
 822 # RFC 2980
 823 sub cmd_xhdr ($$;$) {
 824         my ($self, $header, $range) = @_;
 825         do_hdr($self, 1, $header, $range);
 826 }
 827
 828 sub hdr_mid_prefix ($$$$$) {
 829         my ($self, $xhdr, $ng, $n, $mid) = @_;
 830         return $mid if $xhdr;
 831
 832         # HDR for RFC 3977 users
 833         if (my $self_ng = $self->{ng}) {
 834                 ($self_ng eq $ng) ? $n : '0';
 835         } else {
 836                 '0';
 837         }
 838 }
 839
 840 sub hdr_mid_response ($$$$$$) {
 841         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 842         my $res = '';
 843         if ($xhdr) {
 844                 $res .= r221 . "\r\n";
 845                 $res .= "$mid $v\r\n";
 846         } else {
 847                 $res .= r225 . "\r\n";
 848                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 849                 $res .= "$pfx $v\r\n";
 850         }
 851         res($self, $res .= '.');
 852         undef;
 853 }
 854
 855 sub xrover_i {
 856         my ($self, $beg, $end) = @_;
 857         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 858         more($self, "$$beg $h") if defined($h);
 859         $$beg++ < $end;
 860 }
 861
 862 sub cmd_xrover ($;$) {
 863         my ($self, $range) = @_;
 864         my $ng = $self->{ng} or return '412 no newsgroup selected';
 865         (defined $range && $range =~ /[<>]/) and
 866                 return '420 No article(s) selected'; # no message IDs
 867
 868         $range = $self->{article} unless defined $range;
 869         my $r = get_range($self, $range);
 870         return $r unless ref $r;
 871         more($self, '224 Overview information follows');
 872         long_response($self, \&xrover_i, @$r);
 873 }
 874
 875 sub over_line ($$$$) {
 876         my ($self, $ng, $num, $smsg) = @_;
 877         # n.b. field access and procedural calls can be
 878         # 10%-15% faster than OO method calls:
 879         my $s = join("\t", $num,
 880                 $smsg->{subject},
 881                 $smsg->{from},
 882                 PublicInbox::Smsg::date($smsg),
 883                 "<$smsg->{mid}>",
 884                 $smsg->{references},
 885                 $smsg->{bytes},
 886                 $smsg->{lines},
 887                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 888         utf8::encode($s);
 889         $s
 890 }
 891
 892 sub cmd_over ($;$) {
 893         my ($self, $range) = @_;
 894         if ($range && $range =~ $ONE_MSGID) {
 895                 my ($ng, $n) = mid_lookup($self, $1);
 896                 defined $n or return r430;
 897                 my $smsg = $ng->over->get_art($n) or return r430;
 898                 more($self, '224 Overview information follows (multi-line)');
 899
 900                 # Only set article number column if it's the current group
 901                 my $self_ng = $self->{ng};
 902                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 903                 more($self, over_line($self, $ng, $n, $smsg));
 904                 '.';
 905         } else {
 906                 cmd_xover($self, $range);
 907         }
 908 }
 909
 910 sub xover_i {
 911         my ($self, $beg, $end) = @_;
 912         my $ng = $self->{ng};
 913         my $msgs = $ng->over->query_xover($$beg, $end);
 914         my $nr = scalar @$msgs or return;
 915
 916         # OVERVIEW.FMT
 917         more($self, join("\r\n", map {
 918                 over_line($self, $ng, $_->{num}, $_);
 919                 } @$msgs));
 920         $$beg = $msgs->[-1]->{num} + 1;
 921 }
 922
 923 sub cmd_xover ($;$) {
 924         my ($self, $range) = @_;
 925         $range = $self->{article} unless defined $range;
 926         my $r = get_range($self, $range);
 927         return $r unless ref $r;
 928         my ($beg, $end) = @$r;
 929         more($self, "224 Overview information follows for $$beg to $end");
 930         long_response($self, \&xover_i, @$r);
 931 }
 932
 933 sub compressed { undef }
 934
 935 sub cmd_starttls ($) {
 936         my ($self) = @_;
 937         my $sock = $self->{sock} or return;
 938         # RFC 4642 2.2.1
 939         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 940         my $opt = $self->{nntpd}->{accept_tls} or
 941                 return '580 can not initiate TLS negotiation';
 942         res($self, '382 Continue with TLS negotiation');
 943         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 944         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 945         undef;
 946 }
 947
 948 # RFC 8054
 949 sub cmd_compress ($$) {
 950         my ($self, $alg) = @_;
 951         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 952         return r502 if $self->compressed;
 953         PublicInbox::NNTPdeflate->enable($self);
 954         $self->requeue;
 955         undef
 956 }
 957
 958 sub zflush {} # overridden by NNTPdeflate
 959
 960 sub cmd_xpath ($$) {
 961         my ($self, $mid) = @_;
 962         return r501 unless $mid =~ $ONE_MSGID;
 963         $mid = $1;
 964         my @paths;
 965         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 966                 my $n = $ng->mm->num_for($mid);
 967                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 968         }
 969         return '430 no such article on server' unless @paths;
 970         '223 '.join(' ', @paths);
 971 }
 972
 973 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 974
 975 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 976
 977 sub do_write ($$) {
 978         my $self = $_[0];
 979         my $done = $self->write(\($_[1]));
 980         return 0 unless $self->{sock};
 981
 982         $done;
 983 }
 984
 985 sub err ($$;@) {
 986         my ($self, $fmt, @args) = @_;
 987         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 988 }
 989
 990 sub out ($$;@) {
 991         my ($self, $fmt, @args) = @_;
 992         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 993 }
 994
 995 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 996 sub event_step {
 997         my ($self) = @_;
 998
 999         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1000
1001         $self->update_idle_time;
1002         # only read more requests if we've drained the write buffer,
1003         # otherwise we can be buffering infinitely w/o backpressure
1004
1005         my $rbuf = $self->{rbuf} // \(my $x = '');
1006         my $line = index($$rbuf, "\n");
1007         while ($line < 0) {
1008                 return $self->close if length($$rbuf) >= LINE_MAX;
1009                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1010                 $line = index($$rbuf, "\n");
1011         }
1012         $line = substr($$rbuf, 0, $line + 1, '');
1013         $line =~ s/\r?\n\z//s;
1014         return $self->close if $line =~ /[[:cntrl:]]/s;
1015
1016         my $t0 = now();
1017         my $fd = fileno($self->{sock});
1018         my $r = eval { process_line($self, $line) };
1019         my $pending = $self->{wbuf} ? ' pending' : '';
1020         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1021         return $self->close if $r < 0;
1022         $self->rbuf_idle($rbuf);
1023         $self->update_idle_time;
1024
1025         # maybe there's more pipelined data, or we'll have
1026         # to register it for socket-readiness notifications
1027         $self->requeue unless $pending;
1028 }
1029
1030 # for graceful shutdown in PublicInbox::Daemon:
1031 sub busy {
1032         my ($self, $now) = @_;
1033         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1034 }
1035
1036 1;