lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         return 0 unless defined $res;
  96         res($self, $res);
  97 }
  98
  99 # The keyword argument is not used (rfc3977 5.2.2)
 100 sub cmd_capabilities ($;$) {
 101         my ($self, undef) = @_;
 102         my $res = $CAPABILITIES;
 103         if (!$self->{sock}->can('accept_SSL') &&
 104                         $self->{nntpd}->{accept_tls}) {
 105                 $res .= "STARTTLS\r\n";
 106         }
 107         $res .= '.';
 108 }
 109
 110 sub cmd_mode ($$) {
 111         my ($self, $arg) = @_;
 112         $arg = uc $arg;
 113         return r501 unless $arg eq 'READER';
 114         '201 Posting prohibited';
 115 }
 116
 117 sub cmd_slave ($) { '202 slave status noted' }
 118
 119 sub cmd_xgtitle ($;$) {
 120         my ($self, $wildmat) = @_;
 121         more($self, '282 list of groups and descriptions follows');
 122         list_newsgroups($self, $wildmat);
 123         '.'
 124 }
 125
 126 sub list_overview_fmt ($) {
 127         my ($self) = @_;
 128         $self->msg_more($OVERVIEW_FMT);
 129 }
 130
 131 sub list_headers ($;$) {
 132         my ($self) = @_;
 133         $self->msg_more($LIST_HEADERS);
 134 }
 135
 136 sub list_active ($;$) {
 137         my ($self, $wildmat) = @_;
 138         wildmat2re($wildmat);
 139         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 140                 $ng->{newsgroup} =~ $wildmat or next;
 141                 group_line($self, $ng);
 142         }
 143 }
 144
 145 sub list_active_times ($;$) {
 146         my ($self, $wildmat) = @_;
 147         wildmat2re($wildmat);
 148         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 149                 $ng->{newsgroup} =~ $wildmat or next;
 150                 my $c = eval { $ng->mm->created_at } || time;
 151                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 152         }
 153 }
 154
 155 sub list_newsgroups ($;$) {
 156         my ($self, $wildmat) = @_;
 157         wildmat2re($wildmat);
 158         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 159                 $ng->{newsgroup} =~ $wildmat or next;
 160                 my $d = $ng->description;
 161                 more($self, "$ng->{newsgroup} $d");
 162         }
 163 }
 164
 165 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 166 sub cmd_list ($;$$) {
 167         my ($self, @args) = @_;
 168         if (scalar @args) {
 169                 my $arg = shift @args;
 170                 $arg =~ tr/A-Z./a-z_/;
 171                 $arg = "list_$arg";
 172                 $arg = $self->can($arg);
 173                 return r501 unless $arg && args_ok($arg, scalar @args);
 174                 more($self, '215 information follows');
 175                 $arg->($self, @args);
 176         } else {
 177                 more($self, '215 list of newsgroups follows');
 178                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 179                         group_line($self, $ng);
 180                 }
 181         }
 182         '.'
 183 }
 184
 185 sub listgroup_range_i {
 186         my ($self, $beg, $end) = @_;
 187         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 188         scalar(@$r) or return;
 189         more($self, join("\r\n", map { $_->[0] } @$r));
 190         1;
 191 }
 192
 193 sub listgroup_all_i {
 194         my ($self, $num) = @_;
 195         my $ary = $self->{ng}->mm->ids_after($num);
 196         scalar(@$ary) or return;
 197         more($self, join("\r\n", @$ary));
 198         1;
 199 }
 200
 201 sub cmd_listgroup ($;$$) {
 202         my ($self, $group, $range) = @_;
 203         if (defined $group) {
 204                 my $res = cmd_group($self, $group);
 205                 return $res if ($res !~ /\A211 /);
 206                 more($self, $res);
 207         }
 208         $self->{ng} or return '412 no newsgroup selected';
 209         if (defined $range) {
 210                 my $r = get_range($self, $range);
 211                 return $r unless ref $r;
 212                 long_response($self, \&listgroup_range_i, @$r);
 213         } else { # grab every article number
 214                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 215         }
 216 }
 217
 218 sub parse_time ($$;$) {
 219         my ($date, $time, $gmt) = @_;
 220         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 221         if (defined $gmt) {
 222                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 223                 $gmt = 1;
 224         }
 225         my ($YYYY, $MM, $DD);
 226         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 227                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 228         } else { # legacy clients send YYMMDD
 229                 my $YY;
 230                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 231                 my @now = $gmt ? gmtime : localtime;
 232                 my $cur_year = $now[5] + 1900;
 233                 my $cur_cent = int($cur_year / 100) * 100;
 234                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 235                         ($YY + 1900) : ($YY + $cur_cent);
 236         }
 237         if ($gmt) {
 238                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 239         } else {
 240                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 241         }
 242 }
 243
 244 sub group_line ($$) {
 245         my ($self, $ng) = @_;
 246         my ($min, $max) = $ng->mm->minmax;
 247         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 248 }
 249
 250 sub cmd_newgroups ($$$;$$) {
 251         my ($self, $date, $time, $gmt, $dists) = @_;
 252         my $ts = eval { parse_time($date, $time, $gmt) };
 253         return r501 if $@;
 254
 255         # TODO dists
 256         more($self, '231 list of new newsgroups follows');
 257         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 258                 my $c = eval { $ng->mm->created_at } || 0;
 259                 next unless $c > $ts;
 260                 group_line($self, $ng);
 261         }
 262         '.'
 263 }
 264
 265 sub wildmat2re (;$) {
 266         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 267         my %keep;
 268         my $salt = rand;
 269         my $tmp = $_[0];
 270
 271         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 272                 my $orig = $1;
 273                 my $key = sha1_hex($orig . $salt);
 274                 $orig =~ s/([^\w\-])+/\Q$1/g;
 275                 $keep{$key} = $orig;
 276                 $key
 277                 #gex;
 278         my %map = ('*' => '.*', '?' => '.' );
 279         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 280         if (scalar %keep) {
 281                 $tmp =~ s#([a-f0-9]{40})#
 282                         my $orig = $keep{$1};
 283                         defined $orig ? $orig : $1;
 284                         #ge;
 285         }
 286         $_[0] = qr/\A$tmp\z/;
 287 }
 288
 289 sub ngpat2re (;$) {
 290         return $_[0] = qr/\A\z/ unless defined $_[0];
 291         my %map = ('*' => '.*', ',' => '|');
 292         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 293         $_[0] = qr/\A(?:$_[0])\z/;
 294 }
 295
 296 sub newnews_i {
 297         my ($self, $overs, $ts, $prev) = @_;
 298         my $over = $overs->[0];
 299         my $msgs = $over->query_ts($ts, $$prev);
 300         if (scalar @$msgs) {
 301                 more($self, '<' .
 302                         join(">\r\n<", map { $_->{mid} } @$msgs ).
 303                         '>');
 304                 $$prev = $msgs->[-1]->{num};
 305         } else {
 306                 shift @$overs;
 307                 if (@$overs) { # continue onto next newsgroup
 308                         $$prev = 0;
 309                         return 1;
 310                 } else { # break out of the long response.
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 sub cmd_newnews ($$$$;$$) {
 317         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 318         my $ts = eval { parse_time($date, $time, $gmt) };
 319         return r501 if $@;
 320         more($self, '230 list of new articles by message-id follows');
 321         my ($keep, $skip) = split('!', $newsgroups, 2);
 322         ngpat2re($keep);
 323         ngpat2re($skip);
 324         my @overs;
 325         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 326                 $ng->{newsgroup} =~ $keep or next;
 327                 $ng->{newsgroup} =~ $skip and next;
 328                 my $over = $ng->over or next;
 329                 push @overs, $over;
 330         };
 331         return '.' unless @overs;
 332
 333         my $prev = 0;
 334         long_response($self, \&newnews_i, \@overs, $ts, \$prev);
 335 }
 336
 337 sub cmd_group ($$) {
 338         my ($self, $group) = @_;
 339         my $no_such = '411 no such news group';
 340         my $nntpd = $self->{nntpd};
 341         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 342         $nntpd->idler_start;
 343
 344         $self->{ng} = $ng;
 345         my ($min, $max) = $ng->mm->minmax;
 346         $min ||= 0;
 347         $max ||= 0;
 348         $self->{article} = $min;
 349         my $est_size = $max - $min;
 350         "211 $est_size $min $max $group";
 351 }
 352
 353 sub article_adj ($$) {
 354         my ($self, $off) = @_;
 355         my $ng = $self->{ng} or return '412 no newsgroup selected';
 356
 357         my $n = $self->{article};
 358         defined $n or return '420 no current article has been selected';
 359
 360         $n += $off;
 361         my $mid = $ng->mm->mid_for($n);
 362         unless ($mid) {
 363                 $n = $off > 0 ? 'next' : 'previous';
 364                 return "421 no $n article in this group";
 365         }
 366         $self->{article} = $n;
 367         "223 $n <$mid> article retrieved - request text separately";
 368 }
 369
 370 sub cmd_next ($) { article_adj($_[0], 1) }
 371 sub cmd_last ($) { article_adj($_[0], -1) }
 372
 373 # We want to encourage using email and CC-ing everybody involved to avoid
 374 # the single-point-of-failure a single server provides.
 375 sub cmd_post ($) {
 376         my ($self) = @_;
 377         my $ng = $self->{ng};
 378         $ng ? "440 mailto:$ng->{-primary_address} to post"
 379                 : '440 posting not allowed'
 380 }
 381
 382 sub cmd_quit ($) {
 383         my ($self) = @_;
 384         res($self, '205 closing connection - goodbye!');
 385         $self->shutdn;
 386         undef;
 387 }
 388
 389 sub header_append ($$$) {
 390         my ($hdr, $k, $v) = @_;
 391         my @v = $hdr->header_raw($k);
 392         foreach (@v) {
 393                 return if $v eq $_;
 394         }
 395         $hdr->header_set($k, @v, $v);
 396 }
 397
 398 sub xref ($$$$) {
 399         my ($self, $ng, $n, $mid) = @_;
 400         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 401
 402         # num_for is pretty cheap and sometimes we'll lookup the existence
 403         # of an article without getting even the OVER info.  In other words,
 404         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 405         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 406         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 407                 next if $ng eq $other;
 408                 my $num = eval { $other->mm->num_for($mid) } or next;
 409                 $ret .= " $other->{newsgroup}:$num";
 410         }
 411         $ret;
 412 }
 413
 414 sub set_nntp_headers ($$) {
 415         my ($hdr, $smsg) = @_;
 416         my ($mid) = $smsg->{mid};
 417
 418         # leafnode (and maybe other NNTP clients) have trouble dealing
 419         # with v2 messages which have multiple Message-IDs (either due
 420         # to our own content-based dedupe or buggy git-send-email versions).
 421         my @mids = $hdr->header_raw('Message-ID');
 422         if (scalar(@mids) > 1) {
 423                 my $mid0 = "<$mid>";
 424                 $hdr->header_set('Message-ID', $mid0);
 425                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 426                 my %seen = map { $_ => 1 } (@alt, $mid0);
 427                 push(@alt, grep { !$seen{$_}++ } @mids);
 428                 $hdr->header_set('X-Alt-Message-ID', @alt);
 429         }
 430
 431         # clobber some existing headers
 432         my $ibx = $smsg->{-ibx};
 433         my $xref = xref($smsg->{nntp}, $ibx, $smsg->{num}, $mid);
 434         $hdr->header_set('Xref', $xref);
 435
 436         # RFC 5536 3.1.4
 437         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 438         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 439         $newsgroups =~ tr/ /,/;
 440         $hdr->header_set('Newsgroups', $newsgroups);
 441
 442         # *something* here is required for leafnode, try to follow
 443         # RFC 5536 3.1.5...
 444         $hdr->header_set('Path', $server_name . '!not-for-mail');
 445
 446         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 447         if (my $url = $ibx->base_url) {
 448                 $mid = mid_escape($mid);
 449                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 450                 header_append($hdr, 'List-Archive', "<$url>");
 451         }
 452 }
 453
 454 sub art_lookup ($$$) {
 455         my ($self, $art, $code) = @_;
 456         my $ng = $self->{ng};
 457         my ($n, $mid);
 458         my $err;
 459         if (defined $art) {
 460                 if ($art =~ /\A[0-9]+\z/) {
 461                         $err = '423 no such article number in this group';
 462                         $n = int($art);
 463                         goto find_mid;
 464                 } elsif ($art =~ $ONE_MSGID) {
 465                         $mid = $1;
 466                         $err = r430;
 467                         $n = $ng->mm->num_for($mid) if $ng;
 468                         goto found if defined $n;
 469                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 470                                 $n = $g->mm->num_for($mid);
 471                                 if (defined $n) {
 472                                         $ng = $g;
 473                                         goto found;
 474                                 }
 475                         }
 476                         return $err;
 477                 } else {
 478                         return r501;
 479                 }
 480         } else {
 481                 $err = '420 no current article has been selected';
 482                 $n = $self->{article};
 483                 defined $n or return $err;
 484 find_mid:
 485                 $ng or return '412 no newsgroup has been selected';
 486                 $mid = $ng->mm->mid_for($n);
 487                 defined $mid or return $err;
 488         }
 489 found:
 490         my $smsg = $ng->over->get_art($n) or return $err;
 491         $smsg->{-ibx} = $ng;
 492         if ($code == 223) { # STAT
 493                 set_art($self, $n);
 494                 "223 $n <$smsg->{mid}> article retrieved - " .
 495                         "request text separately";
 496         } else { # HEAD | BODY | ARTICLE
 497                 $smsg->{nntp} = $self;
 498                 $smsg->{nntp_code} = $code;
 499                 set_art($self, $art);
 500                 # this dereferences to `undef'
 501                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 502         }
 503 }
 504
 505 sub msg_body_write ($$) {
 506         my ($self, $msg) = @_;
 507
 508         # these can momentarily double the memory consumption :<
 509         $$msg =~ s/^\./../smg;
 510         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 511         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 512         $self->msg_more($$msg);
 513 }
 514
 515 sub set_art {
 516         my ($self, $art) = @_;
 517         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 518 }
 519
 520 sub msg_hdr_write ($$) {
 521         my ($eml, $smsg) = @_;
 522         set_nntp_headers($eml, $smsg);
 523
 524         my $hdr = $eml->{hdr} // \(my $x = '');
 525         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 526         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 527         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 528
 529         # for leafnode compatibility, we need to ensure Message-ID headers
 530         # are only a single line.
 531         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 532         $smsg->{nntp}->msg_more($$hdr);
 533 }
 534
 535 sub blob_cb { # called by git->cat_async via git_async_cat
 536         my ($bref, $oid, $type, $size, $smsg) = @_;
 537         my $self = $smsg->{nntp};
 538         my $code = $smsg->{nntp_code};
 539         if (!defined($oid)) {
 540                 # it's possible to have TOCTOU if an admin runs
 541                 # public-inbox-(edit|purge), just move onto the next message
 542                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 543                 return $self->requeue;
 544         } elsif ($smsg->{blob} ne $oid) {
 545                 $self->close;
 546                 die "BUG: $smsg->{blob} != $oid";
 547         }
 548         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 549         my $eml = PublicInbox::Eml->new($bref);
 550         if ($code == 220) {
 551                 more($self, $r .= 'head and body follow');
 552                 msg_hdr_write($eml, $smsg);
 553                 $self->msg_more("\r\n");
 554                 msg_body_write($self, $bref);
 555         } elsif ($code == 221) {
 556                 more($self, $r .= 'head follows');
 557                 msg_hdr_write($eml, $smsg);
 558         } elsif ($code == 222) {
 559                 more($self, $r .= 'body follows');
 560                 msg_body_write($self, $bref);
 561         } else {
 562                 $self->close;
 563                 die "BUG: bad code: $r";
 564         }
 565         $self->write(\".\r\n"); # flushes (includes ->zflush)
 566         $self->requeue;
 567 }
 568
 569 sub cmd_article ($;$) {
 570         my ($self, $art) = @_;
 571         art_lookup($self, $art, 220);
 572 }
 573
 574 sub cmd_head ($;$) {
 575         my ($self, $art) = @_;
 576         art_lookup($self, $art, 221);
 577 }
 578
 579 sub cmd_body ($;$) {
 580         my ($self, $art) = @_;
 581         art_lookup($self, $art, 222);
 582 }
 583
 584 sub cmd_stat ($;$) {
 585         my ($self, $art) = @_;
 586         art_lookup($self, $art, 223); # art may be msgid
 587 }
 588
 589 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 590
 591 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 592
 593 sub cmd_help ($) {
 594         my ($self) = @_;
 595         more($self, '100 help text follows');
 596         '.'
 597 }
 598
 599 sub get_range ($$) {
 600         my ($self, $range) = @_;
 601         my $ng = $self->{ng} or return '412 no news group has been selected';
 602         defined $range or return '420 No article(s) selected';
 603         my ($beg, $end);
 604         my ($min, $max) = $ng->mm->minmax;
 605         if ($range =~ /\A([0-9]+)\z/) {
 606                 $beg = $end = $1;
 607         } elsif ($range =~ /\A([0-9]+)-\z/) {
 608                 ($beg, $end) = ($1, $max);
 609         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 610                 ($beg, $end) = ($1, $2);
 611         } else {
 612                 return r501;
 613         }
 614         $beg = $min if ($beg < $min);
 615         $end = $max if ($end > $max);
 616         return '420 No article(s) selected' if ($beg > $end);
 617         [ \$beg, $end ];
 618 }
 619
 620 sub long_step {
 621         my ($self) = @_;
 622         # wbuf is unset or empty, here; {long} may add to it
 623         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 624         my $more = eval { $cb->($self, @args) };
 625         if ($@ || !$self->{sock}) { # something bad happened...
 626                 delete $self->{long_cb};
 627                 my $elapsed = now() - $t0;
 628                 if ($@) {
 629                         err($self,
 630                             "%s during long response[$fd] - %0.6f",
 631                             $@, $elapsed);
 632                 }
 633                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 634                 $self->close;
 635         } elsif ($more) { # $self->{wbuf}:
 636                 $self->update_idle_time;
 637
 638                 # COMPRESS users all share the same DEFLATE context.
 639                 # Flush it here to ensure clients don't see
 640                 # each other's data
 641                 $self->zflush;
 642
 643                 # no recursion, schedule another call ASAP, but only after
 644                 # all pending writes are done.  autovivify wbuf:
 645                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 646
 647                 # wbuf may be populated by $cb, no need to rearm if so:
 648                 $self->requeue if $new_size == 1;
 649         } else { # all done!
 650                 delete $self->{long_cb};
 651                 res($self, '.');
 652                 my $elapsed = now() - $t0;
 653                 my $fd = fileno($self->{sock});
 654                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 655                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 656                 $self->requeue unless $wbuf && @$wbuf;
 657         }
 658 }
 659
 660 sub long_response ($$;@) {
 661         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 662
 663         my $sock = $self->{sock} or return;
 664         # make sure we disable reading during a long response,
 665         # clients should not be sending us stuff and making us do more
 666         # work while we are stream a response to them
 667         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 668         long_step($self); # kick off!
 669         undef;
 670 }
 671
 672 sub hdr_msgid_range_i {
 673         my ($self, $beg, $end) = @_;
 674         my $r = $self->{ng}->mm->msg_range($beg, $end);
 675         @$r or return;
 676         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 677         1;
 678 }
 679
 680 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 681         my ($self, $xhdr, $range) = @_;
 682
 683         if (defined $range && $range =~ $ONE_MSGID) {
 684                 my ($ng, $n) = mid_lookup($self, $1);
 685                 return r430 unless $n;
 686                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 687         } else { # numeric range
 688                 $range = $self->{article} unless defined $range;
 689                 my $r = get_range($self, $range);
 690                 return $r unless ref $r;
 691                 more($self, $xhdr ? r221 : r225);
 692                 long_response($self, \&hdr_msgid_range_i, @$r);
 693         }
 694 }
 695
 696 sub mid_lookup ($$) {
 697         my ($self, $mid) = @_;
 698         my $self_ng = $self->{ng};
 699         if ($self_ng) {
 700                 my $n = $self_ng->mm->num_for($mid);
 701                 return ($self_ng, $n) if defined $n;
 702         }
 703         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 704                 next if defined $self_ng && $ng eq $self_ng;
 705                 my $n = $ng->mm->num_for($mid);
 706                 return ($ng, $n) if defined $n;
 707         }
 708         (undef, undef);
 709 }
 710
 711 sub xref_range_i {
 712         my ($self, $beg, $end) = @_;
 713         my $ng = $self->{ng};
 714         my $r = $ng->mm->msg_range($beg, $end);
 715         @$r or return;
 716         more($self, join("\r\n", map {
 717                 my $num = $_->[0];
 718                 "$num ".xref($self, $ng, $num, $_->[1]);
 719         } @$r));
 720         1;
 721 }
 722
 723 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 724         my ($self, $xhdr, $range) = @_;
 725
 726         if (defined $range && $range =~ $ONE_MSGID) {
 727                 my $mid = $1;
 728                 my ($ng, $n) = mid_lookup($self, $mid);
 729                 return r430 unless $n;
 730                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 731                                 xref($self, $ng, $n, $mid));
 732         } else { # numeric range
 733                 $range = $self->{article} unless defined $range;
 734                 my $r = get_range($self, $range);
 735                 return $r unless ref $r;
 736                 more($self, $xhdr ? r221 : r225);
 737                 long_response($self, \&xref_range_i, @$r);
 738         }
 739 }
 740
 741 sub over_header_for {
 742         my ($over, $num, $field) = @_;
 743         my $smsg = $over->get_art($num) or return;
 744         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 745         $smsg->{$field};
 746 }
 747
 748 sub smsg_range_i {
 749         my ($self, $beg, $end, $field) = @_;
 750         my $over = $self->{ng}->over;
 751         my $msgs = $over->query_xover($$beg, $end);
 752         scalar(@$msgs) or return;
 753         my $tmp = '';
 754
 755         # ->{$field} is faster than ->$field invocations, so favor that.
 756         if ($field eq 'date') {
 757                 for my $s (@$msgs) {
 758                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 759                 }
 760         } else {
 761                 for my $s (@$msgs) {
 762                         $tmp .= "$s->{num} $s->{$field}\r\n";
 763                 }
 764         }
 765         utf8::encode($tmp);
 766         $self->msg_more($tmp);
 767         $$beg = $msgs->[-1]->{num} + 1;
 768 }
 769
 770 sub hdr_smsg ($$$$) {
 771         my ($self, $xhdr, $field, $range) = @_;
 772         if (defined $range && $range =~ $ONE_MSGID) {
 773                 my ($ng, $n) = mid_lookup($self, $1);
 774                 return r430 unless defined $n;
 775                 my $v = over_header_for($ng->over, $n, $field);
 776                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 777         } else { # numeric range
 778                 $range = $self->{article} unless defined $range;
 779                 my $r = get_range($self, $range);
 780                 return $r unless ref $r;
 781                 more($self, $xhdr ? r221 : r225);
 782                 long_response($self, \&smsg_range_i, @$r, $field);
 783         }
 784 }
 785
 786 sub do_hdr ($$$;$) {
 787         my ($self, $xhdr, $header, $range) = @_;
 788         my $sub = lc $header;
 789         if ($sub eq 'message-id') {
 790                 hdr_message_id($self, $xhdr, $range);
 791         } elsif ($sub eq 'xref') {
 792                 hdr_xref($self, $xhdr, $range);
 793         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 794                                 bytes|lines)\z/x) {
 795                 hdr_smsg($self, $xhdr, $sub, $range);
 796         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 797                 hdr_smsg($self, $xhdr, $1, $range);
 798         } else {
 799                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 800         }
 801 }
 802
 803 # RFC 3977
 804 sub cmd_hdr ($$;$) {
 805         my ($self, $header, $range) = @_;
 806         do_hdr($self, 0, $header, $range);
 807 }
 808
 809 # RFC 2980
 810 sub cmd_xhdr ($$;$) {
 811         my ($self, $header, $range) = @_;
 812         do_hdr($self, 1, $header, $range);
 813 }
 814
 815 sub hdr_mid_prefix ($$$$$) {
 816         my ($self, $xhdr, $ng, $n, $mid) = @_;
 817         return $mid if $xhdr;
 818
 819         # HDR for RFC 3977 users
 820         if (my $self_ng = $self->{ng}) {
 821                 ($self_ng eq $ng) ? $n : '0';
 822         } else {
 823                 '0';
 824         }
 825 }
 826
 827 sub hdr_mid_response ($$$$$$) {
 828         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 829         my $res = '';
 830         if ($xhdr) {
 831                 $res .= r221 . "\r\n";
 832                 $res .= "$mid $v\r\n";
 833         } else {
 834                 $res .= r225 . "\r\n";
 835                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 836                 $res .= "$pfx $v\r\n";
 837         }
 838         res($self, $res .= '.');
 839         undef;
 840 }
 841
 842 sub xrover_i {
 843         my ($self, $beg, $end) = @_;
 844         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 845         more($self, "$$beg $h") if defined($h);
 846         $$beg++ < $end;
 847 }
 848
 849 sub cmd_xrover ($;$) {
 850         my ($self, $range) = @_;
 851         my $ng = $self->{ng} or return '412 no newsgroup selected';
 852         (defined $range && $range =~ /[<>]/) and
 853                 return '420 No article(s) selected'; # no message IDs
 854
 855         $range = $self->{article} unless defined $range;
 856         my $r = get_range($self, $range);
 857         return $r unless ref $r;
 858         more($self, '224 Overview information follows');
 859         long_response($self, \&xrover_i, @$r);
 860 }
 861
 862 sub over_line ($$$$) {
 863         my ($self, $ng, $num, $smsg) = @_;
 864         # n.b. field access and procedural calls can be
 865         # 10%-15% faster than OO method calls:
 866         my $s = join("\t", $num,
 867                 $smsg->{subject},
 868                 $smsg->{from},
 869                 PublicInbox::Smsg::date($smsg),
 870                 "<$smsg->{mid}>",
 871                 $smsg->{references},
 872                 $smsg->{bytes},
 873                 $smsg->{lines},
 874                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 875         utf8::encode($s);
 876         $s
 877 }
 878
 879 sub cmd_over ($;$) {
 880         my ($self, $range) = @_;
 881         if ($range && $range =~ $ONE_MSGID) {
 882                 my ($ng, $n) = mid_lookup($self, $1);
 883                 defined $n or return r430;
 884                 my $smsg = $ng->over->get_art($n) or return r430;
 885                 more($self, '224 Overview information follows (multi-line)');
 886
 887                 # Only set article number column if it's the current group
 888                 my $self_ng = $self->{ng};
 889                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 890                 more($self, over_line($self, $ng, $n, $smsg));
 891                 '.';
 892         } else {
 893                 cmd_xover($self, $range);
 894         }
 895 }
 896
 897 sub xover_i {
 898         my ($self, $beg, $end) = @_;
 899         my $ng = $self->{ng};
 900         my $msgs = $ng->over->query_xover($$beg, $end);
 901         my $nr = scalar @$msgs or return;
 902
 903         # OVERVIEW.FMT
 904         more($self, join("\r\n", map {
 905                 over_line($self, $ng, $_->{num}, $_);
 906                 } @$msgs));
 907         $$beg = $msgs->[-1]->{num} + 1;
 908 }
 909
 910 sub cmd_xover ($;$) {
 911         my ($self, $range) = @_;
 912         $range = $self->{article} unless defined $range;
 913         my $r = get_range($self, $range);
 914         return $r unless ref $r;
 915         my ($beg, $end) = @$r;
 916         more($self, "224 Overview information follows for $$beg to $end");
 917         long_response($self, \&xover_i, @$r);
 918 }
 919
 920 sub compressed { undef }
 921
 922 sub cmd_starttls ($) {
 923         my ($self) = @_;
 924         my $sock = $self->{sock} or return;
 925         # RFC 4642 2.2.1
 926         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 927         my $opt = $self->{nntpd}->{accept_tls} or
 928                 return '580 can not initiate TLS negotiation';
 929         res($self, '382 Continue with TLS negotiation');
 930         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 931         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 932         undef;
 933 }
 934
 935 # RFC 8054
 936 sub cmd_compress ($$) {
 937         my ($self, $alg) = @_;
 938         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 939         return r502 if $self->compressed;
 940         PublicInbox::NNTPdeflate->enable($self);
 941         $self->requeue;
 942         undef
 943 }
 944
 945 sub zflush {} # overridden by NNTPdeflate
 946
 947 sub cmd_xpath ($$) {
 948         my ($self, $mid) = @_;
 949         return r501 unless $mid =~ $ONE_MSGID;
 950         $mid = $1;
 951         my @paths;
 952         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 953                 my $n = $ng->mm->num_for($mid);
 954                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 955         }
 956         return '430 no such article on server' unless @paths;
 957         '223 '.join(' ', @paths);
 958 }
 959
 960 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 961
 962 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 963
 964 sub do_write ($$) {
 965         my $self = $_[0];
 966         my $done = $self->write(\($_[1]));
 967         return 0 unless $self->{sock};
 968
 969         $done;
 970 }
 971
 972 sub err ($$;@) {
 973         my ($self, $fmt, @args) = @_;
 974         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 975 }
 976
 977 sub out ($$;@) {
 978         my ($self, $fmt, @args) = @_;
 979         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 980 }
 981
 982 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 983 sub event_step {
 984         my ($self) = @_;
 985
 986         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
 987
 988         $self->update_idle_time;
 989         # only read more requests if we've drained the write buffer,
 990         # otherwise we can be buffering infinitely w/o backpressure
 991
 992         my $rbuf = $self->{rbuf} // \(my $x = '');
 993         my $line = index($$rbuf, "\n");
 994         while ($line < 0) {
 995                 return $self->close if length($$rbuf) >= LINE_MAX;
 996                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
 997                 $line = index($$rbuf, "\n");
 998         }
 999         $line = substr($$rbuf, 0, $line + 1, '');
1000         $line =~ s/\r?\n\z//s;
1001         return $self->close if $line =~ /[[:cntrl:]]/s;
1002
1003         my $t0 = now();
1004         my $fd = fileno($self->{sock});
1005         my $r = eval { process_line($self, $line) };
1006         my $pending = $self->{wbuf} ? ' pending' : '';
1007         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1008         return $self->close if $r < 0;
1009         $self->rbuf_idle($rbuf);
1010         $self->update_idle_time;
1011
1012         # maybe there's more pipelined data, or we'll have
1013         # to register it for socket-readiness notifications
1014         $self->requeue unless $pending;
1015 }
1016
1017 # for graceful shutdown in PublicInbox::Daemon:
1018 sub busy {
1019         my ($self, $now) = @_;
1020         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1021 }
1022
1023 1;