lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n.";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         defined($res) ? res($self, $res) : 0;
  96 }
  97
  98 # The keyword argument is not used (rfc3977 5.2.2)
  99 sub cmd_capabilities ($;$) {
 100         my ($self, undef) = @_;
 101         my $res = $CAPABILITIES;
 102         if (!$self->{sock}->can('accept_SSL') &&
 103                         $self->{nntpd}->{accept_tls}) {
 104                 $res .= "STARTTLS\r\n";
 105         }
 106         $res .= '.';
 107 }
 108
 109 sub cmd_mode ($$) {
 110         my ($self, $arg) = @_;
 111         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 112 }
 113
 114 sub cmd_slave ($) { '202 slave status noted' }
 115
 116 sub cmd_xgtitle ($;$) {
 117         my ($self, $wildmat) = @_;
 118         more($self, '282 list of groups and descriptions follows');
 119         list_newsgroups($self, $wildmat);
 120 }
 121
 122 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 123
 124 sub list_headers ($;$) { $LIST_HEADERS }
 125
 126 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 127         my ($self, $groupnames) = @_;
 128         my @window = splice(@$groupnames, 0, 100) or return 0;
 129         my $ibx;
 130         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 131         for my $ngname (@window) {
 132                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 133         }
 134         scalar(@$groupnames); # continue if there's more
 135 }
 136
 137 sub list_active ($;$) { # called by cmd_list
 138         my ($self, $wildmat) = @_;
 139         wildmat2re($wildmat);
 140         long_response($self, \&list_active_i, [
 141                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 142 }
 143
 144 sub list_active_times_i {
 145         my ($self, $groupnames) = @_;
 146         my @window = splice(@$groupnames, 0, 100) or return 0;
 147         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 148         for my $ngname (@window) {
 149                 my $ibx = $groups->{$ngname} or next;
 150                 my $c = eval { $ibx->uidvalidity } // time;
 151                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 152         }
 153         scalar(@$groupnames); # continue if there's more
 154 }
 155
 156 sub list_active_times ($;$) { # called by cmd_list
 157         my ($self, $wildmat) = @_;
 158         wildmat2re($wildmat);
 159         long_response($self, \&list_active_times_i, [
 160                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 161 }
 162
 163 sub list_newsgroups_i {
 164         my ($self, $groupnames) = @_;
 165         my @window = splice(@$groupnames, 0, 100) or return 0;
 166         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 167         my $ibx;
 168         for my $ngname (@window) {
 169                 $ibx = $groups->{$ngname} and
 170                         more($self, "$ngname ".$ibx->description);
 171         }
 172         scalar(@$groupnames); # continue if there's more
 173 }
 174
 175 sub list_newsgroups ($;$) { # called by cmd_list
 176         my ($self, $wildmat) = @_;
 177         wildmat2re($wildmat);
 178         long_response($self, \&list_newsgroups_i, [
 179                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 180 }
 181
 182 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 183 sub cmd_list ($;$$) {
 184         my ($self, @args) = @_;
 185         if (scalar @args) {
 186                 my $arg = shift @args;
 187                 $arg =~ tr/A-Z./a-z_/;
 188                 my $ret = $arg eq 'active';
 189                 $arg = "list_$arg";
 190                 $arg = $self->can($arg);
 191                 return r501 unless $arg && args_ok($arg, scalar @args);
 192                 more($self, '215 information follows');
 193                 $arg->($self, @args);
 194         } else {
 195                 more($self, '215 list of newsgroups follows');
 196                 long_response($self, \&list_active_i, [ # copy array
 197                         @{$self->{nntpd}->{groupnames}} ]);
 198         }
 199 }
 200
 201 sub listgroup_range_i {
 202         my ($self, $beg, $end) = @_;
 203         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 204         scalar(@$r) or return;
 205         more($self, join("\r\n", map { $_->[0] } @$r));
 206         1;
 207 }
 208
 209 sub listgroup_all_i {
 210         my ($self, $num) = @_;
 211         my $ary = $self->{ng}->mm->ids_after($num);
 212         scalar(@$ary) or return;
 213         more($self, join("\r\n", @$ary));
 214         1;
 215 }
 216
 217 sub cmd_listgroup ($;$$) {
 218         my ($self, $group, $range) = @_;
 219         if (defined $group) {
 220                 my $res = cmd_group($self, $group);
 221                 return $res if ($res !~ /\A211 /);
 222                 more($self, $res);
 223         }
 224         $self->{ng} or return '412 no newsgroup selected';
 225         if (defined $range) {
 226                 my $r = get_range($self, $range);
 227                 return $r unless ref $r;
 228                 long_response($self, \&listgroup_range_i, @$r);
 229         } else { # grab every article number
 230                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 231         }
 232 }
 233
 234 sub parse_time ($$;$) {
 235         my ($date, $time, $gmt) = @_;
 236         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 237         if (defined $gmt) {
 238                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 239                 $gmt = 1;
 240         }
 241         my ($YYYY, $MM, $DD);
 242         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 243                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 244         } else { # legacy clients send YYMMDD
 245                 my $YY;
 246                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 247                 my @now = $gmt ? gmtime : localtime;
 248                 my $cur_year = $now[5] + 1900;
 249                 my $cur_cent = int($cur_year / 100) * 100;
 250                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 251                         ($YY + 1900) : ($YY + $cur_cent);
 252         }
 253         if ($gmt) {
 254                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 255         } else {
 256                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         }
 258 }
 259
 260 sub group_line ($$) {
 261         my ($self, $ng) = @_;
 262         my ($min, $max) = $ng->mm->minmax;
 263         more($self, "$ng->{newsgroup} $max $min n");
 264 }
 265
 266 sub newgroups_i {
 267         my ($self, $ts, $i, $groupnames) = @_;
 268         my $end = $$i + 100;
 269         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 270         while ($$i < $end) {
 271                 my $ngname = $groupnames->[$$i++] // return;
 272                 my $ibx = $groups->{$ngname} or next; # expired on reload
 273                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 274                 group_line($self, $ibx);
 275         }
 276         1;
 277 }
 278
 279 sub cmd_newgroups ($$$;$$) {
 280         my ($self, $date, $time, $gmt, $dists) = @_;
 281         my $ts = eval { parse_time($date, $time, $gmt) };
 282         return r501 if $@;
 283
 284         # TODO dists
 285         more($self, '231 list of new newsgroups follows');
 286         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 287                                 $self->{nntpd}->{groupnames});
 288 }
 289
 290 sub wildmat2re (;$) {
 291         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 292         my %keep;
 293         my $salt = rand;
 294         my $tmp = $_[0];
 295
 296         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 297                 my $orig = $1;
 298                 my $key = sha1_hex($orig . $salt);
 299                 $orig =~ s/([^\w\-])+/\Q$1/g;
 300                 $keep{$key} = $orig;
 301                 $key
 302                 #gex;
 303         my %map = ('*' => '.*', '?' => '.' );
 304         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 305         if (scalar %keep) {
 306                 $tmp =~ s#([a-f0-9]{40})#
 307                         my $orig = $keep{$1};
 308                         defined $orig ? $orig : $1;
 309                         #ge;
 310         }
 311         $_[0] = qr/\A$tmp\z/;
 312 }
 313
 314 sub ngpat2re (;$) {
 315         return $_[0] = qr/\A\z/ unless defined $_[0];
 316         my %map = ('*' => '.*', ',' => '|');
 317         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 318         $_[0] = qr/\A(?:$_[0])\z/;
 319 }
 320
 321 sub newnews_i {
 322         my ($self, $names, $ts, $prev) = @_;
 323         my $ngname = $names->[0];
 324         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 325                 if (my $over = $ibx->over) {
 326                         my $msgs = $over->query_ts($ts, $$prev);
 327                         if (scalar @$msgs) {
 328                                 more($self, '<' .
 329                                         join(">\r\n<",
 330                                                 map { $_->{mid} } @$msgs ) .
 331                                         '>');
 332                                 $$prev = $msgs->[-1]->{num};
 333                                 return 1; # continue on current group
 334                         }
 335                 }
 336         }
 337         shift @$names;
 338         if (@$names) { # continue onto next newsgroup
 339                 $$prev = 0;
 340                 1;
 341         } else { # all done, break out of the long_response
 342                 undef;
 343         }
 344 }
 345
 346 sub cmd_newnews ($$$$;$$) {
 347         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 348         my $ts = eval { parse_time($date, $time, $gmt) };
 349         return r501 if $@;
 350         more($self, '230 list of new articles by message-id follows');
 351         my ($keep, $skip) = split('!', $newsgroups, 2);
 352         ngpat2re($keep);
 353         ngpat2re($skip);
 354         my @names = grep(!/$skip/, grep(/$keep/,
 355                                 @{$self->{nntpd}->{groupnames}}));
 356         return '.' unless scalar(@names);
 357         my $prev = 0;
 358         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 359 }
 360
 361 sub cmd_group ($$) {
 362         my ($self, $group) = @_;
 363         my $no_such = '411 no such news group';
 364         my $nntpd = $self->{nntpd};
 365         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 366         $nntpd->idler_start;
 367
 368         $self->{ng} = $ng;
 369         my ($min, $max) = $ng->mm->minmax;
 370         $self->{article} = $min;
 371         my $est_size = $max - $min;
 372         "211 $est_size $min $max $group";
 373 }
 374
 375 sub article_adj ($$) {
 376         my ($self, $off) = @_;
 377         my $ng = $self->{ng} or return '412 no newsgroup selected';
 378
 379         my $n = $self->{article};
 380         defined $n or return '420 no current article has been selected';
 381
 382         $n += $off;
 383         my $mid = $ng->mm->mid_for($n);
 384         unless ($mid) {
 385                 $n = $off > 0 ? 'next' : 'previous';
 386                 return "421 no $n article in this group";
 387         }
 388         $self->{article} = $n;
 389         "223 $n <$mid> article retrieved - request text separately";
 390 }
 391
 392 sub cmd_next ($) { article_adj($_[0], 1) }
 393 sub cmd_last ($) { article_adj($_[0], -1) }
 394
 395 # We want to encourage using email and CC-ing everybody involved to avoid
 396 # the single-point-of-failure a single server provides.
 397 sub cmd_post ($) {
 398         my ($self) = @_;
 399         my $ng = $self->{ng};
 400         $ng ? "440 mailto:$ng->{-primary_address} to post"
 401                 : '440 posting not allowed'
 402 }
 403
 404 sub cmd_quit ($) {
 405         my ($self) = @_;
 406         res($self, '205 closing connection - goodbye!');
 407         $self->shutdn;
 408         undef;
 409 }
 410
 411 sub header_append ($$$) {
 412         my ($hdr, $k, $v) = @_;
 413         my @v = $hdr->header_raw($k);
 414         foreach (@v) {
 415                 return if $v eq $_;
 416         }
 417         $hdr->header_set($k, @v, $v);
 418 }
 419
 420 sub xref ($$$) {
 421         my ($self, $cur_ibx, $smsg) = @_;
 422         my $nntpd = $self->{nntpd};
 423         my $cur_ngname = $cur_ibx->{newsgroup};
 424         my $ret = "$nntpd->{servername} $cur_ngname:$smsg->{num}";
 425         if (my $ALL = $nntpd->{pi_config}->ALL) {
 426                 if (my $ary = $ALL->nntp_xref_for($cur_ibx, $smsg)) {
 427                         $ret .= join(' ', '', @$ary) if scalar(@$ary);
 428                 }
 429                 # better off wrong than slow if there's thousands of groups,
 430                 # so no fallback to the slow path below:
 431         } else { # slow path
 432                 my $mid = $smsg->{mid};
 433                 my $groups = $nntpd->{pi_config}->{-by_newsgroup};
 434                 for my $xngname (@{$nntpd->{groupnames}}) {
 435                         next if $cur_ngname eq $xngname;
 436                         my $xibx = $groups->{$xngname} or next;
 437                         my $num = eval { $xibx->mm->num_for($mid) } or next;
 438                         $ret .= " $xngname:$num";
 439                 }
 440         }
 441         $ret;
 442 }
 443
 444 sub set_nntp_headers ($$) {
 445         my ($hdr, $smsg) = @_;
 446         my ($mid) = $smsg->{mid};
 447
 448         # leafnode (and maybe other NNTP clients) have trouble dealing
 449         # with v2 messages which have multiple Message-IDs (either due
 450         # to our own content-based dedupe or buggy git-send-email versions).
 451         my @mids = $hdr->header_raw('Message-ID');
 452         if (scalar(@mids) > 1) {
 453                 my $mid0 = "<$mid>";
 454                 $hdr->header_set('Message-ID', $mid0);
 455                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 456                 my %seen = map { $_ => 1 } (@alt, $mid0);
 457                 push(@alt, grep { !$seen{$_}++ } @mids);
 458                 $hdr->header_set('X-Alt-Message-ID', @alt);
 459         }
 460
 461         # clobber some existing headers
 462         my $ibx = $smsg->{-ibx};
 463         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 464         $hdr->header_set('Xref', $xref);
 465
 466         # RFC 5536 3.1.4
 467         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 468         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 469         $newsgroups =~ tr/ /,/;
 470         $hdr->header_set('Newsgroups', $newsgroups);
 471
 472         # *something* here is required for leafnode, try to follow
 473         # RFC 5536 3.1.5...
 474         $hdr->header_set('Path', $server_name . '!not-for-mail');
 475
 476         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 477         if (my $url = $ibx->base_url) {
 478                 $mid = mid_escape($mid);
 479                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 480                 header_append($hdr, 'List-Archive', "<$url>");
 481         }
 482 }
 483
 484 sub art_lookup ($$$) {
 485         my ($self, $art, $code) = @_;
 486         my ($ibx, $n);
 487         my $err;
 488         if (defined $art) {
 489                 if ($art =~ /\A[0-9]+\z/) {
 490                         $err = '423 no such article number in this group';
 491                         $n = int($art);
 492                         goto find_ibx;
 493                 } elsif ($art =~ $ONE_MSGID) {
 494                         ($ibx, $n) = mid_lookup($self, $1);
 495                         goto found if $ibx;
 496                         return r430;
 497                 } else {
 498                         return r501;
 499                 }
 500         } else {
 501                 $err = '420 no current article has been selected';
 502                 $n = $self->{article} // return $err;
 503 find_ibx:
 504                 $ibx = $self->{ng} or
 505                                 return '412 no newsgroup has been selected';
 506         }
 507 found:
 508         my $smsg = $ibx->over->get_art($n) or return $err;
 509         $smsg->{-ibx} = $ibx;
 510         if ($code == 223) { # STAT
 511                 set_art($self, $n);
 512                 "223 $n <$smsg->{mid}> article retrieved - " .
 513                         "request text separately";
 514         } else { # HEAD | BODY | ARTICLE
 515                 $smsg->{nntp} = $self;
 516                 $smsg->{nntp_code} = $code;
 517                 set_art($self, $art);
 518                 # this dereferences to `undef'
 519                 ${git_async_cat($ibx->git, $smsg->{blob}, \&blob_cb, $smsg)};
 520         }
 521 }
 522
 523 sub msg_body_write ($$) {
 524         my ($self, $msg) = @_;
 525
 526         # these can momentarily double the memory consumption :<
 527         $$msg =~ s/^\./../smg;
 528         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 529         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 530         $self->msg_more($$msg);
 531 }
 532
 533 sub set_art {
 534         my ($self, $art) = @_;
 535         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 536 }
 537
 538 sub msg_hdr_write ($$) {
 539         my ($eml, $smsg) = @_;
 540         set_nntp_headers($eml, $smsg);
 541
 542         my $hdr = $eml->{hdr} // \(my $x = '');
 543         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 544         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 545         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 546
 547         # for leafnode compatibility, we need to ensure Message-ID headers
 548         # are only a single line.
 549         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 550         $smsg->{nntp}->msg_more($$hdr);
 551 }
 552
 553 sub blob_cb { # called by git->cat_async via git_async_cat
 554         my ($bref, $oid, $type, $size, $smsg) = @_;
 555         my $self = $smsg->{nntp};
 556         my $code = $smsg->{nntp_code};
 557         if (!defined($oid)) {
 558                 # it's possible to have TOCTOU if an admin runs
 559                 # public-inbox-(edit|purge), just move onto the next message
 560                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 561                 return $self->requeue;
 562         } elsif ($smsg->{blob} ne $oid) {
 563                 $self->close;
 564                 die "BUG: $smsg->{blob} != $oid";
 565         }
 566         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 567         my $eml = PublicInbox::Eml->new($bref);
 568         if ($code == 220) {
 569                 more($self, $r .= 'head and body follow');
 570                 msg_hdr_write($eml, $smsg);
 571                 $self->msg_more("\r\n");
 572                 msg_body_write($self, $bref);
 573         } elsif ($code == 221) {
 574                 more($self, $r .= 'head follows');
 575                 msg_hdr_write($eml, $smsg);
 576         } elsif ($code == 222) {
 577                 more($self, $r .= 'body follows');
 578                 msg_body_write($self, $bref);
 579         } else {
 580                 $self->close;
 581                 die "BUG: bad code: $r";
 582         }
 583         $self->write(\".\r\n"); # flushes (includes ->zflush)
 584         $self->requeue;
 585 }
 586
 587 sub cmd_article ($;$) {
 588         my ($self, $art) = @_;
 589         art_lookup($self, $art, 220);
 590 }
 591
 592 sub cmd_head ($;$) {
 593         my ($self, $art) = @_;
 594         art_lookup($self, $art, 221);
 595 }
 596
 597 sub cmd_body ($;$) {
 598         my ($self, $art) = @_;
 599         art_lookup($self, $art, 222);
 600 }
 601
 602 sub cmd_stat ($;$) {
 603         my ($self, $art) = @_;
 604         art_lookup($self, $art, 223); # art may be msgid
 605 }
 606
 607 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 608
 609 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 610
 611 sub cmd_help ($) {
 612         my ($self) = @_;
 613         more($self, '100 help text follows');
 614         '.'
 615 }
 616
 617 sub get_range ($$) {
 618         my ($self, $range) = @_;
 619         my $ng = $self->{ng} or return '412 no news group has been selected';
 620         defined $range or return '420 No article(s) selected';
 621         my ($beg, $end);
 622         my ($min, $max) = $ng->mm->minmax;
 623         if ($range =~ /\A([0-9]+)\z/) {
 624                 $beg = $end = $1;
 625         } elsif ($range =~ /\A([0-9]+)-\z/) {
 626                 ($beg, $end) = ($1, $max);
 627         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 628                 ($beg, $end) = ($1, $2);
 629         } else {
 630                 return r501;
 631         }
 632         $beg = $min if ($beg < $min);
 633         $end = $max if ($end > $max);
 634         return '420 No article(s) selected' if ($beg > $end);
 635         [ \$beg, $end ];
 636 }
 637
 638 sub long_step {
 639         my ($self) = @_;
 640         # wbuf is unset or empty, here; {long} may add to it
 641         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 642         my $more = eval { $cb->($self, @args) };
 643         if ($@ || !$self->{sock}) { # something bad happened...
 644                 delete $self->{long_cb};
 645                 my $elapsed = now() - $t0;
 646                 if ($@) {
 647                         err($self,
 648                             "%s during long response[$fd] - %0.6f",
 649                             $@, $elapsed);
 650                 }
 651                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 652                 $self->close;
 653         } elsif ($more) { # $self->{wbuf}:
 654                 $self->update_idle_time;
 655
 656                 # COMPRESS users all share the same DEFLATE context.
 657                 # Flush it here to ensure clients don't see
 658                 # each other's data
 659                 $self->zflush;
 660
 661                 # no recursion, schedule another call ASAP, but only after
 662                 # all pending writes are done.  autovivify wbuf:
 663                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 664
 665                 # wbuf may be populated by $cb, no need to rearm if so:
 666                 $self->requeue if $new_size == 1;
 667         } else { # all done!
 668                 delete $self->{long_cb};
 669                 res($self, '.');
 670                 my $elapsed = now() - $t0;
 671                 my $fd = fileno($self->{sock});
 672                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 673                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 674                 $self->requeue unless $wbuf && @$wbuf;
 675         }
 676 }
 677
 678 sub long_response ($$;@) {
 679         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 680
 681         my $sock = $self->{sock} or return;
 682         # make sure we disable reading during a long response,
 683         # clients should not be sending us stuff and making us do more
 684         # work while we are stream a response to them
 685         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 686         long_step($self); # kick off!
 687         undef;
 688 }
 689
 690 sub hdr_msgid_range_i {
 691         my ($self, $beg, $end) = @_;
 692         my $r = $self->{ng}->mm->msg_range($beg, $end);
 693         @$r or return;
 694         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 695         1;
 696 }
 697
 698 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 699         my ($self, $xhdr, $range) = @_;
 700
 701         if (defined $range && $range =~ $ONE_MSGID) {
 702                 my ($ng, $n) = mid_lookup($self, $1);
 703                 return r430 unless $n;
 704                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 705         } else { # numeric range
 706                 $range = $self->{article} unless defined $range;
 707                 my $r = get_range($self, $range);
 708                 return $r unless ref $r;
 709                 more($self, $xhdr ? r221 : r225);
 710                 long_response($self, \&hdr_msgid_range_i, @$r);
 711         }
 712 }
 713
 714 sub mid_lookup ($$) {
 715         my ($self, $mid) = @_;
 716         my $self_ng = $self->{ng};
 717         if ($self_ng) {
 718                 my $n = $self_ng->mm->num_for($mid);
 719                 return ($self_ng, $n) if defined $n;
 720         }
 721         my $pi_cfg = $self->{nntpd}->{pi_config};
 722         if (my $ALL = $pi_cfg->ALL) {
 723                 my ($id, $prev);
 724                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 725                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 726                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 727                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 728                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 729                                 return ($ibx, $xnum) if $ibx;
 730                                 # fall through to trying all xref3s
 731                         } else {
 732                                 warn <<EOF;
 733 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 734 EOF
 735                         }
 736                         # try all xref3s
 737                         for my $x (@$xr3) {
 738                                 my ($ngname, $xnum) = split(/:/, $x);
 739                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 740                                 return ($ibx, $xnum) if $ibx;
 741                                 warn "W: `$ngname' does not exist for #$xnum\n";
 742                         }
 743                 }
 744                 # no warning here, $mid is just invalid
 745         } else { # slow path for non-ALL users
 746                 foreach my $ibx (values %{$self->{nntpd}->{groups}}) {
 747                         next if defined $self_ng && $ibx eq $self_ng;
 748                         my $n = $ibx->mm->num_for($mid);
 749                         return ($ibx, $n) if defined $n;
 750                 }
 751         }
 752         (undef, undef);
 753 }
 754
 755 sub xref_range_i {
 756         my ($self, $beg, $end) = @_;
 757         my $ng = $self->{ng};
 758         my $msgs = $ng->over->query_xover($$beg, $end);
 759         scalar(@$msgs) or return;
 760         $$beg = $msgs->[-1]->{num} + 1;
 761         more($self, join("\r\n", map {
 762                 "$_->{num} ".xref($self, $ng, $_);
 763         } @$msgs));
 764         1;
 765 }
 766
 767 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 768         my ($self, $xhdr, $range) = @_;
 769
 770         if (defined $range && $range =~ $ONE_MSGID) {
 771                 my $mid = $1;
 772                 my ($ng, $n) = mid_lookup($self, $mid);
 773                 return r430 unless $n;
 774                 my $smsg = $ng->over->get_art($n) or return;
 775                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 776                                 xref($self, $ng, $smsg));
 777         } else { # numeric range
 778                 $range = $self->{article} unless defined $range;
 779                 my $r = get_range($self, $range);
 780                 return $r unless ref $r;
 781                 more($self, $xhdr ? r221 : r225);
 782                 long_response($self, \&xref_range_i, @$r);
 783         }
 784 }
 785
 786 sub over_header_for {
 787         my ($over, $num, $field) = @_;
 788         my $smsg = $over->get_art($num) or return;
 789         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 790         $smsg->{$field};
 791 }
 792
 793 sub smsg_range_i {
 794         my ($self, $beg, $end, $field) = @_;
 795         my $over = $self->{ng}->over;
 796         my $msgs = $over->query_xover($$beg, $end);
 797         scalar(@$msgs) or return;
 798         my $tmp = '';
 799
 800         # ->{$field} is faster than ->$field invocations, so favor that.
 801         if ($field eq 'date') {
 802                 for my $s (@$msgs) {
 803                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 804                 }
 805         } else {
 806                 for my $s (@$msgs) {
 807                         $tmp .= "$s->{num} $s->{$field}\r\n";
 808                 }
 809         }
 810         utf8::encode($tmp);
 811         $self->msg_more($tmp);
 812         $$beg = $msgs->[-1]->{num} + 1;
 813 }
 814
 815 sub hdr_smsg ($$$$) {
 816         my ($self, $xhdr, $field, $range) = @_;
 817         if (defined $range && $range =~ $ONE_MSGID) {
 818                 my ($ng, $n) = mid_lookup($self, $1);
 819                 return r430 unless defined $n;
 820                 my $v = over_header_for($ng->over, $n, $field);
 821                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 822         } else { # numeric range
 823                 $range = $self->{article} unless defined $range;
 824                 my $r = get_range($self, $range);
 825                 return $r unless ref $r;
 826                 more($self, $xhdr ? r221 : r225);
 827                 long_response($self, \&smsg_range_i, @$r, $field);
 828         }
 829 }
 830
 831 sub do_hdr ($$$;$) {
 832         my ($self, $xhdr, $header, $range) = @_;
 833         my $sub = lc $header;
 834         if ($sub eq 'message-id') {
 835                 hdr_message_id($self, $xhdr, $range);
 836         } elsif ($sub eq 'xref') {
 837                 hdr_xref($self, $xhdr, $range);
 838         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 839                                 bytes|lines)\z/x) {
 840                 hdr_smsg($self, $xhdr, $sub, $range);
 841         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 842                 hdr_smsg($self, $xhdr, $1, $range);
 843         } else {
 844                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 845         }
 846 }
 847
 848 # RFC 3977
 849 sub cmd_hdr ($$;$) {
 850         my ($self, $header, $range) = @_;
 851         do_hdr($self, 0, $header, $range);
 852 }
 853
 854 # RFC 2980
 855 sub cmd_xhdr ($$;$) {
 856         my ($self, $header, $range) = @_;
 857         do_hdr($self, 1, $header, $range);
 858 }
 859
 860 sub hdr_mid_prefix ($$$$$) {
 861         my ($self, $xhdr, $ng, $n, $mid) = @_;
 862         return $mid if $xhdr;
 863
 864         # HDR for RFC 3977 users
 865         if (my $self_ng = $self->{ng}) {
 866                 ($self_ng eq $ng) ? $n : '0';
 867         } else {
 868                 '0';
 869         }
 870 }
 871
 872 sub hdr_mid_response ($$$$$$) {
 873         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 874         my $res = '';
 875         if ($xhdr) {
 876                 $res .= r221 . "\r\n";
 877                 $res .= "$mid $v\r\n";
 878         } else {
 879                 $res .= r225 . "\r\n";
 880                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 881                 $res .= "$pfx $v\r\n";
 882         }
 883         res($self, $res .= '.');
 884         undef;
 885 }
 886
 887 sub xrover_i {
 888         my ($self, $beg, $end) = @_;
 889         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 890         more($self, "$$beg $h") if defined($h);
 891         $$beg++ < $end;
 892 }
 893
 894 sub cmd_xrover ($;$) {
 895         my ($self, $range) = @_;
 896         my $ng = $self->{ng} or return '412 no newsgroup selected';
 897         (defined $range && $range =~ /[<>]/) and
 898                 return '420 No article(s) selected'; # no message IDs
 899
 900         $range = $self->{article} unless defined $range;
 901         my $r = get_range($self, $range);
 902         return $r unless ref $r;
 903         more($self, '224 Overview information follows');
 904         long_response($self, \&xrover_i, @$r);
 905 }
 906
 907 sub over_line ($$$) {
 908         my ($self, $ng, $smsg) = @_;
 909         # n.b. field access and procedural calls can be
 910         # 10%-15% faster than OO method calls:
 911         my $s = join("\t", $smsg->{num},
 912                 $smsg->{subject},
 913                 $smsg->{from},
 914                 PublicInbox::Smsg::date($smsg),
 915                 "<$smsg->{mid}>",
 916                 $smsg->{references},
 917                 $smsg->{bytes},
 918                 $smsg->{lines},
 919                 "Xref: " . xref($self, $ng, $smsg));
 920         utf8::encode($s);
 921         $s
 922 }
 923
 924 sub cmd_over ($;$) {
 925         my ($self, $range) = @_;
 926         if ($range && $range =~ $ONE_MSGID) {
 927                 my ($ng, $n) = mid_lookup($self, $1);
 928                 defined $n or return r430;
 929                 my $smsg = $ng->over->get_art($n) or return r430;
 930                 more($self, '224 Overview information follows (multi-line)');
 931
 932                 # Only set article number column if it's the current group
 933                 my $self_ng = $self->{ng};
 934                 $smsg->{num} = 0 if (!$self_ng || $self_ng ne $ng);
 935                 more($self, over_line($self, $ng, $smsg));
 936                 '.';
 937         } else {
 938                 cmd_xover($self, $range);
 939         }
 940 }
 941
 942 sub xover_i {
 943         my ($self, $beg, $end) = @_;
 944         my $ng = $self->{ng};
 945         my $msgs = $ng->over->query_xover($$beg, $end);
 946         my $nr = scalar @$msgs or return;
 947
 948         # OVERVIEW.FMT
 949         more($self, join("\r\n", map {
 950                 over_line($self, $ng, $_);
 951                 } @$msgs));
 952         $$beg = $msgs->[-1]->{num} + 1;
 953 }
 954
 955 sub cmd_xover ($;$) {
 956         my ($self, $range) = @_;
 957         $range = $self->{article} unless defined $range;
 958         my $r = get_range($self, $range);
 959         return $r unless ref $r;
 960         my ($beg, $end) = @$r;
 961         more($self, "224 Overview information follows for $$beg to $end");
 962         long_response($self, \&xover_i, @$r);
 963 }
 964
 965 sub compressed { undef }
 966
 967 sub cmd_starttls ($) {
 968         my ($self) = @_;
 969         my $sock = $self->{sock} or return;
 970         # RFC 4642 2.2.1
 971         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 972         my $opt = $self->{nntpd}->{accept_tls} or
 973                 return '580 can not initiate TLS negotiation';
 974         res($self, '382 Continue with TLS negotiation');
 975         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 976         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 977         undef;
 978 }
 979
 980 # RFC 8054
 981 sub cmd_compress ($$) {
 982         my ($self, $alg) = @_;
 983         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 984         return r502 if $self->compressed;
 985         PublicInbox::NNTPdeflate->enable($self);
 986         $self->requeue;
 987         undef
 988 }
 989
 990 sub zflush {} # overridden by NNTPdeflate
 991
 992 sub cmd_xpath ($$) {
 993         my ($self, $mid) = @_;
 994         return r501 unless $mid =~ $ONE_MSGID;
 995         $mid = $1;
 996         my @paths;
 997         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 998                 my $n = $ng->mm->num_for($mid);
 999                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
1000         }
1001         return '430 no such article on server' unless @paths;
1002         '223 '.join(' ', @paths);
1003 }
1004
1005 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1006
1007 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1008
1009 sub do_write ($$) {
1010         my $self = $_[0];
1011         my $done = $self->write(\($_[1]));
1012         return 0 unless $self->{sock};
1013
1014         $done;
1015 }
1016
1017 sub err ($$;@) {
1018         my ($self, $fmt, @args) = @_;
1019         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1020 }
1021
1022 sub out ($$;@) {
1023         my ($self, $fmt, @args) = @_;
1024         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1025 }
1026
1027 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1028 sub event_step {
1029         my ($self) = @_;
1030
1031         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1032
1033         $self->update_idle_time;
1034         # only read more requests if we've drained the write buffer,
1035         # otherwise we can be buffering infinitely w/o backpressure
1036
1037         my $rbuf = $self->{rbuf} // \(my $x = '');
1038         my $line = index($$rbuf, "\n");
1039         while ($line < 0) {
1040                 return $self->close if length($$rbuf) >= LINE_MAX;
1041                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1042                 $line = index($$rbuf, "\n");
1043         }
1044         $line = substr($$rbuf, 0, $line + 1, '');
1045         $line =~ s/\r?\n\z//s;
1046         return $self->close if $line =~ /[[:cntrl:]]/s;
1047
1048         my $t0 = now();
1049         my $fd = fileno($self->{sock});
1050         my $r = eval { process_line($self, $line) };
1051         my $pending = $self->{wbuf} ? ' pending' : '';
1052         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1053         return $self->close if $r < 0;
1054         $self->rbuf_idle($rbuf);
1055         $self->update_idle_time;
1056
1057         # maybe there's more pipelined data, or we'll have
1058         # to register it for socket-readiness notifications
1059         $self->requeue unless $pending;
1060 }
1061
1062 # for graceful shutdown in PublicInbox::Daemon:
1063 sub busy {
1064         my ($self, $now) = @_;
1065         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1066 }
1067
1068 1;