lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng long_cb);
  10 use PublicInbox::MID qw(mid_escape);
  11 use Email::Simple;
  12 use POSIX qw(strftime);
  13 use PublicInbox::DS qw(now);
  14 use Digest::SHA qw(sha1_hex);
  15 use Time::Local qw(timegm timelocal);
  16 use constant {
  17         LINE_MAX => 512, # RFC 977 section 2.3
  18         r501 => '501 command syntax error',
  19         r502 => '502 Command unavailable',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24 };
  25 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  26 use Errno qw(EAGAIN);
  27
  28 my @OVERVIEW = qw(Subject From Date Message-ID References);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  30                 "Xref:full\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33 my $CAPABILITIES = <<"";
  34 101 Capability list:\r
  35 VERSION 2\r
  36 READER\r
  37 NEWNEWS\r
  38 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  39 HDR\r
  40 OVER\r
  41
  42 my $have_deflate;
  43
  44 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  45
  46 sub new ($$$) {
  47         my ($class, $sock, $nntpd) = @_;
  48         my $self = fields::new($class);
  49         my $ev = EPOLLIN;
  50         my $wbuf;
  51         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  52                 return CORE::close($sock) if $! != EAGAIN;
  53                 $ev = PublicInbox::TLS::epollbit();
  54                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  55         }
  56         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  57         $self->{nntpd} = $nntpd;
  58         if ($wbuf) {
  59                 $self->{wbuf} = $wbuf;
  60         } else {
  61                 greet($self);
  62         }
  63         $self->update_idle_time;
  64         $self;
  65 }
  66
  67 sub args_ok ($$) {
  68         my ($cb, $argc) = @_;
  69         my $tot = prototype $cb;
  70         my ($nreq, undef) = split(';', $tot);
  71         $nreq = ($nreq =~ tr/$//) - 1;
  72         $tot = ($tot =~ tr/$//) - 1;
  73         ($argc <= $tot && $argc >= $nreq);
  74 }
  75
  76 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  77 sub process_line ($$) {
  78         my ($self, $l) = @_;
  79         my ($req, @args) = split(/[ \t]/, $l);
  80         return 1 unless defined($req); # skip blank line
  81         $req = $self->can('cmd_'.lc($req));
  82         return res($self, '500 command not recognized') unless $req;
  83         return res($self, r501) unless args_ok($req, scalar @args);
  84
  85         my $res = eval { $req->($self, @args) };
  86         my $err = $@;
  87         if ($err && $self->{sock}) {
  88                 local $/ = "\n";
  89                 chomp($l);
  90                 err($self, 'error from: %s (%s)', $l, $err);
  91                 $res = '503 program fault - command not performed';
  92         }
  93         return 0 unless defined $res;
  94         res($self, $res);
  95 }
  96
  97 # The keyword argument is not used (rfc3977 5.2.2)
  98 sub cmd_capabilities ($;$) {
  99         my ($self, undef) = @_;
 100         my $res = $CAPABILITIES;
 101         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 102                         $self->{nntpd}->{accept_tls}) {
 103                 $res .= "STARTTLS\r\n";
 104         }
 105         $res .= '.';
 106 }
 107
 108 sub cmd_mode ($$) {
 109         my ($self, $arg) = @_;
 110         $arg = uc $arg;
 111         return r501 unless $arg eq 'READER';
 112         '201 Posting prohibited';
 113 }
 114
 115 sub cmd_slave ($) { '202 slave status noted' }
 116
 117 sub cmd_xgtitle ($;$) {
 118         my ($self, $wildmat) = @_;
 119         more($self, '282 list of groups and descriptions follows');
 120         list_newsgroups($self, $wildmat);
 121         '.'
 122 }
 123
 124 sub list_overview_fmt ($) {
 125         my ($self) = @_;
 126         $self->msg_more($OVERVIEW_FMT);
 127 }
 128
 129 sub list_headers ($;$) {
 130         my ($self) = @_;
 131         $self->msg_more($LIST_HEADERS);
 132 }
 133
 134 sub list_active ($;$) {
 135         my ($self, $wildmat) = @_;
 136         wildmat2re($wildmat);
 137         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 138                 $ng->{newsgroup} =~ $wildmat or next;
 139                 group_line($self, $ng);
 140         }
 141 }
 142
 143 sub list_active_times ($;$) {
 144         my ($self, $wildmat) = @_;
 145         wildmat2re($wildmat);
 146         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 147                 $ng->{newsgroup} =~ $wildmat or next;
 148                 my $c = eval { $ng->mm->created_at } || time;
 149                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 150         }
 151 }
 152
 153 sub list_newsgroups ($;$) {
 154         my ($self, $wildmat) = @_;
 155         wildmat2re($wildmat);
 156         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 157                 $ng->{newsgroup} =~ $wildmat or next;
 158                 my $d = $ng->description;
 159                 more($self, "$ng->{newsgroup} $d");
 160         }
 161 }
 162
 163 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 164 sub cmd_list ($;$$) {
 165         my ($self, @args) = @_;
 166         if (scalar @args) {
 167                 my $arg = shift @args;
 168                 $arg =~ tr/A-Z./a-z_/;
 169                 $arg = "list_$arg";
 170                 $arg = $self->can($arg);
 171                 return r501 unless $arg && args_ok($arg, scalar @args);
 172                 more($self, '215 information follows');
 173                 $arg->($self, @args);
 174         } else {
 175                 more($self, '215 list of newsgroups follows');
 176                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                         group_line($self, $ng);
 178                 }
 179         }
 180         '.'
 181 }
 182
 183 sub listgroup_range_i {
 184         my ($self, $beg, $end) = @_;
 185         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 186         scalar(@$r) or return;
 187         more($self, join("\r\n", map { $_->[0] } @$r));
 188         1;
 189 }
 190
 191 sub listgroup_all_i {
 192         my ($self, $num) = @_;
 193         my $ary = $self->{ng}->mm->ids_after($num);
 194         scalar(@$ary) or return;
 195         more($self, join("\r\n", @$ary));
 196         1;
 197 }
 198
 199 sub cmd_listgroup ($;$$) {
 200         my ($self, $group, $range) = @_;
 201         if (defined $group) {
 202                 my $res = cmd_group($self, $group);
 203                 return $res if ($res !~ /\A211 /);
 204                 more($self, $res);
 205         }
 206         $self->{ng} or return '412 no newsgroup selected';
 207         if (defined $range) {
 208                 my $r = get_range($self, $range);
 209                 return $r unless ref $r;
 210                 long_response($self, \&listgroup_range_i, @$r);
 211         } else { # grab every article number
 212                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 213         }
 214 }
 215
 216 sub parse_time ($$;$) {
 217         my ($date, $time, $gmt) = @_;
 218         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 219         if (defined $gmt) {
 220                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 221                 $gmt = 1;
 222         }
 223         my ($YYYY, $MM, $DD);
 224         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 225                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 226         } else { # legacy clients send YYMMDD
 227                 my $YY;
 228                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 229                 my @now = $gmt ? gmtime : localtime;
 230                 my $cur_year = $now[5] + 1900;
 231                 my $cur_cent = int($cur_year / 100) * 100;
 232                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 233                         ($YY + 1900) : ($YY + $cur_cent);
 234         }
 235         if ($gmt) {
 236                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 237         } else {
 238                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 239         }
 240 }
 241
 242 sub group_line ($$) {
 243         my ($self, $ng) = @_;
 244         my ($min, $max) = $ng->mm->minmax;
 245         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 246 }
 247
 248 sub cmd_newgroups ($$$;$$) {
 249         my ($self, $date, $time, $gmt, $dists) = @_;
 250         my $ts = eval { parse_time($date, $time, $gmt) };
 251         return r501 if $@;
 252
 253         # TODO dists
 254         more($self, '231 list of new newsgroups follows');
 255         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 256                 my $c = eval { $ng->mm->created_at } || 0;
 257                 next unless $c > $ts;
 258                 group_line($self, $ng);
 259         }
 260         '.'
 261 }
 262
 263 sub wildmat2re (;$) {
 264         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 265         my %keep;
 266         my $salt = rand;
 267         my $tmp = $_[0];
 268
 269         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 270                 my $orig = $1;
 271                 my $key = sha1_hex($orig . $salt);
 272                 $orig =~ s/([^\w\-])+/\Q$1/g;
 273                 $keep{$key} = $orig;
 274                 $key
 275                 #gex;
 276         my %map = ('*' => '.*', '?' => '.' );
 277         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 278         if (scalar %keep) {
 279                 $tmp =~ s#([a-f0-9]{40})#
 280                         my $orig = $keep{$1};
 281                         defined $orig ? $orig : $1;
 282                         #ge;
 283         }
 284         $_[0] = qr/\A$tmp\z/;
 285 }
 286
 287 sub ngpat2re (;$) {
 288         return $_[0] = qr/\A\z/ unless defined $_[0];
 289         my %map = ('*' => '.*', ',' => '|');
 290         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 291         $_[0] = qr/\A(?:$_[0])\z/;
 292 }
 293
 294 sub newnews_i {
 295         my ($self, $overs, $ts, $prev) = @_;
 296         my $over = $overs->[0];
 297         my $msgs = $over->query_ts($ts, $$prev);
 298         if (scalar @$msgs) {
 299                 more($self, '<' .
 300                         join(">\r\n<", map { $_->mid } @$msgs ).
 301                         '>');
 302                 $$prev = $msgs->[-1]->{num};
 303         } else {
 304                 shift @$overs;
 305                 if (@$overs) { # continue onto next newsgroup
 306                         $$prev = 0;
 307                         return 1;
 308                 } else { # break out of the long response.
 309                         return;
 310                 }
 311         }
 312 }
 313
 314 sub cmd_newnews ($$$$;$$) {
 315         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 316         my $ts = eval { parse_time($date, $time, $gmt) };
 317         return r501 if $@;
 318         more($self, '230 list of new articles by message-id follows');
 319         my ($keep, $skip) = split('!', $newsgroups, 2);
 320         ngpat2re($keep);
 321         ngpat2re($skip);
 322         my @overs;
 323         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 324                 $ng->{newsgroup} =~ $keep or next;
 325                 $ng->{newsgroup} =~ $skip and next;
 326                 my $over = $ng->over or next;
 327                 push @overs, $over;
 328         };
 329         return '.' unless @overs;
 330
 331         my $prev = 0;
 332         long_response($self, \&newnews_i, \@overs, $ts, \$prev);
 333 }
 334
 335 sub cmd_group ($$) {
 336         my ($self, $group) = @_;
 337         my $no_such = '411 no such news group';
 338         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 339
 340         $self->{ng} = $ng;
 341         my ($min, $max) = $ng->mm->minmax;
 342         $min ||= 0;
 343         $max ||= 0;
 344         $self->{article} = $min;
 345         my $est_size = $max - $min;
 346         "211 $est_size $min $max $group";
 347 }
 348
 349 sub article_adj ($$) {
 350         my ($self, $off) = @_;
 351         my $ng = $self->{ng} or return '412 no newsgroup selected';
 352
 353         my $n = $self->{article};
 354         defined $n or return '420 no current article has been selected';
 355
 356         $n += $off;
 357         my $mid = $ng->mm->mid_for($n);
 358         unless ($mid) {
 359                 $n = $off > 0 ? 'next' : 'previous';
 360                 return "421 no $n article in this group";
 361         }
 362         $self->{article} = $n;
 363         "223 $n <$mid> article retrieved - request text separately";
 364 }
 365
 366 sub cmd_next ($) { article_adj($_[0], 1) }
 367 sub cmd_last ($) { article_adj($_[0], -1) }
 368
 369 # We want to encourage using email and CC-ing everybody involved to avoid
 370 # the single-point-of-failure a single server provides.
 371 sub cmd_post ($) {
 372         my ($self) = @_;
 373         my $ng = $self->{ng};
 374         $ng ? "440 mailto:$ng->{-primary_address} to post"
 375                 : '440 posting not allowed'
 376 }
 377
 378 sub cmd_quit ($) {
 379         my ($self) = @_;
 380         res($self, '205 closing connection - goodbye!');
 381         $self->shutdn;
 382         undef;
 383 }
 384
 385 sub header_append ($$$) {
 386         my ($hdr, $k, $v) = @_;
 387         my @v = $hdr->header($k);
 388         foreach (@v) {
 389                 return if $v eq $_;
 390         }
 391         $hdr->header_set($k, @v, $v);
 392 }
 393
 394 sub xref ($$$$) {
 395         my ($self, $ng, $n, $mid) = @_;
 396         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 397
 398         # num_for is pretty cheap and sometimes we'll lookup the existence
 399         # of an article without getting even the OVER info.  In other words,
 400         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 401         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 402         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 403                 next if $ng eq $other;
 404                 my $num = eval { $other->mm->num_for($mid) } or next;
 405                 $ret .= " $other->{newsgroup}:$num";
 406         }
 407         $ret;
 408 }
 409
 410 sub set_nntp_headers ($$$$$) {
 411         my ($self, $hdr, $ng, $n, $mid) = @_;
 412
 413         # why? leafnode requires a Path: header for some inexplicable
 414         # reason.  We'll fake the shortest one possible.
 415         $hdr->header_set('Path', 'y');
 416
 417         # leafnode (and maybe other NNTP clients) have trouble dealing
 418         # with v2 messages which have multiple Message-IDs (either due
 419         # to our own content-based dedupe or buggy git-send-email versions).
 420         my @mids = $hdr->header('Message-ID');
 421         if (scalar(@mids) > 1) {
 422                 my $mid0 = "<$mid>";
 423                 $hdr->header_set('Message-ID', $mid0);
 424                 my @alt = $hdr->header('X-Alt-Message-ID');
 425                 my %seen = map { $_ => 1 } (@alt, $mid0);
 426                 foreach my $m (@mids) {
 427                         next if $seen{$m}++;
 428                         push @alt, $m;
 429                 }
 430                 $hdr->header_set('X-Alt-Message-ID', @alt);
 431         }
 432
 433         # clobber some
 434         my $xref = xref($self, $ng, $n, $mid);
 435         $hdr->header_set('Xref', $xref);
 436         $xref =~ s/:[0-9]+//g;
 437         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 438         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 439         if (my $url = $ng->base_url) {
 440                 $mid = mid_escape($mid);
 441                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 442                 header_append($hdr, 'List-Archive', "<$url>");
 443         }
 444 }
 445
 446 sub art_lookup ($$$) {
 447         my ($self, $art, $set_headers) = @_;
 448         my $ng = $self->{ng};
 449         my ($n, $mid);
 450         my $err;
 451         if (defined $art) {
 452                 if ($art =~ /\A[0-9]+\z/) {
 453                         $err = '423 no such article number in this group';
 454                         $n = int($art);
 455                         goto find_mid;
 456                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 457                         $mid = $1;
 458                         $err = r430;
 459                         $n = $ng->mm->num_for($mid) if $ng;
 460                         goto found if defined $n;
 461                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 462                                 $n = $g->mm->num_for($mid);
 463                                 if (defined $n) {
 464                                         $ng = $g;
 465                                         goto found;
 466                                 }
 467                         }
 468                         return $err;
 469                 } else {
 470                         return r501;
 471                 }
 472         } else {
 473                 $err = '420 no current article has been selected';
 474                 $n = $self->{article};
 475                 defined $n or return $err;
 476 find_mid:
 477                 $ng or return '412 no newsgroup has been selected';
 478                 $mid = $ng->mm->mid_for($n);
 479                 defined $mid or return $err;
 480         }
 481 found:
 482         my $smsg = $ng->over->get_art($n) or return $err;
 483         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 484
 485         # Email::Simple->new will modify $msg in-place as documented
 486         # in its manpage, so what's left is the body and we won't need
 487         # to call Email::Simple::body(), later
 488         my $hdr = Email::Simple->new($msg)->header_obj;
 489         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 490         [ $n, $mid, $msg, $hdr ];
 491 }
 492
 493 sub msg_body_write ($$) {
 494         my ($self, $msg) = @_;
 495
 496         # these can momentarily double the memory consumption :<
 497         $$msg =~ s/^\./../smg;
 498         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 499         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 500         $self->msg_more($$msg);
 501         '.'
 502 }
 503
 504 sub set_art {
 505         my ($self, $art) = @_;
 506         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 507 }
 508
 509 sub msg_hdr_write ($$$) {
 510         my ($self, $hdr, $body_follows) = @_;
 511         $hdr = $hdr->as_string;
 512         utf8::encode($hdr);
 513         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 514
 515         # for leafnode compatibility, we need to ensure Message-ID headers
 516         # are only a single line.  We can't subclass Email::Simple::Header
 517         # and override _default_fold_at in here, either; since that won't
 518         # affect messages already in the archive.
 519         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 520         $hdr .= "\r\n" if $body_follows;
 521         $self->msg_more($hdr);
 522 }
 523
 524 sub cmd_article ($;$) {
 525         my ($self, $art) = @_;
 526         my $r = art_lookup($self, $art, 1);
 527         return $r unless ref $r;
 528         my ($n, $mid, $msg, $hdr) = @$r;
 529         set_art($self, $art);
 530         more($self, "220 $n <$mid> article retrieved - head and body follow");
 531         msg_hdr_write($self, $hdr, 1);
 532         msg_body_write($self, $msg);
 533 }
 534
 535 sub cmd_head ($;$) {
 536         my ($self, $art) = @_;
 537         my $r = art_lookup($self, $art, 2);
 538         return $r unless ref $r;
 539         my ($n, $mid, undef, $hdr) = @$r;
 540         set_art($self, $art);
 541         more($self, "221 $n <$mid> article retrieved - head follows");
 542         msg_hdr_write($self, $hdr, 0);
 543         '.'
 544 }
 545
 546 sub cmd_body ($;$) {
 547         my ($self, $art) = @_;
 548         my $r = art_lookup($self, $art, 0);
 549         return $r unless ref $r;
 550         my ($n, $mid, $msg) = @$r;
 551         set_art($self, $art);
 552         more($self, "222 $n <$mid> article retrieved - body follows");
 553         msg_body_write($self, $msg);
 554 }
 555
 556 sub cmd_stat ($;$) {
 557         my ($self, $art) = @_;
 558         my $r = art_lookup($self, $art, 0);
 559         return $r unless ref $r;
 560         my ($n, $mid) = @$r;
 561         set_art($self, $art);
 562         "223 $n <$mid> article retrieved - request text separately";
 563 }
 564
 565 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 566
 567 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 568
 569 sub cmd_help ($) {
 570         my ($self) = @_;
 571         more($self, '100 help text follows');
 572         '.'
 573 }
 574
 575 sub get_range ($$) {
 576         my ($self, $range) = @_;
 577         my $ng = $self->{ng} or return '412 no news group has been selected';
 578         defined $range or return '420 No article(s) selected';
 579         my ($beg, $end);
 580         my ($min, $max) = $ng->mm->minmax;
 581         if ($range =~ /\A([0-9]+)\z/) {
 582                 $beg = $end = $1;
 583         } elsif ($range =~ /\A([0-9]+)-\z/) {
 584                 ($beg, $end) = ($1, $max);
 585         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 586                 ($beg, $end) = ($1, $2);
 587         } else {
 588                 return r501;
 589         }
 590         $beg = $min if ($beg < $min);
 591         $end = $max if ($end > $max);
 592         return '420 No article(s) selected' if ($beg > $end);
 593         [ \$beg, $end ];
 594 }
 595
 596 sub long_step {
 597         my ($self) = @_;
 598         # wbuf is unset or empty, here; {long} may add to it
 599         my ($cb, $t0, @args) = @{$self->{long_cb}};
 600         my $more = eval { $cb->($self, @args) };
 601         if ($@ || !$self->{sock}) { # something bad happened...
 602                 delete $self->{long_cb};
 603                 my $elapsed = now() - $t0;
 604                 my $fd = fileno($self->{sock});
 605                 if ($@) {
 606                         err($self,
 607                             "%s during long response[$fd] - %0.6f",
 608                             $@, $elapsed);
 609                 }
 610                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 611                 $self->close;
 612         } elsif ($more) { # $self->{wbuf}:
 613                 $self->update_idle_time;
 614
 615                 # COMPRESS users all share the same DEFLATE context.
 616                 # Flush it here to ensure clients don't see
 617                 # each other's data
 618                 $self->zflush;
 619
 620                 # no recursion, schedule another call ASAP
 621                 # but only after all pending writes are done
 622                 my $wbuf = $self->{wbuf} ||= [];
 623                 push @$wbuf, \&long_step;
 624
 625                 # wbuf may be populated by $cb, no need to rearm if so:
 626                 $self->requeue if scalar(@$wbuf) == 1;
 627         } else { # all done!
 628                 delete $self->{long_cb};
 629                 res($self, '.');
 630                 my $elapsed = now() - $t0;
 631                 my $fd = fileno($self->{sock});
 632                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 633                 my $wbuf = $self->{wbuf};
 634                 $self->requeue unless $wbuf && @$wbuf;
 635         }
 636 }
 637
 638 sub long_response ($$;@) {
 639         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 640
 641         $self->{sock} or return;
 642         # make sure we disable reading during a long response,
 643         # clients should not be sending us stuff and making us do more
 644         # work while we are stream a response to them
 645         $self->{long_cb} = [ $cb, now(), @args ];
 646         long_step($self); # kick off!
 647         undef;
 648 }
 649
 650 sub hdr_msgid_range_i {
 651         my ($self, $beg, $end) = @_;
 652         my $r = $self->{ng}->mm->msg_range($beg, $end);
 653         @$r or return;
 654         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 655         1;
 656 }
 657
 658 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 659         my ($self, $xhdr, $range) = @_;
 660
 661         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 662                 my ($ng, $n) = mid_lookup($self, $1);
 663                 return r430 unless $n;
 664                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 665         } else { # numeric range
 666                 $range = $self->{article} unless defined $range;
 667                 my $r = get_range($self, $range);
 668                 return $r unless ref $r;
 669                 more($self, $xhdr ? r221 : r225);
 670                 long_response($self, \&hdr_msgid_range_i, @$r);
 671         }
 672 }
 673
 674 sub mid_lookup ($$) {
 675         my ($self, $mid) = @_;
 676         my $self_ng = $self->{ng};
 677         if ($self_ng) {
 678                 my $n = $self_ng->mm->num_for($mid);
 679                 return ($self_ng, $n) if defined $n;
 680         }
 681         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 682                 next if defined $self_ng && $ng eq $self_ng;
 683                 my $n = $ng->mm->num_for($mid);
 684                 return ($ng, $n) if defined $n;
 685         }
 686         (undef, undef);
 687 }
 688
 689 sub xref_range_i {
 690         my ($self, $beg, $end) = @_;
 691         my $ng = $self->{ng};
 692         my $r = $ng->mm->msg_range($beg, $end);
 693         @$r or return;
 694         more($self, join("\r\n", map {
 695                 my $num = $_->[0];
 696                 "$num ".xref($self, $ng, $num, $_->[1]);
 697         } @$r));
 698         1;
 699 }
 700
 701 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 702         my ($self, $xhdr, $range) = @_;
 703
 704         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 705                 my $mid = $1;
 706                 my ($ng, $n) = mid_lookup($self, $mid);
 707                 return r430 unless $n;
 708                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 709                                 xref($self, $ng, $n, $mid));
 710         } else { # numeric range
 711                 $range = $self->{article} unless defined $range;
 712                 my $r = get_range($self, $range);
 713                 return $r unless ref $r;
 714                 more($self, $xhdr ? r221 : r225);
 715                 long_response($self, \&xref_range_i, @$r);
 716         }
 717 }
 718
 719 sub over_header_for {
 720         my ($over, $num, $field) = @_;
 721         my $smsg = $over->get_art($num) or return;
 722         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 723         $smsg->{$field};
 724 }
 725
 726 sub searchmsg_range_i {
 727         my ($self, $beg, $end, $field) = @_;
 728         my $over = $self->{ng}->over;
 729         my $msgs = $over->query_xover($$beg, $end);
 730         scalar(@$msgs) or return;
 731         my $tmp = '';
 732         foreach my $s (@$msgs) {
 733                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 734         }
 735         utf8::encode($tmp);
 736         $self->msg_more($tmp);
 737         $$beg = $msgs->[-1]->{num} + 1;
 738 }
 739
 740 sub hdr_searchmsg ($$$$) {
 741         my ($self, $xhdr, $field, $range) = @_;
 742         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 743                 my ($ng, $n) = mid_lookup($self, $1);
 744                 return r430 unless defined $n;
 745                 my $v = over_header_for($ng->over, $n, $field);
 746                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 747         } else { # numeric range
 748                 $range = $self->{article} unless defined $range;
 749                 my $r = get_range($self, $range);
 750                 return $r unless ref $r;
 751                 more($self, $xhdr ? r221 : r225);
 752                 long_response($self, \&searchmsg_range_i, @$r, $field);
 753         }
 754 }
 755
 756 sub do_hdr ($$$;$) {
 757         my ($self, $xhdr, $header, $range) = @_;
 758         my $sub = lc $header;
 759         if ($sub eq 'message-id') {
 760                 hdr_message_id($self, $xhdr, $range);
 761         } elsif ($sub eq 'xref') {
 762                 hdr_xref($self, $xhdr, $range);
 763         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 764                                 bytes|lines)\z/x) {
 765                 hdr_searchmsg($self, $xhdr, $sub, $range);
 766         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 767                 hdr_searchmsg($self, $xhdr, $1, $range);
 768         } else {
 769                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 770         }
 771 }
 772
 773 # RFC 3977
 774 sub cmd_hdr ($$;$) {
 775         my ($self, $header, $range) = @_;
 776         do_hdr($self, 0, $header, $range);
 777 }
 778
 779 # RFC 2980
 780 sub cmd_xhdr ($$;$) {
 781         my ($self, $header, $range) = @_;
 782         do_hdr($self, 1, $header, $range);
 783 }
 784
 785 sub hdr_mid_prefix ($$$$$) {
 786         my ($self, $xhdr, $ng, $n, $mid) = @_;
 787         return $mid if $xhdr;
 788
 789         # HDR for RFC 3977 users
 790         if (my $self_ng = $self->{ng}) {
 791                 ($self_ng eq $ng) ? $n : '0';
 792         } else {
 793                 '0';
 794         }
 795 }
 796
 797 sub hdr_mid_response ($$$$$$) {
 798         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 799         my $res = '';
 800         if ($xhdr) {
 801                 $res .= r221 . "\r\n";
 802                 $res .= "$mid $v\r\n";
 803         } else {
 804                 $res .= r225 . "\r\n";
 805                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 806                 $res .= "$pfx $v\r\n";
 807         }
 808         res($self, $res .= '.');
 809         undef;
 810 }
 811
 812 sub xrover_i {
 813         my ($self, $beg, $end) = @_;
 814         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 815         more($self, "$$beg $h") if defined($h);
 816         $$beg++ < $end;
 817 }
 818
 819 sub cmd_xrover ($;$) {
 820         my ($self, $range) = @_;
 821         my $ng = $self->{ng} or return '412 no newsgroup selected';
 822         (defined $range && $range =~ /[<>]/) and
 823                 return '420 No article(s) selected'; # no message IDs
 824
 825         $range = $self->{article} unless defined $range;
 826         my $r = get_range($self, $range);
 827         return $r unless ref $r;
 828         more($self, '224 Overview information follows');
 829         long_response($self, \&xrover_i, @$r);
 830 }
 831
 832 sub over_line ($$$$) {
 833         my ($self, $ng, $num, $smsg) = @_;
 834         # n.b. field access and procedural calls can be
 835         # 10%-15% faster than OO method calls:
 836         my $s = join("\t", $num,
 837                 $smsg->{subject},
 838                 $smsg->{from},
 839                 PublicInbox::SearchMsg::date($smsg),
 840                 "<$smsg->{mid}>",
 841                 $smsg->{references},
 842                 $smsg->{bytes},
 843                 $smsg->{lines},
 844                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 845         utf8::encode($s);
 846         $s
 847 }
 848
 849 sub cmd_over ($;$) {
 850         my ($self, $range) = @_;
 851         if ($range && $range =~ /\A<(.+)>\z/) {
 852                 my ($ng, $n) = mid_lookup($self, $1);
 853                 defined $n or return r430;
 854                 my $smsg = $ng->over->get_art($n) or return r430;
 855                 more($self, '224 Overview information follows (multi-line)');
 856
 857                 # Only set article number column if it's the current group
 858                 my $self_ng = $self->{ng};
 859                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 860                 more($self, over_line($self, $ng, $n, $smsg));
 861                 '.';
 862         } else {
 863                 cmd_xover($self, $range);
 864         }
 865 }
 866
 867 sub xover_i {
 868         my ($self, $beg, $end) = @_;
 869         my $ng = $self->{ng};
 870         my $msgs = $ng->over->query_xover($$beg, $end);
 871         my $nr = scalar @$msgs or return;
 872
 873         # OVERVIEW.FMT
 874         more($self, join("\r\n", map {
 875                 over_line($self, $ng, $_->{num}, $_);
 876                 } @$msgs));
 877         $$beg = $msgs->[-1]->{num} + 1;
 878 }
 879
 880 sub cmd_xover ($;$) {
 881         my ($self, $range) = @_;
 882         $range = $self->{article} unless defined $range;
 883         my $r = get_range($self, $range);
 884         return $r unless ref $r;
 885         my ($beg, $end) = @$r;
 886         more($self, "224 Overview information follows for $$beg to $end");
 887         long_response($self, \&xover_i, @$r);
 888 }
 889
 890 sub compressed { undef }
 891
 892 sub cmd_starttls ($) {
 893         my ($self) = @_;
 894         my $sock = $self->{sock} or return;
 895         # RFC 4642 2.2.1
 896         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 897         my $opt = $self->{nntpd}->{accept_tls} or
 898                 return '580 can not initiate TLS negotiation';
 899         res($self, '382 Continue with TLS negotiation');
 900         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 901         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 902         undef;
 903 }
 904
 905 # RFC 8054
 906 sub cmd_compress ($$) {
 907         my ($self, $alg) = @_;
 908         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 909         return r502 if $self->compressed || !$have_deflate;
 910         PublicInbox::NNTPdeflate->enable($self);
 911         $self->requeue;
 912         undef
 913 }
 914
 915 sub zflush {} # overridden by NNTPdeflate
 916
 917 sub cmd_xpath ($$) {
 918         my ($self, $mid) = @_;
 919         return r501 unless $mid =~ /\A<(.+)>\z/;
 920         $mid = $1;
 921         my @paths;
 922         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 923                 my $n = $ng->mm->num_for($mid);
 924                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 925         }
 926         return '430 no such article on server' unless @paths;
 927         '223 '.join(' ', @paths);
 928 }
 929
 930 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 931
 932 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 933
 934 sub do_write ($$) {
 935         my $self = $_[0];
 936         my $done = $self->write(\($_[1]));
 937         return 0 unless $self->{sock};
 938
 939         $done;
 940 }
 941
 942 sub err ($$;@) {
 943         my ($self, $fmt, @args) = @_;
 944         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 945 }
 946
 947 sub out ($$;@) {
 948         my ($self, $fmt, @args) = @_;
 949         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 950 }
 951
 952 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 953 sub event_step {
 954         my ($self) = @_;
 955
 956         return unless $self->flush_write && $self->{sock};
 957
 958         $self->update_idle_time;
 959         # only read more requests if we've drained the write buffer,
 960         # otherwise we can be buffering infinitely w/o backpressure
 961
 962         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 963         my $r = 1;
 964
 965         if (index($$rbuf, "\n") < 0) {
 966                 my $off = bytes::length($$rbuf);
 967                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 968         }
 969         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 970                 my $line = $1;
 971                 return $self->close if $line =~ /[[:cntrl:]]/s;
 972                 my $t0 = now();
 973                 my $fd = fileno($self->{sock});
 974                 $r = eval { process_line($self, $line) };
 975                 my $pending = $self->{wbuf} ? ' pending' : '';
 976                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 977         }
 978
 979         return $self->close if $r < 0;
 980         my $len = bytes::length($$rbuf);
 981         return $self->close if ($len >= LINE_MAX);
 982         $self->rbuf_idle($rbuf);
 983         $self->update_idle_time;
 984
 985         # maybe there's more pipelined data, or we'll have
 986         # to register it for socket-readiness notifications
 987         $self->requeue unless $self->{wbuf};
 988 }
 989
 990 # for graceful shutdown in PublicInbox::Daemon:
 991 sub busy {
 992         my ($self, $now) = @_;
 993         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 994 }
 995
 996 # this is an import to prevent "perl -c" from complaining about fields
 997 sub import {
 998         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 999                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
1000 }
1001
1002 1;