lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Msgmap;
   9 use PublicInbox::GitCatFile;
  10 use PublicInbox::MID qw(mid2path);
  11 use Email::MIME;
  12 use Data::Dumper qw(Dumper);
  13 use POSIX qw(strftime);
  14 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  15 use constant {
  16         r501 => '501 command syntax error',
  17         r221 => '221 Header follows',
  18         r224 => '224 Overview information follows (multi-line)',
  19         r225 => '225 Headers follow (multi-line)',
  20         r430 => '430 No article with that message-id',
  21         long_response_limit => 0xffffffff,
  22 };
  23
  24 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  25
  26 my @OVERVIEW = qw(Subject From Date Message-ID References Bytes Lines);
  27 my %OVERVIEW = map { $_ => 1 } @OVERVIEW;
  28
  29 # disable commands with easy DoS potential:
  30 # LISTGROUP could get pretty bad, too...
  31 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  32
  33 sub new ($$$) {
  34         my ($class, $sock, $nntpd) = @_;
  35         my $self = fields::new($class);
  36         binmode $sock, ':utf8'; # RFC 3977
  37         $self->SUPER::new($sock);
  38         $self->{nntpd} = $nntpd;
  39         res($self, '201 server ready - post via email');
  40         $self->{rbuf} = '';
  41         $self->watch_read(1);
  42         $self;
  43 }
  44
  45 sub args_ok ($$) {
  46         my ($cb, $argc) = @_;
  47         my $tot = prototype $cb;
  48         my ($nreq, undef) = split(';', $tot);
  49         $nreq = ($nreq =~ tr/$//) - 1;
  50         $tot = ($tot =~ tr/$//) - 1;
  51         ($argc <= $tot && $argc >= $nreq);
  52 }
  53
  54 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  55 sub process_line ($$) {
  56         my ($self, $l) = @_;
  57         my ($req, @args) = split(/\s+/, $l);
  58         $req = lc($req);
  59         $req = eval {
  60                 no strict 'refs';
  61                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
  62         };
  63         return res($self, '500 command not recognized') unless $req;
  64         return res($self, r501) unless args_ok($req, scalar @args);
  65
  66         my $res = eval { $req->($self, @args) };
  67         my $err = $@;
  68         if ($err && !$self->{closed}) {
  69                 chomp($l = Dumper(\$l));
  70                 err($self, "error from: $l $err");
  71                 $res = '503 program fault - command not performed';
  72         }
  73         return 0 unless defined $res;
  74         res($self, $res);
  75 }
  76
  77 sub cmd_mode ($$) {
  78         my ($self, $arg) = @_;
  79         $arg = uc $arg;
  80         return r501 unless $arg eq 'READER';
  81         '200 reader status acknowledged';
  82 }
  83
  84 sub cmd_slave ($) { '202 slave status noted' }
  85
  86 sub cmd_xgtitle ($;$) {
  87         my ($self, $wildmat) = @_;
  88         more($self, '282 list of groups and descriptions follows');
  89         list_newsgroups($self, $wildmat);
  90         '.'
  91 }
  92
  93 sub list_overview_fmt ($$) {
  94         my ($self) = @_;
  95         more($self, $_ . ':') foreach @OVERVIEW;
  96 }
  97
  98 sub list_active ($;$) {
  99         my ($self, $wildmat) = @_;
 100         wildmat2re($wildmat);
 101         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 102                 $ng->{name} =~ $wildmat or next;
 103                 group_line($self, $ng);
 104         }
 105 }
 106
 107 sub list_active_times ($;$) {
 108         my ($self, $wildmat) = @_;
 109         wildmat2re($wildmat);
 110         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 111                 $ng->{name} =~ $wildmat or next;
 112                 my $c = eval { $ng->mm->created_at } || time;
 113                 more($self, "$ng->{name} $c $ng->{address}");
 114         }
 115 }
 116
 117 sub list_newsgroups ($;$) {
 118         my ($self, $wildmat) = @_;
 119         wildmat2re($wildmat);
 120         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 121                 $ng->{name} =~ $wildmat or next;
 122                 my $d = $ng->description;
 123                 more($self, "$ng->{name} $d");
 124         }
 125 }
 126
 127 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 128 sub cmd_list ($;$$) {
 129         my ($self, @args) = @_;
 130         if (scalar @args) {
 131                 my $arg = shift @args;
 132                 $arg =~ tr/A-Z./a-z_/;
 133                 $arg = "list_$arg";
 134                 return r501 if $DISABLED{$arg};
 135
 136                 $arg = eval {
 137                         no strict 'refs';
 138                         *{$arg}{CODE};
 139                 };
 140                 return r501 unless $arg && args_ok($arg, scalar @args);
 141                 more($self, '215 information follows');
 142                 $arg->($self, @args);
 143         } else {
 144                 more($self, '215 list of newsgroups follows');
 145                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 146                         group_line($self, $ng);
 147                 }
 148         }
 149         '.'
 150 }
 151
 152 sub cmd_listgroup ($;$) {
 153         my ($self, $group) = @_;
 154         if (defined $group) {
 155                 my $res = cmd_group($self, $group);
 156                 return $res if ($res !~ /\A211 /);
 157                 more($self, $res);
 158         }
 159
 160         $self->{ng} or return '412 no newsgroup selected';
 161         $self->long_response(0, long_response_limit, sub {
 162                 my ($i) = @_;
 163                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 164                         my ($ary) = @_;
 165                         more($self, join("\r\n", @$ary));
 166                 });
 167
 168                 # -1 to adjust for implicit increment in long_response
 169                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 170         });
 171 }
 172
 173 sub parse_time ($$;$) {
 174         my ($date, $time, $gmt) = @_;
 175         use Time::Local qw();
 176         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 177         if (defined $gmt) {
 178                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 179                 $gmt = 1;
 180         }
 181         my @now = $gmt ? gmtime : localtime;
 182         my ($YYYY, $MM, $DD);
 183         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 184                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 185         } else { # legacy clients send YYMMDD
 186                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 187                 if ($YYYY > strftime('%y', @now)) {
 188                         my $cur_year = $now[5] + 1900;
 189                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 190                 }
 191         }
 192         if ($gmt) {
 193                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 194         } else {
 195                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 196         }
 197 }
 198
 199 sub group_line ($$) {
 200         my ($self, $ng) = @_;
 201         my ($min, $max) = $ng->mm->minmax;
 202         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 203 }
 204
 205 sub cmd_newgroups ($$$;$$) {
 206         my ($self, $date, $time, $gmt, $dists) = @_;
 207         my $ts = eval { parse_time($date, $time, $gmt) };
 208         return r501 if $@;
 209
 210         # TODO dists
 211         more($self, '231 list of new newsgroups follows');
 212         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 213                 my $c = eval { $ng->mm->created_at } || 0;
 214                 next unless $c > $ts;
 215                 group_line($self, $ng);
 216         }
 217         '.'
 218 }
 219
 220 sub wildmat2re (;$) {
 221         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 222         my %keep;
 223         my $salt = rand;
 224         use Digest::SHA qw(sha1_hex);
 225         my $tmp = $_[0];
 226
 227         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 228                 my $orig = $1;
 229                 my $key = sha1_hex($orig . $salt);
 230                 $orig =~ s/([^\w\-])+/\Q$1/g;
 231                 $keep{$key} = $orig;
 232                 $key
 233                 #gex;
 234         my %map = ('*' => '.*', '?' => '.' );
 235         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 236         if (scalar %keep) {
 237                 $tmp =~ s#([a-f0-9]{40})#
 238                         my $orig = $keep{$1};
 239                         defined $orig ? $orig : $1;
 240                         #ge;
 241         }
 242         $_[0] = qr/\A$tmp\z/;
 243 }
 244
 245 sub ngpat2re (;$) {
 246         return $_[0] = qr/\A\z/ unless defined $_[0];
 247         my %map = ('*' => '.*', ',' => '|');
 248         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 249         $_[0] = qr/\A(?:$_[0])\z/;
 250 }
 251
 252 sub cmd_newnews ($$$$;$$) {
 253         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 254         my $ts = eval { parse_time($date, $time, $gmt) };
 255         return r501 if $@;
 256         more($self, '230 list of new articles by message-id follows');
 257         my ($keep, $skip) = split('!', $newsgroups, 2);
 258         ngpat2re($keep);
 259         ngpat2re($skip);
 260         my @srch;
 261         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 262                 $ng->{name} =~ $keep or next;
 263                 $ng->{name} =~ $skip and next;
 264                 my $srch = $ng->search or next;
 265                 push @srch, $srch;
 266         };
 267         return '.' unless @srch;
 268
 269         $ts .= '..';
 270         my $opts = { asc => 1, limit => 1000, offset => 0 };
 271         $self->long_response(0, long_response_limit, sub {
 272                 my ($i) = @_;
 273                 my $srch = $srch[0];
 274                 my $res = $srch->query($ts, $opts);
 275                 my $msgs = $res->{msgs};
 276                 if (my $nr = scalar @$msgs) {
 277                         more($self, '<' .
 278                                 join(">\r\n<", map { $_->mid } @$msgs ).
 279                                 '>');
 280                         $opts->{offset} += $nr;
 281                 } else {
 282                         shift @srch;
 283                         if (@srch) { # continue onto next newsgroup
 284                                 $opts->{offset} = 0;
 285                         } else { # break out of the long response.
 286                                 $$i = long_response_limit;
 287                         }
 288                 }
 289         });
 290 }
 291
 292 sub cmd_group ($$) {
 293         my ($self, $group) = @_;
 294         my $no_such = '411 no such news group';
 295         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 296
 297         $self->{ng} = $ng;
 298         my ($min, $max) = $ng->mm->minmax;
 299         $min ||= 0;
 300         $max ||= 0;
 301         $self->{article} = $min;
 302         my $est_size = $max - $min;
 303         "211 $est_size $min $max $group";
 304 }
 305
 306 sub article_adj ($$) {
 307         my ($self, $off) = @_;
 308         my $ng = $self->{ng} or return '412 no newsgroup selected';
 309
 310         my $n = $self->{article};
 311         defined $n or return '420 no current article has been selected';
 312
 313         $n += $off;
 314         my $mid = $ng->mm->mid_for($n);
 315         unless ($mid) {
 316                 $n = $off > 0 ? 'next' : 'previous';
 317                 return "421 no $n article in this group";
 318         }
 319         $self->{article} = $n;
 320         "223 $n <$mid> article retrieved - request text separately";
 321 }
 322
 323 sub cmd_next ($) { article_adj($_[0], 1) }
 324 sub cmd_last ($) { article_adj($_[0], -1) }
 325
 326 # We want to encourage using email and CC-ing everybody involved to avoid
 327 # the single-point-of-failure a single server provides.
 328 sub cmd_post ($) {
 329         my ($self) = @_;
 330         my $ng = $self->{ng};
 331         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 332 }
 333
 334 sub cmd_quit ($) {
 335         my ($self) = @_;
 336         res($self, '205 closing connection - goodbye!');
 337         $self->close;
 338         undef;
 339 }
 340
 341 sub art_lookup ($$$) {
 342         my ($self, $art, $set_headers) = @_;
 343         my $ng = $self->{ng};
 344         my ($n, $mid);
 345         my $err;
 346         if (defined $art) {
 347                 if ($art =~ /\A\d+\z/o) {
 348                         $err = '423 no such article number in this group';
 349                         $n = int($art);
 350                         goto find_mid;
 351                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 352                         $mid = $1;
 353                         $err = r430;
 354                         $n = $ng->mm->num_for($mid) if $ng;
 355                         goto found if defined $n;
 356                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 357                                 $n = $g->mm->num_for($mid);
 358                                 if (defined $n) {
 359                                         $ng = $g;
 360                                         goto found;
 361                                 }
 362                         }
 363                         return $err;
 364                 } else {
 365                         return r501;
 366                 }
 367         } else {
 368                 $err = '420 no current article has been selected';
 369                 $n = $self->{article};
 370                 defined $n or return $err;
 371 find_mid:
 372                 $ng or return '412 no newsgroup has been selected';
 373                 $mid = $ng->mm->mid_for($n);
 374                 defined $mid or return $err;
 375         }
 376 found:
 377         my $o = 'HEAD:' . mid2path($mid);
 378         my $bytes;
 379         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 380         return $err unless $s;
 381         my $lines;
 382         if ($set_headers) {
 383                 $s->header_set('Newsgroups', $ng->{name});
 384                 $s->header_set('Xref', xref($ng, $n));
 385                 $lines = $s->body =~ tr!\n!\n!;
 386
 387                 # must be last
 388                 $s->body_set('') if ($set_headers == 2);
 389         }
 390         [ $n, $mid, $s, $bytes, $lines, $ng ];
 391 }
 392
 393 sub simple_body_write ($$) {
 394         my ($self, $s) = @_;
 395         my $body = $s->body;
 396         $s->body_set('');
 397         $body =~ s/^\./../smg;
 398         $body =~ s/(?<!\r)\n/\r\n/sg;
 399         do_more($self, $body);
 400         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 401         '.'
 402 }
 403
 404 sub set_art {
 405         my ($self, $art) = @_;
 406         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 407 }
 408
 409 sub cmd_article ($;$) {
 410         my ($self, $art) = @_;
 411         my $r = $self->art_lookup($art, 1);
 412         return $r unless ref $r;
 413         my ($n, $mid, $s) = @$r;
 414         set_art($self, $art);
 415         more($self, "220 $n <$mid> article retrieved - head and body follow");
 416         do_more($self, $s->header_obj->as_string);
 417         do_more($self, "\r\n");
 418         simple_body_write($self, $s);
 419 }
 420
 421 sub cmd_head ($;$) {
 422         my ($self, $art) = @_;
 423         my $r = $self->art_lookup($art, 2);
 424         return $r unless ref $r;
 425         my ($n, $mid, $s) = @$r;
 426         set_art($self, $art);
 427         more($self, "221 $n <$mid> article retrieved - head follows");
 428         do_more($self, $s->header_obj->as_string);
 429         '.'
 430 }
 431
 432 sub cmd_body ($;$) {
 433         my ($self, $art) = @_;
 434         my $r = $self->art_lookup($art, 0);
 435         return $r unless ref $r;
 436         my ($n, $mid, $s) = @$r;
 437         set_art($self, $art);
 438         more($self, "222 $n <$mid> article retrieved - body follows");
 439         simple_body_write($self, $s);
 440 }
 441
 442 sub cmd_stat ($;$) {
 443         my ($self, $art) = @_;
 444         my $r = $self->art_lookup($art, 0);
 445         return $r unless ref $r;
 446         my ($n, $mid, undef) = @$r;
 447         set_art($self, $art);
 448         "223 $n <$mid> article retrieved - request text separately";
 449 }
 450
 451 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 452
 453 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 454
 455 sub cmd_help ($) {
 456         my ($self) = @_;
 457         more($self, '100 help text follows');
 458         '.'
 459 }
 460
 461 sub get_range ($$) {
 462         my ($self, $range) = @_;
 463         my $ng = $self->{ng} or return '412 no news group has been selected';
 464         defined $range or return '420 No article(s) selected';
 465         my ($beg, $end);
 466         my ($min, $max) = $ng->mm->minmax;
 467         if ($range =~ /\A(\d+)\z/) {
 468                 $beg = $end = $1;
 469         } elsif ($range =~ /\A(\d+)-\z/) {
 470                 ($beg, $end) = ($1, $max);
 471         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 472                 ($beg, $end) = ($1, $2);
 473         } else {
 474                 return r501;
 475         }
 476         $beg = $min if ($beg < $min);
 477         $end = $max if ($end > $max);
 478         return '420 No article(s) selected' if ($beg > $end);
 479         [ $beg, $end ];
 480 }
 481
 482 sub hdr_val ($$) {
 483         my ($r, $header) = @_;
 484         return $r->[3] if $header =~ /\A:?bytes\z/i;
 485         return $r->[4] if $header =~ /\A:?lines\z/i;
 486         $r = $r->[2]->header_obj->header($header);
 487         defined $r or return;
 488         $r =~ s/[\r\n\t]+/ /sg;
 489         $r;
 490 }
 491
 492 sub long_response ($$$$) {
 493         my ($self, $beg, $end, $cb) = @_;
 494         die "BUG: nested long response" if $self->{long_res};
 495
 496         my $fd = $self->{fd};
 497         defined $fd or return;
 498         # make sure we disable reading during a long response,
 499         # clients should not be sending us stuff and making us do more
 500         # work while we are stream a response to them
 501         $self->watch_read(0);
 502         my $t0 = now();
 503         $self->{long_res} = sub {
 504                 # limit our own running time for fairness with other
 505                 # clients and to avoid buffering too much:
 506                 my $lim = 100;
 507
 508                 my $err;
 509                 do {
 510                         eval { $cb->(\$beg) };
 511                 } until (($err = $@) || $self->{closed} ||
 512                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 513
 514                 if ($err || $self->{closed}) {
 515                         $self->{long_res} = undef;
 516
 517                         if ($err) {
 518                                 err($self,
 519                                     "$err during long response[$fd] - %0.6f",
 520                                         now() - $t0);
 521                         }
 522                         if ($self->{closed}) {
 523                                 out($self, " deferred[$fd] aborted - %0.6f",
 524                                            now() - $t0);
 525                         } else {
 526                                 $self->watch_read(1);
 527                         }
 528                 } elsif (!$lim || $self->{write_buf_size}) {
 529                         # no recursion, schedule another call ASAP
 530                         # but only after all pending writes are done
 531                         Danga::Socket->AddTimer(0, sub {
 532                                 $self->write($self->{long_res});
 533                         });
 534                 } else { # all done!
 535                         $self->{long_res} = undef;
 536                         $self->watch_read(1);
 537                         res($self, '.');
 538                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 539                 }
 540         };
 541         $self->{long_res}->(); # kick off!
 542         undef;
 543 }
 544
 545 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 546         my ($self, $xhdr, $range) = @_;
 547
 548         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 549                 my ($ng, $n) = mid_lookup($self, $1);
 550                 return r430 unless $n;
 551                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 552         } else { # numeric range
 553                 $range = $self->{article} unless defined $range;
 554                 my $r = get_range($self, $range);
 555                 return $r unless ref $r;
 556                 my $mm = $self->{ng}->mm;
 557                 my ($beg, $end) = @$r;
 558                 more($self, $xhdr ? r221 : r225);
 559                 $self->long_response($beg, $end, sub {
 560                         my ($i) = @_;
 561                         my $mid = $mm->mid_for($$i);
 562                         more($self, "$$i <$mid>") if defined $mid;
 563                 });
 564         }
 565 }
 566
 567 sub xref ($$) {
 568         my ($ng, $n) = @_;
 569         "$ng->{domain} $ng->{name}:$n"
 570 }
 571
 572 sub mid_lookup ($$) {
 573         my ($self, $mid) = @_;
 574         my $self_ng = $self->{ng};
 575         if ($self_ng) {
 576                 my $n = $self_ng->mm->num_for($mid);
 577                 return ($self_ng, $n) if defined $n;
 578         }
 579         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 580                 next if defined $self_ng && $ng eq $self_ng;
 581                 my $n = $ng->mm->num_for($mid);
 582                 return ($ng, $n) if defined $n;
 583         }
 584         (undef, undef);
 585 }
 586
 587 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 588         my ($self, $xhdr, $range) = @_;
 589
 590         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 591                 my ($ng, $n) = mid_lookup($self, $1);
 592                 return r430 unless $n;
 593                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 594         } else { # numeric range
 595                 $range = $self->{article} unless defined $range;
 596                 my $r = get_range($self, $range);
 597                 return $r unless ref $r;
 598                 my $ng = $self->{ng};
 599                 my $mm = $ng->mm;
 600                 my ($beg, $end) = @$r;
 601                 more($self, $xhdr ? r221 : r225);
 602                 $self->long_response($beg, $end, sub {
 603                         my ($i) = @_;
 604                         my $mid = $mm->mid_for($$i);
 605                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 606                 });
 607         }
 608 }
 609
 610 sub header_obj_for {
 611         my ($srch, $mid) = @_;
 612         eval {
 613                 my $smsg = $srch->lookup_message($mid);
 614                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 615                 $smsg->mini_mime->header_obj;
 616         };
 617 };
 618
 619 sub hdr_searchmsg ($$$$) {
 620         my ($self, $xhdr, $hdr, $range) = @_;
 621         my $filter;
 622         if ($hdr eq 'date') {
 623                 $hdr = 'X-PI-TS';
 624                 $filter = sub ($) {
 625                         strftime('%a, %d %b %Y %T %z', gmtime($_[0]));
 626                 };
 627         }
 628
 629         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 630                 my ($ng, $n) = mid_lookup($self, $1);
 631                 return r430 unless $n;
 632                 if (my $srch = $ng->search) {
 633                         my $m = header_obj_for($srch, $range);
 634                         my $v = $m->header($hdr);
 635                         $v = $filter->($v) if defined $v && $filter;
 636                         hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 637                 } else {
 638                         hdr_slow($self, $xhdr, $hdr, $range);
 639                 }
 640         } else { # numeric range
 641                 $range = $self->{article} unless defined $range;
 642                 my $srch = $self->{ng}->search or
 643                                 return hdr_slow($self, $xhdr, $hdr, $range);
 644                 my $mm = $self->{ng}->mm;
 645                 my $r = get_range($self, $range);
 646                 return $r unless ref $r;
 647                 my ($beg, $end) = @$r;
 648                 more($self, $xhdr ? r221 : r225);
 649                 $self->long_response($beg, $end, sub {
 650                         my ($i) = @_;
 651                         my $mid = $mm->mid_for($$i) or return;
 652                         my $m = header_obj_for($srch, $mid) or return;
 653                         my $v = $m->header($hdr);
 654                         defined $v or return;
 655                         $v = $filter->($v) if $filter;
 656                         more($self, "$$i $v");
 657                 });
 658         }
 659 }
 660
 661 sub do_hdr ($$$;$) {
 662         my ($self, $xhdr, $header, $range) = @_;
 663         my $sub = lc $header;
 664         if ($sub eq 'message-id') {
 665                 hdr_message_id($self, $xhdr, $range);
 666         } elsif ($sub eq 'xref') {
 667                 hdr_xref($self, $xhdr, $range);
 668         } elsif ($sub =~ /\A(subject|references|date)\z/) {
 669                 hdr_searchmsg($self, $xhdr, $sub, $range);
 670         } else {
 671                 hdr_slow($self, $xhdr, $header, $range);
 672         }
 673 }
 674
 675 # RFC 3977
 676 sub cmd_hdr ($$;$) {
 677         my ($self, $header, $range) = @_;
 678         do_hdr($self, 0, $header, $range);
 679 }
 680
 681 # RFC 2980
 682 sub cmd_xhdr ($$;$) {
 683         my ($self, $header, $range) = @_;
 684         do_hdr($self, 1, $header, $range);
 685 }
 686
 687 sub hdr_mid_prefix ($$$$$) {
 688         my ($self, $xhdr, $ng, $n, $mid) = @_;
 689         return $mid if $xhdr;
 690
 691         # HDR for RFC 3977 users
 692         if (my $self_ng = $self->{ng}) {
 693                 ($self_ng eq $ng) ? $n : '0';
 694         } else {
 695                 '0';
 696         }
 697 }
 698
 699 sub hdr_mid_response ($$$$$$) {
 700         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 701         my $res = '';
 702         if ($xhdr) {
 703                 $res .= r221 . "\r\n";
 704                 $res .= "$mid $v\r\n" if defined $v;
 705         } else {
 706                 $res .= r225 . "\r\n";
 707                 if (defined $v) {
 708                         my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 709                         $res .= "$pfx $v\r\n";
 710                 }
 711         }
 712         res($self, $res .= '.');
 713         undef;
 714 }
 715
 716 sub hdr_slow ($$$$) {
 717         my ($self, $xhdr, $header, $range) = @_;
 718
 719         if (defined $range && $range =~ /\A<.+>\z/) { # Message-ID
 720                 my $r = $self->art_lookup($range, 2);
 721                 return $r unless ref $r;
 722                 my ($n, $ng) = ($r->[0], $r->[5]);
 723                 my $v = hdr_val($r, $header);
 724                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 725         } else { # numeric range
 726                 $range = $self->{article} unless defined $range;
 727                 my $r = get_range($self, $range);
 728                 return $r unless ref $r;
 729                 my ($beg, $end) = @$r;
 730                 more($self, $xhdr ? r221 : r225);
 731                 $self->long_response($beg, $end, sub {
 732                         my ($i) = @_;
 733                         $r = $self->art_lookup($$i, 2);
 734                         return unless ref $r;
 735                         defined($r = hdr_val($r, $header)) or return;
 736                         more($self, "$$i $r");
 737                 });
 738         }
 739 }
 740
 741 sub cmd_xrover ($;$) {
 742         my ($self, $range) = @_;
 743         my $ng = $self->{ng} or return '412 no newsgroup selected';
 744         (defined $range && $range =~ /[<>]/) and
 745                 return '420 No article(s) selected'; # no message IDs
 746
 747         $range = $self->{article} unless defined $range;
 748         my $r = get_range($self, $range);
 749         return $r unless ref $r;
 750         my ($beg, $end) = @$r;
 751         my $mm = $ng->mm;
 752         my $srch = $ng->search;
 753         more($self, '224 Overview information follows');
 754         $self->long_response($beg, $end, sub {
 755                 my ($i) = @_;
 756                 my $mid = $mm->mid_for($$i) or return;
 757                 my $m = header_obj_for($srch, $mid) or return;
 758                 my $h = $m->header('references');
 759                 more($self, "$$i $h") if defined $h;
 760         });
 761 }
 762
 763 sub over_line ($$) {
 764         my ($self, $r) = @_;
 765
 766         more($self, join("\t", $r->[0], map {
 767                                 my $h = hdr_val($r, $_);
 768                                 defined $h ? $h : '';
 769                         } @OVERVIEW ));
 770 }
 771
 772 sub cmd_over ($;$) {
 773         my ($self, $range) = @_;
 774         if ($range && $range =~ /\A<.+>\z/) {
 775                 my $r = $self->art_lookup($range, 2);
 776                 return '430 No article with that message-id' unless ref $r;
 777                 more($self, '224 Overview information follows (multi-line)');
 778
 779                 # Only set article number column if it's the current group
 780                 my $ng = $self->{ng};
 781                 $r->[0] = 0 if (!$ng || $ng ne $r->[5]);
 782                 over_line($self, $r);
 783                 '.';
 784         } else {
 785                 cmd_xover($self, $range);
 786         }
 787 }
 788
 789 sub cmd_xover ($;$) {
 790         my ($self, $range) = @_;
 791         $range = $self->{article} unless defined $range;
 792         my $r = get_range($self, $range);
 793         return $r unless ref $r;
 794         my ($beg, $end) = @$r;
 795         more($self, "224 Overview information follows for $beg to $end");
 796         $self->long_response($beg, $end, sub {
 797                 my ($i) = @_;
 798                 my $r = $self->art_lookup($$i, 2);
 799                 return unless ref $r;
 800                 over_line($self, $r);
 801         });
 802 }
 803
 804 sub cmd_xpath ($$) {
 805         my ($self, $mid) = @_;
 806         return r501 unless $mid =~ /\A<(.+)>\z/;
 807         $mid = $1;
 808         my @paths;
 809         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 810                 my $n = $ng->mm->num_for($mid);
 811                 push @paths, "$ng->{name}/$n" if defined $n;
 812         }
 813         return '430 no such article on server' unless @paths;
 814         '223 '.join(' ', @paths);
 815 }
 816
 817 sub res ($$) {
 818         my ($self, $line) = @_;
 819         do_write($self, $line . "\r\n");
 820 }
 821
 822 sub more ($$) {
 823         my ($self, $line) = @_;
 824         do_more($self, $line . "\r\n");
 825 }
 826
 827 sub do_write ($$) {
 828         my ($self, $data) = @_;
 829         my $done = $self->write($data);
 830         die if $self->{closed};
 831
 832         # Do not watch for readability if we have data in the queue,
 833         # instead re-enable watching for readability when we can
 834         $self->watch_read(0) if (!$done || $self->{long_res});
 835
 836         $done;
 837 }
 838
 839 sub err ($$;@) {
 840         my ($self, $fmt, @args) = @_;
 841         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 842 }
 843
 844 sub out ($$;@) {
 845         my ($self, $fmt, @args) = @_;
 846         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 847 }
 848
 849 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 850
 851 sub do_more ($$) {
 852         my ($self, $data) = @_;
 853         if (MSG_MORE && !$self->{write_buf_size}) {
 854                 my $n = send($self->{sock}, $data, MSG_MORE);
 855                 if (defined $n) {
 856                         my $dlen = length($data);
 857                         return 1 if $n == $dlen; # all done!
 858                         $data = substr($data, $n, $dlen - $n);
 859                 }
 860         }
 861         $self->do_write($data);
 862 }
 863
 864 # callbacks for by Danga::Socket
 865
 866 sub event_hup { $_[0]->close }
 867 sub event_err { $_[0]->close }
 868
 869 sub event_write {
 870         my ($self) = @_;
 871         # only continue watching for readability when we are done writing:
 872         if ($self->write(undef) == 1 && !$self->{long_res}) {
 873                 $self->watch_read(1);
 874         }
 875 }
 876
 877 sub event_read {
 878         my ($self) = @_;
 879         use constant LINE_MAX => 512; # RFC 977 section 2.3
 880         my $r = 1;
 881
 882         my $buf = $self->read(LINE_MAX) or return $self->close;
 883         $self->{rbuf} .= $$buf;
 884         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 885                 my $line = $1;
 886                 my $t0 = now();
 887                 my $fd = $self->{fd};
 888                 $r = eval { $self->process_line($line) };
 889                 my $d = $self->{long_res} ?
 890                         " deferred[$fd]" : '';
 891                 out($self, "[$fd] $line - %0.6f$d", now() - $t0);
 892         }
 893
 894         return $self->close if $r < 0;
 895         my $len = length($self->{rbuf});
 896         return $self->close if ($len >= LINE_MAX);
 897 }
 898
 899 sub watch_read {
 900         my ($self, $bool) = @_;
 901         my $rv = $self->SUPER::watch_read($bool);
 902         if ($bool && $self->{rbuf} ne '') {
 903                 # Force another read if there is a pipelined request.
 904                 # We don't know if the socket has anything for us to read,
 905                 # and we must double-check again by the time the timer fires
 906                 # in case we really did dispatch a read event and started
 907                 # another long response.
 908                 Danga::Socket->AddTimer(0, sub {
 909                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 910                                 $self->event_read;
 911                         }
 912                 });
 913         }
 914         $rv;
 915 }
 916
 917 sub busy () {
 918         my ($self) = @_;
 919         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 920 }
 921
 922 1;