lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLOUT EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_step($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub requeue ($) {
  62         push @$nextq, $_[0];
  63         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
  64 }
  65
  66 sub update_idle_time ($) {
  67         my ($self) = @_;
  68         my $sock = $self->{sock} or return;
  69         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  70 }
  71
  72 sub expire_old () {
  73         my $now = now();
  74         my $exp = $EXPTIME;
  75         my $old = $now - $exp;
  76         my $nr = 0;
  77         my $closed = 0;
  78         my %new;
  79         while (my ($fd, $v) = each %$EXPMAP) {
  80                 my ($idle_time, $nntp) = @$v;
  81                 if ($idle_time < $old) {
  82                         if ($nntp->shutdn) {
  83                                 $closed++;
  84                         } else {
  85                                 ++$nr;
  86                                 $new{$fd} = $v;
  87                         }
  88                 } else {
  89                         ++$nr;
  90                         $new{$fd} = $v;
  91                 }
  92         }
  93         $EXPMAP = \%new;
  94         if ($nr) {
  95                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  96         } else {
  97                 $expt = undef;
  98                 # noop to kick outselves out of the loop ASAP so descriptors
  99                 # really get closed
 100                 PublicInbox::EvCleanup::asap(sub {}) if $closed;
 101         }
 102 }
 103
 104 sub new ($$$) {
 105         my ($class, $sock, $nntpd) = @_;
 106         my $self = fields::new($class);
 107         my $ev = EPOLLOUT | EPOLLONESHOT;
 108         my $wbuf = [];
 109         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
 110                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
 111                 $ev |= EPOLLONESHOT;
 112                 $wbuf->[0] = \&PublicInbox::DS::accept_tls_step;
 113         }
 114         $self->SUPER::new($sock, $ev);
 115         $self->{nntpd} = $nntpd;
 116         my $greet = "201 $nntpd->{servername} ready - post via email\r\n";
 117         open my $fh, '<:scalar',  \$greet or die "open :scalar: $!";
 118         push @$wbuf, $fh;
 119         $self->{wbuf} = $wbuf;
 120         $self->{rbuf} = '';
 121         update_idle_time($self);
 122         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 123         $self;
 124 }
 125
 126 sub args_ok ($$) {
 127         my ($cb, $argc) = @_;
 128         my $tot = prototype $cb;
 129         my ($nreq, undef) = split(';', $tot);
 130         $nreq = ($nreq =~ tr/$//) - 1;
 131         $tot = ($tot =~ tr/$//) - 1;
 132         ($argc <= $tot && $argc >= $nreq);
 133 }
 134
 135 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 136 sub process_line ($$) {
 137         my ($self, $l) = @_;
 138         my ($req, @args) = split(/[ \t]/, $l);
 139         return 1 unless defined($req); # skip blank line
 140         $req = lc($req);
 141         $req = eval {
 142                 no strict 'refs';
 143                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 144         };
 145         return res($self, '500 command not recognized') unless $req;
 146         return res($self, r501) unless args_ok($req, scalar @args);
 147
 148         my $res = eval { $req->($self, @args) };
 149         my $err = $@;
 150         if ($err && $self->{sock}) {
 151                 local $/ = "\n";
 152                 chomp($l);
 153                 err($self, 'error from: %s (%s)', $l, $err);
 154                 $res = '503 program fault - command not performed';
 155         }
 156         return 0 unless defined $res;
 157         res($self, $res);
 158 }
 159
 160 sub cmd_mode ($$) {
 161         my ($self, $arg) = @_;
 162         $arg = uc $arg;
 163         return r501 unless $arg eq 'READER';
 164         '201 Posting prohibited';
 165 }
 166
 167 sub cmd_slave ($) { '202 slave status noted' }
 168
 169 sub cmd_xgtitle ($;$) {
 170         my ($self, $wildmat) = @_;
 171         more($self, '282 list of groups and descriptions follows');
 172         list_newsgroups($self, $wildmat);
 173         '.'
 174 }
 175
 176 sub list_overview_fmt ($) {
 177         my ($self) = @_;
 178         msg_more($self, $OVERVIEW_FMT);
 179 }
 180
 181 sub list_headers ($;$) {
 182         my ($self) = @_;
 183         msg_more($self, $LIST_HEADERS);
 184 }
 185
 186 sub list_active ($;$) {
 187         my ($self, $wildmat) = @_;
 188         wildmat2re($wildmat);
 189         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 190                 $ng->{newsgroup} =~ $wildmat or next;
 191                 group_line($self, $ng);
 192         }
 193 }
 194
 195 sub list_active_times ($;$) {
 196         my ($self, $wildmat) = @_;
 197         wildmat2re($wildmat);
 198         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 199                 $ng->{newsgroup} =~ $wildmat or next;
 200                 my $c = eval { $ng->mm->created_at } || time;
 201                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 202         }
 203 }
 204
 205 sub list_newsgroups ($;$) {
 206         my ($self, $wildmat) = @_;
 207         wildmat2re($wildmat);
 208         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 209                 $ng->{newsgroup} =~ $wildmat or next;
 210                 my $d = $ng->description;
 211                 more($self, "$ng->{newsgroup} $d");
 212         }
 213 }
 214
 215 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 216 sub cmd_list ($;$$) {
 217         my ($self, @args) = @_;
 218         if (scalar @args) {
 219                 my $arg = shift @args;
 220                 $arg =~ tr/A-Z./a-z_/;
 221                 $arg = "list_$arg";
 222                 return r501 if $DISABLED{$arg};
 223
 224                 $arg = eval {
 225                         no strict 'refs';
 226                         *{$arg}{CODE};
 227                 };
 228                 return r501 unless $arg && args_ok($arg, scalar @args);
 229                 more($self, '215 information follows');
 230                 $arg->($self, @args);
 231         } else {
 232                 more($self, '215 list of newsgroups follows');
 233                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 234                         group_line($self, $ng);
 235                 }
 236         }
 237         '.'
 238 }
 239
 240 sub cmd_listgroup ($;$) {
 241         my ($self, $group) = @_;
 242         if (defined $group) {
 243                 my $res = cmd_group($self, $group);
 244                 return $res if ($res !~ /\A211 /);
 245                 more($self, $res);
 246         }
 247
 248         $self->{ng} or return '412 no newsgroup selected';
 249         my $n = 0;
 250         long_response($self, sub {
 251                 my $ary = $self->{ng}->mm->ids_after(\$n);
 252                 scalar @$ary or return;
 253                 more($self, join("\r\n", @$ary));
 254                 1;
 255         });
 256 }
 257
 258 sub parse_time ($$;$) {
 259         my ($date, $time, $gmt) = @_;
 260         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 261         if (defined $gmt) {
 262                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 263                 $gmt = 1;
 264         }
 265         my @now = $gmt ? gmtime : localtime;
 266         my ($YYYY, $MM, $DD);
 267         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 268                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 269         } else { # legacy clients send YYMMDD
 270                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 271                 my $cur_year = $now[5] + 1900;
 272                 if ($YYYY > $cur_year) {
 273                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 274                 }
 275         }
 276         if ($gmt) {
 277                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 278         } else {
 279                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 280         }
 281 }
 282
 283 sub group_line ($$) {
 284         my ($self, $ng) = @_;
 285         my ($min, $max) = $ng->mm->minmax;
 286         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 287 }
 288
 289 sub cmd_newgroups ($$$;$$) {
 290         my ($self, $date, $time, $gmt, $dists) = @_;
 291         my $ts = eval { parse_time($date, $time, $gmt) };
 292         return r501 if $@;
 293
 294         # TODO dists
 295         more($self, '231 list of new newsgroups follows');
 296         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 297                 my $c = eval { $ng->mm->created_at } || 0;
 298                 next unless $c > $ts;
 299                 group_line($self, $ng);
 300         }
 301         '.'
 302 }
 303
 304 sub wildmat2re (;$) {
 305         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 306         my %keep;
 307         my $salt = rand;
 308         my $tmp = $_[0];
 309
 310         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 311                 my $orig = $1;
 312                 my $key = sha1_hex($orig . $salt);
 313                 $orig =~ s/([^\w\-])+/\Q$1/g;
 314                 $keep{$key} = $orig;
 315                 $key
 316                 #gex;
 317         my %map = ('*' => '.*', '?' => '.' );
 318         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 319         if (scalar %keep) {
 320                 $tmp =~ s#([a-f0-9]{40})#
 321                         my $orig = $keep{$1};
 322                         defined $orig ? $orig : $1;
 323                         #ge;
 324         }
 325         $_[0] = qr/\A$tmp\z/;
 326 }
 327
 328 sub ngpat2re (;$) {
 329         return $_[0] = qr/\A\z/ unless defined $_[0];
 330         my %map = ('*' => '.*', ',' => '|');
 331         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 332         $_[0] = qr/\A(?:$_[0])\z/;
 333 }
 334
 335 sub cmd_newnews ($$$$;$$) {
 336         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 337         my $ts = eval { parse_time($date, $time, $gmt) };
 338         return r501 if $@;
 339         more($self, '230 list of new articles by message-id follows');
 340         my ($keep, $skip) = split('!', $newsgroups, 2);
 341         ngpat2re($keep);
 342         ngpat2re($skip);
 343         my @over;
 344         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 345                 $ng->{newsgroup} =~ $keep or next;
 346                 $ng->{newsgroup} =~ $skip and next;
 347                 my $over = $ng->over or next;
 348                 push @over, $over;
 349         };
 350         return '.' unless @over;
 351
 352         my $prev = 0;
 353         long_response($self, sub {
 354                 my $over = $over[0];
 355                 my $msgs = $over->query_ts($ts, $prev);
 356                 if (scalar @$msgs) {
 357                         more($self, '<' .
 358                                 join(">\r\n<", map { $_->mid } @$msgs ).
 359                                 '>');
 360                         $prev = $msgs->[-1]->{num};
 361                 } else {
 362                         shift @over;
 363                         if (@over) { # continue onto next newsgroup
 364                                 $prev = 0;
 365                                 return 1;
 366                         } else { # break out of the long response.
 367                                 return;
 368                         }
 369                 }
 370         });
 371 }
 372
 373 sub cmd_group ($$) {
 374         my ($self, $group) = @_;
 375         my $no_such = '411 no such news group';
 376         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 377
 378         $self->{ng} = $ng;
 379         my ($min, $max) = $ng->mm->minmax;
 380         $min ||= 0;
 381         $max ||= 0;
 382         $self->{article} = $min;
 383         my $est_size = $max - $min;
 384         "211 $est_size $min $max $group";
 385 }
 386
 387 sub article_adj ($$) {
 388         my ($self, $off) = @_;
 389         my $ng = $self->{ng} or return '412 no newsgroup selected';
 390
 391         my $n = $self->{article};
 392         defined $n or return '420 no current article has been selected';
 393
 394         $n += $off;
 395         my $mid = $ng->mm->mid_for($n);
 396         unless ($mid) {
 397                 $n = $off > 0 ? 'next' : 'previous';
 398                 return "421 no $n article in this group";
 399         }
 400         $self->{article} = $n;
 401         "223 $n <$mid> article retrieved - request text separately";
 402 }
 403
 404 sub cmd_next ($) { article_adj($_[0], 1) }
 405 sub cmd_last ($) { article_adj($_[0], -1) }
 406
 407 # We want to encourage using email and CC-ing everybody involved to avoid
 408 # the single-point-of-failure a single server provides.
 409 sub cmd_post ($) {
 410         my ($self) = @_;
 411         my $ng = $self->{ng};
 412         $ng ? "440 mailto:$ng->{-primary_address} to post"
 413                 : '440 posting not allowed'
 414 }
 415
 416 sub cmd_quit ($) {
 417         my ($self) = @_;
 418         res($self, '205 closing connection - goodbye!');
 419         $self->shutdn;
 420         undef;
 421 }
 422
 423 sub header_append ($$$) {
 424         my ($hdr, $k, $v) = @_;
 425         my @v = $hdr->header($k);
 426         foreach (@v) {
 427                 return if $v eq $_;
 428         }
 429         $hdr->header_set($k, @v, $v);
 430 }
 431
 432 sub xref ($$$$) {
 433         my ($self, $ng, $n, $mid) = @_;
 434         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 435
 436         # num_for is pretty cheap and sometimes we'll lookup the existence
 437         # of an article without getting even the OVER info.  In other words,
 438         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 439         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 440         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 441                 next if $ng eq $other;
 442                 my $num = eval { $other->mm->num_for($mid) } or next;
 443                 $ret .= " $other->{newsgroup}:$num";
 444         }
 445         $ret;
 446 }
 447
 448 sub set_nntp_headers ($$$$$) {
 449         my ($self, $hdr, $ng, $n, $mid) = @_;
 450
 451         # why? leafnode requires a Path: header for some inexplicable
 452         # reason.  We'll fake the shortest one possible.
 453         $hdr->header_set('Path', 'y');
 454
 455         # leafnode (and maybe other NNTP clients) have trouble dealing
 456         # with v2 messages which have multiple Message-IDs (either due
 457         # to our own content-based dedupe or buggy git-send-email versions).
 458         my @mids = $hdr->header('Message-ID');
 459         if (scalar(@mids) > 1) {
 460                 my $mid0 = "<$mid>";
 461                 $hdr->header_set('Message-ID', $mid0);
 462                 my @alt = $hdr->header('X-Alt-Message-ID');
 463                 my %seen = map { $_ => 1 } (@alt, $mid0);
 464                 foreach my $m (@mids) {
 465                         next if $seen{$m}++;
 466                         push @alt, $m;
 467                 }
 468                 $hdr->header_set('X-Alt-Message-ID', @alt);
 469         }
 470
 471         # clobber some
 472         my $xref = xref($self, $ng, $n, $mid);
 473         $hdr->header_set('Xref', $xref);
 474         $xref =~ s/:[0-9]+//g;
 475         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 476         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 477         if (my $url = $ng->base_url) {
 478                 $mid = mid_escape($mid);
 479                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 480                 header_append($hdr, 'List-Archive', "<$url>");
 481         }
 482 }
 483
 484 sub art_lookup ($$$) {
 485         my ($self, $art, $set_headers) = @_;
 486         my $ng = $self->{ng};
 487         my ($n, $mid);
 488         my $err;
 489         if (defined $art) {
 490                 if ($art =~ /\A[0-9]+\z/) {
 491                         $err = '423 no such article number in this group';
 492                         $n = int($art);
 493                         goto find_mid;
 494                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 495                         $mid = $1;
 496                         $err = r430;
 497                         $n = $ng->mm->num_for($mid) if $ng;
 498                         goto found if defined $n;
 499                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 500                                 $n = $g->mm->num_for($mid);
 501                                 if (defined $n) {
 502                                         $ng = $g;
 503                                         goto found;
 504                                 }
 505                         }
 506                         return $err;
 507                 } else {
 508                         return r501;
 509                 }
 510         } else {
 511                 $err = '420 no current article has been selected';
 512                 $n = $self->{article};
 513                 defined $n or return $err;
 514 find_mid:
 515                 $ng or return '412 no newsgroup has been selected';
 516                 $mid = $ng->mm->mid_for($n);
 517                 defined $mid or return $err;
 518         }
 519 found:
 520         my $smsg = $ng->over->get_art($n) or return $err;
 521         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 522         my $s = Email::Simple->new($msg);
 523         if ($set_headers) {
 524                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 525
 526                 # must be last
 527                 $s->body_set('') if ($set_headers == 2);
 528         }
 529         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 530 }
 531
 532 sub simple_body_write ($$) {
 533         my ($self, $s) = @_;
 534         my $body = $s->body;
 535         $s->body_set('');
 536         $body =~ s/^\./../smg;
 537         $body =~ s/(?<!\r)\n/\r\n/sg;
 538         msg_more($self, $body);
 539         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 540         '.'
 541 }
 542
 543 sub set_art {
 544         my ($self, $art) = @_;
 545         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 546 }
 547
 548 sub _header ($) {
 549         my $hdr = $_[0]->header_obj->as_string;
 550         utf8::encode($hdr);
 551         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 552
 553         # for leafnode compatibility, we need to ensure Message-ID headers
 554         # are only a single line.  We can't subclass Email::Simple::Header
 555         # and override _default_fold_at in here, either; since that won't
 556         # affect messages already in the archive.
 557         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 558
 559         $hdr
 560 }
 561
 562 sub cmd_article ($;$) {
 563         my ($self, $art) = @_;
 564         my $r = art_lookup($self, $art, 1);
 565         return $r unless ref $r;
 566         my ($n, $mid, $s) = @$r;
 567         set_art($self, $art);
 568         more($self, "220 $n <$mid> article retrieved - head and body follow");
 569         msg_more($self, _header($s));
 570         msg_more($self, "\r\n");
 571         simple_body_write($self, $s);
 572 }
 573
 574 sub cmd_head ($;$) {
 575         my ($self, $art) = @_;
 576         my $r = art_lookup($self, $art, 2);
 577         return $r unless ref $r;
 578         my ($n, $mid, $s) = @$r;
 579         set_art($self, $art);
 580         more($self, "221 $n <$mid> article retrieved - head follows");
 581         msg_more($self, _header($s));
 582         '.'
 583 }
 584
 585 sub cmd_body ($;$) {
 586         my ($self, $art) = @_;
 587         my $r = art_lookup($self, $art, 0);
 588         return $r unless ref $r;
 589         my ($n, $mid, $s) = @$r;
 590         set_art($self, $art);
 591         more($self, "222 $n <$mid> article retrieved - body follows");
 592         simple_body_write($self, $s);
 593 }
 594
 595 sub cmd_stat ($;$) {
 596         my ($self, $art) = @_;
 597         my $r = art_lookup($self, $art, 0);
 598         return $r unless ref $r;
 599         my ($n, $mid, undef) = @$r;
 600         set_art($self, $art);
 601         "223 $n <$mid> article retrieved - request text separately";
 602 }
 603
 604 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 605
 606 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 607
 608 sub cmd_help ($) {
 609         my ($self) = @_;
 610         more($self, '100 help text follows');
 611         '.'
 612 }
 613
 614 sub get_range ($$) {
 615         my ($self, $range) = @_;
 616         my $ng = $self->{ng} or return '412 no news group has been selected';
 617         defined $range or return '420 No article(s) selected';
 618         my ($beg, $end);
 619         my ($min, $max) = $ng->mm->minmax;
 620         if ($range =~ /\A([0-9]+)\z/) {
 621                 $beg = $end = $1;
 622         } elsif ($range =~ /\A([0-9]+)-\z/) {
 623                 ($beg, $end) = ($1, $max);
 624         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 625                 ($beg, $end) = ($1, $2);
 626         } else {
 627                 return r501;
 628         }
 629         $beg = $min if ($beg < $min);
 630         $end = $max if ($end > $max);
 631         return '420 No article(s) selected' if ($beg > $end);
 632         [ $beg, $end ];
 633 }
 634
 635 sub long_response ($$) {
 636         my ($self, $cb) = @_;
 637         die "BUG: nested long response" if $self->{long_res};
 638
 639         my $fd = fileno($self->{sock});
 640         defined $fd or return;
 641         # make sure we disable reading during a long response,
 642         # clients should not be sending us stuff and making us do more
 643         # work while we are stream a response to them
 644         my $t0 = now();
 645         $self->{long_res} = sub {
 646                 my $more = eval { $cb->() };
 647                 if ($@ || !$self->{sock}) { # something bad happened...
 648                         delete $self->{long_res};
 649
 650                         if ($@) {
 651                                 err($self,
 652                                     "%s during long response[$fd] - %0.6f",
 653                                     $@, now() - $t0);
 654                         }
 655                         if ($self->{sock}) {
 656                                 update_idle_time($self);
 657                                 requeue($self);
 658                         } else {
 659                                 out($self, " deferred[$fd] aborted - %0.6f",
 660                                            now() - $t0);
 661                         }
 662                 } elsif ($more) { # $self->{wbuf}:
 663                         # no recursion, schedule another call ASAP
 664                         # but only after all pending writes are done
 665                         update_idle_time($self);
 666                         requeue($self);
 667                 } else { # all done!
 668                         delete $self->{long_res};
 669                         res($self, '.');
 670                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 671                         requeue($self);
 672                 }
 673         };
 674         $self->{long_res}->(); # kick off!
 675         undef;
 676 }
 677
 678 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 679         my ($self, $xhdr, $range) = @_;
 680
 681         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 682                 my ($ng, $n) = mid_lookup($self, $1);
 683                 return r430 unless $n;
 684                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 685         } else { # numeric range
 686                 $range = $self->{article} unless defined $range;
 687                 my $r = get_range($self, $range);
 688                 return $r unless ref $r;
 689                 my $mm = $self->{ng}->mm;
 690                 my ($beg, $end) = @$r;
 691                 more($self, $xhdr ? r221 : r225);
 692                 long_response($self, sub {
 693                         my $r = $mm->msg_range(\$beg, $end);
 694                         @$r or return;
 695                         more($self, join("\r\n", map {
 696                                 "$_->[0] <$_->[1]>"
 697                         } @$r));
 698                         1;
 699                 });
 700         }
 701 }
 702
 703 sub mid_lookup ($$) {
 704         my ($self, $mid) = @_;
 705         my $self_ng = $self->{ng};
 706         if ($self_ng) {
 707                 my $n = $self_ng->mm->num_for($mid);
 708                 return ($self_ng, $n) if defined $n;
 709         }
 710         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 711                 next if defined $self_ng && $ng eq $self_ng;
 712                 my $n = $ng->mm->num_for($mid);
 713                 return ($ng, $n) if defined $n;
 714         }
 715         (undef, undef);
 716 }
 717
 718 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 719         my ($self, $xhdr, $range) = @_;
 720
 721         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 722                 my $mid = $1;
 723                 my ($ng, $n) = mid_lookup($self, $mid);
 724                 return r430 unless $n;
 725                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 726                                 xref($self, $ng, $n, $mid));
 727         } else { # numeric range
 728                 $range = $self->{article} unless defined $range;
 729                 my $r = get_range($self, $range);
 730                 return $r unless ref $r;
 731                 my $ng = $self->{ng};
 732                 my $mm = $ng->mm;
 733                 my ($beg, $end) = @$r;
 734                 more($self, $xhdr ? r221 : r225);
 735                 long_response($self, sub {
 736                         my $r = $mm->msg_range(\$beg, $end);
 737                         @$r or return;
 738                         more($self, join("\r\n", map {
 739                                 my $num = $_->[0];
 740                                 "$num ".xref($self, $ng, $num, $_->[1]);
 741                         } @$r));
 742                         1;
 743                 });
 744         }
 745 }
 746
 747 sub over_header_for {
 748         my ($over, $num, $field) = @_;
 749         my $smsg = $over->get_art($num) or return;
 750         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 751         $smsg->{$field};
 752 }
 753
 754 sub hdr_searchmsg ($$$$) {
 755         my ($self, $xhdr, $field, $range) = @_;
 756         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 757                 my ($ng, $n) = mid_lookup($self, $1);
 758                 return r430 unless defined $n;
 759                 my $v = over_header_for($ng->over, $n, $field);
 760                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 761         } else { # numeric range
 762                 $range = $self->{article} unless defined $range;
 763                 my $over = $self->{ng}->over;
 764                 my $mm = $self->{ng}->mm;
 765                 my $r = get_range($self, $range);
 766                 return $r unless ref $r;
 767                 my ($beg, $end) = @$r;
 768                 more($self, $xhdr ? r221 : r225);
 769                 my $cur = $beg;
 770                 long_response($self, sub {
 771                         my $msgs = $over->query_xover($cur, $end);
 772                         my $nr = scalar @$msgs or return;
 773                         my $tmp = '';
 774                         foreach my $s (@$msgs) {
 775                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 776                         }
 777                         utf8::encode($tmp);
 778                         msg_more($self, $tmp);
 779                         $cur = $msgs->[-1]->{num} + 1;
 780                 });
 781         }
 782 }
 783
 784 sub do_hdr ($$$;$) {
 785         my ($self, $xhdr, $header, $range) = @_;
 786         my $sub = lc $header;
 787         if ($sub eq 'message-id') {
 788                 hdr_message_id($self, $xhdr, $range);
 789         } elsif ($sub eq 'xref') {
 790                 hdr_xref($self, $xhdr, $range);
 791         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 792                                 bytes|lines)\z/x) {
 793                 hdr_searchmsg($self, $xhdr, $sub, $range);
 794         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 795                 hdr_searchmsg($self, $xhdr, $1, $range);
 796         } else {
 797                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 798         }
 799 }
 800
 801 # RFC 3977
 802 sub cmd_hdr ($$;$) {
 803         my ($self, $header, $range) = @_;
 804         do_hdr($self, 0, $header, $range);
 805 }
 806
 807 # RFC 2980
 808 sub cmd_xhdr ($$;$) {
 809         my ($self, $header, $range) = @_;
 810         do_hdr($self, 1, $header, $range);
 811 }
 812
 813 sub hdr_mid_prefix ($$$$$) {
 814         my ($self, $xhdr, $ng, $n, $mid) = @_;
 815         return $mid if $xhdr;
 816
 817         # HDR for RFC 3977 users
 818         if (my $self_ng = $self->{ng}) {
 819                 ($self_ng eq $ng) ? $n : '0';
 820         } else {
 821                 '0';
 822         }
 823 }
 824
 825 sub hdr_mid_response ($$$$$$) {
 826         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 827         my $res = '';
 828         if ($xhdr) {
 829                 $res .= r221 . "\r\n";
 830                 $res .= "$mid $v\r\n";
 831         } else {
 832                 $res .= r225 . "\r\n";
 833                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 834                 $res .= "$pfx $v\r\n";
 835         }
 836         res($self, $res .= '.');
 837         undef;
 838 }
 839
 840 sub cmd_xrover ($;$) {
 841         my ($self, $range) = @_;
 842         my $ng = $self->{ng} or return '412 no newsgroup selected';
 843         (defined $range && $range =~ /[<>]/) and
 844                 return '420 No article(s) selected'; # no message IDs
 845
 846         $range = $self->{article} unless defined $range;
 847         my $r = get_range($self, $range);
 848         return $r unless ref $r;
 849         my ($beg, $end) = @$r;
 850         my $mm = $ng->mm;
 851         my $over = $ng->over;
 852         more($self, '224 Overview information follows');
 853
 854         long_response($self, sub {
 855                 my $h = over_header_for($over, $beg, 'references');
 856                 more($self, "$beg $h") if defined($h);
 857                 $beg++ < $end;
 858         });
 859 }
 860
 861 sub over_line ($$$$) {
 862         my ($self, $ng, $num, $smsg) = @_;
 863         # n.b. field access and procedural calls can be
 864         # 10%-15% faster than OO method calls:
 865         my $s = join("\t", $num,
 866                 $smsg->{subject},
 867                 $smsg->{from},
 868                 PublicInbox::SearchMsg::date($smsg),
 869                 "<$smsg->{mid}>",
 870                 $smsg->{references},
 871                 $smsg->{bytes},
 872                 $smsg->{lines},
 873                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 874         utf8::encode($s);
 875         $s
 876 }
 877
 878 sub cmd_over ($;$) {
 879         my ($self, $range) = @_;
 880         if ($range && $range =~ /\A<(.+)>\z/) {
 881                 my ($ng, $n) = mid_lookup($self, $1);
 882                 defined $n or return r430;
 883                 my $smsg = $ng->over->get_art($n) or return r430;
 884                 more($self, '224 Overview information follows (multi-line)');
 885
 886                 # Only set article number column if it's the current group
 887                 my $self_ng = $self->{ng};
 888                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 889                 more($self, over_line($self, $ng, $n, $smsg));
 890                 '.';
 891         } else {
 892                 cmd_xover($self, $range);
 893         }
 894 }
 895
 896 sub cmd_xover ($;$) {
 897         my ($self, $range) = @_;
 898         $range = $self->{article} unless defined $range;
 899         my $r = get_range($self, $range);
 900         return $r unless ref $r;
 901         my ($beg, $end) = @$r;
 902         more($self, "224 Overview information follows for $beg to $end");
 903         my $over = $self->{ng}->over;
 904         my $cur = $beg;
 905         long_response($self, sub {
 906                 my $msgs = $over->query_xover($cur, $end);
 907                 my $nr = scalar @$msgs or return;
 908
 909                 # OVERVIEW.FMT
 910                 more($self, join("\r\n", map {
 911                         over_line($self, $self->{ng}, $_->{num}, $_);
 912                         } @$msgs));
 913                 $cur = $msgs->[-1]->{num} + 1;
 914         });
 915 }
 916
 917 sub cmd_starttls ($) {
 918         my ($self) = @_;
 919         my $sock = $self->{sock} or return;
 920         # RFC 4642 2.2.1
 921         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 922         my $opt = $self->{nntpd}->{accept_tls} or
 923                 return '580 can not initiate TLS negotiation';
 924         res($self, '382 Continue with TLS negotiation');
 925         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 926         requeue($self) if PublicInbox::DS::accept_tls_step($self);
 927         undef;
 928 }
 929
 930 sub cmd_xpath ($$) {
 931         my ($self, $mid) = @_;
 932         return r501 unless $mid =~ /\A<(.+)>\z/;
 933         $mid = $1;
 934         my @paths;
 935         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 936                 my $n = $ng->mm->num_for($mid);
 937                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 938         }
 939         return '430 no such article on server' unless @paths;
 940         '223 '.join(' ', @paths);
 941 }
 942
 943 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 944
 945 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 946
 947 sub do_write ($$) {
 948         my $self = $_[0];
 949         my $done = $self->write(\($_[1]));
 950         return 0 unless $self->{sock};
 951
 952         $done;
 953 }
 954
 955 sub err ($$;@) {
 956         my ($self, $fmt, @args) = @_;
 957         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 958 }
 959
 960 sub out ($$;@) {
 961         my ($self, $fmt, @args) = @_;
 962         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 963 }
 964
 965 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 966 sub event_step {
 967         my ($self) = @_;
 968
 969         return unless $self->flush_write && $self->{sock};
 970
 971         update_idle_time($self);
 972         # only read more requests if we've drained the write buffer,
 973         # otherwise we can be buffering infinitely w/o backpressure
 974
 975         use constant LINE_MAX => 512; # RFC 977 section 2.3
 976         my $rbuf = \($self->{rbuf});
 977         my $r = 1;
 978
 979         if (index($$rbuf, "\n") < 0) {
 980                 my $off = bytes::length($$rbuf);
 981                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 982         }
 983         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 984                 my $line = $1;
 985                 return $self->close if $line =~ /[[:cntrl:]]/s;
 986                 my $t0 = now();
 987                 my $fd = fileno($self->{sock});
 988                 $r = eval { process_line($self, $line) };
 989                 my $d = $self->{long_res} ?
 990                         " deferred[$fd]" : '';
 991                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 992         }
 993
 994         return $self->close if $r < 0;
 995         my $len = bytes::length($$rbuf);
 996         return $self->close if ($len >= LINE_MAX);
 997         update_idle_time($self);
 998
 999         # maybe there's more pipelined data, or we'll have
1000         # to register it for socket-readiness notifications
1001         requeue($self) unless ($self->{long_res} || $self->{wbuf});
1002 }
1003
1004 sub not_idle_long ($$) {
1005         my ($self, $now) = @_;
1006         my $sock = $self->{sock} or return;
1007         my $ary = $EXPMAP->{fileno($sock)} or return;
1008         my $exp_at = $ary->[0] + $EXPTIME;
1009         $exp_at > $now;
1010 }
1011
1012 # for graceful shutdown in PublicInbox::Daemon:
1013 sub busy {
1014         my ($self, $now) = @_;
1015         ($self->{rbuf} ne '' || $self->{long_res} ||
1016                 $self->{wbuf} || not_idle_long($self, $now));
1017 }
1018
1019 1;