lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng long_cb);
  10 use PublicInbox::MID qw(mid_escape);
  11 use Email::Simple;
  12 use POSIX qw(strftime);
  13 use PublicInbox::DS qw(now);
  14 use Digest::SHA qw(sha1_hex);
  15 use Time::Local qw(timegm timelocal);
  16 use constant {
  17         LINE_MAX => 512, # RFC 977 section 2.3
  18         r501 => '501 command syntax error',
  19         r502 => '502 Command unavailable',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24 };
  25 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  26 use Errno qw(EAGAIN);
  27
  28 my @OVERVIEW = qw(Subject From Date Message-ID References);
  29 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  30                 "Xref:full\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33 my $CAPABILITIES = <<"";
  34 101 Capability list:\r
  35 VERSION 2\r
  36 READER\r
  37 NEWNEWS\r
  38 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  39 HDR\r
  40 OVER\r
  41
  42 my $have_deflate;
  43
  44 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  45
  46 sub new ($$$) {
  47         my ($class, $sock, $nntpd) = @_;
  48         my $self = fields::new($class);
  49         my $ev = EPOLLIN;
  50         my $wbuf;
  51         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  52                 return CORE::close($sock) if $! != EAGAIN;
  53                 $ev = PublicInbox::TLS::epollbit();
  54                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  55         }
  56         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  57         $self->{nntpd} = $nntpd;
  58         if ($wbuf) {
  59                 $self->{wbuf} = $wbuf;
  60         } else {
  61                 greet($self);
  62         }
  63         $self->update_idle_time;
  64         $self;
  65 }
  66
  67 sub args_ok ($$) {
  68         my ($cb, $argc) = @_;
  69         my $tot = prototype $cb;
  70         my ($nreq, undef) = split(';', $tot);
  71         $nreq = ($nreq =~ tr/$//) - 1;
  72         $tot = ($tot =~ tr/$//) - 1;
  73         ($argc <= $tot && $argc >= $nreq);
  74 }
  75
  76 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  77 sub process_line ($$) {
  78         my ($self, $l) = @_;
  79         my ($req, @args) = split(/[ \t]/, $l);
  80         return 1 unless defined($req); # skip blank line
  81         $req = $self->can('cmd_'.lc($req));
  82         return res($self, '500 command not recognized') unless $req;
  83         return res($self, r501) unless args_ok($req, scalar @args);
  84
  85         my $res = eval { $req->($self, @args) };
  86         my $err = $@;
  87         if ($err && $self->{sock}) {
  88                 local $/ = "\n";
  89                 chomp($l);
  90                 err($self, 'error from: %s (%s)', $l, $err);
  91                 $res = '503 program fault - command not performed';
  92         }
  93         return 0 unless defined $res;
  94         res($self, $res);
  95 }
  96
  97 # The keyword argument is not used (rfc3977 5.2.2)
  98 sub cmd_capabilities ($;$) {
  99         my ($self, undef) = @_;
 100         my $res = $CAPABILITIES;
 101         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 102                         $self->{nntpd}->{accept_tls}) {
 103                 $res .= "STARTTLS\r\n";
 104         }
 105         $res .= '.';
 106 }
 107
 108 sub cmd_mode ($$) {
 109         my ($self, $arg) = @_;
 110         $arg = uc $arg;
 111         return r501 unless $arg eq 'READER';
 112         '201 Posting prohibited';
 113 }
 114
 115 sub cmd_slave ($) { '202 slave status noted' }
 116
 117 sub cmd_xgtitle ($;$) {
 118         my ($self, $wildmat) = @_;
 119         more($self, '282 list of groups and descriptions follows');
 120         list_newsgroups($self, $wildmat);
 121         '.'
 122 }
 123
 124 sub list_overview_fmt ($) {
 125         my ($self) = @_;
 126         $self->msg_more($OVERVIEW_FMT);
 127 }
 128
 129 sub list_headers ($;$) {
 130         my ($self) = @_;
 131         $self->msg_more($LIST_HEADERS);
 132 }
 133
 134 sub list_active ($;$) {
 135         my ($self, $wildmat) = @_;
 136         wildmat2re($wildmat);
 137         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 138                 $ng->{newsgroup} =~ $wildmat or next;
 139                 group_line($self, $ng);
 140         }
 141 }
 142
 143 sub list_active_times ($;$) {
 144         my ($self, $wildmat) = @_;
 145         wildmat2re($wildmat);
 146         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 147                 $ng->{newsgroup} =~ $wildmat or next;
 148                 my $c = eval { $ng->mm->created_at } || time;
 149                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 150         }
 151 }
 152
 153 sub list_newsgroups ($;$) {
 154         my ($self, $wildmat) = @_;
 155         wildmat2re($wildmat);
 156         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 157                 $ng->{newsgroup} =~ $wildmat or next;
 158                 my $d = $ng->description;
 159                 more($self, "$ng->{newsgroup} $d");
 160         }
 161 }
 162
 163 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 164 sub cmd_list ($;$$) {
 165         my ($self, @args) = @_;
 166         if (scalar @args) {
 167                 my $arg = shift @args;
 168                 $arg =~ tr/A-Z./a-z_/;
 169                 $arg = "list_$arg";
 170                 $arg = $self->can($arg);
 171                 return r501 unless $arg && args_ok($arg, scalar @args);
 172                 more($self, '215 information follows');
 173                 $arg->($self, @args);
 174         } else {
 175                 more($self, '215 list of newsgroups follows');
 176                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                         group_line($self, $ng);
 178                 }
 179         }
 180         '.'
 181 }
 182
 183 sub listgroup_range_i {
 184         my ($self, $beg, $end) = @_;
 185         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 186         scalar(@$r) or return;
 187         more($self, join("\r\n", map { $_->[0] } @$r));
 188         1;
 189 }
 190
 191 sub listgroup_all_i {
 192         my ($self, $num) = @_;
 193         my $ary = $self->{ng}->mm->ids_after($num);
 194         scalar(@$ary) or return;
 195         more($self, join("\r\n", @$ary));
 196         1;
 197 }
 198
 199 sub cmd_listgroup ($;$$) {
 200         my ($self, $group, $range) = @_;
 201         if (defined $group) {
 202                 my $res = cmd_group($self, $group);
 203                 return $res if ($res !~ /\A211 /);
 204                 more($self, $res);
 205         }
 206         $self->{ng} or return '412 no newsgroup selected';
 207         if (defined $range) {
 208                 my $r = get_range($self, $range);
 209                 return $r unless ref $r;
 210                 long_response($self, \&listgroup_range_i, @$r);
 211         } else { # grab every article number
 212                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 213         }
 214 }
 215
 216 sub parse_time ($$;$) {
 217         my ($date, $time, $gmt) = @_;
 218         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 219         if (defined $gmt) {
 220                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 221                 $gmt = 1;
 222         }
 223         my @now = $gmt ? gmtime : localtime;
 224         my ($YYYY, $MM, $DD);
 225         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 226                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 227         } else { # legacy clients send YYMMDD
 228                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 229                 my $cur_year = $now[5] + 1900;
 230                 if ($YYYY > $cur_year) {
 231                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 232                 }
 233         }
 234         if ($gmt) {
 235                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 236         } else {
 237                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 238         }
 239 }
 240
 241 sub group_line ($$) {
 242         my ($self, $ng) = @_;
 243         my ($min, $max) = $ng->mm->minmax;
 244         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 245 }
 246
 247 sub cmd_newgroups ($$$;$$) {
 248         my ($self, $date, $time, $gmt, $dists) = @_;
 249         my $ts = eval { parse_time($date, $time, $gmt) };
 250         return r501 if $@;
 251
 252         # TODO dists
 253         more($self, '231 list of new newsgroups follows');
 254         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 255                 my $c = eval { $ng->mm->created_at } || 0;
 256                 next unless $c > $ts;
 257                 group_line($self, $ng);
 258         }
 259         '.'
 260 }
 261
 262 sub wildmat2re (;$) {
 263         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 264         my %keep;
 265         my $salt = rand;
 266         my $tmp = $_[0];
 267
 268         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 269                 my $orig = $1;
 270                 my $key = sha1_hex($orig . $salt);
 271                 $orig =~ s/([^\w\-])+/\Q$1/g;
 272                 $keep{$key} = $orig;
 273                 $key
 274                 #gex;
 275         my %map = ('*' => '.*', '?' => '.' );
 276         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 277         if (scalar %keep) {
 278                 $tmp =~ s#([a-f0-9]{40})#
 279                         my $orig = $keep{$1};
 280                         defined $orig ? $orig : $1;
 281                         #ge;
 282         }
 283         $_[0] = qr/\A$tmp\z/;
 284 }
 285
 286 sub ngpat2re (;$) {
 287         return $_[0] = qr/\A\z/ unless defined $_[0];
 288         my %map = ('*' => '.*', ',' => '|');
 289         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 290         $_[0] = qr/\A(?:$_[0])\z/;
 291 }
 292
 293 sub newnews_i {
 294         my ($self, $overs, $ts, $prev) = @_;
 295         my $over = $overs->[0];
 296         my $msgs = $over->query_ts($ts, $$prev);
 297         if (scalar @$msgs) {
 298                 more($self, '<' .
 299                         join(">\r\n<", map { $_->mid } @$msgs ).
 300                         '>');
 301                 $$prev = $msgs->[-1]->{num};
 302         } else {
 303                 shift @$overs;
 304                 if (@$overs) { # continue onto next newsgroup
 305                         $$prev = 0;
 306                         return 1;
 307                 } else { # break out of the long response.
 308                         return;
 309                 }
 310         }
 311 }
 312
 313 sub cmd_newnews ($$$$;$$) {
 314         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 315         my $ts = eval { parse_time($date, $time, $gmt) };
 316         return r501 if $@;
 317         more($self, '230 list of new articles by message-id follows');
 318         my ($keep, $skip) = split('!', $newsgroups, 2);
 319         ngpat2re($keep);
 320         ngpat2re($skip);
 321         my @overs;
 322         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 323                 $ng->{newsgroup} =~ $keep or next;
 324                 $ng->{newsgroup} =~ $skip and next;
 325                 my $over = $ng->over or next;
 326                 push @overs, $over;
 327         };
 328         return '.' unless @overs;
 329
 330         my $prev = 0;
 331         long_response($self, \&newnews_i, \@overs, $ts, \$prev);
 332 }
 333
 334 sub cmd_group ($$) {
 335         my ($self, $group) = @_;
 336         my $no_such = '411 no such news group';
 337         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 338
 339         $self->{ng} = $ng;
 340         my ($min, $max) = $ng->mm->minmax;
 341         $min ||= 0;
 342         $max ||= 0;
 343         $self->{article} = $min;
 344         my $est_size = $max - $min;
 345         "211 $est_size $min $max $group";
 346 }
 347
 348 sub article_adj ($$) {
 349         my ($self, $off) = @_;
 350         my $ng = $self->{ng} or return '412 no newsgroup selected';
 351
 352         my $n = $self->{article};
 353         defined $n or return '420 no current article has been selected';
 354
 355         $n += $off;
 356         my $mid = $ng->mm->mid_for($n);
 357         unless ($mid) {
 358                 $n = $off > 0 ? 'next' : 'previous';
 359                 return "421 no $n article in this group";
 360         }
 361         $self->{article} = $n;
 362         "223 $n <$mid> article retrieved - request text separately";
 363 }
 364
 365 sub cmd_next ($) { article_adj($_[0], 1) }
 366 sub cmd_last ($) { article_adj($_[0], -1) }
 367
 368 # We want to encourage using email and CC-ing everybody involved to avoid
 369 # the single-point-of-failure a single server provides.
 370 sub cmd_post ($) {
 371         my ($self) = @_;
 372         my $ng = $self->{ng};
 373         $ng ? "440 mailto:$ng->{-primary_address} to post"
 374                 : '440 posting not allowed'
 375 }
 376
 377 sub cmd_quit ($) {
 378         my ($self) = @_;
 379         res($self, '205 closing connection - goodbye!');
 380         $self->shutdn;
 381         undef;
 382 }
 383
 384 sub header_append ($$$) {
 385         my ($hdr, $k, $v) = @_;
 386         my @v = $hdr->header($k);
 387         foreach (@v) {
 388                 return if $v eq $_;
 389         }
 390         $hdr->header_set($k, @v, $v);
 391 }
 392
 393 sub xref ($$$$) {
 394         my ($self, $ng, $n, $mid) = @_;
 395         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 396
 397         # num_for is pretty cheap and sometimes we'll lookup the existence
 398         # of an article without getting even the OVER info.  In other words,
 399         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 400         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 401         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 402                 next if $ng eq $other;
 403                 my $num = eval { $other->mm->num_for($mid) } or next;
 404                 $ret .= " $other->{newsgroup}:$num";
 405         }
 406         $ret;
 407 }
 408
 409 sub set_nntp_headers ($$$$$) {
 410         my ($self, $hdr, $ng, $n, $mid) = @_;
 411
 412         # why? leafnode requires a Path: header for some inexplicable
 413         # reason.  We'll fake the shortest one possible.
 414         $hdr->header_set('Path', 'y');
 415
 416         # leafnode (and maybe other NNTP clients) have trouble dealing
 417         # with v2 messages which have multiple Message-IDs (either due
 418         # to our own content-based dedupe or buggy git-send-email versions).
 419         my @mids = $hdr->header('Message-ID');
 420         if (scalar(@mids) > 1) {
 421                 my $mid0 = "<$mid>";
 422                 $hdr->header_set('Message-ID', $mid0);
 423                 my @alt = $hdr->header('X-Alt-Message-ID');
 424                 my %seen = map { $_ => 1 } (@alt, $mid0);
 425                 foreach my $m (@mids) {
 426                         next if $seen{$m}++;
 427                         push @alt, $m;
 428                 }
 429                 $hdr->header_set('X-Alt-Message-ID', @alt);
 430         }
 431
 432         # clobber some
 433         my $xref = xref($self, $ng, $n, $mid);
 434         $hdr->header_set('Xref', $xref);
 435         $xref =~ s/:[0-9]+//g;
 436         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 437         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 438         if (my $url = $ng->base_url) {
 439                 $mid = mid_escape($mid);
 440                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 441                 header_append($hdr, 'List-Archive', "<$url>");
 442         }
 443 }
 444
 445 sub art_lookup ($$$) {
 446         my ($self, $art, $set_headers) = @_;
 447         my $ng = $self->{ng};
 448         my ($n, $mid);
 449         my $err;
 450         if (defined $art) {
 451                 if ($art =~ /\A[0-9]+\z/) {
 452                         $err = '423 no such article number in this group';
 453                         $n = int($art);
 454                         goto find_mid;
 455                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 456                         $mid = $1;
 457                         $err = r430;
 458                         $n = $ng->mm->num_for($mid) if $ng;
 459                         goto found if defined $n;
 460                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 461                                 $n = $g->mm->num_for($mid);
 462                                 if (defined $n) {
 463                                         $ng = $g;
 464                                         goto found;
 465                                 }
 466                         }
 467                         return $err;
 468                 } else {
 469                         return r501;
 470                 }
 471         } else {
 472                 $err = '420 no current article has been selected';
 473                 $n = $self->{article};
 474                 defined $n or return $err;
 475 find_mid:
 476                 $ng or return '412 no newsgroup has been selected';
 477                 $mid = $ng->mm->mid_for($n);
 478                 defined $mid or return $err;
 479         }
 480 found:
 481         my $smsg = $ng->over->get_art($n) or return $err;
 482         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 483
 484         # Email::Simple->new will modify $msg in-place as documented
 485         # in its manpage, so what's left is the body and we won't need
 486         # to call Email::Simple::body(), later
 487         my $hdr = Email::Simple->new($msg)->header_obj;
 488         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 489         [ $n, $mid, $msg, $hdr ];
 490 }
 491
 492 sub msg_body_write ($$) {
 493         my ($self, $msg) = @_;
 494
 495         # these can momentarily double the memory consumption :<
 496         $$msg =~ s/^\./../smg;
 497         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 498         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 499         $self->msg_more($$msg);
 500         '.'
 501 }
 502
 503 sub set_art {
 504         my ($self, $art) = @_;
 505         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 506 }
 507
 508 sub msg_hdr_write ($$$) {
 509         my ($self, $hdr, $body_follows) = @_;
 510         $hdr = $hdr->as_string;
 511         utf8::encode($hdr);
 512         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 513
 514         # for leafnode compatibility, we need to ensure Message-ID headers
 515         # are only a single line.  We can't subclass Email::Simple::Header
 516         # and override _default_fold_at in here, either; since that won't
 517         # affect messages already in the archive.
 518         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 519         $hdr .= "\r\n" if $body_follows;
 520         $self->msg_more($hdr);
 521 }
 522
 523 sub cmd_article ($;$) {
 524         my ($self, $art) = @_;
 525         my $r = art_lookup($self, $art, 1);
 526         return $r unless ref $r;
 527         my ($n, $mid, $msg, $hdr) = @$r;
 528         set_art($self, $art);
 529         more($self, "220 $n <$mid> article retrieved - head and body follow");
 530         msg_hdr_write($self, $hdr, 1);
 531         msg_body_write($self, $msg);
 532 }
 533
 534 sub cmd_head ($;$) {
 535         my ($self, $art) = @_;
 536         my $r = art_lookup($self, $art, 2);
 537         return $r unless ref $r;
 538         my ($n, $mid, undef, $hdr) = @$r;
 539         set_art($self, $art);
 540         more($self, "221 $n <$mid> article retrieved - head follows");
 541         msg_hdr_write($self, $hdr, 0);
 542         '.'
 543 }
 544
 545 sub cmd_body ($;$) {
 546         my ($self, $art) = @_;
 547         my $r = art_lookup($self, $art, 0);
 548         return $r unless ref $r;
 549         my ($n, $mid, $msg) = @$r;
 550         set_art($self, $art);
 551         more($self, "222 $n <$mid> article retrieved - body follows");
 552         msg_body_write($self, $msg);
 553 }
 554
 555 sub cmd_stat ($;$) {
 556         my ($self, $art) = @_;
 557         my $r = art_lookup($self, $art, 0);
 558         return $r unless ref $r;
 559         my ($n, $mid) = @$r;
 560         set_art($self, $art);
 561         "223 $n <$mid> article retrieved - request text separately";
 562 }
 563
 564 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 565
 566 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 567
 568 sub cmd_help ($) {
 569         my ($self) = @_;
 570         more($self, '100 help text follows');
 571         '.'
 572 }
 573
 574 sub get_range ($$) {
 575         my ($self, $range) = @_;
 576         my $ng = $self->{ng} or return '412 no news group has been selected';
 577         defined $range or return '420 No article(s) selected';
 578         my ($beg, $end);
 579         my ($min, $max) = $ng->mm->minmax;
 580         if ($range =~ /\A([0-9]+)\z/) {
 581                 $beg = $end = $1;
 582         } elsif ($range =~ /\A([0-9]+)-\z/) {
 583                 ($beg, $end) = ($1, $max);
 584         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 585                 ($beg, $end) = ($1, $2);
 586         } else {
 587                 return r501;
 588         }
 589         $beg = $min if ($beg < $min);
 590         $end = $max if ($end > $max);
 591         return '420 No article(s) selected' if ($beg > $end);
 592         [ \$beg, $end ];
 593 }
 594
 595 sub long_step {
 596         my ($self) = @_;
 597         # wbuf is unset or empty, here; {long} may add to it
 598         my ($cb, $t0, @args) = @{$self->{long_cb}};
 599         my $more = eval { $cb->($self, @args) };
 600         if ($@ || !$self->{sock}) { # something bad happened...
 601                 delete $self->{long_cb};
 602                 my $elapsed = now() - $t0;
 603                 my $fd = fileno($self->{sock});
 604                 if ($@) {
 605                         err($self,
 606                             "%s during long response[$fd] - %0.6f",
 607                             $@, $elapsed);
 608                 }
 609                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 610                 $self->close;
 611         } elsif ($more) { # $self->{wbuf}:
 612                 $self->update_idle_time;
 613
 614                 # COMPRESS users all share the same DEFLATE context.
 615                 # Flush it here to ensure clients don't see
 616                 # each other's data
 617                 $self->zflush;
 618
 619                 # no recursion, schedule another call ASAP
 620                 # but only after all pending writes are done
 621                 my $wbuf = $self->{wbuf} ||= [];
 622                 push @$wbuf, \&long_step;
 623
 624                 # wbuf may be populated by $cb, no need to rearm if so:
 625                 $self->requeue if scalar(@$wbuf) == 1;
 626         } else { # all done!
 627                 delete $self->{long_cb};
 628                 res($self, '.');
 629                 my $elapsed = now() - $t0;
 630                 my $fd = fileno($self->{sock});
 631                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 632                 my $wbuf = $self->{wbuf};
 633                 $self->requeue unless $wbuf && @$wbuf;
 634         }
 635 }
 636
 637 sub long_response ($$;@) {
 638         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 639
 640         $self->{sock} or return;
 641         # make sure we disable reading during a long response,
 642         # clients should not be sending us stuff and making us do more
 643         # work while we are stream a response to them
 644         $self->{long_cb} = [ $cb, now(), @args ];
 645         long_step($self); # kick off!
 646         undef;
 647 }
 648
 649 sub hdr_msgid_range_i {
 650         my ($self, $beg, $end) = @_;
 651         my $r = $self->{ng}->mm->msg_range($beg, $end);
 652         @$r or return;
 653         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 654         1;
 655 }
 656
 657 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 658         my ($self, $xhdr, $range) = @_;
 659
 660         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 661                 my ($ng, $n) = mid_lookup($self, $1);
 662                 return r430 unless $n;
 663                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 664         } else { # numeric range
 665                 $range = $self->{article} unless defined $range;
 666                 my $r = get_range($self, $range);
 667                 return $r unless ref $r;
 668                 more($self, $xhdr ? r221 : r225);
 669                 long_response($self, \&hdr_msgid_range_i, @$r);
 670         }
 671 }
 672
 673 sub mid_lookup ($$) {
 674         my ($self, $mid) = @_;
 675         my $self_ng = $self->{ng};
 676         if ($self_ng) {
 677                 my $n = $self_ng->mm->num_for($mid);
 678                 return ($self_ng, $n) if defined $n;
 679         }
 680         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 681                 next if defined $self_ng && $ng eq $self_ng;
 682                 my $n = $ng->mm->num_for($mid);
 683                 return ($ng, $n) if defined $n;
 684         }
 685         (undef, undef);
 686 }
 687
 688 sub xref_range_i {
 689         my ($self, $beg, $end) = @_;
 690         my $ng = $self->{ng};
 691         my $r = $ng->mm->msg_range($beg, $end);
 692         @$r or return;
 693         more($self, join("\r\n", map {
 694                 my $num = $_->[0];
 695                 "$num ".xref($self, $ng, $num, $_->[1]);
 696         } @$r));
 697         1;
 698 }
 699
 700 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 701         my ($self, $xhdr, $range) = @_;
 702
 703         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 704                 my $mid = $1;
 705                 my ($ng, $n) = mid_lookup($self, $mid);
 706                 return r430 unless $n;
 707                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 708                                 xref($self, $ng, $n, $mid));
 709         } else { # numeric range
 710                 $range = $self->{article} unless defined $range;
 711                 my $r = get_range($self, $range);
 712                 return $r unless ref $r;
 713                 more($self, $xhdr ? r221 : r225);
 714                 long_response($self, \&xref_range_i, @$r);
 715         }
 716 }
 717
 718 sub over_header_for {
 719         my ($over, $num, $field) = @_;
 720         my $smsg = $over->get_art($num) or return;
 721         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 722         $smsg->{$field};
 723 }
 724
 725 sub searchmsg_range_i {
 726         my ($self, $beg, $end, $field) = @_;
 727         my $over = $self->{ng}->over;
 728         my $msgs = $over->query_xover($$beg, $end);
 729         scalar(@$msgs) or return;
 730         my $tmp = '';
 731         foreach my $s (@$msgs) {
 732                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 733         }
 734         utf8::encode($tmp);
 735         $self->msg_more($tmp);
 736         $$beg = $msgs->[-1]->{num} + 1;
 737 }
 738
 739 sub hdr_searchmsg ($$$$) {
 740         my ($self, $xhdr, $field, $range) = @_;
 741         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 742                 my ($ng, $n) = mid_lookup($self, $1);
 743                 return r430 unless defined $n;
 744                 my $v = over_header_for($ng->over, $n, $field);
 745                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 746         } else { # numeric range
 747                 $range = $self->{article} unless defined $range;
 748                 my $r = get_range($self, $range);
 749                 return $r unless ref $r;
 750                 more($self, $xhdr ? r221 : r225);
 751                 long_response($self, \&searchmsg_range_i, @$r, $field);
 752         }
 753 }
 754
 755 sub do_hdr ($$$;$) {
 756         my ($self, $xhdr, $header, $range) = @_;
 757         my $sub = lc $header;
 758         if ($sub eq 'message-id') {
 759                 hdr_message_id($self, $xhdr, $range);
 760         } elsif ($sub eq 'xref') {
 761                 hdr_xref($self, $xhdr, $range);
 762         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 763                                 bytes|lines)\z/x) {
 764                 hdr_searchmsg($self, $xhdr, $sub, $range);
 765         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 766                 hdr_searchmsg($self, $xhdr, $1, $range);
 767         } else {
 768                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 769         }
 770 }
 771
 772 # RFC 3977
 773 sub cmd_hdr ($$;$) {
 774         my ($self, $header, $range) = @_;
 775         do_hdr($self, 0, $header, $range);
 776 }
 777
 778 # RFC 2980
 779 sub cmd_xhdr ($$;$) {
 780         my ($self, $header, $range) = @_;
 781         do_hdr($self, 1, $header, $range);
 782 }
 783
 784 sub hdr_mid_prefix ($$$$$) {
 785         my ($self, $xhdr, $ng, $n, $mid) = @_;
 786         return $mid if $xhdr;
 787
 788         # HDR for RFC 3977 users
 789         if (my $self_ng = $self->{ng}) {
 790                 ($self_ng eq $ng) ? $n : '0';
 791         } else {
 792                 '0';
 793         }
 794 }
 795
 796 sub hdr_mid_response ($$$$$$) {
 797         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 798         my $res = '';
 799         if ($xhdr) {
 800                 $res .= r221 . "\r\n";
 801                 $res .= "$mid $v\r\n";
 802         } else {
 803                 $res .= r225 . "\r\n";
 804                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 805                 $res .= "$pfx $v\r\n";
 806         }
 807         res($self, $res .= '.');
 808         undef;
 809 }
 810
 811 sub xrover_i {
 812         my ($self, $beg, $end) = @_;
 813         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 814         more($self, "$$beg $h") if defined($h);
 815         $$beg++ < $end;
 816 }
 817
 818 sub cmd_xrover ($;$) {
 819         my ($self, $range) = @_;
 820         my $ng = $self->{ng} or return '412 no newsgroup selected';
 821         (defined $range && $range =~ /[<>]/) and
 822                 return '420 No article(s) selected'; # no message IDs
 823
 824         $range = $self->{article} unless defined $range;
 825         my $r = get_range($self, $range);
 826         return $r unless ref $r;
 827         more($self, '224 Overview information follows');
 828         long_response($self, \&xrover_i, @$r);
 829 }
 830
 831 sub over_line ($$$$) {
 832         my ($self, $ng, $num, $smsg) = @_;
 833         # n.b. field access and procedural calls can be
 834         # 10%-15% faster than OO method calls:
 835         my $s = join("\t", $num,
 836                 $smsg->{subject},
 837                 $smsg->{from},
 838                 PublicInbox::SearchMsg::date($smsg),
 839                 "<$smsg->{mid}>",
 840                 $smsg->{references},
 841                 $smsg->{bytes},
 842                 $smsg->{lines},
 843                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 844         utf8::encode($s);
 845         $s
 846 }
 847
 848 sub cmd_over ($;$) {
 849         my ($self, $range) = @_;
 850         if ($range && $range =~ /\A<(.+)>\z/) {
 851                 my ($ng, $n) = mid_lookup($self, $1);
 852                 defined $n or return r430;
 853                 my $smsg = $ng->over->get_art($n) or return r430;
 854                 more($self, '224 Overview information follows (multi-line)');
 855
 856                 # Only set article number column if it's the current group
 857                 my $self_ng = $self->{ng};
 858                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 859                 more($self, over_line($self, $ng, $n, $smsg));
 860                 '.';
 861         } else {
 862                 cmd_xover($self, $range);
 863         }
 864 }
 865
 866 sub cmd_xover ($;$) {
 867         my ($self, $range) = @_;
 868         $range = $self->{article} unless defined $range;
 869         my $r = get_range($self, $range);
 870         return $r unless ref $r;
 871         my ($beg, $end) = @$r;
 872         more($self, "224 Overview information follows for $$beg to $end");
 873         my $over = $self->{ng}->over;
 874         my $cur = $$beg;
 875         long_response($self, sub {
 876                 my $msgs = $over->query_xover($cur, $end);
 877                 my $nr = scalar @$msgs or return;
 878
 879                 # OVERVIEW.FMT
 880                 more($self, join("\r\n", map {
 881                         over_line($self, $self->{ng}, $_->{num}, $_);
 882                         } @$msgs));
 883                 $cur = $msgs->[-1]->{num} + 1;
 884         });
 885 }
 886
 887 sub compressed { undef }
 888
 889 sub cmd_starttls ($) {
 890         my ($self) = @_;
 891         my $sock = $self->{sock} or return;
 892         # RFC 4642 2.2.1
 893         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 894         my $opt = $self->{nntpd}->{accept_tls} or
 895                 return '580 can not initiate TLS negotiation';
 896         res($self, '382 Continue with TLS negotiation');
 897         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 898         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 899         undef;
 900 }
 901
 902 # RFC 8054
 903 sub cmd_compress ($$) {
 904         my ($self, $alg) = @_;
 905         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 906         return r502 if $self->compressed || !$have_deflate;
 907         PublicInbox::NNTPdeflate->enable($self);
 908         $self->requeue;
 909         undef
 910 }
 911
 912 sub zflush {} # overridden by NNTPdeflate
 913
 914 sub cmd_xpath ($$) {
 915         my ($self, $mid) = @_;
 916         return r501 unless $mid =~ /\A<(.+)>\z/;
 917         $mid = $1;
 918         my @paths;
 919         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 920                 my $n = $ng->mm->num_for($mid);
 921                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 922         }
 923         return '430 no such article on server' unless @paths;
 924         '223 '.join(' ', @paths);
 925 }
 926
 927 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 928
 929 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 930
 931 sub do_write ($$) {
 932         my $self = $_[0];
 933         my $done = $self->write(\($_[1]));
 934         return 0 unless $self->{sock};
 935
 936         $done;
 937 }
 938
 939 sub err ($$;@) {
 940         my ($self, $fmt, @args) = @_;
 941         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 942 }
 943
 944 sub out ($$;@) {
 945         my ($self, $fmt, @args) = @_;
 946         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 947 }
 948
 949 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 950 sub event_step {
 951         my ($self) = @_;
 952
 953         return unless $self->flush_write && $self->{sock};
 954
 955         $self->update_idle_time;
 956         # only read more requests if we've drained the write buffer,
 957         # otherwise we can be buffering infinitely w/o backpressure
 958
 959         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 960         my $r = 1;
 961
 962         if (index($$rbuf, "\n") < 0) {
 963                 my $off = bytes::length($$rbuf);
 964                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 965         }
 966         while ($r > 0 && $$rbuf =~ s/\A[ \t]*([^\n]*?)\r?\n//) {
 967                 my $line = $1;
 968                 return $self->close if $line =~ /[[:cntrl:]]/s;
 969                 my $t0 = now();
 970                 my $fd = fileno($self->{sock});
 971                 $r = eval { process_line($self, $line) };
 972                 my $pending = $self->{wbuf} ? ' pending' : '';
 973                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 974         }
 975
 976         return $self->close if $r < 0;
 977         my $len = bytes::length($$rbuf);
 978         return $self->close if ($len >= LINE_MAX);
 979         $self->rbuf_idle($rbuf);
 980         $self->update_idle_time;
 981
 982         # maybe there's more pipelined data, or we'll have
 983         # to register it for socket-readiness notifications
 984         $self->requeue unless $self->{wbuf};
 985 }
 986
 987 # for graceful shutdown in PublicInbox::Daemon:
 988 sub busy {
 989         my ($self, $now) = @_;
 990         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
 991 }
 992
 993 # this is an import to prevent "perl -c" from complaining about fields
 994 sub import {
 995         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
 996                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
 997 }
 998
 999 1;