lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41
  42 sub update_idle_time ($) {
  43         my ($self) = @_;
  44         my $sock = $self->{sock} or return;
  45         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  46 }
  47
  48 sub expire_old () {
  49         my $now = now();
  50         my $exp = $EXPTIME;
  51         my $old = $now - $exp;
  52         my $nr = 0;
  53         my $closed = 0;
  54         my %new;
  55         while (my ($fd, $v) = each %$EXPMAP) {
  56                 my ($idle_time, $nntp) = @$v;
  57                 if ($idle_time < $old) {
  58                         if ($nntp->shutdn) {
  59                                 $closed++;
  60                         } else {
  61                                 ++$nr;
  62                                 $new{$fd} = $v;
  63                         }
  64                 } else {
  65                         ++$nr;
  66                         $new{$fd} = $v;
  67                 }
  68         }
  69         $EXPMAP = \%new;
  70         if ($nr) {
  71                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  72         } else {
  73                 $expt = undef;
  74                 # noop to kick outselves out of the loop ASAP so descriptors
  75                 # really get closed
  76                 PublicInbox::EvCleanup::asap(sub {}) if $closed;
  77         }
  78 }
  79
  80 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  81
  82 sub new ($$$) {
  83         my ($class, $sock, $nntpd) = @_;
  84         my $self = fields::new($class);
  85         my $ev = EPOLLIN;
  86         my $wbuf;
  87         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  88                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  89                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  90         }
  91         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  92         $self->{nntpd} = $nntpd;
  93         if ($wbuf) {
  94                 $self->{wbuf} = $wbuf;
  95         } else {
  96                 greet($self);
  97         }
  98         update_idle_time($self);
  99         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 100         $self;
 101 }
 102
 103 sub args_ok ($$) {
 104         my ($cb, $argc) = @_;
 105         my $tot = prototype $cb;
 106         my ($nreq, undef) = split(';', $tot);
 107         $nreq = ($nreq =~ tr/$//) - 1;
 108         $tot = ($tot =~ tr/$//) - 1;
 109         ($argc <= $tot && $argc >= $nreq);
 110 }
 111
 112 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 113 sub process_line ($$) {
 114         my ($self, $l) = @_;
 115         my ($req, @args) = split(/[ \t]/, $l);
 116         return 1 unless defined($req); # skip blank line
 117         $req = lc($req);
 118         $req = eval {
 119                 no strict 'refs';
 120                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 121         };
 122         return res($self, '500 command not recognized') unless $req;
 123         return res($self, r501) unless args_ok($req, scalar @args);
 124
 125         my $res = eval { $req->($self, @args) };
 126         my $err = $@;
 127         if ($err && $self->{sock}) {
 128                 local $/ = "\n";
 129                 chomp($l);
 130                 err($self, 'error from: %s (%s)', $l, $err);
 131                 $res = '503 program fault - command not performed';
 132         }
 133         return 0 unless defined $res;
 134         res($self, $res);
 135 }
 136
 137 sub cmd_mode ($$) {
 138         my ($self, $arg) = @_;
 139         $arg = uc $arg;
 140         return r501 unless $arg eq 'READER';
 141         '201 Posting prohibited';
 142 }
 143
 144 sub cmd_slave ($) { '202 slave status noted' }
 145
 146 sub cmd_xgtitle ($;$) {
 147         my ($self, $wildmat) = @_;
 148         more($self, '282 list of groups and descriptions follows');
 149         list_newsgroups($self, $wildmat);
 150         '.'
 151 }
 152
 153 sub list_overview_fmt ($) {
 154         my ($self) = @_;
 155         msg_more($self, $OVERVIEW_FMT);
 156 }
 157
 158 sub list_headers ($;$) {
 159         my ($self) = @_;
 160         msg_more($self, $LIST_HEADERS);
 161 }
 162
 163 sub list_active ($;$) {
 164         my ($self, $wildmat) = @_;
 165         wildmat2re($wildmat);
 166         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 167                 $ng->{newsgroup} =~ $wildmat or next;
 168                 group_line($self, $ng);
 169         }
 170 }
 171
 172 sub list_active_times ($;$) {
 173         my ($self, $wildmat) = @_;
 174         wildmat2re($wildmat);
 175         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                 $ng->{newsgroup} =~ $wildmat or next;
 177                 my $c = eval { $ng->mm->created_at } || time;
 178                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 179         }
 180 }
 181
 182 sub list_newsgroups ($;$) {
 183         my ($self, $wildmat) = @_;
 184         wildmat2re($wildmat);
 185         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 186                 $ng->{newsgroup} =~ $wildmat or next;
 187                 my $d = $ng->description;
 188                 more($self, "$ng->{newsgroup} $d");
 189         }
 190 }
 191
 192 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 193 sub cmd_list ($;$$) {
 194         my ($self, @args) = @_;
 195         if (scalar @args) {
 196                 my $arg = shift @args;
 197                 $arg =~ tr/A-Z./a-z_/;
 198                 $arg = "list_$arg";
 199                 return r501 if $DISABLED{$arg};
 200
 201                 $arg = eval {
 202                         no strict 'refs';
 203                         *{$arg}{CODE};
 204                 };
 205                 return r501 unless $arg && args_ok($arg, scalar @args);
 206                 more($self, '215 information follows');
 207                 $arg->($self, @args);
 208         } else {
 209                 more($self, '215 list of newsgroups follows');
 210                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 211                         group_line($self, $ng);
 212                 }
 213         }
 214         '.'
 215 }
 216
 217 sub cmd_listgroup ($;$) {
 218         my ($self, $group) = @_;
 219         if (defined $group) {
 220                 my $res = cmd_group($self, $group);
 221                 return $res if ($res !~ /\A211 /);
 222                 more($self, $res);
 223         }
 224
 225         $self->{ng} or return '412 no newsgroup selected';
 226         my $n = 0;
 227         long_response($self, sub {
 228                 my $ary = $self->{ng}->mm->ids_after(\$n);
 229                 scalar @$ary or return;
 230                 more($self, join("\r\n", @$ary));
 231                 1;
 232         });
 233 }
 234
 235 sub parse_time ($$;$) {
 236         my ($date, $time, $gmt) = @_;
 237         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 238         if (defined $gmt) {
 239                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 240                 $gmt = 1;
 241         }
 242         my @now = $gmt ? gmtime : localtime;
 243         my ($YYYY, $MM, $DD);
 244         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 248                 my $cur_year = $now[5] + 1900;
 249                 if ($YYYY > $cur_year) {
 250                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 251                 }
 252         }
 253         if ($gmt) {
 254                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 255         } else {
 256                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         }
 258 }
 259
 260 sub group_line ($$) {
 261         my ($self, $ng) = @_;
 262         my ($min, $max) = $ng->mm->minmax;
 263         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 264 }
 265
 266 sub cmd_newgroups ($$$;$$) {
 267         my ($self, $date, $time, $gmt, $dists) = @_;
 268         my $ts = eval { parse_time($date, $time, $gmt) };
 269         return r501 if $@;
 270
 271         # TODO dists
 272         more($self, '231 list of new newsgroups follows');
 273         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 274                 my $c = eval { $ng->mm->created_at } || 0;
 275                 next unless $c > $ts;
 276                 group_line($self, $ng);
 277         }
 278         '.'
 279 }
 280
 281 sub wildmat2re (;$) {
 282         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 283         my %keep;
 284         my $salt = rand;
 285         my $tmp = $_[0];
 286
 287         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 288                 my $orig = $1;
 289                 my $key = sha1_hex($orig . $salt);
 290                 $orig =~ s/([^\w\-])+/\Q$1/g;
 291                 $keep{$key} = $orig;
 292                 $key
 293                 #gex;
 294         my %map = ('*' => '.*', '?' => '.' );
 295         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 296         if (scalar %keep) {
 297                 $tmp =~ s#([a-f0-9]{40})#
 298                         my $orig = $keep{$1};
 299                         defined $orig ? $orig : $1;
 300                         #ge;
 301         }
 302         $_[0] = qr/\A$tmp\z/;
 303 }
 304
 305 sub ngpat2re (;$) {
 306         return $_[0] = qr/\A\z/ unless defined $_[0];
 307         my %map = ('*' => '.*', ',' => '|');
 308         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 309         $_[0] = qr/\A(?:$_[0])\z/;
 310 }
 311
 312 sub cmd_newnews ($$$$;$$) {
 313         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 314         my $ts = eval { parse_time($date, $time, $gmt) };
 315         return r501 if $@;
 316         more($self, '230 list of new articles by message-id follows');
 317         my ($keep, $skip) = split('!', $newsgroups, 2);
 318         ngpat2re($keep);
 319         ngpat2re($skip);
 320         my @over;
 321         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 322                 $ng->{newsgroup} =~ $keep or next;
 323                 $ng->{newsgroup} =~ $skip and next;
 324                 my $over = $ng->over or next;
 325                 push @over, $over;
 326         };
 327         return '.' unless @over;
 328
 329         my $prev = 0;
 330         long_response($self, sub {
 331                 my $over = $over[0];
 332                 my $msgs = $over->query_ts($ts, $prev);
 333                 if (scalar @$msgs) {
 334                         more($self, '<' .
 335                                 join(">\r\n<", map { $_->mid } @$msgs ).
 336                                 '>');
 337                         $prev = $msgs->[-1]->{num};
 338                 } else {
 339                         shift @over;
 340                         if (@over) { # continue onto next newsgroup
 341                                 $prev = 0;
 342                                 return 1;
 343                         } else { # break out of the long response.
 344                                 return;
 345                         }
 346                 }
 347         });
 348 }
 349
 350 sub cmd_group ($$) {
 351         my ($self, $group) = @_;
 352         my $no_such = '411 no such news group';
 353         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 354
 355         $self->{ng} = $ng;
 356         my ($min, $max) = $ng->mm->minmax;
 357         $min ||= 0;
 358         $max ||= 0;
 359         $self->{article} = $min;
 360         my $est_size = $max - $min;
 361         "211 $est_size $min $max $group";
 362 }
 363
 364 sub article_adj ($$) {
 365         my ($self, $off) = @_;
 366         my $ng = $self->{ng} or return '412 no newsgroup selected';
 367
 368         my $n = $self->{article};
 369         defined $n or return '420 no current article has been selected';
 370
 371         $n += $off;
 372         my $mid = $ng->mm->mid_for($n);
 373         unless ($mid) {
 374                 $n = $off > 0 ? 'next' : 'previous';
 375                 return "421 no $n article in this group";
 376         }
 377         $self->{article} = $n;
 378         "223 $n <$mid> article retrieved - request text separately";
 379 }
 380
 381 sub cmd_next ($) { article_adj($_[0], 1) }
 382 sub cmd_last ($) { article_adj($_[0], -1) }
 383
 384 # We want to encourage using email and CC-ing everybody involved to avoid
 385 # the single-point-of-failure a single server provides.
 386 sub cmd_post ($) {
 387         my ($self) = @_;
 388         my $ng = $self->{ng};
 389         $ng ? "440 mailto:$ng->{-primary_address} to post"
 390                 : '440 posting not allowed'
 391 }
 392
 393 sub cmd_quit ($) {
 394         my ($self) = @_;
 395         res($self, '205 closing connection - goodbye!');
 396         $self->shutdn;
 397         undef;
 398 }
 399
 400 sub header_append ($$$) {
 401         my ($hdr, $k, $v) = @_;
 402         my @v = $hdr->header($k);
 403         foreach (@v) {
 404                 return if $v eq $_;
 405         }
 406         $hdr->header_set($k, @v, $v);
 407 }
 408
 409 sub xref ($$$$) {
 410         my ($self, $ng, $n, $mid) = @_;
 411         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 412
 413         # num_for is pretty cheap and sometimes we'll lookup the existence
 414         # of an article without getting even the OVER info.  In other words,
 415         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 416         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 417         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 418                 next if $ng eq $other;
 419                 my $num = eval { $other->mm->num_for($mid) } or next;
 420                 $ret .= " $other->{newsgroup}:$num";
 421         }
 422         $ret;
 423 }
 424
 425 sub set_nntp_headers ($$$$$) {
 426         my ($self, $hdr, $ng, $n, $mid) = @_;
 427
 428         # why? leafnode requires a Path: header for some inexplicable
 429         # reason.  We'll fake the shortest one possible.
 430         $hdr->header_set('Path', 'y');
 431
 432         # leafnode (and maybe other NNTP clients) have trouble dealing
 433         # with v2 messages which have multiple Message-IDs (either due
 434         # to our own content-based dedupe or buggy git-send-email versions).
 435         my @mids = $hdr->header('Message-ID');
 436         if (scalar(@mids) > 1) {
 437                 my $mid0 = "<$mid>";
 438                 $hdr->header_set('Message-ID', $mid0);
 439                 my @alt = $hdr->header('X-Alt-Message-ID');
 440                 my %seen = map { $_ => 1 } (@alt, $mid0);
 441                 foreach my $m (@mids) {
 442                         next if $seen{$m}++;
 443                         push @alt, $m;
 444                 }
 445                 $hdr->header_set('X-Alt-Message-ID', @alt);
 446         }
 447
 448         # clobber some
 449         my $xref = xref($self, $ng, $n, $mid);
 450         $hdr->header_set('Xref', $xref);
 451         $xref =~ s/:[0-9]+//g;
 452         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 453         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 454         if (my $url = $ng->base_url) {
 455                 $mid = mid_escape($mid);
 456                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 457                 header_append($hdr, 'List-Archive', "<$url>");
 458         }
 459 }
 460
 461 sub art_lookup ($$$) {
 462         my ($self, $art, $set_headers) = @_;
 463         my $ng = $self->{ng};
 464         my ($n, $mid);
 465         my $err;
 466         if (defined $art) {
 467                 if ($art =~ /\A[0-9]+\z/) {
 468                         $err = '423 no such article number in this group';
 469                         $n = int($art);
 470                         goto find_mid;
 471                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 472                         $mid = $1;
 473                         $err = r430;
 474                         $n = $ng->mm->num_for($mid) if $ng;
 475                         goto found if defined $n;
 476                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 477                                 $n = $g->mm->num_for($mid);
 478                                 if (defined $n) {
 479                                         $ng = $g;
 480                                         goto found;
 481                                 }
 482                         }
 483                         return $err;
 484                 } else {
 485                         return r501;
 486                 }
 487         } else {
 488                 $err = '420 no current article has been selected';
 489                 $n = $self->{article};
 490                 defined $n or return $err;
 491 find_mid:
 492                 $ng or return '412 no newsgroup has been selected';
 493                 $mid = $ng->mm->mid_for($n);
 494                 defined $mid or return $err;
 495         }
 496 found:
 497         my $smsg = $ng->over->get_art($n) or return $err;
 498         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 499         my $s = Email::Simple->new($msg);
 500         if ($set_headers) {
 501                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 502
 503                 # must be last
 504                 $s->body_set('') if ($set_headers == 2);
 505         }
 506         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 507 }
 508
 509 sub simple_body_write ($$) {
 510         my ($self, $s) = @_;
 511         my $body = $s->body;
 512         $s->body_set('');
 513         $body =~ s/^\./../smg;
 514         $body =~ s/(?<!\r)\n/\r\n/sg;
 515         msg_more($self, $body);
 516         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 517         '.'
 518 }
 519
 520 sub set_art {
 521         my ($self, $art) = @_;
 522         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 523 }
 524
 525 sub _header ($) {
 526         my $hdr = $_[0]->header_obj->as_string;
 527         utf8::encode($hdr);
 528         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 529
 530         # for leafnode compatibility, we need to ensure Message-ID headers
 531         # are only a single line.  We can't subclass Email::Simple::Header
 532         # and override _default_fold_at in here, either; since that won't
 533         # affect messages already in the archive.
 534         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 535
 536         $hdr
 537 }
 538
 539 sub cmd_article ($;$) {
 540         my ($self, $art) = @_;
 541         my $r = art_lookup($self, $art, 1);
 542         return $r unless ref $r;
 543         my ($n, $mid, $s) = @$r;
 544         set_art($self, $art);
 545         more($self, "220 $n <$mid> article retrieved - head and body follow");
 546         msg_more($self, _header($s));
 547         msg_more($self, "\r\n");
 548         simple_body_write($self, $s);
 549 }
 550
 551 sub cmd_head ($;$) {
 552         my ($self, $art) = @_;
 553         my $r = art_lookup($self, $art, 2);
 554         return $r unless ref $r;
 555         my ($n, $mid, $s) = @$r;
 556         set_art($self, $art);
 557         more($self, "221 $n <$mid> article retrieved - head follows");
 558         msg_more($self, _header($s));
 559         '.'
 560 }
 561
 562 sub cmd_body ($;$) {
 563         my ($self, $art) = @_;
 564         my $r = art_lookup($self, $art, 0);
 565         return $r unless ref $r;
 566         my ($n, $mid, $s) = @$r;
 567         set_art($self, $art);
 568         more($self, "222 $n <$mid> article retrieved - body follows");
 569         simple_body_write($self, $s);
 570 }
 571
 572 sub cmd_stat ($;$) {
 573         my ($self, $art) = @_;
 574         my $r = art_lookup($self, $art, 0);
 575         return $r unless ref $r;
 576         my ($n, $mid, undef) = @$r;
 577         set_art($self, $art);
 578         "223 $n <$mid> article retrieved - request text separately";
 579 }
 580
 581 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 582
 583 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 584
 585 sub cmd_help ($) {
 586         my ($self) = @_;
 587         more($self, '100 help text follows');
 588         '.'
 589 }
 590
 591 sub get_range ($$) {
 592         my ($self, $range) = @_;
 593         my $ng = $self->{ng} or return '412 no news group has been selected';
 594         defined $range or return '420 No article(s) selected';
 595         my ($beg, $end);
 596         my ($min, $max) = $ng->mm->minmax;
 597         if ($range =~ /\A([0-9]+)\z/) {
 598                 $beg = $end = $1;
 599         } elsif ($range =~ /\A([0-9]+)-\z/) {
 600                 ($beg, $end) = ($1, $max);
 601         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 602                 ($beg, $end) = ($1, $2);
 603         } else {
 604                 return r501;
 605         }
 606         $beg = $min if ($beg < $min);
 607         $end = $max if ($end > $max);
 608         return '420 No article(s) selected' if ($beg > $end);
 609         [ $beg, $end ];
 610 }
 611
 612 sub long_response ($$) {
 613         my ($self, $cb) = @_; # cb returns true if more, false if done
 614
 615         my $fd = fileno($self->{sock});
 616         defined $fd or return;
 617         # make sure we disable reading during a long response,
 618         # clients should not be sending us stuff and making us do more
 619         # work while we are stream a response to them
 620         my $t0 = now();
 621         my $long_cb; # DANGER: self-referential
 622         $long_cb = sub {
 623                 # wbuf is unset or empty, here; $cb may add to it
 624                 my $more = eval { $cb->() };
 625                 if ($@ || !$self->{sock}) { # something bad happened...
 626                         $long_cb = undef;
 627                         my $diff = now() - $t0;
 628                         if ($@) {
 629                                 err($self,
 630                                     "%s during long response[$fd] - %0.6f",
 631                                     $@, $diff);
 632                         }
 633                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 634                         $self->close;
 635                 } elsif ($more) { # $self->{wbuf}:
 636                         update_idle_time($self);
 637
 638                         # no recursion, schedule another call ASAP
 639                         # but only after all pending writes are done
 640                         my $wbuf = $self->{wbuf} ||= [];
 641                         push @$wbuf, $long_cb;
 642
 643                         # wbuf may be populated by $cb, no need to rearm if so:
 644                         $self->requeue if scalar(@$wbuf) == 1;
 645                 } else { # all done!
 646                         $long_cb = undef;
 647                         res($self, '.');
 648                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 649                         $self->requeue unless $self->{wbuf};
 650                 }
 651         };
 652         $self->write($long_cb); # kick off!
 653         undef;
 654 }
 655
 656 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 657         my ($self, $xhdr, $range) = @_;
 658
 659         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 660                 my ($ng, $n) = mid_lookup($self, $1);
 661                 return r430 unless $n;
 662                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 663         } else { # numeric range
 664                 $range = $self->{article} unless defined $range;
 665                 my $r = get_range($self, $range);
 666                 return $r unless ref $r;
 667                 my $mm = $self->{ng}->mm;
 668                 my ($beg, $end) = @$r;
 669                 more($self, $xhdr ? r221 : r225);
 670                 long_response($self, sub {
 671                         my $r = $mm->msg_range(\$beg, $end);
 672                         @$r or return;
 673                         more($self, join("\r\n", map {
 674                                 "$_->[0] <$_->[1]>"
 675                         } @$r));
 676                         1;
 677                 });
 678         }
 679 }
 680
 681 sub mid_lookup ($$) {
 682         my ($self, $mid) = @_;
 683         my $self_ng = $self->{ng};
 684         if ($self_ng) {
 685                 my $n = $self_ng->mm->num_for($mid);
 686                 return ($self_ng, $n) if defined $n;
 687         }
 688         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 689                 next if defined $self_ng && $ng eq $self_ng;
 690                 my $n = $ng->mm->num_for($mid);
 691                 return ($ng, $n) if defined $n;
 692         }
 693         (undef, undef);
 694 }
 695
 696 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 697         my ($self, $xhdr, $range) = @_;
 698
 699         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 700                 my $mid = $1;
 701                 my ($ng, $n) = mid_lookup($self, $mid);
 702                 return r430 unless $n;
 703                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 704                                 xref($self, $ng, $n, $mid));
 705         } else { # numeric range
 706                 $range = $self->{article} unless defined $range;
 707                 my $r = get_range($self, $range);
 708                 return $r unless ref $r;
 709                 my $ng = $self->{ng};
 710                 my $mm = $ng->mm;
 711                 my ($beg, $end) = @$r;
 712                 more($self, $xhdr ? r221 : r225);
 713                 long_response($self, sub {
 714                         my $r = $mm->msg_range(\$beg, $end);
 715                         @$r or return;
 716                         more($self, join("\r\n", map {
 717                                 my $num = $_->[0];
 718                                 "$num ".xref($self, $ng, $num, $_->[1]);
 719                         } @$r));
 720                         1;
 721                 });
 722         }
 723 }
 724
 725 sub over_header_for {
 726         my ($over, $num, $field) = @_;
 727         my $smsg = $over->get_art($num) or return;
 728         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 729         $smsg->{$field};
 730 }
 731
 732 sub hdr_searchmsg ($$$$) {
 733         my ($self, $xhdr, $field, $range) = @_;
 734         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 735                 my ($ng, $n) = mid_lookup($self, $1);
 736                 return r430 unless defined $n;
 737                 my $v = over_header_for($ng->over, $n, $field);
 738                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 739         } else { # numeric range
 740                 $range = $self->{article} unless defined $range;
 741                 my $over = $self->{ng}->over;
 742                 my $mm = $self->{ng}->mm;
 743                 my $r = get_range($self, $range);
 744                 return $r unless ref $r;
 745                 my ($beg, $end) = @$r;
 746                 more($self, $xhdr ? r221 : r225);
 747                 my $cur = $beg;
 748                 long_response($self, sub {
 749                         my $msgs = $over->query_xover($cur, $end);
 750                         my $nr = scalar @$msgs or return;
 751                         my $tmp = '';
 752                         foreach my $s (@$msgs) {
 753                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 754                         }
 755                         utf8::encode($tmp);
 756                         msg_more($self, $tmp);
 757                         $cur = $msgs->[-1]->{num} + 1;
 758                 });
 759         }
 760 }
 761
 762 sub do_hdr ($$$;$) {
 763         my ($self, $xhdr, $header, $range) = @_;
 764         my $sub = lc $header;
 765         if ($sub eq 'message-id') {
 766                 hdr_message_id($self, $xhdr, $range);
 767         } elsif ($sub eq 'xref') {
 768                 hdr_xref($self, $xhdr, $range);
 769         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 770                                 bytes|lines)\z/x) {
 771                 hdr_searchmsg($self, $xhdr, $sub, $range);
 772         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 773                 hdr_searchmsg($self, $xhdr, $1, $range);
 774         } else {
 775                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 776         }
 777 }
 778
 779 # RFC 3977
 780 sub cmd_hdr ($$;$) {
 781         my ($self, $header, $range) = @_;
 782         do_hdr($self, 0, $header, $range);
 783 }
 784
 785 # RFC 2980
 786 sub cmd_xhdr ($$;$) {
 787         my ($self, $header, $range) = @_;
 788         do_hdr($self, 1, $header, $range);
 789 }
 790
 791 sub hdr_mid_prefix ($$$$$) {
 792         my ($self, $xhdr, $ng, $n, $mid) = @_;
 793         return $mid if $xhdr;
 794
 795         # HDR for RFC 3977 users
 796         if (my $self_ng = $self->{ng}) {
 797                 ($self_ng eq $ng) ? $n : '0';
 798         } else {
 799                 '0';
 800         }
 801 }
 802
 803 sub hdr_mid_response ($$$$$$) {
 804         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 805         my $res = '';
 806         if ($xhdr) {
 807                 $res .= r221 . "\r\n";
 808                 $res .= "$mid $v\r\n";
 809         } else {
 810                 $res .= r225 . "\r\n";
 811                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 812                 $res .= "$pfx $v\r\n";
 813         }
 814         res($self, $res .= '.');
 815         undef;
 816 }
 817
 818 sub cmd_xrover ($;$) {
 819         my ($self, $range) = @_;
 820         my $ng = $self->{ng} or return '412 no newsgroup selected';
 821         (defined $range && $range =~ /[<>]/) and
 822                 return '420 No article(s) selected'; # no message IDs
 823
 824         $range = $self->{article} unless defined $range;
 825         my $r = get_range($self, $range);
 826         return $r unless ref $r;
 827         my ($beg, $end) = @$r;
 828         my $mm = $ng->mm;
 829         my $over = $ng->over;
 830         more($self, '224 Overview information follows');
 831
 832         long_response($self, sub {
 833                 my $h = over_header_for($over, $beg, 'references');
 834                 more($self, "$beg $h") if defined($h);
 835                 $beg++ < $end;
 836         });
 837 }
 838
 839 sub over_line ($$$$) {
 840         my ($self, $ng, $num, $smsg) = @_;
 841         # n.b. field access and procedural calls can be
 842         # 10%-15% faster than OO method calls:
 843         my $s = join("\t", $num,
 844                 $smsg->{subject},
 845                 $smsg->{from},
 846                 PublicInbox::SearchMsg::date($smsg),
 847                 "<$smsg->{mid}>",
 848                 $smsg->{references},
 849                 $smsg->{bytes},
 850                 $smsg->{lines},
 851                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 852         utf8::encode($s);
 853         $s
 854 }
 855
 856 sub cmd_over ($;$) {
 857         my ($self, $range) = @_;
 858         if ($range && $range =~ /\A<(.+)>\z/) {
 859                 my ($ng, $n) = mid_lookup($self, $1);
 860                 defined $n or return r430;
 861                 my $smsg = $ng->over->get_art($n) or return r430;
 862                 more($self, '224 Overview information follows (multi-line)');
 863
 864                 # Only set article number column if it's the current group
 865                 my $self_ng = $self->{ng};
 866                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 867                 more($self, over_line($self, $ng, $n, $smsg));
 868                 '.';
 869         } else {
 870                 cmd_xover($self, $range);
 871         }
 872 }
 873
 874 sub cmd_xover ($;$) {
 875         my ($self, $range) = @_;
 876         $range = $self->{article} unless defined $range;
 877         my $r = get_range($self, $range);
 878         return $r unless ref $r;
 879         my ($beg, $end) = @$r;
 880         more($self, "224 Overview information follows for $beg to $end");
 881         my $over = $self->{ng}->over;
 882         my $cur = $beg;
 883         long_response($self, sub {
 884                 my $msgs = $over->query_xover($cur, $end);
 885                 my $nr = scalar @$msgs or return;
 886
 887                 # OVERVIEW.FMT
 888                 more($self, join("\r\n", map {
 889                         over_line($self, $self->{ng}, $_->{num}, $_);
 890                         } @$msgs));
 891                 $cur = $msgs->[-1]->{num} + 1;
 892         });
 893 }
 894
 895 sub cmd_starttls ($) {
 896         my ($self) = @_;
 897         my $sock = $self->{sock} or return;
 898         # RFC 4642 2.2.1
 899         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 900         my $opt = $self->{nntpd}->{accept_tls} or
 901                 return '580 can not initiate TLS negotiation';
 902         res($self, '382 Continue with TLS negotiation');
 903         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 904         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 905         undef;
 906 }
 907
 908 sub cmd_xpath ($$) {
 909         my ($self, $mid) = @_;
 910         return r501 unless $mid =~ /\A<(.+)>\z/;
 911         $mid = $1;
 912         my @paths;
 913         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 914                 my $n = $ng->mm->num_for($mid);
 915                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 916         }
 917         return '430 no such article on server' unless @paths;
 918         '223 '.join(' ', @paths);
 919 }
 920
 921 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 922
 923 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 924
 925 sub do_write ($$) {
 926         my $self = $_[0];
 927         my $done = $self->write(\($_[1]));
 928         return 0 unless $self->{sock};
 929
 930         $done;
 931 }
 932
 933 sub err ($$;@) {
 934         my ($self, $fmt, @args) = @_;
 935         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 936 }
 937
 938 sub out ($$;@) {
 939         my ($self, $fmt, @args) = @_;
 940         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 941 }
 942
 943 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 944 sub event_step {
 945         my ($self) = @_;
 946
 947         return unless $self->flush_write && $self->{sock};
 948
 949         update_idle_time($self);
 950         # only read more requests if we've drained the write buffer,
 951         # otherwise we can be buffering infinitely w/o backpressure
 952
 953         use constant LINE_MAX => 512; # RFC 977 section 2.3
 954         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 955         my $r = 1;
 956
 957         if (index($$rbuf, "\n") < 0) {
 958                 my $off = bytes::length($$rbuf);
 959                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 960         }
 961         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 962                 my $line = $1;
 963                 return $self->close if $line =~ /[[:cntrl:]]/s;
 964                 my $t0 = now();
 965                 my $fd = fileno($self->{sock});
 966                 $r = eval { process_line($self, $line) };
 967                 my $pending = $self->{wbuf} ? ' pending' : '';
 968                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 969         }
 970
 971         return $self->close if $r < 0;
 972         my $len = bytes::length($$rbuf);
 973         return $self->close if ($len >= LINE_MAX);
 974         $self->rbuf_idle($rbuf);
 975         update_idle_time($self);
 976
 977         # maybe there's more pipelined data, or we'll have
 978         # to register it for socket-readiness notifications
 979         $self->requeue unless $self->{wbuf};
 980 }
 981
 982 sub not_idle_long ($$) {
 983         my ($self, $now) = @_;
 984         my $sock = $self->{sock} or return;
 985         my $ary = $EXPMAP->{fileno($sock)} or return;
 986         my $exp_at = $ary->[0] + $EXPTIME;
 987         $exp_at > $now;
 988 }
 989
 990 # for graceful shutdown in PublicInbox::Daemon:
 991 sub busy {
 992         my ($self, $now) = @_;
 993         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
 994 }
 995
 996 1;