lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::NNTP;
   4 use strict;
   5 use warnings;
   6 use base qw(Danga::Socket);
   7 use fields qw(nntpd article rbuf ng long_res);
   8 use PublicInbox::Search;
   9 use PublicInbox::Msgmap;
  10 use PublicInbox::GitCatFile;
  11 use PublicInbox::MID qw(mid2path);
  12 use Email::MIME;
  13 use Data::Dumper qw(Dumper);
  14 use POSIX qw(strftime);
  15 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  16 use constant {
  17         r501 => '501 command syntax error',
  18         r221 => '221 Header follows',
  19         r224 => '224 Overview information follows (multi-line)',
  20         r225 => '225 Headers follow (multi-line)',
  21         r430 => '430 No article with that message-id',
  22         long_response_limit => 0xffffffff,
  23 };
  24
  25 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  26
  27 my @OVERVIEW = qw(Subject From Date Message-ID References);
  28 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  29 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  30                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  31
  32 # disable commands with easy DoS potential:
  33 # LISTGROUP could get pretty bad, too...
  34 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  35
  36 my $EXPMAP; # fd -> [ idle_time, $self ]
  37 my $EXPTIMER;
  38 our $EXPTIME = 180; # 3 minutes
  39
  40 sub update_idle_time ($) {
  41         my ($self) = @_;
  42         my $tmp = $self->{sock} or return;
  43         $tmp = fileno($tmp);
  44         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  45 }
  46
  47 sub expire_old () {
  48         my $now = now();
  49         my $exp = $EXPTIME;
  50         my $old = $now - $exp;
  51         my $next = $now + $exp;
  52         my $nr = 0;
  53         my %new;
  54         while (my ($fd, $v) = each %$EXPMAP) {
  55                 my ($idle_time, $nntp) = @$v;
  56                 if ($idle_time < $old) {
  57                         $nntp->close; # idempotent
  58                 } else {
  59                         my $nexp = $idle_time + $exp;
  60                         $next = $nexp if ($nexp < $next);
  61                         ++$nr;
  62                         $new{$fd} = $v;
  63                 }
  64         }
  65         $EXPMAP = \%new;
  66         if ($nr) {
  67                 $next -= $now;
  68                 $next = 0 if $next < 0;
  69                 $EXPTIMER = Danga::Socket->AddTimer($next, *expire_old);
  70         } else {
  71                 $EXPTIMER = undef;
  72                 # noop to kick outselves out of the loop so descriptors
  73                 # really get closed
  74                 Danga::Socket->AddTimer(0, *expire_cleanup);
  75         }
  76 }
  77
  78 sub new ($$$) {
  79         my ($class, $sock, $nntpd) = @_;
  80         my $self = fields::new($class);
  81         binmode $sock, ':utf8'; # RFC 3977
  82         $self->SUPER::new($sock);
  83         $self->{nntpd} = $nntpd;
  84         res($self, '201 server ready - post via email');
  85         $self->{rbuf} = '';
  86         $self->watch_read(1);
  87         update_idle_time($self);
  88         $EXPTIMER ||= Danga::Socket->AddTimer($EXPTIME, *expire_old);
  89         $self;
  90 }
  91
  92 sub args_ok ($$) {
  93         my ($cb, $argc) = @_;
  94         my $tot = prototype $cb;
  95         my ($nreq, undef) = split(';', $tot);
  96         $nreq = ($nreq =~ tr/$//) - 1;
  97         $tot = ($tot =~ tr/$//) - 1;
  98         ($argc <= $tot && $argc >= $nreq);
  99 }
 100
 101 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 102 sub process_line ($$) {
 103         my ($self, $l) = @_;
 104         my ($req, @args) = split(/\s+/, $l);
 105         $req = lc($req);
 106         $req = eval {
 107                 no strict 'refs';
 108                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 109         };
 110         return res($self, '500 command not recognized') unless $req;
 111         return res($self, r501) unless args_ok($req, scalar @args);
 112
 113         my $res = eval { $req->($self, @args) };
 114         my $err = $@;
 115         if ($err && !$self->{closed}) {
 116                 chomp($l = Dumper(\$l));
 117                 err($self, "error from: $l $err");
 118                 $res = '503 program fault - command not performed';
 119         }
 120         return 0 unless defined $res;
 121         res($self, $res);
 122 }
 123
 124 sub cmd_mode ($$) {
 125         my ($self, $arg) = @_;
 126         $arg = uc $arg;
 127         return r501 unless $arg eq 'READER';
 128         '201 Posting prohibited';
 129 }
 130
 131 sub cmd_slave ($) { '202 slave status noted' }
 132
 133 sub cmd_xgtitle ($;$) {
 134         my ($self, $wildmat) = @_;
 135         more($self, '282 list of groups and descriptions follows');
 136         list_newsgroups($self, $wildmat);
 137         '.'
 138 }
 139
 140 sub list_overview_fmt ($) {
 141         my ($self) = @_;
 142         do_more($self, $OVERVIEW_FMT);
 143 }
 144
 145 sub list_headers ($;$) {
 146         my ($self) = @_;
 147         do_more($self, $LIST_HEADERS);
 148 }
 149
 150 sub list_active ($;$) {
 151         my ($self, $wildmat) = @_;
 152         wildmat2re($wildmat);
 153         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 154                 $ng->{name} =~ $wildmat or next;
 155                 group_line($self, $ng);
 156         }
 157 }
 158
 159 sub list_active_times ($;$) {
 160         my ($self, $wildmat) = @_;
 161         wildmat2re($wildmat);
 162         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 163                 $ng->{name} =~ $wildmat or next;
 164                 my $c = eval { $ng->mm->created_at } || time;
 165                 more($self, "$ng->{name} $c $ng->{address}");
 166         }
 167 }
 168
 169 sub list_newsgroups ($;$) {
 170         my ($self, $wildmat) = @_;
 171         wildmat2re($wildmat);
 172         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 173                 $ng->{name} =~ $wildmat or next;
 174                 my $d = $ng->description;
 175                 more($self, "$ng->{name} $d");
 176         }
 177 }
 178
 179 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 180 sub cmd_list ($;$$) {
 181         my ($self, @args) = @_;
 182         if (scalar @args) {
 183                 my $arg = shift @args;
 184                 $arg =~ tr/A-Z./a-z_/;
 185                 $arg = "list_$arg";
 186                 return r501 if $DISABLED{$arg};
 187
 188                 $arg = eval {
 189                         no strict 'refs';
 190                         *{$arg}{CODE};
 191                 };
 192                 return r501 unless $arg && args_ok($arg, scalar @args);
 193                 more($self, '215 information follows');
 194                 $arg->($self, @args);
 195         } else {
 196                 more($self, '215 list of newsgroups follows');
 197                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 198                         group_line($self, $ng);
 199                 }
 200         }
 201         '.'
 202 }
 203
 204 sub cmd_listgroup ($;$) {
 205         my ($self, $group) = @_;
 206         if (defined $group) {
 207                 my $res = cmd_group($self, $group);
 208                 return $res if ($res !~ /\A211 /);
 209                 more($self, $res);
 210         }
 211
 212         $self->{ng} or return '412 no newsgroup selected';
 213         $self->long_response(0, long_response_limit, sub {
 214                 my ($i) = @_;
 215                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 216                         my ($ary) = @_;
 217                         more($self, join("\r\n", @$ary));
 218                 });
 219
 220                 # -1 to adjust for implicit increment in long_response
 221                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 222         });
 223 }
 224
 225 sub parse_time ($$;$) {
 226         my ($date, $time, $gmt) = @_;
 227         use Time::Local qw();
 228         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 229         if (defined $gmt) {
 230                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt\n";
 231                 $gmt = 1;
 232         }
 233         my @now = $gmt ? gmtime : localtime;
 234         my ($YYYY, $MM, $DD);
 235         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 236                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 237         } else { # legacy clients send YYMMDD
 238                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 239                 if ($YYYY > strftime('%y', @now)) {
 240                         my $cur_year = $now[5] + 1900;
 241                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 242                 }
 243         }
 244         if ($gmt) {
 245                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 246         } else {
 247                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 248         }
 249 }
 250
 251 sub group_line ($$) {
 252         my ($self, $ng) = @_;
 253         my ($min, $max) = $ng->mm->minmax;
 254         more($self, "$ng->{name} $max $min n") if defined $min && defined $max;
 255 }
 256
 257 sub cmd_newgroups ($$$;$$) {
 258         my ($self, $date, $time, $gmt, $dists) = @_;
 259         my $ts = eval { parse_time($date, $time, $gmt) };
 260         return r501 if $@;
 261
 262         # TODO dists
 263         more($self, '231 list of new newsgroups follows');
 264         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 265                 my $c = eval { $ng->mm->created_at } || 0;
 266                 next unless $c > $ts;
 267                 group_line($self, $ng);
 268         }
 269         '.'
 270 }
 271
 272 sub wildmat2re (;$) {
 273         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 274         my %keep;
 275         my $salt = rand;
 276         use Digest::SHA qw(sha1_hex);
 277         my $tmp = $_[0];
 278
 279         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 280                 my $orig = $1;
 281                 my $key = sha1_hex($orig . $salt);
 282                 $orig =~ s/([^\w\-])+/\Q$1/g;
 283                 $keep{$key} = $orig;
 284                 $key
 285                 #gex;
 286         my %map = ('*' => '.*', '?' => '.' );
 287         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 288         if (scalar %keep) {
 289                 $tmp =~ s#([a-f0-9]{40})#
 290                         my $orig = $keep{$1};
 291                         defined $orig ? $orig : $1;
 292                         #ge;
 293         }
 294         $_[0] = qr/\A$tmp\z/;
 295 }
 296
 297 sub ngpat2re (;$) {
 298         return $_[0] = qr/\A\z/ unless defined $_[0];
 299         my %map = ('*' => '.*', ',' => '|');
 300         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 301         $_[0] = qr/\A(?:$_[0])\z/;
 302 }
 303
 304 sub cmd_newnews ($$$$;$$) {
 305         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 306         my $ts = eval { parse_time($date, $time, $gmt) };
 307         return r501 if $@;
 308         more($self, '230 list of new articles by message-id follows');
 309         my ($keep, $skip) = split('!', $newsgroups, 2);
 310         ngpat2re($keep);
 311         ngpat2re($skip);
 312         my @srch;
 313         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 314                 $ng->{name} =~ $keep or next;
 315                 $ng->{name} =~ $skip and next;
 316                 my $srch = $ng->search or next;
 317                 push @srch, $srch;
 318         };
 319         return '.' unless @srch;
 320
 321         $ts .= '..';
 322         my $opts = { asc => 1, limit => 1000, offset => 0 };
 323         $self->long_response(0, long_response_limit, sub {
 324                 my ($i) = @_;
 325                 my $srch = $srch[0];
 326                 my $res = $srch->query($ts, $opts);
 327                 my $msgs = $res->{msgs};
 328                 if (my $nr = scalar @$msgs) {
 329                         more($self, '<' .
 330                                 join(">\r\n<", map { $_->mid } @$msgs ).
 331                                 '>');
 332                         $opts->{offset} += $nr;
 333                 } else {
 334                         shift @srch;
 335                         if (@srch) { # continue onto next newsgroup
 336                                 $opts->{offset} = 0;
 337                         } else { # break out of the long response.
 338                                 $$i = long_response_limit;
 339                         }
 340                 }
 341         });
 342 }
 343
 344 sub cmd_group ($$) {
 345         my ($self, $group) = @_;
 346         my $no_such = '411 no such news group';
 347         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 348
 349         $self->{ng} = $ng;
 350         my ($min, $max) = $ng->mm->minmax;
 351         $min ||= 0;
 352         $max ||= 0;
 353         $self->{article} = $min;
 354         my $est_size = $max - $min;
 355         "211 $est_size $min $max $group";
 356 }
 357
 358 sub article_adj ($$) {
 359         my ($self, $off) = @_;
 360         my $ng = $self->{ng} or return '412 no newsgroup selected';
 361
 362         my $n = $self->{article};
 363         defined $n or return '420 no current article has been selected';
 364
 365         $n += $off;
 366         my $mid = $ng->mm->mid_for($n);
 367         unless ($mid) {
 368                 $n = $off > 0 ? 'next' : 'previous';
 369                 return "421 no $n article in this group";
 370         }
 371         $self->{article} = $n;
 372         "223 $n <$mid> article retrieved - request text separately";
 373 }
 374
 375 sub cmd_next ($) { article_adj($_[0], 1) }
 376 sub cmd_last ($) { article_adj($_[0], -1) }
 377
 378 # We want to encourage using email and CC-ing everybody involved to avoid
 379 # the single-point-of-failure a single server provides.
 380 sub cmd_post ($) {
 381         my ($self) = @_;
 382         my $ng = $self->{ng};
 383         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 384 }
 385
 386 sub cmd_quit ($) {
 387         my ($self) = @_;
 388         res($self, '205 closing connection - goodbye!');
 389         $self->close;
 390         undef;
 391 }
 392
 393 sub art_lookup ($$$) {
 394         my ($self, $art, $set_headers) = @_;
 395         my $ng = $self->{ng};
 396         my ($n, $mid);
 397         my $err;
 398         if (defined $art) {
 399                 if ($art =~ /\A\d+\z/o) {
 400                         $err = '423 no such article number in this group';
 401                         $n = int($art);
 402                         goto find_mid;
 403                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 404                         $mid = $1;
 405                         $err = r430;
 406                         $n = $ng->mm->num_for($mid) if $ng;
 407                         goto found if defined $n;
 408                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 409                                 $n = $g->mm->num_for($mid);
 410                                 if (defined $n) {
 411                                         $ng = $g;
 412                                         goto found;
 413                                 }
 414                         }
 415                         return $err;
 416                 } else {
 417                         return r501;
 418                 }
 419         } else {
 420                 $err = '420 no current article has been selected';
 421                 $n = $self->{article};
 422                 defined $n or return $err;
 423 find_mid:
 424                 $ng or return '412 no newsgroup has been selected';
 425                 $mid = $ng->mm->mid_for($n);
 426                 defined $mid or return $err;
 427         }
 428 found:
 429         my $o = 'HEAD:' . mid2path($mid);
 430         my $bytes;
 431         my $s = eval { Email::MIME->new($ng->gcf->cat_file($o, \$bytes)) };
 432         return $err unless $s;
 433         my $lines;
 434         if ($set_headers) {
 435                 $s->header_set('Newsgroups', $ng->{name});
 436                 $s->header_set('Xref', xref($ng, $n));
 437                 $lines = $s->body =~ tr!\n!\n!;
 438
 439                 # must be last
 440                 $s->body_set('') if ($set_headers == 2);
 441         }
 442         [ $n, $mid, $s, $bytes, $lines, $ng ];
 443 }
 444
 445 sub simple_body_write ($$) {
 446         my ($self, $s) = @_;
 447         my $body = $s->body;
 448         $s->body_set('');
 449         $body =~ s/^\./../smg;
 450         $body =~ s/(?<!\r)\n/\r\n/sg;
 451         do_more($self, $body);
 452         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 453         '.'
 454 }
 455
 456 sub set_art {
 457         my ($self, $art) = @_;
 458         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 459 }
 460
 461 sub cmd_article ($;$) {
 462         my ($self, $art) = @_;
 463         my $r = $self->art_lookup($art, 1);
 464         return $r unless ref $r;
 465         my ($n, $mid, $s) = @$r;
 466         set_art($self, $art);
 467         more($self, "220 $n <$mid> article retrieved - head and body follow");
 468         do_more($self, $s->header_obj->as_string);
 469         do_more($self, "\r\n");
 470         simple_body_write($self, $s);
 471 }
 472
 473 sub cmd_head ($;$) {
 474         my ($self, $art) = @_;
 475         my $r = $self->art_lookup($art, 2);
 476         return $r unless ref $r;
 477         my ($n, $mid, $s) = @$r;
 478         set_art($self, $art);
 479         more($self, "221 $n <$mid> article retrieved - head follows");
 480         do_more($self, $s->header_obj->as_string);
 481         '.'
 482 }
 483
 484 sub cmd_body ($;$) {
 485         my ($self, $art) = @_;
 486         my $r = $self->art_lookup($art, 0);
 487         return $r unless ref $r;
 488         my ($n, $mid, $s) = @$r;
 489         set_art($self, $art);
 490         more($self, "222 $n <$mid> article retrieved - body follows");
 491         simple_body_write($self, $s);
 492 }
 493
 494 sub cmd_stat ($;$) {
 495         my ($self, $art) = @_;
 496         my $r = $self->art_lookup($art, 0);
 497         return $r unless ref $r;
 498         my ($n, $mid, undef) = @$r;
 499         set_art($self, $art);
 500         "223 $n <$mid> article retrieved - request text separately";
 501 }
 502
 503 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 504
 505 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 506
 507 sub cmd_help ($) {
 508         my ($self) = @_;
 509         more($self, '100 help text follows');
 510         '.'
 511 }
 512
 513 sub get_range ($$) {
 514         my ($self, $range) = @_;
 515         my $ng = $self->{ng} or return '412 no news group has been selected';
 516         defined $range or return '420 No article(s) selected';
 517         my ($beg, $end);
 518         my ($min, $max) = $ng->mm->minmax;
 519         if ($range =~ /\A(\d+)\z/) {
 520                 $beg = $end = $1;
 521         } elsif ($range =~ /\A(\d+)-\z/) {
 522                 ($beg, $end) = ($1, $max);
 523         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 524                 ($beg, $end) = ($1, $2);
 525         } else {
 526                 return r501;
 527         }
 528         $beg = $min if ($beg < $min);
 529         $end = $max if ($end > $max);
 530         return '420 No article(s) selected' if ($beg > $end);
 531         [ $beg, $end ];
 532 }
 533
 534 sub hdr_val ($$) {
 535         my ($r, $header) = @_;
 536         return $r->[3] if $header =~ /\A:?bytes\z/i;
 537         return $r->[4] if $header =~ /\A:?lines\z/i;
 538         $r = $r->[2]->header_obj->header($header);
 539         defined $r or return;
 540         $r =~ s/[\r\n\t]+/ /sg;
 541         $r;
 542 }
 543
 544 sub long_response ($$$$) {
 545         my ($self, $beg, $end, $cb) = @_;
 546         die "BUG: nested long response" if $self->{long_res};
 547
 548         my $fd = $self->{fd};
 549         defined $fd or return;
 550         # make sure we disable reading during a long response,
 551         # clients should not be sending us stuff and making us do more
 552         # work while we are stream a response to them
 553         $self->watch_read(0);
 554         my $t0 = now();
 555         $self->{long_res} = sub {
 556                 # limit our own running time for fairness with other
 557                 # clients and to avoid buffering too much:
 558                 my $lim = 100;
 559
 560                 my $err;
 561                 do {
 562                         eval { $cb->(\$beg) };
 563                 } until (($err = $@) || $self->{closed} ||
 564                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 565
 566                 if ($err || $self->{closed}) {
 567                         $self->{long_res} = undef;
 568
 569                         if ($err) {
 570                                 err($self,
 571                                     "$err during long response[$fd] - %0.6f",
 572                                         now() - $t0);
 573                         }
 574                         if ($self->{closed}) {
 575                                 out($self, " deferred[$fd] aborted - %0.6f",
 576                                            now() - $t0);
 577                         } else {
 578                                 update_idle_time($self);
 579                                 $self->watch_read(1);
 580                         }
 581                 } elsif (!$lim || $self->{write_buf_size}) {
 582                         # no recursion, schedule another call ASAP
 583                         # but only after all pending writes are done
 584                         update_idle_time($self);
 585                         Danga::Socket->AddTimer(0, sub {
 586                                 $self->write($self->{long_res});
 587                         });
 588                 } else { # all done!
 589                         $self->{long_res} = undef;
 590                         $self->watch_read(1);
 591                         res($self, '.');
 592                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 593                 }
 594         };
 595         $self->{long_res}->(); # kick off!
 596         undef;
 597 }
 598
 599 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 600         my ($self, $xhdr, $range) = @_;
 601
 602         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 603                 my ($ng, $n) = mid_lookup($self, $1);
 604                 return r430 unless $n;
 605                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 606         } else { # numeric range
 607                 $range = $self->{article} unless defined $range;
 608                 my $r = get_range($self, $range);
 609                 return $r unless ref $r;
 610                 my $mm = $self->{ng}->mm;
 611                 my ($beg, $end) = @$r;
 612                 more($self, $xhdr ? r221 : r225);
 613                 $self->long_response($beg, $end, sub {
 614                         my ($i) = @_;
 615                         my $mid = $mm->mid_for($$i);
 616                         more($self, "$$i <$mid>") if defined $mid;
 617                 });
 618         }
 619 }
 620
 621 sub xref ($$) {
 622         my ($ng, $n) = @_;
 623         "$ng->{domain} $ng->{name}:$n"
 624 }
 625
 626 sub mid_lookup ($$) {
 627         my ($self, $mid) = @_;
 628         my $self_ng = $self->{ng};
 629         if ($self_ng) {
 630                 my $n = $self_ng->mm->num_for($mid);
 631                 return ($self_ng, $n) if defined $n;
 632         }
 633         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 634                 next if defined $self_ng && $ng eq $self_ng;
 635                 my $n = $ng->mm->num_for($mid);
 636                 return ($ng, $n) if defined $n;
 637         }
 638         (undef, undef);
 639 }
 640
 641 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 642         my ($self, $xhdr, $range) = @_;
 643
 644         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 645                 my ($ng, $n) = mid_lookup($self, $1);
 646                 return r430 unless $n;
 647                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 648         } else { # numeric range
 649                 $range = $self->{article} unless defined $range;
 650                 my $r = get_range($self, $range);
 651                 return $r unless ref $r;
 652                 my $ng = $self->{ng};
 653                 my $mm = $ng->mm;
 654                 my ($beg, $end) = @$r;
 655                 more($self, $xhdr ? r221 : r225);
 656                 $self->long_response($beg, $end, sub {
 657                         my ($i) = @_;
 658                         my $mid = $mm->mid_for($$i);
 659                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 660                 });
 661         }
 662 }
 663
 664 sub search_header_for {
 665         my ($srch, $mid, $field) = @_;
 666         my $smsg = $srch->lookup_message($mid) or return;
 667         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 668         $smsg->$field;
 669 }
 670
 671 sub hdr_searchmsg ($$$$) {
 672         my ($self, $xhdr, $field, $range) = @_;
 673         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 674                 my ($ng, $n) = mid_lookup($self, $1);
 675                 return r430 unless $n;
 676                 my $v = search_header_for($ng->search, $range, $field);
 677                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 678         } else { # numeric range
 679                 $range = $self->{article} unless defined $range;
 680                 my $srch = $self->{ng}->search;
 681                 my $mm = $self->{ng}->mm;
 682                 my $r = get_range($self, $range);
 683                 return $r unless ref $r;
 684                 my ($beg, $end) = @$r;
 685                 more($self, $xhdr ? r221 : r225);
 686                 my $off = 0;
 687                 $self->long_response($beg, $end, sub {
 688                         my ($i) = @_;
 689                         my $res = $srch->query_xover($beg, $end, $off);
 690                         my $msgs = $res->{msgs};
 691                         my $nr = scalar @$msgs or return;
 692                         $off += $nr;
 693                         my $tmp = '';
 694                         foreach my $s (@$msgs) {
 695                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 696                         }
 697                         do_more($self, $tmp);
 698                         # -1 to adjust for implicit increment in long_response
 699                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 700                 });
 701         }
 702 }
 703
 704 sub do_hdr ($$$;$) {
 705         my ($self, $xhdr, $header, $range) = @_;
 706         my $sub = lc $header;
 707         if ($sub eq 'message-id') {
 708                 hdr_message_id($self, $xhdr, $range);
 709         } elsif ($sub eq 'xref') {
 710                 hdr_xref($self, $xhdr, $range);
 711         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 712                                 bytes|lines)\z/x) {
 713                 hdr_searchmsg($self, $xhdr, $sub, $range);
 714         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 715                 hdr_searchmsg($self, $xhdr, $1, $range);
 716         } else {
 717                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 718         }
 719 }
 720
 721 # RFC 3977
 722 sub cmd_hdr ($$;$) {
 723         my ($self, $header, $range) = @_;
 724         do_hdr($self, 0, $header, $range);
 725 }
 726
 727 # RFC 2980
 728 sub cmd_xhdr ($$;$) {
 729         my ($self, $header, $range) = @_;
 730         do_hdr($self, 1, $header, $range);
 731 }
 732
 733 sub hdr_mid_prefix ($$$$$) {
 734         my ($self, $xhdr, $ng, $n, $mid) = @_;
 735         return $mid if $xhdr;
 736
 737         # HDR for RFC 3977 users
 738         if (my $self_ng = $self->{ng}) {
 739                 ($self_ng eq $ng) ? $n : '0';
 740         } else {
 741                 '0';
 742         }
 743 }
 744
 745 sub hdr_mid_response ($$$$$$) {
 746         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 747         my $res = '';
 748         if ($xhdr) {
 749                 $res .= r221 . "\r\n";
 750                 $res .= "$mid $v\r\n";
 751         } else {
 752                 $res .= r225 . "\r\n";
 753                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 754                 $res .= "$pfx $v\r\n";
 755         }
 756         res($self, $res .= '.');
 757         undef;
 758 }
 759
 760 sub cmd_xrover ($;$) {
 761         my ($self, $range) = @_;
 762         my $ng = $self->{ng} or return '412 no newsgroup selected';
 763         (defined $range && $range =~ /[<>]/) and
 764                 return '420 No article(s) selected'; # no message IDs
 765
 766         $range = $self->{article} unless defined $range;
 767         my $r = get_range($self, $range);
 768         return $r unless ref $r;
 769         my ($beg, $end) = @$r;
 770         my $mm = $ng->mm;
 771         my $srch = $ng->search;
 772         more($self, '224 Overview information follows');
 773         $self->long_response($beg, $end, sub {
 774                 my ($i) = @_;
 775                 my $mid = $mm->mid_for($$i) or return;
 776                 my $h = search_header_for($srch, $mid, 'references');
 777                 more($self, "$$i $h");
 778         });
 779 }
 780
 781 sub over_line ($$) {
 782         my ($num, $smsg) = @_;
 783         # n.b. field access and procedural calls can be
 784         # 10%-15% faster than OO method calls:
 785         join("\t", $num,
 786                 $smsg->{subject},
 787                 $smsg->{from},
 788                 PublicInbox::SearchMsg::date($smsg),
 789                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 790                 $smsg->{references},
 791                 PublicInbox::SearchMsg::bytes($smsg),
 792                 PublicInbox::SearchMsg::lines($smsg));
 793 }
 794
 795 sub cmd_over ($;$) {
 796         my ($self, $range) = @_;
 797         if ($range && $range =~ /\A<(.+)>\z/) {
 798                 my ($ng, $n) = mid_lookup($self, $1);
 799                 my $smsg = $ng->search->lookup_message($range) or
 800                         return '430 No article with that message-id';
 801                 more($self, '224 Overview information follows (multi-line)');
 802                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 803
 804                 # Only set article number column if it's the current group
 805                 my $self_ng = $self->{ng};
 806                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 807                 more($self, over_line($n, $smsg));
 808                 '.';
 809         } else {
 810                 cmd_xover($self, $range);
 811         }
 812 }
 813
 814 sub cmd_xover ($;$) {
 815         my ($self, $range) = @_;
 816         $range = $self->{article} unless defined $range;
 817         my $r = get_range($self, $range);
 818         return $r unless ref $r;
 819         my ($beg, $end) = @$r;
 820         more($self, "224 Overview information follows for $beg to $end");
 821         my $srch = $self->{ng}->search;
 822         my $off = 0;
 823         $self->long_response($beg, $end, sub {
 824                 my ($i) = @_;
 825                 my $res = $srch->query_xover($beg, $end, $off);
 826                 my $msgs = $res->{msgs};
 827                 my $nr = scalar @$msgs or return;
 828                 $off += $nr;
 829
 830                 # OVERVIEW.FMT
 831                 more($self, join("\r\n", map {
 832                         over_line(PublicInbox::SearchMsg::num($_), $_);
 833                         } @$msgs));
 834
 835                 # -1 to adjust for implicit increment in long_response
 836                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 837         });
 838 }
 839
 840 sub cmd_xpath ($$) {
 841         my ($self, $mid) = @_;
 842         return r501 unless $mid =~ /\A<(.+)>\z/;
 843         $mid = $1;
 844         my @paths;
 845         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 846                 my $n = $ng->mm->num_for($mid);
 847                 push @paths, "$ng->{name}/$n" if defined $n;
 848         }
 849         return '430 no such article on server' unless @paths;
 850         '223 '.join(' ', @paths);
 851 }
 852
 853 sub res ($$) {
 854         my ($self, $line) = @_;
 855         do_write($self, $line . "\r\n");
 856 }
 857
 858 sub more ($$) {
 859         my ($self, $line) = @_;
 860         do_more($self, $line . "\r\n");
 861 }
 862
 863 sub do_write ($$) {
 864         my ($self, $data) = @_;
 865         my $done = $self->write($data);
 866         die if $self->{closed};
 867
 868         # Do not watch for readability if we have data in the queue,
 869         # instead re-enable watching for readability when we can
 870         $self->watch_read(0) if (!$done || $self->{long_res});
 871
 872         $done;
 873 }
 874
 875 sub err ($$;@) {
 876         my ($self, $fmt, @args) = @_;
 877         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 878 }
 879
 880 sub out ($$;@) {
 881         my ($self, $fmt, @args) = @_;
 882         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 883 }
 884
 885 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 886
 887 sub do_more ($$) {
 888         my ($self, $data) = @_;
 889         if (MSG_MORE && !$self->{write_buf_size}) {
 890                 my $n = send($self->{sock}, $data, MSG_MORE);
 891                 if (defined $n) {
 892                         my $dlen = length($data);
 893                         return 1 if $n == $dlen; # all done!
 894                         $data = substr($data, $n, $dlen - $n);
 895                 }
 896         }
 897         $self->do_write($data);
 898 }
 899
 900 # callbacks for by Danga::Socket
 901
 902 sub event_hup { $_[0]->close }
 903 sub event_err { $_[0]->close }
 904
 905 sub event_write {
 906         my ($self) = @_;
 907         update_idle_time($self);
 908         # only continue watching for readability when we are done writing:
 909         if ($self->write(undef) == 1 && !$self->{long_res}) {
 910                 $self->watch_read(1);
 911         }
 912 }
 913
 914 sub event_read {
 915         my ($self) = @_;
 916         use constant LINE_MAX => 512; # RFC 977 section 2.3
 917         my $r = 1;
 918
 919         my $buf = $self->read(LINE_MAX) or return $self->close;
 920         $self->{rbuf} .= $$buf;
 921         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 922                 my $line = $1;
 923                 my $t0 = now();
 924                 my $fd = $self->{fd};
 925                 $r = eval { $self->process_line($line) };
 926                 my $d = $self->{long_res} ?
 927                         " deferred[$fd]" : '';
 928                 out($self, "[$fd] $line - %0.6f$d", now() - $t0);
 929         }
 930
 931         return $self->close if $r < 0;
 932         my $len = length($self->{rbuf});
 933         return $self->close if ($len >= LINE_MAX);
 934         update_idle_time($self);
 935 }
 936
 937 sub watch_read {
 938         my ($self, $bool) = @_;
 939         my $rv = $self->SUPER::watch_read($bool);
 940         if ($bool && $self->{rbuf} ne '') {
 941                 # Force another read if there is a pipelined request.
 942                 # We don't know if the socket has anything for us to read,
 943                 # and we must double-check again by the time the timer fires
 944                 # in case we really did dispatch a read event and started
 945                 # another long response.
 946                 Danga::Socket->AddTimer(0, sub {
 947                         if (&Danga::Socket::POLLIN & $self->{event_watch}) {
 948                                 $self->event_read;
 949                         }
 950                 });
 951         }
 952         $rv;
 953 }
 954
 955 sub busy () {
 956         my ($self) = @_;
 957         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
 958 }
 959
 960 1;