lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use URI::Escape qw(uri_escape_utf8);
  19 use constant {
  20         r501 => '501 command syntax error',
  21         r221 => '221 Header follows',
  22         r224 => '224 Overview information follows (multi-line)',
  23         r225 => '225 Headers follow (multi-line)',
  24         r430 => '430 No article with that message-id',
  25         long_response_limit => 0xffffffff,
  26 };
  27
  28 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 # LISTGROUP could get pretty bad, too...
  37 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  38
  39 my $EXPMAP; # fd -> [ idle_time, $self ]
  40 my $expt;
  41 our $EXPTIME = 180; # 3 minutes
  42 my $WEAKEN = {}; # string(nntpd) -> nntpd
  43 my $weakt;
  44 my $nextt;
  45
  46 my $nextq = [];
  47 sub next_tick () {
  48         $nextt = undef;
  49         my $q = $nextq;
  50         $nextq = [];
  51         foreach my $nntp (@$q) {
  52                 # for request && response protocols, always finish writing
  53                 # before finishing reading:
  54                 if (my $long_cb = $nntp->{long_res}) {
  55                         $nntp->write($long_cb);
  56                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  57                         event_read($nntp);
  58                 }
  59         }
  60 }
  61
  62 sub update_idle_time ($) {
  63         my ($self) = @_;
  64         my $tmp = $self->{sock} or return;
  65         $tmp = fileno($tmp);
  66         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  67 }
  68
  69 # reduce FD pressure by closing some "git cat-file --batch" processes
  70 # and unused FDs for msgmap and Xapian indices
  71 sub weaken_groups () {
  72         $weakt = undef;
  73         foreach my $nntpd (values %$WEAKEN) {
  74                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  75         }
  76         $WEAKEN = {};
  77 }
  78
  79 sub expire_old () {
  80         my $now = now();
  81         my $exp = $EXPTIME;
  82         my $old = $now - $exp;
  83         my $nr = 0;
  84         my %new;
  85         while (my ($fd, $v) = each %$EXPMAP) {
  86                 my ($idle_time, $nntp) = @$v;
  87                 if ($idle_time < $old) {
  88                         $nntp->close; # idempotent
  89                 } else {
  90                         ++$nr;
  91                         $new{$fd} = $v;
  92                 }
  93         }
  94         $EXPMAP = \%new;
  95         if ($nr) {
  96                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  97                 weaken_groups();
  98         } else {
  99                 $expt = undef;
 100                 # noop to kick outselves out of the loop ASAP so descriptors
 101                 # really get closed
 102                 PublicInbox::EvCleanup::asap(sub {});
 103
 104                 # grace period for reaping resources
 105                 $weakt ||= PublicInbox::EvCleanup::later(*weaken_groups);
 106         }
 107 }
 108
 109 sub new ($$$) {
 110         my ($class, $sock, $nntpd) = @_;
 111         my $self = fields::new($class);
 112         $self->SUPER::new($sock);
 113         $self->{nntpd} = $nntpd;
 114         res($self, '201 server ready - post via email');
 115         $self->{rbuf} = '';
 116         $self->watch_read(1);
 117         update_idle_time($self);
 118         $WEAKEN->{"$nntpd"} = $nntpd;
 119         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 120         $self;
 121 }
 122
 123 sub args_ok ($$) {
 124         my ($cb, $argc) = @_;
 125         my $tot = prototype $cb;
 126         my ($nreq, undef) = split(';', $tot);
 127         $nreq = ($nreq =~ tr/$//) - 1;
 128         $tot = ($tot =~ tr/$//) - 1;
 129         ($argc <= $tot && $argc >= $nreq);
 130 }
 131
 132 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 133 sub process_line ($$) {
 134         my ($self, $l) = @_;
 135         my ($req, @args) = split(/\s+/, $l);
 136         $req = lc($req);
 137         $req = eval {
 138                 no strict 'refs';
 139                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 140         };
 141         return res($self, '500 command not recognized') unless $req;
 142         return res($self, r501) unless args_ok($req, scalar @args);
 143
 144         my $res = eval { $req->($self, @args) };
 145         my $err = $@;
 146         if ($err && !$self->{closed}) {
 147                 chomp($l);
 148                 err($self, 'error from: %s (%s)', $l, $err);
 149                 $res = '503 program fault - command not performed';
 150         }
 151         return 0 unless defined $res;
 152         res($self, $res);
 153 }
 154
 155 sub cmd_mode ($$) {
 156         my ($self, $arg) = @_;
 157         $arg = uc $arg;
 158         return r501 unless $arg eq 'READER';
 159         '201 Posting prohibited';
 160 }
 161
 162 sub cmd_slave ($) { '202 slave status noted' }
 163
 164 sub cmd_xgtitle ($;$) {
 165         my ($self, $wildmat) = @_;
 166         more($self, '282 list of groups and descriptions follows');
 167         list_newsgroups($self, $wildmat);
 168         '.'
 169 }
 170
 171 sub list_overview_fmt ($) {
 172         my ($self) = @_;
 173         do_more($self, $OVERVIEW_FMT);
 174 }
 175
 176 sub list_headers ($;$) {
 177         my ($self) = @_;
 178         do_more($self, $LIST_HEADERS);
 179 }
 180
 181 sub list_active ($;$) {
 182         my ($self, $wildmat) = @_;
 183         wildmat2re($wildmat);
 184         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 185                 $ng->{newsgroup} =~ $wildmat or next;
 186                 group_line($self, $ng);
 187         }
 188 }
 189
 190 sub list_active_times ($;$) {
 191         my ($self, $wildmat) = @_;
 192         wildmat2re($wildmat);
 193         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 194                 $ng->{newsgroup} =~ $wildmat or next;
 195                 my $c = eval { $ng->mm->created_at } || time;
 196                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 197         }
 198 }
 199
 200 sub list_newsgroups ($;$) {
 201         my ($self, $wildmat) = @_;
 202         wildmat2re($wildmat);
 203         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 204                 $ng->{newsgroup} =~ $wildmat or next;
 205                 my $d = $ng->description;
 206                 more($self, "$ng->{newsgroup} $d");
 207         }
 208 }
 209
 210 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 211 sub cmd_list ($;$$) {
 212         my ($self, @args) = @_;
 213         if (scalar @args) {
 214                 my $arg = shift @args;
 215                 $arg =~ tr/A-Z./a-z_/;
 216                 $arg = "list_$arg";
 217                 return r501 if $DISABLED{$arg};
 218
 219                 $arg = eval {
 220                         no strict 'refs';
 221                         *{$arg}{CODE};
 222                 };
 223                 return r501 unless $arg && args_ok($arg, scalar @args);
 224                 more($self, '215 information follows');
 225                 $arg->($self, @args);
 226         } else {
 227                 more($self, '215 list of newsgroups follows');
 228                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 229                         group_line($self, $ng);
 230                 }
 231         }
 232         '.'
 233 }
 234
 235 sub cmd_listgroup ($;$) {
 236         my ($self, $group) = @_;
 237         if (defined $group) {
 238                 my $res = cmd_group($self, $group);
 239                 return $res if ($res !~ /\A211 /);
 240                 more($self, $res);
 241         }
 242
 243         $self->{ng} or return '412 no newsgroup selected';
 244         long_response($self, 0, long_response_limit, sub {
 245                 my ($i) = @_;
 246                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 247                         my ($ary) = @_;
 248                         more($self, join("\r\n", @$ary));
 249                 });
 250
 251                 # -1 to adjust for implicit increment in long_response
 252                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 253         });
 254 }
 255
 256 sub parse_time ($$;$) {
 257         my ($date, $time, $gmt) = @_;
 258         use Time::Local qw();
 259         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 260         if (defined $gmt) {
 261                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 262                 $gmt = 1;
 263         }
 264         my @now = $gmt ? gmtime : localtime;
 265         my ($YYYY, $MM, $DD);
 266         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 267                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 268         } else { # legacy clients send YYMMDD
 269                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 270                 if ($YYYY > strftime('%y', @now)) {
 271                         my $cur_year = $now[5] + 1900;
 272                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 273                 }
 274         }
 275         if ($gmt) {
 276                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 277         } else {
 278                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 279         }
 280 }
 281
 282 sub group_line ($$) {
 283         my ($self, $ng) = @_;
 284         my ($min, $max) = $ng->mm->minmax;
 285         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 286 }
 287
 288 sub cmd_newgroups ($$$;$$) {
 289         my ($self, $date, $time, $gmt, $dists) = @_;
 290         my $ts = eval { parse_time($date, $time, $gmt) };
 291         return r501 if $@;
 292
 293         # TODO dists
 294         more($self, '231 list of new newsgroups follows');
 295         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 296                 my $c = eval { $ng->mm->created_at } || 0;
 297                 next unless $c > $ts;
 298                 group_line($self, $ng);
 299         }
 300         '.'
 301 }
 302
 303 sub wildmat2re (;$) {
 304         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 305         my %keep;
 306         my $salt = rand;
 307         use Digest::SHA qw(sha1_hex);
 308         my $tmp = $_[0];
 309
 310         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 311                 my $orig = $1;
 312                 my $key = sha1_hex($orig . $salt);
 313                 $orig =~ s/([^\w\-])+/\Q$1/g;
 314                 $keep{$key} = $orig;
 315                 $key
 316                 #gex;
 317         my %map = ('*' => '.*', '?' => '.' );
 318         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 319         if (scalar %keep) {
 320                 $tmp =~ s#([a-f0-9]{40})#
 321                         my $orig = $keep{$1};
 322                         defined $orig ? $orig : $1;
 323                         #ge;
 324         }
 325         $_[0] = qr/\A$tmp\z/;
 326 }
 327
 328 sub ngpat2re (;$) {
 329         return $_[0] = qr/\A\z/ unless defined $_[0];
 330         my %map = ('*' => '.*', ',' => '|');
 331         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 332         $_[0] = qr/\A(?:$_[0])\z/;
 333 }
 334
 335 sub cmd_newnews ($$$$;$$) {
 336         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 337         my $ts = eval { parse_time($date, $time, $gmt) };
 338         return r501 if $@;
 339         more($self, '230 list of new articles by message-id follows');
 340         my ($keep, $skip) = split('!', $newsgroups, 2);
 341         ngpat2re($keep);
 342         ngpat2re($skip);
 343         my @srch;
 344         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 345                 $ng->{newsgroup} =~ $keep or next;
 346                 $ng->{newsgroup} =~ $skip and next;
 347                 my $srch = $ng->search or next;
 348                 push @srch, $srch;
 349         };
 350         return '.' unless @srch;
 351
 352         $ts .= '..';
 353         my $opts = { asc => 1, limit => 1000, offset => 0 };
 354         long_response($self, 0, long_response_limit, sub {
 355                 my ($i) = @_;
 356                 my $srch = $srch[0];
 357                 my $res = $srch->query($ts, $opts);
 358                 my $msgs = $res->{msgs};
 359                 if (my $nr = scalar @$msgs) {
 360                         more($self, '<' .
 361                                 join(">\r\n<", map { $_->mid } @$msgs ).
 362                                 '>');
 363                         $opts->{offset} += $nr;
 364                 } else {
 365                         shift @srch;
 366                         if (@srch) { # continue onto next newsgroup
 367                                 $opts->{offset} = 0;
 368                         } else { # break out of the long response.
 369                                 $$i = long_response_limit;
 370                         }
 371                 }
 372         });
 373 }
 374
 375 sub cmd_group ($$) {
 376         my ($self, $group) = @_;
 377         my $no_such = '411 no such news group';
 378         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 379
 380         $self->{ng} = $ng;
 381         my ($min, $max) = $ng->mm->minmax;
 382         $min ||= 0;
 383         $max ||= 0;
 384         $self->{article} = $min;
 385         my $est_size = $max - $min;
 386         "211 $est_size $min $max $group";
 387 }
 388
 389 sub article_adj ($$) {
 390         my ($self, $off) = @_;
 391         my $ng = $self->{ng} or return '412 no newsgroup selected';
 392
 393         my $n = $self->{article};
 394         defined $n or return '420 no current article has been selected';
 395
 396         $n += $off;
 397         my $mid = $ng->mm->mid_for($n);
 398         unless ($mid) {
 399                 $n = $off > 0 ? 'next' : 'previous';
 400                 return "421 no $n article in this group";
 401         }
 402         $self->{article} = $n;
 403         "223 $n <$mid> article retrieved - request text separately";
 404 }
 405
 406 sub cmd_next ($) { article_adj($_[0], 1) }
 407 sub cmd_last ($) { article_adj($_[0], -1) }
 408
 409 # We want to encourage using email and CC-ing everybody involved to avoid
 410 # the single-point-of-failure a single server provides.
 411 sub cmd_post ($) {
 412         my ($self) = @_;
 413         my $ng = $self->{ng};
 414         $ng ? "440 mailto:$ng->{-primary_address} to post"
 415                 : '440 posting not allowed'
 416 }
 417
 418 sub cmd_quit ($) {
 419         my ($self) = @_;
 420         res($self, '205 closing connection - goodbye!');
 421         $self->close;
 422         undef;
 423 }
 424
 425 sub header_append ($$$) {
 426         my ($hdr, $k, $v) = @_;
 427         my @v = $hdr->header($k);
 428         foreach (@v) {
 429                 return if $v eq $_;
 430         }
 431         $hdr->header_set($k, @v, $v);
 432 }
 433
 434 sub set_nntp_headers {
 435         my ($hdr, $ng, $n, $mid) = @_;
 436
 437         # clobber some
 438         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 439         $hdr->header_set('Xref', xref($ng, $n));
 440         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 441         if (my $url = $ng->base_url) {
 442                 $mid = uri_escape_utf8($mid);
 443                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 444                 header_append($hdr, 'List-Archive', "<$url>");
 445         }
 446 }
 447
 448 sub art_lookup ($$$) {
 449         my ($self, $art, $set_headers) = @_;
 450         my $ng = $self->{ng};
 451         my ($n, $mid);
 452         my $err;
 453         if (defined $art) {
 454                 if ($art =~ /\A\d+\z/o) {
 455                         $err = '423 no such article number in this group';
 456                         $n = int($art);
 457                         goto find_mid;
 458                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 459                         $mid = $1;
 460                         $err = r430;
 461                         $n = $ng->mm->num_for($mid) if $ng;
 462                         goto found if defined $n;
 463                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 464                                 $n = $g->mm->num_for($mid);
 465                                 if (defined $n) {
 466                                         $ng = $g;
 467                                         goto found;
 468                                 }
 469                         }
 470                         return $err;
 471                 } else {
 472                         return r501;
 473                 }
 474         } else {
 475                 $err = '420 no current article has been selected';
 476                 $n = $self->{article};
 477                 defined $n or return $err;
 478 find_mid:
 479                 $ng or return '412 no newsgroup has been selected';
 480                 $mid = $ng->mm->mid_for($n);
 481                 defined $mid or return $err;
 482         }
 483 found:
 484         my $o = 'HEAD:' . mid2path($mid);
 485         my $bytes;
 486         my $s = eval { Email::Simple->new($ng->git->cat_file($o, \$bytes)) };
 487         return $err unless $s;
 488         my $lines;
 489         if ($set_headers) {
 490                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 491                 $lines = $s->body =~ tr!\n!\n!;
 492
 493                 # must be last
 494                 $s->body_set('') if ($set_headers == 2);
 495         }
 496         [ $n, $mid, $s, $bytes, $lines, $ng ];
 497 }
 498
 499 sub simple_body_write ($$) {
 500         my ($self, $s) = @_;
 501         my $body = $s->body;
 502         $s->body_set('');
 503         $body =~ s/^\./../smg;
 504         $body =~ s/(?<!\r)\n/\r\n/sg;
 505         do_more($self, $body);
 506         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 507         '.'
 508 }
 509
 510 sub set_art {
 511         my ($self, $art) = @_;
 512         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 513 }
 514
 515 sub cmd_article ($;$) {
 516         my ($self, $art) = @_;
 517         my $r = art_lookup($self, $art, 1);
 518         return $r unless ref $r;
 519         my ($n, $mid, $s) = @$r;
 520         set_art($self, $art);
 521         more($self, "220 $n <$mid> article retrieved - head and body follow");
 522         do_more($self, $s->header_obj->as_string);
 523         do_more($self, "\r\n");
 524         simple_body_write($self, $s);
 525 }
 526
 527 sub cmd_head ($;$) {
 528         my ($self, $art) = @_;
 529         my $r = art_lookup($self, $art, 2);
 530         return $r unless ref $r;
 531         my ($n, $mid, $s) = @$r;
 532         set_art($self, $art);
 533         more($self, "221 $n <$mid> article retrieved - head follows");
 534         do_more($self, $s->header_obj->as_string);
 535         '.'
 536 }
 537
 538 sub cmd_body ($;$) {
 539         my ($self, $art) = @_;
 540         my $r = art_lookup($self, $art, 0);
 541         return $r unless ref $r;
 542         my ($n, $mid, $s) = @$r;
 543         set_art($self, $art);
 544         more($self, "222 $n <$mid> article retrieved - body follows");
 545         simple_body_write($self, $s);
 546 }
 547
 548 sub cmd_stat ($;$) {
 549         my ($self, $art) = @_;
 550         my $r = art_lookup($self, $art, 0);
 551         return $r unless ref $r;
 552         my ($n, $mid, undef) = @$r;
 553         set_art($self, $art);
 554         "223 $n <$mid> article retrieved - request text separately";
 555 }
 556
 557 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 558
 559 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 560
 561 sub cmd_help ($) {
 562         my ($self) = @_;
 563         more($self, '100 help text follows');
 564         '.'
 565 }
 566
 567 sub get_range ($$) {
 568         my ($self, $range) = @_;
 569         my $ng = $self->{ng} or return '412 no news group has been selected';
 570         defined $range or return '420 No article(s) selected';
 571         my ($beg, $end);
 572         my ($min, $max) = $ng->mm->minmax;
 573         if ($range =~ /\A(\d+)\z/) {
 574                 $beg = $end = $1;
 575         } elsif ($range =~ /\A(\d+)-\z/) {
 576                 ($beg, $end) = ($1, $max);
 577         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 578                 ($beg, $end) = ($1, $2);
 579         } else {
 580                 return r501;
 581         }
 582         $beg = $min if ($beg < $min);
 583         $end = $max if ($end > $max);
 584         return '420 No article(s) selected' if ($beg > $end);
 585         [ $beg, $end ];
 586 }
 587
 588 sub long_response ($$$$) {
 589         my ($self, $beg, $end, $cb) = @_;
 590         die "BUG: nested long response" if $self->{long_res};
 591
 592         my $fd = $self->{fd};
 593         defined $fd or return;
 594         # make sure we disable reading during a long response,
 595         # clients should not be sending us stuff and making us do more
 596         # work while we are stream a response to them
 597         $self->watch_read(0);
 598         my $t0 = now();
 599         $self->{long_res} = sub {
 600                 # limit our own running time for fairness with other
 601                 # clients and to avoid buffering too much:
 602                 my $lim = 100;
 603
 604                 my $err;
 605                 do {
 606                         eval { $cb->(\$beg) };
 607                 } until (($err = $@) || $self->{closed} ||
 608                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 609
 610                 if ($err || $self->{closed}) {
 611                         $self->{long_res} = undef;
 612
 613                         if ($err) {
 614                                 err($self,
 615                                     "%s during long response[$fd] - %0.6f",
 616                                     $err, now() - $t0);
 617                         }
 618                         if ($self->{closed}) {
 619                                 out($self, " deferred[$fd] aborted - %0.6f",
 620                                            now() - $t0);
 621                         } else {
 622                                 update_idle_time($self);
 623                                 $self->watch_read(1);
 624                         }
 625                 } elsif (!$lim || $self->{write_buf_size}) {
 626                         # no recursion, schedule another call ASAP
 627                         # but only after all pending writes are done
 628                         update_idle_time($self);
 629
 630                         push @$nextq, $self;
 631                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 632                 } else { # all done!
 633                         $self->{long_res} = undef;
 634                         $self->watch_read(1);
 635                         res($self, '.');
 636                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 637                 }
 638         };
 639         $self->{long_res}->(); # kick off!
 640         undef;
 641 }
 642
 643 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 644         my ($self, $xhdr, $range) = @_;
 645
 646         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 647                 my ($ng, $n) = mid_lookup($self, $1);
 648                 return r430 unless $n;
 649                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 650         } else { # numeric range
 651                 $range = $self->{article} unless defined $range;
 652                 my $r = get_range($self, $range);
 653                 return $r unless ref $r;
 654                 my $mm = $self->{ng}->mm;
 655                 my ($beg, $end) = @$r;
 656                 more($self, $xhdr ? r221 : r225);
 657                 long_response($self, $beg, $end, sub {
 658                         my ($i) = @_;
 659                         my $mid = $mm->mid_for($$i);
 660                         more($self, "$$i <$mid>") if defined $mid;
 661                 });
 662         }
 663 }
 664
 665 sub xref ($$) {
 666         my ($ng, $n) = @_;
 667         "$ng->{domain} $ng->{newsgroup}:$n"
 668 }
 669
 670 sub mid_lookup ($$) {
 671         my ($self, $mid) = @_;
 672         my $self_ng = $self->{ng};
 673         if ($self_ng) {
 674                 my $n = $self_ng->mm->num_for($mid);
 675                 return ($self_ng, $n) if defined $n;
 676         }
 677         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 678                 next if defined $self_ng && $ng eq $self_ng;
 679                 my $n = $ng->mm->num_for($mid);
 680                 return ($ng, $n) if defined $n;
 681         }
 682         (undef, undef);
 683 }
 684
 685 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 686         my ($self, $xhdr, $range) = @_;
 687
 688         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 689                 my ($ng, $n) = mid_lookup($self, $1);
 690                 return r430 unless $n;
 691                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 692         } else { # numeric range
 693                 $range = $self->{article} unless defined $range;
 694                 my $r = get_range($self, $range);
 695                 return $r unless ref $r;
 696                 my $ng = $self->{ng};
 697                 my $mm = $ng->mm;
 698                 my ($beg, $end) = @$r;
 699                 more($self, $xhdr ? r221 : r225);
 700                 long_response($self, $beg, $end, sub {
 701                         my ($i) = @_;
 702                         my $mid = $mm->mid_for($$i);
 703                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 704                 });
 705         }
 706 }
 707
 708 sub search_header_for {
 709         my ($srch, $mid, $field) = @_;
 710         my $smsg = $srch->lookup_message($mid) or return;
 711         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 712         $smsg->$field;
 713 }
 714
 715 sub hdr_searchmsg ($$$$) {
 716         my ($self, $xhdr, $field, $range) = @_;
 717         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 718                 my ($ng, $n) = mid_lookup($self, $1);
 719                 return r430 unless $n;
 720                 my $v = search_header_for($ng->search, $range, $field);
 721                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 722         } else { # numeric range
 723                 $range = $self->{article} unless defined $range;
 724                 my $srch = $self->{ng}->search;
 725                 my $mm = $self->{ng}->mm;
 726                 my $r = get_range($self, $range);
 727                 return $r unless ref $r;
 728                 my ($beg, $end) = @$r;
 729                 more($self, $xhdr ? r221 : r225);
 730                 my $off = 0;
 731                 long_response($self, $beg, $end, sub {
 732                         my ($i) = @_;
 733                         my $res = $srch->query_xover($beg, $end, $off);
 734                         my $msgs = $res->{msgs};
 735                         my $nr = scalar @$msgs or return;
 736                         $off += $nr;
 737                         my $tmp = '';
 738                         foreach my $s (@$msgs) {
 739                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 740                         }
 741                         do_more($self, $tmp);
 742                         # -1 to adjust for implicit increment in long_response
 743                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 744                 });
 745         }
 746 }
 747
 748 sub do_hdr ($$$;$) {
 749         my ($self, $xhdr, $header, $range) = @_;
 750         my $sub = lc $header;
 751         if ($sub eq 'message-id') {
 752                 hdr_message_id($self, $xhdr, $range);
 753         } elsif ($sub eq 'xref') {
 754                 hdr_xref($self, $xhdr, $range);
 755         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 756                                 bytes|lines)\z/x) {
 757                 hdr_searchmsg($self, $xhdr, $sub, $range);
 758         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 759                 hdr_searchmsg($self, $xhdr, $1, $range);
 760         } else {
 761                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 762         }
 763 }
 764
 765 # RFC 3977
 766 sub cmd_hdr ($$;$) {
 767         my ($self, $header, $range) = @_;
 768         do_hdr($self, 0, $header, $range);
 769 }
 770
 771 # RFC 2980
 772 sub cmd_xhdr ($$;$) {
 773         my ($self, $header, $range) = @_;
 774         do_hdr($self, 1, $header, $range);
 775 }
 776
 777 sub hdr_mid_prefix ($$$$$) {
 778         my ($self, $xhdr, $ng, $n, $mid) = @_;
 779         return $mid if $xhdr;
 780
 781         # HDR for RFC 3977 users
 782         if (my $self_ng = $self->{ng}) {
 783                 ($self_ng eq $ng) ? $n : '0';
 784         } else {
 785                 '0';
 786         }
 787 }
 788
 789 sub hdr_mid_response ($$$$$$) {
 790         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 791         my $res = '';
 792         if ($xhdr) {
 793                 $res .= r221 . "\r\n";
 794                 $res .= "$mid $v\r\n";
 795         } else {
 796                 $res .= r225 . "\r\n";
 797                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 798                 $res .= "$pfx $v\r\n";
 799         }
 800         res($self, $res .= '.');
 801         undef;
 802 }
 803
 804 sub cmd_xrover ($;$) {
 805         my ($self, $range) = @_;
 806         my $ng = $self->{ng} or return '412 no newsgroup selected';
 807         (defined $range && $range =~ /[<>]/) and
 808                 return '420 No article(s) selected'; # no message IDs
 809
 810         $range = $self->{article} unless defined $range;
 811         my $r = get_range($self, $range);
 812         return $r unless ref $r;
 813         my ($beg, $end) = @$r;
 814         my $mm = $ng->mm;
 815         my $srch = $ng->search;
 816         more($self, '224 Overview information follows');
 817         long_response($self, $beg, $end, sub {
 818                 my ($i) = @_;
 819                 my $mid = $mm->mid_for($$i) or return;
 820                 my $h = search_header_for($srch, $mid, 'references');
 821                 more($self, "$$i $h");
 822         });
 823 }
 824
 825 sub over_line ($$) {
 826         my ($num, $smsg) = @_;
 827         # n.b. field access and procedural calls can be
 828         # 10%-15% faster than OO method calls:
 829         join("\t", $num,
 830                 $smsg->{subject},
 831                 $smsg->{from},
 832                 PublicInbox::SearchMsg::date($smsg),
 833                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 834                 $smsg->{references},
 835                 PublicInbox::SearchMsg::bytes($smsg),
 836                 PublicInbox::SearchMsg::lines($smsg));
 837 }
 838
 839 sub cmd_over ($;$) {
 840         my ($self, $range) = @_;
 841         if ($range && $range =~ /\A<(.+)>\z/) {
 842                 my ($ng, $n) = mid_lookup($self, $1);
 843                 my $smsg = $ng->search->lookup_message($range) or
 844                         return '430 No article with that message-id';
 845                 more($self, '224 Overview information follows (multi-line)');
 846                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 847
 848                 # Only set article number column if it's the current group
 849                 my $self_ng = $self->{ng};
 850                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 851                 more($self, over_line($n, $smsg));
 852                 '.';
 853         } else {
 854                 cmd_xover($self, $range);
 855         }
 856 }
 857
 858 sub cmd_xover ($;$) {
 859         my ($self, $range) = @_;
 860         $range = $self->{article} unless defined $range;
 861         my $r = get_range($self, $range);
 862         return $r unless ref $r;
 863         my ($beg, $end) = @$r;
 864         more($self, "224 Overview information follows for $beg to $end");
 865         my $srch = $self->{ng}->search;
 866         my $off = 0;
 867         long_response($self, $beg, $end, sub {
 868                 my ($i) = @_;
 869                 my $res = $srch->query_xover($beg, $end, $off);
 870                 my $msgs = $res->{msgs};
 871                 my $nr = scalar @$msgs or return;
 872                 $off += $nr;
 873
 874                 # OVERVIEW.FMT
 875                 more($self, join("\r\n", map {
 876                         over_line(PublicInbox::SearchMsg::num($_), $_);
 877                         } @$msgs));
 878
 879                 # -1 to adjust for implicit increment in long_response
 880                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 881         });
 882 }
 883
 884 sub cmd_xpath ($$) {
 885         my ($self, $mid) = @_;
 886         return r501 unless $mid =~ /\A<(.+)>\z/;
 887         $mid = $1;
 888         my @paths;
 889         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 890                 my $n = $ng->mm->num_for($mid);
 891                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 892         }
 893         return '430 no such article on server' unless @paths;
 894         '223 '.join(' ', @paths);
 895 }
 896
 897 sub res ($$) {
 898         my ($self, $line) = @_;
 899         utf8::encode($line);
 900         do_write($self, $line . "\r\n");
 901 }
 902
 903 sub more ($$) {
 904         my ($self, $line) = @_;
 905         do_more($self, $line . "\r\n");
 906 }
 907
 908 sub do_write ($$) {
 909         my ($self, $data) = @_;
 910         my $done = $self->write($data);
 911         die if $self->{closed};
 912
 913         # Do not watch for readability if we have data in the queue,
 914         # instead re-enable watching for readability when we can
 915         $self->watch_read(0) if (!$done || $self->{long_res});
 916
 917         $done;
 918 }
 919
 920 sub err ($$;@) {
 921         my ($self, $fmt, @args) = @_;
 922         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 923 }
 924
 925 sub out ($$;@) {
 926         my ($self, $fmt, @args) = @_;
 927         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 928 }
 929
 930 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 931
 932 sub do_more ($$) {
 933         my ($self, $data) = @_;
 934         utf8::encode($data);
 935         if (MSG_MORE && !$self->{write_buf_size}) {
 936                 my $n = send($self->{sock}, $data, MSG_MORE);
 937                 if (defined $n) {
 938                         my $dlen = length($data);
 939                         return 1 if $n == $dlen; # all done!
 940                         $data = substr($data, $n, $dlen - $n);
 941                 }
 942         }
 943         do_write($self, $data);
 944 }
 945
 946 # callbacks for Danga::Socket
 947
 948 sub event_hup { $_[0]->close }
 949 sub event_err { $_[0]->close }
 950
 951 sub event_write {
 952         my ($self) = @_;
 953         update_idle_time($self);
 954         # only continue watching for readability when we are done writing:
 955         if ($self->write(undef) == 1 && !$self->{long_res}) {
 956                 $self->watch_read(1);
 957         }
 958 }
 959
 960 sub event_read {
 961         my ($self) = @_;
 962         use constant LINE_MAX => 512; # RFC 977 section 2.3
 963         my $r = 1;
 964
 965         my $buf = $self->read(LINE_MAX) or return $self->close;
 966         $self->{rbuf} .= $$buf;
 967         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 968                 my $line = $1;
 969                 return $self->close if $line =~ /[[:cntrl:]]/s;
 970                 my $t0 = now();
 971                 my $fd = $self->{fd};
 972                 $r = eval { process_line($self, $line) };
 973                 my $d = $self->{long_res} ?
 974                         " deferred[$fd]" : '';
 975                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 976         }
 977
 978         return $self->close if $r < 0;
 979         my $len = length($self->{rbuf});
 980         return $self->close if ($len >= LINE_MAX);
 981         update_idle_time($self);
 982 }
 983
 984 sub watch_read {
 985         my ($self, $bool) = @_;
 986         my $rv = $self->SUPER::watch_read($bool);
 987         if ($bool && $self->{rbuf} ne '') {
 988                 # Force another read if there is a pipelined request.
 989                 # We don't know if the socket has anything for us to read,
 990                 # and we must double-check again by the time the timer fires
 991                 # in case we really did dispatch a read event and started
 992                 # another long response.
 993                 push @$nextq, $self;
 994                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 995         }
 996         $rv;
 997 }
 998
 999 # for graceful shutdown in PublicInbox::Daemon:
1000 sub busy () {
1001         my ($self) = @_;
1002         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1003 }
1004
1005 1;