lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  34                 "Xref:full\r\n.";
  35 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  36                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  37 my $CAPABILITIES = <<"";
  38 101 Capability list:\r
  39 VERSION 2\r
  40 READER\r
  41 NEWNEWS\r
  42 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  43 HDR\r
  44 OVER\r
  45 COMPRESS DEFLATE\r
  46
  47 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  48
  49 sub new ($$$) {
  50         my ($class, $sock, $nntpd) = @_;
  51         my $self = bless { nntpd => $nntpd }, $class;
  52         my $ev = EPOLLIN;
  53         my $wbuf;
  54         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  55                 return CORE::close($sock) if $! != EAGAIN;
  56                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  57                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  58         }
  59         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  60         if ($wbuf) {
  61                 $self->{wbuf} = $wbuf;
  62         } else {
  63                 greet($self);
  64         }
  65         $self->update_idle_time;
  66         $self;
  67 }
  68
  69 sub args_ok ($$) {
  70         my ($cb, $argc) = @_;
  71         my $tot = prototype $cb;
  72         my ($nreq, undef) = split(';', $tot);
  73         $nreq = ($nreq =~ tr/$//) - 1;
  74         $tot = ($tot =~ tr/$//) - 1;
  75         ($argc <= $tot && $argc >= $nreq);
  76 }
  77
  78 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  79 sub process_line ($$) {
  80         my ($self, $l) = @_;
  81         my ($req, @args) = split(/[ \t]+/, $l);
  82         return 1 unless defined($req); # skip blank line
  83         $req = $self->can('cmd_'.lc($req));
  84         return res($self, '500 command not recognized') unless $req;
  85         return res($self, r501) unless args_ok($req, scalar @args);
  86
  87         my $res = eval { $req->($self, @args) };
  88         my $err = $@;
  89         if ($err && $self->{sock}) {
  90                 local $/ = "\n";
  91                 chomp($l);
  92                 err($self, 'error from: %s (%s)', $l, $err);
  93                 $res = '503 program fault - command not performed';
  94         }
  95         return 0 unless defined $res;
  96         res($self, $res);
  97 }
  98
  99 # The keyword argument is not used (rfc3977 5.2.2)
 100 sub cmd_capabilities ($;$) {
 101         my ($self, undef) = @_;
 102         my $res = $CAPABILITIES;
 103         if (!$self->{sock}->can('accept_SSL') &&
 104                         $self->{nntpd}->{accept_tls}) {
 105                 $res .= "STARTTLS\r\n";
 106         }
 107         $res .= '.';
 108 }
 109
 110 sub cmd_mode ($$) {
 111         my ($self, $arg) = @_;
 112         $arg = uc $arg;
 113         return r501 unless $arg eq 'READER';
 114         '201 Posting prohibited';
 115 }
 116
 117 sub cmd_slave ($) { '202 slave status noted' }
 118
 119 sub cmd_xgtitle ($;$) {
 120         my ($self, $wildmat) = @_;
 121         more($self, '282 list of groups and descriptions follows');
 122         list_newsgroups($self, $wildmat);
 123 }
 124
 125 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 126
 127 sub list_headers ($;$) { $LIST_HEADERS }
 128
 129 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 130         my ($self, $groupnames) = @_;
 131         my @window = splice(@$groupnames, 0, 100) or return 0;
 132         my $ibx;
 133         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 134         for my $ngname (@window) {
 135                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 136         }
 137         scalar(@$groupnames); # continue if there's more
 138 }
 139
 140 sub list_active ($;$) { # called by cmd_list
 141         my ($self, $wildmat) = @_;
 142         wildmat2re($wildmat);
 143         long_response($self, \&list_active_i, [
 144                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 145 }
 146
 147 sub list_active_times_i {
 148         my ($self, $groupnames) = @_;
 149         my @window = splice(@$groupnames, 0, 100) or return 0;
 150         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 151         for my $ngname (@window) {
 152                 my $ibx = $groups->{$ngname} or next;
 153                 my $c = eval { $ibx->uidvalidity } // time;
 154                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 155         }
 156         scalar(@$groupnames); # continue if there's more
 157 }
 158
 159 sub list_active_times ($;$) { # called by cmd_list
 160         my ($self, $wildmat) = @_;
 161         wildmat2re($wildmat);
 162         long_response($self, \&list_active_times_i, [
 163                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 164 }
 165
 166 sub list_newsgroups_i {
 167         my ($self, $groupnames) = @_;
 168         my @window = splice(@$groupnames, 0, 100) or return 0;
 169         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 170         my $ibx;
 171         for my $ngname (@window) {
 172                 $ibx = $groups->{$ngname} and
 173                         more($self, "$ngname ".$ibx->description);
 174         }
 175         scalar(@$groupnames); # continue if there's more
 176 }
 177
 178 sub list_newsgroups ($;$) { # called by cmd_list
 179         my ($self, $wildmat) = @_;
 180         wildmat2re($wildmat);
 181         long_response($self, \&list_newsgroups_i, [
 182                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 183 }
 184
 185 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 186 sub cmd_list ($;$$) {
 187         my ($self, @args) = @_;
 188         if (scalar @args) {
 189                 my $arg = shift @args;
 190                 $arg =~ tr/A-Z./a-z_/;
 191                 my $ret = $arg eq 'active';
 192                 $arg = "list_$arg";
 193                 $arg = $self->can($arg);
 194                 return r501 unless $arg && args_ok($arg, scalar @args);
 195                 more($self, '215 information follows');
 196                 $arg->($self, @args);
 197         } else {
 198                 more($self, '215 list of newsgroups follows');
 199                 long_response($self, \&list_active_i, [ # copy array
 200                         @{$self->{nntpd}->{groupnames}} ]);
 201         }
 202 }
 203
 204 sub listgroup_range_i {
 205         my ($self, $beg, $end) = @_;
 206         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 207         scalar(@$r) or return;
 208         more($self, join("\r\n", map { $_->[0] } @$r));
 209         1;
 210 }
 211
 212 sub listgroup_all_i {
 213         my ($self, $num) = @_;
 214         my $ary = $self->{ng}->mm->ids_after($num);
 215         scalar(@$ary) or return;
 216         more($self, join("\r\n", @$ary));
 217         1;
 218 }
 219
 220 sub cmd_listgroup ($;$$) {
 221         my ($self, $group, $range) = @_;
 222         if (defined $group) {
 223                 my $res = cmd_group($self, $group);
 224                 return $res if ($res !~ /\A211 /);
 225                 more($self, $res);
 226         }
 227         $self->{ng} or return '412 no newsgroup selected';
 228         if (defined $range) {
 229                 my $r = get_range($self, $range);
 230                 return $r unless ref $r;
 231                 long_response($self, \&listgroup_range_i, @$r);
 232         } else { # grab every article number
 233                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 234         }
 235 }
 236
 237 sub parse_time ($$;$) {
 238         my ($date, $time, $gmt) = @_;
 239         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 240         if (defined $gmt) {
 241                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 242                 $gmt = 1;
 243         }
 244         my ($YYYY, $MM, $DD);
 245         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 246                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 247         } else { # legacy clients send YYMMDD
 248                 my $YY;
 249                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 250                 my @now = $gmt ? gmtime : localtime;
 251                 my $cur_year = $now[5] + 1900;
 252                 my $cur_cent = int($cur_year / 100) * 100;
 253                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 254                         ($YY + 1900) : ($YY + $cur_cent);
 255         }
 256         if ($gmt) {
 257                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 258         } else {
 259                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 260         }
 261 }
 262
 263 sub group_line ($$) {
 264         my ($self, $ng) = @_;
 265         my ($min, $max) = $ng->mm->minmax;
 266         more($self, "$ng->{newsgroup} $max $min n");
 267 }
 268
 269 sub cmd_newgroups ($$$;$$) {
 270         my ($self, $date, $time, $gmt, $dists) = @_;
 271         my $ts = eval { parse_time($date, $time, $gmt) };
 272         return r501 if $@;
 273
 274         # TODO dists
 275         more($self, '231 list of new newsgroups follows');
 276         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 277                 my $c = eval { $ng->uidvalidity } // 0;
 278                 next unless $c > $ts;
 279                 group_line($self, $ng);
 280         }
 281         '.'
 282 }
 283
 284 sub wildmat2re (;$) {
 285         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 286         my %keep;
 287         my $salt = rand;
 288         my $tmp = $_[0];
 289
 290         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 291                 my $orig = $1;
 292                 my $key = sha1_hex($orig . $salt);
 293                 $orig =~ s/([^\w\-])+/\Q$1/g;
 294                 $keep{$key} = $orig;
 295                 $key
 296                 #gex;
 297         my %map = ('*' => '.*', '?' => '.' );
 298         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 299         if (scalar %keep) {
 300                 $tmp =~ s#([a-f0-9]{40})#
 301                         my $orig = $keep{$1};
 302                         defined $orig ? $orig : $1;
 303                         #ge;
 304         }
 305         $_[0] = qr/\A$tmp\z/;
 306 }
 307
 308 sub ngpat2re (;$) {
 309         return $_[0] = qr/\A\z/ unless defined $_[0];
 310         my %map = ('*' => '.*', ',' => '|');
 311         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 312         $_[0] = qr/\A(?:$_[0])\z/;
 313 }
 314
 315 sub newnews_i {
 316         my ($self, $names, $ts, $prev) = @_;
 317         my $ngname = $names->[0];
 318         if (my $ibx = $self->{nntpd}->{groups}->{$ngname}) {
 319                 if (my $over = $ibx->over) {
 320                         my $msgs = $over->query_ts($ts, $$prev);
 321                         if (scalar @$msgs) {
 322                                 more($self, '<' .
 323                                         join(">\r\n<",
 324                                                 map { $_->{mid} } @$msgs ) .
 325                                         '>');
 326                                 $$prev = $msgs->[-1]->{num};
 327                                 return 1; # continue on current group
 328                         }
 329                 }
 330         }
 331         shift @$names;
 332         if (@$names) { # continue onto next newsgroup
 333                 $$prev = 0;
 334                 1;
 335         } else { # all done, break out of the long_response
 336                 undef;
 337         }
 338 }
 339
 340 sub cmd_newnews ($$$$;$$) {
 341         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 342         my $ts = eval { parse_time($date, $time, $gmt) };
 343         return r501 if $@;
 344         more($self, '230 list of new articles by message-id follows');
 345         my ($keep, $skip) = split('!', $newsgroups, 2);
 346         ngpat2re($keep);
 347         ngpat2re($skip);
 348         my @names = grep(!/$skip/, grep(/$keep/,
 349                                 @{$self->{nntpd}->{groupnames}}));
 350         return '.' unless scalar(@names);
 351         my $prev = 0;
 352         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 353 }
 354
 355 sub cmd_group ($$) {
 356         my ($self, $group) = @_;
 357         my $no_such = '411 no such news group';
 358         my $nntpd = $self->{nntpd};
 359         my $ng = $nntpd->{groups}->{$group} or return $no_such;
 360         $nntpd->idler_start;
 361
 362         $self->{ng} = $ng;
 363         my ($min, $max) = $ng->mm->minmax;
 364         $self->{article} = $min;
 365         my $est_size = $max - $min;
 366         "211 $est_size $min $max $group";
 367 }
 368
 369 sub article_adj ($$) {
 370         my ($self, $off) = @_;
 371         my $ng = $self->{ng} or return '412 no newsgroup selected';
 372
 373         my $n = $self->{article};
 374         defined $n or return '420 no current article has been selected';
 375
 376         $n += $off;
 377         my $mid = $ng->mm->mid_for($n);
 378         unless ($mid) {
 379                 $n = $off > 0 ? 'next' : 'previous';
 380                 return "421 no $n article in this group";
 381         }
 382         $self->{article} = $n;
 383         "223 $n <$mid> article retrieved - request text separately";
 384 }
 385
 386 sub cmd_next ($) { article_adj($_[0], 1) }
 387 sub cmd_last ($) { article_adj($_[0], -1) }
 388
 389 # We want to encourage using email and CC-ing everybody involved to avoid
 390 # the single-point-of-failure a single server provides.
 391 sub cmd_post ($) {
 392         my ($self) = @_;
 393         my $ng = $self->{ng};
 394         $ng ? "440 mailto:$ng->{-primary_address} to post"
 395                 : '440 posting not allowed'
 396 }
 397
 398 sub cmd_quit ($) {
 399         my ($self) = @_;
 400         res($self, '205 closing connection - goodbye!');
 401         $self->shutdn;
 402         undef;
 403 }
 404
 405 sub header_append ($$$) {
 406         my ($hdr, $k, $v) = @_;
 407         my @v = $hdr->header_raw($k);
 408         foreach (@v) {
 409                 return if $v eq $_;
 410         }
 411         $hdr->header_set($k, @v, $v);
 412 }
 413
 414 sub xref ($$$$) {
 415         my ($self, $ng, $n, $mid) = @_;
 416         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 417
 418         # num_for is pretty cheap and sometimes we'll lookup the existence
 419         # of an article without getting even the OVER info.  In other words,
 420         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 421         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 422         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 423                 next if $ng eq $other;
 424                 my $num = eval { $other->mm->num_for($mid) } or next;
 425                 $ret .= " $other->{newsgroup}:$num";
 426         }
 427         $ret;
 428 }
 429
 430 sub set_nntp_headers ($$) {
 431         my ($hdr, $smsg) = @_;
 432         my ($mid) = $smsg->{mid};
 433
 434         # leafnode (and maybe other NNTP clients) have trouble dealing
 435         # with v2 messages which have multiple Message-IDs (either due
 436         # to our own content-based dedupe or buggy git-send-email versions).
 437         my @mids = $hdr->header_raw('Message-ID');
 438         if (scalar(@mids) > 1) {
 439                 my $mid0 = "<$mid>";
 440                 $hdr->header_set('Message-ID', $mid0);
 441                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 442                 my %seen = map { $_ => 1 } (@alt, $mid0);
 443                 push(@alt, grep { !$seen{$_}++ } @mids);
 444                 $hdr->header_set('X-Alt-Message-ID', @alt);
 445         }
 446
 447         # clobber some existing headers
 448         my $ibx = $smsg->{-ibx};
 449         my $xref = xref($smsg->{nntp}, $ibx, $smsg->{num}, $mid);
 450         $hdr->header_set('Xref', $xref);
 451
 452         # RFC 5536 3.1.4
 453         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 454         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 455         $newsgroups =~ tr/ /,/;
 456         $hdr->header_set('Newsgroups', $newsgroups);
 457
 458         # *something* here is required for leafnode, try to follow
 459         # RFC 5536 3.1.5...
 460         $hdr->header_set('Path', $server_name . '!not-for-mail');
 461
 462         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 463         if (my $url = $ibx->base_url) {
 464                 $mid = mid_escape($mid);
 465                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 466                 header_append($hdr, 'List-Archive', "<$url>");
 467         }
 468 }
 469
 470 sub art_lookup ($$$) {
 471         my ($self, $art, $code) = @_;
 472         my $ng = $self->{ng};
 473         my ($n, $mid);
 474         my $err;
 475         if (defined $art) {
 476                 if ($art =~ /\A[0-9]+\z/) {
 477                         $err = '423 no such article number in this group';
 478                         $n = int($art);
 479                         goto find_mid;
 480                 } elsif ($art =~ $ONE_MSGID) {
 481                         $mid = $1;
 482                         $err = r430;
 483                         $n = $ng->mm->num_for($mid) if $ng;
 484                         goto found if defined $n;
 485                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 486                                 $n = $g->mm->num_for($mid);
 487                                 if (defined $n) {
 488                                         $ng = $g;
 489                                         goto found;
 490                                 }
 491                         }
 492                         return $err;
 493                 } else {
 494                         return r501;
 495                 }
 496         } else {
 497                 $err = '420 no current article has been selected';
 498                 $n = $self->{article};
 499                 defined $n or return $err;
 500 find_mid:
 501                 $ng or return '412 no newsgroup has been selected';
 502                 $mid = $ng->mm->mid_for($n);
 503                 defined $mid or return $err;
 504         }
 505 found:
 506         my $smsg = $ng->over->get_art($n) or return $err;
 507         $smsg->{-ibx} = $ng;
 508         if ($code == 223) { # STAT
 509                 set_art($self, $n);
 510                 "223 $n <$smsg->{mid}> article retrieved - " .
 511                         "request text separately";
 512         } else { # HEAD | BODY | ARTICLE
 513                 $smsg->{nntp} = $self;
 514                 $smsg->{nntp_code} = $code;
 515                 set_art($self, $art);
 516                 # this dereferences to `undef'
 517                 ${git_async_cat($ng->git, $smsg->{blob}, \&blob_cb, $smsg)};
 518         }
 519 }
 520
 521 sub msg_body_write ($$) {
 522         my ($self, $msg) = @_;
 523
 524         # these can momentarily double the memory consumption :<
 525         $$msg =~ s/^\./../smg;
 526         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 527         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 528         $self->msg_more($$msg);
 529 }
 530
 531 sub set_art {
 532         my ($self, $art) = @_;
 533         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 534 }
 535
 536 sub msg_hdr_write ($$) {
 537         my ($eml, $smsg) = @_;
 538         set_nntp_headers($eml, $smsg);
 539
 540         my $hdr = $eml->{hdr} // \(my $x = '');
 541         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 542         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 543         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 544
 545         # for leafnode compatibility, we need to ensure Message-ID headers
 546         # are only a single line.
 547         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 548         $smsg->{nntp}->msg_more($$hdr);
 549 }
 550
 551 sub blob_cb { # called by git->cat_async via git_async_cat
 552         my ($bref, $oid, $type, $size, $smsg) = @_;
 553         my $self = $smsg->{nntp};
 554         my $code = $smsg->{nntp_code};
 555         if (!defined($oid)) {
 556                 # it's possible to have TOCTOU if an admin runs
 557                 # public-inbox-(edit|purge), just move onto the next message
 558                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 559                 return $self->requeue;
 560         } elsif ($smsg->{blob} ne $oid) {
 561                 $self->close;
 562                 die "BUG: $smsg->{blob} != $oid";
 563         }
 564         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 565         my $eml = PublicInbox::Eml->new($bref);
 566         if ($code == 220) {
 567                 more($self, $r .= 'head and body follow');
 568                 msg_hdr_write($eml, $smsg);
 569                 $self->msg_more("\r\n");
 570                 msg_body_write($self, $bref);
 571         } elsif ($code == 221) {
 572                 more($self, $r .= 'head follows');
 573                 msg_hdr_write($eml, $smsg);
 574         } elsif ($code == 222) {
 575                 more($self, $r .= 'body follows');
 576                 msg_body_write($self, $bref);
 577         } else {
 578                 $self->close;
 579                 die "BUG: bad code: $r";
 580         }
 581         $self->write(\".\r\n"); # flushes (includes ->zflush)
 582         $self->requeue;
 583 }
 584
 585 sub cmd_article ($;$) {
 586         my ($self, $art) = @_;
 587         art_lookup($self, $art, 220);
 588 }
 589
 590 sub cmd_head ($;$) {
 591         my ($self, $art) = @_;
 592         art_lookup($self, $art, 221);
 593 }
 594
 595 sub cmd_body ($;$) {
 596         my ($self, $art) = @_;
 597         art_lookup($self, $art, 222);
 598 }
 599
 600 sub cmd_stat ($;$) {
 601         my ($self, $art) = @_;
 602         art_lookup($self, $art, 223); # art may be msgid
 603 }
 604
 605 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 606
 607 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 608
 609 sub cmd_help ($) {
 610         my ($self) = @_;
 611         more($self, '100 help text follows');
 612         '.'
 613 }
 614
 615 sub get_range ($$) {
 616         my ($self, $range) = @_;
 617         my $ng = $self->{ng} or return '412 no news group has been selected';
 618         defined $range or return '420 No article(s) selected';
 619         my ($beg, $end);
 620         my ($min, $max) = $ng->mm->minmax;
 621         if ($range =~ /\A([0-9]+)\z/) {
 622                 $beg = $end = $1;
 623         } elsif ($range =~ /\A([0-9]+)-\z/) {
 624                 ($beg, $end) = ($1, $max);
 625         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 626                 ($beg, $end) = ($1, $2);
 627         } else {
 628                 return r501;
 629         }
 630         $beg = $min if ($beg < $min);
 631         $end = $max if ($end > $max);
 632         return '420 No article(s) selected' if ($beg > $end);
 633         [ \$beg, $end ];
 634 }
 635
 636 sub long_step {
 637         my ($self) = @_;
 638         # wbuf is unset or empty, here; {long} may add to it
 639         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 640         my $more = eval { $cb->($self, @args) };
 641         if ($@ || !$self->{sock}) { # something bad happened...
 642                 delete $self->{long_cb};
 643                 my $elapsed = now() - $t0;
 644                 if ($@) {
 645                         err($self,
 646                             "%s during long response[$fd] - %0.6f",
 647                             $@, $elapsed);
 648                 }
 649                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 650                 $self->close;
 651         } elsif ($more) { # $self->{wbuf}:
 652                 $self->update_idle_time;
 653
 654                 # COMPRESS users all share the same DEFLATE context.
 655                 # Flush it here to ensure clients don't see
 656                 # each other's data
 657                 $self->zflush;
 658
 659                 # no recursion, schedule another call ASAP, but only after
 660                 # all pending writes are done.  autovivify wbuf:
 661                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 662
 663                 # wbuf may be populated by $cb, no need to rearm if so:
 664                 $self->requeue if $new_size == 1;
 665         } else { # all done!
 666                 delete $self->{long_cb};
 667                 res($self, '.');
 668                 my $elapsed = now() - $t0;
 669                 my $fd = fileno($self->{sock});
 670                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 671                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 672                 $self->requeue unless $wbuf && @$wbuf;
 673         }
 674 }
 675
 676 sub long_response ($$;@) {
 677         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 678
 679         my $sock = $self->{sock} or return;
 680         # make sure we disable reading during a long response,
 681         # clients should not be sending us stuff and making us do more
 682         # work while we are stream a response to them
 683         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 684         long_step($self); # kick off!
 685         undef;
 686 }
 687
 688 sub hdr_msgid_range_i {
 689         my ($self, $beg, $end) = @_;
 690         my $r = $self->{ng}->mm->msg_range($beg, $end);
 691         @$r or return;
 692         more($self, join("\r\n", map { "$_->[0] <$_->[1]>" } @$r));
 693         1;
 694 }
 695
 696 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 697         my ($self, $xhdr, $range) = @_;
 698
 699         if (defined $range && $range =~ $ONE_MSGID) {
 700                 my ($ng, $n) = mid_lookup($self, $1);
 701                 return r430 unless $n;
 702                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 703         } else { # numeric range
 704                 $range = $self->{article} unless defined $range;
 705                 my $r = get_range($self, $range);
 706                 return $r unless ref $r;
 707                 more($self, $xhdr ? r221 : r225);
 708                 long_response($self, \&hdr_msgid_range_i, @$r);
 709         }
 710 }
 711
 712 sub mid_lookup ($$) {
 713         my ($self, $mid) = @_;
 714         my $self_ng = $self->{ng};
 715         if ($self_ng) {
 716                 my $n = $self_ng->mm->num_for($mid);
 717                 return ($self_ng, $n) if defined $n;
 718         }
 719         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 720                 next if defined $self_ng && $ng eq $self_ng;
 721                 my $n = $ng->mm->num_for($mid);
 722                 return ($ng, $n) if defined $n;
 723         }
 724         (undef, undef);
 725 }
 726
 727 sub xref_range_i {
 728         my ($self, $beg, $end) = @_;
 729         my $ng = $self->{ng};
 730         my $r = $ng->mm->msg_range($beg, $end);
 731         @$r or return;
 732         more($self, join("\r\n", map {
 733                 my $num = $_->[0];
 734                 "$num ".xref($self, $ng, $num, $_->[1]);
 735         } @$r));
 736         1;
 737 }
 738
 739 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 740         my ($self, $xhdr, $range) = @_;
 741
 742         if (defined $range && $range =~ $ONE_MSGID) {
 743                 my $mid = $1;
 744                 my ($ng, $n) = mid_lookup($self, $mid);
 745                 return r430 unless $n;
 746                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 747                                 xref($self, $ng, $n, $mid));
 748         } else { # numeric range
 749                 $range = $self->{article} unless defined $range;
 750                 my $r = get_range($self, $range);
 751                 return $r unless ref $r;
 752                 more($self, $xhdr ? r221 : r225);
 753                 long_response($self, \&xref_range_i, @$r);
 754         }
 755 }
 756
 757 sub over_header_for {
 758         my ($over, $num, $field) = @_;
 759         my $smsg = $over->get_art($num) or return;
 760         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 761         $smsg->{$field};
 762 }
 763
 764 sub smsg_range_i {
 765         my ($self, $beg, $end, $field) = @_;
 766         my $over = $self->{ng}->over;
 767         my $msgs = $over->query_xover($$beg, $end);
 768         scalar(@$msgs) or return;
 769         my $tmp = '';
 770
 771         # ->{$field} is faster than ->$field invocations, so favor that.
 772         if ($field eq 'date') {
 773                 for my $s (@$msgs) {
 774                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 775                 }
 776         } else {
 777                 for my $s (@$msgs) {
 778                         $tmp .= "$s->{num} $s->{$field}\r\n";
 779                 }
 780         }
 781         utf8::encode($tmp);
 782         $self->msg_more($tmp);
 783         $$beg = $msgs->[-1]->{num} + 1;
 784 }
 785
 786 sub hdr_smsg ($$$$) {
 787         my ($self, $xhdr, $field, $range) = @_;
 788         if (defined $range && $range =~ $ONE_MSGID) {
 789                 my ($ng, $n) = mid_lookup($self, $1);
 790                 return r430 unless defined $n;
 791                 my $v = over_header_for($ng->over, $n, $field);
 792                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 793         } else { # numeric range
 794                 $range = $self->{article} unless defined $range;
 795                 my $r = get_range($self, $range);
 796                 return $r unless ref $r;
 797                 more($self, $xhdr ? r221 : r225);
 798                 long_response($self, \&smsg_range_i, @$r, $field);
 799         }
 800 }
 801
 802 sub do_hdr ($$$;$) {
 803         my ($self, $xhdr, $header, $range) = @_;
 804         my $sub = lc $header;
 805         if ($sub eq 'message-id') {
 806                 hdr_message_id($self, $xhdr, $range);
 807         } elsif ($sub eq 'xref') {
 808                 hdr_xref($self, $xhdr, $range);
 809         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 810                                 bytes|lines)\z/x) {
 811                 hdr_smsg($self, $xhdr, $sub, $range);
 812         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 813                 hdr_smsg($self, $xhdr, $1, $range);
 814         } else {
 815                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 816         }
 817 }
 818
 819 # RFC 3977
 820 sub cmd_hdr ($$;$) {
 821         my ($self, $header, $range) = @_;
 822         do_hdr($self, 0, $header, $range);
 823 }
 824
 825 # RFC 2980
 826 sub cmd_xhdr ($$;$) {
 827         my ($self, $header, $range) = @_;
 828         do_hdr($self, 1, $header, $range);
 829 }
 830
 831 sub hdr_mid_prefix ($$$$$) {
 832         my ($self, $xhdr, $ng, $n, $mid) = @_;
 833         return $mid if $xhdr;
 834
 835         # HDR for RFC 3977 users
 836         if (my $self_ng = $self->{ng}) {
 837                 ($self_ng eq $ng) ? $n : '0';
 838         } else {
 839                 '0';
 840         }
 841 }
 842
 843 sub hdr_mid_response ($$$$$$) {
 844         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 845         my $res = '';
 846         if ($xhdr) {
 847                 $res .= r221 . "\r\n";
 848                 $res .= "$mid $v\r\n";
 849         } else {
 850                 $res .= r225 . "\r\n";
 851                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 852                 $res .= "$pfx $v\r\n";
 853         }
 854         res($self, $res .= '.');
 855         undef;
 856 }
 857
 858 sub xrover_i {
 859         my ($self, $beg, $end) = @_;
 860         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 861         more($self, "$$beg $h") if defined($h);
 862         $$beg++ < $end;
 863 }
 864
 865 sub cmd_xrover ($;$) {
 866         my ($self, $range) = @_;
 867         my $ng = $self->{ng} or return '412 no newsgroup selected';
 868         (defined $range && $range =~ /[<>]/) and
 869                 return '420 No article(s) selected'; # no message IDs
 870
 871         $range = $self->{article} unless defined $range;
 872         my $r = get_range($self, $range);
 873         return $r unless ref $r;
 874         more($self, '224 Overview information follows');
 875         long_response($self, \&xrover_i, @$r);
 876 }
 877
 878 sub over_line ($$$$) {
 879         my ($self, $ng, $num, $smsg) = @_;
 880         # n.b. field access and procedural calls can be
 881         # 10%-15% faster than OO method calls:
 882         my $s = join("\t", $num,
 883                 $smsg->{subject},
 884                 $smsg->{from},
 885                 PublicInbox::Smsg::date($smsg),
 886                 "<$smsg->{mid}>",
 887                 $smsg->{references},
 888                 $smsg->{bytes},
 889                 $smsg->{lines},
 890                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 891         utf8::encode($s);
 892         $s
 893 }
 894
 895 sub cmd_over ($;$) {
 896         my ($self, $range) = @_;
 897         if ($range && $range =~ $ONE_MSGID) {
 898                 my ($ng, $n) = mid_lookup($self, $1);
 899                 defined $n or return r430;
 900                 my $smsg = $ng->over->get_art($n) or return r430;
 901                 more($self, '224 Overview information follows (multi-line)');
 902
 903                 # Only set article number column if it's the current group
 904                 my $self_ng = $self->{ng};
 905                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 906                 more($self, over_line($self, $ng, $n, $smsg));
 907                 '.';
 908         } else {
 909                 cmd_xover($self, $range);
 910         }
 911 }
 912
 913 sub xover_i {
 914         my ($self, $beg, $end) = @_;
 915         my $ng = $self->{ng};
 916         my $msgs = $ng->over->query_xover($$beg, $end);
 917         my $nr = scalar @$msgs or return;
 918
 919         # OVERVIEW.FMT
 920         more($self, join("\r\n", map {
 921                 over_line($self, $ng, $_->{num}, $_);
 922                 } @$msgs));
 923         $$beg = $msgs->[-1]->{num} + 1;
 924 }
 925
 926 sub cmd_xover ($;$) {
 927         my ($self, $range) = @_;
 928         $range = $self->{article} unless defined $range;
 929         my $r = get_range($self, $range);
 930         return $r unless ref $r;
 931         my ($beg, $end) = @$r;
 932         more($self, "224 Overview information follows for $$beg to $end");
 933         long_response($self, \&xover_i, @$r);
 934 }
 935
 936 sub compressed { undef }
 937
 938 sub cmd_starttls ($) {
 939         my ($self) = @_;
 940         my $sock = $self->{sock} or return;
 941         # RFC 4642 2.2.1
 942         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 943         my $opt = $self->{nntpd}->{accept_tls} or
 944                 return '580 can not initiate TLS negotiation';
 945         res($self, '382 Continue with TLS negotiation');
 946         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 947         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 948         undef;
 949 }
 950
 951 # RFC 8054
 952 sub cmd_compress ($$) {
 953         my ($self, $alg) = @_;
 954         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 955         return r502 if $self->compressed;
 956         PublicInbox::NNTPdeflate->enable($self);
 957         $self->requeue;
 958         undef
 959 }
 960
 961 sub zflush {} # overridden by NNTPdeflate
 962
 963 sub cmd_xpath ($$) {
 964         my ($self, $mid) = @_;
 965         return r501 unless $mid =~ $ONE_MSGID;
 966         $mid = $1;
 967         my @paths;
 968         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 969                 my $n = $ng->mm->num_for($mid);
 970                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 971         }
 972         return '430 no such article on server' unless @paths;
 973         '223 '.join(' ', @paths);
 974 }
 975
 976 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 977
 978 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 979
 980 sub do_write ($$) {
 981         my $self = $_[0];
 982         my $done = $self->write(\($_[1]));
 983         return 0 unless $self->{sock};
 984
 985         $done;
 986 }
 987
 988 sub err ($$;@) {
 989         my ($self, $fmt, @args) = @_;
 990         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 991 }
 992
 993 sub out ($$;@) {
 994         my ($self, $fmt, @args) = @_;
 995         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 996 }
 997
 998 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 999 sub event_step {
1000         my ($self) = @_;
1001
1002         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1003
1004         $self->update_idle_time;
1005         # only read more requests if we've drained the write buffer,
1006         # otherwise we can be buffering infinitely w/o backpressure
1007
1008         my $rbuf = $self->{rbuf} // \(my $x = '');
1009         my $line = index($$rbuf, "\n");
1010         while ($line < 0) {
1011                 return $self->close if length($$rbuf) >= LINE_MAX;
1012                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1013                 $line = index($$rbuf, "\n");
1014         }
1015         $line = substr($$rbuf, 0, $line + 1, '');
1016         $line =~ s/\r?\n\z//s;
1017         return $self->close if $line =~ /[[:cntrl:]]/s;
1018
1019         my $t0 = now();
1020         my $fd = fileno($self->{sock});
1021         my $r = eval { process_line($self, $line) };
1022         my $pending = $self->{wbuf} ? ' pending' : '';
1023         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1024         return $self->close if $r < 0;
1025         $self->rbuf_idle($rbuf);
1026         $self->update_idle_time;
1027
1028         # maybe there's more pipelined data, or we'll have
1029         # to register it for socket-readiness notifications
1030         $self->requeue unless $pending;
1031 }
1032
1033 # for graceful shutdown in PublicInbox::Daemon:
1034 sub busy {
1035         my ($self, $now) = @_;
1036         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1037 }
1038
1039 1;