lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_step($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub requeue ($) {
  62         push @$nextq, $_[0];
  63         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
  64 }
  65
  66 sub update_idle_time ($) {
  67         my ($self) = @_;
  68         my $sock = $self->{sock} or return;
  69         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  70 }
  71
  72 sub expire_old () {
  73         my $now = now();
  74         my $exp = $EXPTIME;
  75         my $old = $now - $exp;
  76         my $nr = 0;
  77         my %new;
  78         while (my ($fd, $v) = each %$EXPMAP) {
  79                 my ($idle_time, $nntp) = @$v;
  80                 if ($idle_time < $old) {
  81                         $nntp->close; # idempotent
  82                 } else {
  83                         ++$nr;
  84                         $new{$fd} = $v;
  85                 }
  86         }
  87         $EXPMAP = \%new;
  88         if ($nr) {
  89                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  90         } else {
  91                 $expt = undef;
  92                 # noop to kick outselves out of the loop ASAP so descriptors
  93                 # really get closed
  94                 PublicInbox::EvCleanup::asap(sub {});
  95         }
  96 }
  97
  98 sub new ($$$) {
  99         my ($class, $sock, $nntpd) = @_;
 100         my $self = fields::new($class);
 101         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
 102         $self->{nntpd} = $nntpd;
 103         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
 104         $self->{rbuf} = '';
 105         update_idle_time($self);
 106         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 107         $self;
 108 }
 109
 110 sub args_ok ($$) {
 111         my ($cb, $argc) = @_;
 112         my $tot = prototype $cb;
 113         my ($nreq, undef) = split(';', $tot);
 114         $nreq = ($nreq =~ tr/$//) - 1;
 115         $tot = ($tot =~ tr/$//) - 1;
 116         ($argc <= $tot && $argc >= $nreq);
 117 }
 118
 119 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 120 sub process_line ($$) {
 121         my ($self, $l) = @_;
 122         my ($req, @args) = split(/[ \t]/, $l);
 123         return 1 unless defined($req); # skip blank line
 124         $req = lc($req);
 125         $req = eval {
 126                 no strict 'refs';
 127                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 128         };
 129         return res($self, '500 command not recognized') unless $req;
 130         return res($self, r501) unless args_ok($req, scalar @args);
 131
 132         my $res = eval { $req->($self, @args) };
 133         my $err = $@;
 134         if ($err && $self->{sock}) {
 135                 local $/ = "\n";
 136                 chomp($l);
 137                 err($self, 'error from: %s (%s)', $l, $err);
 138                 $res = '503 program fault - command not performed';
 139         }
 140         return 0 unless defined $res;
 141         res($self, $res);
 142 }
 143
 144 sub cmd_mode ($$) {
 145         my ($self, $arg) = @_;
 146         $arg = uc $arg;
 147         return r501 unless $arg eq 'READER';
 148         '201 Posting prohibited';
 149 }
 150
 151 sub cmd_slave ($) { '202 slave status noted' }
 152
 153 sub cmd_xgtitle ($;$) {
 154         my ($self, $wildmat) = @_;
 155         more($self, '282 list of groups and descriptions follows');
 156         list_newsgroups($self, $wildmat);
 157         '.'
 158 }
 159
 160 sub list_overview_fmt ($) {
 161         my ($self) = @_;
 162         msg_more($self, $OVERVIEW_FMT);
 163 }
 164
 165 sub list_headers ($;$) {
 166         my ($self) = @_;
 167         msg_more($self, $LIST_HEADERS);
 168 }
 169
 170 sub list_active ($;$) {
 171         my ($self, $wildmat) = @_;
 172         wildmat2re($wildmat);
 173         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 174                 $ng->{newsgroup} =~ $wildmat or next;
 175                 group_line($self, $ng);
 176         }
 177 }
 178
 179 sub list_active_times ($;$) {
 180         my ($self, $wildmat) = @_;
 181         wildmat2re($wildmat);
 182         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 183                 $ng->{newsgroup} =~ $wildmat or next;
 184                 my $c = eval { $ng->mm->created_at } || time;
 185                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 186         }
 187 }
 188
 189 sub list_newsgroups ($;$) {
 190         my ($self, $wildmat) = @_;
 191         wildmat2re($wildmat);
 192         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 193                 $ng->{newsgroup} =~ $wildmat or next;
 194                 my $d = $ng->description;
 195                 more($self, "$ng->{newsgroup} $d");
 196         }
 197 }
 198
 199 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 200 sub cmd_list ($;$$) {
 201         my ($self, @args) = @_;
 202         if (scalar @args) {
 203                 my $arg = shift @args;
 204                 $arg =~ tr/A-Z./a-z_/;
 205                 $arg = "list_$arg";
 206                 return r501 if $DISABLED{$arg};
 207
 208                 $arg = eval {
 209                         no strict 'refs';
 210                         *{$arg}{CODE};
 211                 };
 212                 return r501 unless $arg && args_ok($arg, scalar @args);
 213                 more($self, '215 information follows');
 214                 $arg->($self, @args);
 215         } else {
 216                 more($self, '215 list of newsgroups follows');
 217                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 218                         group_line($self, $ng);
 219                 }
 220         }
 221         '.'
 222 }
 223
 224 sub cmd_listgroup ($;$) {
 225         my ($self, $group) = @_;
 226         if (defined $group) {
 227                 my $res = cmd_group($self, $group);
 228                 return $res if ($res !~ /\A211 /);
 229                 more($self, $res);
 230         }
 231
 232         $self->{ng} or return '412 no newsgroup selected';
 233         my $n = 0;
 234         long_response($self, sub {
 235                 my $ary = $self->{ng}->mm->ids_after(\$n);
 236                 scalar @$ary or return;
 237                 more($self, join("\r\n", @$ary));
 238                 1;
 239         });
 240 }
 241
 242 sub parse_time ($$;$) {
 243         my ($date, $time, $gmt) = @_;
 244         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 245         if (defined $gmt) {
 246                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 247                 $gmt = 1;
 248         }
 249         my @now = $gmt ? gmtime : localtime;
 250         my ($YYYY, $MM, $DD);
 251         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 252                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 253         } else { # legacy clients send YYMMDD
 254                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 255                 my $cur_year = $now[5] + 1900;
 256                 if ($YYYY > $cur_year) {
 257                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 258                 }
 259         }
 260         if ($gmt) {
 261                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 262         } else {
 263                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 264         }
 265 }
 266
 267 sub group_line ($$) {
 268         my ($self, $ng) = @_;
 269         my ($min, $max) = $ng->mm->minmax;
 270         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 271 }
 272
 273 sub cmd_newgroups ($$$;$$) {
 274         my ($self, $date, $time, $gmt, $dists) = @_;
 275         my $ts = eval { parse_time($date, $time, $gmt) };
 276         return r501 if $@;
 277
 278         # TODO dists
 279         more($self, '231 list of new newsgroups follows');
 280         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 281                 my $c = eval { $ng->mm->created_at } || 0;
 282                 next unless $c > $ts;
 283                 group_line($self, $ng);
 284         }
 285         '.'
 286 }
 287
 288 sub wildmat2re (;$) {
 289         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 290         my %keep;
 291         my $salt = rand;
 292         my $tmp = $_[0];
 293
 294         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 295                 my $orig = $1;
 296                 my $key = sha1_hex($orig . $salt);
 297                 $orig =~ s/([^\w\-])+/\Q$1/g;
 298                 $keep{$key} = $orig;
 299                 $key
 300                 #gex;
 301         my %map = ('*' => '.*', '?' => '.' );
 302         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 303         if (scalar %keep) {
 304                 $tmp =~ s#([a-f0-9]{40})#
 305                         my $orig = $keep{$1};
 306                         defined $orig ? $orig : $1;
 307                         #ge;
 308         }
 309         $_[0] = qr/\A$tmp\z/;
 310 }
 311
 312 sub ngpat2re (;$) {
 313         return $_[0] = qr/\A\z/ unless defined $_[0];
 314         my %map = ('*' => '.*', ',' => '|');
 315         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 316         $_[0] = qr/\A(?:$_[0])\z/;
 317 }
 318
 319 sub cmd_newnews ($$$$;$$) {
 320         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 321         my $ts = eval { parse_time($date, $time, $gmt) };
 322         return r501 if $@;
 323         more($self, '230 list of new articles by message-id follows');
 324         my ($keep, $skip) = split('!', $newsgroups, 2);
 325         ngpat2re($keep);
 326         ngpat2re($skip);
 327         my @over;
 328         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 329                 $ng->{newsgroup} =~ $keep or next;
 330                 $ng->{newsgroup} =~ $skip and next;
 331                 my $over = $ng->over or next;
 332                 push @over, $over;
 333         };
 334         return '.' unless @over;
 335
 336         my $prev = 0;
 337         long_response($self, sub {
 338                 my $over = $over[0];
 339                 my $msgs = $over->query_ts($ts, $prev);
 340                 if (scalar @$msgs) {
 341                         more($self, '<' .
 342                                 join(">\r\n<", map { $_->mid } @$msgs ).
 343                                 '>');
 344                         $prev = $msgs->[-1]->{num};
 345                 } else {
 346                         shift @over;
 347                         if (@over) { # continue onto next newsgroup
 348                                 $prev = 0;
 349                                 return 1;
 350                         } else { # break out of the long response.
 351                                 return;
 352                         }
 353                 }
 354         });
 355 }
 356
 357 sub cmd_group ($$) {
 358         my ($self, $group) = @_;
 359         my $no_such = '411 no such news group';
 360         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 361
 362         $self->{ng} = $ng;
 363         my ($min, $max) = $ng->mm->minmax;
 364         $min ||= 0;
 365         $max ||= 0;
 366         $self->{article} = $min;
 367         my $est_size = $max - $min;
 368         "211 $est_size $min $max $group";
 369 }
 370
 371 sub article_adj ($$) {
 372         my ($self, $off) = @_;
 373         my $ng = $self->{ng} or return '412 no newsgroup selected';
 374
 375         my $n = $self->{article};
 376         defined $n or return '420 no current article has been selected';
 377
 378         $n += $off;
 379         my $mid = $ng->mm->mid_for($n);
 380         unless ($mid) {
 381                 $n = $off > 0 ? 'next' : 'previous';
 382                 return "421 no $n article in this group";
 383         }
 384         $self->{article} = $n;
 385         "223 $n <$mid> article retrieved - request text separately";
 386 }
 387
 388 sub cmd_next ($) { article_adj($_[0], 1) }
 389 sub cmd_last ($) { article_adj($_[0], -1) }
 390
 391 # We want to encourage using email and CC-ing everybody involved to avoid
 392 # the single-point-of-failure a single server provides.
 393 sub cmd_post ($) {
 394         my ($self) = @_;
 395         my $ng = $self->{ng};
 396         $ng ? "440 mailto:$ng->{-primary_address} to post"
 397                 : '440 posting not allowed'
 398 }
 399
 400 sub cmd_quit ($) {
 401         my ($self) = @_;
 402         res($self, '205 closing connection - goodbye!');
 403         $self->close;
 404         undef;
 405 }
 406
 407 sub header_append ($$$) {
 408         my ($hdr, $k, $v) = @_;
 409         my @v = $hdr->header($k);
 410         foreach (@v) {
 411                 return if $v eq $_;
 412         }
 413         $hdr->header_set($k, @v, $v);
 414 }
 415
 416 sub xref ($$$$) {
 417         my ($self, $ng, $n, $mid) = @_;
 418         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 419
 420         # num_for is pretty cheap and sometimes we'll lookup the existence
 421         # of an article without getting even the OVER info.  In other words,
 422         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 423         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 424         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 425                 next if $ng eq $other;
 426                 my $num = eval { $other->mm->num_for($mid) } or next;
 427                 $ret .= " $other->{newsgroup}:$num";
 428         }
 429         $ret;
 430 }
 431
 432 sub set_nntp_headers ($$$$$) {
 433         my ($self, $hdr, $ng, $n, $mid) = @_;
 434
 435         # why? leafnode requires a Path: header for some inexplicable
 436         # reason.  We'll fake the shortest one possible.
 437         $hdr->header_set('Path', 'y');
 438
 439         # leafnode (and maybe other NNTP clients) have trouble dealing
 440         # with v2 messages which have multiple Message-IDs (either due
 441         # to our own content-based dedupe or buggy git-send-email versions).
 442         my @mids = $hdr->header('Message-ID');
 443         if (scalar(@mids) > 1) {
 444                 my $mid0 = "<$mid>";
 445                 $hdr->header_set('Message-ID', $mid0);
 446                 my @alt = $hdr->header('X-Alt-Message-ID');
 447                 my %seen = map { $_ => 1 } (@alt, $mid0);
 448                 foreach my $m (@mids) {
 449                         next if $seen{$m}++;
 450                         push @alt, $m;
 451                 }
 452                 $hdr->header_set('X-Alt-Message-ID', @alt);
 453         }
 454
 455         # clobber some
 456         my $xref = xref($self, $ng, $n, $mid);
 457         $hdr->header_set('Xref', $xref);
 458         $xref =~ s/:[0-9]+//g;
 459         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 460         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 461         if (my $url = $ng->base_url) {
 462                 $mid = mid_escape($mid);
 463                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 464                 header_append($hdr, 'List-Archive', "<$url>");
 465         }
 466 }
 467
 468 sub art_lookup ($$$) {
 469         my ($self, $art, $set_headers) = @_;
 470         my $ng = $self->{ng};
 471         my ($n, $mid);
 472         my $err;
 473         if (defined $art) {
 474                 if ($art =~ /\A[0-9]+\z/) {
 475                         $err = '423 no such article number in this group';
 476                         $n = int($art);
 477                         goto find_mid;
 478                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 479                         $mid = $1;
 480                         $err = r430;
 481                         $n = $ng->mm->num_for($mid) if $ng;
 482                         goto found if defined $n;
 483                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 484                                 $n = $g->mm->num_for($mid);
 485                                 if (defined $n) {
 486                                         $ng = $g;
 487                                         goto found;
 488                                 }
 489                         }
 490                         return $err;
 491                 } else {
 492                         return r501;
 493                 }
 494         } else {
 495                 $err = '420 no current article has been selected';
 496                 $n = $self->{article};
 497                 defined $n or return $err;
 498 find_mid:
 499                 $ng or return '412 no newsgroup has been selected';
 500                 $mid = $ng->mm->mid_for($n);
 501                 defined $mid or return $err;
 502         }
 503 found:
 504         my $smsg = $ng->over->get_art($n) or return $err;
 505         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 506         my $s = Email::Simple->new($msg);
 507         if ($set_headers) {
 508                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 509
 510                 # must be last
 511                 $s->body_set('') if ($set_headers == 2);
 512         }
 513         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 514 }
 515
 516 sub simple_body_write ($$) {
 517         my ($self, $s) = @_;
 518         my $body = $s->body;
 519         $s->body_set('');
 520         $body =~ s/^\./../smg;
 521         $body =~ s/(?<!\r)\n/\r\n/sg;
 522         msg_more($self, $body);
 523         msg_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 524         '.'
 525 }
 526
 527 sub set_art {
 528         my ($self, $art) = @_;
 529         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 530 }
 531
 532 sub _header ($) {
 533         my $hdr = $_[0]->header_obj->as_string;
 534         utf8::encode($hdr);
 535         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 536
 537         # for leafnode compatibility, we need to ensure Message-ID headers
 538         # are only a single line.  We can't subclass Email::Simple::Header
 539         # and override _default_fold_at in here, either; since that won't
 540         # affect messages already in the archive.
 541         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 542
 543         $hdr
 544 }
 545
 546 sub cmd_article ($;$) {
 547         my ($self, $art) = @_;
 548         my $r = art_lookup($self, $art, 1);
 549         return $r unless ref $r;
 550         my ($n, $mid, $s) = @$r;
 551         set_art($self, $art);
 552         more($self, "220 $n <$mid> article retrieved - head and body follow");
 553         msg_more($self, _header($s));
 554         msg_more($self, "\r\n");
 555         simple_body_write($self, $s);
 556 }
 557
 558 sub cmd_head ($;$) {
 559         my ($self, $art) = @_;
 560         my $r = art_lookup($self, $art, 2);
 561         return $r unless ref $r;
 562         my ($n, $mid, $s) = @$r;
 563         set_art($self, $art);
 564         more($self, "221 $n <$mid> article retrieved - head follows");
 565         msg_more($self, _header($s));
 566         '.'
 567 }
 568
 569 sub cmd_body ($;$) {
 570         my ($self, $art) = @_;
 571         my $r = art_lookup($self, $art, 0);
 572         return $r unless ref $r;
 573         my ($n, $mid, $s) = @$r;
 574         set_art($self, $art);
 575         more($self, "222 $n <$mid> article retrieved - body follows");
 576         simple_body_write($self, $s);
 577 }
 578
 579 sub cmd_stat ($;$) {
 580         my ($self, $art) = @_;
 581         my $r = art_lookup($self, $art, 0);
 582         return $r unless ref $r;
 583         my ($n, $mid, undef) = @$r;
 584         set_art($self, $art);
 585         "223 $n <$mid> article retrieved - request text separately";
 586 }
 587
 588 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 589
 590 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 591
 592 sub cmd_help ($) {
 593         my ($self) = @_;
 594         more($self, '100 help text follows');
 595         '.'
 596 }
 597
 598 sub get_range ($$) {
 599         my ($self, $range) = @_;
 600         my $ng = $self->{ng} or return '412 no news group has been selected';
 601         defined $range or return '420 No article(s) selected';
 602         my ($beg, $end);
 603         my ($min, $max) = $ng->mm->minmax;
 604         if ($range =~ /\A([0-9]+)\z/) {
 605                 $beg = $end = $1;
 606         } elsif ($range =~ /\A([0-9]+)-\z/) {
 607                 ($beg, $end) = ($1, $max);
 608         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 609                 ($beg, $end) = ($1, $2);
 610         } else {
 611                 return r501;
 612         }
 613         $beg = $min if ($beg < $min);
 614         $end = $max if ($end > $max);
 615         return '420 No article(s) selected' if ($beg > $end);
 616         [ $beg, $end ];
 617 }
 618
 619 sub long_response ($$) {
 620         my ($self, $cb) = @_;
 621         die "BUG: nested long response" if $self->{long_res};
 622
 623         my $fd = fileno($self->{sock});
 624         defined $fd or return;
 625         # make sure we disable reading during a long response,
 626         # clients should not be sending us stuff and making us do more
 627         # work while we are stream a response to them
 628         my $t0 = now();
 629         $self->{long_res} = sub {
 630                 my $more = eval { $cb->() };
 631                 if ($@ || !$self->{sock}) { # something bad happened...
 632                         delete $self->{long_res};
 633
 634                         if ($@) {
 635                                 err($self,
 636                                     "%s during long response[$fd] - %0.6f",
 637                                     $@, now() - $t0);
 638                         }
 639                         if ($self->{sock}) {
 640                                 update_idle_time($self);
 641                                 requeue($self);
 642                         } else {
 643                                 out($self, " deferred[$fd] aborted - %0.6f",
 644                                            now() - $t0);
 645                         }
 646                 } elsif ($more) { # $self->{wbuf}:
 647                         # no recursion, schedule another call ASAP
 648                         # but only after all pending writes are done
 649                         update_idle_time($self);
 650                         requeue($self);
 651                 } else { # all done!
 652                         delete $self->{long_res};
 653                         res($self, '.');
 654                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 655                         requeue($self);
 656                 }
 657         };
 658         $self->{long_res}->(); # kick off!
 659         undef;
 660 }
 661
 662 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 663         my ($self, $xhdr, $range) = @_;
 664
 665         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 666                 my ($ng, $n) = mid_lookup($self, $1);
 667                 return r430 unless $n;
 668                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 669         } else { # numeric range
 670                 $range = $self->{article} unless defined $range;
 671                 my $r = get_range($self, $range);
 672                 return $r unless ref $r;
 673                 my $mm = $self->{ng}->mm;
 674                 my ($beg, $end) = @$r;
 675                 more($self, $xhdr ? r221 : r225);
 676                 long_response($self, sub {
 677                         my $r = $mm->msg_range(\$beg, $end);
 678                         @$r or return;
 679                         more($self, join("\r\n", map {
 680                                 "$_->[0] <$_->[1]>"
 681                         } @$r));
 682                         1;
 683                 });
 684         }
 685 }
 686
 687 sub mid_lookup ($$) {
 688         my ($self, $mid) = @_;
 689         my $self_ng = $self->{ng};
 690         if ($self_ng) {
 691                 my $n = $self_ng->mm->num_for($mid);
 692                 return ($self_ng, $n) if defined $n;
 693         }
 694         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 695                 next if defined $self_ng && $ng eq $self_ng;
 696                 my $n = $ng->mm->num_for($mid);
 697                 return ($ng, $n) if defined $n;
 698         }
 699         (undef, undef);
 700 }
 701
 702 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 703         my ($self, $xhdr, $range) = @_;
 704
 705         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 706                 my $mid = $1;
 707                 my ($ng, $n) = mid_lookup($self, $mid);
 708                 return r430 unless $n;
 709                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 710                                 xref($self, $ng, $n, $mid));
 711         } else { # numeric range
 712                 $range = $self->{article} unless defined $range;
 713                 my $r = get_range($self, $range);
 714                 return $r unless ref $r;
 715                 my $ng = $self->{ng};
 716                 my $mm = $ng->mm;
 717                 my ($beg, $end) = @$r;
 718                 more($self, $xhdr ? r221 : r225);
 719                 long_response($self, sub {
 720                         my $r = $mm->msg_range(\$beg, $end);
 721                         @$r or return;
 722                         more($self, join("\r\n", map {
 723                                 my $num = $_->[0];
 724                                 "$num ".xref($self, $ng, $num, $_->[1]);
 725                         } @$r));
 726                         1;
 727                 });
 728         }
 729 }
 730
 731 sub over_header_for {
 732         my ($over, $num, $field) = @_;
 733         my $smsg = $over->get_art($num) or return;
 734         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 735         $smsg->{$field};
 736 }
 737
 738 sub hdr_searchmsg ($$$$) {
 739         my ($self, $xhdr, $field, $range) = @_;
 740         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 741                 my ($ng, $n) = mid_lookup($self, $1);
 742                 return r430 unless defined $n;
 743                 my $v = over_header_for($ng->over, $n, $field);
 744                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 745         } else { # numeric range
 746                 $range = $self->{article} unless defined $range;
 747                 my $over = $self->{ng}->over;
 748                 my $mm = $self->{ng}->mm;
 749                 my $r = get_range($self, $range);
 750                 return $r unless ref $r;
 751                 my ($beg, $end) = @$r;
 752                 more($self, $xhdr ? r221 : r225);
 753                 my $cur = $beg;
 754                 long_response($self, sub {
 755                         my $msgs = $over->query_xover($cur, $end);
 756                         my $nr = scalar @$msgs or return;
 757                         my $tmp = '';
 758                         foreach my $s (@$msgs) {
 759                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 760                         }
 761                         utf8::encode($tmp);
 762                         msg_more($self, $tmp);
 763                         $cur = $msgs->[-1]->{num} + 1;
 764                 });
 765         }
 766 }
 767
 768 sub do_hdr ($$$;$) {
 769         my ($self, $xhdr, $header, $range) = @_;
 770         my $sub = lc $header;
 771         if ($sub eq 'message-id') {
 772                 hdr_message_id($self, $xhdr, $range);
 773         } elsif ($sub eq 'xref') {
 774                 hdr_xref($self, $xhdr, $range);
 775         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 776                                 bytes|lines)\z/x) {
 777                 hdr_searchmsg($self, $xhdr, $sub, $range);
 778         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 779                 hdr_searchmsg($self, $xhdr, $1, $range);
 780         } else {
 781                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 782         }
 783 }
 784
 785 # RFC 3977
 786 sub cmd_hdr ($$;$) {
 787         my ($self, $header, $range) = @_;
 788         do_hdr($self, 0, $header, $range);
 789 }
 790
 791 # RFC 2980
 792 sub cmd_xhdr ($$;$) {
 793         my ($self, $header, $range) = @_;
 794         do_hdr($self, 1, $header, $range);
 795 }
 796
 797 sub hdr_mid_prefix ($$$$$) {
 798         my ($self, $xhdr, $ng, $n, $mid) = @_;
 799         return $mid if $xhdr;
 800
 801         # HDR for RFC 3977 users
 802         if (my $self_ng = $self->{ng}) {
 803                 ($self_ng eq $ng) ? $n : '0';
 804         } else {
 805                 '0';
 806         }
 807 }
 808
 809 sub hdr_mid_response ($$$$$$) {
 810         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 811         my $res = '';
 812         if ($xhdr) {
 813                 $res .= r221 . "\r\n";
 814                 $res .= "$mid $v\r\n";
 815         } else {
 816                 $res .= r225 . "\r\n";
 817                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 818                 $res .= "$pfx $v\r\n";
 819         }
 820         res($self, $res .= '.');
 821         undef;
 822 }
 823
 824 sub cmd_xrover ($;$) {
 825         my ($self, $range) = @_;
 826         my $ng = $self->{ng} or return '412 no newsgroup selected';
 827         (defined $range && $range =~ /[<>]/) and
 828                 return '420 No article(s) selected'; # no message IDs
 829
 830         $range = $self->{article} unless defined $range;
 831         my $r = get_range($self, $range);
 832         return $r unless ref $r;
 833         my ($beg, $end) = @$r;
 834         my $mm = $ng->mm;
 835         my $over = $ng->over;
 836         more($self, '224 Overview information follows');
 837
 838         long_response($self, sub {
 839                 my $h = over_header_for($over, $beg, 'references');
 840                 more($self, "$beg $h") if defined($h);
 841                 $beg++ < $end;
 842         });
 843 }
 844
 845 sub over_line ($$$$) {
 846         my ($self, $ng, $num, $smsg) = @_;
 847         # n.b. field access and procedural calls can be
 848         # 10%-15% faster than OO method calls:
 849         my $s = join("\t", $num,
 850                 $smsg->{subject},
 851                 $smsg->{from},
 852                 PublicInbox::SearchMsg::date($smsg),
 853                 "<$smsg->{mid}>",
 854                 $smsg->{references},
 855                 $smsg->{bytes},
 856                 $smsg->{lines},
 857                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 858         utf8::encode($s);
 859         $s
 860 }
 861
 862 sub cmd_over ($;$) {
 863         my ($self, $range) = @_;
 864         if ($range && $range =~ /\A<(.+)>\z/) {
 865                 my ($ng, $n) = mid_lookup($self, $1);
 866                 defined $n or return r430;
 867                 my $smsg = $ng->over->get_art($n) or return r430;
 868                 more($self, '224 Overview information follows (multi-line)');
 869
 870                 # Only set article number column if it's the current group
 871                 my $self_ng = $self->{ng};
 872                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 873                 more($self, over_line($self, $ng, $n, $smsg));
 874                 '.';
 875         } else {
 876                 cmd_xover($self, $range);
 877         }
 878 }
 879
 880 sub cmd_xover ($;$) {
 881         my ($self, $range) = @_;
 882         $range = $self->{article} unless defined $range;
 883         my $r = get_range($self, $range);
 884         return $r unless ref $r;
 885         my ($beg, $end) = @$r;
 886         more($self, "224 Overview information follows for $beg to $end");
 887         my $over = $self->{ng}->over;
 888         my $cur = $beg;
 889         long_response($self, sub {
 890                 my $msgs = $over->query_xover($cur, $end);
 891                 my $nr = scalar @$msgs or return;
 892
 893                 # OVERVIEW.FMT
 894                 more($self, join("\r\n", map {
 895                         over_line($self, $self->{ng}, $_->{num}, $_);
 896                         } @$msgs));
 897                 $cur = $msgs->[-1]->{num} + 1;
 898         });
 899 }
 900
 901 sub cmd_xpath ($$) {
 902         my ($self, $mid) = @_;
 903         return r501 unless $mid =~ /\A<(.+)>\z/;
 904         $mid = $1;
 905         my @paths;
 906         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 907                 my $n = $ng->mm->num_for($mid);
 908                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 909         }
 910         return '430 no such article on server' unless @paths;
 911         '223 '.join(' ', @paths);
 912 }
 913
 914 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 915
 916 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 917
 918 sub do_write ($$) {
 919         my $self = $_[0];
 920         my $done = $self->write(\($_[1]));
 921         return 0 unless $self->{sock};
 922
 923         $done;
 924 }
 925
 926 sub err ($$;@) {
 927         my ($self, $fmt, @args) = @_;
 928         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 929 }
 930
 931 sub out ($$;@) {
 932         my ($self, $fmt, @args) = @_;
 933         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 934 }
 935
 936 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 937 sub event_step {
 938         my ($self) = @_;
 939
 940         return unless $self->flush_write && $self->{sock};
 941
 942         update_idle_time($self);
 943         # only read more requests if we've drained the write buffer,
 944         # otherwise we can be buffering infinitely w/o backpressure
 945
 946         use constant LINE_MAX => 512; # RFC 977 section 2.3
 947         my $rbuf = \($self->{rbuf});
 948         my $r = 1;
 949
 950         if (index($$rbuf, "\n") < 0) {
 951                 my $off = bytes::length($$rbuf);
 952                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 953         }
 954         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 955                 my $line = $1;
 956                 return $self->close if $line =~ /[[:cntrl:]]/s;
 957                 my $t0 = now();
 958                 my $fd = fileno($self->{sock});
 959                 $r = eval { process_line($self, $line) };
 960                 my $d = $self->{long_res} ?
 961                         " deferred[$fd]" : '';
 962                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 963         }
 964
 965         return $self->close if $r < 0;
 966         my $len = bytes::length($$rbuf);
 967         return $self->close if ($len >= LINE_MAX);
 968         update_idle_time($self);
 969
 970         # maybe there's more pipelined data, or we'll have
 971         # to register it for socket-readiness notifications
 972         requeue($self) unless ($self->{long_res} || $self->{wbuf});
 973 }
 974
 975 sub not_idle_long ($$) {
 976         my ($self, $now) = @_;
 977         my $sock = $self->{sock} or return;
 978         my $ary = $EXPMAP->{fileno($sock)} or return;
 979         my $exp_at = $ary->[0] + $EXPTIME;
 980         $exp_at > $now;
 981 }
 982
 983 # for graceful shutdown in PublicInbox::Daemon:
 984 sub busy {
 985         my ($self, $now) = @_;
 986         ($self->{rbuf} ne '' || $self->{long_res} ||
 987                 $self->{wbuf} || not_idle_long($self, $now));
 988 }
 989
 990 1;