lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 require PublicInbox::EvCleanup;
  14 use Email::Simple;
  15 use POSIX qw(strftime);
  16 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  17 use URI::Escape qw(uri_escape_utf8);
  18 use constant {
  19         r501 => '501 command syntax error',
  20         r221 => '221 Header follows',
  21         r224 => '224 Overview information follows (multi-line)',
  22         r225 => '225 Headers follow (multi-line)',
  23         r430 => '430 No article with that message-id',
  24         long_response_limit => 0xffffffff,
  25 };
  26
  27 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  28
  29 my @OVERVIEW = qw(Subject From Date Message-ID References);
  30 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  31 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  32                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  33
  34 # disable commands with easy DoS potential:
  35 # LISTGROUP could get pretty bad, too...
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $WEAKEN = {}; # string(nntpd) -> nntpd
  42 my $weakt;
  43 my $nextt;
  44
  45 my $nextq = [];
  46 sub next_tick () {
  47         $nextt = undef;
  48         my $q = $nextq;
  49         $nextq = [];
  50         foreach my $nntp (@$q) {
  51                 # for request && response protocols, always finish writing
  52                 # before finishing reading:
  53                 if (my $long_cb = $nntp->{long_res}) {
  54                         $nntp->write($long_cb);
  55                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  56                         event_read($nntp);
  57                 }
  58         }
  59 }
  60
  61 sub update_idle_time ($) {
  62         my ($self) = @_;
  63         my $fd = $self->{fd};
  64         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  65 }
  66
  67 # reduce FD pressure by closing some "git cat-file --batch" processes
  68 # and unused FDs for msgmap and Xapian indices
  69 sub weaken_groups () {
  70         $weakt = undef;
  71         foreach my $nntpd (values %$WEAKEN) {
  72                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  73         }
  74         $WEAKEN = {};
  75 }
  76
  77 sub expire_old () {
  78         my $now = now();
  79         my $exp = $EXPTIME;
  80         my $old = $now - $exp;
  81         my $nr = 0;
  82         my %new;
  83         while (my ($fd, $v) = each %$EXPMAP) {
  84                 my ($idle_time, $nntp) = @$v;
  85                 if ($idle_time < $old) {
  86                         $nntp->close; # idempotent
  87                 } else {
  88                         ++$nr;
  89                         $new{$fd} = $v;
  90                 }
  91         }
  92         $EXPMAP = \%new;
  93         if ($nr) {
  94                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  95                 weaken_groups();
  96         } else {
  97                 $expt = undef;
  98                 # noop to kick outselves out of the loop ASAP so descriptors
  99                 # really get closed
 100                 PublicInbox::EvCleanup::asap(sub {});
 101
 102                 # grace period for reaping resources
 103                 $weakt ||= PublicInbox::EvCleanup::later(*weaken_groups);
 104         }
 105 }
 106
 107 sub new ($$$) {
 108         my ($class, $sock, $nntpd) = @_;
 109         my $self = fields::new($class);
 110         $self->SUPER::new($sock);
 111         $self->{nntpd} = $nntpd;
 112         res($self, '201 server ready - post via email');
 113         $self->{rbuf} = '';
 114         $self->watch_read(1);
 115         update_idle_time($self);
 116         $WEAKEN->{"$nntpd"} = $nntpd;
 117         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 118         $self;
 119 }
 120
 121 sub args_ok ($$) {
 122         my ($cb, $argc) = @_;
 123         my $tot = prototype $cb;
 124         my ($nreq, undef) = split(';', $tot);
 125         $nreq = ($nreq =~ tr/$//) - 1;
 126         $tot = ($tot =~ tr/$//) - 1;
 127         ($argc <= $tot && $argc >= $nreq);
 128 }
 129
 130 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 131 sub process_line ($$) {
 132         my ($self, $l) = @_;
 133         my ($req, @args) = split(/\s+/, $l);
 134         $req = lc($req);
 135         $req = eval {
 136                 no strict 'refs';
 137                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 138         };
 139         return res($self, '500 command not recognized') unless $req;
 140         return res($self, r501) unless args_ok($req, scalar @args);
 141
 142         my $res = eval { $req->($self, @args) };
 143         my $err = $@;
 144         if ($err && !$self->{closed}) {
 145                 chomp($l);
 146                 err($self, 'error from: %s (%s)', $l, $err);
 147                 $res = '503 program fault - command not performed';
 148         }
 149         return 0 unless defined $res;
 150         res($self, $res);
 151 }
 152
 153 sub cmd_mode ($$) {
 154         my ($self, $arg) = @_;
 155         $arg = uc $arg;
 156         return r501 unless $arg eq 'READER';
 157         '201 Posting prohibited';
 158 }
 159
 160 sub cmd_slave ($) { '202 slave status noted' }
 161
 162 sub cmd_xgtitle ($;$) {
 163         my ($self, $wildmat) = @_;
 164         more($self, '282 list of groups and descriptions follows');
 165         list_newsgroups($self, $wildmat);
 166         '.'
 167 }
 168
 169 sub list_overview_fmt ($) {
 170         my ($self) = @_;
 171         do_more($self, $OVERVIEW_FMT);
 172 }
 173
 174 sub list_headers ($;$) {
 175         my ($self) = @_;
 176         do_more($self, $LIST_HEADERS);
 177 }
 178
 179 sub list_active ($;$) {
 180         my ($self, $wildmat) = @_;
 181         wildmat2re($wildmat);
 182         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 183                 $ng->{newsgroup} =~ $wildmat or next;
 184                 group_line($self, $ng);
 185         }
 186 }
 187
 188 sub list_active_times ($;$) {
 189         my ($self, $wildmat) = @_;
 190         wildmat2re($wildmat);
 191         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 192                 $ng->{newsgroup} =~ $wildmat or next;
 193                 my $c = eval { $ng->mm->created_at } || time;
 194                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 195         }
 196 }
 197
 198 sub list_newsgroups ($;$) {
 199         my ($self, $wildmat) = @_;
 200         wildmat2re($wildmat);
 201         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 202                 $ng->{newsgroup} =~ $wildmat or next;
 203                 my $d = $ng->description;
 204                 more($self, "$ng->{newsgroup} $d");
 205         }
 206 }
 207
 208 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 209 sub cmd_list ($;$$) {
 210         my ($self, @args) = @_;
 211         if (scalar @args) {
 212                 my $arg = shift @args;
 213                 $arg =~ tr/A-Z./a-z_/;
 214                 $arg = "list_$arg";
 215                 return r501 if $DISABLED{$arg};
 216
 217                 $arg = eval {
 218                         no strict 'refs';
 219                         *{$arg}{CODE};
 220                 };
 221                 return r501 unless $arg && args_ok($arg, scalar @args);
 222                 more($self, '215 information follows');
 223                 $arg->($self, @args);
 224         } else {
 225                 more($self, '215 list of newsgroups follows');
 226                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 227                         group_line($self, $ng);
 228                 }
 229         }
 230         '.'
 231 }
 232
 233 sub cmd_listgroup ($;$) {
 234         my ($self, $group) = @_;
 235         if (defined $group) {
 236                 my $res = cmd_group($self, $group);
 237                 return $res if ($res !~ /\A211 /);
 238                 more($self, $res);
 239         }
 240
 241         $self->{ng} or return '412 no newsgroup selected';
 242         long_response($self, 0, long_response_limit, sub {
 243                 my ($i) = @_;
 244                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 245                         my ($ary) = @_;
 246                         more($self, join("\r\n", @$ary));
 247                 });
 248
 249                 # -1 to adjust for implicit increment in long_response
 250                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 251         });
 252 }
 253
 254 sub parse_time ($$;$) {
 255         my ($date, $time, $gmt) = @_;
 256         use Time::Local qw();
 257         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 258         if (defined $gmt) {
 259                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 260                 $gmt = 1;
 261         }
 262         my @now = $gmt ? gmtime : localtime;
 263         my ($YYYY, $MM, $DD);
 264         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 265                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 266         } else { # legacy clients send YYMMDD
 267                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 268                 if ($YYYY > strftime('%y', @now)) {
 269                         my $cur_year = $now[5] + 1900;
 270                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 271                 }
 272         }
 273         if ($gmt) {
 274                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 275         } else {
 276                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 277         }
 278 }
 279
 280 sub group_line ($$) {
 281         my ($self, $ng) = @_;
 282         my ($min, $max) = $ng->mm->minmax;
 283         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 284 }
 285
 286 sub cmd_newgroups ($$$;$$) {
 287         my ($self, $date, $time, $gmt, $dists) = @_;
 288         my $ts = eval { parse_time($date, $time, $gmt) };
 289         return r501 if $@;
 290
 291         # TODO dists
 292         more($self, '231 list of new newsgroups follows');
 293         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 294                 my $c = eval { $ng->mm->created_at } || 0;
 295                 next unless $c > $ts;
 296                 group_line($self, $ng);
 297         }
 298         '.'
 299 }
 300
 301 sub wildmat2re (;$) {
 302         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 303         my %keep;
 304         my $salt = rand;
 305         use Digest::SHA qw(sha1_hex);
 306         my $tmp = $_[0];
 307
 308         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 309                 my $orig = $1;
 310                 my $key = sha1_hex($orig . $salt);
 311                 $orig =~ s/([^\w\-])+/\Q$1/g;
 312                 $keep{$key} = $orig;
 313                 $key
 314                 #gex;
 315         my %map = ('*' => '.*', '?' => '.' );
 316         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 317         if (scalar %keep) {
 318                 $tmp =~ s#([a-f0-9]{40})#
 319                         my $orig = $keep{$1};
 320                         defined $orig ? $orig : $1;
 321                         #ge;
 322         }
 323         $_[0] = qr/\A$tmp\z/;
 324 }
 325
 326 sub ngpat2re (;$) {
 327         return $_[0] = qr/\A\z/ unless defined $_[0];
 328         my %map = ('*' => '.*', ',' => '|');
 329         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 330         $_[0] = qr/\A(?:$_[0])\z/;
 331 }
 332
 333 sub cmd_newnews ($$$$;$$) {
 334         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 335         my $ts = eval { parse_time($date, $time, $gmt) };
 336         return r501 if $@;
 337         more($self, '230 list of new articles by message-id follows');
 338         my ($keep, $skip) = split('!', $newsgroups, 2);
 339         ngpat2re($keep);
 340         ngpat2re($skip);
 341         my @srch;
 342         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 343                 $ng->{newsgroup} =~ $keep or next;
 344                 $ng->{newsgroup} =~ $skip and next;
 345                 my $srch = $ng->search or next;
 346                 push @srch, $srch;
 347         };
 348         return '.' unless @srch;
 349
 350         $ts .= '..';
 351         my $opts = { asc => 1, limit => 1000, offset => 0 };
 352         long_response($self, 0, long_response_limit, sub {
 353                 my ($i) = @_;
 354                 my $srch = $srch[0];
 355                 my $res = $srch->query($ts, $opts);
 356                 my $msgs = $res->{msgs};
 357                 if (my $nr = scalar @$msgs) {
 358                         more($self, '<' .
 359                                 join(">\r\n<", map { $_->mid } @$msgs ).
 360                                 '>');
 361                         $opts->{offset} += $nr;
 362                 } else {
 363                         shift @srch;
 364                         if (@srch) { # continue onto next newsgroup
 365                                 $opts->{offset} = 0;
 366                         } else { # break out of the long response.
 367                                 $$i = long_response_limit;
 368                         }
 369                 }
 370         });
 371 }
 372
 373 sub cmd_group ($$) {
 374         my ($self, $group) = @_;
 375         my $no_such = '411 no such news group';
 376         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 377
 378         $self->{ng} = $ng;
 379         my ($min, $max) = $ng->mm->minmax;
 380         $min ||= 0;
 381         $max ||= 0;
 382         $self->{article} = $min;
 383         my $est_size = $max - $min;
 384         "211 $est_size $min $max $group";
 385 }
 386
 387 sub article_adj ($$) {
 388         my ($self, $off) = @_;
 389         my $ng = $self->{ng} or return '412 no newsgroup selected';
 390
 391         my $n = $self->{article};
 392         defined $n or return '420 no current article has been selected';
 393
 394         $n += $off;
 395         my $mid = $ng->mm->mid_for($n);
 396         unless ($mid) {
 397                 $n = $off > 0 ? 'next' : 'previous';
 398                 return "421 no $n article in this group";
 399         }
 400         $self->{article} = $n;
 401         "223 $n <$mid> article retrieved - request text separately";
 402 }
 403
 404 sub cmd_next ($) { article_adj($_[0], 1) }
 405 sub cmd_last ($) { article_adj($_[0], -1) }
 406
 407 # We want to encourage using email and CC-ing everybody involved to avoid
 408 # the single-point-of-failure a single server provides.
 409 sub cmd_post ($) {
 410         my ($self) = @_;
 411         my $ng = $self->{ng};
 412         $ng ? "440 mailto:$ng->{-primary_address} to post"
 413                 : '440 posting not allowed'
 414 }
 415
 416 sub cmd_quit ($) {
 417         my ($self) = @_;
 418         res($self, '205 closing connection - goodbye!');
 419         $self->close;
 420         undef;
 421 }
 422
 423 sub header_append ($$$) {
 424         my ($hdr, $k, $v) = @_;
 425         my @v = $hdr->header($k);
 426         foreach (@v) {
 427                 return if $v eq $_;
 428         }
 429         $hdr->header_set($k, @v, $v);
 430 }
 431
 432 sub set_nntp_headers {
 433         my ($hdr, $ng, $n, $mid) = @_;
 434
 435         # clobber some
 436         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 437         $hdr->header_set('Xref', xref($ng, $n));
 438         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 439         if (my $url = $ng->base_url) {
 440                 $mid = uri_escape_utf8($mid);
 441                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 442                 header_append($hdr, 'List-Archive', "<$url>");
 443         }
 444 }
 445
 446 sub art_lookup ($$$) {
 447         my ($self, $art, $set_headers) = @_;
 448         my $ng = $self->{ng};
 449         my ($n, $mid);
 450         my $err;
 451         if (defined $art) {
 452                 if ($art =~ /\A\d+\z/o) {
 453                         $err = '423 no such article number in this group';
 454                         $n = int($art);
 455                         goto find_mid;
 456                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 457                         $mid = $1;
 458                         $err = r430;
 459                         $n = $ng->mm->num_for($mid) if $ng;
 460                         goto found if defined $n;
 461                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 462                                 $n = $g->mm->num_for($mid);
 463                                 if (defined $n) {
 464                                         $ng = $g;
 465                                         goto found;
 466                                 }
 467                         }
 468                         return $err;
 469                 } else {
 470                         return r501;
 471                 }
 472         } else {
 473                 $err = '420 no current article has been selected';
 474                 $n = $self->{article};
 475                 defined $n or return $err;
 476 find_mid:
 477                 $ng or return '412 no newsgroup has been selected';
 478                 $mid = $ng->mm->mid_for($n);
 479                 defined $mid or return $err;
 480         }
 481 found:
 482         my $bytes;
 483         my $s = eval { $ng->msg_by_mid($mid, \$bytes) } or return $err;
 484         $s = Email::Simple->new($s);
 485         my $lines;
 486         if ($set_headers) {
 487                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 488                 $lines = $s->body =~ tr!\n!\n!;
 489
 490                 # must be last
 491                 $s->body_set('') if ($set_headers == 2);
 492         }
 493         [ $n, $mid, $s, $bytes, $lines, $ng ];
 494 }
 495
 496 sub simple_body_write ($$) {
 497         my ($self, $s) = @_;
 498         my $body = $s->body;
 499         $s->body_set('');
 500         $body =~ s/^\./../smg;
 501         $body =~ s/(?<!\r)\n/\r\n/sg;
 502         do_more($self, $body);
 503         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 504         '.'
 505 }
 506
 507 sub set_art {
 508         my ($self, $art) = @_;
 509         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 510 }
 511
 512 sub _header ($) {
 513         my $hdr = $_[0]->header_obj->as_string;
 514         utf8::encode($hdr);
 515         $hdr
 516 }
 517
 518 sub cmd_article ($;$) {
 519         my ($self, $art) = @_;
 520         my $r = art_lookup($self, $art, 1);
 521         return $r unless ref $r;
 522         my ($n, $mid, $s) = @$r;
 523         set_art($self, $art);
 524         more($self, "220 $n <$mid> article retrieved - head and body follow");
 525         do_more($self, _header($s));
 526         do_more($self, "\r\n");
 527         simple_body_write($self, $s);
 528 }
 529
 530 sub cmd_head ($;$) {
 531         my ($self, $art) = @_;
 532         my $r = art_lookup($self, $art, 2);
 533         return $r unless ref $r;
 534         my ($n, $mid, $s) = @$r;
 535         set_art($self, $art);
 536         more($self, "221 $n <$mid> article retrieved - head follows");
 537         do_more($self, _header($s));
 538         '.'
 539 }
 540
 541 sub cmd_body ($;$) {
 542         my ($self, $art) = @_;
 543         my $r = art_lookup($self, $art, 0);
 544         return $r unless ref $r;
 545         my ($n, $mid, $s) = @$r;
 546         set_art($self, $art);
 547         more($self, "222 $n <$mid> article retrieved - body follows");
 548         simple_body_write($self, $s);
 549 }
 550
 551 sub cmd_stat ($;$) {
 552         my ($self, $art) = @_;
 553         my $r = art_lookup($self, $art, 0);
 554         return $r unless ref $r;
 555         my ($n, $mid, undef) = @$r;
 556         set_art($self, $art);
 557         "223 $n <$mid> article retrieved - request text separately";
 558 }
 559
 560 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 561
 562 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 563
 564 sub cmd_help ($) {
 565         my ($self) = @_;
 566         more($self, '100 help text follows');
 567         '.'
 568 }
 569
 570 sub get_range ($$) {
 571         my ($self, $range) = @_;
 572         my $ng = $self->{ng} or return '412 no news group has been selected';
 573         defined $range or return '420 No article(s) selected';
 574         my ($beg, $end);
 575         my ($min, $max) = $ng->mm->minmax;
 576         if ($range =~ /\A(\d+)\z/) {
 577                 $beg = $end = $1;
 578         } elsif ($range =~ /\A(\d+)-\z/) {
 579                 ($beg, $end) = ($1, $max);
 580         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 581                 ($beg, $end) = ($1, $2);
 582         } else {
 583                 return r501;
 584         }
 585         $beg = $min if ($beg < $min);
 586         $end = $max if ($end > $max);
 587         return '420 No article(s) selected' if ($beg > $end);
 588         [ $beg, $end ];
 589 }
 590
 591 sub long_response ($$$$) {
 592         my ($self, $beg, $end, $cb) = @_;
 593         die "BUG: nested long response" if $self->{long_res};
 594
 595         my $fd = $self->{fd};
 596         defined $fd or return;
 597         # make sure we disable reading during a long response,
 598         # clients should not be sending us stuff and making us do more
 599         # work while we are stream a response to them
 600         $self->watch_read(0);
 601         my $t0 = now();
 602         $self->{long_res} = sub {
 603                 # limit our own running time for fairness with other
 604                 # clients and to avoid buffering too much:
 605                 my $lim = 100;
 606
 607                 my $err;
 608                 do {
 609                         eval { $cb->(\$beg) };
 610                 } until (($err = $@) || $self->{closed} ||
 611                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 612
 613                 if ($err || $self->{closed}) {
 614                         $self->{long_res} = undef;
 615
 616                         if ($err) {
 617                                 err($self,
 618                                     "%s during long response[$fd] - %0.6f",
 619                                     $err, now() - $t0);
 620                         }
 621                         if ($self->{closed}) {
 622                                 out($self, " deferred[$fd] aborted - %0.6f",
 623                                            now() - $t0);
 624                         } else {
 625                                 update_idle_time($self);
 626                                 $self->watch_read(1);
 627                         }
 628                 } elsif (!$lim || $self->{write_buf_size}) {
 629                         # no recursion, schedule another call ASAP
 630                         # but only after all pending writes are done
 631                         update_idle_time($self);
 632
 633                         push @$nextq, $self;
 634                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 635                 } else { # all done!
 636                         $self->{long_res} = undef;
 637                         $self->watch_read(1);
 638                         res($self, '.');
 639                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 640                 }
 641         };
 642         $self->{long_res}->(); # kick off!
 643         undef;
 644 }
 645
 646 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 647         my ($self, $xhdr, $range) = @_;
 648
 649         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 650                 my ($ng, $n) = mid_lookup($self, $1);
 651                 return r430 unless $n;
 652                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 653         } else { # numeric range
 654                 $range = $self->{article} unless defined $range;
 655                 my $r = get_range($self, $range);
 656                 return $r unless ref $r;
 657                 my $mm = $self->{ng}->mm;
 658                 my ($beg, $end) = @$r;
 659                 more($self, $xhdr ? r221 : r225);
 660                 long_response($self, $beg, $end, sub {
 661                         my ($i) = @_;
 662                         my $mid = $mm->mid_for($$i);
 663                         more($self, "$$i <$mid>") if defined $mid;
 664                 });
 665         }
 666 }
 667
 668 sub xref ($$) {
 669         my ($ng, $n) = @_;
 670         "$ng->{domain} $ng->{newsgroup}:$n"
 671 }
 672
 673 sub mid_lookup ($$) {
 674         my ($self, $mid) = @_;
 675         my $self_ng = $self->{ng};
 676         if ($self_ng) {
 677                 my $n = $self_ng->mm->num_for($mid);
 678                 return ($self_ng, $n) if defined $n;
 679         }
 680         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 681                 next if defined $self_ng && $ng eq $self_ng;
 682                 my $n = $ng->mm->num_for($mid);
 683                 return ($ng, $n) if defined $n;
 684         }
 685         (undef, undef);
 686 }
 687
 688 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 689         my ($self, $xhdr, $range) = @_;
 690
 691         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 692                 my ($ng, $n) = mid_lookup($self, $1);
 693                 return r430 unless $n;
 694                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 695         } else { # numeric range
 696                 $range = $self->{article} unless defined $range;
 697                 my $r = get_range($self, $range);
 698                 return $r unless ref $r;
 699                 my $ng = $self->{ng};
 700                 my $mm = $ng->mm;
 701                 my ($beg, $end) = @$r;
 702                 more($self, $xhdr ? r221 : r225);
 703                 long_response($self, $beg, $end, sub {
 704                         my ($i) = @_;
 705                         my $mid = $mm->mid_for($$i);
 706                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 707                 });
 708         }
 709 }
 710
 711 sub search_header_for {
 712         my ($srch, $mid, $field) = @_;
 713         my $smsg = $srch->lookup_mail($mid) or return;
 714         $smsg->$field;
 715 }
 716
 717 sub hdr_searchmsg ($$$$) {
 718         my ($self, $xhdr, $field, $range) = @_;
 719         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 720                 my ($ng, $n) = mid_lookup($self, $1);
 721                 return r430 unless $n;
 722                 my $v = search_header_for($ng->search, $range, $field);
 723                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 724         } else { # numeric range
 725                 $range = $self->{article} unless defined $range;
 726                 my $srch = $self->{ng}->search;
 727                 my $mm = $self->{ng}->mm;
 728                 my $r = get_range($self, $range);
 729                 return $r unless ref $r;
 730                 my ($beg, $end) = @$r;
 731                 more($self, $xhdr ? r221 : r225);
 732                 my $off = 0;
 733                 long_response($self, $beg, $end, sub {
 734                         my ($i) = @_;
 735                         my $res = $srch->query_xover($beg, $end, $off);
 736                         my $msgs = $res->{msgs};
 737                         my $nr = scalar @$msgs or return;
 738                         $off += $nr;
 739                         my $tmp = '';
 740                         foreach my $s (@$msgs) {
 741                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 742                         }
 743                         utf8::encode($tmp);
 744                         do_more($self, $tmp);
 745                         # -1 to adjust for implicit increment in long_response
 746                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 747                 });
 748         }
 749 }
 750
 751 sub do_hdr ($$$;$) {
 752         my ($self, $xhdr, $header, $range) = @_;
 753         my $sub = lc $header;
 754         if ($sub eq 'message-id') {
 755                 hdr_message_id($self, $xhdr, $range);
 756         } elsif ($sub eq 'xref') {
 757                 hdr_xref($self, $xhdr, $range);
 758         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 759                                 bytes|lines)\z/x) {
 760                 hdr_searchmsg($self, $xhdr, $sub, $range);
 761         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 762                 hdr_searchmsg($self, $xhdr, $1, $range);
 763         } else {
 764                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 765         }
 766 }
 767
 768 # RFC 3977
 769 sub cmd_hdr ($$;$) {
 770         my ($self, $header, $range) = @_;
 771         do_hdr($self, 0, $header, $range);
 772 }
 773
 774 # RFC 2980
 775 sub cmd_xhdr ($$;$) {
 776         my ($self, $header, $range) = @_;
 777         do_hdr($self, 1, $header, $range);
 778 }
 779
 780 sub hdr_mid_prefix ($$$$$) {
 781         my ($self, $xhdr, $ng, $n, $mid) = @_;
 782         return $mid if $xhdr;
 783
 784         # HDR for RFC 3977 users
 785         if (my $self_ng = $self->{ng}) {
 786                 ($self_ng eq $ng) ? $n : '0';
 787         } else {
 788                 '0';
 789         }
 790 }
 791
 792 sub hdr_mid_response ($$$$$$) {
 793         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 794         my $res = '';
 795         if ($xhdr) {
 796                 $res .= r221 . "\r\n";
 797                 $res .= "$mid $v\r\n";
 798         } else {
 799                 $res .= r225 . "\r\n";
 800                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 801                 $res .= "$pfx $v\r\n";
 802         }
 803         res($self, $res .= '.');
 804         undef;
 805 }
 806
 807 sub cmd_xrover ($;$) {
 808         my ($self, $range) = @_;
 809         my $ng = $self->{ng} or return '412 no newsgroup selected';
 810         (defined $range && $range =~ /[<>]/) and
 811                 return '420 No article(s) selected'; # no message IDs
 812
 813         $range = $self->{article} unless defined $range;
 814         my $r = get_range($self, $range);
 815         return $r unless ref $r;
 816         my ($beg, $end) = @$r;
 817         my $mm = $ng->mm;
 818         my $srch = $ng->search;
 819         more($self, '224 Overview information follows');
 820         long_response($self, $beg, $end, sub {
 821                 my ($i) = @_;
 822                 my $mid = $mm->mid_for($$i) or return;
 823                 my $h = search_header_for($srch, $mid, 'references');
 824                 more($self, "$$i $h");
 825         });
 826 }
 827
 828 sub over_line ($$) {
 829         my ($num, $smsg) = @_;
 830         # n.b. field access and procedural calls can be
 831         # 10%-15% faster than OO method calls:
 832         my $s = join("\t", $num,
 833                 $smsg->{subject},
 834                 $smsg->{from},
 835                 PublicInbox::SearchMsg::date($smsg),
 836                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 837                 $smsg->{references},
 838                 PublicInbox::SearchMsg::bytes($smsg),
 839                 PublicInbox::SearchMsg::lines($smsg));
 840         utf8::encode($s);
 841         $s
 842 }
 843
 844 sub cmd_over ($;$) {
 845         my ($self, $range) = @_;
 846         if ($range && $range =~ /\A<(.+)>\z/) {
 847                 my ($ng, $n) = mid_lookup($self, $1);
 848                 my $smsg = $ng->search->lookup_mail($range) or
 849                         return '430 No article with that message-id';
 850                 more($self, '224 Overview information follows (multi-line)');
 851
 852                 # Only set article number column if it's the current group
 853                 my $self_ng = $self->{ng};
 854                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 855                 more($self, over_line($n, $smsg));
 856                 '.';
 857         } else {
 858                 cmd_xover($self, $range);
 859         }
 860 }
 861
 862 sub cmd_xover ($;$) {
 863         my ($self, $range) = @_;
 864         $range = $self->{article} unless defined $range;
 865         my $r = get_range($self, $range);
 866         return $r unless ref $r;
 867         my ($beg, $end) = @$r;
 868         more($self, "224 Overview information follows for $beg to $end");
 869         my $srch = $self->{ng}->search;
 870         my $off = 0;
 871         long_response($self, $beg, $end, sub {
 872                 my ($i) = @_;
 873                 my $res = $srch->query_xover($beg, $end, $off);
 874                 my $msgs = $res->{msgs};
 875                 my $nr = scalar @$msgs or return;
 876                 $off += $nr;
 877
 878                 # OVERVIEW.FMT
 879                 more($self, join("\r\n", map {
 880                         over_line(PublicInbox::SearchMsg::num($_), $_);
 881                         } @$msgs));
 882
 883                 # -1 to adjust for implicit increment in long_response
 884                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 885         });
 886 }
 887
 888 sub cmd_xpath ($$) {
 889         my ($self, $mid) = @_;
 890         return r501 unless $mid =~ /\A<(.+)>\z/;
 891         $mid = $1;
 892         my @paths;
 893         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 894                 my $n = $ng->mm->num_for($mid);
 895                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 896         }
 897         return '430 no such article on server' unless @paths;
 898         '223 '.join(' ', @paths);
 899 }
 900
 901 sub res ($$) {
 902         my ($self, $line) = @_;
 903         do_write($self, $line . "\r\n");
 904 }
 905
 906 sub more ($$) {
 907         my ($self, $line) = @_;
 908         do_more($self, $line . "\r\n");
 909 }
 910
 911 sub do_write ($$) {
 912         my ($self, $data) = @_;
 913         my $done = $self->write($data);
 914         die if $self->{closed};
 915
 916         # Do not watch for readability if we have data in the queue,
 917         # instead re-enable watching for readability when we can
 918         $self->watch_read(0) if (!$done || $self->{long_res});
 919
 920         $done;
 921 }
 922
 923 sub err ($$;@) {
 924         my ($self, $fmt, @args) = @_;
 925         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 926 }
 927
 928 sub out ($$;@) {
 929         my ($self, $fmt, @args) = @_;
 930         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 931 }
 932
 933 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 934
 935 sub do_more ($$) {
 936         my ($self, $data) = @_;
 937         if (MSG_MORE && !$self->{write_buf_size}) {
 938                 my $n = send($self->{sock}, $data, MSG_MORE);
 939                 if (defined $n) {
 940                         my $dlen = length($data);
 941                         return 1 if $n == $dlen; # all done!
 942                         $data = substr($data, $n, $dlen - $n);
 943                 }
 944         }
 945         do_write($self, $data);
 946 }
 947
 948 # callbacks for Danga::Socket
 949
 950 sub event_hup { $_[0]->close }
 951 sub event_err { $_[0]->close }
 952
 953 sub event_write {
 954         my ($self) = @_;
 955         update_idle_time($self);
 956         # only continue watching for readability when we are done writing:
 957         if ($self->write(undef) == 1 && !$self->{long_res}) {
 958                 $self->watch_read(1);
 959         }
 960 }
 961
 962 sub event_read {
 963         my ($self) = @_;
 964         use constant LINE_MAX => 512; # RFC 977 section 2.3
 965         my $r = 1;
 966
 967         my $buf = $self->read(LINE_MAX) or return $self->close;
 968         $self->{rbuf} .= $$buf;
 969         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 970                 my $line = $1;
 971                 return $self->close if $line =~ /[[:cntrl:]]/s;
 972                 my $t0 = now();
 973                 my $fd = $self->{fd};
 974                 $r = eval { process_line($self, $line) };
 975                 my $d = $self->{long_res} ?
 976                         " deferred[$fd]" : '';
 977                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 978         }
 979
 980         return $self->close if $r < 0;
 981         my $len = length($self->{rbuf});
 982         return $self->close if ($len >= LINE_MAX);
 983         update_idle_time($self);
 984 }
 985
 986 sub watch_read {
 987         my ($self, $bool) = @_;
 988         my $rv = $self->SUPER::watch_read($bool);
 989         if ($bool && $self->{rbuf} ne '') {
 990                 # Force another read if there is a pipelined request.
 991                 # We don't know if the socket has anything for us to read,
 992                 # and we must double-check again by the time the timer fires
 993                 # in case we really did dispatch a read event and started
 994                 # another long response.
 995                 push @$nextq, $self;
 996                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 997         }
 998         $rv;
 999 }
1000
1001 sub not_idle_long ($$) {
1002         my ($self, $now) = @_;
1003         defined(my $fd = $self->{fd}) or return;
1004         my $ary = $EXPMAP->{$fd} or return;
1005         my $exp_at = $ary->[0] + $EXPTIME;
1006         $exp_at > $now;
1007 }
1008
1009 # for graceful shutdown in PublicInbox::Daemon:
1010 sub busy {
1011         my ($self, $now) = @_;
1012         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size} ||
1013          not_idle_long($self, $now));
1014 }
1015
1016 1;