lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27
  28 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         foreach my $nntp (@$q) {
  49                 # for request && response protocols, always finish writing
  50                 # before finishing reading:
  51                 if (my $long_cb = $nntp->{long_res}) {
  52                         $nntp->write($long_cb);
  53                 } else {
  54                         # pipelined request, we bypassed socket-readiness
  55                         # checks to get here:
  56                         event_read($nntp);
  57
  58                         # maybe there's more pipelined data, or we'll have
  59                         # to register it for socket-readiness notifications
  60                         if (!$nntp->{long_res} && !$nntp->{closed}) {
  61                                 check_read($nntp);
  62                         }
  63                 }
  64         }
  65 }
  66
  67 sub update_idle_time ($) {
  68         my ($self) = @_;
  69         my $sock = $self->{sock} or return;
  70         my $fd = fileno($sock);
  71         defined $fd and $EXPMAP->{$fd} = [ now(), $self ];
  72 }
  73
  74 sub expire_old () {
  75         my $now = now();
  76         my $exp = $EXPTIME;
  77         my $old = $now - $exp;
  78         my $nr = 0;
  79         my %new;
  80         while (my ($fd, $v) = each %$EXPMAP) {
  81                 my ($idle_time, $nntp) = @$v;
  82                 if ($idle_time < $old) {
  83                         $nntp->close; # idempotent
  84                 } else {
  85                         ++$nr;
  86                         $new{$fd} = $v;
  87                 }
  88         }
  89         $EXPMAP = \%new;
  90         if ($nr) {
  91                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  92         } else {
  93                 $expt = undef;
  94                 # noop to kick outselves out of the loop ASAP so descriptors
  95                 # really get closed
  96                 PublicInbox::EvCleanup::asap(sub {});
  97         }
  98 }
  99
 100 sub new ($$$) {
 101         my ($class, $sock, $nntpd) = @_;
 102         my $self = fields::new($class);
 103         $self->SUPER::new($sock);
 104         $self->{nntpd} = $nntpd;
 105         res($self, '201 ' . $nntpd->{servername} . ' ready - post via email');
 106         $self->{rbuf} = '';
 107         $self->watch_read(1);
 108         update_idle_time($self);
 109         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 110         $self;
 111 }
 112
 113 sub args_ok ($$) {
 114         my ($cb, $argc) = @_;
 115         my $tot = prototype $cb;
 116         my ($nreq, undef) = split(';', $tot);
 117         $nreq = ($nreq =~ tr/$//) - 1;
 118         $tot = ($tot =~ tr/$//) - 1;
 119         ($argc <= $tot && $argc >= $nreq);
 120 }
 121
 122 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 123 sub process_line ($$) {
 124         my ($self, $l) = @_;
 125         my ($req, @args) = split(/[ \t]/, $l);
 126         return 1 unless defined($req); # skip blank line
 127         $req = lc($req);
 128         $req = eval {
 129                 no strict 'refs';
 130                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 131         };
 132         return res($self, '500 command not recognized') unless $req;
 133         return res($self, r501) unless args_ok($req, scalar @args);
 134
 135         my $res = eval { $req->($self, @args) };
 136         my $err = $@;
 137         if ($err && !$self->{closed}) {
 138                 local $/ = "\n";
 139                 chomp($l);
 140                 err($self, 'error from: %s (%s)', $l, $err);
 141                 $res = '503 program fault - command not performed';
 142         }
 143         return 0 unless defined $res;
 144         res($self, $res);
 145 }
 146
 147 sub cmd_mode ($$) {
 148         my ($self, $arg) = @_;
 149         $arg = uc $arg;
 150         return r501 unless $arg eq 'READER';
 151         '201 Posting prohibited';
 152 }
 153
 154 sub cmd_slave ($) { '202 slave status noted' }
 155
 156 sub cmd_xgtitle ($;$) {
 157         my ($self, $wildmat) = @_;
 158         more($self, '282 list of groups and descriptions follows');
 159         list_newsgroups($self, $wildmat);
 160         '.'
 161 }
 162
 163 sub list_overview_fmt ($) {
 164         my ($self) = @_;
 165         do_more($self, $OVERVIEW_FMT);
 166 }
 167
 168 sub list_headers ($;$) {
 169         my ($self) = @_;
 170         do_more($self, $LIST_HEADERS);
 171 }
 172
 173 sub list_active ($;$) {
 174         my ($self, $wildmat) = @_;
 175         wildmat2re($wildmat);
 176         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 177                 $ng->{newsgroup} =~ $wildmat or next;
 178                 group_line($self, $ng);
 179         }
 180 }
 181
 182 sub list_active_times ($;$) {
 183         my ($self, $wildmat) = @_;
 184         wildmat2re($wildmat);
 185         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 186                 $ng->{newsgroup} =~ $wildmat or next;
 187                 my $c = eval { $ng->mm->created_at } || time;
 188                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 189         }
 190 }
 191
 192 sub list_newsgroups ($;$) {
 193         my ($self, $wildmat) = @_;
 194         wildmat2re($wildmat);
 195         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 196                 $ng->{newsgroup} =~ $wildmat or next;
 197                 my $d = $ng->description;
 198                 more($self, "$ng->{newsgroup} $d");
 199         }
 200 }
 201
 202 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 203 sub cmd_list ($;$$) {
 204         my ($self, @args) = @_;
 205         if (scalar @args) {
 206                 my $arg = shift @args;
 207                 $arg =~ tr/A-Z./a-z_/;
 208                 $arg = "list_$arg";
 209                 return r501 if $DISABLED{$arg};
 210
 211                 $arg = eval {
 212                         no strict 'refs';
 213                         *{$arg}{CODE};
 214                 };
 215                 return r501 unless $arg && args_ok($arg, scalar @args);
 216                 more($self, '215 information follows');
 217                 $arg->($self, @args);
 218         } else {
 219                 more($self, '215 list of newsgroups follows');
 220                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 221                         group_line($self, $ng);
 222                 }
 223         }
 224         '.'
 225 }
 226
 227 sub cmd_listgroup ($;$) {
 228         my ($self, $group) = @_;
 229         if (defined $group) {
 230                 my $res = cmd_group($self, $group);
 231                 return $res if ($res !~ /\A211 /);
 232                 more($self, $res);
 233         }
 234
 235         $self->{ng} or return '412 no newsgroup selected';
 236         my $n = 0;
 237         long_response($self, sub {
 238                 my $ary = $self->{ng}->mm->ids_after(\$n);
 239                 scalar @$ary or return;
 240                 more($self, join("\r\n", @$ary));
 241                 1;
 242         });
 243 }
 244
 245 sub parse_time ($$;$) {
 246         my ($date, $time, $gmt) = @_;
 247         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 248         if (defined $gmt) {
 249                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 250                 $gmt = 1;
 251         }
 252         my @now = $gmt ? gmtime : localtime;
 253         my ($YYYY, $MM, $DD);
 254         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 255                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 256         } else { # legacy clients send YYMMDD
 257                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 258                 my $cur_year = $now[5] + 1900;
 259                 if ($YYYY > $cur_year) {
 260                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 261                 }
 262         }
 263         if ($gmt) {
 264                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 265         } else {
 266                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 267         }
 268 }
 269
 270 sub group_line ($$) {
 271         my ($self, $ng) = @_;
 272         my ($min, $max) = $ng->mm->minmax;
 273         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 274 }
 275
 276 sub cmd_newgroups ($$$;$$) {
 277         my ($self, $date, $time, $gmt, $dists) = @_;
 278         my $ts = eval { parse_time($date, $time, $gmt) };
 279         return r501 if $@;
 280
 281         # TODO dists
 282         more($self, '231 list of new newsgroups follows');
 283         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 284                 my $c = eval { $ng->mm->created_at } || 0;
 285                 next unless $c > $ts;
 286                 group_line($self, $ng);
 287         }
 288         '.'
 289 }
 290
 291 sub wildmat2re (;$) {
 292         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 293         my %keep;
 294         my $salt = rand;
 295         my $tmp = $_[0];
 296
 297         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 298                 my $orig = $1;
 299                 my $key = sha1_hex($orig . $salt);
 300                 $orig =~ s/([^\w\-])+/\Q$1/g;
 301                 $keep{$key} = $orig;
 302                 $key
 303                 #gex;
 304         my %map = ('*' => '.*', '?' => '.' );
 305         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 306         if (scalar %keep) {
 307                 $tmp =~ s#([a-f0-9]{40})#
 308                         my $orig = $keep{$1};
 309                         defined $orig ? $orig : $1;
 310                         #ge;
 311         }
 312         $_[0] = qr/\A$tmp\z/;
 313 }
 314
 315 sub ngpat2re (;$) {
 316         return $_[0] = qr/\A\z/ unless defined $_[0];
 317         my %map = ('*' => '.*', ',' => '|');
 318         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 319         $_[0] = qr/\A(?:$_[0])\z/;
 320 }
 321
 322 sub cmd_newnews ($$$$;$$) {
 323         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 324         my $ts = eval { parse_time($date, $time, $gmt) };
 325         return r501 if $@;
 326         more($self, '230 list of new articles by message-id follows');
 327         my ($keep, $skip) = split('!', $newsgroups, 2);
 328         ngpat2re($keep);
 329         ngpat2re($skip);
 330         my @over;
 331         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 332                 $ng->{newsgroup} =~ $keep or next;
 333                 $ng->{newsgroup} =~ $skip and next;
 334                 my $over = $ng->over or next;
 335                 push @over, $over;
 336         };
 337         return '.' unless @over;
 338
 339         my $prev = 0;
 340         long_response($self, sub {
 341                 my $over = $over[0];
 342                 my $msgs = $over->query_ts($ts, $prev);
 343                 if (scalar @$msgs) {
 344                         more($self, '<' .
 345                                 join(">\r\n<", map { $_->mid } @$msgs ).
 346                                 '>');
 347                         $prev = $msgs->[-1]->{num};
 348                 } else {
 349                         shift @over;
 350                         if (@over) { # continue onto next newsgroup
 351                                 $prev = 0;
 352                                 return 1;
 353                         } else { # break out of the long response.
 354                                 return;
 355                         }
 356                 }
 357         });
 358 }
 359
 360 sub cmd_group ($$) {
 361         my ($self, $group) = @_;
 362         my $no_such = '411 no such news group';
 363         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 364
 365         $self->{ng} = $ng;
 366         my ($min, $max) = $ng->mm->minmax;
 367         $min ||= 0;
 368         $max ||= 0;
 369         $self->{article} = $min;
 370         my $est_size = $max - $min;
 371         "211 $est_size $min $max $group";
 372 }
 373
 374 sub article_adj ($$) {
 375         my ($self, $off) = @_;
 376         my $ng = $self->{ng} or return '412 no newsgroup selected';
 377
 378         my $n = $self->{article};
 379         defined $n or return '420 no current article has been selected';
 380
 381         $n += $off;
 382         my $mid = $ng->mm->mid_for($n);
 383         unless ($mid) {
 384                 $n = $off > 0 ? 'next' : 'previous';
 385                 return "421 no $n article in this group";
 386         }
 387         $self->{article} = $n;
 388         "223 $n <$mid> article retrieved - request text separately";
 389 }
 390
 391 sub cmd_next ($) { article_adj($_[0], 1) }
 392 sub cmd_last ($) { article_adj($_[0], -1) }
 393
 394 # We want to encourage using email and CC-ing everybody involved to avoid
 395 # the single-point-of-failure a single server provides.
 396 sub cmd_post ($) {
 397         my ($self) = @_;
 398         my $ng = $self->{ng};
 399         $ng ? "440 mailto:$ng->{-primary_address} to post"
 400                 : '440 posting not allowed'
 401 }
 402
 403 sub cmd_quit ($) {
 404         my ($self) = @_;
 405         res($self, '205 closing connection - goodbye!');
 406         $self->close;
 407         undef;
 408 }
 409
 410 sub header_append ($$$) {
 411         my ($hdr, $k, $v) = @_;
 412         my @v = $hdr->header($k);
 413         foreach (@v) {
 414                 return if $v eq $_;
 415         }
 416         $hdr->header_set($k, @v, $v);
 417 }
 418
 419 sub xref ($$$$) {
 420         my ($self, $ng, $n, $mid) = @_;
 421         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 422
 423         # num_for is pretty cheap and sometimes we'll lookup the existence
 424         # of an article without getting even the OVER info.  In other words,
 425         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 426         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 427         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 428                 next if $ng eq $other;
 429                 my $num = eval { $other->mm->num_for($mid) } or next;
 430                 $ret .= " $other->{newsgroup}:$num";
 431         }
 432         $ret;
 433 }
 434
 435 sub set_nntp_headers ($$$$$) {
 436         my ($self, $hdr, $ng, $n, $mid) = @_;
 437
 438         # clobber some
 439         my $xref = xref($self, $ng, $n, $mid);
 440         $hdr->header_set('Xref', $xref);
 441         $xref =~ s/:[0-9]+//g;
 442         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 443         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 444         if (my $url = $ng->base_url) {
 445                 $mid = mid_escape($mid);
 446                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 447                 header_append($hdr, 'List-Archive', "<$url>");
 448         }
 449 }
 450
 451 sub art_lookup ($$$) {
 452         my ($self, $art, $set_headers) = @_;
 453         my $ng = $self->{ng};
 454         my ($n, $mid);
 455         my $err;
 456         if (defined $art) {
 457                 if ($art =~ /\A[0-9]+\z/) {
 458                         $err = '423 no such article number in this group';
 459                         $n = int($art);
 460                         goto find_mid;
 461                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 462                         $mid = $1;
 463                         $err = r430;
 464                         $n = $ng->mm->num_for($mid) if $ng;
 465                         goto found if defined $n;
 466                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 467                                 $n = $g->mm->num_for($mid);
 468                                 if (defined $n) {
 469                                         $ng = $g;
 470                                         goto found;
 471                                 }
 472                         }
 473                         return $err;
 474                 } else {
 475                         return r501;
 476                 }
 477         } else {
 478                 $err = '420 no current article has been selected';
 479                 $n = $self->{article};
 480                 defined $n or return $err;
 481 find_mid:
 482                 $ng or return '412 no newsgroup has been selected';
 483                 $mid = $ng->mm->mid_for($n);
 484                 defined $mid or return $err;
 485         }
 486 found:
 487         my $smsg = $ng->over->get_art($n) or return $err;
 488         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 489         my $s = Email::Simple->new($msg);
 490         if ($set_headers) {
 491                 set_nntp_headers($self, $s->header_obj, $ng, $n, $mid);
 492
 493                 # must be last
 494                 $s->body_set('') if ($set_headers == 2);
 495         }
 496         [ $n, $mid, $s, $smsg->bytes, $smsg->lines, $ng ];
 497 }
 498
 499 sub simple_body_write ($$) {
 500         my ($self, $s) = @_;
 501         my $body = $s->body;
 502         $s->body_set('');
 503         $body =~ s/^\./../smg;
 504         $body =~ s/(?<!\r)\n/\r\n/sg;
 505         do_more($self, $body);
 506         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 507         '.'
 508 }
 509
 510 sub set_art {
 511         my ($self, $art) = @_;
 512         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 513 }
 514
 515 sub _header ($) {
 516         my $hdr = $_[0]->header_obj->as_string;
 517         utf8::encode($hdr);
 518         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 519         $hdr
 520 }
 521
 522 sub cmd_article ($;$) {
 523         my ($self, $art) = @_;
 524         my $r = art_lookup($self, $art, 1);
 525         return $r unless ref $r;
 526         my ($n, $mid, $s) = @$r;
 527         set_art($self, $art);
 528         more($self, "220 $n <$mid> article retrieved - head and body follow");
 529         do_more($self, _header($s));
 530         do_more($self, "\r\n");
 531         simple_body_write($self, $s);
 532 }
 533
 534 sub cmd_head ($;$) {
 535         my ($self, $art) = @_;
 536         my $r = art_lookup($self, $art, 2);
 537         return $r unless ref $r;
 538         my ($n, $mid, $s) = @$r;
 539         set_art($self, $art);
 540         more($self, "221 $n <$mid> article retrieved - head follows");
 541         do_more($self, _header($s));
 542         '.'
 543 }
 544
 545 sub cmd_body ($;$) {
 546         my ($self, $art) = @_;
 547         my $r = art_lookup($self, $art, 0);
 548         return $r unless ref $r;
 549         my ($n, $mid, $s) = @$r;
 550         set_art($self, $art);
 551         more($self, "222 $n <$mid> article retrieved - body follows");
 552         simple_body_write($self, $s);
 553 }
 554
 555 sub cmd_stat ($;$) {
 556         my ($self, $art) = @_;
 557         my $r = art_lookup($self, $art, 0);
 558         return $r unless ref $r;
 559         my ($n, $mid, undef) = @$r;
 560         set_art($self, $art);
 561         "223 $n <$mid> article retrieved - request text separately";
 562 }
 563
 564 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 565
 566 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 567
 568 sub cmd_help ($) {
 569         my ($self) = @_;
 570         more($self, '100 help text follows');
 571         '.'
 572 }
 573
 574 sub get_range ($$) {
 575         my ($self, $range) = @_;
 576         my $ng = $self->{ng} or return '412 no news group has been selected';
 577         defined $range or return '420 No article(s) selected';
 578         my ($beg, $end);
 579         my ($min, $max) = $ng->mm->minmax;
 580         if ($range =~ /\A([0-9]+)\z/) {
 581                 $beg = $end = $1;
 582         } elsif ($range =~ /\A([0-9]+)-\z/) {
 583                 ($beg, $end) = ($1, $max);
 584         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 585                 ($beg, $end) = ($1, $2);
 586         } else {
 587                 return r501;
 588         }
 589         $beg = $min if ($beg < $min);
 590         $end = $max if ($end > $max);
 591         return '420 No article(s) selected' if ($beg > $end);
 592         [ $beg, $end ];
 593 }
 594
 595 sub long_response ($$) {
 596         my ($self, $cb) = @_;
 597         die "BUG: nested long response" if $self->{long_res};
 598
 599         my $fd = fileno($self->{sock});
 600         defined $fd or return;
 601         # make sure we disable reading during a long response,
 602         # clients should not be sending us stuff and making us do more
 603         # work while we are stream a response to them
 604         $self->watch_read(0);
 605         my $t0 = now();
 606         $self->{long_res} = sub {
 607                 my $more = eval { $cb->() };
 608                 if ($@ || $self->{closed}) {
 609                         $self->{long_res} = undef;
 610
 611                         if ($@) {
 612                                 err($self,
 613                                     "%s during long response[$fd] - %0.6f",
 614                                     $@, now() - $t0);
 615                         }
 616                         if ($self->{closed}) {
 617                                 out($self, " deferred[$fd] aborted - %0.6f",
 618                                            now() - $t0);
 619                         } else {
 620                                 update_idle_time($self);
 621                                 check_read($self);
 622                         }
 623                 } elsif ($more) { # scalar @{$self->{wbuf}}:
 624                         # no recursion, schedule another call ASAP
 625                         # but only after all pending writes are done
 626                         update_idle_time($self);
 627
 628                         push @$nextq, $self;
 629                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 630                 } else { # all done!
 631                         $self->{long_res} = undef;
 632                         check_read($self);
 633                         res($self, '.');
 634                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 635                 }
 636         };
 637         $self->{long_res}->(); # kick off!
 638         undef;
 639 }
 640
 641 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 642         my ($self, $xhdr, $range) = @_;
 643
 644         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 645                 my ($ng, $n) = mid_lookup($self, $1);
 646                 return r430 unless $n;
 647                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 648         } else { # numeric range
 649                 $range = $self->{article} unless defined $range;
 650                 my $r = get_range($self, $range);
 651                 return $r unless ref $r;
 652                 my $mm = $self->{ng}->mm;
 653                 my ($beg, $end) = @$r;
 654                 more($self, $xhdr ? r221 : r225);
 655                 long_response($self, sub {
 656                         my $r = $mm->msg_range(\$beg, $end);
 657                         @$r or return;
 658                         more($self, join("\r\n", map {
 659                                 "$_->[0] <$_->[1]>"
 660                         } @$r));
 661                         1;
 662                 });
 663         }
 664 }
 665
 666 sub mid_lookup ($$) {
 667         my ($self, $mid) = @_;
 668         my $self_ng = $self->{ng};
 669         if ($self_ng) {
 670                 my $n = $self_ng->mm->num_for($mid);
 671                 return ($self_ng, $n) if defined $n;
 672         }
 673         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 674                 next if defined $self_ng && $ng eq $self_ng;
 675                 my $n = $ng->mm->num_for($mid);
 676                 return ($ng, $n) if defined $n;
 677         }
 678         (undef, undef);
 679 }
 680
 681 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 682         my ($self, $xhdr, $range) = @_;
 683
 684         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 685                 my $mid = $1;
 686                 my ($ng, $n) = mid_lookup($self, $mid);
 687                 return r430 unless $n;
 688                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 689                                 xref($self, $ng, $n, $mid));
 690         } else { # numeric range
 691                 $range = $self->{article} unless defined $range;
 692                 my $r = get_range($self, $range);
 693                 return $r unless ref $r;
 694                 my $ng = $self->{ng};
 695                 my $mm = $ng->mm;
 696                 my ($beg, $end) = @$r;
 697                 more($self, $xhdr ? r221 : r225);
 698                 long_response($self, sub {
 699                         my $r = $mm->msg_range(\$beg, $end);
 700                         @$r or return;
 701                         more($self, join("\r\n", map {
 702                                 my $num = $_->[0];
 703                                 "$num ".xref($self, $ng, $num, $_->[1]);
 704                         } @$r));
 705                         1;
 706                 });
 707         }
 708 }
 709
 710 sub over_header_for {
 711         my ($over, $num, $field) = @_;
 712         my $smsg = $over->get_art($num) or return;
 713         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 714         $smsg->{$field};
 715 }
 716
 717 sub hdr_searchmsg ($$$$) {
 718         my ($self, $xhdr, $field, $range) = @_;
 719         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 720                 my ($ng, $n) = mid_lookup($self, $1);
 721                 return r430 unless defined $n;
 722                 my $v = over_header_for($ng->over, $n, $field);
 723                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 724         } else { # numeric range
 725                 $range = $self->{article} unless defined $range;
 726                 my $over = $self->{ng}->over;
 727                 my $mm = $self->{ng}->mm;
 728                 my $r = get_range($self, $range);
 729                 return $r unless ref $r;
 730                 my ($beg, $end) = @$r;
 731                 more($self, $xhdr ? r221 : r225);
 732                 my $cur = $beg;
 733                 long_response($self, sub {
 734                         my $msgs = $over->query_xover($cur, $end);
 735                         my $nr = scalar @$msgs or return;
 736                         my $tmp = '';
 737                         foreach my $s (@$msgs) {
 738                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 739                         }
 740                         utf8::encode($tmp);
 741                         do_more($self, $tmp);
 742                         $cur = $msgs->[-1]->{num} + 1;
 743                 });
 744         }
 745 }
 746
 747 sub do_hdr ($$$;$) {
 748         my ($self, $xhdr, $header, $range) = @_;
 749         my $sub = lc $header;
 750         if ($sub eq 'message-id') {
 751                 hdr_message_id($self, $xhdr, $range);
 752         } elsif ($sub eq 'xref') {
 753                 hdr_xref($self, $xhdr, $range);
 754         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 755                                 bytes|lines)\z/x) {
 756                 hdr_searchmsg($self, $xhdr, $sub, $range);
 757         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 758                 hdr_searchmsg($self, $xhdr, $1, $range);
 759         } else {
 760                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 761         }
 762 }
 763
 764 # RFC 3977
 765 sub cmd_hdr ($$;$) {
 766         my ($self, $header, $range) = @_;
 767         do_hdr($self, 0, $header, $range);
 768 }
 769
 770 # RFC 2980
 771 sub cmd_xhdr ($$;$) {
 772         my ($self, $header, $range) = @_;
 773         do_hdr($self, 1, $header, $range);
 774 }
 775
 776 sub hdr_mid_prefix ($$$$$) {
 777         my ($self, $xhdr, $ng, $n, $mid) = @_;
 778         return $mid if $xhdr;
 779
 780         # HDR for RFC 3977 users
 781         if (my $self_ng = $self->{ng}) {
 782                 ($self_ng eq $ng) ? $n : '0';
 783         } else {
 784                 '0';
 785         }
 786 }
 787
 788 sub hdr_mid_response ($$$$$$) {
 789         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 790         my $res = '';
 791         if ($xhdr) {
 792                 $res .= r221 . "\r\n";
 793                 $res .= "$mid $v\r\n";
 794         } else {
 795                 $res .= r225 . "\r\n";
 796                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 797                 $res .= "$pfx $v\r\n";
 798         }
 799         res($self, $res .= '.');
 800         undef;
 801 }
 802
 803 sub cmd_xrover ($;$) {
 804         my ($self, $range) = @_;
 805         my $ng = $self->{ng} or return '412 no newsgroup selected';
 806         (defined $range && $range =~ /[<>]/) and
 807                 return '420 No article(s) selected'; # no message IDs
 808
 809         $range = $self->{article} unless defined $range;
 810         my $r = get_range($self, $range);
 811         return $r unless ref $r;
 812         my ($beg, $end) = @$r;
 813         my $mm = $ng->mm;
 814         my $over = $ng->over;
 815         more($self, '224 Overview information follows');
 816
 817         long_response($self, sub {
 818                 my $h = over_header_for($over, $beg, 'references');
 819                 more($self, "$beg $h") if defined($h);
 820                 $beg++ < $end;
 821         });
 822 }
 823
 824 sub over_line ($$$$) {
 825         my ($self, $ng, $num, $smsg) = @_;
 826         # n.b. field access and procedural calls can be
 827         # 10%-15% faster than OO method calls:
 828         my $s = join("\t", $num,
 829                 $smsg->{subject},
 830                 $smsg->{from},
 831                 PublicInbox::SearchMsg::date($smsg),
 832                 "<$smsg->{mid}>",
 833                 $smsg->{references},
 834                 $smsg->{bytes},
 835                 $smsg->{lines},
 836                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 837         utf8::encode($s);
 838         $s
 839 }
 840
 841 sub cmd_over ($;$) {
 842         my ($self, $range) = @_;
 843         if ($range && $range =~ /\A<(.+)>\z/) {
 844                 my ($ng, $n) = mid_lookup($self, $1);
 845                 defined $n or return r430;
 846                 my $smsg = $ng->over->get_art($n) or return r430;
 847                 more($self, '224 Overview information follows (multi-line)');
 848
 849                 # Only set article number column if it's the current group
 850                 my $self_ng = $self->{ng};
 851                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 852                 more($self, over_line($self, $ng, $n, $smsg));
 853                 '.';
 854         } else {
 855                 cmd_xover($self, $range);
 856         }
 857 }
 858
 859 sub cmd_xover ($;$) {
 860         my ($self, $range) = @_;
 861         $range = $self->{article} unless defined $range;
 862         my $r = get_range($self, $range);
 863         return $r unless ref $r;
 864         my ($beg, $end) = @$r;
 865         more($self, "224 Overview information follows for $beg to $end");
 866         my $over = $self->{ng}->over;
 867         my $cur = $beg;
 868         long_response($self, sub {
 869                 my $msgs = $over->query_xover($cur, $end);
 870                 my $nr = scalar @$msgs or return;
 871
 872                 # OVERVIEW.FMT
 873                 more($self, join("\r\n", map {
 874                         over_line($self, $self->{ng}, $_->{num}, $_);
 875                         } @$msgs));
 876                 $cur = $msgs->[-1]->{num} + 1;
 877         });
 878 }
 879
 880 sub cmd_xpath ($$) {
 881         my ($self, $mid) = @_;
 882         return r501 unless $mid =~ /\A<(.+)>\z/;
 883         $mid = $1;
 884         my @paths;
 885         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 886                 my $n = $ng->mm->num_for($mid);
 887                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 888         }
 889         return '430 no such article on server' unless @paths;
 890         '223 '.join(' ', @paths);
 891 }
 892
 893 sub res ($$) {
 894         my ($self, $line) = @_;
 895         do_write($self, $line . "\r\n");
 896 }
 897
 898 sub more ($$) {
 899         my ($self, $line) = @_;
 900         do_more($self, $line . "\r\n");
 901 }
 902
 903 sub do_write ($$) {
 904         my ($self, $data) = @_;
 905         my $done = $self->write($data);
 906         return 0 if $self->{closed};
 907
 908         # Do not watch for readability if we have data in the queue,
 909         # instead re-enable watching for readability when we can
 910         $self->watch_read(0) if (!$done || $self->{long_res});
 911
 912         $done;
 913 }
 914
 915 sub err ($$;@) {
 916         my ($self, $fmt, @args) = @_;
 917         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 918 }
 919
 920 sub out ($$;@) {
 921         my ($self, $fmt, @args) = @_;
 922         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 923 }
 924
 925 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 926
 927 sub do_more ($$) {
 928         my ($self, $data) = @_;
 929         if (MSG_MORE && !scalar(@{$self->{wbuf}})) {
 930                 my $n = send($self->{sock}, $data, MSG_MORE);
 931                 if (defined $n) {
 932                         my $dlen = length($data);
 933                         return 1 if $n == $dlen; # all done!
 934                         $data = substr($data, $n, $dlen - $n);
 935                 }
 936         }
 937         do_write($self, $data);
 938 }
 939
 940 sub event_write {
 941         my ($self) = @_;
 942         update_idle_time($self);
 943         # only continue watching for readability when we are done writing:
 944         if ($self->write(undef) == 1 && !$self->{long_res}) {
 945                 $self->watch_read(1);
 946         }
 947 }
 948
 949 sub event_read {
 950         my ($self) = @_;
 951         use constant LINE_MAX => 512; # RFC 977 section 2.3
 952         my $rbuf = \($self->{rbuf});
 953         my $r;
 954
 955         if (index($$rbuf, "\n") < 0) {
 956                 my $off = length($$rbuf);
 957                 $r = sysread($self->{sock}, $$rbuf, LINE_MAX, $off);
 958                 unless (defined $r) {
 959                         return if $!{EAGAIN};
 960                         return $self->close;
 961                 }
 962                 return $self->close if $r == 0;
 963         }
 964         $r = 1;
 965         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 966                 my $line = $1;
 967                 return $self->close if $line =~ /[[:cntrl:]]/s;
 968                 my $t0 = now();
 969                 my $fd = fileno($self->{sock});
 970                 $r = eval { process_line($self, $line) };
 971                 my $d = $self->{long_res} ?
 972                         " deferred[$fd]" : '';
 973                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 974         }
 975
 976         return $self->close if $r < 0;
 977         my $len = length($$rbuf);
 978         return $self->close if ($len >= LINE_MAX);
 979         update_idle_time($self);
 980 }
 981
 982 sub check_read {
 983         my ($self) = @_;
 984         if (index($self->{rbuf}, "\n") >= 0) {
 985                 # Force another read if there is a pipelined request.
 986                 # We don't know if the socket has anything for us to read,
 987                 # and we must double-check again by the time the timer fires
 988                 # in case we really did dispatch a read event and started
 989                 # another long response.
 990                 push @$nextq, $self;
 991                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 992         } else {
 993                 # no pipelined requests available, let the kernel know
 994                 # to wake us up if there's more
 995                 $self->watch_read(1); # PublicInbox::DS::watch_read
 996         }
 997 }
 998
 999 sub not_idle_long ($$) {
1000         my ($self, $now) = @_;
1001         my $sock = $self->{sock} or return;
1002         defined(my $fd = fileno($sock)) or return;
1003         my $ary = $EXPMAP->{$fd} or return;
1004         my $exp_at = $ary->[0] + $EXPTIME;
1005         $exp_at > $now;
1006 }
1007
1008 # for graceful shutdown in PublicInbox::Daemon:
1009 sub busy {
1010         my ($self, $now) = @_;
1011         ($self->{rbuf} ne '' || $self->{long_res} ||
1012                 scalar(@{$self->{wbuf}}) || not_idle_long($self, $now));
1013 }
1014
1015 1;