lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ng: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use parent qw(PublicInbox::DS);
  13 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  14 use PublicInbox::Eml;
  15 use POSIX qw(strftime);
  16 use PublicInbox::DS qw(now);
  17 use Digest::SHA qw(sha1_hex);
  18 use Time::Local qw(timegm timelocal);
  19 use PublicInbox::GitAsyncCat;
  20 use PublicInbox::Address;
  21
  22 use constant {
  23         LINE_MAX => 512, # RFC 977 section 2.3
  24         r501 => '501 command syntax error',
  25         r502 => '502 Command unavailable',
  26         r221 => '221 Header follows',
  27         r224 => '224 Overview information follows (multi-line)',
  28         r225 => '225 Headers follow (multi-line)',
  29         r430 => '430 No article with that message-id',
  30 };
  31 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  32 use Errno qw(EAGAIN);
  33 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  34 my @OVERVIEW = qw(Subject From Date Message-ID References);
  35 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  36                 "Xref:full\r\n.";
  37 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  38                         qw(:bytes :lines Xref To Cc)) . "\r\n.";
  39 my $CAPABILITIES = <<"";
  40 101 Capability list:\r
  41 VERSION 2\r
  42 READER\r
  43 NEWNEWS\r
  44 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  45 HDR\r
  46 OVER\r
  47 COMPRESS DEFLATE\r
  48
  49 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  50
  51 sub new ($$$) {
  52         my ($class, $sock, $nntpd) = @_;
  53         my $self = bless { nntpd => $nntpd }, $class;
  54         my $ev = EPOLLIN;
  55         my $wbuf;
  56         if ($sock->can('accept_SSL') && !$sock->accept_SSL) {
  57                 return CORE::close($sock) if $! != EAGAIN;
  58                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
  59                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  60         }
  61         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  62         if ($wbuf) {
  63                 $self->{wbuf} = $wbuf;
  64         } else {
  65                 greet($self);
  66         }
  67         $self->update_idle_time;
  68         $self;
  69 }
  70
  71 sub args_ok ($$) {
  72         my ($cb, $argc) = @_;
  73         my $tot = prototype $cb;
  74         my ($nreq, undef) = split(';', $tot);
  75         $nreq = ($nreq =~ tr/$//) - 1;
  76         $tot = ($tot =~ tr/$//) - 1;
  77         ($argc <= $tot && $argc >= $nreq);
  78 }
  79
  80 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  81 sub process_line ($$) {
  82         my ($self, $l) = @_;
  83         my ($req, @args) = split(/[ \t]+/, $l);
  84         return 1 unless defined($req); # skip blank line
  85         $req = $self->can('cmd_'.lc($req));
  86         return res($self, '500 command not recognized') unless $req;
  87         return res($self, r501) unless args_ok($req, scalar @args);
  88
  89         my $res = eval { $req->($self, @args) };
  90         my $err = $@;
  91         if ($err && $self->{sock}) {
  92                 local $/ = "\n";
  93                 chomp($l);
  94                 err($self, 'error from: %s (%s)', $l, $err);
  95                 $res = '503 program fault - command not performed';
  96         }
  97         defined($res) ? res($self, $res) : 0;
  98 }
  99
 100 # The keyword argument is not used (rfc3977 5.2.2)
 101 sub cmd_capabilities ($;$) {
 102         my ($self, undef) = @_;
 103         my $res = $CAPABILITIES;
 104         if (!$self->{sock}->can('accept_SSL') &&
 105                         $self->{nntpd}->{accept_tls}) {
 106                 $res .= "STARTTLS\r\n";
 107         }
 108         $res .= '.';
 109 }
 110
 111 sub cmd_mode ($$) {
 112         my ($self, $arg) = @_;
 113         uc($arg) eq 'READER' ? '201 Posting prohibited' : r501;
 114 }
 115
 116 sub cmd_slave ($) { '202 slave status noted' }
 117
 118 sub cmd_xgtitle ($;$) {
 119         my ($self, $wildmat) = @_;
 120         more($self, '282 list of groups and descriptions follows');
 121         list_newsgroups($self, $wildmat);
 122 }
 123
 124 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 125
 126 sub list_headers ($;$) { $LIST_HEADERS }
 127
 128 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 129         my ($self, $groupnames) = @_;
 130         my @window = splice(@$groupnames, 0, 100) or return 0;
 131         my $ibx;
 132         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 135         }
 136         scalar(@$groupnames); # continue if there's more
 137 }
 138
 139 sub list_active ($;$) { # called by cmd_list
 140         my ($self, $wildmat) = @_;
 141         wildmat2re($wildmat);
 142         long_response($self, \&list_active_i, [
 143                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 144 }
 145
 146 sub list_active_times_i {
 147         my ($self, $groupnames) = @_;
 148         my @window = splice(@$groupnames, 0, 100) or return 0;
 149         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 150         for my $ngname (@window) {
 151                 my $ibx = $groups->{$ngname} or next;
 152                 my $c = eval { $ibx->uidvalidity } // time;
 153                 more($self, "$ngname $c <$ibx->{-primary_address}>");
 154         }
 155         scalar(@$groupnames); # continue if there's more
 156 }
 157
 158 sub list_active_times ($;$) { # called by cmd_list
 159         my ($self, $wildmat) = @_;
 160         wildmat2re($wildmat);
 161         long_response($self, \&list_active_times_i, [
 162                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 163 }
 164
 165 sub list_newsgroups_i {
 166         my ($self, $groupnames) = @_;
 167         my @window = splice(@$groupnames, 0, 100) or return 0;
 168         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 169         my $ibx;
 170         for my $ngname (@window) {
 171                 $ibx = $groups->{$ngname} and
 172                         more($self, "$ngname ".$ibx->description);
 173         }
 174         scalar(@$groupnames); # continue if there's more
 175 }
 176
 177 sub list_newsgroups ($;$) { # called by cmd_list
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         long_response($self, \&list_newsgroups_i, [
 181                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 182 }
 183
 184 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 185 sub cmd_list ($;$$) {
 186         my ($self, @args) = @_;
 187         if (scalar @args) {
 188                 my $arg = shift @args;
 189                 $arg =~ tr/A-Z./a-z_/;
 190                 my $ret = $arg eq 'active';
 191                 $arg = "list_$arg";
 192                 $arg = $self->can($arg);
 193                 return r501 unless $arg && args_ok($arg, scalar @args);
 194                 more($self, '215 information follows');
 195                 $arg->($self, @args);
 196         } else {
 197                 more($self, '215 list of newsgroups follows');
 198                 long_response($self, \&list_active_i, [ # copy array
 199                         @{$self->{nntpd}->{groupnames}} ]);
 200         }
 201 }
 202
 203 sub listgroup_range_i {
 204         my ($self, $beg, $end) = @_;
 205         my $r = $self->{ng}->mm->msg_range($beg, $end, 'num');
 206         scalar(@$r) or return;
 207         $self->msg_more(join('', map { "$_->[0]\r\n" } @$r));
 208         1;
 209 }
 210
 211 sub listgroup_all_i {
 212         my ($self, $num) = @_;
 213         my $ary = $self->{ng}->mm->ids_after($num);
 214         scalar(@$ary) or return;
 215         more($self, join("\r\n", @$ary));
 216         1;
 217 }
 218
 219 sub cmd_listgroup ($;$$) {
 220         my ($self, $group, $range) = @_;
 221         if (defined $group) {
 222                 my $res = cmd_group($self, $group);
 223                 return $res if ($res !~ /\A211 /);
 224                 more($self, $res);
 225         }
 226         $self->{ng} or return '412 no newsgroup selected';
 227         if (defined $range) {
 228                 my $r = get_range($self, $range);
 229                 return $r unless ref $r;
 230                 long_response($self, \&listgroup_range_i, @$r);
 231         } else { # grab every article number
 232                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 233         }
 234 }
 235
 236 sub parse_time ($$;$) {
 237         my ($date, $time, $gmt) = @_;
 238         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 239         if (defined $gmt) {
 240                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 241                 $gmt = 1;
 242         }
 243         my ($YYYY, $MM, $DD);
 244         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 245                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 246         } else { # legacy clients send YYMMDD
 247                 my $YY;
 248                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 249                 my @now = $gmt ? gmtime : localtime;
 250                 my $cur_year = $now[5] + 1900;
 251                 my $cur_cent = int($cur_year / 100) * 100;
 252                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 253                         ($YY + 1900) : ($YY + $cur_cent);
 254         }
 255         if ($gmt) {
 256                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 257         } else {
 258                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 259         }
 260 }
 261
 262 sub group_line ($$) {
 263         my ($self, $ng) = @_;
 264         my ($min, $max) = $ng->mm->minmax;
 265         more($self, "$ng->{newsgroup} $max $min n");
 266 }
 267
 268 sub newgroups_i {
 269         my ($self, $ts, $i, $groupnames) = @_;
 270         my $end = $$i + 100;
 271         my $groups = $self->{nntpd}->{pi_config}->{-by_newsgroup};
 272         while ($$i < $end) {
 273                 my $ngname = $groupnames->[$$i++] // return;
 274                 my $ibx = $groups->{$ngname} or next; # expired on reload
 275                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 276                 group_line($self, $ibx);
 277         }
 278         1;
 279 }
 280
 281 sub cmd_newgroups ($$$;$$) {
 282         my ($self, $date, $time, $gmt, $dists) = @_;
 283         my $ts = eval { parse_time($date, $time, $gmt) };
 284         return r501 if $@;
 285
 286         # TODO dists
 287         more($self, '231 list of new newsgroups follows');
 288         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 289                                 $self->{nntpd}->{groupnames});
 290 }
 291
 292 sub wildmat2re (;$) {
 293         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 294         my %keep;
 295         my $salt = rand;
 296         my $tmp = $_[0];
 297
 298         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 299                 my $orig = $1;
 300                 my $key = sha1_hex($orig . $salt);
 301                 $orig =~ s/([^\w\-])+/\Q$1/g;
 302                 $keep{$key} = $orig;
 303                 $key
 304                 #gex;
 305         my %map = ('*' => '.*', '?' => '.' );
 306         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 307         if (scalar %keep) {
 308                 $tmp =~ s#([a-f0-9]{40})#
 309                         my $orig = $keep{$1};
 310                         defined $orig ? $orig : $1;
 311                         #ge;
 312         }
 313         $_[0] = qr/\A$tmp\z/;
 314 }
 315
 316 sub ngpat2re (;$) {
 317         return $_[0] = qr/\A\z/ unless defined $_[0];
 318         my %map = ('*' => '.*', ',' => '|');
 319         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 320         $_[0] = qr/\A(?:$_[0])\z/;
 321 }
 322
 323 sub newnews_i {
 324         my ($self, $names, $ts, $prev) = @_;
 325         my $ngname = $names->[0];
 326         if (my $ibx = $self->{nntpd}->{pi_config}->{-by_newsgroup}->{$ngname}) {
 327                 if (my $over = $ibx->over) {
 328                         my $msgs = $over->query_ts($ts, $$prev);
 329                         if (scalar @$msgs) {
 330                                 $self->msg_more(join('', map {
 331                                                         "<$_->{mid}>\r\n";
 332                                                 } @$msgs));
 333                                 $$prev = $msgs->[-1]->{num};
 334                                 return 1; # continue on current group
 335                         }
 336                 }
 337         }
 338         shift @$names;
 339         if (@$names) { # continue onto next newsgroup
 340                 $$prev = 0;
 341                 1;
 342         } else { # all done, break out of the long_response
 343                 undef;
 344         }
 345 }
 346
 347 sub cmd_newnews ($$$$;$$) {
 348         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 349         my $ts = eval { parse_time($date, $time, $gmt) };
 350         return r501 if $@;
 351         more($self, '230 list of new articles by message-id follows');
 352         my ($keep, $skip) = split('!', $newsgroups, 2);
 353         ngpat2re($keep);
 354         ngpat2re($skip);
 355         my @names = grep(!/$skip/, grep(/$keep/,
 356                                 @{$self->{nntpd}->{groupnames}}));
 357         return '.' unless scalar(@names);
 358         my $prev = 0;
 359         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 360 }
 361
 362 sub cmd_group ($$) {
 363         my ($self, $group) = @_;
 364         my $nntpd = $self->{nntpd};
 365         my $ibx = $nntpd->{pi_config}->{-by_newsgroup}->{$group} or
 366                 return '411 no such news group';
 367         $nntpd->idler_start;
 368
 369         $self->{ng} = $ibx;
 370         my ($min, $max) = $ibx->mm->minmax;
 371         $self->{article} = $min;
 372         my $est_size = $max - $min;
 373         "211 $est_size $min $max $group";
 374 }
 375
 376 sub article_adj ($$) {
 377         my ($self, $off) = @_;
 378         my $ng = $self->{ng} or return '412 no newsgroup selected';
 379
 380         my $n = $self->{article};
 381         defined $n or return '420 no current article has been selected';
 382
 383         $n += $off;
 384         my $mid = $ng->mm->mid_for($n);
 385         unless ($mid) {
 386                 $n = $off > 0 ? 'next' : 'previous';
 387                 return "421 no $n article in this group";
 388         }
 389         $self->{article} = $n;
 390         "223 $n <$mid> article retrieved - request text separately";
 391 }
 392
 393 sub cmd_next ($) { article_adj($_[0], 1) }
 394 sub cmd_last ($) { article_adj($_[0], -1) }
 395
 396 # We want to encourage using email and CC-ing everybody involved to avoid
 397 # the single-point-of-failure a single server provides.
 398 sub cmd_post ($) {
 399         my ($self) = @_;
 400         my $ng = $self->{ng};
 401         $ng ? "440 mailto:$ng->{-primary_address} to post"
 402                 : '440 posting not allowed'
 403 }
 404
 405 sub cmd_quit ($) {
 406         my ($self) = @_;
 407         res($self, '205 closing connection - goodbye!');
 408         $self->shutdn;
 409         undef;
 410 }
 411
 412 sub header_append ($$$) {
 413         my ($hdr, $k, $v) = @_;
 414         my @v = $hdr->header_raw($k);
 415         foreach (@v) {
 416                 return if $v eq $_;
 417         }
 418         $hdr->header_set($k, @v, $v);
 419 }
 420
 421 sub xref_by_tc ($$$) {
 422         my ($xref, $pi_cfg, $smsg) = @_;
 423         my $by_addr = $pi_cfg->{-by_addr};
 424         my $mid = $smsg->{mid};
 425         for my $f (qw(to cc)) {
 426                 my @ibxs = map {
 427                         $by_addr->{lc($_)} // ()
 428                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 429                 for my $ibx (@ibxs) {
 430                         my $ngname = $ibx->{newsgroup} // next;
 431                         next if defined $xref->{$ngname};
 432                         $xref->{$ngname} = eval { $ibx->mm->num_for($mid) };
 433                 }
 434         }
 435 }
 436
 437 sub xref ($$$) {
 438         my ($self, $cur_ibx, $smsg) = @_;
 439         my $nntpd = $self->{nntpd};
 440         my $cur_ng = $cur_ibx->{newsgroup};
 441         my $xref;
 442         if (my $ALL = $nntpd->{pi_config}->ALL) {
 443                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 444                 xref_by_tc($xref, $nntpd->{pi_config}, $smsg);
 445         } else { # slow path
 446                 $xref = { $cur_ng => $smsg->{num} };
 447                 my $mid = $smsg->{mid};
 448                 for my $ibx (values %{$nntpd->{pi_config}->{-by_newsgroup}}) {
 449                         next if defined($xref->{$ibx->{newsgroup}});
 450                         my $num = eval { $ibx->mm->num_for($mid) } // next;
 451                         $xref->{$ibx->{newsgroup}} = $num;
 452                 }
 453         }
 454         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 455         $ret .= " $_:$xref->{$_}" for (sort keys %$xref);
 456         $ret;
 457 }
 458
 459 sub set_nntp_headers ($$) {
 460         my ($hdr, $smsg) = @_;
 461         my ($mid) = $smsg->{mid};
 462
 463         # leafnode (and maybe other NNTP clients) have trouble dealing
 464         # with v2 messages which have multiple Message-IDs (either due
 465         # to our own content-based dedupe or buggy git-send-email versions).
 466         my @mids = $hdr->header_raw('Message-ID');
 467         if (scalar(@mids) > 1) {
 468                 my $mid0 = "<$mid>";
 469                 $hdr->header_set('Message-ID', $mid0);
 470                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 471                 my %seen = map { $_ => 1 } (@alt, $mid0);
 472                 push(@alt, grep { !$seen{$_}++ } @mids);
 473                 $hdr->header_set('X-Alt-Message-ID', @alt);
 474         }
 475
 476         # clobber some existing headers
 477         my $ibx = $smsg->{-ibx};
 478         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 479         $hdr->header_set('Xref', $xref);
 480
 481         # RFC 5536 3.1.4
 482         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 483         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 484         $newsgroups =~ tr/ /,/;
 485         $hdr->header_set('Newsgroups', $newsgroups);
 486
 487         # *something* here is required for leafnode, try to follow
 488         # RFC 5536 3.1.5...
 489         $hdr->header_set('Path', $server_name . '!not-for-mail');
 490
 491         header_append($hdr, 'List-Post', "<mailto:$ibx->{-primary_address}>");
 492         if (my $url = $ibx->base_url) {
 493                 $mid = mid_escape($mid);
 494                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 495                 header_append($hdr, 'List-Archive', "<$url>");
 496         }
 497 }
 498
 499 sub art_lookup ($$$) {
 500         my ($self, $art, $code) = @_;
 501         my ($ibx, $n);
 502         my $err;
 503         if (defined $art) {
 504                 if ($art =~ /\A[0-9]+\z/) {
 505                         $err = '423 no such article number in this group';
 506                         $n = int($art);
 507                         goto find_ibx;
 508                 } elsif ($art =~ $ONE_MSGID) {
 509                         ($ibx, $n) = mid_lookup($self, $1);
 510                         goto found if $ibx;
 511                         return r430;
 512                 } else {
 513                         return r501;
 514                 }
 515         } else {
 516                 $err = '420 no current article has been selected';
 517                 $n = $self->{article} // return $err;
 518 find_ibx:
 519                 $ibx = $self->{ng} or
 520                                 return '412 no newsgroup has been selected';
 521         }
 522 found:
 523         my $smsg = $ibx->over->get_art($n) or return $err;
 524         $smsg->{-ibx} = $ibx;
 525         if ($code == 223) { # STAT
 526                 set_art($self, $n);
 527                 "223 $n <$smsg->{mid}> article retrieved - " .
 528                         "request text separately";
 529         } else { # HEAD | BODY | ARTICLE
 530                 $smsg->{nntp} = $self;
 531                 $smsg->{nntp_code} = $code;
 532                 set_art($self, $art);
 533                 # this dereferences to `undef'
 534                 ${git_async_cat($ibx->git, $smsg->{blob}, \&blob_cb, $smsg)};
 535         }
 536 }
 537
 538 sub msg_body_write ($$) {
 539         my ($self, $msg) = @_;
 540
 541         # these can momentarily double the memory consumption :<
 542         $$msg =~ s/^\./../smg;
 543         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 544         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 545         $self->msg_more($$msg);
 546 }
 547
 548 sub set_art {
 549         my ($self, $art) = @_;
 550         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 551 }
 552
 553 sub msg_hdr_write ($$) {
 554         my ($eml, $smsg) = @_;
 555         set_nntp_headers($eml, $smsg);
 556
 557         my $hdr = $eml->{hdr} // \(my $x = '');
 558         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 559         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 560         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 561
 562         # for leafnode compatibility, we need to ensure Message-ID headers
 563         # are only a single line.
 564         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 565         $smsg->{nntp}->msg_more($$hdr);
 566 }
 567
 568 sub blob_cb { # called by git->cat_async via git_async_cat
 569         my ($bref, $oid, $type, $size, $smsg) = @_;
 570         my $self = $smsg->{nntp};
 571         my $code = $smsg->{nntp_code};
 572         if (!defined($oid)) {
 573                 # it's possible to have TOCTOU if an admin runs
 574                 # public-inbox-(edit|purge), just move onto the next message
 575                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 576                 return $self->requeue;
 577         } elsif ($smsg->{blob} ne $oid) {
 578                 $self->close;
 579                 die "BUG: $smsg->{blob} != $oid";
 580         }
 581         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 582         my $eml = PublicInbox::Eml->new($bref);
 583         if ($code == 220) {
 584                 more($self, $r .= 'head and body follow');
 585                 msg_hdr_write($eml, $smsg);
 586                 $self->msg_more("\r\n");
 587                 msg_body_write($self, $bref);
 588         } elsif ($code == 221) {
 589                 more($self, $r .= 'head follows');
 590                 msg_hdr_write($eml, $smsg);
 591         } elsif ($code == 222) {
 592                 more($self, $r .= 'body follows');
 593                 msg_body_write($self, $bref);
 594         } else {
 595                 $self->close;
 596                 die "BUG: bad code: $r";
 597         }
 598         $self->write(\".\r\n"); # flushes (includes ->zflush)
 599         $self->requeue;
 600 }
 601
 602 sub cmd_article ($;$) {
 603         my ($self, $art) = @_;
 604         art_lookup($self, $art, 220);
 605 }
 606
 607 sub cmd_head ($;$) {
 608         my ($self, $art) = @_;
 609         art_lookup($self, $art, 221);
 610 }
 611
 612 sub cmd_body ($;$) {
 613         my ($self, $art) = @_;
 614         art_lookup($self, $art, 222);
 615 }
 616
 617 sub cmd_stat ($;$) {
 618         my ($self, $art) = @_;
 619         art_lookup($self, $art, 223); # art may be msgid
 620 }
 621
 622 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 623
 624 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 625
 626 sub cmd_help ($) {
 627         my ($self) = @_;
 628         more($self, '100 help text follows');
 629         '.'
 630 }
 631
 632 sub get_range ($$) {
 633         my ($self, $range) = @_;
 634         my $ng = $self->{ng} or return '412 no news group has been selected';
 635         defined $range or return '420 No article(s) selected';
 636         my ($beg, $end);
 637         my ($min, $max) = $ng->mm->minmax;
 638         if ($range =~ /\A([0-9]+)\z/) {
 639                 $beg = $end = $1;
 640         } elsif ($range =~ /\A([0-9]+)-\z/) {
 641                 ($beg, $end) = ($1, $max);
 642         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 643                 ($beg, $end) = ($1, $2);
 644         } else {
 645                 return r501;
 646         }
 647         $beg = $min if ($beg < $min);
 648         $end = $max if ($end > $max);
 649         return '420 No article(s) selected' if ($beg > $end);
 650         [ \$beg, $end ];
 651 }
 652
 653 sub long_step {
 654         my ($self) = @_;
 655         # wbuf is unset or empty, here; {long} may add to it
 656         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 657         my $more = eval { $cb->($self, @args) };
 658         if ($@ || !$self->{sock}) { # something bad happened...
 659                 delete $self->{long_cb};
 660                 my $elapsed = now() - $t0;
 661                 if ($@) {
 662                         err($self,
 663                             "%s during long response[$fd] - %0.6f",
 664                             $@, $elapsed);
 665                 }
 666                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 667                 $self->close;
 668         } elsif ($more) { # $self->{wbuf}:
 669                 $self->update_idle_time;
 670
 671                 # COMPRESS users all share the same DEFLATE context.
 672                 # Flush it here to ensure clients don't see
 673                 # each other's data
 674                 $self->zflush;
 675
 676                 # no recursion, schedule another call ASAP, but only after
 677                 # all pending writes are done.  autovivify wbuf:
 678                 my $new_size = push(@{$self->{wbuf}}, \&long_step);
 679
 680                 # wbuf may be populated by $cb, no need to rearm if so:
 681                 $self->requeue if $new_size == 1;
 682         } else { # all done!
 683                 delete $self->{long_cb};
 684                 res($self, '.');
 685                 my $elapsed = now() - $t0;
 686                 my $fd = fileno($self->{sock});
 687                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 688                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 689                 $self->requeue unless $wbuf && @$wbuf;
 690         }
 691 }
 692
 693 sub long_response ($$;@) {
 694         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 695
 696         my $sock = $self->{sock} or return;
 697         # make sure we disable reading during a long response,
 698         # clients should not be sending us stuff and making us do more
 699         # work while we are stream a response to them
 700         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 701         long_step($self); # kick off!
 702         undef;
 703 }
 704
 705 sub hdr_msgid_range_i {
 706         my ($self, $beg, $end) = @_;
 707         my $r = $self->{ng}->mm->msg_range($beg, $end);
 708         @$r or return;
 709         $self->msg_more(join('', map { "$_->[0] <$_->[1]>\r\n" } @$r));
 710         1;
 711 }
 712
 713 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 714         my ($self, $xhdr, $range) = @_;
 715
 716         if (defined $range && $range =~ $ONE_MSGID) {
 717                 my ($ng, $n) = mid_lookup($self, $1);
 718                 return r430 unless $n;
 719                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 720         } else { # numeric range
 721                 $range = $self->{article} unless defined $range;
 722                 my $r = get_range($self, $range);
 723                 return $r unless ref $r;
 724                 more($self, $xhdr ? r221 : r225);
 725                 long_response($self, \&hdr_msgid_range_i, @$r);
 726         }
 727 }
 728
 729 sub mid_lookup ($$) {
 730         my ($self, $mid) = @_;
 731         my $self_ng = $self->{ng};
 732         if ($self_ng) {
 733                 my $n = $self_ng->mm->num_for($mid);
 734                 return ($self_ng, $n) if defined $n;
 735         }
 736         my $pi_cfg = $self->{nntpd}->{pi_config};
 737         if (my $ALL = $pi_cfg->ALL) {
 738                 my ($id, $prev);
 739                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 740                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 741                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 742                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 743                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 744                                 return ($ibx, $xnum) if $ibx;
 745                                 # fall through to trying all xref3s
 746                         } else {
 747                                 warn <<EOF;
 748 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 749 EOF
 750                         }
 751                         # try all xref3s
 752                         for my $x (@$xr3) {
 753                                 my ($ngname, $xnum) = split(/:/, $x);
 754                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 755                                 return ($ibx, $xnum) if $ibx;
 756                                 warn "W: `$ngname' does not exist for #$xnum\n";
 757                         }
 758                 }
 759                 # no warning here, $mid is just invalid
 760         } else { # slow path for non-ALL users
 761                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 762                         next if defined $self_ng && $ibx eq $self_ng;
 763                         my $n = $ibx->mm->num_for($mid);
 764                         return ($ibx, $n) if defined $n;
 765                 }
 766         }
 767         (undef, undef);
 768 }
 769
 770 sub xref_range_i {
 771         my ($self, $beg, $end) = @_;
 772         my $ng = $self->{ng};
 773         my $msgs = $ng->over->query_xover($$beg, $end);
 774         scalar(@$msgs) or return;
 775         $$beg = $msgs->[-1]->{num} + 1;
 776         $self->msg_more(join('', map {
 777                 "$_->{num} ".xref($self, $ng, $_) . "\r\n";
 778         } @$msgs));
 779         1;
 780 }
 781
 782 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 783         my ($self, $xhdr, $range) = @_;
 784
 785         if (defined $range && $range =~ $ONE_MSGID) {
 786                 my $mid = $1;
 787                 my ($ng, $n) = mid_lookup($self, $mid);
 788                 return r430 unless $n;
 789                 my $smsg = $ng->over->get_art($n) or return;
 790                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 791                                 xref($self, $ng, $smsg));
 792         } else { # numeric range
 793                 $range = $self->{article} unless defined $range;
 794                 my $r = get_range($self, $range);
 795                 return $r unless ref $r;
 796                 more($self, $xhdr ? r221 : r225);
 797                 long_response($self, \&xref_range_i, @$r);
 798         }
 799 }
 800
 801 sub over_header_for {
 802         my ($over, $num, $field) = @_;
 803         my $smsg = $over->get_art($num) or return;
 804         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 805         $smsg->{$field};
 806 }
 807
 808 sub smsg_range_i {
 809         my ($self, $beg, $end, $field) = @_;
 810         my $over = $self->{ng}->over;
 811         my $msgs = $over->query_xover($$beg, $end);
 812         scalar(@$msgs) or return;
 813         my $tmp = '';
 814
 815         # ->{$field} is faster than ->$field invocations, so favor that.
 816         if ($field eq 'date') {
 817                 for my $s (@$msgs) {
 818                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 819                 }
 820         } else {
 821                 for my $s (@$msgs) {
 822                         $tmp .= "$s->{num} $s->{$field}\r\n";
 823                 }
 824         }
 825         utf8::encode($tmp);
 826         $self->msg_more($tmp);
 827         $$beg = $msgs->[-1]->{num} + 1;
 828 }
 829
 830 sub hdr_smsg ($$$$) {
 831         my ($self, $xhdr, $field, $range) = @_;
 832         if (defined $range && $range =~ $ONE_MSGID) {
 833                 my ($ng, $n) = mid_lookup($self, $1);
 834                 return r430 unless defined $n;
 835                 my $v = over_header_for($ng->over, $n, $field);
 836                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 837         } else { # numeric range
 838                 $range = $self->{article} unless defined $range;
 839                 my $r = get_range($self, $range);
 840                 return $r unless ref $r;
 841                 more($self, $xhdr ? r221 : r225);
 842                 long_response($self, \&smsg_range_i, @$r, $field);
 843         }
 844 }
 845
 846 sub do_hdr ($$$;$) {
 847         my ($self, $xhdr, $header, $range) = @_;
 848         my $sub = lc $header;
 849         if ($sub eq 'message-id') {
 850                 hdr_message_id($self, $xhdr, $range);
 851         } elsif ($sub eq 'xref') {
 852                 hdr_xref($self, $xhdr, $range);
 853         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 854                                 bytes|lines)\z/x) {
 855                 hdr_smsg($self, $xhdr, $sub, $range);
 856         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 857                 hdr_smsg($self, $xhdr, $1, $range);
 858         } else {
 859                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 860         }
 861 }
 862
 863 # RFC 3977
 864 sub cmd_hdr ($$;$) {
 865         my ($self, $header, $range) = @_;
 866         do_hdr($self, 0, $header, $range);
 867 }
 868
 869 # RFC 2980
 870 sub cmd_xhdr ($$;$) {
 871         my ($self, $header, $range) = @_;
 872         do_hdr($self, 1, $header, $range);
 873 }
 874
 875 sub hdr_mid_prefix ($$$$$) {
 876         my ($self, $xhdr, $ng, $n, $mid) = @_;
 877         return $mid if $xhdr;
 878
 879         # HDR for RFC 3977 users
 880         if (my $self_ng = $self->{ng}) {
 881                 ($self_ng eq $ng) ? $n : '0';
 882         } else {
 883                 '0';
 884         }
 885 }
 886
 887 sub hdr_mid_response ($$$$$$) {
 888         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 889         my $res = '';
 890         if ($xhdr) {
 891                 $res .= r221 . "\r\n";
 892                 $res .= "$mid $v\r\n";
 893         } else {
 894                 $res .= r225 . "\r\n";
 895                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 896                 $res .= "$pfx $v\r\n";
 897         }
 898         res($self, $res .= '.');
 899         undef;
 900 }
 901
 902 sub xrover_i {
 903         my ($self, $beg, $end) = @_;
 904         my $h = over_header_for($self->{ng}->over, $$beg, 'references');
 905         more($self, "$$beg $h") if defined($h);
 906         $$beg++ < $end;
 907 }
 908
 909 sub cmd_xrover ($;$) {
 910         my ($self, $range) = @_;
 911         my $ng = $self->{ng} or return '412 no newsgroup selected';
 912         (defined $range && $range =~ /[<>]/) and
 913                 return '420 No article(s) selected'; # no message IDs
 914
 915         $range = $self->{article} unless defined $range;
 916         my $r = get_range($self, $range);
 917         return $r unless ref $r;
 918         more($self, '224 Overview information follows');
 919         long_response($self, \&xrover_i, @$r);
 920 }
 921
 922 sub over_line ($$$) {
 923         my ($self, $ng, $smsg) = @_;
 924         # n.b. field access and procedural calls can be
 925         # 10%-15% faster than OO method calls:
 926         my $s = join("\t", $smsg->{num},
 927                 $smsg->{subject},
 928                 $smsg->{from},
 929                 PublicInbox::Smsg::date($smsg),
 930                 "<$smsg->{mid}>",
 931                 $smsg->{references},
 932                 $smsg->{bytes},
 933                 $smsg->{lines},
 934                 "Xref: " . xref($self, $ng, $smsg));
 935         utf8::encode($s);
 936         $s .= "\r\n";
 937 }
 938
 939 sub cmd_over ($;$) {
 940         my ($self, $range) = @_;
 941         if ($range && $range =~ $ONE_MSGID) {
 942                 my ($ng, $n) = mid_lookup($self, $1);
 943                 defined $n or return r430;
 944                 my $smsg = $ng->over->get_art($n) or return r430;
 945                 more($self, '224 Overview information follows (multi-line)');
 946
 947                 # Only set article number column if it's the current group
 948                 # (RFC 3977 8.3.2)
 949                 my $self_ng = $self->{ng};
 950                 if (!$self_ng || $self_ng ne $ng) {
 951                         # set {-orig_num} for nntp_xref_for
 952                         $smsg->{-orig_num} = $smsg->{num};
 953                         $smsg->{num} = 0;
 954                 }
 955                 $self->msg_more(over_line($self, $ng, $smsg));
 956                 '.';
 957         } else {
 958                 cmd_xover($self, $range);
 959         }
 960 }
 961
 962 sub xover_i {
 963         my ($self, $beg, $end) = @_;
 964         my $ng = $self->{ng};
 965         my $msgs = $ng->over->query_xover($$beg, $end);
 966         my $nr = scalar @$msgs or return;
 967
 968         # OVERVIEW.FMT
 969         $self->msg_more(join('', map {
 970                 over_line($self, $ng, $_);
 971                 } @$msgs));
 972         $$beg = $msgs->[-1]->{num} + 1;
 973 }
 974
 975 sub cmd_xover ($;$) {
 976         my ($self, $range) = @_;
 977         $range = $self->{article} unless defined $range;
 978         my $r = get_range($self, $range);
 979         return $r unless ref $r;
 980         my ($beg, $end) = @$r;
 981         more($self, "224 Overview information follows for $$beg to $end");
 982         long_response($self, \&xover_i, @$r);
 983 }
 984
 985 sub compressed { undef }
 986
 987 sub cmd_starttls ($) {
 988         my ($self) = @_;
 989         my $sock = $self->{sock} or return;
 990         # RFC 4642 2.2.1
 991         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 992         my $opt = $self->{nntpd}->{accept_tls} or
 993                 return '580 can not initiate TLS negotiation';
 994         res($self, '382 Continue with TLS negotiation');
 995         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 996         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 997         undef;
 998 }
 999
1000 # RFC 8054
1001 sub cmd_compress ($$) {
1002         my ($self, $alg) = @_;
1003         return '503 Only DEFLATE is supported' if uc($alg) ne 'DEFLATE';
1004         return r502 if $self->compressed;
1005         PublicInbox::NNTPdeflate->enable($self);
1006         $self->requeue;
1007         undef
1008 }
1009
1010 sub zflush {} # overridden by NNTPdeflate
1011
1012 sub cmd_xpath ($$) {
1013         my ($self, $mid) = @_;
1014         return r501 unless $mid =~ $ONE_MSGID;
1015         $mid = $1;
1016         my @paths;
1017         my $pi_cfg = $self->{nntpd}->{pi_config};
1018         my $groups = $pi_cfg->{-by_newsgroup};
1019         if (my $ALL = $pi_cfg->ALL) {
1020                 my ($id, $prev, %seen);
1021                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
1022                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
1023                         for my $x (@$xr3) {
1024                                 my ($ngname, $n) = split(/:/, $x);
1025                                 $x = "$ngname/$n";
1026                                 if ($groups->{$ngname} && !$seen{$x}++) {
1027                                         push(@paths, $x);
1028                                 }
1029                         }
1030                 }
1031         } else { # slow path, no point in using long_response
1032                 for my $ibx (values %$groups) {
1033                         my $n = $ibx->mm->num_for($mid) // next;
1034                         push @paths, "$ibx->{newsgroup}/$n";
1035                 }
1036         }
1037         return '430 no such article on server' unless @paths;
1038         '223 '.join(' ', sort(@paths));
1039 }
1040
1041 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
1042
1043 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
1044
1045 sub do_write ($$) {
1046         my $self = $_[0];
1047         my $done = $self->write(\($_[1]));
1048         return 0 unless $self->{sock};
1049
1050         $done;
1051 }
1052
1053 sub err ($$;@) {
1054         my ($self, $fmt, @args) = @_;
1055         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
1056 }
1057
1058 sub out ($$;@) {
1059         my ($self, $fmt, @args) = @_;
1060         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
1061 }
1062
1063 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
1064 sub event_step {
1065         my ($self) = @_;
1066
1067         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
1068
1069         $self->update_idle_time;
1070         # only read more requests if we've drained the write buffer,
1071         # otherwise we can be buffering infinitely w/o backpressure
1072
1073         my $rbuf = $self->{rbuf} // \(my $x = '');
1074         my $line = index($$rbuf, "\n");
1075         while ($line < 0) {
1076                 return $self->close if length($$rbuf) >= LINE_MAX;
1077                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1078                 $line = index($$rbuf, "\n");
1079         }
1080         $line = substr($$rbuf, 0, $line + 1, '');
1081         $line =~ s/\r?\n\z//s;
1082         return $self->close if $line =~ /[[:cntrl:]]/s;
1083
1084         my $t0 = now();
1085         my $fd = fileno($self->{sock});
1086         my $r = eval { process_line($self, $line) };
1087         my $pending = $self->{wbuf} ? ' pending' : '';
1088         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1089         return $self->close if $r < 0;
1090         $self->rbuf_idle($rbuf);
1091         $self->update_idle_time;
1092
1093         # maybe there's more pipelined data, or we'll have
1094         # to register it for socket-readiness notifications
1095         $self->requeue unless $pending;
1096 }
1097
1098 # for graceful shutdown in PublicInbox::Daemon:
1099 sub busy {
1100         my ($self, $now) = @_;
1101         ($self->{rbuf} || $self->{wbuf} || $self->not_idle_long($now));
1102 }
1103
1104 1;