lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(Danga::Socket);
   9 use fields qw(nntpd article rbuf ng long_res);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::Git;
  13 use PublicInbox::MID qw(mid2path);
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  18 use URI::Escape qw(uri_escape_utf8);
  19 use Encode qw(find_encoding);
  20 my $enc_utf8 = find_encoding('UTF-8');
  21 use constant {
  22         r501 => '501 command syntax error',
  23         r221 => '221 Header follows',
  24         r224 => '224 Overview information follows (multi-line)',
  25         r225 => '225 Headers follow (multi-line)',
  26         r430 => '430 No article with that message-id',
  27         long_response_limit => 0xffffffff,
  28 };
  29
  30 sub now () { clock_gettime(CLOCK_MONOTONIC) };
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36
  37 # disable commands with easy DoS potential:
  38 # LISTGROUP could get pretty bad, too...
  39 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  40
  41 my $EXPMAP; # fd -> [ idle_time, $self ]
  42 my $expt;
  43 our $EXPTIME = 180; # 3 minutes
  44 my $WEAKEN = {}; # string(nntpd) -> nntpd
  45 my $weakt;
  46 my $nextt;
  47
  48 my $nextq = [];
  49 sub next_tick () {
  50         $nextt = undef;
  51         my $q = $nextq;
  52         $nextq = [];
  53         foreach my $nntp (@$q) {
  54                 # for request && response protocols, always finish writing
  55                 # before finishing reading:
  56                 if (my $long_cb = $nntp->{long_res}) {
  57                         $nntp->write($long_cb);
  58                 } elsif (&Danga::Socket::POLLIN & $nntp->{event_watch}) {
  59                         event_read($nntp);
  60                 }
  61         }
  62 }
  63
  64 sub update_idle_time ($) {
  65         my ($self) = @_;
  66         my $tmp = $self->{sock} or return;
  67         $tmp = fileno($tmp);
  68         defined $tmp and $EXPMAP->{$tmp} = [ now(), $self ];
  69 }
  70
  71 # reduce FD pressure by closing some "git cat-file --batch" processes
  72 # and unused FDs for msgmap and Xapian indices
  73 sub weaken_groups () {
  74         $weakt = undef;
  75         foreach my $nntpd (values %$WEAKEN) {
  76                 $_->weaken_all foreach (@{$nntpd->{grouplist}});
  77         }
  78         $WEAKEN = {};
  79 }
  80
  81 sub expire_old () {
  82         my $now = now();
  83         my $exp = $EXPTIME;
  84         my $old = $now - $exp;
  85         my $nr = 0;
  86         my %new;
  87         while (my ($fd, $v) = each %$EXPMAP) {
  88                 my ($idle_time, $nntp) = @$v;
  89                 if ($idle_time < $old) {
  90                         $nntp->close; # idempotent
  91                 } else {
  92                         ++$nr;
  93                         $new{$fd} = $v;
  94                 }
  95         }
  96         $EXPMAP = \%new;
  97         if ($nr) {
  98                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  99                 weaken_groups();
 100         } else {
 101                 $expt = undef;
 102                 # noop to kick outselves out of the loop ASAP so descriptors
 103                 # really get closed
 104                 PublicInbox::EvCleanup::asap(sub {});
 105
 106                 # grace period for reaping resources
 107                 $weakt ||= PublicInbox::EvCleanup::later(*weaken_groups);
 108         }
 109 }
 110
 111 sub new ($$$) {
 112         my ($class, $sock, $nntpd) = @_;
 113         my $self = fields::new($class);
 114         $self->SUPER::new($sock);
 115         $self->{nntpd} = $nntpd;
 116         res($self, '201 server ready - post via email');
 117         $self->{rbuf} = '';
 118         $self->watch_read(1);
 119         update_idle_time($self);
 120         $WEAKEN->{"$nntpd"} = $nntpd;
 121         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 122         $self;
 123 }
 124
 125 sub args_ok ($$) {
 126         my ($cb, $argc) = @_;
 127         my $tot = prototype $cb;
 128         my ($nreq, undef) = split(';', $tot);
 129         $nreq = ($nreq =~ tr/$//) - 1;
 130         $tot = ($tot =~ tr/$//) - 1;
 131         ($argc <= $tot && $argc >= $nreq);
 132 }
 133
 134 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 135 sub process_line ($$) {
 136         my ($self, $l) = @_;
 137         my ($req, @args) = split(/\s+/, $l);
 138         $req = lc($req);
 139         $req = eval {
 140                 no strict 'refs';
 141                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 142         };
 143         return res($self, '500 command not recognized') unless $req;
 144         return res($self, r501) unless args_ok($req, scalar @args);
 145
 146         my $res = eval { $req->($self, @args) };
 147         my $err = $@;
 148         if ($err && !$self->{closed}) {
 149                 chomp($l);
 150                 err($self, 'error from: %s (%s)', $l, $err);
 151                 $res = '503 program fault - command not performed';
 152         }
 153         return 0 unless defined $res;
 154         res($self, $res);
 155 }
 156
 157 sub cmd_mode ($$) {
 158         my ($self, $arg) = @_;
 159         $arg = uc $arg;
 160         return r501 unless $arg eq 'READER';
 161         '201 Posting prohibited';
 162 }
 163
 164 sub cmd_slave ($) { '202 slave status noted' }
 165
 166 sub cmd_xgtitle ($;$) {
 167         my ($self, $wildmat) = @_;
 168         more($self, '282 list of groups and descriptions follows');
 169         list_newsgroups($self, $wildmat);
 170         '.'
 171 }
 172
 173 sub list_overview_fmt ($) {
 174         my ($self) = @_;
 175         do_more($self, $OVERVIEW_FMT);
 176 }
 177
 178 sub list_headers ($;$) {
 179         my ($self) = @_;
 180         do_more($self, $LIST_HEADERS);
 181 }
 182
 183 sub list_active ($;$) {
 184         my ($self, $wildmat) = @_;
 185         wildmat2re($wildmat);
 186         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 187                 $ng->{newsgroup} =~ $wildmat or next;
 188                 group_line($self, $ng);
 189         }
 190 }
 191
 192 sub list_active_times ($;$) {
 193         my ($self, $wildmat) = @_;
 194         wildmat2re($wildmat);
 195         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 196                 $ng->{newsgroup} =~ $wildmat or next;
 197                 my $c = eval { $ng->mm->created_at } || time;
 198                 more($self, "$ng->{newsgroup} $c $ng->{address}");
 199         }
 200 }
 201
 202 sub list_newsgroups ($;$) {
 203         my ($self, $wildmat) = @_;
 204         wildmat2re($wildmat);
 205         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 206                 $ng->{newsgroup} =~ $wildmat or next;
 207                 my $d = $ng->description;
 208                 more($self, "$ng->{newsgroup} $d");
 209         }
 210 }
 211
 212 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 213 sub cmd_list ($;$$) {
 214         my ($self, @args) = @_;
 215         if (scalar @args) {
 216                 my $arg = shift @args;
 217                 $arg =~ tr/A-Z./a-z_/;
 218                 $arg = "list_$arg";
 219                 return r501 if $DISABLED{$arg};
 220
 221                 $arg = eval {
 222                         no strict 'refs';
 223                         *{$arg}{CODE};
 224                 };
 225                 return r501 unless $arg && args_ok($arg, scalar @args);
 226                 more($self, '215 information follows');
 227                 $arg->($self, @args);
 228         } else {
 229                 more($self, '215 list of newsgroups follows');
 230                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 231                         group_line($self, $ng);
 232                 }
 233         }
 234         '.'
 235 }
 236
 237 sub cmd_listgroup ($;$) {
 238         my ($self, $group) = @_;
 239         if (defined $group) {
 240                 my $res = cmd_group($self, $group);
 241                 return $res if ($res !~ /\A211 /);
 242                 more($self, $res);
 243         }
 244
 245         $self->{ng} or return '412 no newsgroup selected';
 246         long_response($self, 0, long_response_limit, sub {
 247                 my ($i) = @_;
 248                 my $nr = $self->{ng}->mm->id_batch($$i, sub {
 249                         my ($ary) = @_;
 250                         more($self, join("\r\n", @$ary));
 251                 });
 252
 253                 # -1 to adjust for implicit increment in long_response
 254                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 255         });
 256 }
 257
 258 sub parse_time ($$;$) {
 259         my ($date, $time, $gmt) = @_;
 260         use Time::Local qw();
 261         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 262         if (defined $gmt) {
 263                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 264                 $gmt = 1;
 265         }
 266         my @now = $gmt ? gmtime : localtime;
 267         my ($YYYY, $MM, $DD);
 268         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 269                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 270         } else { # legacy clients send YYMMDD
 271                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 272                 if ($YYYY > strftime('%y', @now)) {
 273                         my $cur_year = $now[5] + 1900;
 274                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 275                 }
 276         }
 277         if ($gmt) {
 278                 Time::Local::timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 279         } else {
 280                 Time::Local::timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 281         }
 282 }
 283
 284 sub group_line ($$) {
 285         my ($self, $ng) = @_;
 286         my ($min, $max) = $ng->mm->minmax;
 287         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 288 }
 289
 290 sub cmd_newgroups ($$$;$$) {
 291         my ($self, $date, $time, $gmt, $dists) = @_;
 292         my $ts = eval { parse_time($date, $time, $gmt) };
 293         return r501 if $@;
 294
 295         # TODO dists
 296         more($self, '231 list of new newsgroups follows');
 297         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 298                 my $c = eval { $ng->mm->created_at } || 0;
 299                 next unless $c > $ts;
 300                 group_line($self, $ng);
 301         }
 302         '.'
 303 }
 304
 305 sub wildmat2re (;$) {
 306         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 307         my %keep;
 308         my $salt = rand;
 309         use Digest::SHA qw(sha1_hex);
 310         my $tmp = $_[0];
 311
 312         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 313                 my $orig = $1;
 314                 my $key = sha1_hex($orig . $salt);
 315                 $orig =~ s/([^\w\-])+/\Q$1/g;
 316                 $keep{$key} = $orig;
 317                 $key
 318                 #gex;
 319         my %map = ('*' => '.*', '?' => '.' );
 320         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 321         if (scalar %keep) {
 322                 $tmp =~ s#([a-f0-9]{40})#
 323                         my $orig = $keep{$1};
 324                         defined $orig ? $orig : $1;
 325                         #ge;
 326         }
 327         $_[0] = qr/\A$tmp\z/;
 328 }
 329
 330 sub ngpat2re (;$) {
 331         return $_[0] = qr/\A\z/ unless defined $_[0];
 332         my %map = ('*' => '.*', ',' => '|');
 333         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 334         $_[0] = qr/\A(?:$_[0])\z/;
 335 }
 336
 337 sub cmd_newnews ($$$$;$$) {
 338         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 339         my $ts = eval { parse_time($date, $time, $gmt) };
 340         return r501 if $@;
 341         more($self, '230 list of new articles by message-id follows');
 342         my ($keep, $skip) = split('!', $newsgroups, 2);
 343         ngpat2re($keep);
 344         ngpat2re($skip);
 345         my @srch;
 346         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 347                 $ng->{newsgroup} =~ $keep or next;
 348                 $ng->{newsgroup} =~ $skip and next;
 349                 my $srch = $ng->search or next;
 350                 push @srch, $srch;
 351         };
 352         return '.' unless @srch;
 353
 354         $ts .= '..';
 355         my $opts = { asc => 1, limit => 1000, offset => 0 };
 356         long_response($self, 0, long_response_limit, sub {
 357                 my ($i) = @_;
 358                 my $srch = $srch[0];
 359                 my $res = $srch->query($ts, $opts);
 360                 my $msgs = $res->{msgs};
 361                 if (my $nr = scalar @$msgs) {
 362                         more($self, '<' .
 363                                 join(">\r\n<", map { $_->mid } @$msgs ).
 364                                 '>');
 365                         $opts->{offset} += $nr;
 366                 } else {
 367                         shift @srch;
 368                         if (@srch) { # continue onto next newsgroup
 369                                 $opts->{offset} = 0;
 370                         } else { # break out of the long response.
 371                                 $$i = long_response_limit;
 372                         }
 373                 }
 374         });
 375 }
 376
 377 sub cmd_group ($$) {
 378         my ($self, $group) = @_;
 379         my $no_such = '411 no such news group';
 380         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 381
 382         $self->{ng} = $ng;
 383         my ($min, $max) = $ng->mm->minmax;
 384         $min ||= 0;
 385         $max ||= 0;
 386         $self->{article} = $min;
 387         my $est_size = $max - $min;
 388         "211 $est_size $min $max $group";
 389 }
 390
 391 sub article_adj ($$) {
 392         my ($self, $off) = @_;
 393         my $ng = $self->{ng} or return '412 no newsgroup selected';
 394
 395         my $n = $self->{article};
 396         defined $n or return '420 no current article has been selected';
 397
 398         $n += $off;
 399         my $mid = $ng->mm->mid_for($n);
 400         unless ($mid) {
 401                 $n = $off > 0 ? 'next' : 'previous';
 402                 return "421 no $n article in this group";
 403         }
 404         $self->{article} = $n;
 405         "223 $n <$mid> article retrieved - request text separately";
 406 }
 407
 408 sub cmd_next ($) { article_adj($_[0], 1) }
 409 sub cmd_last ($) { article_adj($_[0], -1) }
 410
 411 # We want to encourage using email and CC-ing everybody involved to avoid
 412 # the single-point-of-failure a single server provides.
 413 sub cmd_post ($) {
 414         my ($self) = @_;
 415         my $ng = $self->{ng};
 416         $ng ? "440 mailto:$ng->{address} to post" : '440 posting not allowed'
 417 }
 418
 419 sub cmd_quit ($) {
 420         my ($self) = @_;
 421         res($self, '205 closing connection - goodbye!');
 422         $self->close;
 423         undef;
 424 }
 425
 426 sub header_append ($$$) {
 427         my ($hdr, $k, $v) = @_;
 428         my @v = $hdr->header($k);
 429         foreach (@v) {
 430                 return if $v eq $_;
 431         }
 432         $hdr->header_set($k, @v, $v);
 433 }
 434
 435 sub set_nntp_headers {
 436         my ($hdr, $ng, $n, $mid) = @_;
 437
 438         # clobber some
 439         $hdr->header_set('Newsgroups', $ng->{newsgroup});
 440         $hdr->header_set('Xref', xref($ng, $n));
 441         header_append($hdr, 'List-Post', "<mailto:$ng->{address}>");
 442         if (my $url = $ng->{url}) {
 443                 $mid = uri_escape_utf8($mid);
 444                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 445                 header_append($hdr, 'List-Archive', "<$url>");
 446         }
 447 }
 448
 449 sub art_lookup ($$$) {
 450         my ($self, $art, $set_headers) = @_;
 451         my $ng = $self->{ng};
 452         my ($n, $mid);
 453         my $err;
 454         if (defined $art) {
 455                 if ($art =~ /\A\d+\z/o) {
 456                         $err = '423 no such article number in this group';
 457                         $n = int($art);
 458                         goto find_mid;
 459                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 460                         $mid = $1;
 461                         $err = r430;
 462                         $n = $ng->mm->num_for($mid) if $ng;
 463                         goto found if defined $n;
 464                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 465                                 $n = $g->mm->num_for($mid);
 466                                 if (defined $n) {
 467                                         $ng = $g;
 468                                         goto found;
 469                                 }
 470                         }
 471                         return $err;
 472                 } else {
 473                         return r501;
 474                 }
 475         } else {
 476                 $err = '420 no current article has been selected';
 477                 $n = $self->{article};
 478                 defined $n or return $err;
 479 find_mid:
 480                 $ng or return '412 no newsgroup has been selected';
 481                 $mid = $ng->mm->mid_for($n);
 482                 defined $mid or return $err;
 483         }
 484 found:
 485         my $o = 'HEAD:' . mid2path($mid);
 486         my $bytes;
 487         my $s = eval { Email::Simple->new($ng->gcf->cat_file($o, \$bytes)) };
 488         return $err unless $s;
 489         my $lines;
 490         if ($set_headers) {
 491                 set_nntp_headers($s->header_obj, $ng, $n, $mid);
 492                 $lines = $s->body =~ tr!\n!\n!;
 493
 494                 # must be last
 495                 $s->body_set('') if ($set_headers == 2);
 496         }
 497         [ $n, $mid, $s, $bytes, $lines, $ng ];
 498 }
 499
 500 sub simple_body_write ($$) {
 501         my ($self, $s) = @_;
 502         my $body = $s->body;
 503         $s->body_set('');
 504         $body =~ s/^\./../smg;
 505         $body =~ s/(?<!\r)\n/\r\n/sg;
 506         do_more($self, $body);
 507         do_more($self, "\r\n") unless $body =~ /\r\n\z/s;
 508         '.'
 509 }
 510
 511 sub set_art {
 512         my ($self, $art) = @_;
 513         $self->{article} = $art if defined $art && $art =~ /\A\d+\z/;
 514 }
 515
 516 sub cmd_article ($;$) {
 517         my ($self, $art) = @_;
 518         my $r = art_lookup($self, $art, 1);
 519         return $r unless ref $r;
 520         my ($n, $mid, $s) = @$r;
 521         set_art($self, $art);
 522         more($self, "220 $n <$mid> article retrieved - head and body follow");
 523         do_more($self, $s->header_obj->as_string);
 524         do_more($self, "\r\n");
 525         simple_body_write($self, $s);
 526 }
 527
 528 sub cmd_head ($;$) {
 529         my ($self, $art) = @_;
 530         my $r = art_lookup($self, $art, 2);
 531         return $r unless ref $r;
 532         my ($n, $mid, $s) = @$r;
 533         set_art($self, $art);
 534         more($self, "221 $n <$mid> article retrieved - head follows");
 535         do_more($self, $s->header_obj->as_string);
 536         '.'
 537 }
 538
 539 sub cmd_body ($;$) {
 540         my ($self, $art) = @_;
 541         my $r = art_lookup($self, $art, 0);
 542         return $r unless ref $r;
 543         my ($n, $mid, $s) = @$r;
 544         set_art($self, $art);
 545         more($self, "222 $n <$mid> article retrieved - body follows");
 546         simple_body_write($self, $s);
 547 }
 548
 549 sub cmd_stat ($;$) {
 550         my ($self, $art) = @_;
 551         my $r = art_lookup($self, $art, 0);
 552         return $r unless ref $r;
 553         my ($n, $mid, undef) = @$r;
 554         set_art($self, $art);
 555         "223 $n <$mid> article retrieved - request text separately";
 556 }
 557
 558 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 559
 560 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 561
 562 sub cmd_help ($) {
 563         my ($self) = @_;
 564         more($self, '100 help text follows');
 565         '.'
 566 }
 567
 568 sub get_range ($$) {
 569         my ($self, $range) = @_;
 570         my $ng = $self->{ng} or return '412 no news group has been selected';
 571         defined $range or return '420 No article(s) selected';
 572         my ($beg, $end);
 573         my ($min, $max) = $ng->mm->minmax;
 574         if ($range =~ /\A(\d+)\z/) {
 575                 $beg = $end = $1;
 576         } elsif ($range =~ /\A(\d+)-\z/) {
 577                 ($beg, $end) = ($1, $max);
 578         } elsif ($range =~ /\A(\d+)-(\d+)\z/) {
 579                 ($beg, $end) = ($1, $2);
 580         } else {
 581                 return r501;
 582         }
 583         $beg = $min if ($beg < $min);
 584         $end = $max if ($end > $max);
 585         return '420 No article(s) selected' if ($beg > $end);
 586         [ $beg, $end ];
 587 }
 588
 589 sub long_response ($$$$) {
 590         my ($self, $beg, $end, $cb) = @_;
 591         die "BUG: nested long response" if $self->{long_res};
 592
 593         my $fd = $self->{fd};
 594         defined $fd or return;
 595         # make sure we disable reading during a long response,
 596         # clients should not be sending us stuff and making us do more
 597         # work while we are stream a response to them
 598         $self->watch_read(0);
 599         my $t0 = now();
 600         $self->{long_res} = sub {
 601                 # limit our own running time for fairness with other
 602                 # clients and to avoid buffering too much:
 603                 my $lim = 100;
 604
 605                 my $err;
 606                 do {
 607                         eval { $cb->(\$beg) };
 608                 } until (($err = $@) || $self->{closed} ||
 609                          ++$beg > $end || !--$lim || $self->{write_buf_size});
 610
 611                 if ($err || $self->{closed}) {
 612                         $self->{long_res} = undef;
 613
 614                         if ($err) {
 615                                 err($self,
 616                                     "%s during long response[$fd] - %0.6f",
 617                                     $err, now() - $t0);
 618                         }
 619                         if ($self->{closed}) {
 620                                 out($self, " deferred[$fd] aborted - %0.6f",
 621                                            now() - $t0);
 622                         } else {
 623                                 update_idle_time($self);
 624                                 $self->watch_read(1);
 625                         }
 626                 } elsif (!$lim || $self->{write_buf_size}) {
 627                         # no recursion, schedule another call ASAP
 628                         # but only after all pending writes are done
 629                         update_idle_time($self);
 630
 631                         push @$nextq, $self;
 632                         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 633                 } else { # all done!
 634                         $self->{long_res} = undef;
 635                         $self->watch_read(1);
 636                         res($self, '.');
 637                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 638                 }
 639         };
 640         $self->{long_res}->(); # kick off!
 641         undef;
 642 }
 643
 644 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 645         my ($self, $xhdr, $range) = @_;
 646
 647         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 648                 my ($ng, $n) = mid_lookup($self, $1);
 649                 return r430 unless $n;
 650                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 651         } else { # numeric range
 652                 $range = $self->{article} unless defined $range;
 653                 my $r = get_range($self, $range);
 654                 return $r unless ref $r;
 655                 my $mm = $self->{ng}->mm;
 656                 my ($beg, $end) = @$r;
 657                 more($self, $xhdr ? r221 : r225);
 658                 long_response($self, $beg, $end, sub {
 659                         my ($i) = @_;
 660                         my $mid = $mm->mid_for($$i);
 661                         more($self, "$$i <$mid>") if defined $mid;
 662                 });
 663         }
 664 }
 665
 666 sub xref ($$) {
 667         my ($ng, $n) = @_;
 668         "$ng->{domain} $ng->{newsgroup}:$n"
 669 }
 670
 671 sub mid_lookup ($$) {
 672         my ($self, $mid) = @_;
 673         my $self_ng = $self->{ng};
 674         if ($self_ng) {
 675                 my $n = $self_ng->mm->num_for($mid);
 676                 return ($self_ng, $n) if defined $n;
 677         }
 678         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 679                 next if defined $self_ng && $ng eq $self_ng;
 680                 my $n = $ng->mm->num_for($mid);
 681                 return ($ng, $n) if defined $n;
 682         }
 683         (undef, undef);
 684 }
 685
 686 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 687         my ($self, $xhdr, $range) = @_;
 688
 689         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 690                 my ($ng, $n) = mid_lookup($self, $1);
 691                 return r430 unless $n;
 692                 hdr_mid_response($self, $xhdr, $ng, $n, $range, xref($ng, $n));
 693         } else { # numeric range
 694                 $range = $self->{article} unless defined $range;
 695                 my $r = get_range($self, $range);
 696                 return $r unless ref $r;
 697                 my $ng = $self->{ng};
 698                 my $mm = $ng->mm;
 699                 my ($beg, $end) = @$r;
 700                 more($self, $xhdr ? r221 : r225);
 701                 long_response($self, $beg, $end, sub {
 702                         my ($i) = @_;
 703                         my $mid = $mm->mid_for($$i);
 704                         more($self, "$$i ".xref($ng, $$i)) if defined $mid;
 705                 });
 706         }
 707 }
 708
 709 sub search_header_for {
 710         my ($srch, $mid, $field) = @_;
 711         my $smsg = $srch->lookup_message($mid) or return;
 712         $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 713         $smsg->$field;
 714 }
 715
 716 sub hdr_searchmsg ($$$$) {
 717         my ($self, $xhdr, $field, $range) = @_;
 718         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 719                 my ($ng, $n) = mid_lookup($self, $1);
 720                 return r430 unless $n;
 721                 my $v = search_header_for($ng->search, $range, $field);
 722                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 723         } else { # numeric range
 724                 $range = $self->{article} unless defined $range;
 725                 my $srch = $self->{ng}->search;
 726                 my $mm = $self->{ng}->mm;
 727                 my $r = get_range($self, $range);
 728                 return $r unless ref $r;
 729                 my ($beg, $end) = @$r;
 730                 more($self, $xhdr ? r221 : r225);
 731                 my $off = 0;
 732                 long_response($self, $beg, $end, sub {
 733                         my ($i) = @_;
 734                         my $res = $srch->query_xover($beg, $end, $off);
 735                         my $msgs = $res->{msgs};
 736                         my $nr = scalar @$msgs or return;
 737                         $off += $nr;
 738                         my $tmp = '';
 739                         foreach my $s (@$msgs) {
 740                                 $tmp .= $s->num . ' ' . $s->$field . "\r\n";
 741                         }
 742                         do_more($self, $tmp);
 743                         # -1 to adjust for implicit increment in long_response
 744                         $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 745                 });
 746         }
 747 }
 748
 749 sub do_hdr ($$$;$) {
 750         my ($self, $xhdr, $header, $range) = @_;
 751         my $sub = lc $header;
 752         if ($sub eq 'message-id') {
 753                 hdr_message_id($self, $xhdr, $range);
 754         } elsif ($sub eq 'xref') {
 755                 hdr_xref($self, $xhdr, $range);
 756         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 757                                 bytes|lines)\z/x) {
 758                 hdr_searchmsg($self, $xhdr, $sub, $range);
 759         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 760                 hdr_searchmsg($self, $xhdr, $1, $range);
 761         } else {
 762                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 763         }
 764 }
 765
 766 # RFC 3977
 767 sub cmd_hdr ($$;$) {
 768         my ($self, $header, $range) = @_;
 769         do_hdr($self, 0, $header, $range);
 770 }
 771
 772 # RFC 2980
 773 sub cmd_xhdr ($$;$) {
 774         my ($self, $header, $range) = @_;
 775         do_hdr($self, 1, $header, $range);
 776 }
 777
 778 sub hdr_mid_prefix ($$$$$) {
 779         my ($self, $xhdr, $ng, $n, $mid) = @_;
 780         return $mid if $xhdr;
 781
 782         # HDR for RFC 3977 users
 783         if (my $self_ng = $self->{ng}) {
 784                 ($self_ng eq $ng) ? $n : '0';
 785         } else {
 786                 '0';
 787         }
 788 }
 789
 790 sub hdr_mid_response ($$$$$$) {
 791         my ($self, $xhdr, $ng, $n, $mid, $v) = @_; # r: art_lookup result
 792         my $res = '';
 793         if ($xhdr) {
 794                 $res .= r221 . "\r\n";
 795                 $res .= "$mid $v\r\n";
 796         } else {
 797                 $res .= r225 . "\r\n";
 798                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 799                 $res .= "$pfx $v\r\n";
 800         }
 801         res($self, $res .= '.');
 802         undef;
 803 }
 804
 805 sub cmd_xrover ($;$) {
 806         my ($self, $range) = @_;
 807         my $ng = $self->{ng} or return '412 no newsgroup selected';
 808         (defined $range && $range =~ /[<>]/) and
 809                 return '420 No article(s) selected'; # no message IDs
 810
 811         $range = $self->{article} unless defined $range;
 812         my $r = get_range($self, $range);
 813         return $r unless ref $r;
 814         my ($beg, $end) = @$r;
 815         my $mm = $ng->mm;
 816         my $srch = $ng->search;
 817         more($self, '224 Overview information follows');
 818         long_response($self, $beg, $end, sub {
 819                 my ($i) = @_;
 820                 my $mid = $mm->mid_for($$i) or return;
 821                 my $h = search_header_for($srch, $mid, 'references');
 822                 more($self, "$$i $h");
 823         });
 824 }
 825
 826 sub over_line ($$) {
 827         my ($num, $smsg) = @_;
 828         # n.b. field access and procedural calls can be
 829         # 10%-15% faster than OO method calls:
 830         join("\t", $num,
 831                 $smsg->{subject},
 832                 $smsg->{from},
 833                 PublicInbox::SearchMsg::date($smsg),
 834                 '<'.PublicInbox::SearchMsg::mid($smsg).'>',
 835                 $smsg->{references},
 836                 PublicInbox::SearchMsg::bytes($smsg),
 837                 PublicInbox::SearchMsg::lines($smsg));
 838 }
 839
 840 sub cmd_over ($;$) {
 841         my ($self, $range) = @_;
 842         if ($range && $range =~ /\A<(.+)>\z/) {
 843                 my ($ng, $n) = mid_lookup($self, $1);
 844                 my $smsg = $ng->search->lookup_message($range) or
 845                         return '430 No article with that message-id';
 846                 more($self, '224 Overview information follows (multi-line)');
 847                 $smsg = PublicInbox::SearchMsg->load_doc($smsg->{doc});
 848
 849                 # Only set article number column if it's the current group
 850                 my $self_ng = $self->{ng};
 851                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 852                 more($self, over_line($n, $smsg));
 853                 '.';
 854         } else {
 855                 cmd_xover($self, $range);
 856         }
 857 }
 858
 859 sub cmd_xover ($;$) {
 860         my ($self, $range) = @_;
 861         $range = $self->{article} unless defined $range;
 862         my $r = get_range($self, $range);
 863         return $r unless ref $r;
 864         my ($beg, $end) = @$r;
 865         more($self, "224 Overview information follows for $beg to $end");
 866         my $srch = $self->{ng}->search;
 867         my $off = 0;
 868         long_response($self, $beg, $end, sub {
 869                 my ($i) = @_;
 870                 my $res = $srch->query_xover($beg, $end, $off);
 871                 my $msgs = $res->{msgs};
 872                 my $nr = scalar @$msgs or return;
 873                 $off += $nr;
 874
 875                 # OVERVIEW.FMT
 876                 more($self, join("\r\n", map {
 877                         over_line(PublicInbox::SearchMsg::num($_), $_);
 878                         } @$msgs));
 879
 880                 # -1 to adjust for implicit increment in long_response
 881                 $$i = $nr ? $$i + $nr - 1 : long_response_limit;
 882         });
 883 }
 884
 885 sub cmd_xpath ($$) {
 886         my ($self, $mid) = @_;
 887         return r501 unless $mid =~ /\A<(.+)>\z/;
 888         $mid = $1;
 889         my @paths;
 890         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 891                 my $n = $ng->mm->num_for($mid);
 892                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 893         }
 894         return '430 no such article on server' unless @paths;
 895         '223 '.join(' ', @paths);
 896 }
 897
 898 sub res ($$) {
 899         my ($self, $line) = @_;
 900         $line = $enc_utf8->encode($line);
 901         do_write($self, $line . "\r\n");
 902 }
 903
 904 sub more ($$) {
 905         my ($self, $line) = @_;
 906         do_more($self, $line . "\r\n");
 907 }
 908
 909 sub do_write ($$) {
 910         my ($self, $data) = @_;
 911         my $done = $self->write($data);
 912         die if $self->{closed};
 913
 914         # Do not watch for readability if we have data in the queue,
 915         # instead re-enable watching for readability when we can
 916         $self->watch_read(0) if (!$done || $self->{long_res});
 917
 918         $done;
 919 }
 920
 921 sub err ($$;@) {
 922         my ($self, $fmt, @args) = @_;
 923         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 924 }
 925
 926 sub out ($$;@) {
 927         my ($self, $fmt, @args) = @_;
 928         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 929 }
 930
 931 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 932
 933 sub do_more ($$) {
 934         my ($self, $data) = @_;
 935         $data = $enc_utf8->encode($data);
 936         if (MSG_MORE && !$self->{write_buf_size}) {
 937                 my $n = send($self->{sock}, $data, MSG_MORE);
 938                 if (defined $n) {
 939                         my $dlen = length($data);
 940                         return 1 if $n == $dlen; # all done!
 941                         $data = substr($data, $n, $dlen - $n);
 942                 }
 943         }
 944         do_write($self, $data);
 945 }
 946
 947 # callbacks for Danga::Socket
 948
 949 sub event_hup { $_[0]->close }
 950 sub event_err { $_[0]->close }
 951
 952 sub event_write {
 953         my ($self) = @_;
 954         update_idle_time($self);
 955         # only continue watching for readability when we are done writing:
 956         if ($self->write(undef) == 1 && !$self->{long_res}) {
 957                 $self->watch_read(1);
 958         }
 959 }
 960
 961 sub event_read {
 962         my ($self) = @_;
 963         use constant LINE_MAX => 512; # RFC 977 section 2.3
 964         my $r = 1;
 965
 966         my $buf = $self->read(LINE_MAX) or return $self->close;
 967         $self->{rbuf} .= $$buf;
 968         while ($r > 0 && $self->{rbuf} =~ s/\A\s*([^\r\n]+)\r?\n//) {
 969                 my $line = $1;
 970                 return $self->close if $line =~ /[[:cntrl:]]/s;
 971                 my $t0 = now();
 972                 my $fd = $self->{fd};
 973                 $r = eval { process_line($self, $line) };
 974                 my $d = $self->{long_res} ?
 975                         " deferred[$fd]" : '';
 976                 out($self, "[$fd] %s - %0.6f$d", $line, now() - $t0);
 977         }
 978
 979         return $self->close if $r < 0;
 980         my $len = length($self->{rbuf});
 981         return $self->close if ($len >= LINE_MAX);
 982         update_idle_time($self);
 983 }
 984
 985 sub watch_read {
 986         my ($self, $bool) = @_;
 987         my $rv = $self->SUPER::watch_read($bool);
 988         if ($bool && $self->{rbuf} ne '') {
 989                 # Force another read if there is a pipelined request.
 990                 # We don't know if the socket has anything for us to read,
 991                 # and we must double-check again by the time the timer fires
 992                 # in case we really did dispatch a read event and started
 993                 # another long response.
 994                 push @$nextq, $self;
 995                 $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
 996         }
 997         $rv;
 998 }
 999
1000 # for graceful shutdown in PublicInbox::Daemon:
1001 sub busy () {
1002         my ($self) = @_;
1003         ($self->{rbuf} ne '' || $self->{long_res} || $self->{write_buf_size});
1004 }
1005
1006 1;