lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article rbuf ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now msg_more));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         r501 => '501 command syntax error',
  22         r221 => '221 Header follows',
  23         r224 => '224 Overview information follows (multi-line)',
  24         r225 => '225 Headers follow (multi-line)',
  25         r430 => '430 No article with that message-id',
  26 };
  27 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  28 use Errno qw(EAGAIN);
  29
  30 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  31 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  32 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  33                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  34
  35 # disable commands with easy DoS potential:
  36 my %DISABLED; # = map { $_ => 1 } qw(xover list_overview_fmt newnews xhdr);
  37
  38 my $EXPMAP; # fd -> [ idle_time, $self ]
  39 my $expt;
  40 our $EXPTIME = 180; # 3 minutes
  41 my $nextt;
  42
  43 my $nextq = [];
  44 sub next_tick () {
  45         $nextt = undef;
  46         my $q = $nextq;
  47         $nextq = [];
  48         event_step($_) for @$q;
  49 }
  50
  51 sub requeue ($) {
  52         push @$nextq, $_[0];
  53         $nextt ||= PublicInbox::EvCleanup::asap(*next_tick);
  54 }
  55
  56 sub update_idle_time ($) {
  57         my ($self) = @_;
  58         my $sock = $self->{sock} or return;
  59         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  60 }
  61
  62 sub expire_old () {
  63         my $now = now();
  64         my $exp = $EXPTIME;
  65         my $old = $now - $exp;
  66         my $nr = 0;
  67         my $closed = 0;
  68         my %new;
  69         while (my ($fd, $v) = each %$EXPMAP) {
  70                 my ($idle_time, $nntp) = @$v;
  71                 if ($idle_time < $old) {
  72                         if ($nntp->shutdn) {
  73                                 $closed++;
  74                         } else {
  75                                 ++$nr;
  76                                 $new{$fd} = $v;
  77                         }
  78                 } else {
  79                         ++$nr;
  80                         $new{$fd} = $v;
  81                 }
  82         }
  83         $EXPMAP = \%new;
  84         if ($nr) {
  85                 $expt = PublicInbox::EvCleanup::later(*expire_old);
  86         } else {
  87                 $expt = undef;
  88                 # noop to kick outselves out of the loop ASAP so descriptors
  89                 # really get closed
  90                 PublicInbox::EvCleanup::asap(sub {}) if $closed;
  91         }
  92 }
  93
  94 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  95
  96 sub new ($$$) {
  97         my ($class, $sock, $nntpd) = @_;
  98         my $self = fields::new($class);
  99         my $ev = EPOLLIN;
 100         my $wbuf;
 101         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
 102                 $ev = PublicInbox::TLS::epollbit() or return CORE::close($sock);
 103                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
 104         }
 105         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
 106         $self->{nntpd} = $nntpd;
 107         if ($wbuf) {
 108                 $self->{wbuf} = $wbuf;
 109         } else {
 110                 greet($self);
 111         }
 112         update_idle_time($self);
 113         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
 114         $self;
 115 }
 116
 117 sub args_ok ($$) {
 118         my ($cb, $argc) = @_;
 119         my $tot = prototype $cb;
 120         my ($nreq, undef) = split(';', $tot);
 121         $nreq = ($nreq =~ tr/$//) - 1;
 122         $tot = ($tot =~ tr/$//) - 1;
 123         ($argc <= $tot && $argc >= $nreq);
 124 }
 125
 126 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 127 sub process_line ($$) {
 128         my ($self, $l) = @_;
 129         my ($req, @args) = split(/[ \t]/, $l);
 130         return 1 unless defined($req); # skip blank line
 131         $req = lc($req);
 132         $req = eval {
 133                 no strict 'refs';
 134                 $req = $DISABLED{$req} ? undef : *{'cmd_'.$req}{CODE};
 135         };
 136         return res($self, '500 command not recognized') unless $req;
 137         return res($self, r501) unless args_ok($req, scalar @args);
 138
 139         my $res = eval { $req->($self, @args) };
 140         my $err = $@;
 141         if ($err && $self->{sock}) {
 142                 local $/ = "\n";
 143                 chomp($l);
 144                 err($self, 'error from: %s (%s)', $l, $err);
 145                 $res = '503 program fault - command not performed';
 146         }
 147         return 0 unless defined $res;
 148         res($self, $res);
 149 }
 150
 151 sub cmd_mode ($$) {
 152         my ($self, $arg) = @_;
 153         $arg = uc $arg;
 154         return r501 unless $arg eq 'READER';
 155         '201 Posting prohibited';
 156 }
 157
 158 sub cmd_slave ($) { '202 slave status noted' }
 159
 160 sub cmd_xgtitle ($;$) {
 161         my ($self, $wildmat) = @_;
 162         more($self, '282 list of groups and descriptions follows');
 163         list_newsgroups($self, $wildmat);
 164         '.'
 165 }
 166
 167 sub list_overview_fmt ($) {
 168         my ($self) = @_;
 169         msg_more($self, $OVERVIEW_FMT);
 170 }
 171
 172 sub list_headers ($;$) {
 173         my ($self) = @_;
 174         msg_more($self, $LIST_HEADERS);
 175 }
 176
 177 sub list_active ($;$) {
 178         my ($self, $wildmat) = @_;
 179         wildmat2re($wildmat);
 180         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 181                 $ng->{newsgroup} =~ $wildmat or next;
 182                 group_line($self, $ng);
 183         }
 184 }
 185
 186 sub list_active_times ($;$) {
 187         my ($self, $wildmat) = @_;
 188         wildmat2re($wildmat);
 189         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 190                 $ng->{newsgroup} =~ $wildmat or next;
 191                 my $c = eval { $ng->mm->created_at } || time;
 192                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 193         }
 194 }
 195
 196 sub list_newsgroups ($;$) {
 197         my ($self, $wildmat) = @_;
 198         wildmat2re($wildmat);
 199         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 200                 $ng->{newsgroup} =~ $wildmat or next;
 201                 my $d = $ng->description;
 202                 more($self, "$ng->{newsgroup} $d");
 203         }
 204 }
 205
 206 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 207 sub cmd_list ($;$$) {
 208         my ($self, @args) = @_;
 209         if (scalar @args) {
 210                 my $arg = shift @args;
 211                 $arg =~ tr/A-Z./a-z_/;
 212                 $arg = "list_$arg";
 213                 return r501 if $DISABLED{$arg};
 214
 215                 $arg = eval {
 216                         no strict 'refs';
 217                         *{$arg}{CODE};
 218                 };
 219                 return r501 unless $arg && args_ok($arg, scalar @args);
 220                 more($self, '215 information follows');
 221                 $arg->($self, @args);
 222         } else {
 223                 more($self, '215 list of newsgroups follows');
 224                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 225                         group_line($self, $ng);
 226                 }
 227         }
 228         '.'
 229 }
 230
 231 sub cmd_listgroup ($;$) {
 232         my ($self, $group) = @_;
 233         if (defined $group) {
 234                 my $res = cmd_group($self, $group);
 235                 return $res if ($res !~ /\A211 /);
 236                 more($self, $res);
 237         }
 238
 239         $self->{ng} or return '412 no newsgroup selected';
 240         my $n = 0;
 241         long_response($self, sub {
 242                 my $ary = $self->{ng}->mm->ids_after(\$n);
 243                 scalar @$ary or return;
 244                 more($self, join("\r\n", @$ary));
 245                 1;
 246         });
 247 }
 248
 249 sub parse_time ($$;$) {
 250         my ($date, $time, $gmt) = @_;
 251         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 252         if (defined $gmt) {
 253                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 254                 $gmt = 1;
 255         }
 256         my @now = $gmt ? gmtime : localtime;
 257         my ($YYYY, $MM, $DD);
 258         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 259                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 260         } else { # legacy clients send YYMMDD
 261                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 262                 my $cur_year = $now[5] + 1900;
 263                 if ($YYYY > $cur_year) {
 264                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 265                 }
 266         }
 267         if ($gmt) {
 268                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 269         } else {
 270                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 271         }
 272 }
 273
 274 sub group_line ($$) {
 275         my ($self, $ng) = @_;
 276         my ($min, $max) = $ng->mm->minmax;
 277         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 278 }
 279
 280 sub cmd_newgroups ($$$;$$) {
 281         my ($self, $date, $time, $gmt, $dists) = @_;
 282         my $ts = eval { parse_time($date, $time, $gmt) };
 283         return r501 if $@;
 284
 285         # TODO dists
 286         more($self, '231 list of new newsgroups follows');
 287         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 288                 my $c = eval { $ng->mm->created_at } || 0;
 289                 next unless $c > $ts;
 290                 group_line($self, $ng);
 291         }
 292         '.'
 293 }
 294
 295 sub wildmat2re (;$) {
 296         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 297         my %keep;
 298         my $salt = rand;
 299         my $tmp = $_[0];
 300
 301         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 302                 my $orig = $1;
 303                 my $key = sha1_hex($orig . $salt);
 304                 $orig =~ s/([^\w\-])+/\Q$1/g;
 305                 $keep{$key} = $orig;
 306                 $key
 307                 #gex;
 308         my %map = ('*' => '.*', '?' => '.' );
 309         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 310         if (scalar %keep) {
 311                 $tmp =~ s#([a-f0-9]{40})#
 312                         my $orig = $keep{$1};
 313                         defined $orig ? $orig : $1;
 314                         #ge;
 315         }
 316         $_[0] = qr/\A$tmp\z/;
 317 }
 318
 319 sub ngpat2re (;$) {
 320         return $_[0] = qr/\A\z/ unless defined $_[0];
 321         my %map = ('*' => '.*', ',' => '|');
 322         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 323         $_[0] = qr/\A(?:$_[0])\z/;
 324 }
 325
 326 sub cmd_newnews ($$$$;$$) {
 327         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 328         my $ts = eval { parse_time($date, $time, $gmt) };
 329         return r501 if $@;
 330         more($self, '230 list of new articles by message-id follows');
 331         my ($keep, $skip) = split('!', $newsgroups, 2);
 332         ngpat2re($keep);
 333         ngpat2re($skip);
 334         my @over;
 335         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 336                 $ng->{newsgroup} =~ $keep or next;
 337                 $ng->{newsgroup} =~ $skip and next;
 338                 my $over = $ng->over or next;
 339                 push @over, $over;
 340         };
 341         return '.' unless @over;
 342
 343         my $prev = 0;
 344         long_response($self, sub {
 345                 my $over = $over[0];
 346                 my $msgs = $over->query_ts($ts, $prev);
 347                 if (scalar @$msgs) {
 348                         more($self, '<' .
 349                                 join(">\r\n<", map { $_->mid } @$msgs ).
 350                                 '>');
 351                         $prev = $msgs->[-1]->{num};
 352                 } else {
 353                         shift @over;
 354                         if (@over) { # continue onto next newsgroup
 355                                 $prev = 0;
 356                                 return 1;
 357                         } else { # break out of the long response.
 358                                 return;
 359                         }
 360                 }
 361         });
 362 }
 363
 364 sub cmd_group ($$) {
 365         my ($self, $group) = @_;
 366         my $no_such = '411 no such news group';
 367         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 368
 369         $self->{ng} = $ng;
 370         my ($min, $max) = $ng->mm->minmax;
 371         $min ||= 0;
 372         $max ||= 0;
 373         $self->{article} = $min;
 374         my $est_size = $max - $min;
 375         "211 $est_size $min $max $group";
 376 }
 377
 378 sub article_adj ($$) {
 379         my ($self, $off) = @_;
 380         my $ng = $self->{ng} or return '412 no newsgroup selected';
 381
 382         my $n = $self->{article};
 383         defined $n or return '420 no current article has been selected';
 384
 385         $n += $off;
 386         my $mid = $ng->mm->mid_for($n);
 387         unless ($mid) {
 388                 $n = $off > 0 ? 'next' : 'previous';
 389                 return "421 no $n article in this group";
 390         }
 391         $self->{article} = $n;
 392         "223 $n <$mid> article retrieved - request text separately";
 393 }
 394
 395 sub cmd_next ($) { article_adj($_[0], 1) }
 396 sub cmd_last ($) { article_adj($_[0], -1) }
 397
 398 # We want to encourage using email and CC-ing everybody involved to avoid
 399 # the single-point-of-failure a single server provides.
 400 sub cmd_post ($) {
 401         my ($self) = @_;
 402         my $ng = $self->{ng};
 403         $ng ? "440 mailto:$ng->{-primary_address} to post"
 404                 : '440 posting not allowed'
 405 }
 406
 407 sub cmd_quit ($) {
 408         my ($self) = @_;
 409         res($self, '205 closing connection - goodbye!');
 410         $self->shutdn;
 411         undef;
 412 }
 413
 414 sub header_append ($$$) {
 415         my ($hdr, $k, $v) = @_;
 416         my @v = $hdr->header($k);
 417         foreach (@v) {
 418                 return if $v eq $_;
 419         }
 420         $hdr->header_set($k, @v, $v);
 421 }
 422
 423 sub xref ($$$$) {
 424         my ($self, $ng, $n, $mid) = @_;
 425         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 426
 427         # num_for is pretty cheap and sometimes we'll lookup the existence
 428         # of an article without getting even the OVER info.  In other words,
 429         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 430         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 431         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 432                 next if $ng eq $other;
 433                 my $num = eval { $other->mm->num_for($mid) } or next;
 434                 $ret .= " $other->{newsgroup}:$num";
 435         }
 436         $ret;
 437 }
 438
 439 sub set_nntp_headers ($$$$$) {
 440         my ($self, $hdr, $ng, $n, $mid) = @_;
 441
 442         # why? leafnode requires a Path: header for some inexplicable
 443         # reason.  We'll fake the shortest one possible.
 444         $hdr->header_set('Path', 'y');
 445
 446         # leafnode (and maybe other NNTP clients) have trouble dealing
 447         # with v2 messages which have multiple Message-IDs (either due
 448         # to our own content-based dedupe or buggy git-send-email versions).
 449         my @mids = $hdr->header('Message-ID');
 450         if (scalar(@mids) > 1) {
 451                 my $mid0 = "<$mid>";
 452                 $hdr->header_set('Message-ID', $mid0);
 453                 my @alt = $hdr->header('X-Alt-Message-ID');
 454                 my %seen = map { $_ => 1 } (@alt, $mid0);
 455                 foreach my $m (@mids) {
 456                         next if $seen{$m}++;
 457                         push @alt, $m;
 458                 }
 459                 $hdr->header_set('X-Alt-Message-ID', @alt);
 460         }
 461
 462         # clobber some
 463         my $xref = xref($self, $ng, $n, $mid);
 464         $hdr->header_set('Xref', $xref);
 465         $xref =~ s/:[0-9]+//g;
 466         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 467         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 468         if (my $url = $ng->base_url) {
 469                 $mid = mid_escape($mid);
 470                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 471                 header_append($hdr, 'List-Archive', "<$url>");
 472         }
 473 }
 474
 475 sub art_lookup ($$$) {
 476         my ($self, $art, $set_headers) = @_;
 477         my $ng = $self->{ng};
 478         my ($n, $mid);
 479         my $err;
 480         if (defined $art) {
 481                 if ($art =~ /\A[0-9]+\z/) {
 482                         $err = '423 no such article number in this group';
 483                         $n = int($art);
 484                         goto find_mid;
 485                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 486                         $mid = $1;
 487                         $err = r430;
 488                         $n = $ng->mm->num_for($mid) if $ng;
 489                         goto found if defined $n;
 490                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 491                                 $n = $g->mm->num_for($mid);
 492                                 if (defined $n) {
 493                                         $ng = $g;
 494                                         goto found;
 495                                 }
 496                         }
 497                         return $err;
 498                 } else {
 499                         return r501;
 500                 }
 501         } else {
 502                 $err = '420 no current article has been selected';
 503                 $n = $self->{article};
 504                 defined $n or return $err;
 505 find_mid:
 506                 $ng or return '412 no newsgroup has been selected';
 507                 $mid = $ng->mm->mid_for($n);
 508                 defined $mid or return $err;
 509         }
 510 found:
 511         my $smsg = $ng->over->get_art($n) or return $err;
 512         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 513
 514         # Email::Simple->new will modify $msg in-place as documented
 515         # in its manpage, so what's left is the body and we won't need
 516         # to call Email::Simple::body(), later
 517         my $hdr = Email::Simple->new($msg)->header_obj;
 518         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 519         [ $n, $mid, $msg, $hdr ];
 520 }
 521
 522 sub msg_body_write ($$) {
 523         my ($self, $msg) = @_;
 524         $$msg =~ s/^\./../smg;
 525         $$msg =~ s/(?<!\r)\n/\r\n/sg;
 526         msg_more($self, $$msg);
 527         msg_more($self, "\r\n") unless $$msg =~ /\r\n\z/s;
 528         '.'
 529 }
 530
 531 sub set_art {
 532         my ($self, $art) = @_;
 533         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 534 }
 535
 536 sub _header ($) {
 537         my $hdr = $_[0]->as_string;
 538         utf8::encode($hdr);
 539         $hdr =~ s/(?<!\r)\n/\r\n/sg;
 540
 541         # for leafnode compatibility, we need to ensure Message-ID headers
 542         # are only a single line.  We can't subclass Email::Simple::Header
 543         # and override _default_fold_at in here, either; since that won't
 544         # affect messages already in the archive.
 545         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 546
 547         $hdr
 548 }
 549
 550 sub cmd_article ($;$) {
 551         my ($self, $art) = @_;
 552         my $r = art_lookup($self, $art, 1);
 553         return $r unless ref $r;
 554         my ($n, $mid, $msg, $hdr) = @$r;
 555         set_art($self, $art);
 556         more($self, "220 $n <$mid> article retrieved - head and body follow");
 557         msg_more($self, _header($hdr));
 558         msg_more($self, "\r\n");
 559         msg_body_write($self, $msg);
 560 }
 561
 562 sub cmd_head ($;$) {
 563         my ($self, $art) = @_;
 564         my $r = art_lookup($self, $art, 2);
 565         return $r unless ref $r;
 566         my ($n, $mid, undef, $hdr) = @$r;
 567         set_art($self, $art);
 568         more($self, "221 $n <$mid> article retrieved - head follows");
 569         msg_more($self, _header($hdr));
 570         '.'
 571 }
 572
 573 sub cmd_body ($;$) {
 574         my ($self, $art) = @_;
 575         my $r = art_lookup($self, $art, 0);
 576         return $r unless ref $r;
 577         my ($n, $mid, $msg) = @$r;
 578         set_art($self, $art);
 579         more($self, "222 $n <$mid> article retrieved - body follows");
 580         msg_body_write($self, $msg);
 581 }
 582
 583 sub cmd_stat ($;$) {
 584         my ($self, $art) = @_;
 585         my $r = art_lookup($self, $art, 0);
 586         return $r unless ref $r;
 587         my ($n, $mid) = @$r;
 588         set_art($self, $art);
 589         "223 $n <$mid> article retrieved - request text separately";
 590 }
 591
 592 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 593
 594 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 595
 596 sub cmd_help ($) {
 597         my ($self) = @_;
 598         more($self, '100 help text follows');
 599         '.'
 600 }
 601
 602 sub get_range ($$) {
 603         my ($self, $range) = @_;
 604         my $ng = $self->{ng} or return '412 no news group has been selected';
 605         defined $range or return '420 No article(s) selected';
 606         my ($beg, $end);
 607         my ($min, $max) = $ng->mm->minmax;
 608         if ($range =~ /\A([0-9]+)\z/) {
 609                 $beg = $end = $1;
 610         } elsif ($range =~ /\A([0-9]+)-\z/) {
 611                 ($beg, $end) = ($1, $max);
 612         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 613                 ($beg, $end) = ($1, $2);
 614         } else {
 615                 return r501;
 616         }
 617         $beg = $min if ($beg < $min);
 618         $end = $max if ($end > $max);
 619         return '420 No article(s) selected' if ($beg > $end);
 620         [ $beg, $end ];
 621 }
 622
 623 sub long_response ($$) {
 624         my ($self, $cb) = @_; # cb returns true if more, false if done
 625
 626         my $fd = fileno($self->{sock});
 627         defined $fd or return;
 628         # make sure we disable reading during a long response,
 629         # clients should not be sending us stuff and making us do more
 630         # work while we are stream a response to them
 631         my $t0 = now();
 632         my $long_cb; # DANGER: self-referential
 633         $long_cb = sub {
 634                 # wbuf is unset or empty, here; $cb may add to it
 635                 my $more = eval { $cb->() };
 636                 if ($@ || !$self->{sock}) { # something bad happened...
 637                         $long_cb = undef;
 638                         my $diff = now() - $t0;
 639                         if ($@) {
 640                                 err($self,
 641                                     "%s during long response[$fd] - %0.6f",
 642                                     $@, $diff);
 643                         }
 644                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 645                         $self->close;
 646                 } elsif ($more) { # $self->{wbuf}:
 647                         update_idle_time($self);
 648
 649                         # no recursion, schedule another call ASAP
 650                         # but only after all pending writes are done
 651                         my $wbuf = $self->{wbuf} ||= [];
 652                         push @$wbuf, $long_cb;
 653
 654                         # wbuf may be populated by $cb, no need to rearm if so:
 655                         requeue($self) if scalar(@$wbuf) == 1;
 656                 } else { # all done!
 657                         $long_cb = undef;
 658                         res($self, '.');
 659                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 660                         requeue($self) unless $self->{wbuf};
 661                 }
 662         };
 663         $self->write($long_cb); # kick off!
 664         undef;
 665 }
 666
 667 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 668         my ($self, $xhdr, $range) = @_;
 669
 670         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 671                 my ($ng, $n) = mid_lookup($self, $1);
 672                 return r430 unless $n;
 673                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 674         } else { # numeric range
 675                 $range = $self->{article} unless defined $range;
 676                 my $r = get_range($self, $range);
 677                 return $r unless ref $r;
 678                 my $mm = $self->{ng}->mm;
 679                 my ($beg, $end) = @$r;
 680                 more($self, $xhdr ? r221 : r225);
 681                 long_response($self, sub {
 682                         my $r = $mm->msg_range(\$beg, $end);
 683                         @$r or return;
 684                         more($self, join("\r\n", map {
 685                                 "$_->[0] <$_->[1]>"
 686                         } @$r));
 687                         1;
 688                 });
 689         }
 690 }
 691
 692 sub mid_lookup ($$) {
 693         my ($self, $mid) = @_;
 694         my $self_ng = $self->{ng};
 695         if ($self_ng) {
 696                 my $n = $self_ng->mm->num_for($mid);
 697                 return ($self_ng, $n) if defined $n;
 698         }
 699         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 700                 next if defined $self_ng && $ng eq $self_ng;
 701                 my $n = $ng->mm->num_for($mid);
 702                 return ($ng, $n) if defined $n;
 703         }
 704         (undef, undef);
 705 }
 706
 707 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 708         my ($self, $xhdr, $range) = @_;
 709
 710         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 711                 my $mid = $1;
 712                 my ($ng, $n) = mid_lookup($self, $mid);
 713                 return r430 unless $n;
 714                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 715                                 xref($self, $ng, $n, $mid));
 716         } else { # numeric range
 717                 $range = $self->{article} unless defined $range;
 718                 my $r = get_range($self, $range);
 719                 return $r unless ref $r;
 720                 my $ng = $self->{ng};
 721                 my $mm = $ng->mm;
 722                 my ($beg, $end) = @$r;
 723                 more($self, $xhdr ? r221 : r225);
 724                 long_response($self, sub {
 725                         my $r = $mm->msg_range(\$beg, $end);
 726                         @$r or return;
 727                         more($self, join("\r\n", map {
 728                                 my $num = $_->[0];
 729                                 "$num ".xref($self, $ng, $num, $_->[1]);
 730                         } @$r));
 731                         1;
 732                 });
 733         }
 734 }
 735
 736 sub over_header_for {
 737         my ($over, $num, $field) = @_;
 738         my $smsg = $over->get_art($num) or return;
 739         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 740         $smsg->{$field};
 741 }
 742
 743 sub hdr_searchmsg ($$$$) {
 744         my ($self, $xhdr, $field, $range) = @_;
 745         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 746                 my ($ng, $n) = mid_lookup($self, $1);
 747                 return r430 unless defined $n;
 748                 my $v = over_header_for($ng->over, $n, $field);
 749                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 750         } else { # numeric range
 751                 $range = $self->{article} unless defined $range;
 752                 my $over = $self->{ng}->over;
 753                 my $mm = $self->{ng}->mm;
 754                 my $r = get_range($self, $range);
 755                 return $r unless ref $r;
 756                 my ($beg, $end) = @$r;
 757                 more($self, $xhdr ? r221 : r225);
 758                 my $cur = $beg;
 759                 long_response($self, sub {
 760                         my $msgs = $over->query_xover($cur, $end);
 761                         my $nr = scalar @$msgs or return;
 762                         my $tmp = '';
 763                         foreach my $s (@$msgs) {
 764                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 765                         }
 766                         utf8::encode($tmp);
 767                         msg_more($self, $tmp);
 768                         $cur = $msgs->[-1]->{num} + 1;
 769                 });
 770         }
 771 }
 772
 773 sub do_hdr ($$$;$) {
 774         my ($self, $xhdr, $header, $range) = @_;
 775         my $sub = lc $header;
 776         if ($sub eq 'message-id') {
 777                 hdr_message_id($self, $xhdr, $range);
 778         } elsif ($sub eq 'xref') {
 779                 hdr_xref($self, $xhdr, $range);
 780         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 781                                 bytes|lines)\z/x) {
 782                 hdr_searchmsg($self, $xhdr, $sub, $range);
 783         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 784                 hdr_searchmsg($self, $xhdr, $1, $range);
 785         } else {
 786                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 787         }
 788 }
 789
 790 # RFC 3977
 791 sub cmd_hdr ($$;$) {
 792         my ($self, $header, $range) = @_;
 793         do_hdr($self, 0, $header, $range);
 794 }
 795
 796 # RFC 2980
 797 sub cmd_xhdr ($$;$) {
 798         my ($self, $header, $range) = @_;
 799         do_hdr($self, 1, $header, $range);
 800 }
 801
 802 sub hdr_mid_prefix ($$$$$) {
 803         my ($self, $xhdr, $ng, $n, $mid) = @_;
 804         return $mid if $xhdr;
 805
 806         # HDR for RFC 3977 users
 807         if (my $self_ng = $self->{ng}) {
 808                 ($self_ng eq $ng) ? $n : '0';
 809         } else {
 810                 '0';
 811         }
 812 }
 813
 814 sub hdr_mid_response ($$$$$$) {
 815         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 816         my $res = '';
 817         if ($xhdr) {
 818                 $res .= r221 . "\r\n";
 819                 $res .= "$mid $v\r\n";
 820         } else {
 821                 $res .= r225 . "\r\n";
 822                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 823                 $res .= "$pfx $v\r\n";
 824         }
 825         res($self, $res .= '.');
 826         undef;
 827 }
 828
 829 sub cmd_xrover ($;$) {
 830         my ($self, $range) = @_;
 831         my $ng = $self->{ng} or return '412 no newsgroup selected';
 832         (defined $range && $range =~ /[<>]/) and
 833                 return '420 No article(s) selected'; # no message IDs
 834
 835         $range = $self->{article} unless defined $range;
 836         my $r = get_range($self, $range);
 837         return $r unless ref $r;
 838         my ($beg, $end) = @$r;
 839         my $mm = $ng->mm;
 840         my $over = $ng->over;
 841         more($self, '224 Overview information follows');
 842
 843         long_response($self, sub {
 844                 my $h = over_header_for($over, $beg, 'references');
 845                 more($self, "$beg $h") if defined($h);
 846                 $beg++ < $end;
 847         });
 848 }
 849
 850 sub over_line ($$$$) {
 851         my ($self, $ng, $num, $smsg) = @_;
 852         # n.b. field access and procedural calls can be
 853         # 10%-15% faster than OO method calls:
 854         my $s = join("\t", $num,
 855                 $smsg->{subject},
 856                 $smsg->{from},
 857                 PublicInbox::SearchMsg::date($smsg),
 858                 "<$smsg->{mid}>",
 859                 $smsg->{references},
 860                 $smsg->{bytes},
 861                 $smsg->{lines},
 862                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 863         utf8::encode($s);
 864         $s
 865 }
 866
 867 sub cmd_over ($;$) {
 868         my ($self, $range) = @_;
 869         if ($range && $range =~ /\A<(.+)>\z/) {
 870                 my ($ng, $n) = mid_lookup($self, $1);
 871                 defined $n or return r430;
 872                 my $smsg = $ng->over->get_art($n) or return r430;
 873                 more($self, '224 Overview information follows (multi-line)');
 874
 875                 # Only set article number column if it's the current group
 876                 my $self_ng = $self->{ng};
 877                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 878                 more($self, over_line($self, $ng, $n, $smsg));
 879                 '.';
 880         } else {
 881                 cmd_xover($self, $range);
 882         }
 883 }
 884
 885 sub cmd_xover ($;$) {
 886         my ($self, $range) = @_;
 887         $range = $self->{article} unless defined $range;
 888         my $r = get_range($self, $range);
 889         return $r unless ref $r;
 890         my ($beg, $end) = @$r;
 891         more($self, "224 Overview information follows for $beg to $end");
 892         my $over = $self->{ng}->over;
 893         my $cur = $beg;
 894         long_response($self, sub {
 895                 my $msgs = $over->query_xover($cur, $end);
 896                 my $nr = scalar @$msgs or return;
 897
 898                 # OVERVIEW.FMT
 899                 more($self, join("\r\n", map {
 900                         over_line($self, $self->{ng}, $_->{num}, $_);
 901                         } @$msgs));
 902                 $cur = $msgs->[-1]->{num} + 1;
 903         });
 904 }
 905
 906 sub cmd_starttls ($) {
 907         my ($self) = @_;
 908         my $sock = $self->{sock} or return;
 909         # RFC 4642 2.2.1
 910         (ref($sock) eq 'IO::Socket::SSL') and return '502 Command unavailable';
 911         my $opt = $self->{nntpd}->{accept_tls} or
 912                 return '580 can not initiate TLS negotiation';
 913         res($self, '382 Continue with TLS negotiation');
 914         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 915         requeue($self) if PublicInbox::DS::accept_tls_step($self);
 916         undef;
 917 }
 918
 919 sub cmd_xpath ($$) {
 920         my ($self, $mid) = @_;
 921         return r501 unless $mid =~ /\A<(.+)>\z/;
 922         $mid = $1;
 923         my @paths;
 924         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 925                 my $n = $ng->mm->num_for($mid);
 926                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 927         }
 928         return '430 no such article on server' unless @paths;
 929         '223 '.join(' ', @paths);
 930 }
 931
 932 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 933
 934 sub more ($$) { msg_more($_[0], $_[1] . "\r\n") }
 935
 936 sub do_write ($$) {
 937         my $self = $_[0];
 938         my $done = $self->write(\($_[1]));
 939         return 0 unless $self->{sock};
 940
 941         $done;
 942 }
 943
 944 sub err ($$;@) {
 945         my ($self, $fmt, @args) = @_;
 946         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 947 }
 948
 949 sub out ($$;@) {
 950         my ($self, $fmt, @args) = @_;
 951         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 952 }
 953
 954 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 955 sub event_step {
 956         my ($self) = @_;
 957
 958         return unless $self->flush_write && $self->{sock};
 959
 960         update_idle_time($self);
 961         # only read more requests if we've drained the write buffer,
 962         # otherwise we can be buffering infinitely w/o backpressure
 963
 964         use constant LINE_MAX => 512; # RFC 977 section 2.3
 965         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 966         my $r = 1;
 967
 968         if (index($$rbuf, "\n") < 0) {
 969                 my $off = bytes::length($$rbuf);
 970                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 971         }
 972         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 973                 my $line = $1;
 974                 return $self->close if $line =~ /[[:cntrl:]]/s;
 975                 my $t0 = now();
 976                 my $fd = fileno($self->{sock});
 977                 $r = eval { process_line($self, $line) };
 978                 my $pending = $self->{wbuf} ? ' pending' : '';
 979                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 980         }
 981
 982         return $self->close if $r < 0;
 983         my $len = bytes::length($$rbuf);
 984         return $self->close if ($len >= LINE_MAX);
 985         if ($len) {
 986                 $self->{rbuf} = $rbuf;
 987         } else {
 988                 delete $self->{rbuf};
 989         }
 990         update_idle_time($self);
 991
 992         # maybe there's more pipelined data, or we'll have
 993         # to register it for socket-readiness notifications
 994         requeue($self) unless $self->{wbuf};
 995 }
 996
 997 sub not_idle_long ($$) {
 998         my ($self, $now) = @_;
 999         my $sock = $self->{sock} or return;
1000         my $ary = $EXPMAP->{fileno($sock)} or return;
1001         my $exp_at = $ary->[0] + $EXPTIME;
1002         $exp_at > $now;
1003 }
1004
1005 # for graceful shutdown in PublicInbox::Daemon:
1006 sub busy {
1007         my ($self, $now) = @_;
1008         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
1009 }
1010
1011 1;