lib/PublicInbox/NNTP.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 package PublicInbox::NNTP;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::DS);
   9 use fields qw(nntpd article ng);
  10 use PublicInbox::Search;
  11 use PublicInbox::Msgmap;
  12 use PublicInbox::MID qw(mid_escape);
  13 use PublicInbox::Git;
  14 require PublicInbox::EvCleanup;
  15 use Email::Simple;
  16 use POSIX qw(strftime);
  17 PublicInbox::DS->import(qw(now));
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use constant {
  21         LINE_MAX => 512, # RFC 977 section 2.3
  22         r501 => '501 command syntax error',
  23         r502 => '502 Command unavailable',
  24         r221 => '221 Header follows',
  25         r224 => '224 Overview information follows (multi-line)',
  26         r225 => '225 Headers follow (multi-line)',
  27         r430 => '430 No article with that message-id',
  28 };
  29 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  30 use Errno qw(EAGAIN);
  31
  32 my @OVERVIEW = qw(Subject From Date Message-ID References Xref);
  33 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines)) . ":\r\n";
  34 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  35                         qw(:bytes :lines Xref To Cc)) . "\r\n";
  36 my $CAPABILITIES = <<"";
  37 101 Capability list:\r
  38 VERSION 2\r
  39 READER\r
  40 NEWNEWS\r
  41 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  42 HDR\r
  43 OVER\r
  44
  45 my $have_deflate;
  46 my $EXPMAP; # fd -> [ idle_time, $self ]
  47 my $expt;
  48 our $EXPTIME = 180; # 3 minutes
  49
  50 sub update_idle_time ($) {
  51         my ($self) = @_;
  52         my $sock = $self->{sock} or return;
  53         $EXPMAP->{fileno($sock)} = [ now(), $self ];
  54 }
  55
  56 sub expire_old () {
  57         my $now = now();
  58         my $exp = $EXPTIME;
  59         my $old = $now - $exp;
  60         my $nr = 0;
  61         my %new;
  62         while (my ($fd, $v) = each %$EXPMAP) {
  63                 my ($idle_time, $nntp) = @$v;
  64                 if ($idle_time < $old) {
  65                         if (!$nntp->shutdn) {
  66                                 ++$nr;
  67                                 $new{$fd} = $v;
  68                         }
  69                 } else {
  70                         ++$nr;
  71                         $new{$fd} = $v;
  72                 }
  73         }
  74         $EXPMAP = \%new;
  75         $expt = PublicInbox::EvCleanup::later(*expire_old) if $nr;
  76 }
  77
  78 sub greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  79
  80 sub new ($$$) {
  81         my ($class, $sock, $nntpd) = @_;
  82         my $self = fields::new($class);
  83         my $ev = EPOLLIN;
  84         my $wbuf;
  85         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  86                 return CORE::close($sock) if $! != EAGAIN;
  87                 $ev = PublicInbox::TLS::epollbit();
  88                 $wbuf = [ \&PublicInbox::DS::accept_tls_step, \&greet ];
  89         }
  90         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  91         $self->{nntpd} = $nntpd;
  92         if ($wbuf) {
  93                 $self->{wbuf} = $wbuf;
  94         } else {
  95                 greet($self);
  96         }
  97         update_idle_time($self);
  98         $expt ||= PublicInbox::EvCleanup::later(*expire_old);
  99         $self;
 100 }
 101
 102 sub args_ok ($$) {
 103         my ($cb, $argc) = @_;
 104         my $tot = prototype $cb;
 105         my ($nreq, undef) = split(';', $tot);
 106         $nreq = ($nreq =~ tr/$//) - 1;
 107         $tot = ($tot =~ tr/$//) - 1;
 108         ($argc <= $tot && $argc >= $nreq);
 109 }
 110
 111 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 112 sub process_line ($$) {
 113         my ($self, $l) = @_;
 114         my ($req, @args) = split(/[ \t]/, $l);
 115         return 1 unless defined($req); # skip blank line
 116         $req = eval {
 117                 no strict 'refs';
 118                 *{'cmd_'.lc($req)}{CODE};
 119         };
 120         return res($self, '500 command not recognized') unless $req;
 121         return res($self, r501) unless args_ok($req, scalar @args);
 122
 123         my $res = eval { $req->($self, @args) };
 124         my $err = $@;
 125         if ($err && $self->{sock}) {
 126                 local $/ = "\n";
 127                 chomp($l);
 128                 err($self, 'error from: %s (%s)', $l, $err);
 129                 $res = '503 program fault - command not performed';
 130         }
 131         return 0 unless defined $res;
 132         res($self, $res);
 133 }
 134
 135 # The keyword argument is not used (rfc3977 5.2.2)
 136 sub cmd_capabilities ($;$) {
 137         my ($self, undef) = @_;
 138         my $res = $CAPABILITIES;
 139         if (ref($self->{sock}) ne 'IO::Socket::SSL' &&
 140                         $self->{nntpd}->{accept_tls}) {
 141                 $res .= "STARTTLS\r\n";
 142         }
 143         $res .= '.';
 144 }
 145
 146 sub cmd_mode ($$) {
 147         my ($self, $arg) = @_;
 148         $arg = uc $arg;
 149         return r501 unless $arg eq 'READER';
 150         '201 Posting prohibited';
 151 }
 152
 153 sub cmd_slave ($) { '202 slave status noted' }
 154
 155 sub cmd_xgtitle ($;$) {
 156         my ($self, $wildmat) = @_;
 157         more($self, '282 list of groups and descriptions follows');
 158         list_newsgroups($self, $wildmat);
 159         '.'
 160 }
 161
 162 sub list_overview_fmt ($) {
 163         my ($self) = @_;
 164         $self->msg_more($OVERVIEW_FMT);
 165 }
 166
 167 sub list_headers ($;$) {
 168         my ($self) = @_;
 169         $self->msg_more($LIST_HEADERS);
 170 }
 171
 172 sub list_active ($;$) {
 173         my ($self, $wildmat) = @_;
 174         wildmat2re($wildmat);
 175         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 176                 $ng->{newsgroup} =~ $wildmat or next;
 177                 group_line($self, $ng);
 178         }
 179 }
 180
 181 sub list_active_times ($;$) {
 182         my ($self, $wildmat) = @_;
 183         wildmat2re($wildmat);
 184         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 185                 $ng->{newsgroup} =~ $wildmat or next;
 186                 my $c = eval { $ng->mm->created_at } || time;
 187                 more($self, "$ng->{newsgroup} $c $ng->{-primary_address}");
 188         }
 189 }
 190
 191 sub list_newsgroups ($;$) {
 192         my ($self, $wildmat) = @_;
 193         wildmat2re($wildmat);
 194         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 195                 $ng->{newsgroup} =~ $wildmat or next;
 196                 my $d = $ng->description;
 197                 more($self, "$ng->{newsgroup} $d");
 198         }
 199 }
 200
 201 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 202 sub cmd_list ($;$$) {
 203         my ($self, @args) = @_;
 204         if (scalar @args) {
 205                 my $arg = shift @args;
 206                 $arg =~ tr/A-Z./a-z_/;
 207                 $arg = "list_$arg";
 208
 209                 $arg = eval {
 210                         no strict 'refs';
 211                         *{$arg}{CODE};
 212                 };
 213                 return r501 unless $arg && args_ok($arg, scalar @args);
 214                 more($self, '215 information follows');
 215                 $arg->($self, @args);
 216         } else {
 217                 more($self, '215 list of newsgroups follows');
 218                 foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 219                         group_line($self, $ng);
 220                 }
 221         }
 222         '.'
 223 }
 224
 225 sub cmd_listgroup ($;$) {
 226         my ($self, $group) = @_;
 227         if (defined $group) {
 228                 my $res = cmd_group($self, $group);
 229                 return $res if ($res !~ /\A211 /);
 230                 more($self, $res);
 231         }
 232
 233         $self->{ng} or return '412 no newsgroup selected';
 234         my $n = 0;
 235         long_response($self, sub {
 236                 my $ary = $self->{ng}->mm->ids_after(\$n);
 237                 scalar @$ary or return;
 238                 more($self, join("\r\n", @$ary));
 239                 1;
 240         });
 241 }
 242
 243 sub parse_time ($$;$) {
 244         my ($date, $time, $gmt) = @_;
 245         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 246         if (defined $gmt) {
 247                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 248                 $gmt = 1;
 249         }
 250         my @now = $gmt ? gmtime : localtime;
 251         my ($YYYY, $MM, $DD);
 252         if (bytes::length($date) == 8) { # RFC 3977 allows YYYYMMDD
 253                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 254         } else { # legacy clients send YYMMDD
 255                 ($YYYY, $MM, $DD) = unpack('A2A2A2', $date);
 256                 my $cur_year = $now[5] + 1900;
 257                 if ($YYYY > $cur_year) {
 258                         $YYYY += int($cur_year / 1000) * 1000 - 100;
 259                 }
 260         }
 261         if ($gmt) {
 262                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 263         } else {
 264                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 265         }
 266 }
 267
 268 sub group_line ($$) {
 269         my ($self, $ng) = @_;
 270         my ($min, $max) = $ng->mm->minmax;
 271         more($self, "$ng->{newsgroup} $max $min n") if defined $min && defined $max;
 272 }
 273
 274 sub cmd_newgroups ($$$;$$) {
 275         my ($self, $date, $time, $gmt, $dists) = @_;
 276         my $ts = eval { parse_time($date, $time, $gmt) };
 277         return r501 if $@;
 278
 279         # TODO dists
 280         more($self, '231 list of new newsgroups follows');
 281         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 282                 my $c = eval { $ng->mm->created_at } || 0;
 283                 next unless $c > $ts;
 284                 group_line($self, $ng);
 285         }
 286         '.'
 287 }
 288
 289 sub wildmat2re (;$) {
 290         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 291         my %keep;
 292         my $salt = rand;
 293         my $tmp = $_[0];
 294
 295         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 296                 my $orig = $1;
 297                 my $key = sha1_hex($orig . $salt);
 298                 $orig =~ s/([^\w\-])+/\Q$1/g;
 299                 $keep{$key} = $orig;
 300                 $key
 301                 #gex;
 302         my %map = ('*' => '.*', '?' => '.' );
 303         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 304         if (scalar %keep) {
 305                 $tmp =~ s#([a-f0-9]{40})#
 306                         my $orig = $keep{$1};
 307                         defined $orig ? $orig : $1;
 308                         #ge;
 309         }
 310         $_[0] = qr/\A$tmp\z/;
 311 }
 312
 313 sub ngpat2re (;$) {
 314         return $_[0] = qr/\A\z/ unless defined $_[0];
 315         my %map = ('*' => '.*', ',' => '|');
 316         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 317         $_[0] = qr/\A(?:$_[0])\z/;
 318 }
 319
 320 sub cmd_newnews ($$$$;$$) {
 321         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 322         my $ts = eval { parse_time($date, $time, $gmt) };
 323         return r501 if $@;
 324         more($self, '230 list of new articles by message-id follows');
 325         my ($keep, $skip) = split('!', $newsgroups, 2);
 326         ngpat2re($keep);
 327         ngpat2re($skip);
 328         my @over;
 329         foreach my $ng (@{$self->{nntpd}->{grouplist}}) {
 330                 $ng->{newsgroup} =~ $keep or next;
 331                 $ng->{newsgroup} =~ $skip and next;
 332                 my $over = $ng->over or next;
 333                 push @over, $over;
 334         };
 335         return '.' unless @over;
 336
 337         my $prev = 0;
 338         long_response($self, sub {
 339                 my $over = $over[0];
 340                 my $msgs = $over->query_ts($ts, $prev);
 341                 if (scalar @$msgs) {
 342                         more($self, '<' .
 343                                 join(">\r\n<", map { $_->mid } @$msgs ).
 344                                 '>');
 345                         $prev = $msgs->[-1]->{num};
 346                 } else {
 347                         shift @over;
 348                         if (@over) { # continue onto next newsgroup
 349                                 $prev = 0;
 350                                 return 1;
 351                         } else { # break out of the long response.
 352                                 return;
 353                         }
 354                 }
 355         });
 356 }
 357
 358 sub cmd_group ($$) {
 359         my ($self, $group) = @_;
 360         my $no_such = '411 no such news group';
 361         my $ng = $self->{nntpd}->{groups}->{$group} or return $no_such;
 362
 363         $self->{ng} = $ng;
 364         my ($min, $max) = $ng->mm->minmax;
 365         $min ||= 0;
 366         $max ||= 0;
 367         $self->{article} = $min;
 368         my $est_size = $max - $min;
 369         "211 $est_size $min $max $group";
 370 }
 371
 372 sub article_adj ($$) {
 373         my ($self, $off) = @_;
 374         my $ng = $self->{ng} or return '412 no newsgroup selected';
 375
 376         my $n = $self->{article};
 377         defined $n or return '420 no current article has been selected';
 378
 379         $n += $off;
 380         my $mid = $ng->mm->mid_for($n);
 381         unless ($mid) {
 382                 $n = $off > 0 ? 'next' : 'previous';
 383                 return "421 no $n article in this group";
 384         }
 385         $self->{article} = $n;
 386         "223 $n <$mid> article retrieved - request text separately";
 387 }
 388
 389 sub cmd_next ($) { article_adj($_[0], 1) }
 390 sub cmd_last ($) { article_adj($_[0], -1) }
 391
 392 # We want to encourage using email and CC-ing everybody involved to avoid
 393 # the single-point-of-failure a single server provides.
 394 sub cmd_post ($) {
 395         my ($self) = @_;
 396         my $ng = $self->{ng};
 397         $ng ? "440 mailto:$ng->{-primary_address} to post"
 398                 : '440 posting not allowed'
 399 }
 400
 401 sub cmd_quit ($) {
 402         my ($self) = @_;
 403         res($self, '205 closing connection - goodbye!');
 404         $self->shutdn;
 405         undef;
 406 }
 407
 408 sub header_append ($$$) {
 409         my ($hdr, $k, $v) = @_;
 410         my @v = $hdr->header($k);
 411         foreach (@v) {
 412                 return if $v eq $_;
 413         }
 414         $hdr->header_set($k, @v, $v);
 415 }
 416
 417 sub xref ($$$$) {
 418         my ($self, $ng, $n, $mid) = @_;
 419         my $ret = $self->{nntpd}->{servername} . " $ng->{newsgroup}:$n";
 420
 421         # num_for is pretty cheap and sometimes we'll lookup the existence
 422         # of an article without getting even the OVER info.  In other words,
 423         # I'm not sure if its worth optimizing by scanning To:/Cc: and
 424         # PublicInbox::ExtMsg on the PSGI end is just as expensive
 425         foreach my $other (@{$self->{nntpd}->{grouplist}}) {
 426                 next if $ng eq $other;
 427                 my $num = eval { $other->mm->num_for($mid) } or next;
 428                 $ret .= " $other->{newsgroup}:$num";
 429         }
 430         $ret;
 431 }
 432
 433 sub set_nntp_headers ($$$$$) {
 434         my ($self, $hdr, $ng, $n, $mid) = @_;
 435
 436         # why? leafnode requires a Path: header for some inexplicable
 437         # reason.  We'll fake the shortest one possible.
 438         $hdr->header_set('Path', 'y');
 439
 440         # leafnode (and maybe other NNTP clients) have trouble dealing
 441         # with v2 messages which have multiple Message-IDs (either due
 442         # to our own content-based dedupe or buggy git-send-email versions).
 443         my @mids = $hdr->header('Message-ID');
 444         if (scalar(@mids) > 1) {
 445                 my $mid0 = "<$mid>";
 446                 $hdr->header_set('Message-ID', $mid0);
 447                 my @alt = $hdr->header('X-Alt-Message-ID');
 448                 my %seen = map { $_ => 1 } (@alt, $mid0);
 449                 foreach my $m (@mids) {
 450                         next if $seen{$m}++;
 451                         push @alt, $m;
 452                 }
 453                 $hdr->header_set('X-Alt-Message-ID', @alt);
 454         }
 455
 456         # clobber some
 457         my $xref = xref($self, $ng, $n, $mid);
 458         $hdr->header_set('Xref', $xref);
 459         $xref =~ s/:[0-9]+//g;
 460         $hdr->header_set('Newsgroups', (split(/ /, $xref, 2))[1]);
 461         header_append($hdr, 'List-Post', "<mailto:$ng->{-primary_address}>");
 462         if (my $url = $ng->base_url) {
 463                 $mid = mid_escape($mid);
 464                 header_append($hdr, 'Archived-At', "<$url$mid/>");
 465                 header_append($hdr, 'List-Archive', "<$url>");
 466         }
 467 }
 468
 469 sub art_lookup ($$$) {
 470         my ($self, $art, $set_headers) = @_;
 471         my $ng = $self->{ng};
 472         my ($n, $mid);
 473         my $err;
 474         if (defined $art) {
 475                 if ($art =~ /\A[0-9]+\z/) {
 476                         $err = '423 no such article number in this group';
 477                         $n = int($art);
 478                         goto find_mid;
 479                 } elsif ($art =~ /\A<([^>]+)>\z/) {
 480                         $mid = $1;
 481                         $err = r430;
 482                         $n = $ng->mm->num_for($mid) if $ng;
 483                         goto found if defined $n;
 484                         foreach my $g (values %{$self->{nntpd}->{groups}}) {
 485                                 $n = $g->mm->num_for($mid);
 486                                 if (defined $n) {
 487                                         $ng = $g;
 488                                         goto found;
 489                                 }
 490                         }
 491                         return $err;
 492                 } else {
 493                         return r501;
 494                 }
 495         } else {
 496                 $err = '420 no current article has been selected';
 497                 $n = $self->{article};
 498                 defined $n or return $err;
 499 find_mid:
 500                 $ng or return '412 no newsgroup has been selected';
 501                 $mid = $ng->mm->mid_for($n);
 502                 defined $mid or return $err;
 503         }
 504 found:
 505         my $smsg = $ng->over->get_art($n) or return $err;
 506         my $msg = $ng->msg_by_smsg($smsg) or return $err;
 507
 508         # Email::Simple->new will modify $msg in-place as documented
 509         # in its manpage, so what's left is the body and we won't need
 510         # to call Email::Simple::body(), later
 511         my $hdr = Email::Simple->new($msg)->header_obj;
 512         set_nntp_headers($self, $hdr, $ng, $n, $mid) if $set_headers;
 513         [ $n, $mid, $msg, $hdr ];
 514 }
 515
 516 sub msg_body_write ($$) {
 517         my ($self, $msg) = @_;
 518
 519         # these can momentarily double the memory consumption :<
 520         $$msg =~ s/^\./../smg;
 521         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 522         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 523         $self->msg_more($$msg);
 524         '.'
 525 }
 526
 527 sub set_art {
 528         my ($self, $art) = @_;
 529         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 530 }
 531
 532 sub msg_hdr_write ($$$) {
 533         my ($self, $hdr, $body_follows) = @_;
 534         $hdr = $hdr->as_string;
 535         utf8::encode($hdr);
 536         $hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 537
 538         # for leafnode compatibility, we need to ensure Message-ID headers
 539         # are only a single line.  We can't subclass Email::Simple::Header
 540         # and override _default_fold_at in here, either; since that won't
 541         # affect messages already in the archive.
 542         $hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 543         $hdr .= "\r\n" if $body_follows;
 544         $self->msg_more($hdr);
 545 }
 546
 547 sub cmd_article ($;$) {
 548         my ($self, $art) = @_;
 549         my $r = art_lookup($self, $art, 1);
 550         return $r unless ref $r;
 551         my ($n, $mid, $msg, $hdr) = @$r;
 552         set_art($self, $art);
 553         more($self, "220 $n <$mid> article retrieved - head and body follow");
 554         msg_hdr_write($self, $hdr, 1);
 555         msg_body_write($self, $msg);
 556 }
 557
 558 sub cmd_head ($;$) {
 559         my ($self, $art) = @_;
 560         my $r = art_lookup($self, $art, 2);
 561         return $r unless ref $r;
 562         my ($n, $mid, undef, $hdr) = @$r;
 563         set_art($self, $art);
 564         more($self, "221 $n <$mid> article retrieved - head follows");
 565         msg_hdr_write($self, $hdr, 0);
 566         '.'
 567 }
 568
 569 sub cmd_body ($;$) {
 570         my ($self, $art) = @_;
 571         my $r = art_lookup($self, $art, 0);
 572         return $r unless ref $r;
 573         my ($n, $mid, $msg) = @$r;
 574         set_art($self, $art);
 575         more($self, "222 $n <$mid> article retrieved - body follows");
 576         msg_body_write($self, $msg);
 577 }
 578
 579 sub cmd_stat ($;$) {
 580         my ($self, $art) = @_;
 581         my $r = art_lookup($self, $art, 0);
 582         return $r unless ref $r;
 583         my ($n, $mid) = @$r;
 584         set_art($self, $art);
 585         "223 $n <$mid> article retrieved - request text separately";
 586 }
 587
 588 sub cmd_ihave ($) { '435 article not wanted - do not send it' }
 589
 590 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time)) }
 591
 592 sub cmd_help ($) {
 593         my ($self) = @_;
 594         more($self, '100 help text follows');
 595         '.'
 596 }
 597
 598 sub get_range ($$) {
 599         my ($self, $range) = @_;
 600         my $ng = $self->{ng} or return '412 no news group has been selected';
 601         defined $range or return '420 No article(s) selected';
 602         my ($beg, $end);
 603         my ($min, $max) = $ng->mm->minmax;
 604         if ($range =~ /\A([0-9]+)\z/) {
 605                 $beg = $end = $1;
 606         } elsif ($range =~ /\A([0-9]+)-\z/) {
 607                 ($beg, $end) = ($1, $max);
 608         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 609                 ($beg, $end) = ($1, $2);
 610         } else {
 611                 return r501;
 612         }
 613         $beg = $min if ($beg < $min);
 614         $end = $max if ($end > $max);
 615         return '420 No article(s) selected' if ($beg > $end);
 616         [ $beg, $end ];
 617 }
 618
 619 sub long_response ($$) {
 620         my ($self, $cb) = @_; # cb returns true if more, false if done
 621
 622         my $fd = fileno($self->{sock});
 623         defined $fd or return;
 624         # make sure we disable reading during a long response,
 625         # clients should not be sending us stuff and making us do more
 626         # work while we are stream a response to them
 627         my $t0 = now();
 628         my $long_cb; # DANGER: self-referential
 629         $long_cb = sub {
 630                 # wbuf is unset or empty, here; $cb may add to it
 631                 my $more = eval { $cb->() };
 632                 if ($@ || !$self->{sock}) { # something bad happened...
 633                         $long_cb = undef;
 634                         my $diff = now() - $t0;
 635                         if ($@) {
 636                                 err($self,
 637                                     "%s during long response[$fd] - %0.6f",
 638                                     $@, $diff);
 639                         }
 640                         out($self, " deferred[$fd] aborted - %0.6f", $diff);
 641                         $self->close;
 642                 } elsif ($more) { # $self->{wbuf}:
 643                         update_idle_time($self);
 644
 645                         # no recursion, schedule another call ASAP
 646                         # but only after all pending writes are done
 647                         my $wbuf = $self->{wbuf} ||= [];
 648                         push @$wbuf, $long_cb;
 649
 650                         # wbuf may be populated by $cb, no need to rearm if so:
 651                         $self->requeue if scalar(@$wbuf) == 1;
 652                 } else { # all done!
 653                         $long_cb = undef;
 654                         res($self, '.');
 655                         out($self, " deferred[$fd] done - %0.6f", now() - $t0);
 656                         $self->requeue unless $self->{wbuf};
 657                 }
 658         };
 659         $self->write($long_cb); # kick off!
 660         undef;
 661 }
 662
 663 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 664         my ($self, $xhdr, $range) = @_;
 665
 666         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 667                 my ($ng, $n) = mid_lookup($self, $1);
 668                 return r430 unless $n;
 669                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $range);
 670         } else { # numeric range
 671                 $range = $self->{article} unless defined $range;
 672                 my $r = get_range($self, $range);
 673                 return $r unless ref $r;
 674                 my $mm = $self->{ng}->mm;
 675                 my ($beg, $end) = @$r;
 676                 more($self, $xhdr ? r221 : r225);
 677                 long_response($self, sub {
 678                         my $r = $mm->msg_range(\$beg, $end);
 679                         @$r or return;
 680                         more($self, join("\r\n", map {
 681                                 "$_->[0] <$_->[1]>"
 682                         } @$r));
 683                         1;
 684                 });
 685         }
 686 }
 687
 688 sub mid_lookup ($$) {
 689         my ($self, $mid) = @_;
 690         my $self_ng = $self->{ng};
 691         if ($self_ng) {
 692                 my $n = $self_ng->mm->num_for($mid);
 693                 return ($self_ng, $n) if defined $n;
 694         }
 695         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 696                 next if defined $self_ng && $ng eq $self_ng;
 697                 my $n = $ng->mm->num_for($mid);
 698                 return ($ng, $n) if defined $n;
 699         }
 700         (undef, undef);
 701 }
 702
 703 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 704         my ($self, $xhdr, $range) = @_;
 705
 706         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 707                 my $mid = $1;
 708                 my ($ng, $n) = mid_lookup($self, $mid);
 709                 return r430 unless $n;
 710                 hdr_mid_response($self, $xhdr, $ng, $n, $range,
 711                                 xref($self, $ng, $n, $mid));
 712         } else { # numeric range
 713                 $range = $self->{article} unless defined $range;
 714                 my $r = get_range($self, $range);
 715                 return $r unless ref $r;
 716                 my $ng = $self->{ng};
 717                 my $mm = $ng->mm;
 718                 my ($beg, $end) = @$r;
 719                 more($self, $xhdr ? r221 : r225);
 720                 long_response($self, sub {
 721                         my $r = $mm->msg_range(\$beg, $end);
 722                         @$r or return;
 723                         more($self, join("\r\n", map {
 724                                 my $num = $_->[0];
 725                                 "$num ".xref($self, $ng, $num, $_->[1]);
 726                         } @$r));
 727                         1;
 728                 });
 729         }
 730 }
 731
 732 sub over_header_for {
 733         my ($over, $num, $field) = @_;
 734         my $smsg = $over->get_art($num) or return;
 735         return PublicInbox::SearchMsg::date($smsg) if $field eq 'date';
 736         $smsg->{$field};
 737 }
 738
 739 sub hdr_searchmsg ($$$$) {
 740         my ($self, $xhdr, $field, $range) = @_;
 741         if (defined $range && $range =~ /\A<(.+)>\z/) { # Message-ID
 742                 my ($ng, $n) = mid_lookup($self, $1);
 743                 return r430 unless defined $n;
 744                 my $v = over_header_for($ng->over, $n, $field);
 745                 hdr_mid_response($self, $xhdr, $ng, $n, $range, $v);
 746         } else { # numeric range
 747                 $range = $self->{article} unless defined $range;
 748                 my $over = $self->{ng}->over;
 749                 my $mm = $self->{ng}->mm;
 750                 my $r = get_range($self, $range);
 751                 return $r unless ref $r;
 752                 my ($beg, $end) = @$r;
 753                 more($self, $xhdr ? r221 : r225);
 754                 my $cur = $beg;
 755                 long_response($self, sub {
 756                         my $msgs = $over->query_xover($cur, $end);
 757                         my $nr = scalar @$msgs or return;
 758                         my $tmp = '';
 759                         foreach my $s (@$msgs) {
 760                                 $tmp .= $s->{num} . ' ' . $s->$field . "\r\n";
 761                         }
 762                         utf8::encode($tmp);
 763                         $self->msg_more($tmp);
 764                         $cur = $msgs->[-1]->{num} + 1;
 765                 });
 766         }
 767 }
 768
 769 sub do_hdr ($$$;$) {
 770         my ($self, $xhdr, $header, $range) = @_;
 771         my $sub = lc $header;
 772         if ($sub eq 'message-id') {
 773                 hdr_message_id($self, $xhdr, $range);
 774         } elsif ($sub eq 'xref') {
 775                 hdr_xref($self, $xhdr, $range);
 776         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 777                                 bytes|lines)\z/x) {
 778                 hdr_searchmsg($self, $xhdr, $sub, $range);
 779         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 780                 hdr_searchmsg($self, $xhdr, $1, $range);
 781         } else {
 782                 $xhdr ? (r221 . "\r\n.") : "503 HDR not permitted on $header";
 783         }
 784 }
 785
 786 # RFC 3977
 787 sub cmd_hdr ($$;$) {
 788         my ($self, $header, $range) = @_;
 789         do_hdr($self, 0, $header, $range);
 790 }
 791
 792 # RFC 2980
 793 sub cmd_xhdr ($$;$) {
 794         my ($self, $header, $range) = @_;
 795         do_hdr($self, 1, $header, $range);
 796 }
 797
 798 sub hdr_mid_prefix ($$$$$) {
 799         my ($self, $xhdr, $ng, $n, $mid) = @_;
 800         return $mid if $xhdr;
 801
 802         # HDR for RFC 3977 users
 803         if (my $self_ng = $self->{ng}) {
 804                 ($self_ng eq $ng) ? $n : '0';
 805         } else {
 806                 '0';
 807         }
 808 }
 809
 810 sub hdr_mid_response ($$$$$$) {
 811         my ($self, $xhdr, $ng, $n, $mid, $v) = @_;
 812         my $res = '';
 813         if ($xhdr) {
 814                 $res .= r221 . "\r\n";
 815                 $res .= "$mid $v\r\n";
 816         } else {
 817                 $res .= r225 . "\r\n";
 818                 my $pfx = hdr_mid_prefix($self, $xhdr, $ng, $n, $mid);
 819                 $res .= "$pfx $v\r\n";
 820         }
 821         res($self, $res .= '.');
 822         undef;
 823 }
 824
 825 sub cmd_xrover ($;$) {
 826         my ($self, $range) = @_;
 827         my $ng = $self->{ng} or return '412 no newsgroup selected';
 828         (defined $range && $range =~ /[<>]/) and
 829                 return '420 No article(s) selected'; # no message IDs
 830
 831         $range = $self->{article} unless defined $range;
 832         my $r = get_range($self, $range);
 833         return $r unless ref $r;
 834         my ($beg, $end) = @$r;
 835         my $mm = $ng->mm;
 836         my $over = $ng->over;
 837         more($self, '224 Overview information follows');
 838
 839         long_response($self, sub {
 840                 my $h = over_header_for($over, $beg, 'references');
 841                 more($self, "$beg $h") if defined($h);
 842                 $beg++ < $end;
 843         });
 844 }
 845
 846 sub over_line ($$$$) {
 847         my ($self, $ng, $num, $smsg) = @_;
 848         # n.b. field access and procedural calls can be
 849         # 10%-15% faster than OO method calls:
 850         my $s = join("\t", $num,
 851                 $smsg->{subject},
 852                 $smsg->{from},
 853                 PublicInbox::SearchMsg::date($smsg),
 854                 "<$smsg->{mid}>",
 855                 $smsg->{references},
 856                 $smsg->{bytes},
 857                 $smsg->{lines},
 858                 "Xref: " . xref($self, $ng, $num, $smsg->{mid}));
 859         utf8::encode($s);
 860         $s
 861 }
 862
 863 sub cmd_over ($;$) {
 864         my ($self, $range) = @_;
 865         if ($range && $range =~ /\A<(.+)>\z/) {
 866                 my ($ng, $n) = mid_lookup($self, $1);
 867                 defined $n or return r430;
 868                 my $smsg = $ng->over->get_art($n) or return r430;
 869                 more($self, '224 Overview information follows (multi-line)');
 870
 871                 # Only set article number column if it's the current group
 872                 my $self_ng = $self->{ng};
 873                 $n = 0 if (!$self_ng || $self_ng ne $ng);
 874                 more($self, over_line($self, $ng, $n, $smsg));
 875                 '.';
 876         } else {
 877                 cmd_xover($self, $range);
 878         }
 879 }
 880
 881 sub cmd_xover ($;$) {
 882         my ($self, $range) = @_;
 883         $range = $self->{article} unless defined $range;
 884         my $r = get_range($self, $range);
 885         return $r unless ref $r;
 886         my ($beg, $end) = @$r;
 887         more($self, "224 Overview information follows for $beg to $end");
 888         my $over = $self->{ng}->over;
 889         my $cur = $beg;
 890         long_response($self, sub {
 891                 my $msgs = $over->query_xover($cur, $end);
 892                 my $nr = scalar @$msgs or return;
 893
 894                 # OVERVIEW.FMT
 895                 more($self, join("\r\n", map {
 896                         over_line($self, $self->{ng}, $_->{num}, $_);
 897                         } @$msgs));
 898                 $cur = $msgs->[-1]->{num} + 1;
 899         });
 900 }
 901
 902 sub compressed { undef }
 903
 904 sub cmd_starttls ($) {
 905         my ($self) = @_;
 906         my $sock = $self->{sock} or return;
 907         # RFC 4642 2.2.1
 908         return r502 if (ref($sock) eq 'IO::Socket::SSL' || $self->compressed);
 909         my $opt = $self->{nntpd}->{accept_tls} or
 910                 return '580 can not initiate TLS negotiation';
 911         res($self, '382 Continue with TLS negotiation');
 912         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 913         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 914         undef;
 915 }
 916
 917 # RFC 8054
 918 sub cmd_compress ($$) {
 919         my ($self, $alg) = @_;
 920         return '503 Only the DEFLATE is supported' if uc($alg) ne 'DEFLATE';
 921         return r502 if $self->compressed || !$have_deflate;
 922         res($self, '206 Compression active');
 923         PublicInbox::NNTPdeflate->enable($self);
 924         $self->requeue;
 925         undef
 926 }
 927
 928 sub cmd_xpath ($$) {
 929         my ($self, $mid) = @_;
 930         return r501 unless $mid =~ /\A<(.+)>\z/;
 931         $mid = $1;
 932         my @paths;
 933         foreach my $ng (values %{$self->{nntpd}->{groups}}) {
 934                 my $n = $ng->mm->num_for($mid);
 935                 push @paths, "$ng->{newsgroup}/$n" if defined $n;
 936         }
 937         return '430 no such article on server' unless @paths;
 938         '223 '.join(' ', @paths);
 939 }
 940
 941 sub res ($$) { do_write($_[0], $_[1] . "\r\n") }
 942
 943 sub more ($$) { $_[0]->msg_more($_[1] . "\r\n") }
 944
 945 sub do_write ($$) {
 946         my $self = $_[0];
 947         my $done = $self->write(\($_[1]));
 948         return 0 unless $self->{sock};
 949
 950         $done;
 951 }
 952
 953 sub err ($$;@) {
 954         my ($self, $fmt, @args) = @_;
 955         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 956 }
 957
 958 sub out ($$;@) {
 959         my ($self, $fmt, @args) = @_;
 960         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 961 }
 962
 963 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 964 sub event_step {
 965         my ($self) = @_;
 966
 967         return unless $self->flush_write && $self->{sock};
 968
 969         update_idle_time($self);
 970         # only read more requests if we've drained the write buffer,
 971         # otherwise we can be buffering infinitely w/o backpressure
 972
 973         my $rbuf = $self->{rbuf} // (\(my $x = ''));
 974         my $r = 1;
 975
 976         if (index($$rbuf, "\n") < 0) {
 977                 my $off = bytes::length($$rbuf);
 978                 $r = $self->do_read($rbuf, LINE_MAX, $off) or return;
 979         }
 980         while ($r > 0 && $$rbuf =~ s/\A[ \t\r\n]*([^\r\n]*)\r?\n//) {
 981                 my $line = $1;
 982                 return $self->close if $line =~ /[[:cntrl:]]/s;
 983                 my $t0 = now();
 984                 my $fd = fileno($self->{sock});
 985                 $r = eval { process_line($self, $line) };
 986                 my $pending = $self->{wbuf} ? ' pending' : '';
 987                 out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
 988         }
 989
 990         return $self->close if $r < 0;
 991         my $len = bytes::length($$rbuf);
 992         return $self->close if ($len >= LINE_MAX);
 993         $self->rbuf_idle($rbuf);
 994         update_idle_time($self);
 995
 996         # maybe there's more pipelined data, or we'll have
 997         # to register it for socket-readiness notifications
 998         $self->requeue unless $self->{wbuf};
 999 }
1000
1001 sub not_idle_long ($$) {
1002         my ($self, $now) = @_;
1003         my $sock = $self->{sock} or return;
1004         my $ary = $EXPMAP->{fileno($sock)} or return;
1005         my $exp_at = $ary->[0] + $EXPTIME;
1006         $exp_at > $now;
1007 }
1008
1009 # for graceful shutdown in PublicInbox::Daemon:
1010 sub busy {
1011         my ($self, $now) = @_;
1012         ($self->{rbuf} || $self->{wbuf} || not_idle_long($self, $now));
1013 }
1014
1015 # this is an import to prevent "perl -c" from complaining about fields
1016 sub import {
1017         $have_deflate = eval { require PublicInbox::NNTPdeflate } and
1018                 $CAPABILITIES .= "COMPRESS DEFLATE\r\n";
1019 }
1020
1021 1;